source: palm/trunk/SOURCE/init_masks.f90 @ 1035

Last change on this file since 1035 was 1035, checked in by raasch, 9 years ago

revisions r1031 and r1034 documented

  • Property svn:keywords set to Id
File size: 23.4 KB
Line 
1 SUBROUTINE init_masks
2
3!------------------------------------------------------------------------------!
4! Current revisions:
5! -----------------
6!
7!
8! Former revisions:
9! -----------------
10! $Id: init_masks.f90 1035 2012-10-22 11:42:53Z raasch $
11!
12! 1032 2012-10-21 13:03:21Z letzel
13! mask locations determined based on scalar positions
14!
15! 1031 2012-10-19 14:35:30Z raasch
16! netCDF4 without parallel file support implemented
17!
18! 996 2012-09-07 10:41:47Z raasch
19! little reformatting
20!
21! 978 2012-08-09 08:28:32Z fricke
22! +z0h*
23!
24! 809 2012-01-30 13:32:58Z maronga
25! Bugfix: replaced .AND. and .NOT. with && and ! in the preprocessor directives
26!
27! 807 2012-01-25 11:53:51Z maronga
28! New cpp directive "__check" implemented which is used by check_namelist_files
29!
30! 771 2011-10-27 10:56:21Z heinze
31! +lpt
32!
33! 595 2010-11-12 09:52:10Z helmke
34! Calculation of z locations for masked output changed
35!
36! 564 2010-09-30 13:18:59Z helmke
37! assignment of mask_xyz_loop added, palm message identifiers of masked output
38! changed
39!
40! 557 2010-09-07 14:50:07Z weinreis
41! bugfix message string in set_mask_locations
42!
43! 553 2010-09-01 14:09:06Z weinreis
44! parameters for masked output are replaced by arrays
45!
46! 493 2010-03-01 08:30:24Z raasch
47! netcdf_format_mask* and format_parallel_io replaced by netcdf_data_format
48!
49! 410 2009-12-04 17:05:40Z letzel
50! Initial revision
51!
52!
53! Description:
54! ------------
55! Initialize masked data output
56!------------------------------------------------------------------------------!
57
58    USE arrays_3d
59    USE control_parameters
60    USE grid_variables
61    USE indices
62    USE netcdf_control
63    USE particle_attributes
64    USE pegrid
65
66    IMPLICIT NONE
67
68    CHARACTER (LEN=6)   ::  var
69    CHARACTER (LEN=7)   ::  unit
70    CHARACTER (LEN=10), DIMENSION(max_masks,100) ::  do_mask, do_mask_user
71
72    INTEGER :: i, ilen, ind(6), ind_array(1), j, k, n, sender
73    INTEGER, DIMENSION(:), ALLOCATABLE ::  tmp_array
74
75    LOGICAL ::  found
76!
77!-- Allocation and initialization
78    ALLOCATE( tmp_array( MAX(nx,ny,nz)+1 ) )
79
80    ALLOCATE( mask_i(max_masks,nxr-nxl+1), &
81              mask_j(max_masks,nyn-nys+1), &
82              mask_k(max_masks,nzt-nzb+1) )
83!
84!-- internal mask arrays ("mask,dimension,selection")
85    ALLOCATE( mask(max_masks,3,mask_xyz_dimension), &
86              mask_loop(max_masks,3,3) )
87   
88!
89!-- Parallel mask output not yet tested
90    IF ( netcdf_data_format > 4 )  THEN
91       message_string = 'netCDF file formats '//                         &
92                        '3 (netCDF 4) and 4 (netCDF 4 Classic model)'//  &
93                        '&are currently not supported (not yet tested).'
94       CALL message( 'init_masks', 'PA0328', 1, 2, 0, 6, 0 )
95    ENDIF
96
97!
98!-- Store data output parameters for masked data output in few shared arrays
99    DO  mid = 1, masks
100   
101       do_mask     (mid,:) = data_output_masks(mid,:)
102       do_mask_user(mid,:) = data_output_masks_user(mid,:)
103       mask      (mid,1,:) = mask_x(mid,:) 
104       mask      (mid,2,:) = mask_y(mid,:)
105       mask      (mid,3,:) = mask_z(mid,:) 
106       
107       IF ( mask_x_loop(mid,1) == -1.0  .AND.  mask_x_loop(mid,2) == -1.0  &
108            .AND.  mask_x_loop(mid,3) == -1.0 )  THEN
109          mask_loop(mid,1,1:2) = -1.0
110          mask_loop(mid,1,3) = 0.0
111       ELSE
112          mask_loop(mid,1,:) = mask_x_loop(mid,:)
113       ENDIF
114       IF ( mask_y_loop(mid,1) == -1.0  .AND.  mask_y_loop(mid,2) == -1.0  &
115            .AND.  mask_y_loop(mid,3) == -1.0 )  THEN
116          mask_loop(mid,2,1:2) = -1.0
117          mask_loop(mid,2,3) = 0.0
118       ELSE
119          mask_loop(mid,2,:) = mask_y_loop(mid,:)
120       ENDIF
121       IF ( mask_z_loop(mid,1) == -1.0  .AND.  mask_z_loop(mid,2) == -1.0  &
122            .AND.  mask_z_loop(mid,3) == -1.0 )  THEN
123          mask_loop(mid,3,1:2) = -1.0
124          mask_loop(mid,3,3) = 0.0
125       ELSE
126          mask_loop(mid,3,:) = mask_z_loop(mid,:)
127       ENDIF
128       
129    ENDDO
130   
131    mask_i = -1; mask_j = -1; mask_k = -1
132   
133!
134!-- Global arrays are required by define_netcdf_header.
135    IF ( myid == 0  .OR.  netcdf_data_format > 4 )  THEN
136       ALLOCATE( mask_i_global(max_masks,nx+1), &
137                 mask_j_global(max_masks,ny+1), &
138                 mask_k_global(max_masks,nz+1) )
139       mask_i_global = -1; mask_j_global = -1; mask_k_global = -1
140    ENDIF
141
142!
143!-- Determine variable names for each mask
144    DO  mid = 1, masks
145!
146!--    Append user-defined data output variables to the standard data output
147       IF ( do_mask_user(mid,1) /= ' ' )  THEN
148          i = 1
149          DO  WHILE ( do_mask(mid,i) /= ' '  .AND.  i <= 100 )
150             i = i + 1
151          ENDDO
152          j = 1
153          DO  WHILE ( do_mask_user(mid,j) /= ' '  .AND.  j <= 100 )
154             IF ( i > 100 )  THEN
155                WRITE ( message_string, * ) 'number of output quantitities ', &
156                     'given by data_output_mask and data_output_mask_user ', &
157                     'exceeds the limit of 100'
158                CALL message( 'init_masks', 'PA0329', 1, 2, 0, 6, 0 )
159             ENDIF
160             do_mask(mid,i) = do_mask_user(mid,j)
161             i = i + 1
162             j = j + 1
163          ENDDO
164       ENDIF
165
166!
167!--    Check and set steering parameters for mask data output and averaging
168       i   = 1
169       DO WHILE ( do_mask(mid,i) /= ' '  .AND.  i <= 100 )
170!
171!--       Check for data averaging
172          ilen = LEN_TRIM( do_mask(mid,i) )
173          j = 0                                              ! no data averaging
174          IF ( ilen > 3 )  THEN
175             IF ( do_mask(mid,i)(ilen-2:ilen) == '_av' )  THEN
176                j = 1                                           ! data averaging
177                do_mask(mid,i) = do_mask(mid,i)(1:ilen-3)
178             ENDIF
179          ENDIF
180          var = TRIM( do_mask(mid,i) )
181!
182!--       Check for allowed value and set units
183          SELECT CASE ( TRIM( var ) )
184
185             CASE ( 'e' )
186                IF ( constant_diffusion )  THEN
187                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
188                        '" requires constant_diffusion = .FALSE.'
189                   CALL message( 'init_masks', 'PA0103', 1, 2, 0, 6, 0 )
190                ENDIF
191                unit = 'm2/s2'
192
193             CASE ( 'lpt' )
194                IF ( .NOT. cloud_physics )  THEN
195                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
196                        '" requires cloud_physics = .TRUE.'
197                   CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 )
198                ENDIF
199                unit = 'K'
200
201             CASE ( 'pc', 'pr' )
202                IF ( .NOT. particle_advection )  THEN
203                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
204                        '" requires a "particles_par"-NAMELIST in the ', &
205                        'parameter file (PARIN)'
206                   CALL message( 'init_masks', 'PA0104', 1, 2, 0, 6, 0 )
207                ENDIF
208                IF ( TRIM( var ) == 'pc' )  unit = 'number'
209                IF ( TRIM( var ) == 'pr' )  unit = 'm'
210
211             CASE ( 'q', 'vpt' )
212                IF ( .NOT. humidity )  THEN
213                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
214                        '" requires humidity = .TRUE.'
215                   CALL message( 'init_masks', 'PA0105', 1, 2, 0, 6, 0 )
216                ENDIF
217                IF ( TRIM( var ) == 'q'   )  unit = 'kg/kg'
218                IF ( TRIM( var ) == 'vpt' )  unit = 'K'
219
220             CASE ( 'ql' )
221                IF ( .NOT. ( cloud_physics  .OR.  cloud_droplets ) )  THEN
222                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
223                        '" requires cloud_physics = .TRUE. or cloud_droplets', &
224                        ' = .TRUE.'
225                   CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 )
226                ENDIF
227                unit = 'kg/kg'
228
229             CASE ( 'ql_c', 'ql_v', 'ql_vp' )
230                IF ( .NOT. cloud_droplets )  THEN
231                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
232                        '" requires cloud_droplets = .TRUE.'
233                   CALL message( 'init_masks', 'PA0107', 1, 2, 0, 6, 0 )
234                ENDIF
235                IF ( TRIM( var ) == 'ql_c'  )  unit = 'kg/kg'
236                IF ( TRIM( var ) == 'ql_v'  )  unit = 'm3'
237                IF ( TRIM( var ) == 'ql_vp' )  unit = 'none'
238
239             CASE ( 'qv' )
240                IF ( .NOT. cloud_physics )  THEN
241                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
242                        '" requires cloud_physics = .TRUE.'
243                   CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 )
244                ENDIF
245                unit = 'kg/kg'
246
247             CASE ( 'rho' )
248                IF ( .NOT. ocean )  THEN
249                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
250                        '" requires ocean = .TRUE.'
251                   CALL message( 'init_masks', 'PA0109', 1, 2, 0, 6, 0 )
252                ENDIF
253                unit = 'kg/m3'
254
255             CASE ( 's' )
256                IF ( .NOT. passive_scalar )  THEN
257                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
258                        '" requires passive_scalar = .TRUE.'
259                   CALL message( 'init_masks', 'PA0110', 1, 2, 0, 6, 0 )
260                ENDIF
261                unit = 'conc'
262
263             CASE ( 'sa' )
264                IF ( .NOT. ocean )  THEN
265                   WRITE ( message_string, * ) 'output of "', TRIM( var ), &
266                        '" requires ocean = .TRUE.'
267                   CALL message( 'init_masks', 'PA0109', 1, 2, 0, 6, 0 )
268                ENDIF
269                unit = 'psu'
270
271             CASE ( 'u*', 't*', 'lwp*', 'pra*', 'prr*', 'z0*', 'z0h*' )
272                WRITE ( message_string, * ) 'illegal value for data_',&
273                     'output: "', TRIM( var ), '" is only allowed', &
274                     'for horizontal cross section'
275                CALL message( 'init_masks', 'PA0111', 1, 2, 0, 6, 0 )
276
277             CASE ( 'p', 'pt', 'u', 'v', 'w' )
278                IF ( TRIM( var ) == 'p'  )  unit = 'Pa'
279                IF ( TRIM( var ) == 'pt' )  unit = 'K'
280                IF ( TRIM( var ) == 'u'  )  unit = 'm/s'
281                IF ( TRIM( var ) == 'v'  )  unit = 'm/s'
282                IF ( TRIM( var ) == 'w'  )  unit = 'm/s'
283                CONTINUE
284
285             CASE DEFAULT
286                CALL user_check_data_output( var, unit )
287
288                IF ( unit == 'illegal' )  THEN
289                   IF ( do_mask_user(mid,1) /= ' ' )  THEN
290                      WRITE ( message_string, * ) 'illegal value for data_',&
291                           'output or data_output_user: "', &
292                           TRIM( do_mask(mid,i) ), '"'
293                      CALL message( 'init_masks', 'PA0114', 1, 2, 0, 6, 0 )
294                   ELSE
295                      WRITE ( message_string, * ) 'illegal value for data_',&
296                           'output: "', TRIM( do_mask(mid,i) ), '"'
297                      CALL message( 'init_masks', 'PA0330', 1, 2, 0, 6, 0 )
298                   ENDIF
299                ENDIF
300
301          END SELECT
302!
303!--       Set the internal steering parameters appropriately
304          domask_no(mid,j)                    = domask_no(mid,j) + 1
305          domask(mid,j,domask_no(mid,j))      = do_mask(mid,i)
306          domask_unit(mid,j,domask_no(mid,j)) = unit
307
308          IF ( j == 1 )  THEN
309!
310!--          Check, if variable is already subject to averaging
311             found = .FALSE.
312             DO  k = 1, doav_n
313                IF ( TRIM( doav(k) ) == TRIM( var ) )  found = .TRUE.
314             ENDDO
315
316             IF ( .NOT. found )  THEN
317                doav_n = doav_n + 1
318                doav(doav_n) = var
319             ENDIF
320          ENDIF
321
322          i = i + 1
323
324       ENDDO   ! do_mask(mid,i)
325    ENDDO   ! mid
326
327
328!
329!-- Determine mask locations for each mask
330    DO  mid = 1, masks
331!
332!--    Set local masks for each subdomain along all three dimensions
333       CALL set_mask_locations( 1, dx, 'dx', nx, 'nx', nxl, nxr )
334       CALL set_mask_locations( 2, dy, 'dy', ny, 'ny', nys, nyn )
335       CALL set_mask_locations( 3, dz, 'dz', nz, 'nz', nzb, nzt )
336!
337!--    Set global masks along all three dimensions (required by
338!--    define_netcdf_header).
339#if defined( __parallel ) && ! defined ( __check )
340!
341!--    PE0 receives partial arrays from all processors of the respective mask
342!--    and outputs them. Here a barrier has to be set, because otherwise
343!--    "-MPI- FATAL: Remote protocol queue full" may occur.
344
345       CALL MPI_BARRIER( comm2d, ierr )
346
347       IF ( myid == 0 )  THEN
348!
349!--       Local arrays can be relocated directly.
350          mask_i_global(mid,mask_start_l(mid,1): &
351                       mask_start_l(mid,1)+mask_size_l(mid,1)-1) = &
352                       mask_i(mid,:mask_size_l(mid,1))
353          mask_j_global(mid,mask_start_l(mid,2): &
354                       mask_start_l(mid,2)+mask_size_l(mid,2)-1) = &
355                       mask_j(mid,:mask_size_l(mid,2))
356          mask_k_global(mid,mask_start_l(mid,3): &
357                       mask_start_l(mid,3)+mask_size_l(mid,3)-1) = &
358                       mask_k(mid,:mask_size_l(mid,3))
359!
360!--       Receive data from all other PEs.
361          DO  n = 1, numprocs-1
362!
363!--          Receive index limits first, then arrays.
364!--          Index limits are received in arbitrary order from the PEs.
365             CALL MPI_RECV( ind(1), 6, MPI_INTEGER, MPI_ANY_SOURCE, 0,  &
366                  comm2d, status, ierr )
367!
368!--          Not all PEs have data for the mask.
369             IF ( ind(1) /= -9999 )  THEN
370                sender = status(MPI_SOURCE)
371                CALL MPI_RECV( tmp_array(ind(1)), ind(2)-ind(1)+1,  &
372                               MPI_INTEGER, sender, 1, comm2d, status, ierr )
373                mask_i_global(mid,ind(1):ind(2)) = tmp_array(ind(1):ind(2))
374                CALL MPI_RECV( tmp_array(ind(3)), ind(4)-ind(3)+1,  &
375                               MPI_INTEGER, sender, 2, comm2d, status, ierr )
376                mask_j_global(mid,ind(3):ind(4)) = tmp_array(ind(3):ind(4))
377                CALL MPI_RECV( tmp_array(ind(5)), ind(6)-ind(5)+1,  &
378                               MPI_INTEGER, sender, 3, comm2d, status, ierr )
379                mask_k_global(mid,ind(5):ind(6)) = tmp_array(ind(5):ind(6))
380             ENDIF
381          ENDDO
382
383       ELSE
384!
385!--       If at least part of the mask resides on the PE, send the index limits
386!--       for the target array, otherwise send -9999 to PE0.
387          IF ( mask_size_l(mid,1) > 0  .AND.  mask_size_l(mid,2) > 0  .AND.  &
388               mask_size_l(mid,3) > 0  )  THEN
389             ind(1) = mask_start_l(mid,1)
390             ind(2) = mask_start_l(mid,1) + mask_size_l(mid,1) - 1
391             ind(3) = mask_start_l(mid,2)
392             ind(4) = mask_start_l(mid,2) + mask_size_l(mid,2) - 1
393             ind(5) = mask_start_l(mid,3)
394             ind(6) = mask_start_l(mid,3) + mask_size_l(mid,3) - 1
395          ELSE
396             ind(1) = -9999; ind(2) = -9999
397             ind(3) = -9999; ind(4) = -9999
398             ind(5) = -9999; ind(6) = -9999
399          ENDIF
400          CALL MPI_SEND( ind(1), 6, MPI_INTEGER, 0, 0, comm2d, ierr )
401!
402!--       If applicable, send data to PE0.
403          IF ( ind(1) /= -9999 )  THEN
404             tmp_array(:mask_size_l(mid,1)) = mask_i(mid,:mask_size_l(mid,1))
405             CALL MPI_SEND( tmp_array(1), mask_size_l(mid,1),  &
406                            MPI_INTEGER, 0, 1, comm2d, ierr )
407             tmp_array(:mask_size_l(mid,2)) = mask_j(mid,:mask_size_l(mid,2))
408             CALL MPI_SEND( tmp_array(1), mask_size_l(mid,2),  &
409                            MPI_INTEGER, 0, 2, comm2d, ierr )
410             tmp_array(:mask_size_l(mid,3)) = mask_k(mid,:mask_size_l(mid,3))
411             CALL MPI_SEND( tmp_array(1), mask_size_l(mid,3),  &
412                            MPI_INTEGER, 0, 3, comm2d, ierr )
413          ENDIF
414       ENDIF
415!
416!--    A barrier has to be set, because otherwise some PEs may proceed too fast
417!--    so that PE0 may receive wrong data on tag 0.
418       CALL MPI_BARRIER( comm2d, ierr )
419       
420       IF ( netcdf_data_format > 4 )  THEN
421         
422          CALL MPI_BCAST( mask_i_global(mid,:), nx+1, MPI_INTEGER, 0, comm2d, &
423                          ierr )
424          CALL MPI_BCAST( mask_j_global(mid,:), ny+1, MPI_INTEGER, 0, comm2d, &
425                          ierr )
426          CALL MPI_BCAST( mask_k_global(mid,:), nz+1, MPI_INTEGER, 0, comm2d, &
427                          ierr ) 
428         
429       ENDIF
430
431#elif ! defined ( __parallel )
432!
433!--    Local arrays can be relocated directly.
434       mask_i_global(mid,:) = mask_i(mid,:)
435       mask_j_global(mid,:) = mask_j(mid,:)
436       mask_k_global(mid,:) = mask_k(mid,:)
437#endif
438    ENDDO   ! mid
439
440    DEALLOCATE( tmp_array )
441!
442!-- Internal mask arrays cannot be deallocated on PE 0 because they are
443!-- required for header output on PE 0.
444    IF ( myid /= 0 )  DEALLOCATE( mask, mask_loop )
445
446 CONTAINS
447
448    SUBROUTINE set_mask_locations( dim, dxyz, dxyz_string, nxyz, nxyz_string, &
449                                   lb, ub )
450!------------------------------------------------------------------------------!
451!
452! Description:
453! ------------
454! Set local mask for each subdomain along 'dim' direction.
455!------------------------------------------------------------------------------!
456
457       IMPLICIT NONE
458
459       CHARACTER (LEN=2) :: dxyz_string, nxyz_string
460       INTEGER  ::  count, count_l, dim, m, loop_begin, loop_end, loop_stride, &
461                    lb, nxyz, ub
462       REAL     ::  dxyz, ddxyz, tmp1, tmp2
463
464       count = 0;  count_l = 0;  ddxyz = 1.0 / dxyz;  tmp1 = 0.0;  tmp2 = 0.0
465
466       IF ( mask(mid,dim,1) >= 0.0 )  THEN
467!
468!--       use predefined mask_* array
469          DO  WHILE ( mask(mid,dim,count+1) >= 0.0 )
470             count = count + 1
471             IF ( dim == 1 .OR. dim == 2 )  THEN
472                m = NINT( mask(mid,dim,count) * mask_scale(dim) * ddxyz - 0.5 )
473             ELSEIF ( dim == 3 )  THEN
474                ind_array =  &
475                     MINLOC( ABS( mask(mid,dim,count) * mask_scale(dim) - zu ) )
476                m = ind_array(1) - 1 + nzb  ! MINLOC uses lower array bound 1
477             ENDIF
478             IF ( m > nxyz )  THEN
479                WRITE ( message_string, '(I3,A,I3,A,I1,3A,I3)' )  &
480                     m,' in mask ',mid,' along dimension ',dim,  &
481                     ' exceeds ',nxyz_string,' = ',nxyz
482                CALL message( 'init_masks', 'PA0331', 1, 2, 0, 6, 0 )
483             ENDIF
484             IF ( m >= lb .AND. m <= ub )  THEN
485                IF ( count_l == 0 )  mask_start_l(mid,dim) = count
486                count_l = count_l + 1
487                IF ( dim == 1 )  THEN
488                   mask_i(mid,count_l) = m
489                ELSEIF ( dim == 2 )  THEN
490                   mask_j(mid,count_l) = m
491                ELSEIF ( dim == 3 )  THEN
492                   mask_k(mid,count_l) = m
493                ENDIF
494             ENDIF
495             IF ( count == mask_xyz_dimension )  EXIT
496          ENDDO
497          mask_size(mid,dim)   = count
498          mask_size_l(mid,dim) = count_l
499
500       ELSE
501!
502!--       use predefined mask_loop_* array, or use the default (all grid points
503!--       along this direction)
504          IF ( mask_loop(mid,dim,1) < 0.0 )  THEN
505             tmp1 = mask_loop(mid,dim,1)
506             mask_loop(mid,dim,1) = 0.0   ! (default)
507          ENDIF
508          IF ( dim == 1 .OR. dim == 2 )  THEN
509             IF ( mask_loop(mid,dim,2) < 0.0 )  THEN
510                tmp2 = mask_loop(mid,dim,2)
511                mask_loop(mid,dim,2) = nxyz*dxyz / mask_scale(dim)   ! (default)
512             ENDIF
513             IF ( MAXVAL( mask_loop(mid,dim,1:2) )  &
514                  > nxyz * dxyz / mask_scale(dim) )  THEN
515                WRITE ( message_string, '(2(A,I3,A,I1,A,F9.3),5A,I1,A,F9.3)' ) &
516                     'mask_loop(',mid,',',dim,',1)=',mask_loop(mid,dim,1), &
517                     ' and/or mask_loop(',mid,',',dim,',2)=', &
518                     mask_loop(mid,dim,2),'&exceed ', &
519                     nxyz_string,'*',dxyz_string,'/mask_scale(',dim,')=', &
520                     nxyz*dxyz/mask_scale(dim)
521                CALL message( 'init_masks', 'PA0332', 1, 2, 0, 6, 0 )
522             ENDIF
523             loop_begin  = NINT( mask_loop(mid,dim,1) * mask_scale(dim) &
524                  * ddxyz - 0.5 )
525             loop_end    = NINT( mask_loop(mid,dim,2) * mask_scale(dim) &
526                  * ddxyz - 0.5 )
527             loop_stride = NINT( mask_loop(mid,dim,3) * mask_scale(dim) &
528                  * ddxyz )
529          ELSEIF ( dim == 3 )  THEN
530             IF ( mask_loop(mid,dim,2) < 0.0 )  THEN
531                tmp2 = mask_loop(mid,dim,2)
532                mask_loop(mid,dim,2) = zu(nz) / mask_scale(dim)   ! (default)
533             ENDIF
534             IF ( MAXVAL( mask_loop(mid,dim,1:2) )  &
535                  > zu(nz) / mask_scale(dim) )  THEN
536                WRITE ( message_string, '(2(A,I3,A,I1,A,F9.3),A,I1,A,F9.3)' ) &
537                     'mask_loop(',mid,',',dim,',1)=',mask_loop(mid,dim,1), &
538                     ' and/or mask_loop(',mid,',',dim,',2)=', &
539                     mask_loop(mid,dim,2),'&exceed zu(nz)/mask_scale(',dim, &
540                     ')=',zu(nz)/mask_scale(dim)
541                CALL message( 'init_masks', 'PA0333', 1, 2, 0, 6, 0 )
542             ENDIF
543             ind_array =  &
544                  MINLOC( ABS( mask_loop(mid,dim,1) * mask_scale(dim) - zu ) )
545             loop_begin =  &
546                  ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1
547             ind_array =  &
548                  MINLOC( ABS( mask_loop(mid,dim,2) * mask_scale(dim) - zu ) )
549             loop_end = ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1
550!
551!--          The following line assumes a constant vertical grid spacing within
552!--          the vertical mask range; it fails for vertical grid stretching.
553!--          Maybe revise later. Issue warning but continue execution.
554             loop_stride = NINT( mask_loop(mid,dim,3) * mask_scale(dim) * ddxyz )
555
556             IF ( mask_loop(mid,dim,2) * mask_scale(dim) > dz_stretch_level )  &
557                  THEN
558                WRITE ( message_string, '(A,I3,A,I1,A,F9.3,A,F8.2,3A)' ) &
559                     'mask_loop(',mid,',',dim,',2)=', mask_loop(mid,dim,2),&
560                     ' exceeds dz_stretch_level=',dz_stretch_level, &
561                     '.&Vertical mask locations will not ', &
562                     'match the desired heights&within the stretching ', &
563                     'region. Recommendation: use mask instead of mask_loop.'
564                CALL message( 'init_masks', 'PA0334', 0, 1, 0, 6, 0 )
565             ENDIF
566
567          ENDIF
568!
569!--       If necessary, reset mask_loop(mid,dim,1) and mask_loop(mid,dim,2).
570          IF ( tmp1 < 0.0 )  mask_loop(mid,dim,1) = tmp1
571          IF ( tmp2 < 0.0 )  mask_loop(mid,dim,2) = tmp2
572!
573!--       The default stride +/-1 (every grid point) applies if
574!--       mask_loop(mid,dim,3) is not specified (its default is zero).
575          IF ( loop_stride == 0 )  THEN
576             IF ( loop_end >= loop_begin )  THEN
577                loop_stride =  1
578             ELSE
579                loop_stride = -1
580             ENDIF
581          ENDIF
582          DO  m = loop_begin, loop_end, loop_stride
583             count = count + 1
584             IF ( m >= lb  .AND.  m <= ub )  THEN
585                IF ( count_l == 0 )  mask_start_l(mid,dim) = count
586                count_l = count_l + 1
587                IF ( dim == 1 )  THEN
588                   mask_i(mid,count_l) = m
589                ELSEIF ( dim == 2 )  THEN
590                   mask_j(mid,count_l) = m
591                ELSEIF ( dim == 3 )  THEN
592                   mask_k(mid,count_l) = m
593                ENDIF
594             ENDIF
595          ENDDO
596          mask_size(mid,dim)   = count
597          mask_size_l(mid,dim) = count_l
598       ENDIF
599
600    END SUBROUTINE set_mask_locations
601
602 END SUBROUTINE init_masks
Note: See TracBrowser for help on using the repository browser.