source: palm/trunk/SOURCE/init_masks.f90 @ 1036

Last change on this file since 1036 was 1036, checked in by raasch, 9 years ago

code has been put under the GNU General Public License (v3)

  • Property svn:keywords set to Id
File size: 24.2 KB
Line 
1 SUBROUTINE init_masks
2
3!--------------------------------------------------------------------------------!
4! This file is part of PALM.
5!
6! PALM is free software: you can redistribute it and/or modify it under the terms
7! of the GNU General Public License as published by the Free Software Foundation,
8! either version 3 of the License, or (at your option) any later version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2012  Leibniz University Hannover
18!--------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: init_masks.f90 1036 2012-10-22 13:43:42Z raasch $
27!
28! 1032 2012-10-21 13:03:21Z letzel
29! mask locations determined based on scalar positions
30!
31! 1031 2012-10-19 14:35:30Z raasch
32! netCDF4 without parallel file support implemented
33!
34! 996 2012-09-07 10:41:47Z raasch
35! little reformatting
36!
37! 978 2012-08-09 08:28:32Z fricke
38! +z0h*
39!
40! 809 2012-01-30 13:32:58Z maronga
41! Bugfix: replaced .AND. and .NOT. with && and ! in the preprocessor directives
42!
43! 807 2012-01-25 11:53:51Z maronga
44! New cpp directive "__check" implemented which is used by check_namelist_files
45!
46! 771 2011-10-27 10:56:21Z heinze
47! +lpt
48!
49! 595 2010-11-12 09:52:10Z helmke
50! Calculation of z locations for masked output changed
51!
52! 564 2010-09-30 13:18:59Z helmke
53! assignment of mask_xyz_loop added, palm message identifiers of masked output
54! changed
55!
56! 557 2010-09-07 14:50:07Z weinreis
57! bugfix message string in set_mask_locations
58!
59! 553 2010-09-01 14:09:06Z weinreis
60! parameters for masked output are replaced by arrays
61!
62! 493 2010-03-01 08:30:24Z raasch
63! netcdf_format_mask* and format_parallel_io replaced by netcdf_data_format
64!
65! 410 2009-12-04 17:05:40Z letzel
66! Initial revision
67!
68!
69! Description:
70! ------------
71! Initialize masked data output
72!------------------------------------------------------------------------------!
73
74    USE arrays_3d
75    USE control_parameters
76    USE grid_variables
77    USE indices
78    USE netcdf_control
79    USE particle_attributes
80    USE pegrid
81
82    IMPLICIT NONE
83
84    CHARACTER (LEN=6)   ::  var
85    CHARACTER (LEN=7)   ::  unit
86    CHARACTER (LEN=10), DIMENSION(max_masks,100) ::  do_mask, do_mask_user
87
88    INTEGER :: i, ilen, ind(6), ind_array(1), j, k, n, sender
89    INTEGER, DIMENSION(:), ALLOCATABLE ::  tmp_array
90
91    LOGICAL ::  found
92!
93!-- Allocation and initialization
94    ALLOCATE( tmp_array( MAX(nx,ny,nz)+1 ) )
95
96    ALLOCATE( mask_i(max_masks,nxr-nxl+1), &
97              mask_j(max_masks,nyn-nys+1), &
98              mask_k(max_masks,nzt-nzb+1) )
99!
100!-- internal mask arrays ("mask,dimension,selection")
101    ALLOCATE( mask(max_masks,3,mask_xyz_dimension), &
102              mask_loop(max_masks,3,3) )
103   
104!
105!-- Parallel mask output not yet tested
106    IF ( netcdf_data_format > 4 )  THEN
107       message_string = 'netCDF file formats '//                         &
108                        '3 (netCDF 4) and 4 (netCDF 4 Classic model)'//  &
109                        '&are currently not supported (not yet tested).'
110       CALL message( 'init_masks', 'PA0328', 1, 2, 0, 6, 0 )
111    ENDIF
112
113!
114!-- Store data output parameters for masked data output in few shared arrays
115    DO  mid = 1, masks
116   
117       do_mask     (mid,:) = data_output_masks(mid,:)
118       do_mask_user(mid,:) = data_output_masks_user(mid,:)
119       mask      (mid,1,:) = mask_x(mid,:) 
120       mask      (mid,2,:) = mask_y(mid,:)
121       mask      (mid,3,:) = mask_z(mid,:) 
122       
123       IF ( mask_x_loop(mid,1) == -1.0  .AND.  mask_x_loop(mid,2) == -1.0  &
124            .AND.  mask_x_loop(mid,3) == -1.0 )  THEN
125          mask_loop(mid,1,1:2) = -1.0
126          mask_loop(mid,1,3) = 0.0
127       ELSE
128          mask_loop(mid,1,:) = mask_x_loop(mid,:)
129       ENDIF
130       IF ( mask_y_loop(mid,1) == -1.0  .AND.  mask_y_loop(mid,2) == -1.0  &
131            .AND.  mask_y_loop(mid,3) == -1.0 )  THEN
132          mask_loop(mid,2,1:2) = -1.0
133          mask_loop(mid,2,3) = 0.0
134       ELSE
135          mask_loop(mid,2,:) = mask_y_loop(mid,:)
136       ENDIF
137       IF ( mask_z_loop(mid,1) == -1.0  .AND.  mask_z_loop(mid,2) == -1.0  &
138            .AND.  mask_z_loop(mid,3) == -1.0 )  THEN
139          mask_loop(mid,3,1:2) = -1.0
140          mask_loop(mid,3,3) = 0.0
141       ELSE
142          mask_loop(mid,3,:) = mask_z_loop(mid,:)
143       ENDIF
144       
145    ENDDO
146   
147    mask_i = -1; mask_j = -1; mask_k = -1
148   
149!
150!-- Global arrays are required by define_netcdf_header.
151    IF ( myid == 0  .OR.  netcdf_data_format > 4 )  THEN
152       ALLOCATE( mask_i_global(max_masks,nx+1), &
153                 mask_j_global(max_masks,ny+1), &
154                 mask_k_global(max_masks,nz+1) )
155       mask_i_global = -1; mask_j_global = -1; mask_k_global = -1
156    ENDIF
157
158!
159!-- Determine variable names for each mask
160    DO  mid = 1, masks
161!
162!--    Append user-defined data output variables to the standard data output
163       IF ( do_mask_user(mid,1) /= ' ' )  THEN
164          i = 1
165          DO  WHILE ( do_mask(mid,i) /= ' '  .AND.  i <= 100 )
166             i = i + 1
167          ENDDO
168          j = 1
169          DO  WHILE ( do_mask_user(mid,j) /= ' '  .AND.  j <= 100 )
170             IF ( i > 100 )  THEN
171                WRITE ( message_string, * ) 'number of output quantitities ', &
172                     'given by data_output_mask and data_output_mask_user ', &
173                     'exceeds the limit of 100'
174                CALL message( 'init_masks', 'PA0329', 1, 2, 0, 6, 0 )
175             ENDIF
176             do_mask(mid,i) = do_mask_user(mid,j)
177             i = i + 1
178             j = j + 1
179          ENDDO
180       ENDIF
181
182!
183!--    Check and set steering parameters for mask data output and averaging
184       i   = 1
185       DO WHILE ( do_mask(mid,i) /= ' '  .AND.  i <= 100 )
186!
187!--       Check for data averaging
188          ilen = LEN_TRIM( do_mask(mid,i) )
189          j = 0                                              ! no data averaging
190          IF ( ilen > 3 )  THEN
191             IF ( do_mask(mid,i)(ilen-2:ilen) == '_av' )  THEN
192                j = 1                                           ! data averaging
193                do_mask(mid,i) = do_mask(mid,i)(1:ilen-3)
194             ENDIF
195          ENDIF
196          var = TRIM( do_mask(mid,i) )
197!
198!--       Check for allowed value and set units
199          SELECT CASE ( TRIM( var ) )
200
201             CASE ( 'e' )
202                IF ( constant_diffusion )  THEN
203                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
204                        '" requires constant_diffusion = .FALSE.'
205                   CALL message( 'init_masks', 'PA0103', 1, 2, 0, 6, 0 )
206                ENDIF
207                unit = 'm2/s2'
208
209             CASE ( 'lpt' )
210                IF ( .NOT. cloud_physics )  THEN
211                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
212                        '" requires cloud_physics = .TRUE.'
213                   CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 )
214                ENDIF
215                unit = 'K'
216
217             CASE ( 'pc', 'pr' )
218                IF ( .NOT. particle_advection )  THEN
219                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
220                        '" requires a "particles_par"-NAMELIST in the ', &
221                        'parameter file (PARIN)'
222                   CALL message( 'init_masks', 'PA0104', 1, 2, 0, 6, 0 )
223                ENDIF
224                IF ( TRIM( var ) == 'pc' )  unit = 'number'
225                IF ( TRIM( var ) == 'pr' )  unit = 'm'
226
227             CASE ( 'q', 'vpt' )
228                IF ( .NOT. humidity )  THEN
229                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
230                        '" requires humidity = .TRUE.'
231                   CALL message( 'init_masks', 'PA0105', 1, 2, 0, 6, 0 )
232                ENDIF
233                IF ( TRIM( var ) == 'q'   )  unit = 'kg/kg'
234                IF ( TRIM( var ) == 'vpt' )  unit = 'K'
235
236             CASE ( 'ql' )
237                IF ( .NOT. ( cloud_physics  .OR.  cloud_droplets ) )  THEN
238                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
239                        '" requires cloud_physics = .TRUE. or cloud_droplets', &
240                        ' = .TRUE.'
241                   CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 )
242                ENDIF
243                unit = 'kg/kg'
244
245             CASE ( 'ql_c', 'ql_v', 'ql_vp' )
246                IF ( .NOT. cloud_droplets )  THEN
247                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
248                        '" requires cloud_droplets = .TRUE.'
249                   CALL message( 'init_masks', 'PA0107', 1, 2, 0, 6, 0 )
250                ENDIF
251                IF ( TRIM( var ) == 'ql_c'  )  unit = 'kg/kg'
252                IF ( TRIM( var ) == 'ql_v'  )  unit = 'm3'
253                IF ( TRIM( var ) == 'ql_vp' )  unit = 'none'
254
255             CASE ( 'qv' )
256                IF ( .NOT. cloud_physics )  THEN
257                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
258                        '" requires cloud_physics = .TRUE.'
259                   CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 )
260                ENDIF
261                unit = 'kg/kg'
262
263             CASE ( 'rho' )
264                IF ( .NOT. ocean )  THEN
265                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
266                        '" requires ocean = .TRUE.'
267                   CALL message( 'init_masks', 'PA0109', 1, 2, 0, 6, 0 )
268                ENDIF
269                unit = 'kg/m3'
270
271             CASE ( 's' )
272                IF ( .NOT. passive_scalar )  THEN
273                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
274                        '" requires passive_scalar = .TRUE.'
275                   CALL message( 'init_masks', 'PA0110', 1, 2, 0, 6, 0 )
276                ENDIF
277                unit = 'conc'
278
279             CASE ( 'sa' )
280                IF ( .NOT. ocean )  THEN
281                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
282                        '" requires ocean = .TRUE.'
283                   CALL message( 'init_masks', 'PA0109', 1, 2, 0, 6, 0 )
284                ENDIF
285                unit = 'psu'
286
287             CASE ( 'u*', 't*', 'lwp*', 'pra*', 'prr*', 'z0*', 'z0h*' )
288                WRITE ( message_string, * ) 'illegal value for data_',&
289                     'output: "', TRIM( var ), '" is only allowed', &
290                     'for horizontal cross section'
291                CALL message( 'init_masks', 'PA0111', 1, 2, 0, 6, 0 )
292
293             CASE ( 'p', 'pt', 'u', 'v', 'w' )
294                IF ( TRIM( var ) == 'p'  )  unit = 'Pa'
295                IF ( TRIM( var ) == 'pt' )  unit = 'K'
296                IF ( TRIM( var ) == 'u'  )  unit = 'm/s'
297                IF ( TRIM( var ) == 'v'  )  unit = 'm/s'
298                IF ( TRIM( var ) == 'w'  )  unit = 'm/s'
299                CONTINUE
300
301             CASE DEFAULT
302                CALL user_check_data_output( var, unit )
303
304                IF ( unit == 'illegal' )  THEN
305                   IF ( do_mask_user(mid,1) /= ' ' )  THEN
306                      WRITE ( message_string, * ) 'illegal value for data_',&
307                           'output or data_output_user: "', &
308                           TRIM( do_mask(mid,i) ), '"'
309                      CALL message( 'init_masks', 'PA0114', 1, 2, 0, 6, 0 )
310                   ELSE
311                      WRITE ( message_string, * ) 'illegal value for data_',&
312                           'output: "', TRIM( do_mask(mid,i) ), '"'
313                      CALL message( 'init_masks', 'PA0330', 1, 2, 0, 6, 0 )
314                   ENDIF
315                ENDIF
316
317          END SELECT
318!
319!--       Set the internal steering parameters appropriately
320          domask_no(mid,j)                    = domask_no(mid,j) + 1
321          domask(mid,j,domask_no(mid,j))      = do_mask(mid,i)
322          domask_unit(mid,j,domask_no(mid,j)) = unit
323
324          IF ( j == 1 )  THEN
325!
326!--          Check, if variable is already subject to averaging
327             found = .FALSE.
328             DO  k = 1, doav_n
329                IF ( TRIM( doav(k) ) == TRIM( var ) )  found = .TRUE.
330             ENDDO
331
332             IF ( .NOT. found )  THEN
333                doav_n = doav_n + 1
334                doav(doav_n) = var
335             ENDIF
336          ENDIF
337
338          i = i + 1
339
340       ENDDO   ! do_mask(mid,i)
341    ENDDO   ! mid
342
343
344!
345!-- Determine mask locations for each mask
346    DO  mid = 1, masks
347!
348!--    Set local masks for each subdomain along all three dimensions
349       CALL set_mask_locations( 1, dx, 'dx', nx, 'nx', nxl, nxr )
350       CALL set_mask_locations( 2, dy, 'dy', ny, 'ny', nys, nyn )
351       CALL set_mask_locations( 3, dz, 'dz', nz, 'nz', nzb, nzt )
352!
353!--    Set global masks along all three dimensions (required by
354!--    define_netcdf_header).
355#if defined( __parallel ) && ! defined ( __check )
356!
357!--    PE0 receives partial arrays from all processors of the respective mask
358!--    and outputs them. Here a barrier has to be set, because otherwise
359!--    "-MPI- FATAL: Remote protocol queue full" may occur.
360
361       CALL MPI_BARRIER( comm2d, ierr )
362
363       IF ( myid == 0 )  THEN
364!
365!--       Local arrays can be relocated directly.
366          mask_i_global(mid,mask_start_l(mid,1): &
367                       mask_start_l(mid,1)+mask_size_l(mid,1)-1) = &
368                       mask_i(mid,:mask_size_l(mid,1))
369          mask_j_global(mid,mask_start_l(mid,2): &
370                       mask_start_l(mid,2)+mask_size_l(mid,2)-1) = &
371                       mask_j(mid,:mask_size_l(mid,2))
372          mask_k_global(mid,mask_start_l(mid,3): &
373                       mask_start_l(mid,3)+mask_size_l(mid,3)-1) = &
374                       mask_k(mid,:mask_size_l(mid,3))
375!
376!--       Receive data from all other PEs.
377          DO  n = 1, numprocs-1
378!
379!--          Receive index limits first, then arrays.
380!--          Index limits are received in arbitrary order from the PEs.
381             CALL MPI_RECV( ind(1), 6, MPI_INTEGER, MPI_ANY_SOURCE, 0,  &
382                  comm2d, status, ierr )
383!
384!--          Not all PEs have data for the mask.
385             IF ( ind(1) /= -9999 )  THEN
386                sender = status(MPI_SOURCE)
387                CALL MPI_RECV( tmp_array(ind(1)), ind(2)-ind(1)+1,  &
388                               MPI_INTEGER, sender, 1, comm2d, status, ierr )
389                mask_i_global(mid,ind(1):ind(2)) = tmp_array(ind(1):ind(2))
390                CALL MPI_RECV( tmp_array(ind(3)), ind(4)-ind(3)+1,  &
391                               MPI_INTEGER, sender, 2, comm2d, status, ierr )
392                mask_j_global(mid,ind(3):ind(4)) = tmp_array(ind(3):ind(4))
393                CALL MPI_RECV( tmp_array(ind(5)), ind(6)-ind(5)+1,  &
394                               MPI_INTEGER, sender, 3, comm2d, status, ierr )
395                mask_k_global(mid,ind(5):ind(6)) = tmp_array(ind(5):ind(6))
396             ENDIF
397          ENDDO
398
399       ELSE
400!
401!--       If at least part of the mask resides on the PE, send the index limits
402!--       for the target array, otherwise send -9999 to PE0.
403          IF ( mask_size_l(mid,1) > 0  .AND.  mask_size_l(mid,2) > 0  .AND.  &
404               mask_size_l(mid,3) > 0  )  THEN
405             ind(1) = mask_start_l(mid,1)
406             ind(2) = mask_start_l(mid,1) + mask_size_l(mid,1) - 1
407             ind(3) = mask_start_l(mid,2)
408             ind(4) = mask_start_l(mid,2) + mask_size_l(mid,2) - 1
409             ind(5) = mask_start_l(mid,3)
410             ind(6) = mask_start_l(mid,3) + mask_size_l(mid,3) - 1
411          ELSE
412             ind(1) = -9999; ind(2) = -9999
413             ind(3) = -9999; ind(4) = -9999
414             ind(5) = -9999; ind(6) = -9999
415          ENDIF
416          CALL MPI_SEND( ind(1), 6, MPI_INTEGER, 0, 0, comm2d, ierr )
417!
418!--       If applicable, send data to PE0.
419          IF ( ind(1) /= -9999 )  THEN
420             tmp_array(:mask_size_l(mid,1)) = mask_i(mid,:mask_size_l(mid,1))
421             CALL MPI_SEND( tmp_array(1), mask_size_l(mid,1),  &
422                            MPI_INTEGER, 0, 1, comm2d, ierr )
423             tmp_array(:mask_size_l(mid,2)) = mask_j(mid,:mask_size_l(mid,2))
424             CALL MPI_SEND( tmp_array(1), mask_size_l(mid,2),  &
425                            MPI_INTEGER, 0, 2, comm2d, ierr )
426             tmp_array(:mask_size_l(mid,3)) = mask_k(mid,:mask_size_l(mid,3))
427             CALL MPI_SEND( tmp_array(1), mask_size_l(mid,3),  &
428                            MPI_INTEGER, 0, 3, comm2d, ierr )
429          ENDIF
430       ENDIF
431!
432!--    A barrier has to be set, because otherwise some PEs may proceed too fast
433!--    so that PE0 may receive wrong data on tag 0.
434       CALL MPI_BARRIER( comm2d, ierr )
435       
436       IF ( netcdf_data_format > 4 )  THEN
437         
438          CALL MPI_BCAST( mask_i_global(mid,:), nx+1, MPI_INTEGER, 0, comm2d, &
439                          ierr )
440          CALL MPI_BCAST( mask_j_global(mid,:), ny+1, MPI_INTEGER, 0, comm2d, &
441                          ierr )
442          CALL MPI_BCAST( mask_k_global(mid,:), nz+1, MPI_INTEGER, 0, comm2d, &
443                          ierr ) 
444         
445       ENDIF
446
447#elif ! defined ( __parallel )
448!
449!--    Local arrays can be relocated directly.
450       mask_i_global(mid,:) = mask_i(mid,:)
451       mask_j_global(mid,:) = mask_j(mid,:)
452       mask_k_global(mid,:) = mask_k(mid,:)
453#endif
454    ENDDO   ! mid
455
456    DEALLOCATE( tmp_array )
457!
458!-- Internal mask arrays cannot be deallocated on PE 0 because they are
459!-- required for header output on PE 0.
460    IF ( myid /= 0 )  DEALLOCATE( mask, mask_loop )
461
462 CONTAINS
463
464    SUBROUTINE set_mask_locations( dim, dxyz, dxyz_string, nxyz, nxyz_string, &
465                                   lb, ub )
466!------------------------------------------------------------------------------!
467!
468! Description:
469! ------------
470! Set local mask for each subdomain along 'dim' direction.
471!------------------------------------------------------------------------------!
472
473       IMPLICIT NONE
474
475       CHARACTER (LEN=2) :: dxyz_string, nxyz_string
476       INTEGER  ::  count, count_l, dim, m, loop_begin, loop_end, loop_stride, &
477                    lb, nxyz, ub
478       REAL     ::  dxyz, ddxyz, tmp1, tmp2
479
480       count = 0;  count_l = 0;  ddxyz = 1.0 / dxyz;  tmp1 = 0.0;  tmp2 = 0.0
481
482       IF ( mask(mid,dim,1) >= 0.0 )  THEN
483!
484!--       use predefined mask_* array
485          DO  WHILE ( mask(mid,dim,count+1) >= 0.0 )
486             count = count + 1
487             IF ( dim == 1 .OR. dim == 2 )  THEN
488                m = NINT( mask(mid,dim,count) * mask_scale(dim) * ddxyz - 0.5 )
489             ELSEIF ( dim == 3 )  THEN
490                ind_array =  &
491                     MINLOC( ABS( mask(mid,dim,count) * mask_scale(dim) - zu ) )
492                m = ind_array(1) - 1 + nzb  ! MINLOC uses lower array bound 1
493             ENDIF
494             IF ( m > nxyz )  THEN
495                WRITE ( message_string, '(I3,A,I3,A,I1,3A,I3)' )  &
496                     m,' in mask ',mid,' along dimension ',dim,  &
497                     ' exceeds ',nxyz_string,' = ',nxyz
498                CALL message( 'init_masks', 'PA0331', 1, 2, 0, 6, 0 )
499             ENDIF
500             IF ( m >= lb .AND. m <= ub )  THEN
501                IF ( count_l == 0 )  mask_start_l(mid,dim) = count
502                count_l = count_l + 1
503                IF ( dim == 1 )  THEN
504                   mask_i(mid,count_l) = m
505                ELSEIF ( dim == 2 )  THEN
506                   mask_j(mid,count_l) = m
507                ELSEIF ( dim == 3 )  THEN
508                   mask_k(mid,count_l) = m
509                ENDIF
510             ENDIF
511             IF ( count == mask_xyz_dimension )  EXIT
512          ENDDO
513          mask_size(mid,dim)   = count
514          mask_size_l(mid,dim) = count_l
515
516       ELSE
517!
518!--       use predefined mask_loop_* array, or use the default (all grid points
519!--       along this direction)
520          IF ( mask_loop(mid,dim,1) < 0.0 )  THEN
521             tmp1 = mask_loop(mid,dim,1)
522             mask_loop(mid,dim,1) = 0.0   ! (default)
523          ENDIF
524          IF ( dim == 1 .OR. dim == 2 )  THEN
525             IF ( mask_loop(mid,dim,2) < 0.0 )  THEN
526                tmp2 = mask_loop(mid,dim,2)
527                mask_loop(mid,dim,2) = nxyz*dxyz / mask_scale(dim)   ! (default)
528             ENDIF
529             IF ( MAXVAL( mask_loop(mid,dim,1:2) )  &
530                  > nxyz * dxyz / mask_scale(dim) )  THEN
531                WRITE ( message_string, '(2(A,I3,A,I1,A,F9.3),5A,I1,A,F9.3)' ) &
532                     'mask_loop(',mid,',',dim,',1)=',mask_loop(mid,dim,1), &
533                     ' and/or mask_loop(',mid,',',dim,',2)=', &
534                     mask_loop(mid,dim,2),'&exceed ', &
535                     nxyz_string,'*',dxyz_string,'/mask_scale(',dim,')=', &
536                     nxyz*dxyz/mask_scale(dim)
537                CALL message( 'init_masks', 'PA0332', 1, 2, 0, 6, 0 )
538             ENDIF
539             loop_begin  = NINT( mask_loop(mid,dim,1) * mask_scale(dim) &
540                  * ddxyz - 0.5 )
541             loop_end    = NINT( mask_loop(mid,dim,2) * mask_scale(dim) &
542                  * ddxyz - 0.5 )
543             loop_stride = NINT( mask_loop(mid,dim,3) * mask_scale(dim) &
544                  * ddxyz )
545          ELSEIF ( dim == 3 )  THEN
546             IF ( mask_loop(mid,dim,2) < 0.0 )  THEN
547                tmp2 = mask_loop(mid,dim,2)
548                mask_loop(mid,dim,2) = zu(nz) / mask_scale(dim)   ! (default)
549             ENDIF
550             IF ( MAXVAL( mask_loop(mid,dim,1:2) )  &
551                  > zu(nz) / mask_scale(dim) )  THEN
552                WRITE ( message_string, '(2(A,I3,A,I1,A,F9.3),A,I1,A,F9.3)' ) &
553                     'mask_loop(',mid,',',dim,',1)=',mask_loop(mid,dim,1), &
554                     ' and/or mask_loop(',mid,',',dim,',2)=', &
555                     mask_loop(mid,dim,2),'&exceed zu(nz)/mask_scale(',dim, &
556                     ')=',zu(nz)/mask_scale(dim)
557                CALL message( 'init_masks', 'PA0333', 1, 2, 0, 6, 0 )
558             ENDIF
559             ind_array =  &
560                  MINLOC( ABS( mask_loop(mid,dim,1) * mask_scale(dim) - zu ) )
561             loop_begin =  &
562                  ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1
563             ind_array =  &
564                  MINLOC( ABS( mask_loop(mid,dim,2) * mask_scale(dim) - zu ) )
565             loop_end = ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1
566!
567!--          The following line assumes a constant vertical grid spacing within
568!--          the vertical mask range; it fails for vertical grid stretching.
569!--          Maybe revise later. Issue warning but continue execution.
570             loop_stride = NINT( mask_loop(mid,dim,3) * mask_scale(dim) * ddxyz )
571
572             IF ( mask_loop(mid,dim,2) * mask_scale(dim) > dz_stretch_level )  &
573                  THEN
574                WRITE ( message_string, '(A,I3,A,I1,A,F9.3,A,F8.2,3A)' ) &
575                     'mask_loop(',mid,',',dim,',2)=', mask_loop(mid,dim,2),&
576                     ' exceeds dz_stretch_level=',dz_stretch_level, &
577                     '.&Vertical mask locations will not ', &
578                     'match the desired heights&within the stretching ', &
579                     'region. Recommendation: use mask instead of mask_loop.'
580                CALL message( 'init_masks', 'PA0334', 0, 1, 0, 6, 0 )
581             ENDIF
582
583          ENDIF
584!
585!--       If necessary, reset mask_loop(mid,dim,1) and mask_loop(mid,dim,2).
586          IF ( tmp1 < 0.0 )  mask_loop(mid,dim,1) = tmp1
587          IF ( tmp2 < 0.0 )  mask_loop(mid,dim,2) = tmp2
588!
589!--       The default stride +/-1 (every grid point) applies if
590!--       mask_loop(mid,dim,3) is not specified (its default is zero).
591          IF ( loop_stride == 0 )  THEN
592             IF ( loop_end >= loop_begin )  THEN
593                loop_stride =  1
594             ELSE
595                loop_stride = -1
596             ENDIF
597          ENDIF
598          DO  m = loop_begin, loop_end, loop_stride
599             count = count + 1
600             IF ( m >= lb  .AND.  m <= ub )  THEN
601                IF ( count_l == 0 )  mask_start_l(mid,dim) = count
602                count_l = count_l + 1
603                IF ( dim == 1 )  THEN
604                   mask_i(mid,count_l) = m
605                ELSEIF ( dim == 2 )  THEN
606                   mask_j(mid,count_l) = m
607                ELSEIF ( dim == 3 )  THEN
608                   mask_k(mid,count_l) = m
609                ENDIF
610             ENDIF
611          ENDDO
612          mask_size(mid,dim)   = count
613          mask_size_l(mid,dim) = count_l
614       ENDIF
615
616    END SUBROUTINE set_mask_locations
617
618 END SUBROUTINE init_masks
Note: See TracBrowser for help on using the repository browser.