source: palm/trunk/SOURCE/init_grid.f90 @ 2544

!> @file init_grid.f90
!------------------------------------------------------------------------------!
! This file is part of PALM.
!
! PALM is free software: you can redistribute it and/or modify it under the
! terms of the GNU General Public License as published by the Free Software
! Foundation, either version 3 of the License, or (at your option) any later
! version.
!
! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
!
! You should have received a copy of the GNU General Public License along with
! PALM. If not, see <http://www.gnu.org/licenses/>.
!
! Copyright 1997-2017 Leibniz Universitaet Hannover
!------------------------------------------------------------------------------!
!
! Current revisions:
! -----------------
! 
! 
! Former revisions:
! -----------------
! $Id: init_grid.f90 2478 2017-09-18 13:37:24Z maronga $
! Bugfix, correct flag for use_top
! 
! 2365 2017-08-21 14:59:59Z kanani
! Vertical nesting implemented (SadiqHuq)
! 
! 2319 2017-07-20 17:33:17Z suehring
! Remove print statements
! 
! 2318 2017-07-20 17:27:44Z suehring
! Get topography top index via Function call 
! 
! 2317 2017-07-20 17:27:19Z suehring
! Bugfixes in reading 3D topography from file
! 
! 2274 2017-06-09 13:27:48Z Giersch
! Changed error messages
! 
! 2233 2017-05-30 18:08:54Z suehring
!
! 2232 2017-05-30 17:47:52Z suehring
! - Adjustments according to new topography representation
! - Bugfix: Move determination of nzb_max behind topography modification in 
!   cell-edge case 
! - Get rid off global arrays required for topography output
! - Enable topography input via netcdf 
! - Generic tunnel set-up added
! 
! 2200 2017-04-11 11:37:51Z suehring
! monotonic_adjustment removed
! 
! 2169 2017-03-06 18:16:35Z suehring
! Bugfix, move setting for topography grid convention to init_grid, else, if no
! value is set, the simulation may abort in case of restarts
! 
! 2128 2017-01-23 15:00:03Z suehring
! Bugfix in setting topography from file in case of ocean simulations
! 
! 2088 2016-12-19 16:30:25Z suehring
! Bugfix in generic topography in case of ocean simulations
! 
! 2037 2016-10-26 11:15:40Z knoop
! Anelastic approximation implemented
! 
! 2021 2016-10-07 14:08:57Z suehring
! Bugfix: setting Neumann boundary conditions for topography required for 
! topography flags in multigrid_noopt solver
! 
! 2000 2016-08-20 18:09:15Z knoop
! Forced header and separation lines into 80 columns
! 
! 1994 2016-08-15 09:52:21Z suehring
! Bugfix in definition of generic topography
! 
! 1982 2016-08-01 11:04:48Z suehring
! Bugfix concering consistency check for topography
! 
! 1968 2016-07-18 12:01:49Z suehring
! Changed: PE-wise reading of topography file in order to avoid global definition
! of arrays nzb_local and nzb_tmp. Thereby, topography definition for single
! buildings and street canyons has changed, as well as flag setting for 
! multigrid scheme.
!
! Bugfix in checking l_grid anisotropy. 
! Simplify initial computation of lwall and vertical_influence, i.e. remove 
! nzb_s_inner as it is still zero at this point.
! 
! 1942 2016-06-14 12:18:18Z suehring
! Topography filter implemented to fill holes resolved by only one grid point.
! Initialization of flags for ws-scheme moved to advec_ws.  
! 
! 1931 2016-06-10 12:06:59Z suehring
! Rename multigrid into multigrid_noopt and multigrid_fast into multigrid
!
! 1910 2016-05-26 06:49:46Z raasch
! Bugfix: if topography is read from file, Neumann conditions are used for the
! nzb_local array (instead of cyclic conditions) in case that non-cyclic
! boundary conditions are switched on for the run
!
! 1902 2016-05-09 11:18:56Z suehring
! Set topography flags for multigrid solver only (not for multigrid_fast)
!
! 1886 2016-04-21 11:20:47Z suehring
! Bugfix: setting advection flags near walls
! reformulated index values for nzb_v_inner
! variable discriptions added in declaration block
!
! 1845 2016-04-08 08:29:13Z raasch
! nzb_2d removed
! 
! 1804 2016-04-05 16:30:18Z maronga
! Removed code for parameter file check (__check)
!
! 1779 2016-03-03 08:01:28Z raasch
! coupling_char is trimmed at every place it occurs, because it can have
! different length now
!
! 1762 2016-02-25 12:31:13Z hellstea
! Introduction of nested domain feature
!
! 1743 2016-01-13 10:23:51Z raasch
! Bugfix for calculation of nzb_s_outer and nzb_u_outer at north boundary of
! total domain
!
! 1691 2015-10-26 16:17:44Z maronga
! Renamed prandtl_layer to constant_flux_layer.
! 
! 1682 2015-10-07 23:56:08Z knoop
! Code annotations made doxygen readable 
! 
! 1677 2015-10-02 13:25:23Z boeske
! Bugfix: Ghost points are included in wall_flags_0 and wall_flags_00
! 
! 1675 2015-10-02 08:28:59Z gronemeier
! Bugfix: Definition of topography grid levels
! 
! 1660 2015-09-21 08:15:16Z gronemeier
! Bugfix: Definition of topography grid levels if vertical grid stretching
!         starts below the maximum topography height.
!
! 1580 2015-04-10 13:43:49Z suehring
! Bugfix: setting flags for 5th order scheme near buildings
!
! 1575 2015-03-27 09:56:27Z raasch
! adjustments for psolver-queries
!
! 1557 2015-03-05 16:43:04Z suehring
! Adjustment for monotoinic limiter
!
! 1418 2014-06-06 13:05:08Z fricke
! Bugfix: Change if-condition for stretched grid in the ocean, with the old
!          condition and a negative value for dz_stretch_level the condition
!          was always true for the whole model domain
!
! 1409 2014-05-23 12:11:32Z suehring
! Bugfix: set wall_flags_0 at inflow and outflow boundary also for i <= nxlu 
! j <= nysv
! 
! 1353 2014-04-08 15:21:23Z heinze
! REAL constants provided with KIND-attribute 
!
! 1322 2014-03-20 16:38:49Z raasch
! REAL constants defined as wp-kind
!
! 1320 2014-03-20 08:40:49Z raasch
! ONLY-attribute added to USE-statements,
! kind-parameters added to all INTEGER and REAL declaration statements, 
! kinds are defined in new module kinds, 
! revision history before 2012 removed,
! comment fields (!:) to be used for variable explanations added to
! all variable declaration statements 
! 
! 1221 2013-09-10 08:59:13Z raasch
! wall_flags_00 introduced to hold bits 32-63,
! additional 3D-flag arrays for replacing the 2D-index array nzb_s_inner in
! loops optimized for openACC (pres + flow_statistics)
!
! 1092 2013-02-02 11:24:22Z raasch
! unused variables removed
!
! 1069 2012-11-28 16:18:43Z maronga
! bugfix: added coupling_char to TOPOGRAPHY_DATA to allow topography in the
!         ocean model in case of coupled runs
!
! 1036 2012-10-22 13:43:42Z raasch
! code put under GPL (PALM 3.9)
!
! 1015 2012-09-27 09:23:24Z raasch
! lower index for calculating wall_flags_0 set to nzb_w_inner instead of
! nzb_w_inner+1
!
! 996 2012-09-07 10:41:47Z raasch
! little reformatting
!
! 978 2012-08-09 08:28:32Z fricke
! Bugfix: nzb_max is set to nzt at non-cyclic lateral boundaries
! Bugfix: Set wall_flags_0 for inflow boundary
!
! 927 2012-06-06 19:15:04Z raasch
! Wall flags are not set for multigrid method in case of masking method
!
! 864 2012-03-27 15:10:33Z gryschka 
! In case of ocean and Dirichlet bottom bc for u and v dzu_mg and ddzu_pres
! were not correctly defined for k=1.
!
! 861 2012-03-26 14:18:34Z suehring
! Set wall_flags_0. The array is needed for degradation in ws-scheme near walls,
! inflow and outflow boundaries as well as near the bottom and the top of the
! model domain.!
! Initialization of nzb_s_inner and nzb_w_inner.
! gls has to be at least nbgp to do not exceed the array bounds of nzb_local
! while setting wall_flags_0
!
! 843 2012-02-29 15:16:21Z gryschka
! In case of ocean and dirichlet bc for u and v at the bottom
! the first u-level ist defined at same height as the first w-level
!
! 818 2012-02-08 16:11:23Z maronga
! Bugfix: topo_height is only required if topography is used. It is thus now
! allocated in the topography branch
!
! 809 2012-01-30 13:32:58Z maronga
! Bugfix: replaced .AND. and .NOT. with && and ! in the preprocessor directives
!
! 807 2012-01-25 11:53:51Z maronga
! New cpp directive "__check" implemented which is used by check_namelist_files
!
! Revision 1.1  1997/08/11 06:17:45  raasch
! Initial revision (Testversion)
!
!
! Description:
! ------------
!> Creating grid depending constants
!> To Do: Setting topo flags only based on topo_3d array - flags for former
!> nzb_outer arrays are still not set properly. 
!> To Do: Rearrange topo flag list
!------------------------------------------------------------------------------!
 SUBROUTINE init_grid
 
    USE advec_ws,                                                              &
        ONLY:  ws_init_flags

    USE arrays_3d,                                                             &
        ONLY:  dd2zu, ddzu, ddzu_pres, ddzw, dzu, dzu_mg, dzw, dzw_mg, f1_mg,  &
               f2_mg, f3_mg, l_grid, l_wall, zu, zw
        
    USE control_parameters,                                                    &
        ONLY:  bc_lr_cyc, bc_ns_cyc, building_height, building_length_x,       &
               building_length_y, building_wall_left, building_wall_south,     &
               canyon_height, canyon_wall_left, canyon_wall_south,             &
               canyon_width_x, canyon_width_y, constant_flux_layer,            &
               coupling_char, coupling_mode,                                   &
               dp_level_ind_b, dz, dz_max, dz_stretch_factor,                  &
               dz_stretch_level, dz_stretch_level_index, grid_level, ibc_uv_b, &
               io_blocks, io_group, inflow_l, inflow_n, inflow_r, inflow_s,    &
               lod, masking_method, maximum_grid_level, message_string,        &
               momentum_advec, nest_domain, nest_bound_l, nest_bound_n,        &
               nest_bound_r, nest_bound_s, ocean, outflow_l, outflow_n,        &
               outflow_r, outflow_s, psolver, scalar_advec, topography,        &
               topography_grid_convention, tunnel_height, tunnel_length,       &
               tunnel_width_x, tunnel_width_y, tunnel_wall_depth,              &
               use_surface_fluxes, use_top_fluxes, wall_adjustment_factor
         
    USE grid_variables,                                                        &
        ONLY:  ddx, ddx2, ddy, ddy2, dx, dx2, dy, dy2, zu_s_inner, zw_w_inner
        
    USE indices,                                                               &
        ONLY:  advc_flags_1, advc_flags_2, flags, nbgp, nx, nxl, nxlg, nxl_mg, &
               nxr, nxrg, nxr_mg, ny, nyn, nyng, nyn_mg, nys, nys_mg, nysg, nz,&
               nzb, nzb_diff, nzb_diff_s_inner, nzb_diff_s_outer,              &
               nzb_max, nzb_s_inner, nzb_s_outer, nzb_u_inner,                 &
               nzb_u_outer, nzb_v_inner, nzb_v_outer, nzb_w_inner,             &
               nzb_w_outer, nzt, nzt_mg, wall_flags_0, wall_flags_1,           &
               wall_flags_10, wall_flags_2, wall_flags_3,  wall_flags_4,       &
               wall_flags_5, wall_flags_6, wall_flags_7, wall_flags_8,         &
               wall_flags_9
    
    USE kinds
