source: palm/trunk/SOURCE/random_generator_parallel_mod.f90 @ 2144

Last change on this file since 2144 was 2144, checked in by knoop, 7 years ago

Bugfix: compile time issue removed for parallel random number generator

  • Property svn:keywords set to Id
File size: 16.3 KB
Line 
1!> @file random_generator_parallel_mod.f90
2!------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2017 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22! Bugfix: compile time parameter replacement prevented
23!
24! Former revisions:
25! -----------------
26! $Id: random_generator_parallel_mod.f90 2144 2017-02-07 15:32:45Z knoop $
27!
28! 2000 2016-08-20 18:09:15Z knoop
29! Forced header and separation lines into 80 columns
30!
31! 1850 2016-04-08 13:29:27Z maronga
32! Module renamed
33!
34!
35! 1682 2015-10-07 23:56:08Z knoop
36! Code annotations made doxygen readable
37!
38! 1400 2014-05-09 14:03:54Z knoop
39! Initial revision
40!
41!
42! Description:
43! ------------
44!> This module contains and supports the random number generating routine ran_parallel.
45!> ran_parallel returns a uniform random deviate between 0.0 and 1.0
46!> (exclusive of the end point values).
47!> Additionally it provides the generator with five integer for use as initial state space.
48!> The first tree integers (iran, jran, kran) are maintained as non negative values,
49!> while the last two (mran, nran) have 32-bit nonzero values.
50!> Also provided by this module is support for initializing or reinitializing
51!> the state space to a desired standard sequence number, hashing the initial
52!> values to random values, and allocating and deallocating the internal workspace
53!> Random number generator, produces numbers equally distributed in interval
54!>
55!> This routine is taken from the "numerical recipies vol. 2"
56!------------------------------------------------------------------------------!
57MODULE random_generator_parallel
58 
59
60   USE kinds
61   
62   IMPLICIT NONE
63   
64   PRIVATE
65   PUBLIC random_number_parallel, random_seed_parallel, random_dummy,          &
66          id_random_array, seq_random_array
67   
68   INTEGER(isp), SAVE :: lenran=0             !<
69   INTEGER(isp), SAVE :: seq=0                !<
70   INTEGER(isp), SAVE :: iran0                !<
71   INTEGER(isp), SAVE :: jran0                !<
72   INTEGER(isp), SAVE :: kran0                !<
73   INTEGER(isp), SAVE :: mran0                !<
74   INTEGER(isp), SAVE :: nran0                !<
75   INTEGER(isp), SAVE :: rans                 !<
76   
77   INTEGER(isp), DIMENSION(:, :), POINTER, SAVE :: ranseeds   !<
78   
79   INTEGER(isp), DIMENSION(:), POINTER, SAVE :: iran   !<
80   INTEGER(isp), DIMENSION(:), POINTER, SAVE :: jran   !<
81   INTEGER(isp), DIMENSION(:), POINTER, SAVE :: kran   !<
82   INTEGER(isp), DIMENSION(:), POINTER, SAVE :: mran   !<
83   INTEGER(isp), DIMENSION(:), POINTER, SAVE :: nran   !<
84   INTEGER(isp), DIMENSION(:), POINTER, SAVE :: ranv   !<
85   
86   
87   
88   INTEGER(isp), DIMENSION(:,:), ALLOCATABLE   ::  id_random_array    !<
89   INTEGER(isp), DIMENSION(:,:,:), ALLOCATABLE ::  seq_random_array   !<
90   
91   REAL(wp), SAVE :: amm   !<
92   
93   REAL(wp) :: random_dummy=0.0   !<
94   
95   INTERFACE random_number_parallel
96      MODULE PROCEDURE ran0_s
97   END INTERFACE
98   
99   INTERFACE random_seed_parallel
100      MODULE PROCEDURE random_seed_parallel
101   END INTERFACE
102   
103   INTERFACE ran_hash
104      MODULE PROCEDURE ran_hash_v
105   END INTERFACE
106   
107   INTERFACE reallocate
108      MODULE PROCEDURE reallocate_iv,reallocate_im
109   END INTERFACE
110   
111   INTERFACE arth
112      MODULE PROCEDURE arth_i
113   END INTERFACE
114
115 CONTAINS
116 
117!------------------------------------------------------------------------------!
118! Description:
119! ------------
120!> Lagged Fibonacci generator combined with a Marsaglia shiftsequence.
121!> Returns as harvest a uniform random deviate between 0.0 and 1.0 (exclusive of the end point values).
122!> This generator has the same calling and initialization conventions as Fortran 90's random_number routine.
123!> Use random_seed_parallel to initialize or reinitialize to a particular sequence.
124!> The period of this generator is about 2.0 x 10^28, and it fully vectorizes.
125!> Validity of the integer model assumed by this generator is tested at initialization.
126!------------------------------------------------------------------------------!
127   SUBROUTINE ran0_s(harvest)
128
129      USE kinds
130     
131      IMPLICIT NONE
132     
133      REAL(wp), INTENT(OUT) :: harvest   !<
134     
135      IF  (lenran < 1) CALL ran_init(1)  !- Initialization routine in ran_state.
136     
137      !- Update Fibonacci generator, which has period p^2 + p + 1, p = 2^31 - 69.
138      rans = iran0 - kran0   
139     
140      IF  (rans < 0) rans = rans + 2147483579_isp
141     
142      iran0 = jran0
143      jran0 = kran0
144      kran0 = rans
145     
146      nran0 = ieor( nran0, ishft (nran0, 13) ) !- Update Marsaglia shift sequence with period 2^32 - 1.
147      nran0 = ieor( nran0, ishft (nran0, -17) )
148      nran0 = ieor( nran0, ishft (nran0, 5) )
149     
150      rans  = ieor( nran0, rans )   !- Combine the generators.
151     
152      harvest = amm * merge( rans, not(rans), rans < 0 ) !- Make the result positive definite (note that amm is negative).
153     
154   END SUBROUTINE ran0_s
155
156!------------------------------------------------------------------------------!
157! Description:
158! ------------
159!> Initialize or reinitialize the random generator state space to vectors of size length.
160!> The saved variable seq is hashed (via calls to the module routine ran_hash)
161!> to create unique starting seeds, different for each vector component.
162!------------------------------------------------------------------------------!
163   SUBROUTINE ran_init( length )
164   
165      USE kinds
166     
167      IMPLICIT NONE
168     
169      INTEGER(isp), INTENT(IN) ::  length   !<
170   
171      INTEGER(isp) ::  hg    !<
172      INTEGER(isp) ::  hgm   !<
173      INTEGER(isp) ::  hgng  !<
174     
175      INTEGER(isp) ::  new   !<
176      INTEGER(isp) ::  j     !<
177      INTEGER(isp) ::  hgt   !<
178     
179      IF ( length < lenran ) RETURN !- Simply return if enough space is already allocated.
180     
181      hg=huge(1_isp)
182      hgm=-hg
183      hgng=hgm-1
184      hgt = hg
185     
186      !- The following lines check that kind value isp is in fact a 32-bit integer
187      !- with the usual properties that we expect it to have (under negation and wrap-around addition).
188      !- If all of these tests are satisfied, then the routines that use this module are portable,
189      !- even though they go beyond Fortran 90's integer model.
190     
191      IF  ( hg /= 2147483647 ) CALL ran_error('ran_init: arith assump 1 fails')
192      IF  ( hgng >= 0 )        CALL ran_error('ran_init: arith assump 2 fails')
193      IF  ( hgt+1 /= hgng )    CALL ran_error('ran_init: arith assump 3 fails')
194      IF  ( not(hg) >= 0 )     CALL ran_error('ran_init: arith assump 4 fails')
195      IF  ( not(hgng) < 0 )    CALL ran_error('ran_init: arith assump 5 fails')
196      IF  ( hg+hgng >= 0 )     CALL ran_error('ran_init: arith assump 6 fails')
197      IF  ( not(-1_isp) < 0 )  CALL ran_error('ran_init: arith assump 7 fails')
198      IF  ( not(0_isp) >= 0 )  CALL ran_error('ran_init: arith assump 8 fails')
199      IF  ( not(1_isp) >= 0 )  CALL ran_error('ran_init: arith assump 9 fails')
200     
201      IF  ( lenran > 0) THEN                          !- Reallocate space, or ...
202     
203         ranseeds => reallocate( ranseeds, length, 5)
204         ranv => reallocate( ranv, length-1)
205         new = lenran+1
206         
207      ELSE                                            !- allocate space.
208     
209         ALLOCATE(ranseeds(length,5))
210         ALLOCATE(ranv(length-1))
211         new = 1   !- Index of first location not yet initialized.
212         amm = nearest(1.0_wp,-1.0_wp)/hgng
213         !- Use of nearest is to ensure that returned random deviates are strictly lessthan 1.0.
214         IF  (amm*hgng >= 1.0 .or. amm*hgng <= 0.0)                            &
215            CALL ran_error('ran_init: arith assump 10 fails')
216           
217      END IF 
218     
219      !- Set starting values, unique by seq and vector component.
220      ranseeds(new:,1) = seq
221      ranseeds(new:,2:5)=spread(arth(new,1,size(ranseeds(new:,1))),2,4)
222     
223      DO j=1,4   !- Hash them.
224         CALL ran_hash(ranseeds(new:,j), ranseeds(new:,j+1))
225      END DO
226     
227      WHERE (ranseeds (new: ,1:3) < 0)                                         & 
228         ranseeds(new: ,1:3)=not(ranseeds(new: ,1:3))  !- Enforce nonnegativity.
229         
230      WHERE (ranseeds(new: ,4:5) == 0) ranseeds(new: ,4:5)=1 !- Enforce nonzero.
231     
232      IF  (new == 1) THEN !- Set scalar seeds.
233     
234         iran0 = ranseeds(1,1)
235         jran0 = ranseeds(1,2)
236         kran0 = ranseeds(1,3)
237         mran0 = ranseeds(1,4)
238         nran0 = ranseeds(1,5)
239         rans  = nran0
240         
241      END IF
242     
243      IF  (length > 1) THEN   !- Point to vector seeds.
244     
245         iran => ranseeds(2:,1)
246         jran => ranseeds(2:,2)
247         kran => ranseeds(2:,3)
248         mran => ranseeds(2:,4)
249         nran => ranseeds(2:,5)
250         ranv = nran
251         
252      END IF
253     
254      lenran = length
255     
256   END SUBROUTINE ran_init
257
258!------------------------------------------------------------------------------!
259! Description:
260! ------------
261!> User interface to release the workspace used by the random number routines.
262!------------------------------------------------------------------------------!
263   SUBROUTINE ran_deallocate
264   
265      IF  ( lenran > 0 ) THEN
266     
267         DEALLOCATE(ranseeds, ranv)
268         NULLIFY(ranseeds, ranv, iran, jran, kran, mran, nran)
269         lenran = 0
270         
271      END IF
272     
273   END SUBROUTINE ran_deallocate
274
275!------------------------------------------------------------------------------!
276! Description:
277! ------------
278!> User interface for seeding the random number routines.
279!> Syntax is exactly like Fortran 90's random_seed routine,
280!> with one additional argument keyword: random_sequence, set to any integer
281!> value, causes an immediate new initialization, seeded by that integer.
282!------------------------------------------------------------------------------!
283   SUBROUTINE random_seed_parallel( random_sequence, state_size, put, get )
284   
285      IMPLICIT NONE
286     
287      INTEGER(isp), OPTIONAL, INTENT(IN)  ::  random_sequence   !<
288      INTEGER(isp), OPTIONAL, INTENT(OUT) ::  state_size        !<
289     
290      INTEGER(isp), DIMENSION(:), OPTIONAL, INTENT(IN)  ::  put   !<
291      INTEGER(isp), DIMENSION(:), OPTIONAL, INTENT(OUT) ::  get   !<
292     
293      IF  ( present(state_size) ) THEN
294     
295         state_size = 5 * lenran
296         
297      ELSE IF  ( present(put) ) THEN
298     
299         IF  ( lenran == 0 ) RETURN
300         
301         ranseeds = reshape( put,shape(ranseeds) )
302         
303         WHERE (ranseeds(:,1:3) < 0) ranseeds(: ,1:3) = not(ranseeds(: ,1:3))
304         !- Enforce nonnegativity and nonzero conditions on any user-supplied seeds.
305         
306         WHERE (ranseeds(:,4:5) == 0) ranseeds(:,4:5) = 1
307         
308         iran0 = ranseeds(1,1)
309         jran0 = ranseeds(1,2)
310         kran0 = ranseeds(1,3)
311         mran0 = ranseeds(1,4)
312         nran0 = ranseeds(1,5)
313         
314      ELSE IF  ( present(get) ) THEN
315     
316         IF  (lenran == 0) RETURN
317         
318         ranseeds(1,1:5) = (/ iran0,jran0,kran0,mran0,nran0 /)
319         get = reshape( ranseeds, shape(get) )
320         
321      ELSE IF  ( present(random_sequence) ) THEN
322     
323         CALL ran_deallocate
324         seq = random_sequence
325         
326      END IF
327     
328   END SUBROUTINE random_seed_parallel
329
330!------------------------------------------------------------------------------!
331! Description:
332! ------------
333!> DES-like hashing of two 32-bit integers, using shifts,
334!> xor's, and adds to make the internal nonlinear function.
335!------------------------------------------------------------------------------!
336   SUBROUTINE ran_hash_v( il, ir )
337   
338      IMPLICIT NONE
339     
340      INTEGER(isp), DIMENSION(:), INTENT(INOUT) ::  il   !<
341      INTEGER(isp), DIMENSION(:), INTENT(INOUT) ::  ir   !<
342     
343      INTEGER(isp), DIMENSION(size(il)) ::  is   !<
344     
345      INTEGER(isp) :: j   !<
346     
347      DO j=1,4
348     
349         is = ir
350         ir = ieor( ir, ishft(ir,5) ) + 1422217823
351         ir = ieor( ir, ishft(ir,-16) ) + 1842055030
352         ir = ieor( ir, ishft(ir,9) ) + 80567781
353         ir = ieor( il, ir )
354         il = is
355      END DO
356     
357   END SUBROUTINE ran_hash_v
358
359!------------------------------------------------------------------------------!
360! Description:
361! ------------
362!> User interface to process error-messages
363!> produced by the random_number_parallel module
364!------------------------------------------------------------------------------!
365   SUBROUTINE ran_error(string)
366   
367      CHARACTER(LEN=*), INTENT(IN) ::  string   !<
368     
369      write (*,*) 'Error in module random_number_parallel: ',string
370     
371      STOP 'Program terminated by ran_error'
372     
373   END SUBROUTINE ran_error
374
375!------------------------------------------------------------------------------!
376! Description:
377! ------------
378!> Reallocates the generators state space "ranseeds" to vectors of size length.
379!------------------------------------------------------------------------------!
380   FUNCTION reallocate_iv( p, n )
381   
382      INTEGER(isp), DIMENSION(:), POINTER ::  p               !<
383      INTEGER(isp), DIMENSION(:), POINTER ::  reallocate_iv   !<
384     
385      INTEGER(isp), INTENT(IN) ::  n   !<
386     
387      INTEGER(isp) ::  nold   !<
388      INTEGER(isp) ::  ierr   !<
389     
390      ALLOCATE(reallocate_iv(n),stat=ierr)
391     
392      IF (ierr /= 0) CALL                                                      &
393         ran_error('reallocate_iv: problem in attempt to allocate memory')
394         
395      IF (.not. associated(p)) RETURN
396     
397      nold = size(p)
398     
399      reallocate_iv(1:min(nold,n)) = p(1:min(nold,n))
400     
401      DEALLOCATE(p)
402     
403   END FUNCTION reallocate_iv
404   
405   FUNCTION reallocate_im( p, n, m )
406   
407      INTEGER(isp), DIMENSION(:,:), POINTER ::  p               !<
408      INTEGER(isp), DIMENSION(:,:), POINTER ::  reallocate_im   !<
409     
410      INTEGER(isp), INTENT(IN) ::  m   !<
411      INTEGER(isp), INTENT(IN) ::  n   !<
412     
413      INTEGER(isp) ::  mold   !<
414      INTEGER(isp) ::  nold   !<
415      INTEGER(isp) ::  ierr   !<
416     
417      ALLOCATE(reallocate_im(n,m),stat=ierr)
418     
419      IF (ierr /= 0) CALL                                                      &
420         ran_error('reallocate_im: problem in attempt to allocate memory')
421         
422      IF (.not. associated(p)) RETURN
423     
424      nold = size(p,1)
425      mold = size(p,2)
426     
427      reallocate_im(1:min(nold,n),1:min(mold,m)) =                             &
428         p(1:min(nold,n),1:min(mold,m))
429         
430      DEALLOCATE(p)
431     
432   END FUNCTION reallocate_im
433
434!------------------------------------------------------------------------------!
435! Description:
436! ------------
437!> Reallocates the generators state space "ranseeds" to vectors of size length.
438!------------------------------------------------------------------------------!
439   FUNCTION arth_i(first,increment,n)
440   
441      INTEGER(isp), INTENT(IN) ::  first       !<
442      INTEGER(isp), INTENT(IN) ::  increment   !<
443      INTEGER(isp), INTENT(IN) ::  n           !<
444     
445      INTEGER(isp), DIMENSION(n) ::  arth_i    !<
446     
447      INTEGER(isp) ::  k      !<
448      INTEGER(isp) ::  k2     !<
449      INTEGER(isp) ::  temp   !<
450     
451      INTEGER(isp), PARAMETER ::  npar_arth=16   !<
452      INTEGER(isp), PARAMETER ::  npar2_arth=8   !<
453     
454      IF (n > 0) arth_i(1) = first
455     
456      IF (n <= npar_arth) THEN
457     
458         DO k=2,n
459            arth_i(k) = arth_i(k-1)+increment
460         END DO
461         
462      ELSE
463     
464         DO k=2,npar2_arth
465            arth_i(k) = arth_i(k-1) + increment
466         END DO
467         
468         temp = increment * npar2_arth
469         k = npar2_arth
470         
471         DO
472            IF (k >= n) EXIT
473            k2 = k + k
474            arth_i(k+1:min(k2,n)) = temp + arth_i(1:min(k,n-k))
475            temp = temp + temp
476            k = k2
477         END DO
478         
479      END IF
480     
481   END FUNCTION arth_i
482
483END MODULE random_generator_parallel
Note: See TracBrowser for help on using the repository browser.