source: palm/trunk/SOURCE/timestep_scheme_steering.f90 @ 1001

 SUBROUTINE timestep_scheme_steering

!------------------------------------------------------------------------------!
! Current revisions:
! ------------------
! all actions concerning leapfrog scheme removed
!
! Former revisions:
! -----------------
! $Id: timestep_scheme_steering.f90 1001 2012-09-13 14:08:46Z raasch $
!
! 673 2011-01-18 16:19:48Z suehring
! No pressure term during time integration (tsc(4)=0.0).
!
! RCS Log replace by Id keyword, revision history cleaned up
!
! Revision 1.2  2005/03/26 21:17:06  raasch
! No pressure term for Runge-Kutta-schemes (tsc(4)=0.0)
!
! Revision 1.1  2004/01/28 15:34:47  raasch
! Initial revision
!
!
! Description:
! ------------
! Depending on the timestep scheme set the steering factors for the prognostic
! equations.
!------------------------------------------------------------------------------!

    USE control_parameters

    IMPLICIT NONE


    IF ( timestep_scheme(1:5) == 'runge' )  THEN
!
!--    Runge-Kutta schemes (here the factors depend on the respective
!--    intermediate step)
       IF ( timestep_scheme == 'runge-kutta-2' )  THEN
          IF ( intermediate_timestep_count == 1 )  THEN
             tsc(1:5) = (/ 1.0, 1.0,  0.0, 0.0, 0.0 /)
          ELSE
             tsc(1:5) = (/ 1.0, 0.5, -0.5, 0.0, 1.0 /)
          ENDIF
       ELSE
          IF ( intermediate_timestep_count == 1 )  THEN
             tsc(1:5) = (/ 1.0,   1.0/3.0,        0.0, 0.0, 0.0 /)
          ELSEIF ( intermediate_timestep_count == 2 )  THEN
             tsc(1:5) = (/ 1.0, 15.0/16.0, -25.0/48.0, 0.0, 0.0 /)
          ELSE
             tsc(1:5) = (/ 1.0,  8.0/15.0,   1.0/15.0, 0.0, 1.0 /)
          ENDIF          
       ENDIF

    ELSEIF ( timestep_scheme == 'euler' )  THEN
!
!--    Euler scheme
       tsc(1:5) = (/ 1.0, 1.0, 0.0, 0.0, 1.0 /)

    ENDIF


 END SUBROUTINE timestep_scheme_steering