#if defined ( __netcdf )
    USE netcdf_interface,                                                      &
        ONLY:  netcdf_close_file, netcdf_open_read_file, netcdf_get_attribute, &
               netcdf_get_variable
#endif
    USE pegrid

    USE surface_mod,                                                           &
        ONLY:  get_topography_top_index, init_bc

    USE vertical_nesting_mod,                                                  &
        ONLY:  vnested, vnest_init_grid

    IMPLICIT NONE

    INTEGER(iwp) ::  bh            !< temporary vertical index of building height
    INTEGER(iwp) ::  blx           !< grid point number of building size along x
    INTEGER(iwp) ::  bly           !< grid point number of building size along y
    INTEGER(iwp) ::  bxl           !< index for left building wall
    INTEGER(iwp) ::  bxr           !< index for right building wall
    INTEGER(iwp) ::  byn           !< index for north building wall
    INTEGER(iwp) ::  bys           !< index for south building wall
    INTEGER(iwp) ::  ch            !< temporary vertical index for canyon height
    INTEGER(iwp) ::  cwx           !< grid point number of canyon size along x
    INTEGER(iwp) ::  cwy           !< grid point number of canyon size along y
    INTEGER(iwp) ::  cxl           !< index for left canyon wall
    INTEGER(iwp) ::  cxr           !< index for right canyon wall
    INTEGER(iwp) ::  cyn           !< index for north canyon wall
    INTEGER(iwp) ::  cys           !< index for south canyon wall
    INTEGER(iwp) ::  i             !< index variable along x
    INTEGER(iwp) ::  id_topo       !< NetCDF id of topograhy input file
    INTEGER(iwp) ::  ii            !< loop variable for reading topography file
    INTEGER(iwp) ::  inc           !< incremental parameter for coarsening grid level
    INTEGER(iwp) ::  j             !< index variable along y
    INTEGER(iwp) ::  k             !< index variable along z
    INTEGER(iwp) ::  k_top         !< topography top index on local PE
    INTEGER(iwp) ::  l             !< loop variable 
    INTEGER(iwp) ::  nxl_l         !< index of left PE boundary for multigrid level
    INTEGER(iwp) ::  nxr_l         !< index of right PE boundary for multigrid level
    INTEGER(iwp) ::  nyn_l         !< index of north PE boundary for multigrid level
    INTEGER(iwp) ::  nys_l         !< index of south PE boundary for multigrid level
    INTEGER(iwp) ::  nzb_local_max !< vertical grid index of maximum topography height
    INTEGER(iwp) ::  nzb_local_min !< vertical grid index of minimum topography height
    INTEGER(iwp) ::  nzt_l         !< index of top PE boundary for multigrid level
    INTEGER(iwp) ::  num_hole      !< number of holes (in topography) resolved by only one grid point 
    INTEGER(iwp) ::  num_hole_l    !< number of holes (in topography) resolved by only one grid point on local PE     
    INTEGER(iwp) ::  num_wall      !< number of surrounding vertical walls for a single grid point
    INTEGER(iwp) ::  skip_n_rows   !< counting variable to skip rows while reading topography file    
    INTEGER(iwp) ::  hv_in         !< heavyside function to model inner tunnel surface 
    INTEGER(iwp) ::  hv_out        !< heavyside function to model outer tunnel surface 
    INTEGER(iwp) ::  txe_out       !< end position of outer tunnel wall in x
    INTEGER(iwp) ::  txs_out       !< start position of outer tunnel wall in x
    INTEGER(iwp) ::  tye_out       !< end position of outer tunnel wall in y
    INTEGER(iwp) ::  tys_out       !< start position of outer tunnel wall in y
    INTEGER(iwp) ::  txe_in        !< end position of inner tunnel wall in x
    INTEGER(iwp) ::  txs_in        !< start position of inner tunnel wall in x
    INTEGER(iwp) ::  tye_in        !< end position of inner tunnel wall in y
    INTEGER(iwp) ::  tys_in        !< start position of inner tunnel wall in y
    INTEGER(iwp) ::  td            !< tunnel wall depth
    INTEGER(iwp) ::  th            !< height of outer tunnel wall
                                      
    INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE ::  nzb_local      !< index for topography top at cell-center
    INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE ::  nzb_tmp        !< dummy to calculate topography indices on u- and v-grid

    INTEGER(iwp), DIMENSION(:,:,:), ALLOCATABLE ::  topo_3d !< input array for 3D topography and dummy array for setting "outer"-flags

    LOGICAL  ::  netcdf_extend = .FALSE. !< Flag indicating wether netcdf topography input file or not

    REAL(wp) ::  dum           !< dummy variable to skip columns while reading topography file    
    REAL(wp) ::  dz_stretched  !< stretched vertical grid spacing

    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  oro_height    !< input variable for terrain height
    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  topo_height   !< input variable for topography height

    INTEGER( KIND=1 ), DIMENSION(:,:,:), ALLOCATABLE ::  topo_3d_read !< input variable for 3D topography

!
!-- Calculation of horizontal array bounds including ghost layers
    nxlg = nxl - nbgp
    nxrg = nxr + nbgp
    nysg = nys - nbgp
    nyng = nyn + nbgp

!
!-- Allocate grid arrays
    ALLOCATE( ddzu(1:nzt+1), ddzw(1:nzt+1), dd2zu(1:nzt), dzu(1:nzt+1),        &
              dzw(1:nzt+1), l_grid(1:nzt), zu(nzb:nzt+1), zw(nzb:nzt+1) )

!
!-- Compute height of u-levels from constant grid length and dz stretch factors
    IF ( dz == -1.0_wp )  THEN
       message_string = 'missing dz'
       CALL message( 'init_grid', 'PA0200', 1, 2, 0, 6, 0 ) 
    ELSEIF ( dz <= 0.0_wp )  THEN
       WRITE( message_string, * ) 'dz=',dz,' <= 0.0'
       CALL message( 'init_grid', 'PA0201', 1, 2, 0, 6, 0 )
    ENDIF

!
!-- Define the vertical grid levels
    IF ( .NOT. ocean )  THEN
!
!--    Grid for atmosphere with surface at z=0 (k=0, w-grid).
!--    The second u-level (k=1) corresponds to the top of the 
!--    Prandtl-layer.

       IF ( ibc_uv_b == 0 .OR. ibc_uv_b == 2 ) THEN
          zu(0) = 0.0_wp
      !    zu(0) = - dz * 0.5_wp
       ELSE
          zu(0) = - dz * 0.5_wp
       ENDIF
       zu(1) =   dz * 0.5_wp

       dz_stretch_level_index = nzt+1
       dz_stretched = dz
       DO  k = 2, nzt+1
          IF ( dz_stretch_level <= zu(k-1)  .AND.  dz_stretched < dz_max )  THEN
             dz_stretched = dz_stretched * dz_stretch_factor
             dz_stretched = MIN( dz_stretched, dz_max )
             IF ( dz_stretch_level_index == nzt+1 ) dz_stretch_level_index = k-1
          ENDIF
          zu(k) = zu(k-1) + dz_stretched
       ENDDO

!
!--    Compute the w-levels. They are always staggered half-way between the 
!--    corresponding u-levels. In case of dirichlet bc for u and v at the 
!--    ground the first u- and w-level (k=0) are defined at same height (z=0). 
!--    The top w-level is extrapolated linearly.
       zw(0) = 0.0_wp
       DO  k = 1, nzt
          zw(k) = ( zu(k) + zu(k+1) ) * 0.5_wp
       ENDDO
       zw(nzt+1) = zw(nzt) + 2.0_wp * ( zu(nzt+1) - zw(nzt) )

    ELSE
!
!--    Grid for ocean with free water surface is at k=nzt (w-grid).
!--    In case of neumann bc at the ground the first first u-level (k=0) lies
!--    below the first w-level (k=0). In case of dirichlet bc the first u- and
!--    w-level are defined at same height, but staggered from the second level.
!--    The second u-level (k=1) corresponds to the top of the Prandtl-layer.
       zu(nzt+1) =   dz * 0.5_wp
       zu(nzt)   = - dz * 0.5_wp

       dz_stretch_level_index = 0
       dz_stretched = dz
       DO  k = nzt-1, 0, -1
!
!--       The default value of dz_stretch_level is positive, thus the first 
!--       condition is always true. Hence, the second condition is necessary.
          IF ( dz_stretch_level >= zu(k+1)  .AND.  dz_stretch_level <= 0.0  &
               .AND.  dz_stretched < dz_max )  THEN
             dz_stretched = dz_stretched * dz_stretch_factor
             dz_stretched = MIN( dz_stretched, dz_max )
             IF ( dz_stretch_level_index == 0 ) dz_stretch_level_index = k+1
          ENDIF
          zu(k) = zu(k+1) - dz_stretched
       ENDDO

!
!--    Compute the w-levels. They are always staggered half-way between the 
!--    corresponding u-levels, except in case of dirichlet bc for u and v
!--    at the ground. In this case the first u- and w-level are defined at 
!--    same height. The top w-level (nzt+1) is not used but set for 
!--    consistency, since w and all scalar variables are defined up tp nzt+1.
       zw(nzt+1) = dz
       zw(nzt)   = 0.0_wp
       DO  k = 0, nzt
          zw(k) = ( zu(k) + zu(k+1) ) * 0.5_wp
       ENDDO

!
!--    In case of dirichlet bc for u and v the first u- and w-level are defined
!--    at same height.
       IF ( ibc_uv_b == 0 ) THEN
          zu(0) = zw(0)
       ENDIF

    ENDIF

!
!-- Compute grid lengths.
    DO  k = 1, nzt+1
       dzu(k)  = zu(k) - zu(k-1)
       ddzu(k) = 1.0_wp / dzu(k)
       dzw(k)  = zw(k) - zw(k-1)
       ddzw(k) = 1.0_wp / dzw(k)
    ENDDO

    DO  k = 1, nzt
       dd2zu(k) = 1.0_wp / ( dzu(k) + dzu(k+1) )
    ENDDO
    
!    
!-- The FFT- SOR-pressure solvers assume grid spacings of a staggered grid
!-- everywhere. For the actual grid, the grid spacing at the lowest level
!-- is only dz/2, but should be dz. Therefore, an additional array
!-- containing with appropriate grid information is created for these
!-- solvers.
    IF ( psolver(1:9) /= 'multigrid' )  THEN
       ALLOCATE( ddzu_pres(1:nzt+1) )
       ddzu_pres = ddzu
       ddzu_pres(1) = ddzu_pres(2)  ! change for lowest level
    ENDIF

!
!-- Compute the reciprocal values of the horizontal grid lengths.
    ddx = 1.0_wp / dx
    ddy = 1.0_wp / dy
    dx2 = dx * dx
    dy2 = dy * dy
    ddx2 = 1.0_wp / dx2
    ddy2 = 1.0_wp / dy2

!
!-- Compute the grid-dependent mixing length.
    DO  k = 1, nzt
       l_grid(k)  = ( dx * dy * dzw(k) )**0.33333333333333_wp
    ENDDO

