source: palm/trunk/SOURCE/time_integration.f90 @ 1

 SUBROUTINE time_integration

!------------------------------------------------------------------------------!
! Actual revisions:
! -----------------
! 
!
! Former revisions:
! -----------------
! $Log: time_integration.f90,v $
! Revision 1.8  2006/08/22 14:16:05  raasch
! Disturbances are imposed only for the last Runge-Kutta-substep
!
! Revision 1.7  2006/08/04 15:04:39  raasch
! Output of particle timeseries
!
! Revision 1.6  2006/02/23 12:58:38  raasch
! Data output (1d, 2d, 3d, sp) can be skipped for a given time interval from
! simulation start, additional argument nzb_.._inner added to call of
! disturb_field, nt_anz renamed current_timestep_number, pl.. renamed do..,
! ..anz renamed ..n, dt_average renamed dt_averaging_interval_pr,
! time_average_.. renamed time_do.._av, routines plot_.. renamed data_output_..,
! additional call of user_actions (after_integration)
!
! Revision 1.5  2005/06/26 20:10:20  raasch
! +call of interaction_droplets_ptq (+module of the same name)
!
! Revision 1.4  2005/04/23 09:39:01  raasch
! Revised calculation of output time counters regarding a possible decrease of
! the output time interval in case of restart runs
!
! Revision 1.3  2005/03/26 21:10:26  raasch
! Pres is called by default only at the last Runge-Kutta-substep.
! Determination of the timestep moved from end to the beginning of the
! time loop in order to assure consistent output in run_control (first line
! in restart runs must be equal to the last line in the corresponding
! previous run). Exchange of ghost points for km and kh removed.
! Changes regarding non-cyclic boundary conditions:
! arguments are added to call of routines disturb_field, exchange_horiz,
! and boundary_conds, which is now called for a second time after pres in
! order to set the velocity boundary conditions at the outflow. Velocity
! perturbations are imposed near the inflow throughout the whole run.
!
! Revision 1.2  2004/04/30 13:03:40  raasch
! decalpha-specific warning removed, routine name changed to time_integration,
! particle advection is carried out only once during the intermediate steps,
! impulse_advec renamed momentum_advec
!
! Revision 1.1  2004/04/30 12:58:21  raasch
! Initial revision
!
! Revision 1.44  2004/01/28 15:17:26  raasch
! Additional intermediate timesteps for the Runge-Kutta schemes, setting
! of the steering factors for prognostic equations within the new
! routine timestep_scheme_steering at the beginning of each step (former
! part of routine timestep called at the end of each step), routine
! run_control is not called for the Runge-Kutta schemes automatically in case
! of timestep changes.
!
! Revision 1.43  2003/03/16 09:40:12  raasch
! Two underscores (_) are placed in front of all define-strings
!
! Revision 1.42  2003/03/12 16:33:23  raasch
! New routine prognostic_equations_vec is used on NEC machines
!
! Revision 1.41  2003/03/04 11:31:39  raasch
! Module DVRP added in case that dvrp graphics package is switched on
!
! Revision 1.40  2002/12/19 15:45:13  raasch
! Routine check_cpu_time renamed to check_for_restart
!
! Revision 1.39  2002/06/11 13:11:44  raasch
! +USE user_actions_mod, prognostic_equations_mod,
! temperature offset at cyclic boundaries in case of sloping surface moved
! from prognostic_equations to this subroutine. Particle advection moved from
! prognostic_equations to this routine. A fast version of prognostic_equations
! is called in case that the Piascek-Williams advection scheme is used.
!
! Revision 1.38  2002/05/02 18:52:19  raasch
! Application of time filter and exchange of ghost points moved from
! prognostic_equations to this routine.
! Error in calculating output time intervals for various quantities removed.
!
! Revision 1.37  2001/08/21  09:51:26  09:51:26  raasch (Siegfried Raasch)
! Time measurements for user_actions moved to that subroutine
! 
! Revision 1.36  2001/03/30 07:34:24  raasch
! Timelevel t+dt eliminated, Asselin filter now included in
! prognostic_equations, arguments removed from pres,
! Translation of remaining German identifiers (variables, subroutines, etc.)
!
! Revision 1.35  2001/01/25 07:06:43  raasch
! Time measurements with dvrp software included
!
! Revision 1.34  2001/01/05 15:12:50  raasch
! Calculation and plot of spectra
!
! Revision 1.33  2000/04/27 06:40:49  raasch
! Old revision remarks deleted, output of isosurfaces and particles now
! combined into new routine data_output_dvrp (includes former routines
! plot_particles and plot_isosurface)
!
! Revision 1.32  2000/04/13 13:39:30  schroeter
! computation of prognostic equations moved to the new routine
! prognostic_equation, new routines calc_liquid_water_content and
! compute_vpt
!
! Revision 1.31  2000/01/25  16:25:24  16:25:24  letzel (Marcus Letzel)
! All comments translated into English
! 
! Revision 1.1  1997/08/11 06:19:04  raasch
! Initial revision
!
!
! Description:
! ------------
! Integration in time of the model equations, statistical analysis and graphic
! output
!------------------------------------------------------------------------------!

    USE arrays_3d
    USE averaging
    USE control_parameters
    USE cpulog
