source: palm/trunk/SOURCE/time_integration.f90 @ 1019

Last change on this file since 1019 was 1019, checked in by raasch, 9 years ago

subroutine prognostic_equations_noopt has been removed

  • Property svn:keywords set to Id
File size: 21.1 KB
Line 
1 SUBROUTINE time_integration
2
3!------------------------------------------------------------------------------!
4! Current revisions:
5! -----------------
6! non-optimized version of prognostic_equations removed
7!
8! Former revisions:
9! -----------------
10! $Id: time_integration.f90 1019 2012-09-28 06:46:45Z raasch $
11!
12! 1015 2012-09-27 09:23:24Z raasch
13! +call of prognostic_equations_acc
14!
15! 1001 2012-09-13 14:08:46Z raasch
16! all actions concerning leapfrog- and upstream-spline-scheme removed
17!
18! 849 2012-03-15 10:35:09Z raasch
19! advec_particles renamed lpm, first_call_advec_particles renamed first_call_lpm
20!
21! 825 2012-02-19 03:03:44Z raasch
22! wang_collision_kernel renamed wang_kernel
23!
24! 790 2011-11-29 03:11:20Z raasch
25! exchange of ghostpoints for array diss
26!
27! 707 2011-03-29 11:39:40Z raasch
28! bc_lr/ns replaced by bc_lr/ns_cyc, calls of exchange_horiz are modified,
29! adaption to sloping surface
30!
31! 667  2010-12-23 12:06:00Z suehring/gryschka
32! Calls of exchange_horiz are modified.
33! Adaption to slooping surface.
34!
35! 449 2010-02-02 11:23:59Z raasch
36! Bugfix: exchange of ghost points for prho included
37!
38! 410 2009-12-04 17:05:40Z letzel
39! masked data output
40!
41! 388 2009-09-23 09:40:33Z raasch
42! Using prho instead of rho in diffusvities.
43! Coupling with independent precursor runs.
44! Bugfix: output of particle time series only if particle advection is switched
45!         on
46!
47! 151 2008-03-07 13:42:18Z raasch
48! inflow turbulence is imposed by calling new routine inflow_turbulence
49!
50! 108 2007-08-24 15:10:38Z letzel
51! Call of new routine surface_coupler,
52! presure solver is called after the first Runge-Kutta substep instead of the
53! last in case that call_psolver_at_all_substeps = .F.; for this case, the
54! random perturbation has to be added to the velocity fields also after the
55! first substep
56!
57! 97 2007-06-21 08:23:15Z raasch
58! diffusivities is called with argument rho in case of ocean runs,
59! new argument pt_/prho_reference in calls of diffusivities,
60! ghostpoint exchange for salinity and density
61!
62! 87 2007-05-22 15:46:47Z raasch
63! var_hom renamed pr_palm
64!
65! 75 2007-03-22 09:54:05Z raasch
66! Move call of user_actions( 'after_integration' ) below increment of times
67! and counters,
68! calls of prognostic_equations_.. changed to .._noopt, .._cache, and
69! .._vector, these calls are now controlled by switch loop_optimization,
70! uxrp, vynp eliminated, 2nd+3rd argument removed from exchange horiz,
71! moisture renamed humidity
72!
73! RCS Log replace by Id keyword, revision history cleaned up
74!
75! Revision 1.8  2006/08/22 14:16:05  raasch
76! Disturbances are imposed only for the last Runge-Kutta-substep
77!
78! Revision 1.2  2004/04/30 13:03:40  raasch
79! decalpha-specific warning removed, routine name changed to time_integration,
80! particle advection is carried out only once during the intermediate steps,
81! impulse_advec renamed momentum_advec
82!
83! Revision 1.1  1997/08/11 06:19:04  raasch
84! Initial revision
85!
86!
87! Description:
88! ------------
89! Integration in time of the model equations, statistical analysis and graphic
90! output
91!------------------------------------------------------------------------------!
92
93    USE arrays_3d
94    USE averaging
95    USE control_parameters
96    USE cpulog
97#if defined( __dvrp_graphics )
98    USE DVRP
99#endif
100    USE grid_variables
101    USE indices
102    USE interaction_droplets_ptq_mod
103    USE interfaces
104    USE particle_attributes
105    USE pegrid
106    USE prognostic_equations_mod
107    USE statistics
108    USE user_actions_mod
109
110    IMPLICIT NONE
111
112    CHARACTER (LEN=9) ::  time_to_string
113    INTEGER ::  i, j, k
114
115!
116!-- At the beginning of a simulation determine the time step as well as
117!-- determine and print out the run control parameters
118    IF ( simulated_time == 0.0 )  CALL timestep
119
120    CALL run_control
121
122
123!
124!-- Data exchange between coupled models in case that a call has been omitted
125!-- at the end of the previous run of a job chain.
126    IF ( coupling_mode /= 'uncoupled'  .AND.  run_coupled )  THEN
127!
128!--    In case of model termination initiated by the local model the coupler
129!--    must not be called because this would again cause an MPI hang.
130       DO WHILE ( time_coupling >= dt_coupling .AND. terminate_coupled == 0 )
131          CALL surface_coupler
132          time_coupling = time_coupling - dt_coupling
133       ENDDO
134       IF (time_coupling == 0.0 .AND. time_since_reference_point < dt_coupling)&
135       THEN
136          time_coupling = time_since_reference_point
137       ENDIF
138    ENDIF
139
140
141#if defined( __dvrp_graphics )
142!
143!-- Time measurement with dvrp software 
144    CALL DVRP_LOG_EVENT( 2, current_timestep_number )
145#endif
146
147!
148!-- Start of the time loop
149    DO  WHILE ( simulated_time < end_time  .AND.  .NOT. stop_dt  .AND. &
150                .NOT. terminate_run )
151
152       CALL cpu_log( log_point_s(10), 'timesteps', 'start' )
153!
154!--    Determine size of next time step
155       IF ( simulated_time /= 0.0 )  CALL timestep
156!
157!--    Execute the user-defined actions
158       CALL user_actions( 'before_timestep' )
159
160!
161!--    Start of intermediate step loop
162       intermediate_timestep_count = 0
163       DO  WHILE ( intermediate_timestep_count < &
164                   intermediate_timestep_count_max )
165
166          intermediate_timestep_count = intermediate_timestep_count + 1
167
168!
169!--       Set the steering factors for the prognostic equations which depend
170!--       on the timestep scheme
171          CALL timestep_scheme_steering
172
173!
174!--       Solve the prognostic equations. A fast cache optimized version with
175!--       only one single loop is used in case of Piascek-Williams advection
176!--       scheme. NEC vector machines use a different version, because
177!--       in the other versions a good vectorization is prohibited due to
178!--       inlining problems.
179          IF ( loop_optimization == 'cache' )  THEN
180             CALL prognostic_equations_cache
181          ELSEIF ( loop_optimization == 'vector' )  THEN
182             CALL prognostic_equations_vector
183          ELSEIF ( loop_optimization == 'acc' )  THEN
184             CALL prognostic_equations_acc
185          ENDIF
186
187!
188!--       Particle transport/physics with the Lagrangian particle model
189!--       (only once during intermediate steps, because it uses an Euler-step)
190          IF ( particle_advection  .AND.                         &
191               simulated_time >= particle_advection_start  .AND. &
192               intermediate_timestep_count == 1 )  THEN
193             CALL lpm
194             first_call_lpm = .FALSE.
195          ENDIF
196
197!
198!--       Interaction of droplets with temperature and specific humidity.
199!--       Droplet condensation and evaporation is calculated within
200!--       advec_particles.
201          IF ( cloud_droplets  .AND.  &
202               intermediate_timestep_count == intermediate_timestep_count_max )&
203          THEN
204             CALL interaction_droplets_ptq
205          ENDIF
206
207!
208!--       Exchange of ghost points (lateral boundary conditions)
209          CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'start' )
210          CALL exchange_horiz( u_p, nbgp )
211          CALL exchange_horiz( v_p, nbgp )
212          CALL exchange_horiz( w_p, nbgp )
213          CALL exchange_horiz( pt_p, nbgp )
214          IF ( .NOT. constant_diffusion )  CALL exchange_horiz( e_p, nbgp )
215          IF ( ocean )  THEN
216             CALL exchange_horiz( sa_p, nbgp )
217             CALL exchange_horiz( rho, nbgp )
218             CALL exchange_horiz( prho, nbgp )
219          ENDIF
220          IF (humidity  .OR.  passive_scalar)  CALL exchange_horiz( q_p, nbgp )
221          IF ( cloud_droplets )  THEN
222             CALL exchange_horiz( ql, nbgp )
223             CALL exchange_horiz( ql_c, nbgp )
224             CALL exchange_horiz( ql_v, nbgp )
225             CALL exchange_horiz( ql_vp, nbgp )
226          ENDIF
227          IF ( wang_kernel )  CALL exchange_horiz( diss, nbgp )
228
229          CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'stop' )
230
231!
232!--       Boundary conditions for the prognostic quantities (except of the
233!--       velocities at the outflow in case of a non-cyclic lateral wall)
234          CALL boundary_conds( 'main' )
235
236!
237!--       Swap the time levels in preparation for the next time step.
238          CALL swap_timelevel
239
240!
241!--       Temperature offset must be imposed at cyclic boundaries in x-direction
242!--       when a sloping surface is used
243          IF ( sloping_surface )  THEN
244             IF ( nxl ==  0 )  pt(:,:,nxlg:nxl-1) = pt(:,:,nxlg:nxl-1) - &
245                                                    pt_slope_offset
246             IF ( nxr == nx )  pt(:,:,nxr+1:nxrg) = pt(:,:,nxr+1:nxrg) + &
247                                                    pt_slope_offset
248          ENDIF
249
250!
251!--       Impose a turbulent inflow using the recycling method
252          IF ( turbulent_inflow )  CALL  inflow_turbulence
253
254!
255!--       Impose a random perturbation on the horizontal velocity field
256          IF ( create_disturbances  .AND.                                      &
257               ( call_psolver_at_all_substeps  .AND.                           &
258               intermediate_timestep_count == intermediate_timestep_count_max )&
259          .OR. ( .NOT. call_psolver_at_all_substeps  .AND.                     &
260               intermediate_timestep_count == 1 ) )                            &
261          THEN
262             time_disturb = time_disturb + dt_3d
263             IF ( time_disturb >= dt_disturb )  THEN
264                IF ( hom(nzb+5,1,pr_palm,0) < disturbance_energy_limit )  THEN
265                   CALL disturb_field( nzb_u_inner, tend, u )
266                   CALL disturb_field( nzb_v_inner, tend, v )
267                ELSEIF ( .NOT. bc_lr_cyc  .OR.  .NOT. bc_ns_cyc )  THEN
268!
269!--                Runs with a non-cyclic lateral wall need perturbations
270!--                near the inflow throughout the whole simulation
271                   dist_range = 1
272                   CALL disturb_field( nzb_u_inner, tend, u )
273                   CALL disturb_field( nzb_v_inner, tend, v )
274                   dist_range = 0
275                ENDIF
276                time_disturb = time_disturb - dt_disturb
277             ENDIF
278          ENDIF
279
280!
281!--       Reduce the velocity divergence via the equation for perturbation
282!--       pressure.
283          IF ( intermediate_timestep_count == 1  .OR. &
284                call_psolver_at_all_substeps )  THEN
285             CALL pres
286          ENDIF
287!
288!--       Update device memory for calculating diffusion quantities and for next
289!--       timestep
290          !$acc update device( e, pt, u, v, w )
291          !$acc update device( q )  if ( allocated( q ) )
292
293!
294!--       If required, compute virtuell potential temperature
295          IF ( humidity )  THEN
296             CALL compute_vpt
297             !$acc update device( vpt )
298          ENDIF
299
300!
301!--       If required, compute liquid water content
302          IF ( cloud_physics )  THEN
303             CALL calc_liquid_water_content
304             !$acc update device( ql )
305          ENDIF
306
307!
308!--       Compute the diffusion quantities
309          IF ( .NOT. constant_diffusion )  THEN
310
311!
312!--          First the vertical fluxes in the Prandtl layer are being computed
313             IF ( prandtl_layer )  THEN
314                CALL cpu_log( log_point(19), 'prandtl_fluxes', 'start' )
315                CALL prandtl_fluxes
316                CALL cpu_log( log_point(19), 'prandtl_fluxes', 'stop' )
317!
318!++             Statistics still require updates on host
319                !$acc update host( qs, qsws, rif, shf, ts )
320             ENDIF
321
322!
323!--          Compute the diffusion coefficients
324             CALL cpu_log( log_point(17), 'diffusivities', 'start' )
325             IF ( .NOT. humidity ) THEN
326                IF ( ocean )  THEN
327                   CALL diffusivities( prho, prho_reference )
328                ELSE
329                   CALL diffusivities( pt, pt_reference )
330                ENDIF
331             ELSE
332                CALL diffusivities( vpt, pt_reference )
333             ENDIF
334             CALL cpu_log( log_point(17), 'diffusivities', 'stop' )
335!
336!++          Statistics still require update of diffusivities on host
337             !$acc update host( kh, km )
338
339          ENDIF
340
341       ENDDO   ! Intermediate step loop
342
343!
344!--    Increase simulation time and output times
345       current_timestep_number    = current_timestep_number + 1
346       simulated_time             = simulated_time   + dt_3d
347       simulated_time_chr         = time_to_string( simulated_time )
348       time_since_reference_point = simulated_time - coupling_start_time
349
350       IF ( simulated_time >= skip_time_data_output_av )  THEN
351          time_do_av         = time_do_av       + dt_3d
352       ENDIF
353       IF ( simulated_time >= skip_time_do2d_xy )  THEN
354          time_do2d_xy       = time_do2d_xy     + dt_3d
355       ENDIF
356       IF ( simulated_time >= skip_time_do2d_xz )  THEN
357          time_do2d_xz       = time_do2d_xz     + dt_3d
358       ENDIF
359       IF ( simulated_time >= skip_time_do2d_yz )  THEN
360          time_do2d_yz       = time_do2d_yz     + dt_3d
361       ENDIF
362       IF ( simulated_time >= skip_time_do3d    )  THEN
363          time_do3d          = time_do3d        + dt_3d
364       ENDIF
365       DO  mid = 1, masks
366          IF ( simulated_time >= skip_time_domask(mid) )  THEN
367             time_domask(mid)= time_domask(mid) + dt_3d
368          ENDIF
369       ENDDO
370       time_dvrp          = time_dvrp        + dt_3d
371       IF ( simulated_time >= skip_time_dosp )  THEN
372          time_dosp       = time_dosp        + dt_3d
373       ENDIF
374       time_dots          = time_dots        + dt_3d
375       IF ( .NOT. first_call_lpm )  THEN
376          time_dopts      = time_dopts       + dt_3d
377       ENDIF
378       IF ( simulated_time >= skip_time_dopr )  THEN
379          time_dopr       = time_dopr        + dt_3d
380       ENDIF
381       time_dopr_listing          = time_dopr_listing        + dt_3d
382       time_run_control   = time_run_control + dt_3d
383
384!
385!--    Data exchange between coupled models
386       IF ( coupling_mode /= 'uncoupled'  .AND.  run_coupled )  THEN
387          time_coupling = time_coupling + dt_3d
388
389!
390!--       In case of model termination initiated by the local model
391!--       (terminate_coupled > 0), the coupler must be skipped because it would
392!--       cause an MPI intercomminucation hang.
393!--       If necessary, the coupler will be called at the beginning of the
394!--       next restart run.
395          DO WHILE ( time_coupling >= dt_coupling .AND. terminate_coupled == 0 )
396             CALL surface_coupler
397             time_coupling = time_coupling - dt_coupling
398          ENDDO
399       ENDIF
400
401!
402!--    Execute user-defined actions
403       CALL user_actions( 'after_integration' )
404
405!
406!--    If Galilei transformation is used, determine the distance that the
407!--    model has moved so far
408       IF ( galilei_transformation )  THEN
409          advected_distance_x = advected_distance_x + u_gtrans * dt_3d
410          advected_distance_y = advected_distance_y + v_gtrans * dt_3d
411       ENDIF
412
413!
414!--    Check, if restart is necessary (because cpu-time is expiring or
415!--    because it is forced by user) and set stop flag
416!--    This call is skipped if the remote model has already initiated a restart.
417       IF ( .NOT. terminate_run )  CALL check_for_restart
418
419!
420!--    Carry out statistical analysis and output at the requested output times.
421!--    The MOD function is used for calculating the output time counters (like
422!--    time_dopr) in order to regard a possible decrease of the output time
423!--    interval in case of restart runs
424
425!
426!--    Set a flag indicating that so far no statistics have been created
427!--    for this time step
428       flow_statistics_called = .FALSE.
429
430!
431!--    If required, call flow_statistics for averaging in time
432       IF ( averaging_interval_pr /= 0.0  .AND.  &
433            ( dt_dopr - time_dopr ) <= averaging_interval_pr  .AND.  &
434            simulated_time >= skip_time_dopr )  THEN
435          time_dopr_av = time_dopr_av + dt_3d
436          IF ( time_dopr_av >= dt_averaging_input_pr )  THEN
437             do_sum = .TRUE.
438             time_dopr_av = MOD( time_dopr_av, &
439                                    MAX( dt_averaging_input_pr, dt_3d ) )
440          ENDIF
441       ENDIF
442       IF ( do_sum )  CALL flow_statistics
443
444!
445!--    Sum-up 3d-arrays for later output of time-averaged 2d/3d/masked data
446       IF ( averaging_interval /= 0.0  .AND.                                &
447            ( dt_data_output_av - time_do_av ) <= averaging_interval  .AND. &
448            simulated_time >= skip_time_data_output_av )                    &
449       THEN
450          time_do_sla = time_do_sla + dt_3d
451          IF ( time_do_sla >= dt_averaging_input )  THEN
452             CALL sum_up_3d_data
453             average_count_3d = average_count_3d + 1
454             time_do_sla = MOD( time_do_sla, MAX( dt_averaging_input, dt_3d ) )
455          ENDIF
456       ENDIF
457
458!
459!--    Calculate spectra for time averaging
460       IF ( averaging_interval_sp /= 0.0  .AND.  &
461            ( dt_dosp - time_dosp ) <= averaging_interval_sp  .AND.  &
462            simulated_time >= skip_time_dosp )  THEN
463          time_dosp_av = time_dosp_av + dt_3d
464          IF ( time_dosp_av >= dt_averaging_input_pr )  THEN
465             CALL calc_spectra
466             time_dosp_av = MOD( time_dosp_av, &
467                                 MAX( dt_averaging_input_pr, dt_3d ) )
468          ENDIF
469       ENDIF
470
471!
472!--    Computation and output of run control parameters.
473!--    This is also done whenever perturbations have been imposed
474       IF ( time_run_control >= dt_run_control  .OR.                     &
475            timestep_scheme(1:5) /= 'runge'  .OR.  disturbance_created ) &
476       THEN
477          CALL run_control
478          IF ( time_run_control >= dt_run_control )  THEN
479             time_run_control = MOD( time_run_control, &
480                                     MAX( dt_run_control, dt_3d ) )
481          ENDIF
482       ENDIF
483
484!
485!--    Profile output (ASCII) on file
486       IF ( time_dopr_listing >= dt_dopr_listing )  THEN
487          CALL print_1d
488          time_dopr_listing = MOD( time_dopr_listing, MAX( dt_dopr_listing, &
489                                                           dt_3d ) )
490       ENDIF
491
492!
493!--    Graphic output for PROFIL
494       IF ( time_dopr >= dt_dopr )  THEN
495          IF ( dopr_n /= 0 )  CALL data_output_profiles
496          time_dopr = MOD( time_dopr, MAX( dt_dopr, dt_3d ) )
497          time_dopr_av = 0.0    ! due to averaging (see above)
498       ENDIF
499
500!
501!--    Graphic output for time series
502       IF ( time_dots >= dt_dots )  THEN
503          CALL data_output_tseries
504          time_dots = MOD( time_dots, MAX( dt_dots, dt_3d ) )
505       ENDIF
506
507!
508!--    Output of spectra (formatted for use with PROFIL), in case of no
509!--    time averaging, spectra has to be calculated before
510       IF ( time_dosp >= dt_dosp )  THEN
511          IF ( average_count_sp == 0 )  CALL calc_spectra
512          CALL data_output_spectra
513          time_dosp = MOD( time_dosp, MAX( dt_dosp, dt_3d ) )
514       ENDIF
515
516!
517!--    2d-data output (cross-sections)
518       IF ( time_do2d_xy >= dt_do2d_xy )  THEN
519          CALL data_output_2d( 'xy', 0 )
520          time_do2d_xy = MOD( time_do2d_xy, MAX( dt_do2d_xy, dt_3d ) )
521       ENDIF
522       IF ( time_do2d_xz >= dt_do2d_xz )  THEN
523          CALL data_output_2d( 'xz', 0 )
524          time_do2d_xz = MOD( time_do2d_xz, MAX( dt_do2d_xz, dt_3d ) )
525       ENDIF
526       IF ( time_do2d_yz >= dt_do2d_yz )  THEN
527          CALL data_output_2d( 'yz', 0 )
528          time_do2d_yz = MOD( time_do2d_yz, MAX( dt_do2d_yz, dt_3d ) )
529       ENDIF
530
531!
532!--    3d-data output (volume data)
533       IF ( time_do3d >= dt_do3d )  THEN
534          CALL data_output_3d( 0 )
535          time_do3d = MOD( time_do3d, MAX( dt_do3d, dt_3d ) )
536       ENDIF
537
538!
539!--    masked data output
540       DO  mid = 1, masks
541          IF ( time_domask(mid) >= dt_domask(mid) )  THEN
542             CALL data_output_mask( 0 )
543             time_domask(mid) = MOD( time_domask(mid),  &
544                                     MAX( dt_domask(mid), dt_3d ) )
545          ENDIF
546       ENDDO
547
548!
549!--    Output of time-averaged 2d/3d/masked data
550       IF ( time_do_av >= dt_data_output_av )  THEN
551          CALL average_3d_data
552          CALL data_output_2d( 'xy', 1 )
553          CALL data_output_2d( 'xz', 1 )
554          CALL data_output_2d( 'yz', 1 )
555          CALL data_output_3d( 1 )
556          DO  mid = 1, masks
557             CALL data_output_mask( 1 )
558          ENDDO
559          time_do_av = MOD( time_do_av, MAX( dt_data_output_av, dt_3d ) )
560       ENDIF
561
562!
563!--    Output of particle time series
564       IF ( particle_advection )  THEN
565          IF ( time_dopts >= dt_dopts  .OR. &
566               ( simulated_time >= particle_advection_start  .AND. &
567                 first_call_lpm ) )  THEN
568             CALL data_output_ptseries
569             time_dopts = MOD( time_dopts, MAX( dt_dopts, dt_3d ) )
570          ENDIF
571       ENDIF
572
573!
574!--    Output of dvrp-graphics (isosurface, particles, slicer)
575#if defined( __dvrp_graphics )
576       CALL DVRP_LOG_EVENT( -2, current_timestep_number-1 )
577#endif
578       IF ( time_dvrp >= dt_dvrp )  THEN
579          CALL data_output_dvrp
580          time_dvrp = MOD( time_dvrp, MAX( dt_dvrp, dt_3d ) )
581       ENDIF
582#if defined( __dvrp_graphics )
583       CALL DVRP_LOG_EVENT( 2, current_timestep_number )
584#endif
585
586!
587!--    If required, set the heat flux for the next time step at a random value
588       IF ( constant_heatflux  .AND.  random_heatflux )  CALL disturb_heatflux
589
590!
591!--    Execute user-defined actions
592       CALL user_actions( 'after_timestep' )
593
594       CALL cpu_log( log_point_s(10), 'timesteps', 'stop' )
595
596
597    ENDDO   ! time loop
598
599#if defined( __dvrp_graphics )
600    CALL DVRP_LOG_EVENT( -2, current_timestep_number )
601#endif
602
603 END SUBROUTINE time_integration
Note: See TracBrowser for help on using the repository browser.