!
!-- Allocate outer and inner index arrays for topography and set
!-- defaults.                    
    ALLOCATE( nzb_s_inner(nysg:nyng,nxlg:nxrg),                             &
              nzb_s_outer(nysg:nyng,nxlg:nxrg),                             &
              nzb_u_inner(nysg:nyng,nxlg:nxrg),                             &
              nzb_u_outer(nysg:nyng,nxlg:nxrg),                             &
              nzb_v_inner(nysg:nyng,nxlg:nxrg),                             &
              nzb_v_outer(nysg:nyng,nxlg:nxrg),                             &
              nzb_w_inner(nysg:nyng,nxlg:nxrg),                             &
              nzb_w_outer(nysg:nyng,nxlg:nxrg),                             &
              nzb_diff_s_inner(nysg:nyng,nxlg:nxrg),                        &
              nzb_diff_s_outer(nysg:nyng,nxlg:nxrg),                        &
              nzb_local(nysg:nyng,nxlg:nxrg),                               &
              nzb_tmp(nysg:nyng,nxlg:nxrg),                                 &
              wall_flags_0(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )

    ALLOCATE( topo_3d(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
    topo_3d    = 0

    ALLOCATE( l_wall(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )

    nzb_s_inner = nzb;  nzb_s_outer = nzb
    nzb_u_inner = nzb;  nzb_u_outer = nzb
    nzb_v_inner = nzb;  nzb_v_outer = nzb
    nzb_w_inner = nzb;  nzb_w_outer = nzb

!
!-- Define vertical gridpoint from (or to) which on the usual finite difference
!-- form (which does not use surface fluxes) is applied 
    IF ( constant_flux_layer  .OR.  use_surface_fluxes )  THEN
       nzb_diff = nzb + 2
    ELSE
       nzb_diff = nzb + 1
    ENDIF

    nzb_diff_s_inner = nzb_diff;  nzb_diff_s_outer = nzb_diff

!
!-- Initialize near-wall mixing length l_wall only in the vertical direction
!-- for the moment,
!-- multiplication with wall_adjustment_factor near the end of this routine
    l_wall(nzb,:,:)   = l_grid(1)
    DO  k = nzb+1, nzt
       l_wall(k,:,:)  = l_grid(k)
    ENDDO
    l_wall(nzt+1,:,:) = l_grid(nzt)

    DO  k = 1, nzt
       IF ( l_grid(k) > 1.5_wp * dx * wall_adjustment_factor .OR.  &
            l_grid(k) > 1.5_wp * dy * wall_adjustment_factor )  THEN
          WRITE( message_string, * ) 'grid anisotropy exceeds ', &
                                     'threshold given by only local', &
                                     ' &horizontal reduction of near_wall ', &
                                     'mixing length l_wall', &
                                     ' &starting from height level k = ', k, '.'
          CALL message( 'init_grid', 'PA0202', 0, 1, 0, 6, 0 )
          EXIT
       ENDIF
    ENDDO
!
!-- Set outer and inner index arrays for non-flat topography.
!-- Here consistency checks concerning domain size and periodicity are
!-- necessary.
!-- Within this SELECT CASE structure only nzb_local is initialized
!-- individually depending on the chosen topography type, all other index 
!-- arrays are initialized further below.
    SELECT CASE ( TRIM( topography ) )

       CASE ( 'flat' )
!
!--       nzb_local is required for the multigrid solver
          nzb_local = 0
!
!--       Initialilize 3D topography array, used later for initializing flags
          topo_3d(nzb+1:nzt+1,:,:) = IBSET( topo_3d(nzb+1:nzt+1,:,:), 0 ) 
!
!--       level of detail is required for output routines
          lod       = 1

       CASE ( 'single_building' )
!
!--       Single rectangular building, by default centered in the middle of the
!--       total domain
          blx = NINT( building_length_x / dx )
          bly = NINT( building_length_y / dy )
          bh  = MINLOC( ABS( zw - building_height ), 1 ) - 1
          IF ( ABS( zw(bh)   - building_height ) == &
               ABS( zw(bh+1) - building_height )    )  bh = bh + 1

          IF ( building_wall_left == 9999999.9_wp )  THEN
             building_wall_left = ( nx + 1 - blx ) / 2 * dx
          ENDIF
          bxl = NINT( building_wall_left / dx )
          bxr = bxl + blx

          IF ( building_wall_south == 9999999.9_wp )  THEN
             building_wall_south = ( ny + 1 - bly ) / 2 * dy
          ENDIF
          bys = NINT( building_wall_south / dy )
          byn = bys + bly

!
!--       Building size has to meet some requirements
          IF ( ( bxl < 1 ) .OR. ( bxr > nx-1 ) .OR. ( bxr < bxl+3 ) .OR.  &
               ( bys < 1 ) .OR. ( byn > ny-1 ) .OR. ( byn < bys+3 ) )  THEN
             WRITE( message_string, * ) 'inconsistent building parameters:',   &
                                      '& bxl=', bxl, 'bxr=', bxr, 'bys=', bys, &
                                      'byn=', byn, 'nx=', nx, 'ny=', ny
             CALL message( 'init_grid', 'PA0203', 1, 2, 0, 6, 0 )
          ENDIF

!
!--       Define the building. 
          nzb_local = 0
          IF ( bxl <= nxr  .AND.  bxr >= nxl  .AND.                            &
               bys <= nyn  .AND.  byn >= nys )                                 &        
             nzb_local(MAX(nys,bys):MIN(nyn,byn),MAX(nxl,bxl):MIN(nxr,bxr)) = bh

          CALL exchange_horiz_2d_int( nzb_local, nys, nyn, nxl, nxr, nbgp )
!
!--       Set bit array to mask topography
          DO  i = nxlg, nxrg
             DO  j = nysg, nyng

                topo_3d(nzb_local(j,i)+1:nzt+1,j,i) =                          &
                                 IBSET( topo_3d(nzb_local(j,i)+1:nzt+1,j,i), 0 ) 
             ENDDO
          ENDDO
!
!--       level of detail is required for output routines. Here, 2D topography. 
          lod = 1

          CALL exchange_horiz_int( topo_3d, nbgp )

       CASE ( 'single_street_canyon' )
!
!--       Single quasi-2D street canyon of infinite length in x or y direction.
!--       The canyon is centered in the other direction by default.
          IF ( canyon_width_x /= 9999999.9_wp )  THEN
!
!--          Street canyon in y direction
             cwx = NINT( canyon_width_x / dx )
             IF ( canyon_wall_left == 9999999.9_wp )  THEN
                canyon_wall_left = ( nx + 1 - cwx ) / 2 * dx
             ENDIF
             cxl = NINT( canyon_wall_left / dx )
             cxr = cxl + cwx

          ELSEIF ( canyon_width_y /= 9999999.9_wp )  THEN
!
!--          Street canyon in x direction
             cwy = NINT( canyon_width_y / dy )
             IF ( canyon_wall_south == 9999999.9_wp )  THEN
                canyon_wall_south = ( ny + 1 - cwy ) / 2 * dy
             ENDIF
             cys = NINT( canyon_wall_south / dy )
             cyn = cys + cwy

          ELSE
             
             message_string = 'no street canyon width given'
             CALL message( 'init_grid', 'PA0204', 1, 2, 0, 6, 0 )
  
          ENDIF

          ch  = MINLOC( ABS( zw - canyon_height ), 1 ) - 1
          IF ( ABS( zw(ch)   - canyon_height ) == &
               ABS( zw(ch+1) - canyon_height )    )  ch = ch + 1

          dp_level_ind_b = ch
!
!--       Street canyon size has to meet some requirements
          IF ( canyon_width_x /= 9999999.9_wp )  THEN
             IF ( ( cxl < 1 ) .OR. ( cxr > nx-1 ) .OR. ( cwx < 3 ) .OR.        &
               ( ch < 3 ) )  THEN
                WRITE( message_string, * ) 'inconsistent canyon parameters:',  &
                                           '&cxl=', cxl, 'cxr=', cxr,          &
                                           'cwx=', cwx,                        &
                                           'ch=', ch, 'nx=', nx, 'ny=', ny
                CALL message( 'init_grid', 'PA0205', 1, 2, 0, 6, 0 ) 
             ENDIF
          ELSEIF ( canyon_width_y /= 9999999.9_wp )  THEN
             IF ( ( cys < 1 ) .OR. ( cyn > ny-1 ) .OR. ( cwy < 3 ) .OR.        &
               ( ch < 3 ) )  THEN
                WRITE( message_string, * ) 'inconsistent canyon parameters:',  &
                                           '&cys=', cys, 'cyn=', cyn,          &
                                           'cwy=', cwy,                        &
                                           'ch=', ch, 'nx=', nx, 'ny=', ny
                CALL message( 'init_grid', 'PA0206', 1, 2, 0, 6, 0 ) 
             ENDIF
          ENDIF
          IF ( canyon_width_x /= 9999999.9_wp .AND.                            &                 
               canyon_width_y /= 9999999.9_wp )  THEN
             message_string = 'inconsistent canyon parameters:' //             &   
                              '&street canyon can only be oriented' //         &
                              '&either in x- or in y-direction'
             CALL message( 'init_grid', 'PA0207', 1, 2, 0, 6, 0 )
          ENDIF

          nzb_local = ch
          IF ( canyon_width_x /= 9999999.9_wp )  THEN
             IF ( cxl <= nxr  .AND.  cxr >= nxl )                              &
                nzb_local(:,MAX(nxl,cxl+1):MIN(nxr,cxr-1)) = 0
          ELSEIF ( canyon_width_y /= 9999999.9_wp )  THEN
             IF ( cys <= nyn  .AND.  cyn >= nys )                              &          
                nzb_local(MAX(nys,cys+1):MIN(nyn,cyn-1),:) = 0
          ENDIF

          CALL exchange_horiz_2d_int( nzb_local, nys, nyn, nxl, nxr, nbgp )
!
!--       Set bit array to mask topography
          DO  i = nxlg, nxrg
             DO  j = nysg, nyng
                topo_3d(nzb_local(j,i)+1:nzt+1,j,i) =                          &
                                 IBSET( topo_3d(nzb_local(j,i)+1:nzt+1,j,i), 0 ) 
             ENDDO
          ENDDO
!
!--       level of detail is required for output routines. Here, 2D topography. 
          lod = 1

          CALL exchange_horiz_int( topo_3d, nbgp )

       CASE ( 'tunnel' )

!
!--       Tunnel height
          IF ( tunnel_height == 9999999.9_wp )  THEN
             th = zw( INT( 0.2 * nz) )
          ELSE
             th = tunnel_height
          ENDIF
!
!--       Tunnel-wall depth
          IF ( tunnel_wall_depth == 9999999.9_wp )  THEN
             td = MAX ( dx, dy, dz )
          ELSE
             td = tunnel_wall_depth
          ENDIF
!
!--       Check for tunnel width
          IF ( tunnel_width_x == 9999999.9_wp  .AND.                           &
               tunnel_width_y == 9999999.9_wp  )  THEN
             message_string = 'No tunnel width is given. '
             CALL message( 'init_grid', 'PA0280', 1, 2, 0, 6, 0 )
          ENDIF
          IF ( tunnel_width_x /= 9999999.9_wp  .AND.                           &
               tunnel_width_y /= 9999999.9_wp  )  THEN
             message_string = 'Inconsistent tunnel parameters:' //             &   
                              'tunnel can only be oriented' //                 &
                              'either in x- or in y-direction.'
             CALL message( 'init_grid', 'PA0281', 1, 2, 0, 6, 0 )
          ENDIF
!
!--       Tunnel axis along y
          IF ( tunnel_width_x /= 9999999.9_wp )  THEN
             IF ( tunnel_width_x > ( nx + 1 ) * dx )  THEN
                message_string = 'Tunnel width too large'
                CALL message( 'init_grid', 'PA0282', 1, 2, 0, 6, 0 )
             ENDIF

             txs_out = INT( ( nx + 1 ) * 0.5_wp * dx - tunnel_width_x * 0.5_wp )
             txe_out = INT( ( nx + 1 ) * 0.5_wp * dx + tunnel_width_x * 0.5_wp )
             txs_in  = INT( ( nx + 1 ) * 0.5_wp * dx -                         &
                                      ( tunnel_width_x * 0.5_wp - td ) )
             txe_in  = INT( ( nx + 1 ) * 0.5_wp * dx +                         &
                                      ( tunnel_width_x * 0.5_wp - td ) )

             tys_out = INT( ( ny + 1 ) * 0.5_wp * dy - tunnel_length * 0.5_wp )
             tye_out = INT( ( ny + 1 ) * 0.5_wp * dy + tunnel_length * 0.5_wp )
             tys_in  = tys_out
             tye_in  = tye_out
          ENDIF
          IF ( tunnel_width_x /= 9999999.9_wp  .AND.                           &
               tunnel_width_x - 2.0_wp * tunnel_wall_depth <= 2.0_wp * dx )  THEN
             message_string = 'Tunnel width too small'
             CALL message( 'init_grid', 'PA0175', 1, 2, 0, 6, 0 )
          ENDIF
          IF ( tunnel_width_y /= 9999999.9_wp  .AND.                           &
               tunnel_width_y - 2.0_wp * tunnel_wall_depth <= 2.0_wp * dy )  THEN
             message_string = 'Tunnel width too small'
             CALL message( 'init_grid', 'PA0455', 1, 2, 0, 6, 0 )
          ENDIF
!
!--       Tunnel axis along x
          IF ( tunnel_width_y /= 9999999.9_wp )  THEN
             IF ( tunnel_width_y > ( ny + 1 ) * dy )  THEN
                message_string = 'Tunnel width too large'
                CALL message( 'init_grid', 'PA0456', 1, 2, 0, 6, 0 )
             ENDIF

             txs_out = INT( ( nx + 1 ) * 0.5_wp * dx - tunnel_length * 0.5_wp )
             txe_out = INT( ( nx + 1 ) * 0.5_wp * dx + tunnel_length * 0.5_wp )
             txs_in  = txs_out
             txe_in  = txe_out

             tys_out = INT( ( ny + 1 ) * 0.5_wp * dy - tunnel_width_y * 0.5_wp )
             tye_out = INT( ( ny + 1 ) * 0.5_wp * dy + tunnel_width_y * 0.5_wp )
             tys_in  = INT( ( ny + 1 ) * 0.5_wp * dy -                         &
                                     ( tunnel_width_y * 0.5_wp - td ) )
             tye_in  = INT( ( ny + 1 ) * 0.5_wp * dy +                         &
                                     ( tunnel_width_y * 0.5_wp - td ) )
          ENDIF

          topo_3d = 0
          DO  i = nxl, nxr
             DO  j = nys, nyn
!
!--             Use heaviside function to model outer tunnel surface
                hv_out = th * 0.5_wp *                                         &
                              ( ( SIGN( 1.0_wp, i * dx - txs_out ) + 1.0_wp )  &
                              - ( SIGN( 1.0_wp, i * dx - txe_out ) + 1.0_wp ) )

                hv_out = hv_out * 0.5_wp *                                     &
                            ( ( SIGN( 1.0_wp, j * dy - tys_out ) + 1.0_wp )    &
                            - ( SIGN( 1.0_wp, j * dy - tye_out ) + 1.0_wp ) )
! 
!--             Use heaviside function to model inner tunnel surface
                hv_in  = ( th - td ) * 0.5_wp *                                &
                                ( ( SIGN( 1.0_wp, i * dx - txs_in ) + 1.0_wp ) &
                                - ( SIGN( 1.0_wp, i * dx - txe_in ) + 1.0_wp ) )

                hv_in = hv_in * 0.5_wp *                                       &
                                ( ( SIGN( 1.0_wp, j * dy - tys_in ) + 1.0_wp ) &
                                - ( SIGN( 1.0_wp, j * dy - tye_in ) + 1.0_wp ) )
!
!--             Set flags at x-y-positions without any tunnel surface
                IF ( hv_out - hv_in == 0.0_wp )  THEN
                   topo_3d(nzb+1:nzt+1,j,i) = IBSET( topo_3d(nzb+1:nzt+1,j,i), 0 )
!
!--             Set flags at x-y-positions with tunnel surfaces
                ELSE
                   DO  k = nzb + 1, nzt + 1
!
!--                   Inner tunnel
                      IF ( hv_out - hv_in == th )  THEN
                         IF ( zw(k) <= hv_out )  THEN
                            topo_3d(k,j,i) = IBCLR( topo_3d(k,j,i), 0 )
                         ELSE
                            topo_3d(k,j,i) = IBSET( topo_3d(k,j,i), 0 )
                         ENDIF
                      ENDIF
!
!--                   Lateral tunnel walls
                      IF ( hv_out - hv_in == td )  THEN
                         IF ( zw(k) <= hv_in )  THEN 
                            topo_3d(k,j,i) = IBSET( topo_3d(k,j,i), 0 )
                         ELSEIF ( zw(k) > hv_in  .AND.  zw(k) <= hv_out )  THEN 
                            topo_3d(k,j,i) = IBCLR( topo_3d(k,j,i), 0 )
                         ELSEIF ( zw(k) > hv_out )  THEN 
                            topo_3d(k,j,i) = IBSET( topo_3d(k,j,i), 0 )
                         ENDIF
                      ENDIF
                   ENDDO
                ENDIF
             ENDDO
          ENDDO

          nzb_local = 0
!
!--       level of detail is required for output routines. Here, 3D topography. 
          lod = 2

          CALL exchange_horiz_int( topo_3d, nbgp )

       CASE ( 'read_from_file' )

          ALLOCATE ( oro_height(nys:nyn,nxl:nxr)  )
          ALLOCATE ( topo_height(nys:nyn,nxl:nxr) )
          oro_height  = 0.0_wp
          topo_height = 0.0_wp

          DO  ii = 0, io_blocks-1
             IF ( ii == io_group )  THEN

!
!--             Arbitrary irregular topography data in PALM format (exactly
!--             matching the grid size and total domain size). 
!--             First, check if NetCDF file for topography exist or not.
!--             This case, read topography from NetCDF, else read it from 
!--             ASCII file.
#if defined ( __netcdf )
                INQUIRE( FILE='TOPOGRAPHY_DATA_NC'//TRIM( coupling_char ),     &
                         EXIST=netcdf_extend )
!
!--             NetCDF branch    
                IF ( netcdf_extend )  THEN
!
!--                Open file in read-only mode
                   CALL netcdf_open_read_file( 'TOPOGRAPHY_DATA_NC',           &
                                               id_topo, 20 )  !Error number still need to be set properly 

!
!--                Read terrain height. Reading is done PE-wise, i.e. each
!--                processor reads its own domain. Reading is realized
!--                via looping over x-dimension, i.e. calling 
!--                netcdf_get_variable reads topography along y for given x. 
!--                Orography is 2D. 
                   DO  i = nxl, nxr
                      CALL netcdf_get_variable( id_topo, 'orography_0',        &
                                                i, oro_height(:,i), 20 )  !Error number still need to be set properly 
                   ENDDO
!
!--                Read attribute lod (level of detail), required for variable 
!--                buildings_0 
                   CALL netcdf_get_attribute( id_topo, "lod", lod, .FALSE.,    &
                                              20, 'buildings_0' ) !Error number still need to be set properly 
!
!--                Read building height
!--                2D for lod = 1, 3D for lod = 2
                   IF ( lod == 1 )  THEN
                      DO  i = nxl, nxr
                         CALL netcdf_get_variable( id_topo, 'buildings_0',     &
                                                   i, topo_height(:,i), 20 )  !Error number still need to be set properly 
                      ENDDO

                   ELSEIF ( lod == 2 )  THEN
!
!--                   Allocate 1-byte integer dummy array to read 3D topography
                      ALLOCATE( topo_3d_read(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
!
!--                   Read data PE-wise. Read yz-slices.
                      DO  i = nxl, nxr
                         DO  j = nys, nyn
                            CALL netcdf_get_variable( id_topo, 'buildings_0',  &
                                                      i, j, topo_3d_read(:,j,i), 20 )  !Error number still need to be set properly 
                         ENDDO
                      ENDDO
                   ELSE 
                      message_string = 'NetCDF attribute lod ' //              &
                                       '(level of detail) is not set properly.'
                      CALL message( 'init_grid', 'PA0457', 1, 2, 0, 6, 0 )
                   ENDIF
!
!--                On file, 3D topography grid points is classified with 1, 
!--                atmosphere is classified with 0, contrary to the internal 
!--                treatment. Hence, conversion is required. Moreover, set 
!--                topography array to zero at lowest grid level. 
                   topo_3d = MERGE( 0, 1, topo_3d_read == 1 )
                   topo_3d(nzb,:,:) = 0 
!
!--                Deallocate dummy array
                   DEALLOCATE( topo_3d_read )
!
!--                Close topography input file
                   CALL netcdf_close_file( id_topo, 20 )
#endif

!
!--             ASCII branch. Please note, reading of 3D topography is not
!--             supported in ASCII format. Further, no distinction is made 
!--             between orography and buildings
                ELSE

                   OPEN( 90, FILE='TOPOGRAPHY_DATA'//TRIM( coupling_char ),    &
                         STATUS='OLD', FORM='FORMATTED', ERR=10 )
!
!--                Read topography PE-wise. Rows are read from nyn to nys, columns
!--                are read from nxl to nxr. At first, ny-nyn rows need to be skipped.
                   skip_n_rows = 0
                   DO WHILE ( skip_n_rows < ny - nyn )
                      READ( 90, * )  
                      skip_n_rows = skip_n_rows + 1
                   ENDDO
!
!--                Read data from nyn to nys and nxl to nxr. Therefore, skip 
!--                column until nxl-1 is reached
                   DO  j = nyn, nys, -1
                      READ( 90, *, ERR=11, END=11 )                            &
                                              ( dum, i = 0, nxl-1 ),           &
                                              ( topo_height(j,i), i = nxl, nxr )
                   ENDDO

                   GOTO 12
          
 10                message_string = 'file TOPOGRAPHY'//TRIM( coupling_char )// &
                                    ' does not exist'
                   CALL message( 'init_grid', 'PA0208', 1, 2, 0, 6, 0 )

 11                message_string = 'errors in file TOPOGRAPHY_DATA'//         &
                                    TRIM( coupling_char )
                   CALL message( 'init_grid', 'PA0209', 1, 2, 0, 6, 0 )

 12                CLOSE( 90 )

                ENDIF

             ENDIF
#if defined( __parallel )
             CALL MPI_BARRIER( comm2d, ierr )
#endif
          ENDDO

!
!--       Calculate the index height of the topography
          nzb_local = 0
          DO  i = nxl, nxr
             DO  j = nys, nyn
                IF ( .NOT. ocean )  THEN
                   nzb_local(j,i) = MINLOC( ABS( zw - topo_height(j,i)         &
                                                    - oro_height(j,i) ), 1 ) - 1
                   IF ( ABS( zw(nzb_local(j,i)  ) - topo_height(j,i)           &
                                                  - oro_height(j,i)  ) ==      &
                        ABS( zw(nzb_local(j,i)+1) - topo_height(j,i)           &
                                                  - oro_height(j,i)  )    )    &
                      nzb_local(j,i) = nzb_local(j,i) + 1
                ELSE
                   nzb_local(j,i) = MINLOC( ABS( zw - zw(0)                    &
                                                    - topo_height(j,i)         &
                                                    - oro_height(j,i) ), 1 ) - 1
                   IF ( ABS( zw(nzb_local(j,i)  ) - zw(0)                      &
                                                  - topo_height(j,i)           &
                                                  - oro_height(j,i)  )  ==     &
                        ABS( zw(nzb_local(j,i)+1) - zw(0)                      &
                                                  - topo_height(j,i)           &
                                                  - oro_height(j,i)  )    )    &
                      nzb_local(j,i) = nzb_local(j,i) + 1
                ENDIF

             ENDDO
          ENDDO

          DEALLOCATE ( oro_height  )
          DEALLOCATE ( topo_height )
!
!--       Filter topography, i.e. fill holes resolved by only one grid point.  
!--       Such holes are suspected to lead to velocity blow-ups as continuity 
!--       equation on discrete grid cannot be fulfilled in such case.
!--       For now, check only for holes and fill them to the lowest height level
!--       of the directly adjoining grid points along x- and y- direction. 
!--       Before checking for holes, set lateral boundary conditions for 
!--       topography. After hole-filling, boundary conditions must be set again!
          CALL exchange_horiz_2d_int( nzb_local, nys, nyn, nxl, nxr, nbgp )
          
          IF ( .NOT. bc_ns_cyc )  THEN
             IF ( nys == 0  )  nzb_local(-1,:)   = nzb_local(0,:)
             IF ( nyn == ny )  nzb_local(ny+1,:) = nzb_local(ny,:)
          ENDIF

          IF ( .NOT. bc_lr_cyc )  THEN
             IF ( nxl == 0  )  nzb_local(:,-1)   = nzb_local(:,0)
             IF ( nxr == nx )  nzb_local(:,nx+1) = nzb_local(:,nx)          
          ENDIF

          num_hole_l = 0
          DO i = nxl, nxr
             DO j = nys, nyn

                num_wall = 0

                IF ( nzb_local(j-1,i) > nzb_local(j,i) )                       &
                   num_wall = num_wall + 1
                IF ( nzb_local(j+1,i) > nzb_local(j,i) )                       &
                   num_wall = num_wall + 1
                IF ( nzb_local(j,i-1) > nzb_local(j,i) )                       &
                   num_wall = num_wall + 1
                IF ( nzb_local(j,i+1) > nzb_local(j,i) )                       &
                   num_wall = num_wall + 1

                IF ( num_wall == 4 )  THEN
                   nzb_local(j,i) = MIN( nzb_local(j-1,i), nzb_local(j+1,i),   &
                                         nzb_local(j,i-1), nzb_local(j,i+1) )
                   num_hole_l     = num_hole_l + 1
                ENDIF
             ENDDO
          ENDDO
!
!--       Count the total number of holes, required for informative message.
#if defined( __parallel )
          CALL MPI_ALLREDUCE( num_hole_l, num_hole, 1, MPI_INTEGER, MPI_SUM,   &
                              comm2d, ierr )
#else
          num_hole = num_hole_l
#endif    
!
!--       Create an informative message if any hole was removed.
          IF ( num_hole > 0 )  THEN
             WRITE( message_string, * ) num_hole, 'hole(s) resolved by only '//&
                                                  'one grid point were filled'
             CALL message( 'init_grid', 'PA0430', 0, 0, 0, 6, 0 )
          ENDIF

!
!--       Set bit array to mask topography. Only required for lod = 1
          IF ( lod == 1 )  THEN
             DO  i = nxlg, nxrg
                DO  j = nysg, nyng
                   topo_3d(nzb_local(j,i)+1:nzt+1,j,i) =                          &
                                 IBSET( topo_3d(nzb_local(j,i)+1:nzt+1,j,i), 0 ) 
                ENDDO
             ENDDO
          ENDIF
!
!--       Exchange ghost-points, as well as add cyclic or Neumann boundary 
!--       conditions.
          CALL exchange_horiz_int( topo_3d, nbgp )
          CALL exchange_horiz_2d_int( nzb_local, nys, nyn, nxl, nxr, nbgp )
          
          IF ( .NOT. bc_ns_cyc )  THEN
             IF ( nys == 0  )  topo_3d(:,-1,:)   = topo_3d(:,0,:)
             IF ( nyn == ny )  topo_3d(:,ny+1,:) = topo_3d(:,ny,:)

             IF ( nys == 0  )  nzb_local(-1,:)   = nzb_local(0,:)
             IF ( nyn == ny )  nzb_local(ny+1,:) = nzb_local(ny,:)
          ENDIF

          IF ( .NOT. bc_lr_cyc )  THEN
             IF ( nxl == 0  )  topo_3d(:,:,-1)   = topo_3d(:,:,0)
             IF ( nxr == nx )  topo_3d(:,:,nx+1) = topo_3d(:,:,nx)     

             IF ( nxl == 0  )  nzb_local(:,-1)   = nzb_local(:,0)
             IF ( nxr == nx )  nzb_local(:,nx+1) = nzb_local(:,nx)          
          ENDIF


       CASE DEFAULT
!
!--       The DEFAULT case is reached either if the parameter topography
!--       contains a wrong character string or if the user has defined a special
!--       case in the user interface. There, the subroutine user_init_grid 
!--       checks which of these two conditions applies.
          CALL user_init_grid( topo_3d )

    END SELECT
!
!-- Consistency checks and index array initialization are only required for
!-- non-flat topography, also the initialization of topography height arrays
!-- zu_s_inner and zw_w_inner
    IF ( TRIM( topography ) /= 'flat' )  THEN
#if defined( __parallel )
       CALL MPI_ALLREDUCE( MAXVAL( nzb_local ), nzb_local_max, 1, MPI_INTEGER, &
                           MPI_MAX, comm2d, ierr )
       CALL MPI_ALLREDUCE( MINVAL( nzb_local ), nzb_local_min, 1, MPI_INTEGER, &
                           MPI_MIN, comm2d, ierr )                           
#else
       nzb_local_max = MAXVAL( nzb_local )
       nzb_local_min = MINVAL( nzb_local )
#endif

!
!--    Consistency checks
       IF ( nzb_local_min < 0  .OR.  nzb_local_max  > nz + 1 )  THEN
          WRITE( message_string, * ) 'nzb_local values are outside the',       &
                                'model domain',                                &
                                '&MINVAL( nzb_local ) = ', nzb_local_min,      &
                                '&MAXVAL( nzb_local ) = ', nzb_local_max
          CALL message( 'init_grid', 'PA0210', 1, 2, 0, 6, 0 )
       ENDIF
!
!--    In case of non-flat topography, check whether the convention how to 
!--    define the topography grid has been set correctly, or whether the default
!--    is applicable. If this is not possible, abort.
       IF ( TRIM( topography_grid_convention ) == ' ' )  THEN
          IF ( TRIM( topography ) /= 'single_building' .AND.                   &
               TRIM( topography ) /= 'single_street_canyon' .AND.              &
               TRIM( topography ) /= 'tunnel'  .AND.                           &
               TRIM( topography ) /= 'read_from_file')  THEN
!--          The default value is not applicable here, because it is only valid
!--          for the two standard cases 'single_building' and 'read_from_file'
!--          defined in init_grid.
             WRITE( message_string, * )                                        &
                  'The value for "topography_grid_convention" ',               &
                  'is not set. Its default value is & only valid for ',        &
                  '"topography" = ''single_building'', ',                      &
                  '''single_street_canyon'' & or ''read_from_file''.',         &
                  ' & Choose ''cell_edge'' or ''cell_center''.'
             CALL message( 'init_grid', 'PA0239', 1, 2, 0, 6, 0 )
          ELSE
!--          The default value is applicable here.
!--          Set convention according to topography.
             IF ( TRIM( topography ) == 'single_building' .OR.                 &
                  TRIM( topography ) == 'single_street_canyon' )  THEN
                topography_grid_convention = 'cell_edge'
             ELSEIF ( TRIM( topography ) == 'read_from_file'  .OR.             &
                      TRIM( topography ) == 'tunnel')  THEN
                topography_grid_convention = 'cell_center'
             ENDIF
          ENDIF
       ELSEIF ( TRIM( topography_grid_convention ) /= 'cell_edge' .AND.        &
                TRIM( topography_grid_convention ) /= 'cell_center' )  THEN
          WRITE( message_string, * )                                           &
               'The value for "topography_grid_convention" is ',               &
               'not recognized. & Choose ''cell_edge'' or ''cell_center''.'
          CALL message( 'init_grid', 'PA0240', 1, 2, 0, 6, 0 )
       ENDIF

!
!--    In case of non-flat topography, check whether the convention how to 
!--    define the topography grid has been set correctly, or whether the default
!--    is applicable. If this is not possible, abort.
       IF ( TRIM( topography_grid_convention ) == ' ' )  THEN
          IF ( TRIM( topography ) /= 'single_building' .AND.                   &
               TRIM( topography ) /= 'single_street_canyon' .AND.              &
               TRIM( topography ) /= 'read_from_file' )  THEN
!--          The default value is not applicable here, because it is only valid
!--          for the two standard cases 'single_building' and 'read_from_file'
!--          defined in init_grid.
             WRITE( message_string, * )                                        &
                  'The value for "topography_grid_convention" ',               &
                  'is not set. Its default value is & only valid for ',        &
                  '"topography" = ''single_building'', ',                      &
                  '''single_street_canyon'' & or ''read_from_file''.',         &
                  ' & Choose ''cell_edge'' or ''cell_center''.'
             CALL message( 'init_grid', 'PA0239', 1, 2, 0, 6, 0 )
          ELSE
!--          The default value is applicable here.
!--          Set convention according to topography.
             IF ( TRIM( topography ) == 'single_building' .OR.                 &
                  TRIM( topography ) == 'single_street_canyon' )  THEN
                topography_grid_convention = 'cell_edge'
             ELSEIF ( TRIM( topography ) == 'read_from_file' )  THEN
                topography_grid_convention = 'cell_center'
             ENDIF
          ENDIF
       ELSEIF ( TRIM( topography_grid_convention ) /= 'cell_edge' .AND.        &
                TRIM( topography_grid_convention ) /= 'cell_center' )  THEN
          WRITE( message_string, * )                                           &
               'The value for "topography_grid_convention" is ',               &
               'not recognized. & Choose ''cell_edge'' or ''cell_center''.'
          CALL message( 'init_grid', 'PA0240', 1, 2, 0, 6, 0 )
       ENDIF

       IF ( topography_grid_convention == 'cell_edge' )  THEN
! 
!--       The array nzb_local as defined using the 'cell_edge' convention 
!--       describes the actual total size of topography which is defined at the 
!--       cell edges where u=0 on the topography walls in x-direction and v=0 
!--       on the topography walls in y-direction. However, PALM uses individual
!--       arrays nzb_u|v|w|s_inner|outer that are based on nzb_s_inner.
!--       Therefore, the extent of topography in nzb_local is now reduced by 
!--       1dx at the E topography walls and by 1dy at the N topography walls 
!--       to form the basis for nzb_s_inner. 
!--       Note, the reverse memory access (i-j instead of j-i) is absolutely
!--       required at this point.
          DO  j = nys+1, nyn+1
             DO  i = nxl-1, nxr
                nzb_local(j,i) = MIN( nzb_local(j,i), nzb_local(j,i+1) )
             ENDDO
          ENDDO
!
!--       Exchange ghost points
          CALL exchange_horiz_2d_int( nzb_local, nys, nyn, nxl, nxr, nbgp )

          DO  i = nxl, nxr+1
             DO  j = nys-1, nyn
                nzb_local(j,i) = MIN( nzb_local(j,i), nzb_local(j+1,i) )
             ENDDO
          ENDDO  
!
!--       Exchange ghost points          
          CALL exchange_horiz_2d_int( nzb_local, nys, nyn, nxl, nxr, nbgp )
!
!--       Apply cell-edge convention also for 3D topo array. The former setting
!--       of nzb_local will be removed later. 
          DO  j = nys+1, nyn+1
             DO  i = nxl-1, nxr
                DO  k = nzb, nzt+1
                   IF ( BTEST( topo_3d(k,j,i), 0 )  .OR.                       &
                        BTEST( topo_3d(k,j,i+1), 0 ) )                         &
                      topo_3d(k,j,i) = IBSET( topo_3d(k,j,i), 0 )
                ENDDO
             ENDDO
          ENDDO      
          CALL exchange_horiz_int( topo_3d, nbgp )   

          DO  i = nxl, nxr+1
             DO  j = nys-1, nyn
                DO  k = nzb, nzt+1
                   IF ( BTEST( topo_3d(k,j,i), 0 )  .OR.                       &
                        BTEST( topo_3d(k,j+1,i), 0 ) )                         &
                      topo_3d(k,j,i) = IBSET( topo_3d(k,j,i), 0 )
                ENDDO
             ENDDO
          ENDDO  
          CALL exchange_horiz_int( topo_3d, nbgp )
   
       ENDIF
      
!
!--    Initialize index arrays nzb_s_inner and nzb_w_inner

       nzb_s_inner = nzb_local
       nzb_w_inner = nzb_local

!
!--    Initialize remaining index arrays:
!--    first pre-initialize them with nzb_s_inner...
       nzb_u_inner = nzb_s_inner
       nzb_u_outer = nzb_s_inner
       nzb_v_inner = nzb_s_inner
       nzb_v_outer = nzb_s_inner
       nzb_w_outer = nzb_s_inner
       nzb_s_outer = nzb_s_inner

!
!--    ...then extend pre-initialized arrays in their according directions
!--    based on nzb_local using nzb_tmp as a temporary global index array

!
!--    nzb_s_outer: 
!--    extend nzb_local east-/westwards first, then north-/southwards
       nzb_tmp = nzb_local
       DO  j = nys, nyn
          DO  i = nxl, nxr
             nzb_tmp(j,i) = MAX( nzb_local(j,i-1), nzb_local(j,i),             &
                                 nzb_local(j,i+1) )
          ENDDO
       ENDDO
       
       CALL exchange_horiz_2d_int( nzb_tmp, nys, nyn, nxl, nxr, nbgp )
       
       DO  i = nxl, nxr
          DO  j = nys, nyn
             nzb_s_outer(j,i) = MAX( nzb_tmp(j-1,i), nzb_tmp(j,i),             &
                                     nzb_tmp(j+1,i) )
          ENDDO
!
!--       non-cyclic boundary conditions (overwritten by call of
!--       exchange_horiz_2d_int below in case of cyclic boundary conditions)
          IF ( nys == 0 )  THEN
             j = -1
             nzb_s_outer(j,i) = MAX( nzb_tmp(j+1,i), nzb_tmp(j,i) )
          ENDIF
          IF ( nyn == ny )  THEN
             j = ny + 1
             nzb_s_outer(j,i) = MAX( nzb_tmp(j-1,i), nzb_tmp(j,i) )
          ENDIF
       ENDDO
!
!--    nzb_w_outer: 
!--    identical to nzb_s_outer
       nzb_w_outer = nzb_s_outer

!
!--    nzb_u_inner: 
!--    extend nzb_local rightwards only
       nzb_tmp = nzb_local
       DO  j = nys, nyn
          DO  i = nxl, nxr
             nzb_tmp(j,i) = MAX( nzb_local(j,i-1), nzb_local(j,i) )
          ENDDO
       ENDDO
       
       CALL exchange_horiz_2d_int( nzb_tmp, nys, nyn, nxl, nxr, nbgp )
       
       nzb_u_inner = nzb_tmp
!
!--    nzb_u_outer: 
!--    extend current nzb_tmp (nzb_u_inner) north-/southwards
       DO  i = nxl, nxr
          DO  j = nys, nyn
             nzb_u_outer(j,i) = MAX( nzb_tmp(j-1,i), nzb_tmp(j,i),             &
                                     nzb_tmp(j+1,i) )
          ENDDO
!
!--       non-cyclic boundary conditions (overwritten by call of
!--       exchange_horiz_2d_int below in case of cyclic boundary conditions)
          IF ( nys == 0 )  THEN
             j = -1
             nzb_u_outer(j,i) = MAX( nzb_tmp(j+1,i), nzb_tmp(j,i) )
          ENDIF
          IF ( nyn == ny )  THEN
             j = ny + 1
             nzb_u_outer(j,i) = MAX( nzb_tmp(j-1,i), nzb_tmp(j,i) )
          ENDIF
       ENDDO

!
!--    nzb_v_inner:
!--    extend nzb_local northwards only
       nzb_tmp = nzb_local
       DO  i = nxl, nxr
          DO  j = nys, nyn
             nzb_tmp(j,i) = MAX( nzb_local(j-1,i), nzb_local(j,i) )
          ENDDO
       ENDDO
       
       CALL exchange_horiz_2d_int( nzb_tmp, nys, nyn, nxl, nxr, nbgp )      
       nzb_v_inner = nzb_tmp

!
!--    nzb_v_outer: 
!--    extend current nzb_tmp (nzb_v_inner) right-/leftwards
       DO  j = nys, nyn
          DO  i = nxl, nxr
             nzb_v_outer(j,i) = MAX( nzb_tmp(j,i-1), nzb_tmp(j,i),             &
                                     nzb_tmp(j,i+1) )
          ENDDO
!
!--       non-cyclic boundary conditions (overwritten by call of
!--       exchange_horiz_2d_int below in case of cyclic boundary conditions)
          IF ( nxl == 0 )  THEN
             i = -1
             nzb_v_outer(j,i) = MAX( nzb_tmp(j,i+1), nzb_tmp(j,i) )
          ENDIF
          IF ( nxr == nx )  THEN
             i = nx + 1
             nzb_v_outer(j,i) = MAX( nzb_tmp(j,i-1), nzb_tmp(j,i) )
          ENDIF
       ENDDO

!
!--    Exchange of lateral boundary values (parallel computers) and cyclic
!--    boundary conditions, if applicable.
!--    Since nzb_s_inner and nzb_w_inner are derived directly from nzb_local
!--    they do not require exchange and are not included here.
       CALL exchange_horiz_2d_int( nzb_u_inner, nys, nyn, nxl, nxr, nbgp )
       CALL exchange_horiz_2d_int( nzb_u_outer, nys, nyn, nxl, nxr, nbgp )
       CALL exchange_horiz_2d_int( nzb_v_inner, nys, nyn, nxl, nxr, nbgp )
       CALL exchange_horiz_2d_int( nzb_v_outer, nys, nyn, nxl, nxr, nbgp )
       CALL exchange_horiz_2d_int( nzb_w_outer, nys, nyn, nxl, nxr, nbgp )
       CALL exchange_horiz_2d_int( nzb_s_outer, nys, nyn, nxl, nxr, nbgp )

    ENDIF
!
!-- Deallocate temporary array, as it might be reused for different
!-- grid-levels further below.
    DEALLOCATE( nzb_tmp )

!
!-- Determine the maximum level of topography. It is used for
!-- steering the degradation of order of the applied advection scheme.
!-- In case of non-cyclic lateral boundaries, the order of the advection
!-- scheme has to be reduced up to nzt (required at the lateral boundaries).
    k_top = 0
    DO  i = nxl, nxr
       DO  j = nys, nyn
          DO  k = nzb, nzt + 1
             k_top = MAX( k_top, MERGE( k, 0,                                  &
                                        .NOT. BTEST( topo_3d(k,j,i), 0 ) ) )
          ENDDO
       ENDDO
    ENDDO
#if defined( __parallel )
    CALL MPI_ALLREDUCE( k_top + 1, nzb_max, 1, MPI_INTEGER,                    & !is +1 really necessary here?
                        MPI_MAX, comm2d, ierr )
#else
    nzb_max = k_top + 1
#endif
    IF ( inflow_l .OR. outflow_l .OR. inflow_r .OR. outflow_r .OR.             &
         inflow_n .OR. outflow_n .OR. inflow_s .OR. outflow_s .OR.             &
         nest_domain )                                                         &
    THEN
       nzb_max = nzt
    ENDIF
!
!-- Finally, if topography extents up to the model top, limit nzb_max to nzt.
    nzb_max = MIN( nzb_max, nzt ) 

!
!-- Set the individual index arrays which define the k index from which on
!-- the usual finite difference form (which does not use surface fluxes) is
!-- applied 
    IF ( constant_flux_layer  .OR.  use_surface_fluxes )  THEN
       nzb_diff_s_inner   = nzb_s_inner + 2
       nzb_diff_s_outer   = nzb_s_outer + 2
    ELSE
       nzb_diff_s_inner   = nzb_s_inner + 1
       nzb_diff_s_outer   = nzb_s_outer + 1
    ENDIF

!
!-- Set-up topography flags. First, set flags only for s, u, v and w-grid.
!-- Further special flags will be set in following loops. 
    wall_flags_0 = 0
    DO  j = nys, nyn
       DO  i = nxl, nxr
          DO  k = nzb, nzt+1
!
!--          scalar grid
             IF ( BTEST( topo_3d(k,j,i), 0 ) )                                 &
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 0 )
!
!--          v grid
             IF ( BTEST( topo_3d(k,j,i),   0 )  .AND.                          &
                  BTEST( topo_3d(k,j-1,i), 0 ) )                               &
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 2 )
!
!--     To do: set outer arrays on basis of topo_3d array, adjust for downward-facing walls
!--          s grid outer array
             IF ( k >= nzb_s_outer(j,i) )                                      &
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 24 )
!
!--          s grid outer array
             IF ( k >= nzb_u_outer(j,i) )                                      &
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 26 )
!
!--          s grid outer array
             IF ( k >= nzb_v_outer(j,i) )                                      &
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 27 )
!
!--          w grid outer array
             IF ( k >= nzb_w_outer(j,i) )                                      &
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 28 )
          ENDDO

          DO k = nzb, nzt