#if defined( __dvrp_graphics )
    USE DVRP
#endif
    USE grid_variables
    USE indices
    USE interaction_droplets_ptq_mod
    USE interfaces
    USE particle_attributes
    USE pegrid
    USE prognostic_equations_mod
    USE statistics
    USE user_actions_mod

    IMPLICIT NONE

    CHARACTER (LEN=9) ::  time_to_string
    INTEGER ::  i, j, k

!
!-- At the beginning of a simulation determine the time step as well as
!-- determine and print out the run control parameters
    IF ( simulated_time == 0.0 )  CALL timestep
    CALL run_control

#if defined( __dvrp_graphics )
!
!-- Time measurement with dvrp software  
    CALL DVRP_LOG_EVENT( 2, current_timestep_number )
#endif

!
!-- Start of the time loop
    DO  WHILE ( simulated_time < end_time  .AND.  .NOT. stop_dt  .AND. &
                .NOT. terminate_run )

       CALL cpu_log( log_point_s(10), 'timesteps', 'start' )

!
!--    Determine size of next time step
       IF ( simulated_time /= 0.0 )  CALL timestep

!
!--    Execute the user-defined actions
       CALL user_actions( 'before_timestep' )

!
!--    Start of intermediate step loop
       intermediate_timestep_count = 0
       DO  WHILE ( intermediate_timestep_count < &
                   intermediate_timestep_count_max )

          intermediate_timestep_count = intermediate_timestep_count + 1

!
!--       Set the steering factors for the prognostic equations which depend
!--       on the timestep scheme
          CALL timestep_scheme_steering

!
!--       Solve the prognostic equations. A fast cache optimized version with
!--       only one single loop is used in case of Piascek-Williams advection
!--       scheme. NEC vector machines use a different version, because
!--       in the other versions a good vectorization is prohibited due to
!--       inlining problems.
          IF ( host(1:3) == 'nec' )  THEN
             CALL prognostic_equations_vec
          ELSE
             IF ( momentum_advec == 'ups-scheme'  .OR.  &
                  scalar_advec == 'ups-scheme'   .OR.  &
                  scalar_advec == 'bc-scheme' )        &
             THEN
                CALL prognostic_equations
             ELSE
                CALL prognostic_equations_fast
             ENDIF
          ENDIF

!
!--       Particle advection (only once during intermediate steps, because
!--       it uses an Euler-step)
          IF ( simulated_time >= particle_advection_start  .AND. &
               intermediate_timestep_count == 1 )  THEN
             CALL advec_particles
             first_call_advec_particles = .FALSE.
          ENDIF

!
!--       Interaction of droplets with temperature and specific humidity.
!--       Droplet condensation and evaporation is calculated within
!--       advec_particles.
          IF ( cloud_droplets  .AND.  &
               intermediate_timestep_count == intermediate_timestep_count_max )&
          THEN
             CALL interaction_droplets_ptq
          ENDIF

!
!--       Exchange of ghost points (lateral boundary conditions)
          CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'start' )
          CALL exchange_horiz( u_p, uxrp,    0 )
          CALL exchange_horiz( v_p,    0, vynp )
          CALL exchange_horiz( w_p,    0,    0 )
          CALL exchange_horiz( pt_p,   0,    0 )
          IF ( .NOT. constant_diffusion       )  CALL exchange_horiz( e_p, 0, 0)
          IF ( moisture  .OR.  passive_scalar )  CALL exchange_horiz( q_p, 0, 0)
          IF ( cloud_droplets )  THEN
             CALL exchange_horiz( ql,    0, 0 )
             CALL exchange_horiz( ql_c,  0, 0 )
             CALL exchange_horiz( ql_v,  0, 0 )
             CALL exchange_horiz( ql_vp, 0, 0 )
          ENDIF

          CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'stop' )

