source: palm/trunk/SOURCE/time_integration.f90 @ 1001

Last change on this file since 1001 was 1001, checked in by raasch, 9 years ago

leapfrog timestep scheme and upstream-spline advection scheme completely removed from the code,
reading of dt_fixed from restart file removed

  • Property svn:keywords set to Id
File size: 20.4 KB
Line 
1 SUBROUTINE time_integration
2
3!------------------------------------------------------------------------------!
4! Current revisions:
5! -----------------
6! all actions concerning leapfrog- and upstream-spline-scheme removed
7!
8! Former revisions:
9! -----------------
10! $Id: time_integration.f90 1001 2012-09-13 14:08:46Z raasch $
11!
12! 849 2012-03-15 10:35:09Z raasch
13! advec_particles renamed lpm, first_call_advec_particles renamed first_call_lpm
14!
15! 825 2012-02-19 03:03:44Z raasch
16! wang_collision_kernel renamed wang_kernel
17!
18! 790 2011-11-29 03:11:20Z raasch
19! exchange of ghostpoints for array diss
20!
21! 707 2011-03-29 11:39:40Z raasch
22! bc_lr/ns replaced by bc_lr/ns_cyc, calls of exchange_horiz are modified,
23! adaption to sloping surface
24!
25! 667  2010-12-23 12:06:00Z suehring/gryschka
26! Calls of exchange_horiz are modified.
27! Adaption to slooping surface.
28!
29! 449 2010-02-02 11:23:59Z raasch
30! Bugfix: exchange of ghost points for prho included
31!
32! 410 2009-12-04 17:05:40Z letzel
33! masked data output
34!
35! 388 2009-09-23 09:40:33Z raasch
36! Using prho instead of rho in diffusvities.
37! Coupling with independent precursor runs.
38! Bugfix: output of particle time series only if particle advection is switched
39!         on
40!
41! 151 2008-03-07 13:42:18Z raasch
42! inflow turbulence is imposed by calling new routine inflow_turbulence
43!
44! 108 2007-08-24 15:10:38Z letzel
45! Call of new routine surface_coupler,
46! presure solver is called after the first Runge-Kutta substep instead of the
47! last in case that call_psolver_at_all_substeps = .F.; for this case, the
48! random perturbation has to be added to the velocity fields also after the
49! first substep
50!
51! 97 2007-06-21 08:23:15Z raasch
52! diffusivities is called with argument rho in case of ocean runs,
53! new argument pt_/prho_reference in calls of diffusivities,
54! ghostpoint exchange for salinity and density
55!
56! 87 2007-05-22 15:46:47Z raasch
57! var_hom renamed pr_palm
58!
59! 75 2007-03-22 09:54:05Z raasch
60! Move call of user_actions( 'after_integration' ) below increment of times
61! and counters,
62! calls of prognostic_equations_.. changed to .._noopt, .._cache, and
63! .._vector, these calls are now controlled by switch loop_optimization,
64! uxrp, vynp eliminated, 2nd+3rd argument removed from exchange horiz,
65! moisture renamed humidity
66!
67! RCS Log replace by Id keyword, revision history cleaned up
68!
69! Revision 1.8  2006/08/22 14:16:05  raasch
70! Disturbances are imposed only for the last Runge-Kutta-substep
71!
72! Revision 1.2  2004/04/30 13:03:40  raasch
73! decalpha-specific warning removed, routine name changed to time_integration,
74! particle advection is carried out only once during the intermediate steps,
75! impulse_advec renamed momentum_advec
76!
77! Revision 1.1  1997/08/11 06:19:04  raasch
78! Initial revision
79!
80!
81! Description:
82! ------------
83! Integration in time of the model equations, statistical analysis and graphic
84! output
85!------------------------------------------------------------------------------!
86
87    USE arrays_3d
88    USE averaging
89    USE control_parameters
90    USE cpulog
91#if defined( __dvrp_graphics )
92    USE DVRP
93#endif
94    USE grid_variables
95    USE indices
96    USE interaction_droplets_ptq_mod
97    USE interfaces
98    USE particle_attributes
99    USE pegrid
100    USE prognostic_equations_mod
101    USE statistics
102    USE user_actions_mod
103
104    IMPLICIT NONE
105
106    CHARACTER (LEN=9) ::  time_to_string
107    INTEGER ::  i, j, k
108
109!
110!-- At the beginning of a simulation determine the time step as well as
111!-- determine and print out the run control parameters
112    IF ( simulated_time == 0.0 )  CALL timestep
113
114    CALL run_control
115
116
117!
118!-- Data exchange between coupled models in case that a call has been omitted
119!-- at the end of the previous run of a job chain.
120    IF ( coupling_mode /= 'uncoupled'  .AND.  run_coupled )  THEN
121!
122!--    In case of model termination initiated by the local model the coupler
123!--    must not be called because this would again cause an MPI hang.
124       DO WHILE ( time_coupling >= dt_coupling .AND. terminate_coupled == 0 )
125          CALL surface_coupler
126          time_coupling = time_coupling - dt_coupling
127       ENDDO
128       IF (time_coupling == 0.0 .AND. time_since_reference_point < dt_coupling)&
129       THEN
130          time_coupling = time_since_reference_point
131       ENDIF
132    ENDIF
133
134
135#if defined( __dvrp_graphics )
136!
137!-- Time measurement with dvrp software 
138    CALL DVRP_LOG_EVENT( 2, current_timestep_number )
139#endif
140
141!
142!-- Start of the time loop
143    DO  WHILE ( simulated_time < end_time  .AND.  .NOT. stop_dt  .AND. &
144                .NOT. terminate_run )
145
146       CALL cpu_log( log_point_s(10), 'timesteps', 'start' )
147!
148!--    Determine size of next time step
149       IF ( simulated_time /= 0.0 )  CALL timestep
150!
151!--    Execute the user-defined actions
152       CALL user_actions( 'before_timestep' )
153
154!
155!--    Start of intermediate step loop
156       intermediate_timestep_count = 0
157       DO  WHILE ( intermediate_timestep_count < &
158                   intermediate_timestep_count_max )
159
160          intermediate_timestep_count = intermediate_timestep_count + 1
161
162!
163!--       Set the steering factors for the prognostic equations which depend
164!--       on the timestep scheme
165          CALL timestep_scheme_steering
166
167!
168!--       Solve the prognostic equations. A fast cache optimized version with
169!--       only one single loop is used in case of Piascek-Williams advection
170!--       scheme. NEC vector machines use a different version, because
171!--       in the other versions a good vectorization is prohibited due to
172!--       inlining problems.
173          IF ( loop_optimization == 'vector' )  THEN
174             CALL prognostic_equations_vector
175          ELSE
176             IF ( scalar_advec == 'bc-scheme' )  THEN
177                CALL prognostic_equations_noopt
178             ELSE
179                CALL prognostic_equations_cache
180             ENDIF
181          ENDIF
182
183!
184!--       Particle transport/physics with the Lagrangian particle model
185!--       (only once during intermediate steps, because it uses an Euler-step)
186          IF ( particle_advection  .AND.                         &
187               simulated_time >= particle_advection_start  .AND. &
188               intermediate_timestep_count == 1 )  THEN
189             CALL lpm
190             first_call_lpm = .FALSE.
191          ENDIF
192
193!
194!--       Interaction of droplets with temperature and specific humidity.
195!--       Droplet condensation and evaporation is calculated within
196!--       advec_particles.
197          IF ( cloud_droplets  .AND.  &
198               intermediate_timestep_count == intermediate_timestep_count_max )&
199          THEN
200             CALL interaction_droplets_ptq
201          ENDIF
202
203!
204!--       Exchange of ghost points (lateral boundary conditions)
205          CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'start' )
206          CALL exchange_horiz( u_p, nbgp )
207          CALL exchange_horiz( v_p, nbgp )
208          CALL exchange_horiz( w_p, nbgp )
209          CALL exchange_horiz( pt_p, nbgp )
210          IF ( .NOT. constant_diffusion )  CALL exchange_horiz( e_p, nbgp )
211          IF ( ocean )  THEN
212             CALL exchange_horiz( sa_p, nbgp )
213             CALL exchange_horiz( rho, nbgp )
214             CALL exchange_horiz( prho, nbgp )
215          ENDIF
216          IF (humidity  .OR.  passive_scalar)  CALL exchange_horiz( q_p, nbgp )
217          IF ( cloud_droplets )  THEN
218             CALL exchange_horiz( ql, nbgp )
219             CALL exchange_horiz( ql_c, nbgp )
220             CALL exchange_horiz( ql_v, nbgp )
221             CALL exchange_horiz( ql_vp, nbgp )
222          ENDIF
223          IF ( wang_kernel )  CALL exchange_horiz( diss, nbgp )
224
225          CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'stop' )
226
227!
228!--       Boundary conditions for the prognostic quantities (except of the
229!--       velocities at the outflow in case of a non-cyclic lateral wall)
230          CALL boundary_conds( 'main' )
231
232!
233!--       Swap the time levels in preparation for the next time step.
234          CALL swap_timelevel
235
236!
237!--       Temperature offset must be imposed at cyclic boundaries in x-direction
238!--       when a sloping surface is used
239          IF ( sloping_surface )  THEN
240             IF ( nxl ==  0 )  pt(:,:,nxlg:nxl-1) = pt(:,:,nxlg:nxl-1) - &
241                                                    pt_slope_offset
242             IF ( nxr == nx )  pt(:,:,nxr+1:nxrg) = pt(:,:,nxr+1:nxrg) + &
243                                                    pt_slope_offset
244          ENDIF
245
246!
247!--       Impose a turbulent inflow using the recycling method
248          IF ( turbulent_inflow )  CALL  inflow_turbulence
249
250!
251!--       Impose a random perturbation on the horizontal velocity field
252          IF ( create_disturbances  .AND.                                      &
253               ( call_psolver_at_all_substeps  .AND.                           &
254               intermediate_timestep_count == intermediate_timestep_count_max )&
255          .OR. ( .NOT. call_psolver_at_all_substeps  .AND.                     &
256               intermediate_timestep_count == 1 ) )                            &
257          THEN
258             time_disturb = time_disturb + dt_3d
259             IF ( time_disturb >= dt_disturb )  THEN
260                IF ( hom(nzb+5,1,pr_palm,0) < disturbance_energy_limit )  THEN
261                   CALL disturb_field( nzb_u_inner, tend, u )
262                   CALL disturb_field( nzb_v_inner, tend, v )
263                ELSEIF ( .NOT. bc_lr_cyc  .OR.  .NOT. bc_ns_cyc )  THEN
264!
265!--                Runs with a non-cyclic lateral wall need perturbations
266!--                near the inflow throughout the whole simulation
267                   dist_range = 1
268                   CALL disturb_field( nzb_u_inner, tend, u )
269                   CALL disturb_field( nzb_v_inner, tend, v )
270                   dist_range = 0
271                ENDIF
272                time_disturb = time_disturb - dt_disturb
273             ENDIF
274          ENDIF
275
276!
277!--       Reduce the velocity divergence via the equation for perturbation
278!--       pressure.
279          IF ( intermediate_timestep_count == 1  .OR. &
280                call_psolver_at_all_substeps )  THEN
281             CALL pres
282          ENDIF
283
284!
285!--       If required, compute virtuell potential temperature
286          IF ( humidity ) CALL compute_vpt
287
288!
289!--       If required, compute liquid water content
290          IF ( cloud_physics ) CALL calc_liquid_water_content
291
292!
293!--       Compute the diffusion quantities
294          IF ( .NOT. constant_diffusion )  THEN
295
296!
297!--          First the vertical fluxes in the Prandtl layer are being computed
298             IF ( prandtl_layer )  THEN
299                CALL cpu_log( log_point(19), 'prandtl_fluxes', 'start' )
300                CALL prandtl_fluxes
301                CALL cpu_log( log_point(19), 'prandtl_fluxes', 'stop' )
302             ENDIF
303
304!
305!--          Compute the diffusion coefficients
306             CALL cpu_log( log_point(17), 'diffusivities', 'start' )
307             IF ( .NOT. humidity ) THEN
308                IF ( ocean )  THEN
309                   CALL diffusivities( prho, prho_reference )
310                ELSE
311                   CALL diffusivities( pt, pt_reference )
312                ENDIF
313             ELSE
314                CALL diffusivities( vpt, pt_reference )
315             ENDIF
316             CALL cpu_log( log_point(17), 'diffusivities', 'stop' )
317
318          ENDIF
319
320       ENDDO   ! Intermediate step loop
321
322!
323!--    Increase simulation time and output times
324       current_timestep_number    = current_timestep_number + 1
325       simulated_time             = simulated_time   + dt_3d
326       simulated_time_chr         = time_to_string( simulated_time )
327       time_since_reference_point = simulated_time - coupling_start_time
328
329       IF ( simulated_time >= skip_time_data_output_av )  THEN
330          time_do_av         = time_do_av       + dt_3d
331       ENDIF
332       IF ( simulated_time >= skip_time_do2d_xy )  THEN
333          time_do2d_xy       = time_do2d_xy     + dt_3d
334       ENDIF
335       IF ( simulated_time >= skip_time_do2d_xz )  THEN
336          time_do2d_xz       = time_do2d_xz     + dt_3d
337       ENDIF
338       IF ( simulated_time >= skip_time_do2d_yz )  THEN
339          time_do2d_yz       = time_do2d_yz     + dt_3d
340       ENDIF
341       IF ( simulated_time >= skip_time_do3d    )  THEN
342          time_do3d          = time_do3d        + dt_3d
343       ENDIF
344       DO  mid = 1, masks
345          IF ( simulated_time >= skip_time_domask(mid) )  THEN
346             time_domask(mid)= time_domask(mid) + dt_3d
347          ENDIF
348       ENDDO
349       time_dvrp          = time_dvrp        + dt_3d
350       IF ( simulated_time >= skip_time_dosp )  THEN
351          time_dosp       = time_dosp        + dt_3d
352       ENDIF
353       time_dots          = time_dots        + dt_3d
354       IF ( .NOT. first_call_lpm )  THEN
355          time_dopts      = time_dopts       + dt_3d
356       ENDIF
357       IF ( simulated_time >= skip_time_dopr )  THEN
358          time_dopr       = time_dopr        + dt_3d
359       ENDIF
360       time_dopr_listing          = time_dopr_listing        + dt_3d
361       time_run_control   = time_run_control + dt_3d
362
363!
364!--    Data exchange between coupled models
365       IF ( coupling_mode /= 'uncoupled'  .AND.  run_coupled )  THEN
366          time_coupling = time_coupling + dt_3d
367
368!
369!--       In case of model termination initiated by the local model
370!--       (terminate_coupled > 0), the coupler must be skipped because it would
371!--       cause an MPI intercomminucation hang.
372!--       If necessary, the coupler will be called at the beginning of the
373!--       next restart run.
374          DO WHILE ( time_coupling >= dt_coupling .AND. terminate_coupled == 0 )
375             CALL surface_coupler
376             time_coupling = time_coupling - dt_coupling
377          ENDDO
378       ENDIF
379
380!
381!--    Execute user-defined actions
382       CALL user_actions( 'after_integration' )
383
384!
385!--    If Galilei transformation is used, determine the distance that the
386!--    model has moved so far
387       IF ( galilei_transformation )  THEN
388          advected_distance_x = advected_distance_x + u_gtrans * dt_3d
389          advected_distance_y = advected_distance_y + v_gtrans * dt_3d
390       ENDIF
391
392!
393!--    Check, if restart is necessary (because cpu-time is expiring or
394!--    because it is forced by user) and set stop flag
395!--    This call is skipped if the remote model has already initiated a restart.
396       IF ( .NOT. terminate_run )  CALL check_for_restart
397
398!
399!--    Carry out statistical analysis and output at the requested output times.
400!--    The MOD function is used for calculating the output time counters (like
401!--    time_dopr) in order to regard a possible decrease of the output time
402!--    interval in case of restart runs
403
404!
405!--    Set a flag indicating that so far no statistics have been created
406!--    for this time step
407       flow_statistics_called = .FALSE.
408
409!
410!--    If required, call flow_statistics for averaging in time
411       IF ( averaging_interval_pr /= 0.0  .AND.  &
412            ( dt_dopr - time_dopr ) <= averaging_interval_pr  .AND.  &
413            simulated_time >= skip_time_dopr )  THEN
414          time_dopr_av = time_dopr_av + dt_3d
415          IF ( time_dopr_av >= dt_averaging_input_pr )  THEN
416             do_sum = .TRUE.
417             time_dopr_av = MOD( time_dopr_av, &
418                                    MAX( dt_averaging_input_pr, dt_3d ) )
419          ENDIF
420       ENDIF
421       IF ( do_sum )  CALL flow_statistics
422
423!
424!--    Sum-up 3d-arrays for later output of time-averaged 2d/3d/masked data
425       IF ( averaging_interval /= 0.0  .AND.                                &
426            ( dt_data_output_av - time_do_av ) <= averaging_interval  .AND. &
427            simulated_time >= skip_time_data_output_av )                    &
428       THEN
429          time_do_sla = time_do_sla + dt_3d
430          IF ( time_do_sla >= dt_averaging_input )  THEN
431             CALL sum_up_3d_data
432             average_count_3d = average_count_3d + 1
433             time_do_sla = MOD( time_do_sla, MAX( dt_averaging_input, dt_3d ) )
434          ENDIF
435       ENDIF
436
437!
438!--    Calculate spectra for time averaging
439       IF ( averaging_interval_sp /= 0.0  .AND.  &
440            ( dt_dosp - time_dosp ) <= averaging_interval_sp  .AND.  &
441            simulated_time >= skip_time_dosp )  THEN
442          time_dosp_av = time_dosp_av + dt_3d
443          IF ( time_dosp_av >= dt_averaging_input_pr )  THEN
444             CALL calc_spectra
445             time_dosp_av = MOD( time_dosp_av, &
446                                 MAX( dt_averaging_input_pr, dt_3d ) )
447          ENDIF
448       ENDIF
449
450!
451!--    Computation and output of run control parameters.
452!--    This is also done whenever perturbations have been imposed
453       IF ( time_run_control >= dt_run_control  .OR.                     &
454            timestep_scheme(1:5) /= 'runge'  .OR.  disturbance_created ) &
455       THEN
456          CALL run_control
457          IF ( time_run_control >= dt_run_control )  THEN
458             time_run_control = MOD( time_run_control, &
459                                     MAX( dt_run_control, dt_3d ) )
460          ENDIF
461       ENDIF
462
463!
464!--    Profile output (ASCII) on file
465       IF ( time_dopr_listing >= dt_dopr_listing )  THEN
466          CALL print_1d
467          time_dopr_listing = MOD( time_dopr_listing, MAX( dt_dopr_listing, &
468                                                           dt_3d ) )
469       ENDIF
470
471!
472!--    Graphic output for PROFIL
473       IF ( time_dopr >= dt_dopr )  THEN
474          IF ( dopr_n /= 0 )  CALL data_output_profiles
475          time_dopr = MOD( time_dopr, MAX( dt_dopr, dt_3d ) )
476          time_dopr_av = 0.0    ! due to averaging (see above)
477       ENDIF
478
479!
480!--    Graphic output for time series
481       IF ( time_dots >= dt_dots )  THEN
482          CALL data_output_tseries
483          time_dots = MOD( time_dots, MAX( dt_dots, dt_3d ) )
484       ENDIF
485
486!
487!--    Output of spectra (formatted for use with PROFIL), in case of no
488!--    time averaging, spectra has to be calculated before
489       IF ( time_dosp >= dt_dosp )  THEN
490          IF ( average_count_sp == 0 )  CALL calc_spectra
491          CALL data_output_spectra
492          time_dosp = MOD( time_dosp, MAX( dt_dosp, dt_3d ) )
493       ENDIF
494
495!
496!--    2d-data output (cross-sections)
497       IF ( time_do2d_xy >= dt_do2d_xy )  THEN
498          CALL data_output_2d( 'xy', 0 )
499          time_do2d_xy = MOD( time_do2d_xy, MAX( dt_do2d_xy, dt_3d ) )
500       ENDIF
501       IF ( time_do2d_xz >= dt_do2d_xz )  THEN
502          CALL data_output_2d( 'xz', 0 )
503          time_do2d_xz = MOD( time_do2d_xz, MAX( dt_do2d_xz, dt_3d ) )
504       ENDIF
505       IF ( time_do2d_yz >= dt_do2d_yz )  THEN
506          CALL data_output_2d( 'yz', 0 )
507          time_do2d_yz = MOD( time_do2d_yz, MAX( dt_do2d_yz, dt_3d ) )
508       ENDIF
509
510!
511!--    3d-data output (volume data)
512       IF ( time_do3d >= dt_do3d )  THEN
513          CALL data_output_3d( 0 )
514          time_do3d = MOD( time_do3d, MAX( dt_do3d, dt_3d ) )
515       ENDIF
516
517!
518!--    masked data output
519       DO  mid = 1, masks
520          IF ( time_domask(mid) >= dt_domask(mid) )  THEN
521             CALL data_output_mask( 0 )
522             time_domask(mid) = MOD( time_domask(mid),  &
523                                     MAX( dt_domask(mid), dt_3d ) )
524          ENDIF
525       ENDDO
526
527!
528!--    Output of time-averaged 2d/3d/masked data
529       IF ( time_do_av >= dt_data_output_av )  THEN
530          CALL average_3d_data
531          CALL data_output_2d( 'xy', 1 )
532          CALL data_output_2d( 'xz', 1 )
533          CALL data_output_2d( 'yz', 1 )
534          CALL data_output_3d( 1 )
535          DO  mid = 1, masks
536             CALL data_output_mask( 1 )
537          ENDDO
538          time_do_av = MOD( time_do_av, MAX( dt_data_output_av, dt_3d ) )
539       ENDIF
540
541!
542!--    Output of particle time series
543       IF ( particle_advection )  THEN
544          IF ( time_dopts >= dt_dopts  .OR. &
545               ( simulated_time >= particle_advection_start  .AND. &
546                 first_call_lpm ) )  THEN
547             CALL data_output_ptseries
548             time_dopts = MOD( time_dopts, MAX( dt_dopts, dt_3d ) )
549          ENDIF
550       ENDIF
551
552!
553!--    Output of dvrp-graphics (isosurface, particles, slicer)
554#if defined( __dvrp_graphics )
555       CALL DVRP_LOG_EVENT( -2, current_timestep_number-1 )
556#endif
557       IF ( time_dvrp >= dt_dvrp )  THEN
558          CALL data_output_dvrp
559          time_dvrp = MOD( time_dvrp, MAX( dt_dvrp, dt_3d ) )
560       ENDIF
561#if defined( __dvrp_graphics )
562       CALL DVRP_LOG_EVENT( 2, current_timestep_number )
563#endif
564
565!
566!--    If required, set the heat flux for the next time step at a random value
567       IF ( constant_heatflux  .AND.  random_heatflux )  CALL disturb_heatflux
568
569!
570!--    Execute user-defined actions
571       CALL user_actions( 'after_timestep' )
572
573       CALL cpu_log( log_point_s(10), 'timesteps', 'stop' )
574
575
576    ENDDO   ! time loop
577
578#if defined( __dvrp_graphics )
579    CALL DVRP_LOG_EVENT( -2, current_timestep_number )
580#endif
581
582 END SUBROUTINE time_integration
Note: See TracBrowser for help on using the repository browser.