!
!--          w grid
             IF ( BTEST( topo_3d(k,j,i),   0 )  .AND.                          &
                  BTEST( topo_3d(k+1,j,i), 0 ) )                               &
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 3 )
          ENDDO
          wall_flags_0(nzt+1,j,i) = IBSET( wall_flags_0(nzt+1,j,i), 3 )

       ENDDO
    ENDDO
!
!-- u grid. Note, reverse 
!-- memory access is required for setting flag on u-grid
    DO  j = nys, nyn
       DO  i = nxl, nxr
          DO k = nzb, nzt+1
             IF ( BTEST( topo_3d(k,j,i),   0 )  .AND.                          &
                  BTEST( topo_3d(k,j,i-1), 0 ) )                               &
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 1 )
          ENDDO
       ENDDO
    ENDDO
!
!-- Set further special flags
    DO i = nxl, nxr
       DO j = nys, nyn
          DO k = nzb, nzt+1
!
!--          scalar grid, former nzb_diff_s_inner.
!--          Note, use this flag also to mask topography in diffusion_u and 
!--          diffusion_v along the vertical direction. In case of 
!--          use_surface_fluxes, fluxes are calculated via MOST, else, simple
!--          gradient approach is applied. Please note, in case of u- and v-
!--          diffuison, a small error is made at edges (on the east side for u,
!--          at the north side for v), since topography on scalar grid point
!--          is used instead of topography on u/v-grid. As number of topography grid
!--          points on uv-grid is different than s-grid, different number of 
!--          surface elements would be required. In order to avoid this, 
!--          treat edges (u(k,j,i+1)) simply by a gradient approach, i.e. these
!--          points are not masked within diffusion_u. Tests had shown that the
!--          effect on the flow is negligible. 
             IF ( constant_flux_layer  .OR.  use_surface_fluxes )  THEN
                IF ( BTEST( wall_flags_0(k,j,i), 0 ) )                         &
                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 8 )
             ELSE
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 8 )
             ENDIF

          ENDDO
