Home

Context Navigation

source: palm/trunk/SOURCE/sor.f90 @ 1682

Last change on this file since 1682 was 1682, checked in by knoop, 9 years ago
Code annotations made doxygen readable
Property svn:keywords set to `Id`
File size: 7.7 KB

Line
1	!> @file sor.f90
2	!--------------------------------------------------------------------------------!
3	! This file is part of PALM.
4	!
5	! PALM is free software: you can redistribute it and/or modify it under the terms
6	! of the GNU General Public License as published by the Free Software Foundation,
7	! either version 3 of the License, or (at your option) any later version.
8	!
9	! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
10	! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
11	! A PARTICULAR PURPOSE. See the GNU General Public License for more details.
12	!
13	! You should have received a copy of the GNU General Public License along with
14	! PALM. If not, see <http://www.gnu.org/licenses/>.
15	!
16	! Copyright 1997-2014 Leibniz Universitaet Hannover
17	!--------------------------------------------------------------------------------!
18	!
19	! Current revisions:
20	! -----------------
21	! Code annotations made doxygen readable
22	!
23	! Former revisions:
24	! -----------------
25	! $Id: sor.f90 1682 2015-10-07 23:56:08Z knoop $
26	!
27	! 1353 2014-04-08 15:21:23Z heinze
28	! REAL constants provided with KIND-attribute
29	!
30	! 1320 2014-03-20 08:40:49Z raasch
31	! ONLY-attribute added to USE-statements,
32	! kind-parameters added to all INTEGER and REAL declaration statements,
33	! kinds are defined in new module kinds,
34	! old module precision_kind is removed,
35	! revision history before 2012 removed,
36	! comment fields (!:) to be used for variable explanations added to
37	! all variable declaration statements
38	!
39	! 1036 2012-10-22 13:43:42Z raasch
40	! code put under GPL (PALM 3.9)
41	!
42	! Revision 1.1 1997/08/11 06:25:56 raasch
43	! Initial revision
44	!
45	!
46	! Description:
47	! ------------
48	!> Solve the Poisson-equation with the SOR-Red/Black-scheme.
49	!------------------------------------------------------------------------------!
50	SUBROUTINE sor( d, ddzu, ddzw, p )
51
52
53	USE grid_variables, &
54	ONLY: ddx2, ddy2
55
56	USE indices, &
57	ONLY: nbgp, nxl, nxlg, nxr, nxrg, nyn, nyng, nys, nysg, nz, nzb, nzt
58
59	USE kinds
60
61	USE control_parameters, &
62	ONLY: bc_lr_cyc, bc_ns_cyc, ibc_p_b, ibc_p_t, inflow_l, inflow_n, &
63	inflow_r, inflow_s, n_sor, omega_sor, outflow_l, outflow_n, &
64	outflow_r, outflow_s
65
66	IMPLICIT NONE
67
68	INTEGER(iwp) :: i !<
69	INTEGER(iwp) :: j !<
70	INTEGER(iwp) :: k !<
71	INTEGER(iwp) :: n !<
72	INTEGER(iwp) :: nxl1 !<
73	INTEGER(iwp) :: nxl2 !<
74	INTEGER(iwp) :: nys1 !<
75	INTEGER(iwp) :: nys2 !<
76
77	REAL(wp) :: ddzu(1:nz+1) !<
78	REAL(wp) :: ddzw(1:nzt+1) !<
79
80	REAL(wp) :: d(nzb+1:nzt,nys:nyn,nxl:nxr) !<
81	REAL(wp) :: p(nzb:nzt+1,nysg:nyng,nxlg:nxrg) !<
82
83	REAL(wp), DIMENSION(:), ALLOCATABLE :: f1 !<
84	REAL(wp), DIMENSION(:), ALLOCATABLE :: f2 !<
85	REAL(wp), DIMENSION(:), ALLOCATABLE :: f3 !<
86
87	ALLOCATE( f1(1:nz), f2(1:nz), f3(1:nz) )
88
89	!
90	!-- Compute pre-factors.
91	DO k = 1, nz
92	f2(k) = ddzu(k+1) * ddzw(k)
93	f3(k) = ddzu(k) * ddzw(k)
94	f1(k) = 2.0_wp * ( ddx2 + ddy2 ) + f2(k) + f3(k)
95	ENDDO
96
97	!
98	!-- Limits for RED- and BLACK-part.
99	IF ( MOD( nxl , 2 ) == 0 ) THEN
100	nxl1 = nxl
101	nxl2 = nxl + 1
102	ELSE
103	nxl1 = nxl + 1
104	nxl2 = nxl
105	ENDIF
106	IF ( MOD( nys , 2 ) == 0 ) THEN
107	nys1 = nys
108	nys2 = nys + 1
109	ELSE
110	nys1 = nys + 1
111	nys2 = nys
112	ENDIF
113
114	DO n = 1, n_sor
115
116	!
117	!-- RED-part
118	DO i = nxl1, nxr, 2
119	DO j = nys2, nyn, 2
120	DO k = nzb+1, nzt
121	p(k,j,i) = p(k,j,i) + omega_sor / f1(k) * ( &
122	ddx2 * ( p(k,j,i+1) + p(k,j,i-1) ) + &
123	ddy2 * ( p(k,j+1,i) + p(k,j-1,i) ) + &
124	f2(k) * p(k+1,j,i) + &
125	f3(k) * p(k-1,j,i) - &
126	d(k,j,i) - &
127	f1(k) * p(k,j,i) )
128	ENDDO
129	ENDDO
130	ENDDO
131
132	DO i = nxl2, nxr, 2
133	DO j = nys1, nyn, 2
134	DO k = nzb+1, nzt
135	p(k,j,i) = p(k,j,i) + omega_sor / f1(k) * ( &
136	ddx2 * ( p(k,j,i+1) + p(k,j,i-1) ) + &
137	ddy2 * ( p(k,j+1,i) + p(k,j-1,i) ) + &
138	f2(k) * p(k+1,j,i) + &
139	f3(k) * p(k-1,j,i) - &
140	d(k,j,i) - &
141	f1(k) * p(k,j,i) )
142	ENDDO
143	ENDDO
144	ENDDO
145
146	!
147	!-- Exchange of boundary values for p.
148	CALL exchange_horiz( p, nbgp )
149
150	!
151	!-- Horizontal (Neumann) boundary conditions in case of non-cyclic boundaries
152	IF ( .NOT. bc_lr_cyc ) THEN
153	IF ( inflow_l .OR. outflow_l ) p(:,:,nxl-1) = p(:,:,nxl)
154	IF ( inflow_r .OR. outflow_r ) p(:,:,nxr+1) = p(:,:,nxr)
155	ENDIF
156	IF ( .NOT. bc_ns_cyc ) THEN
157	IF ( inflow_n .OR. outflow_n ) p(:,nyn+1,:) = p(:,nyn,:)
158	IF ( inflow_s .OR. outflow_s ) p(:,nys-1,:) = p(:,nys,:)
159	ENDIF
160
161	!
162	!-- BLACK-part
163	DO i = nxl1, nxr, 2
164	DO j = nys1, nyn, 2
165	DO k = nzb+1, nzt
166	p(k,j,i) = p(k,j,i) + omega_sor / f1(k) * ( &
167	ddx2 * ( p(k,j,i+1) + p(k,j,i-1) ) + &
168	ddy2 * ( p(k,j+1,i) + p(k,j-1,i) ) + &
169	f2(k) * p(k+1,j,i) + &
170	f3(k) * p(k-1,j,i) - &
171	d(k,j,i) - &
172	f1(k) * p(k,j,i) )
173	ENDDO
174	ENDDO
175	ENDDO
176
177	DO i = nxl2, nxr, 2
178	DO j = nys2, nyn, 2
179	DO k = nzb+1, nzt
180	p(k,j,i) = p(k,j,i) + omega_sor / f1(k) * ( &
181	ddx2 * ( p(k,j,i+1) + p(k,j,i-1) ) + &
182	ddy2 * ( p(k,j+1,i) + p(k,j-1,i) ) + &
183	f2(k) * p(k+1,j,i) + &
184	f3(k) * p(k-1,j,i) - &
185	d(k,j,i) - &
186	f1(k) * p(k,j,i) )
187	ENDDO
188	ENDDO
189	ENDDO
190
191	!
192	!-- Exchange of boundary values for p.
193	CALL exchange_horiz( p, nbgp )
194
195	!
196	!-- Boundary conditions top/bottom.
197	!-- Bottom boundary
198	IF ( ibc_p_b == 1 ) THEN ! Neumann
199	p(nzb,:,:) = p(nzb+1,:,:)
200	ELSE ! Dirichlet
201	p(nzb,:,:) = 0.0_wp
202	ENDIF
203
204	!
205	!-- Top boundary
206	IF ( ibc_p_t == 1 ) THEN ! Neumann
207	p(nzt+1,:,:) = p(nzt,:,:)
208	ELSE ! Dirichlet
209	p(nzt+1,:,:) = 0.0_wp
210	ENDIF
211
212	!
213	!-- Horizontal (Neumann) boundary conditions in case of non-cyclic boundaries
214	IF ( .NOT. bc_lr_cyc ) THEN
215	IF ( inflow_l .OR. outflow_l ) p(:,:,nxl-1) = p(:,:,nxl)
216	IF ( inflow_r .OR. outflow_r ) p(:,:,nxr+1) = p(:,:,nxr)
217	ENDIF
218	IF ( .NOT. bc_ns_cyc ) THEN
219	IF ( inflow_n .OR. outflow_n ) p(:,nyn+1,:) = p(:,nyn,:)
220	IF ( inflow_s .OR. outflow_s ) p(:,nys-1,:) = p(:,nys,:)
221	ENDIF
222
223
224	ENDDO
225
226	DEALLOCATE( f1, f2, f3 )
227
228	END SUBROUTINE sor

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

| Impressum | ©Leibniz Universität Hannover |