!
!--       Apply time filter in case of leap-frog timestep
          IF ( tsc(2) == 2.0  .AND.  timestep_scheme(1:8) == 'leapfrog' )  THEN
             CALL asselin_filter
          ENDIF

!
!--       Swap the time levels in preparation for the next time step.
          CALL swap_timelevel

!
!--       Boundary conditions for the prognostic quantities (except of the
!--       velocities at the outflow in case of a non-cyclic lateral wall)
          CALL boundary_conds( 'main' )

!
!--       Temperature offset must be imposed at cyclic boundaries in x-direction
!--       when a sloping surface is used
          IF ( sloping_surface )  THEN
             IF ( nxl ==  0 )  pt(:,:,nxl-1) = pt(:,:,nxl-1) - pt_slope_offset
             IF ( nxr == nx )  pt(:,:,nxr+1) = pt(:,:,nxr+1) + pt_slope_offset
          ENDIF

!
!--       Impose a random perturbation on the horizontal velocity field
          IF ( create_disturbances  .AND.  &
               intermediate_timestep_count == intermediate_timestep_count_max )&
          THEN
             time_disturb = time_disturb + dt_3d
             IF ( time_disturb >= dt_disturb )  THEN
                IF ( hom(nzb+5,1,var_hom,0) < disturbance_energy_limit )  THEN
                   CALL disturb_field( nzb_u_inner, tend, u, uxrp, 0    )
                   CALL disturb_field( nzb_v_inner, tend, v ,   0, vynp )
                ELSEIF ( bc_lr /= 'cyclic'  .OR.  bc_ns /= 'cyclic' )  THEN
!
!--                Runs with a non-cyclic lateral wall need perturbations
!--                near the inflow throughout the whole simulation
                   dist_range = 1
                   CALL disturb_field( nzb_u_inner, tend, u, uxrp, 0    )
                   CALL disturb_field( nzb_v_inner, tend, v ,   0, vynp )
                   dist_range = 0
                ENDIF
                time_disturb = time_disturb - dt_disturb
             ENDIF
          ENDIF

!
!--       Reduce the velocity divergence via the equation for perturbation
!--       pressure.
          IF ( intermediate_timestep_count == intermediate_timestep_count_max &
               .OR.  call_psolver_at_all_substeps )  THEN
             CALL pres
          ENDIF

!
!--       In case of a non-cyclic lateral wall, set the boundary conditions for
!--       the velocities at the outflow
          IF ( bc_lr /= 'cyclic'  .OR.  bc_ns /= 'cyclic' )  THEN
             CALL boundary_conds( 'outflow_uvw' )
          ENDIF

!
!--       If required, compute virtuell potential temperature
          IF ( moisture ) CALL compute_vpt

!
!--       If required, compute liquid water content
          IF ( cloud_physics ) CALL calc_liquid_water_content

!
!--       Compute the diffusion quantities
          IF ( .NOT. constant_diffusion )  THEN

!
!--          First the vertical fluxes in the Prandtl layer are being computed
             IF ( prandtl_layer )  THEN
                CALL cpu_log( log_point(19), 'prandtl_fluxes', 'start' )
                CALL prandtl_fluxes
                CALL cpu_log( log_point(19), 'prandtl_fluxes', 'stop' )
             ENDIF

!
!--          Compute the diffusion coefficients
             CALL cpu_log( log_point(17), 'diffusivities', 'start' )
             IF ( .NOT. moisture ) THEN
                CALL diffusivities( pt )
             ELSE
                CALL diffusivities( vpt )
             ENDIF
             CALL cpu_log( log_point(17), 'diffusivities', 'stop' )

          ENDIF

       ENDDO   ! Intermediate step loop

!
!--    Execute user-defined actions
       CALL user_actions( 'after_integration' )