!
!--       Special flag to control vertical diffusion at model top - former 
!--       nzt_diff
          wall_flags_0(:,j,i) = IBSET( wall_flags_0(:,j,i), 9 )
          IF ( use_top_fluxes )                                                &
             wall_flags_0(nzt+1,j,i) = IBCLR( wall_flags_0(nzt+1,j,i), 9 )

          DO k = nzb+1, nzt
!
!--          Special flag on u grid, former nzb_u_inner + 1, required   
!--          for disturb_field and initialization. Do not disturb directly at
!--          topography, as well as initialize u with zero one grid point outside
!--          of topography.
             IF ( BTEST( wall_flags_0(k-1,j,i), 1 )  .AND.                     &
                  BTEST( wall_flags_0(k,j,i),   1 )  .AND.                     &
                  BTEST( wall_flags_0(k+1,j,i), 1 ) )                          &
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 20 )
!
!--          Special flag on v grid, former nzb_v_inner + 1, required   
!--          for disturb_field and initialization. Do not disturb directly at
!--          topography, as well as initialize v with zero one grid point outside
!--          of topography.
             IF ( BTEST( wall_flags_0(k-1,j,i), 2 )  .AND.                     &
                  BTEST( wall_flags_0(k,j,i),   2 )  .AND.                     &
                  BTEST( wall_flags_0(k+1,j,i), 2 ) )                          &
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 21 )
!
!--          Special flag on scalar grid, former nzb_s_inner+1. Used for 
!--          lpm_sgs_tke
             IF ( BTEST( wall_flags_0(k,j,i),   0 )  .AND.                     &
                  BTEST( wall_flags_0(k-1,j,i), 0 )  .AND.                     &
                  BTEST( wall_flags_0(k+1,j,i), 0 ) )                          &
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 25 )
!
!--          Special flag on scalar grid, nzb_diff_s_outer - 1, required in 
!--          in production_e
             IF ( constant_flux_layer  .OR.  use_surface_fluxes )  THEN
                IF ( BTEST( wall_flags_0(k,j,i),   24 )  .AND.                 &
                     BTEST( wall_flags_0(k-1,j,i), 24 )  .AND.                 &
                     BTEST( wall_flags_0(k+1,j,i), 0 ) )                       &
                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 29 )
             ELSE
                IF ( BTEST( wall_flags_0(k,j,i), 0 ) )                         &
                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 29 )
             ENDIF
!
!--          Special flag on scalar grid, nzb_diff_s_outer - 1, required in 
!--          in production_e
             IF ( constant_flux_layer  .OR.  use_surface_fluxes )  THEN
                IF ( BTEST( wall_flags_0(k,j,i),   0 )  .AND.                  &
                     BTEST( wall_flags_0(k-1,j,i), 0 )  .AND.                  &
                     BTEST( wall_flags_0(k+1,j,i), 0 ) )                       &
                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 30 )
             ELSE
                IF ( BTEST( wall_flags_0(k,j,i), 0 ) )                         &
                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 30 )
             ENDIF
          ENDDO
!
!--       Flags indicating downward facing walls
          DO k = nzb+1, nzt
!
!--          Scalar grid
             IF ( BTEST( wall_flags_0(k-1,j,i), 0 )  .AND.                     &
            .NOT. BTEST( wall_flags_0(k,j,i), 0   ) )                          & 
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 13 ) 
!
!--          Downward facing wall on u grid
             IF ( BTEST( wall_flags_0(k-1,j,i), 1 )  .AND.                     &
            .NOT. BTEST( wall_flags_0(k,j,i), 1   ) )                          & 
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 15 )
!
!--          Downward facing wall on v grid
             IF ( BTEST( wall_flags_0(k-1,j,i), 2 )  .AND.                     &
            .NOT. BTEST( wall_flags_0(k,j,i), 2   ) )                          & 
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 17 )
!
!--          Downward facing wall on w grid
             IF ( BTEST( wall_flags_0(k-1,j,i), 3 )  .AND.                     &
            .NOT. BTEST( wall_flags_0(k,j,i), 3 ) )                            & 
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 19 )
          ENDDO