!
!--    Increase simulation time and output times
       current_timestep_number = current_timestep_number + 1
       simulated_time     = simulated_time   + dt_3d
       simulated_time_chr = time_to_string( simulated_time )
       IF ( simulated_time >= skip_time_data_output_av )  THEN
          time_do_av         = time_do_av       + dt_3d
       ENDIF
       IF ( simulated_time >= skip_time_do2d_xy )  THEN
          time_do2d_xy       = time_do2d_xy     + dt_3d
       ENDIF
       IF ( simulated_time >= skip_time_do2d_xz )  THEN
          time_do2d_xz       = time_do2d_xz     + dt_3d
       ENDIF
       IF ( simulated_time >= skip_time_do2d_yz )  THEN
          time_do2d_yz       = time_do2d_yz     + dt_3d
       ENDIF
       IF ( simulated_time >= skip_time_do3d    )  THEN
          time_do3d          = time_do3d        + dt_3d
       ENDIF
       time_dvrp          = time_dvrp        + dt_3d
       IF ( simulated_time >= skip_time_dosp )  THEN
          time_dosp       = time_dosp        + dt_3d
       ENDIF
       time_dots          = time_dots        + dt_3d
       IF ( .NOT. first_call_advec_particles )  THEN
          time_dopts      = time_dopts       + dt_3d
       ENDIF
       IF ( simulated_time >= skip_time_dopr )  THEN
          time_dopr       = time_dopr        + dt_3d
       ENDIF
       time_dopr_listing          = time_dopr_listing        + dt_3d
       time_run_control   = time_run_control + dt_3d

!
!--    If Galilei transformation is used, determine the distance that the
!--    model has moved so far
       IF ( galilei_transformation )  THEN
          advected_distance_x = advected_distance_x + u_gtrans * dt_3d
          advected_distance_y = advected_distance_y + v_gtrans * dt_3d
       ENDIF

!
!--    Check, if restart is necessary (because cpu-time is expiring or
!--    because it is forced by user) and set stop flag
       CALL check_for_restart

!
!--    Carry out statistical analysis and output at the requested output times.
!--    The MOD function is used for calculating the output time counters (like
!--    time_dopr) in order to regard a possible decrease of the output time
!--    interval in case of restart runs

!
!--    Set a flag indicating that so far no statistics have been created
!--    for this time step
       flow_statistics_called = .FALSE.

!
!--    If required, call flow_statistics for averaging in time
       IF ( averaging_interval_pr /= 0.0  .AND.  &
            ( dt_dopr - time_dopr ) <= averaging_interval_pr  .AND.  &
            simulated_time >= skip_time_dopr )  THEN
          time_dopr_av = time_dopr_av + dt_3d
          IF ( time_dopr_av >= dt_averaging_input_pr )  THEN
             do_sum = .TRUE.
             time_dopr_av = MOD( time_dopr_av, &
                                    MAX( dt_averaging_input_pr, dt_3d ) )
          ENDIF
       ENDIF
       IF ( do_sum )  CALL flow_statistics

!
!--    Sum-up 3d-arrays for later output of time-averaged data
       IF ( averaging_interval /= 0.0  .AND.                                &
            ( dt_data_output_av - time_do_av ) <= averaging_interval  .AND. &
            simulated_time >= skip_time_data_output_av )                    &
       THEN
          time_do_sla = time_do_sla + dt_3d
          IF ( time_do_sla >= dt_averaging_input )  THEN
             CALL sum_up_3d_data
             average_count_3d = average_count_3d + 1
             time_do_sla = MOD( time_do_sla, MAX( dt_averaging_input, dt_3d ) )
          ENDIF
       ENDIF

!
!--    Calculate spectra for time averaging
       IF ( averaging_interval_sp /= 0.0  .AND.  &
            ( dt_dosp - time_dosp ) <= averaging_interval_sp  .AND.  &
            simulated_time >= skip_time_dosp )  THEN
          time_dosp_av = time_dosp_av + dt_3d
          IF ( time_dosp_av >= dt_averaging_input_pr )  THEN
             CALL calc_spectra
             time_dosp_av = MOD( time_dosp_av, &
                                 MAX( dt_averaging_input_pr, dt_3d ) )
          ENDIF
       ENDIF

!
!--    Computation and output of run control parameters.
!--    This is also done whenever the time step has changed or perturbations
!--    have been imposed
       IF ( time_run_control >= dt_run_control  .OR.                     &
            ( dt_changed  .AND.  timestep_scheme(1:5) /= 'runge' )  .OR. &
            disturbance_created )                                        &
       THEN
          CALL run_control
          IF ( time_run_control >= dt_run_control )  THEN
             time_run_control = MOD( time_run_control, &
                                     MAX( dt_run_control, dt_3d ) )
          ENDIF
       ENDIF