!
!--       Flags indicating upward facing walls
          DO k = nzb, nzt
!
!--          Upward facing wall on scalar grid
             IF ( .NOT. BTEST( wall_flags_0(k,j,i),   0 )  .AND.               &
                        BTEST( wall_flags_0(k+1,j,i), 0 ) )                    & 
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 12 )
!
!--          Upward facing wall on u grid
             IF ( .NOT. BTEST( wall_flags_0(k,j,i),   1 )  .AND.               &
                        BTEST( wall_flags_0(k+1,j,i), 1 ) )                    & 
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 14 )

!
!--          Upward facing wall on v grid
             IF ( .NOT. BTEST( wall_flags_0(k,j,i),   2 )  .AND.               &
                        BTEST( wall_flags_0(k+1,j,i), 2 ) )                    & 
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 16 )

!
!--          Upward facing wall on w grid
             IF ( .NOT. BTEST( wall_flags_0(k,j,i),   3 )  .AND.               &
                        BTEST( wall_flags_0(k+1,j,i), 3 ) )                    & 
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 18 )
!
!--          Special flag on scalar grid, former nzb_s_inner
             IF ( BTEST( wall_flags_0(k,j,i), 0 )  .OR.                        &
                  BTEST( wall_flags_0(k,j,i), 12 ) .OR.                        &
                  BTEST( wall_flags_0(k,j,i), 13 ) )                           &
                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 22 )
!
!--          Special flag on scalar grid, nzb_diff_s_inner - 1, required for 
!--          flow_statistics
             IF ( constant_flux_layer  .OR.  use_surface_fluxes )  THEN
                IF ( BTEST( wall_flags_0(k,j,i),   0 )  .AND.                  &
                     BTEST( wall_flags_0(k+1,j,i), 0 ) )                       &
                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 23 )
             ELSE
                IF ( BTEST( wall_flags_0(k,j,i), 22 ) )                        &
                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 23 )
             ENDIF


          ENDDO
          wall_flags_0(nzt+1,j,i) = IBSET( wall_flags_0(nzt+1,j,i), 22 )
          wall_flags_0(nzt+1,j,i) = IBSET( wall_flags_0(nzt+1,j,i), 23 )
       ENDDO
    ENDDO
!
!-- Exchange ghost points for wall flags
    CALL exchange_horiz_int( wall_flags_0, nbgp )
!
!-- Set boundary conditions also for flags. Can be interpreted as Neumann
!-- boundary conditions for topography. 
    IF ( .NOT. bc_ns_cyc )  THEN
       IF ( nys == 0  )  wall_flags_0(:,-1,:)   = wall_flags_0(:,0,:)
       IF ( nyn == ny )  wall_flags_0(:,ny+1,:) = wall_flags_0(:,ny,:)
    ENDIF
    IF ( .NOT. bc_lr_cyc )  THEN
       IF ( nxl == 0  )  wall_flags_0(:,:,-1)   = wall_flags_0(:,:,0)
       IF ( nxr == nx )  wall_flags_0(:,:,nx+1) = wall_flags_0(:,:,nx)           
    ENDIF

!
!-- Initialize boundary conditions via surface type
    CALL init_bc
!
!-- Allocate and set topography height arrays required for data output
    IF ( TRIM( topography ) /= 'flat' )  THEN
!
!--    Allocate and set the arrays containing the topography height

       IF ( nxr == nx  .AND.  nyn /= ny )  THEN
          ALLOCATE( zu_s_inner(nxl:nxr+1,nys:nyn),                             &
                    zw_w_inner(nxl:nxr+1,nys:nyn) )
       ELSEIF ( nxr /= nx  .AND.  nyn == ny )  THEN
          ALLOCATE( zu_s_inner(nxl:nxr,nys:nyn+1),                             &
                    zw_w_inner(nxl:nxr,nys:nyn+1) )
       ELSEIF ( nxr == nx  .AND.  nyn == ny )  THEN
          ALLOCATE( zu_s_inner(nxl:nxr+1,nys:nyn+1),                           &
                    zw_w_inner(nxl:nxr+1,nys:nyn+1) )
       ELSE
          ALLOCATE( zu_s_inner(nxl:nxr,nys:nyn),                               &
                    zw_w_inner(nxl:nxr,nys:nyn) )
       ENDIF

       zu_s_inner   = 0.0_wp
       zw_w_inner   = 0.0_wp
!
!--    Determine local topography height on scalar and w-grid. Note, setting
!--    lateral boundary values is not necessary, realized via wall_flags_0 
!--    array. Further, please note that loop bounds are different from 
!--    nxl to nxr and nys to nyn on south and right model boundary, hence, 
!--    use intrinsic lbound and ubound functions to infer array bounds.
       DO  i = LBOUND(zu_s_inner, 1), UBOUND(zu_s_inner, 1)
          DO  j = LBOUND(zu_s_inner, 2), UBOUND(zu_s_inner, 2)
!
!--          Topography height on scalar grid. Therefore, determine index of 
!--          upward-facing surface element on scalar grid. 
             zu_s_inner(i,j) = zu( get_topography_top_index( j, i, 's' ) )
!
!--          Topography height on w grid. Therefore, determine index of 
!--          upward-facing surface element on w grid.
             zw_w_inner(i,j) = zw( get_topography_top_index( j, i, 's' ) )
          ENDDO
       ENDDO

    ENDIF

!
!-- Calculate wall flag arrays for the multigrid method.
!-- Please note, wall flags are only applied in the not cache-optimized 
!-- version.
    IF ( psolver == 'multigrid_noopt' )  THEN

!
!--    Gridpoint increment of the current level. 
       inc = 1
       DO  l = maximum_grid_level, 1 , -1
!
!--       Set grid_level as it is required for exchange_horiz_2d_int
          grid_level = l

          nxl_l = nxl_mg(l)
          nxr_l = nxr_mg(l)
          nys_l = nys_mg(l)
          nyn_l = nyn_mg(l)
          nzt_l = nzt_mg(l)
!
!--       Assign the flag level to be calculated
          SELECT CASE ( l )
             CASE ( 1 )
                flags => wall_flags_1
             CASE ( 2 )
                flags => wall_flags_2
             CASE ( 3 )
                flags => wall_flags_3
             CASE ( 4 )
                flags => wall_flags_4
             CASE ( 5 )
                flags => wall_flags_5
             CASE ( 6 )
                flags => wall_flags_6
             CASE ( 7 )
                flags => wall_flags_7
             CASE ( 8 )
                flags => wall_flags_8
             CASE ( 9 )
                flags => wall_flags_9
             CASE ( 10 )
                flags => wall_flags_10
          END SELECT