!
!--    Profile output (ASCII) on file
       IF ( time_dopr_listing >= dt_dopr_listing )  THEN
          CALL print_1d
          time_dopr_listing = MOD( time_dopr_listing, MAX( dt_dopr_listing, &
                                                           dt_3d ) )
       ENDIF

!
!--    Graphic output for PROFIL
       IF ( time_dopr >= dt_dopr )  THEN
          IF ( dopr_n /= 0 )  CALL data_output_profiles
          time_dopr = MOD( time_dopr, MAX( dt_dopr, dt_3d ) )
          time_dopr_av = 0.0    ! due to averaging (see above)
       ENDIF

!
!--    Graphic output for time series
       IF ( time_dots >= dt_dots )  THEN
          IF ( dots_n /= 0 )  CALL data_output_tseries
          time_dots = MOD( time_dots, MAX( dt_dots, dt_3d ) )
       ENDIF

!
!--    Output of spectra (formatted for use with PROFIL), in case of no
!--    time averaging, spectra has to be calculated before
       IF ( time_dosp >= dt_dosp )  THEN
          IF ( average_count_sp == 0 )  CALL calc_spectra
          CALL data_output_spectra
          time_dosp = MOD( time_dosp, MAX( dt_dosp, dt_3d ) )
       ENDIF

!
!--    2d-data output (cross-sections)
       IF ( time_do2d_xy >= dt_do2d_xy )  THEN
          CALL data_output_2d( 'xy', 0 )
          time_do2d_xy = MOD( time_do2d_xy, MAX( dt_do2d_xy, dt_3d ) )
       ENDIF
       IF ( time_do2d_xz >= dt_do2d_xz )  THEN
          CALL data_output_2d( 'xz', 0 )
          time_do2d_xz = MOD( time_do2d_xz, MAX( dt_do2d_xz, dt_3d ) )
       ENDIF
       IF ( time_do2d_yz >= dt_do2d_yz )  THEN
          CALL data_output_2d( 'yz', 0 )
          time_do2d_yz = MOD( time_do2d_yz, MAX( dt_do2d_yz, dt_3d ) )
       ENDIF

!
!--    3d-data output (volume data)
       IF ( time_do3d >= dt_do3d )  THEN
          CALL data_output_3d( 0 )
          time_do3d = MOD( time_do3d, MAX( dt_do3d, dt_3d ) )
       ENDIF

!
!--    Output of time-averaged 2d/3d-data
       IF ( time_do_av >= dt_data_output_av )  THEN
          CALL average_3d_data
          CALL data_output_2d( 'xy', 1 )
          CALL data_output_2d( 'xz', 1 )
          CALL data_output_2d( 'yz', 1 )
          CALL data_output_3d( 1 )
          time_do_av = MOD( time_do_av, MAX( dt_data_output_av, dt_3d ) )
       ENDIF

!
!--    Output of particle time series
       IF ( time_dopts >= dt_dopts  .OR. &
            ( simulated_time >= particle_advection_start  .AND. &
              first_call_advec_particles ) )  THEN
          CALL data_output_ptseries
          time_dopts = MOD( time_dopts, MAX( dt_dopts, dt_3d ) )
       ENDIF

!
!--    Output of dvrp-graphics (isosurface, particles, slicer)
#if defined( __dvrp_graphics )
       CALL DVRP_LOG_EVENT( -2, current_timestep_number-1 )
#endif
       IF ( time_dvrp >= dt_dvrp )  THEN
          CALL data_output_dvrp
          time_dvrp = MOD( time_dvrp, MAX( dt_dvrp, dt_3d ) )
       ENDIF
#if defined( __dvrp_graphics )
       CALL DVRP_LOG_EVENT( 2, current_timestep_number )
#endif

!
!--    If required, set the heat flux for the next time step at a random value
       IF ( constant_heatflux  .AND.  random_heatflux )  CALL disturb_heatflux

!
!--    Execute user-defined actions
       CALL user_actions( 'after_timestep' )

       CALL cpu_log( log_point_s(10), 'timesteps', 'stop' )

    ENDDO   ! time loop

#if defined( __dvrp_graphics )
    CALL DVRP_LOG_EVENT( -2, current_timestep_number )
#endif

 END SUBROUTINE time_integration