!
!--       Depending on the grid level, set the respective bits in case of
!--       neighbouring walls
!--       Bit 0:  wall to the bottom
!--       Bit 1:  wall to the top (not realized in remaining PALM code so far)
!--       Bit 2:  wall to the south
!--       Bit 3:  wall to the north
!--       Bit 4:  wall to the left
!--       Bit 5:  wall to the right
!--       Bit 6:  inside building

          flags = 0

!
!--       In case of masking method, flags are not set and multigrid method
!--       works like FFT-solver
          IF ( .NOT. masking_method )  THEN

!
!--          Allocate temporary array for topography heights on coarser grid
!--          level. Please note, 2 ghoist points are required, in order to
!--          calculate flags() on the interior ghost point. 
             ALLOCATE( nzb_tmp(nys_l-2:nyn_l+2,nxl_l-2:nxr_l+2) )
             nzb_tmp = 0
             
             DO  i = nxl_l, nxr_l
                DO  j = nys_l, nyn_l
                   nzb_tmp(j,i) = nzb_local(j*inc,i*inc)
                ENDDO
             ENDDO
!
!--          Exchange ghost points on respective multigrid level. 2 ghost points
!--          are required, in order to calculate flags on 
!--          nys_l-1 / nyn_l+1 / nxl_l-1 / nxr_l+1. The alternative would be to 
!--          exchange 3D-INTEGER array flags on the respective multigrid level.
             CALL exchange_horiz_2d_int( nzb_tmp, nys_l, nyn_l, nxl_l, nxr_l, 2 )
!
!--          Set non-cyclic boundary conditions on respective multigrid level
             IF ( .NOT. bc_ns_cyc )  THEN
                IF ( inflow_s .OR. outflow_s .OR. nest_bound_s  )  THEN
                   nzb_tmp(-2,:) = nzb_tmp(0,:)
                   nzb_tmp(-1,:) = nzb_tmp(0,:)
                ENDIF
                IF ( inflow_n .OR. outflow_n .OR. nest_bound_n )  THEN
                   nzb_tmp(nyn_l+2,:) = nzb_tmp(nyn_l,:)
                   nzb_tmp(nyn_l+1,:) = nzb_tmp(nyn_l,:)
                ENDIF
             ENDIF
             IF ( .NOT. bc_lr_cyc )  THEN
                IF ( inflow_l .OR. outflow_l .OR. nest_bound_l  )  THEN
                   nzb_tmp(:,-2) = nzb_tmp(:,0)
                   nzb_tmp(:,-1) = nzb_tmp(:,0)
                ENDIF
                IF ( inflow_r .OR. outflow_r .OR. nest_bound_r )  THEN
                   nzb_tmp(:,nxr_l+1) = nzb_tmp(:,nxr_l)    
                   nzb_tmp(:,nxr_l+2) = nzb_tmp(:,nxr_l)      
                ENDIF        
             ENDIF
                       
             DO  i = nxl_l-1, nxr_l+1
                DO  j = nys_l-1, nyn_l+1
                   DO  k = nzb, nzt_l+1     
!
!--                   Inside/outside building (inside building does not need
!--                   further tests for walls)
                      IF ( k*inc <= nzb_tmp(j,i) )  THEN

                         flags(k,j,i) = IBSET( flags(k,j,i), 6 )

                      ELSE
!
!--                      Bottom wall
                         IF ( (k-1)*inc <= nzb_tmp(j,i) )  THEN
                            flags(k,j,i) = IBSET( flags(k,j,i), 0 )
                         ENDIF
!
!--                      South wall
                         IF ( k*inc <= nzb_tmp(j-1,i) )  THEN
                            flags(k,j,i) = IBSET( flags(k,j,i), 2 )
                         ENDIF
!
!--                      North wall
                         IF ( k*inc <= nzb_tmp(j+1,i) )  THEN
                            flags(k,j,i) = IBSET( flags(k,j,i), 3 )
                         ENDIF
!
!--                      Left wall
                         IF ( k*inc <= nzb_tmp(j,i-1) )  THEN
                            flags(k,j,i) = IBSET( flags(k,j,i), 4 )
                         ENDIF
!
!--                      Right wall
                         IF ( k*inc <= nzb_tmp(j,i+1) )  THEN
                            flags(k,j,i) = IBSET( flags(k,j,i), 5 )
                         ENDIF

                      ENDIF
                            
                   ENDDO
                ENDDO
             ENDDO

             DEALLOCATE( nzb_tmp )

          ENDIF

          inc = inc * 2

       ENDDO
!
!--    Reset grid_level to "normal" grid
       grid_level = 0
       
    ENDIF
!
!-- Allocate flags needed for masking walls. Even though these flags are only
!-- required in the ws-scheme, the arrays need to be allocated here as they are 
!-- used in OpenACC directives. 
    ALLOCATE( advc_flags_1(nzb:nzt+1,nysg:nyng,nxlg:nxrg),                     &
              advc_flags_2(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
    advc_flags_1 = 0
    advc_flags_2 = 0
!
!-- Init flags for ws-scheme to degrade order of the numerics near walls, i.e. 
!-- to decrease the numerical stencil appropriately.
    IF ( momentum_advec == 'ws-scheme'  .OR.  scalar_advec == 'ws-scheme'      &
       )  THEN
       CALL ws_init_flags
    ENDIF

!
!-- In case of topography: limit near-wall mixing length l_wall further:
!-- Go through all points of the subdomain one by one and look for the closest
!-- surface
    DO  i = nxl, nxr
       DO  j = nys, nyn
          DO  k = nzb+1, nzt
!
!--          Check if current gridpoint belongs to the atmosphere
             IF ( BTEST( wall_flags_0(k,j,i), 0 ) )  THEN
!
!--             Check for neighbouring grid-points.
!--             Vertical distance, down
                IF ( .NOT. BTEST( wall_flags_0(k-1,j,i), 0 ) )                 &
                   l_wall(k,j,i) = MIN( l_grid(k), zu(k) - zw(k-1) )
!
!--             Vertical distance, up
                IF ( .NOT. BTEST( wall_flags_0(k+1,j,i), 0 ) )                 &
                   l_wall(k,j,i) = MIN( l_grid(k), zw(k) - zu(k) )
!
!--             y-distance
                IF ( .NOT. BTEST( wall_flags_0(k,j-1,i), 0 )  .OR.             &
                     .NOT. BTEST( wall_flags_0(k,j+1,i), 0 ) )                 &
                   l_wall(k,j,i) = MIN( l_wall(k,j,i), l_grid(k), 0.5_wp * dy )
!
!--             x-distance
                IF ( .NOT. BTEST( wall_flags_0(k,j,i-1), 0 )  .OR.             &
                     .NOT. BTEST( wall_flags_0(k,j,i+1), 0 ) )                 &
                   l_wall(k,j,i) = MIN( l_wall(k,j,i), l_grid(k), 0.5_wp * dx )
!
!--              yz-distance (vertical edges, down)
                 IF ( .NOT. BTEST( wall_flags_0(k-1,j-1,i), 0 )  .OR.          &
                      .NOT. BTEST( wall_flags_0(k-1,j+1,i), 0 )  )             &
                   l_wall(k,j,i) = MIN( l_wall(k,j,i), l_grid(k),              &
                                        SQRT( 0.25_wp * dy**2 +                &
                                       ( zu(k) - zw(k-1) )**2 ) )
!
!--              yz-distance (vertical edges, up)
                 IF ( .NOT. BTEST( wall_flags_0(k+1,j-1,i), 0 )  .OR.          &
                      .NOT. BTEST( wall_flags_0(k+1,j+1,i), 0 )  )             &
                   l_wall(k,j,i) = MIN( l_wall(k,j,i), l_grid(k),              &
                                        SQRT( 0.25_wp * dy**2 +                &
                                       ( zw(k) - zu(k) )**2 ) )
!
!--              xz-distance (vertical edges, down)
                 IF ( .NOT. BTEST( wall_flags_0(k-1,j,i-1), 0 )  .OR.          &
                      .NOT. BTEST( wall_flags_0(k-1,j,i+1), 0 )  )             &
                   l_wall(k,j,i) = MIN( l_wall(k,j,i), l_grid(k),              &
                                        SQRT( 0.25_wp * dx**2 +                &
                                       ( zu(k) - zw(k-1) )**2 ) )
!
!--              xz-distance (vertical edges, up)
                 IF ( .NOT. BTEST( wall_flags_0(k+1,j,i-1), 0 )  .OR.          &
                      .NOT. BTEST( wall_flags_0(k+1,j,i+1), 0 )  )             &
                   l_wall(k,j,i) = MIN( l_wall(k,j,i), l_grid(k),              &
                                        SQRT( 0.25_wp * dx**2 +                &
                                       ( zw(k) - zu(k) )**2 ) )
!
!--             xy-distance (horizontal edges)
                IF ( .NOT. BTEST( wall_flags_0(k,j-1,i-1), 0 )  .OR.           &
                     .NOT. BTEST( wall_flags_0(k,j+1,i-1), 0 )  .OR.           &
                     .NOT. BTEST( wall_flags_0(k,j-1,i+1), 0 )  .OR.           &
                     .NOT. BTEST( wall_flags_0(k,j+1,i+1), 0 ) )               &
                   l_wall(k,j,i) = MIN( l_wall(k,j,i), l_grid(k),              &
                                        SQRT( 0.25_wp * ( dx**2 + dy**2 ) ) )
!
!--             xyz distance (vertical and horizontal edges, down)
                IF ( .NOT. BTEST( wall_flags_0(k-1,j-1,i-1), 0 )  .OR.         &
                     .NOT. BTEST( wall_flags_0(k-1,j+1,i-1), 0 )  .OR.         &
                     .NOT. BTEST( wall_flags_0(k-1,j-1,i+1), 0 )  .OR.         &
                     .NOT. BTEST( wall_flags_0(k-1,j+1,i+1), 0 ) )             &
                   l_wall(k,j,i) = MIN( l_wall(k,j,i), l_grid(k),              &
                                        SQRT( 0.25_wp * ( dx**2 + dy**2 )      &
                                              +  ( zu(k) - zw(k-1) )**2  ) )
!
!--             xyz distance (vertical and horizontal edges, up)
                IF ( .NOT. BTEST( wall_flags_0(k+1,j-1,i-1), 0 )  .OR.         &
                     .NOT. BTEST( wall_flags_0(k+1,j+1,i-1), 0 )  .OR.         &
                     .NOT. BTEST( wall_flags_0(k+1,j-1,i+1), 0 )  .OR.         &
                     .NOT. BTEST( wall_flags_0(k+1,j+1,i+1), 0 ) )             &
                   l_wall(k,j,i) = MIN( l_wall(k,j,i), l_grid(k),              &
                                        SQRT( 0.25_wp * ( dx**2 + dy**2 )      &
                                              +  ( zw(k) - zu(k) )**2  ) )
                  
             ENDIF
          ENDDO
       ENDDO
    ENDDO
!
!-- Set lateral boundary conditions for l_wall
    CALL exchange_horiz( l_wall, nbgp )     

!
!-- Vertical nesting: communicate vertical grid level arrays between fine and
!-- coarse grid
    IF ( vnested )  CALL vnest_init_grid

 END SUBROUTINE init_grid