source: palm/trunk/SOURCE/pmc_parent_mod.f90 @ 3241

Last change on this file since 3241 was 3241, checked in by raasch, 3 years ago

various changes to avoid compiler warnings (mainly removal of unused variables)

  • Property svn:keywords set to Id
File size: 34.9 KB
Line 
1 MODULE pmc_parent
2
3!------------------------------------------------------------------------------!
4! This file is part of the PALM model system.
5!
6! PALM is free software: you can redistribute it and/or modify it under the
7! terms of the GNU General Public License as published by the Free Software
8! Foundation, either version 3 of the License, or (at your option) any later
9! version.
10!
11! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
12! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
13! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
14!
15! You should have received a copy of the GNU General Public License along with
16! PALM. If not, see <http://www.gnu.org/licenses/>.
17!
18! Copyright 1997-2018 Leibniz Universitaet Hannover
19!------------------------------------------------------------------------------!
20!
21! Current revisions:
22! ------------------
23!
24!
25! Former revisions:
26! -----------------
27! $Id: pmc_parent_mod.f90 3241 2018-09-12 15:02:00Z raasch $
28! unused variables removed
29!
30! 3182 2018-07-27 13:36:03Z suehring
31! Comment extended
32!
33! 2841 2018-02-27 15:02:57Z Giersch
34! Bugfix: wrong placement of include 'mpif.h' corrected
35!
36! 2809 2018-02-15 09:55:58Z schwenkel
37! Bugfix for gfortran: Replace the function C_SIZEOF with STORAGE_SIZE
38!
39! 2801 2018-02-14 16:01:55Z thiele
40! Introduce particle transfer in nested models.
41!
42! 2718 2018-01-02 08:49:38Z maronga
43! Corrected "Former revisions" section
44!
45! 2696 2017-12-14 17:12:51Z kanani
46! Change in file header (GPL part)
47!
48! 2599 2017-11-01 13:18:45Z hellstea
49! Some cleanup and commenting improvements only.
50!
51! 2101 2017-01-05 16:42:31Z suehring
52!
53! 2000 2016-08-20 18:09:15Z knoop
54! Forced header and separation lines into 80 columns
55!
56! 1938 2016-06-13 15:26:05Z hellstea
57! Minor clean up.
58!
59! 1901 2016-05-04 15:39:38Z raasch
60! Module renamed. Code clean up. The words server/client changed to parent/child.
61!
62! 1900 2016-05-04 15:27:53Z raasch
63! re-formatted to match PALM style
64!
65! 1850 2016-04-08 13:29:27Z maronga
66! Module renamed
67!
68!
69! 1833 2016-04-07 14:23:03Z raasch
70! gfortran requires pointer attributes for some array declarations,
71! long line wrapped
72!
73! 1808 2016-04-05 19:44:00Z raasch
74! MPI module used by default on all machines
75!
76! 1797 2016-03-21 16:50:28Z raasch
77! introduction of different datatransfer modes
78!
79! 1791 2016-03-11 10:41:25Z raasch
80! Debug write-statements commented out
81!
82! 1786 2016-03-08 05:49:27Z raasch
83! change in child-parent data transfer: parent now gets data from child
84! instead that child put's it to the parent
85!
86! 1779 2016-03-03 08:01:28Z raasch
87! kind=dp replaced by wp,
88! error messages removed or changed to PALM style, dim_order removed
89! array management changed from linked list to sequential loop
90!
91! 1766 2016-02-29 08:37:15Z raasch
92! modifications to allow for using PALM's pointer version
93! +new routine pmc_s_set_active_data_array
94!
95! 1764 2016-02-28 12:45:19Z raasch
96! cpp-statement added (nesting can only be used in parallel mode)
97!
98! 1762 2016-02-25 12:31:13Z hellstea
99! Initial revision by K. Ketelsen
100!
101! Description:
102! ------------
103!
104! Parent part of Palm Model Coupler
105!------------------------------------------------------------------------------!
106
107#if defined( __parallel )
108    USE, INTRINSIC ::  ISO_C_BINDING
109
110#if !defined( __mpifh )
111    USE MPI
112#endif
113    USE kinds
114    USE pmc_general,                                                           &
115        ONLY: arraydef, childdef, da_namedef, da_namelen, pedef,               &
116              pmc_g_setname, pmc_max_array, pmc_max_models, pmc_sort
117
118    USE pmc_handle_communicator,                                               &
119        ONLY: m_model_comm,m_model_rank,m_model_npes, m_to_child_comm,         &
120              m_world_rank, pmc_parent_for_child
121
122    USE pmc_mpi_wrapper,                                                       &
123        ONLY: pmc_alloc_mem, pmc_bcast, pmc_time
124
125   IMPLICIT NONE
126
127#if defined( __mpifh )
128   INCLUDE "mpif.h"
129#endif
130
131   PRIVATE
132   SAVE
133
134   TYPE childindexdef
135      INTEGER                              ::  nrpoints       !<
136      INTEGER, DIMENSION(:,:), ALLOCATABLE ::  index_list_2d  !<
137   END TYPE childindexdef
138
139   TYPE(childdef), DIMENSION(pmc_max_models),PUBLIC   ::  children     !<
140   TYPE(childindexdef), DIMENSION(pmc_max_models)     ::  indchildren  !<
141
142   INTEGER ::  next_array_in_list = 0  !<
143
144
145   PUBLIC pmc_parent_for_child
146
147
148   INTERFACE pmc_parentinit
149      MODULE PROCEDURE  pmc_parentinit
150   END INTERFACE pmc_parentinit
151
152    INTERFACE pmc_s_set_2d_index_list
153        MODULE PROCEDURE pmc_s_set_2d_index_list
154    END INTERFACE pmc_s_set_2d_index_list
155
156    INTERFACE pmc_s_clear_next_array_list
157        MODULE PROCEDURE pmc_s_clear_next_array_list
158    END INTERFACE pmc_s_clear_next_array_list
159
160    INTERFACE pmc_s_getnextarray
161        MODULE PROCEDURE pmc_s_getnextarray
162    END INTERFACE pmc_s_getnextarray
163
164    INTERFACE pmc_s_set_dataarray
165        MODULE PROCEDURE pmc_s_set_dataarray_2d
166        MODULE PROCEDURE pmc_s_set_dataarray_3d
167        MODULE PROCEDURE pmc_s_set_dataarray_ip2d
168    END INTERFACE pmc_s_set_dataarray
169
170    INTERFACE pmc_s_setind_and_allocmem
171        MODULE PROCEDURE pmc_s_setind_and_allocmem
172    END INTERFACE pmc_s_setind_and_allocmem
173
174    INTERFACE pmc_s_fillbuffer
175        MODULE PROCEDURE pmc_s_fillbuffer
176    END INTERFACE pmc_s_fillbuffer
177
178    INTERFACE pmc_s_getdata_from_buffer
179        MODULE PROCEDURE pmc_s_getdata_from_buffer
180    END INTERFACE pmc_s_getdata_from_buffer
181
182    INTERFACE pmc_s_set_active_data_array
183        MODULE PROCEDURE pmc_s_set_active_data_array
184    END INTERFACE pmc_s_set_active_data_array
185
186    INTERFACE pmc_s_get_child_npes
187        MODULE PROCEDURE pmc_s_get_child_npes
188    END INTERFACE pmc_s_get_child_npes
189
190    PUBLIC pmc_parentinit, pmc_s_clear_next_array_list, pmc_s_fillbuffer,      &
191           pmc_s_getdata_from_buffer, pmc_s_getnextarray,                      &
192           pmc_s_setind_and_allocmem, pmc_s_set_active_data_array,             &
193           pmc_s_set_dataarray, pmc_s_set_2d_index_list,                       &
194           pmc_s_get_child_npes
195
196 CONTAINS
197
198
199 SUBROUTINE pmc_parentinit
200
201    IMPLICIT NONE
202
203    INTEGER(iwp) ::  childid   !<
204    INTEGER(iwp) ::  i         !<
205    INTEGER(iwp) ::  j         !<
206    INTEGER(iwp) ::  istat     !<
207
208    DO  i = 1, SIZE( pmc_parent_for_child )-1
209
210       childid = pmc_parent_for_child( i )
211
212       children(childid)%model_comm = m_model_comm
213       children(childid)%inter_comm = m_to_child_comm(childid)
214
215!
216!--    Get rank and size
217       CALL MPI_COMM_RANK( children(childid)%model_comm,                       &
218                           children(childid)%model_rank, istat )
219       CALL MPI_COMM_SIZE( children(childid)%model_comm,                       &
220                           children(childid)%model_npes, istat )
221       CALL MPI_COMM_REMOTE_SIZE( children(childid)%inter_comm,                &
222                                  children(childid)%inter_npes, istat )
223!
224!--    Intra communicator is used for MPI_GET
225       CALL MPI_INTERCOMM_MERGE( children(childid)%inter_comm, .FALSE.,        &
226                                 children(childid)%intra_comm, istat )
227       CALL MPI_COMM_RANK( children(childid)%intra_comm,                       &
228                           children(childid)%intra_rank, istat )
229
230       ALLOCATE( children(childid)%pes(children(childid)%inter_npes))
231!
232!--    Allocate array of TYPE arraydef for all child PEs to store information
233!--    of the transfer array
234       DO  j = 1, children(childid)%inter_npes
235         ALLOCATE( children(childid)%pes(j)%array_list(pmc_max_array) )
236       ENDDO
237
238       CALL get_da_names_from_child (childid)
239
240    ENDDO
241
242 END SUBROUTINE pmc_parentinit
243
244
245
246 SUBROUTINE pmc_s_set_2d_index_list( childid, index_list )
247
248     IMPLICIT NONE
249
250     INTEGER(iwp), INTENT(IN)                    :: childid     !<
251     INTEGER(iwp), DIMENSION(:,:), INTENT(INOUT) :: index_list  !<
252
253     INTEGER(iwp) ::  ian    !<
254     INTEGER(iwp) ::  ie     !<
255     INTEGER(iwp) ::  ip     !<
256     INTEGER(iwp) ::  is     !<
257     INTEGER(iwp) ::  istat  !<
258
259
260     IF ( m_model_rank == 0 )  THEN
261!
262!--     Sort to ascending parent process order
263        CALL pmc_sort( index_list, 6 )
264        is = 1
265        DO  ip = 0, m_model_npes-1
266!
267!--        Split into parent processes
268           ie = is - 1
269!
270!--        There may be no entry for this process
271           IF ( is <= SIZE( index_list,2 )  .AND.  ie >= 0 )  THEN
272              DO WHILE ( index_list(6,ie+1 ) == ip )
273                 ie = ie + 1
274                 IF ( ie == SIZE( index_list,2 ) )  EXIT
275              ENDDO
276              ian = ie - is + 1
277           ELSE
278              is  = -1
279              ie  = -2
280              ian =  0
281           ENDIF
282!
283!--        Send data to other parent processes
284           IF ( ip == 0 )  THEN
285              indchildren(childid)%nrpoints = ian
286              IF ( ian > 0)  THEN
287                  ALLOCATE( indchildren(childid)%index_list_2d(6,ian) )
288                  indchildren(childid)%index_list_2d(:,1:ian) =                &
289                                                             index_list(:,is:ie)
290              ENDIF
291           ELSE
292              CALL MPI_SEND( ian, 1, MPI_INTEGER, ip, 1000, m_model_comm,      &
293                             istat )
294              IF ( ian > 0)  THEN
295                  CALL MPI_SEND( index_list(1,is), 6*ian, MPI_INTEGER, ip,     &
296                                 1001, m_model_comm, istat )
297              ENDIF
298           ENDIF
299           is = ie + 1
300        ENDDO
301     ELSE
302        CALL MPI_RECV( indchildren(childid)%nrpoints, 1, MPI_INTEGER, 0, 1000, &
303                       m_model_comm, MPI_STATUS_IGNORE, istat )
304        ian = indchildren(childid)%nrpoints
305        IF ( ian > 0 )  THEN
306           ALLOCATE( indchildren(childid)%index_list_2d(6,ian) )
307           CALL MPI_RECV( indchildren(childid)%index_list_2d, 6*ian,           &
308                          MPI_INTEGER, 0, 1001, m_model_comm,                  &
309                          MPI_STATUS_IGNORE, istat)
310        ENDIF
311     ENDIF
312     CALL set_pe_index_list( childid, children(childid),                       &
313                             indchildren(childid)%index_list_2d,               &
314                             indchildren(childid)%nrpoints )
315
316 END SUBROUTINE pmc_s_set_2d_index_list
317
318
319
320 SUBROUTINE pmc_s_clear_next_array_list
321
322    IMPLICIT NONE
323
324    next_array_in_list = 0
325
326 END SUBROUTINE pmc_s_clear_next_array_list
327
328
329
330 LOGICAL FUNCTION pmc_s_getnextarray( childid, myname )
331
332!
333!-- Althoug there are no linked lists any more in PMC, this call still looks like working with a list
334
335    CHARACTER(LEN=*), INTENT(OUT) ::  myname    !<
336    INTEGER(iwp), INTENT(IN)      ::  childid   !<
337
338    TYPE(arraydef), POINTER :: ar
339    TYPE(pedef), POINTER    :: ape
340
341    next_array_in_list = next_array_in_list + 1
342!
343!-- Array names are the same on all children processes, so take first
344!-- process to get the name
345    ape => children(childid)%pes(1)
346
347    IF ( next_array_in_list > ape%nr_arrays )  THEN
348!
349!--    All arrays are done
350       pmc_s_getnextarray = .FALSE.
351       RETURN
352    ENDIF
353
354    ar => ape%array_list(next_array_in_list)
355    myname = ar%name
356!
357!-- Return true if there is still an array in the list
358
359    pmc_s_getnextarray = .TRUE.
360
361 END FUNCTION pmc_s_getnextarray
362
363
364
365 SUBROUTINE pmc_s_set_dataarray_2d( childid, array, array_2 )
366
367    IMPLICIT NONE
368
369    INTEGER(iwp), INTENT(IN) ::  childid   !<
370
371    REAL(wp), INTENT(IN), DIMENSION(:,:), POINTER           ::  array    !<
372    REAL(wp), INTENT(IN), DIMENSION(:,:), POINTER, OPTIONAL ::  array_2  !<
373
374    INTEGER(iwp)               ::  nrdims      !<
375    INTEGER(iwp), DIMENSION(4) ::  dims        !<
376    TYPE(C_PTR)           ::  array_adr   !<
377    TYPE(C_PTR)           ::  second_adr  !<
378
379
380    dims      = 1
381    nrdims    = 2
382    dims(1)   = SIZE( array,1 )
383    dims(2)   = SIZE( array,2 )
384    array_adr = C_LOC( array )
385
386    IF ( PRESENT( array_2 ) )  THEN
387       second_adr = C_LOC(array_2)
388       CALL pmc_s_setarray( childid, nrdims, dims, array_adr,                  &
389                            second_adr = second_adr)
390    ELSE
391       CALL pmc_s_setarray( childid, nrdims, dims, array_adr )
392    ENDIF
393
394 END SUBROUTINE pmc_s_set_dataarray_2d
395
396 SUBROUTINE pmc_s_set_dataarray_ip2d( childid, array )
397
398    IMPLICIT NONE
399
400    INTEGER(iwp),INTENT(IN) ::  childid   !<
401
402    INTEGER(idp), INTENT(IN), DIMENSION(:,:), POINTER           ::  array    !<
403
404    INTEGER(iwp)               ::  nrdims      !<
405    INTEGER(iwp), DIMENSION(4) ::  dims        !<
406    TYPE(C_PTR)           ::  array_adr   !<
407
408
409    dims      = 1
410    nrdims    = 2
411    dims(1)   = SIZE( array,1 )
412    dims(2)   = SIZE( array,2 )
413    array_adr = C_LOC( array )
414
415    CALL pmc_s_setarray( childid, nrdims, dims, array_adr , dimkey=22)
416
417 END SUBROUTINE pmc_s_set_dataarray_ip2d
418
419
420 SUBROUTINE pmc_s_set_dataarray_3d( childid, array, nz_cl, nz, array_2 )
421
422    IMPLICIT NONE
423
424    INTEGER(iwp), INTENT(IN) ::  childid   !<
425    INTEGER(iwp), INTENT(IN) ::  nz        !<
426    INTEGER(iwp), INTENT(IN) ::  nz_cl     !<
427
428    REAL(wp), INTENT(IN), DIMENSION(:,:,:), POINTER           ::  array    !<
429    REAL(wp), INTENT(IN), DIMENSION(:,:,:), POINTER, OPTIONAL ::  array_2  !<
430
431    INTEGER(iwp)               ::  nrdims      !<
432    INTEGER(iwp), DIMENSION(4) ::  dims        !<
433    TYPE(C_PTR)           ::  array_adr   !<
434    TYPE(C_PTR)           ::  second_adr  !<
435
436    nrdims    = 3
437    dims(1)   = SIZE( array,1 )
438    dims(2)   = SIZE( array,2 )
439    dims(3)   = SIZE( array,3 )
440    dims(4)   = nz_cl+dims(1)-nz  ! works for first dimension 1:nz and 0:nz+1
441
442    array_adr = C_LOC(array)
443!
444!-- In PALM's pointer version, two indices have to be stored internally.
445!-- The active address of the data array is set in swap_timelevel.
446    IF ( PRESENT( array_2 ) )  THEN
447      second_adr = C_LOC( array_2 )
448      CALL pmc_s_setarray( childid, nrdims, dims, array_adr,                   &
449                           second_adr = second_adr)
450    ELSE
451       CALL pmc_s_setarray( childid, nrdims, dims, array_adr )
452    ENDIF
453
454 END SUBROUTINE pmc_s_set_dataarray_3d
455
456
457
458 SUBROUTINE pmc_s_setind_and_allocmem( childid )
459
460    USE control_parameters,                                                    &
461        ONLY:  message_string
462
463    IMPLICIT NONE
464
465!
466!-- Naming convention for appendices:   _pc  -> parent to child transfer
467!--                                     _cp  -> child to parent transfer
468!--                                     send -> parent to child transfer
469!--                                     recv -> child to parent transfer
470    INTEGER(iwp), INTENT(IN) ::  childid   !<
471
472    INTEGER(iwp)                   ::  arlen    !<
473    INTEGER(iwp)                   ::  i        !<
474    INTEGER(iwp)                   ::  ierr     !<
475    INTEGER(iwp)                   ::  j        !<
476    INTEGER(iwp)                   ::  myindex  !<
477    INTEGER(iwp)                   ::  rcount   !< count MPI requests
478    INTEGER(iwp)                   ::  tag      !<
479
480    INTEGER(idp)                   ::  bufsize  !< size of MPI data window
481    INTEGER(KIND=MPI_ADDRESS_KIND) ::  winsize  !<
482
483    INTEGER(iwp), DIMENSION(1024)       ::  req      !<
484
485    TYPE(C_PTR)             ::  base_ptr  !<
486    TYPE(pedef), POINTER    ::  ape       !<
487    TYPE(arraydef), POINTER ::  ar        !<
488
489    REAL(wp),DIMENSION(:), POINTER, SAVE ::  base_array_pc  !< base array for parent to child transfer
490    REAL(wp),DIMENSION(:), POINTER, SAVE ::  base_array_cp  !< base array for child to parent transfer
491
492!
493!-- Parent to child direction
494    myindex = 1
495    rcount  = 0
496    bufsize = 8
497!
498!-- First stride: compute size and set index
499    DO  i = 1, children(childid)%inter_npes
500
501       ape => children(childid)%pes(i)
502       tag = 200
503
504       DO  j = 1, ape%nr_arrays
505
506          ar  => ape%array_list(j)
507          IF ( ar%nrdims == 2 )  THEN
508             arlen = ape%nrele
509          ELSEIF ( ar%nrdims == 3 )  THEN
510             arlen = ape%nrele * ar%a_dim(4)
511          ELSE
512             arlen = -1
513          ENDIF
514          ar%sendindex = myindex
515
516          tag    = tag + 1
517          rcount = rcount + 1
518          CALL MPI_ISEND( myindex, 1, MPI_INTEGER, i-1, tag,                   &
519                          children(childid)%inter_comm, req(rcount), ierr )
520!
521!--       Maximum of 1024 pending requests
522
523          IF ( rcount == 1024 )  THEN
524             CALL MPI_WAITALL( rcount, req, MPI_STATUSES_IGNORE, ierr )
525             rcount = 0
526          ENDIF
527
528          myindex = myindex + arlen
529          bufsize = bufsize + arlen
530          ar%sendsize = arlen
531       ENDDO
532
533       IF ( rcount > 0 )  THEN
534          CALL MPI_WAITALL( rcount, req, MPI_STATUSES_IGNORE, ierr )
535       ENDIF
536
537    ENDDO
538!
539!-- Create RMA (One Sided Communication) window for data buffer parent to
540!-- child transfer.
541!-- The buffer of MPI_GET (counterpart of transfer) can be PE-local, i.e.
542!-- it can but must not be part of the MPI RMA window. Only one RMA window is
543!-- required to prepare the data for
544!--                       parent -> child transfer on the parent side
545!-- and for
546!--                       child -> parent transfer on the child side
547    CALL pmc_alloc_mem( base_array_pc, bufsize )
548    children(childid)%totalbuffersize = bufsize * wp
549
550    winsize = bufsize * wp
551    CALL MPI_WIN_CREATE( base_array_pc, winsize, wp, MPI_INFO_NULL,            &
552                         children(childid)%intra_comm,                         &
553                         children(childid)%win_parent_child, ierr )
554!
555!-- Open window to set data
556    CALL MPI_WIN_FENCE( 0, children(childid)%win_parent_child, ierr )
557!
558!-- Second stride: set buffer pointer
559    DO  i = 1, children(childid)%inter_npes
560
561       ape => children(childid)%pes(i)
562
563       DO  j = 1, ape%nr_arrays
564
565          ar => ape%array_list(j)
566          ar%sendbuf = C_LOC( base_array_pc(ar%sendindex) )
567
568          IF ( ar%sendindex + ar%sendsize > bufsize )  THEN             
569             WRITE( message_string, '(a,i4,4i7,1x,a)' )                        &
570                    'parent buffer too small ',i,                              &
571                    ar%sendindex,ar%sendsize,ar%sendindex+ar%sendsize,         &
572                    bufsize,trim(ar%name)
573             CALL message( 'pmc_s_setind_and_allocmem', 'PA0429', 3, 2, 0, 6, 0 )
574          ENDIF
575       ENDDO
576    ENDDO
577!
578!-- Child to parent direction
579    bufsize = 8
580!
581!-- First stride: compute size and set index
582    DO  i = 1, children(childid)%inter_npes
583       ape => children(childid)%pes(i)
584       tag = 300
585       DO  j = 1, ape%nr_arrays
586          ar => ape%array_list(j)
587!
588!--       Receive index from child
589          tag = tag + 1
590          CALL MPI_RECV( myindex, 1, MPI_INTEGER, i-1, tag,                    &
591                         children(childid)%inter_comm, MPI_STATUS_IGNORE, ierr )
592          IF ( ar%nrdims == 3 )  THEN
593             bufsize = MAX( bufsize, ape%nrele * ar%a_dim(4) )
594          ELSE
595             bufsize = MAX( bufsize, ape%nrele )
596          ENDIF
597          ar%recvindex = myindex
598        ENDDO
599    ENDDO
600!
601!-- Create RMA (one sided communication, RMA = Remote Memory Access) data buffer.
602!-- The buffer for MPI_GET can be PE local, i.e. it can but must not be part of
603!-- the MPI RMA window
604    CALL pmc_alloc_mem( base_array_cp, bufsize, base_ptr )
605    children(childid)%totalbuffersize = bufsize * wp
606
607    CALL MPI_BARRIER( children(childid)%intra_comm, ierr )
608!
609!-- Second stride: set buffer pointer
610    DO  i = 1, children(childid)%inter_npes
611       ape => children(childid)%pes(i)
612       DO  j = 1, ape%nr_arrays
613          ar => ape%array_list(j)
614          ar%recvbuf = base_ptr
615       ENDDO
616    ENDDO
617
618 END SUBROUTINE pmc_s_setind_and_allocmem
619
620
621
622 SUBROUTINE pmc_s_fillbuffer( childid, waittime, particle_transfer )
623
624    IMPLICIT NONE
625
626    INTEGER(iwp), INTENT(IN)             ::  childid   !<
627
628    REAL(wp), INTENT(OUT), OPTIONAL ::  waittime  !<
629    LOGICAL, INTENT(IN), OPTIONAL   ::  particle_transfer  !<
630
631
632    INTEGER(iwp)               ::  ierr     !<
633    INTEGER(iwp)               ::  ij       !<
634    INTEGER(iwp)               ::  ip       !<
635    INTEGER(iwp)               ::  j        !<
636    INTEGER(iwp)               ::  myindex  !<
637   
638    LOGICAL                    ::  lo_ptrans
639
640    INTEGER(iwp), DIMENSION(1) ::  buf_shape
641
642    REAL(wp)                            ::  t1       !<
643    REAL(wp)                            ::  t2       !<
644    REAL(wp), POINTER, DIMENSION(:)     ::  buf      !<
645    REAL(wp), POINTER, DIMENSION(:,:)   ::  data_2d  !<
646    REAL(wp), POINTER, DIMENSION(:,:,:) ::  data_3d  !<
647    INTEGER(idp), POINTER, DIMENSION(:)     ::  ibuf      !<
648    INTEGER(idp), POINTER, DIMENSION(:,:)   ::  idata_2d  !<
649
650    TYPE(pedef), POINTER    ::  ape  !<
651    TYPE(arraydef), POINTER ::  ar   !<
652
653!
654!-- Synchronization of the model is done in pmci_synchronize.
655!-- Therefor the RMA window can be filled without
656!-- sychronization at this point and a barrier is not necessary.
657!-- Please note that waittime has to be set in pmc_s_fillbuffer AND
658!-- pmc_c_getbuffer
659    IF ( PRESENT( waittime) )  THEN
660      t1 = pmc_time()
661      CALL MPI_BARRIER( children(childid)%intra_comm, ierr )
662      t2 = pmc_time()
663      waittime = t2- t1
664    ENDIF
665
666    lo_ptrans = .FALSE.
667    IF ( PRESENT( particle_transfer))    lo_ptrans = particle_transfer
668
669    DO  ip = 1, children(childid)%inter_npes
670       ape => children(childid)%pes(ip)
671       DO  j = 1, ape%nr_arrays
672          ar => ape%array_list(j)
673          myindex = 1
674
675          IF ( ar%dimkey == 2 .AND. .NOT.lo_ptrans  )  THEN                            ! PALM 2D REAL*8 Array
676
677             buf_shape(1) = ape%nrele
678             CALL C_F_POINTER( ar%sendbuf, buf, buf_shape )
679             CALL C_F_POINTER( ar%data, data_2d, ar%a_dim(1:2) )
680             DO  ij = 1, ape%nrele
681                buf(myindex) = data_2d(ape%locind(ij)%j,ape%locind(ij)%i)
682                myindex = myindex + 1
683             ENDDO
684
685          ELSEIF ( ar%dimkey == 3  .AND. .NOT.lo_ptrans  )  THEN                       ! PALM 3D REAL*8 Array
686
687             buf_shape(1) = ape%nrele*ar%a_dim(4)
688             CALL C_F_POINTER( ar%sendbuf, buf, buf_shape )
689             CALL C_F_POINTER( ar%data, data_3d, ar%a_dim(1:3) )
690             DO  ij = 1, ape%nrele
691                buf(myindex:myindex+ar%a_dim(4)-1) =                            &
692                        data_3d(1:ar%a_dim(4),ape%locind(ij)%j,ape%locind(ij)%i)
693                myindex = myindex + ar%a_dim(4)
694             ENDDO
695          ELSEIF ( ar%dimkey == 22 .AND. lo_ptrans  )  THEN                           ! 2D INTEGER*8 Array for particle Transfer
696
697             buf_shape(1) = ape%nrele
698             CALL C_F_POINTER( ar%sendbuf, ibuf, buf_shape )
699             CALL C_F_POINTER( ar%data, idata_2d, ar%a_dim(1:2) )
700             DO  ij = 1, ape%nrele
701                ibuf(myindex) = idata_2d(ape%locind(ij)%j,ape%locind(ij)%i)
702                myindex = myindex + 1
703             ENDDO
704          ENDIF
705        ENDDO
706    ENDDO
707!
708!-- Buffer is filled
709    CALL MPI_BARRIER( children(childid)%intra_comm, ierr )
710
711 END SUBROUTINE pmc_s_fillbuffer
712
713
714
715 SUBROUTINE pmc_s_getdata_from_buffer( childid, waittime , particle_transfer, child_process_nr )
716
717    IMPLICIT NONE
718
719    INTEGER(iwp), INTENT(IN)             ::  childid      !<
720    REAL(wp), INTENT(OUT), OPTIONAL ::  waittime     !<
721    LOGICAL, INTENT(IN), OPTIONAL   ::  particle_transfer     !<
722    INTEGER(iwp), INTENT(IN), OPTIONAL   ::  child_process_nr      !<
723
724    INTEGER(iwp)                        ::  ierr          !<
725    INTEGER(iwp)                   ::  ij            !<
726    INTEGER(iwp)                   ::  ip            !<
727    INTEGER(iwp)                   ::  ip_start      !<
728    INTEGER(iwp)                   ::  ip_end        !<
729    INTEGER(iwp)                   ::  j             !<
730    INTEGER(iwp)                   ::  myindex       !<
731    INTEGER(iwp)                   ::  nr            !<
732    INTEGER(iwp)                   ::  target_pe     !<
733    INTEGER(KIND=MPI_ADDRESS_KIND) ::  target_disp   !<
734   
735    LOGICAL                        ::  lo_ptrans
736
737    INTEGER(iwp), DIMENSION(1)          ::  buf_shape     !<
738
739    REAL(wp)                                ::  t1       !<
740    REAL(wp)                                ::  t2       !<
741    REAL(wp), POINTER, DIMENSION(:)         ::  buf      !<
742    REAL(wp), POINTER, DIMENSION(:,:)       ::  data_2d  !<
743    REAL(wp), POINTER, DIMENSION(:,:,:)     ::  data_3d  !<
744    INTEGER(idp), POINTER, DIMENSION(:)     ::  ibuf      !<
745    INTEGER(idp), POINTER, DIMENSION(:,:)   ::  idata_2d  !<
746
747    TYPE(pedef), POINTER                    ::  ape  !<
748    TYPE(arraydef), POINTER                 ::  ar   !<
749
750
751    t1 = pmc_time()
752
753    IF(PRESENT(child_process_nr)) then
754       ip_start = child_process_nr
755       ip_end   = child_process_nr
756    ELSE
757       ip_start = 1
758       ip_end   = children(childid)%inter_npes
759    END IF
760
761    lo_ptrans = .FALSE.
762    IF ( PRESENT( particle_transfer))    lo_ptrans = particle_transfer
763
764    IF(ip_start == 1)   THEN
765!
766!--    Wait for child to fill buffer
767       CALL MPI_BARRIER( children(childid)%intra_comm, ierr )
768       t2 = pmc_time() - t1
769       IF ( PRESENT( waittime ) )  waittime = t2
770
771       CALL MPI_BARRIER( children(childid)%intra_comm, ierr )
772    ENDIF
773
774    DO  ip = ip_start,ip_end
775       ape => children(childid)%pes(ip)
776       DO  j = 1, ape%nr_arrays
777          ar => ape%array_list(j)
778         
779          IF ( ar%recvindex < 0 )  CYCLE
780
781          IF ( ar%dimkey == 2  .AND. .NOT.lo_ptrans  )  THEN
782             nr = ape%nrele
783          ELSEIF ( ar%dimkey == 3  .AND. .NOT.lo_ptrans  )  THEN
784             nr = ape%nrele * ar%a_dim(4)
785          ELSE IF ( ar%dimkey == 22 .AND. lo_ptrans)  THEN
786             nr = ape%nrele
787          ELSE
788             CYCLE                                        !particle array are not transfered here
789          ENDIF
790          buf_shape(1) = nr
791          IF(lo_ptrans)   THEN
792             CALL C_F_POINTER( ar%recvbuf, ibuf, buf_shape )
793          ELSE
794             CALL C_F_POINTER( ar%recvbuf, buf, buf_shape )
795          ENDIF
796
797!
798!--       MPI passive target RMA
799          IF ( nr > 0 )  THEN
800             target_disp = ar%recvindex - 1
801!
802!--          Child processes are located behind parent process
803             target_pe = ip - 1 + m_model_npes
804             CALL MPI_WIN_LOCK( MPI_LOCK_SHARED, target_pe, 0,                      &
805                                children(childid)%win_parent_child, ierr )
806             IF(lo_ptrans)   THEN
807                CALL MPI_GET( ibuf, nr*8, MPI_BYTE, target_pe, target_disp, nr*8,    &              !There is no MPI_INTEGER8 datatype
808                              MPI_BYTE, children(childid)%win_parent_child, ierr )
809             ELSE
810                CALL MPI_GET( buf, nr, MPI_REAL, target_pe, target_disp, nr,        &
811                              MPI_REAL, children(childid)%win_parent_child, ierr )
812             ENDIF
813             CALL MPI_WIN_UNLOCK( target_pe,                                        &
814                                  children(childid)%win_parent_child, ierr )
815          ENDIF
816          myindex = 1
817          IF ( ar%dimkey == 2  .AND. .NOT.lo_ptrans  )  THEN
818
819             CALL C_F_POINTER( ar%data, data_2d, ar%a_dim(1:2) )
820             DO  ij = 1, ape%nrele
821                data_2d(ape%locind(ij)%j,ape%locind(ij)%i) = buf(myindex)
822                myindex = myindex + 1
823             ENDDO
824
825          ELSEIF ( ar%dimkey == 3  .AND. .NOT.lo_ptrans  )  THEN
826
827             CALL C_F_POINTER( ar%data, data_3d, ar%a_dim(1:3))
828             DO  ij = 1, ape%nrele
829                data_3d(1:ar%a_dim(4),ape%locind(ij)%j,ape%locind(ij)%i) =     &
830                                              buf(myindex:myindex+ar%a_dim(4)-1)
831                myindex = myindex + ar%a_dim(4)
832             ENDDO
833
834          ELSE IF ( ar%dimkey == 22 .AND. lo_ptrans)  THEN
835
836             CALL C_F_POINTER( ar%data, idata_2d, ar%a_dim(1:2) )
837             DO  ij = 1, ape%nrele
838                idata_2d(ape%locind(ij)%j,ape%locind(ij)%i) = ibuf(myindex)
839                myindex = myindex + 1
840             ENDDO
841
842          ENDIF
843       ENDDO
844    ENDDO
845
846 END SUBROUTINE pmc_s_getdata_from_buffer
847
848
849
850 SUBROUTINE get_da_names_from_child( childid )
851
852!
853!-- Get data array description and name from child
854    IMPLICIT NONE
855
856    INTEGER(iwp), INTENT(IN) ::  childid  !<
857
858    TYPE(da_namedef) ::  myname  !<
859
860    DO
861       CALL pmc_bcast( myname%couple_index, 0, comm=m_to_child_comm(childid) )
862
863       IF ( myname%couple_index == -1 )  EXIT
864
865       CALL pmc_bcast( myname%parentdesc,   0, comm=m_to_child_comm(childid) )
866       CALL pmc_bcast( myname%nameonparent, 0, comm=m_to_child_comm(childid) )
867       CALL pmc_bcast( myname%childdesc,    0, comm=m_to_child_comm(childid) )
868       CALL pmc_bcast( myname%nameonchild,  0, comm=m_to_child_comm(childid) )
869
870       CALL pmc_g_setname( children(childid), myname%couple_index,             &
871                           myname%nameonparent )
872   ENDDO
873
874 END SUBROUTINE get_da_names_from_child
875
876
877
878 SUBROUTINE pmc_s_setarray(childid, nrdims, dims, array_adr, second_adr, dimkey )
879
880!
881!-- Set array for child inter process 0
882    IMPLICIT NONE
883
884    INTEGER(iwp), INTENT(IN)               :: childid    !<
885    INTEGER(iwp), INTENT(IN)               :: nrdims     !<
886    INTEGER(iwp), INTENT(IN), DIMENSION(:) :: dims       !<
887
888    TYPE(C_PTR), INTENT(IN)           :: array_adr  !<
889    TYPE(C_PTR), INTENT(IN), OPTIONAL :: second_adr !<
890    INTEGER(iwp), INTENT(IN), OPTIONAL     :: dimkey     !<
891
892    INTEGER(iwp) ::  i  !< local counter
893
894    TYPE(pedef), POINTER    ::  ape  !<
895    TYPE(arraydef), POINTER ::  ar   !<
896
897
898    DO  i = 1, children(childid)%inter_npes
899       ape => children(childid)%pes(i)
900       ar  => ape%array_list(next_array_in_list)
901       ar%nrdims = nrdims
902       ar%dimkey = nrdims
903       IF(PRESENT(dimkey)) ar%dimkey = dimkey
904       ar%a_dim  = dims
905       ar%data   = array_adr
906       IF ( PRESENT( second_adr ) )  THEN
907          ar%po_data(1) = array_adr
908          ar%po_data(2) = second_adr
909       ELSE
910          ar%po_data(1) = C_NULL_PTR
911          ar%po_data(2) = C_NULL_PTR
912       ENDIF
913    ENDDO
914
915 END SUBROUTINE pmc_s_setarray
916
917
918
919 SUBROUTINE pmc_s_set_active_data_array( childid, iactive )
920
921    IMPLICIT NONE
922
923    INTEGER(iwp), INTENT(IN) ::  childid   !<
924    INTEGER(iwp), INTENT(IN) ::  iactive   !<
925
926    INTEGER(iwp) :: ip  !<
927    INTEGER(iwp) :: j   !<
928
929    TYPE(pedef), POINTER    ::  ape  !<
930    TYPE(arraydef), POINTER ::  ar   !<
931
932    DO  ip = 1, children(childid)%inter_npes
933       ape => children(childid)%pes(ip)
934       DO  j = 1, ape%nr_arrays
935          ar => ape%array_list(j)
936          if(mod(ar%dimkey,10) == 2) CYCLE           !Not for 2D array
937          IF ( iactive == 1  .OR.  iactive == 2 )  THEN
938             ar%data = ar%po_data(iactive)
939          ENDIF
940       ENDDO
941    ENDDO
942
943 END SUBROUTINE pmc_s_set_active_data_array
944
945 INTEGER FUNCTION pmc_s_get_child_npes (child_id)
946   IMPLICIT NONE
947
948   INTEGER(iwp),INTENT(IN)                 :: child_id
949
950   pmc_s_get_child_npes = children(child_id)%inter_npes
951
952   RETURN
953 END FUNCTION pmc_s_get_child_npes
954
955
956 SUBROUTINE set_pe_index_list( childid, mychild, index_list, nrp )
957
958    IMPLICIT NONE
959
960    INTEGER(iwp), INTENT(IN)                 ::  childid     !<
961    INTEGER(iwp), INTENT(IN), DIMENSION(:,:) ::  index_list  !<
962    INTEGER(iwp), INTENT(IN)                 ::  nrp         !<
963
964    TYPE(childdef), INTENT(INOUT)       ::  mychild     !<
965
966    INTEGER(iwp)                            :: i        !<
967    INTEGER(iwp)                            :: ierr     !<
968    INTEGER(iwp)                            :: ind      !<
969    INTEGER(iwp)                            :: indwin   !<
970    INTEGER(iwp)                            :: indwin2  !<
971    INTEGER(iwp)                            :: i2       !<
972    INTEGER(iwp)                            :: j        !<
973    INTEGER(iwp)                            :: rempe    !<
974    INTEGER(KIND=MPI_ADDRESS_KIND)          :: winsize  !<
975
976    INTEGER(iwp), DIMENSION(mychild%inter_npes)  :: remind   !<
977
978    INTEGER(iwp), DIMENSION(:), POINTER          :: remindw  !<
979    INTEGER(iwp), DIMENSION(:), POINTER          :: rldef    !<
980
981    TYPE(pedef), POINTER                    :: ape      !<
982
983!
984!-- First, count entries for every remote child process
985    DO  i = 1, mychild%inter_npes
986       ape => mychild%pes(i)
987       ape%nrele = 0
988    ENDDO
989!
990!-- Loop over number of coarse grid cells
991    DO  j = 1, nrp
992       rempe = index_list(5,j) + 1   ! process number on remote process
993       ape => mychild%pes(rempe)
994       ape%nrele = ape%nrele + 1     ! Increment number of elements for this child process
995    ENDDO
996
997    DO  i = 1, mychild%inter_npes
998       ape => mychild%pes(i)
999       ALLOCATE( ape%locind(ape%nrele) )
1000    ENDDO
1001
1002    remind = 0
1003!
1004!-- Second, create lists
1005!-- Loop over number of coarse grid cells
1006    DO  j = 1, nrp
1007       rempe = index_list(5,j) + 1
1008       ape => mychild%pes(rempe)
1009       remind(rempe)     = remind(rempe)+1
1010       ind               = remind(rempe)
1011       ape%locind(ind)%i = index_list(1,j)
1012       ape%locind(ind)%j = index_list(2,j)
1013    ENDDO
1014!
1015!-- Prepare number of elements for children processes
1016    CALL pmc_alloc_mem( rldef, mychild%inter_npes*2 )
1017!
1018!-- Number of child processes * size of INTEGER (i just arbitrary INTEGER)
1019    winsize = mychild%inter_npes*STORAGE_SIZE(i)/8*2
1020
1021    CALL MPI_WIN_CREATE( rldef, winsize, iwp, MPI_INFO_NULL,                   &
1022                         mychild%intra_comm, indwin, ierr )
1023!
1024!-- Open window to set data
1025    CALL MPI_WIN_FENCE( 0, indwin, ierr )
1026
1027    rldef(1) = 0            ! index on remote process 0
1028    rldef(2) = remind(1)    ! number of elements on remote process 0
1029!
1030!-- Reserve buffer for index array
1031    DO  i = 2, mychild%inter_npes
1032       i2          = (i-1) * 2 + 1
1033       rldef(i2)   = rldef(i2-2) + rldef(i2-1) * 2  ! index on remote process
1034       rldef(i2+1) = remind(i)                      ! number of elements on remote process
1035    ENDDO
1036!
1037!-- Close window to allow child to access data
1038    CALL MPI_WIN_FENCE( 0, indwin, ierr )
1039!
1040!-- Child has retrieved data
1041    CALL MPI_WIN_FENCE( 0, indwin, ierr )
1042
1043    i2 = 2 * mychild%inter_npes - 1
1044    winsize = ( rldef(i2) + rldef(i2+1) ) * 2
1045!
1046!-- Make sure, MPI_ALLOC_MEM works
1047    winsize = MAX( winsize, 1 )
1048
1049    CALL pmc_alloc_mem( remindw, INT( winsize ) )
1050
1051    CALL MPI_BARRIER( m_model_comm, ierr )
1052    CALL MPI_WIN_CREATE( remindw, winsize*STORAGE_SIZE(i)/8, iwp, MPI_INFO_NULL,     &
1053                         mychild%intra_comm, indwin2, ierr )
1054!
1055!-- Open window to set data
1056    CALL MPI_WIN_FENCE( 0, indwin2, ierr )
1057!
1058!-- Create the 2D index list
1059    DO  j = 1, nrp
1060       rempe = index_list(5,j) + 1    ! process number on remote process
1061       ape => mychild%pes(rempe)
1062       i2    = rempe * 2 - 1
1063       ind   = rldef(i2) + 1
1064       remindw(ind)   = index_list(3,j)
1065       remindw(ind+1) = index_list(4,j)
1066       rldef(i2)      = rldef(i2)+2
1067    ENDDO
1068!
1069!-- All data are set
1070    CALL MPI_WIN_FENCE( 0, indwin2, ierr )
1071!
1072!-- Don't know why, but this barrier is necessary before windows can be freed
1073!-- TODO: find out why this is required
1074    CALL MPI_BARRIER( mychild%intra_comm, ierr )
1075
1076    CALL MPI_WIN_FREE( indwin, ierr )
1077    CALL MPI_WIN_FREE( indwin2, ierr )
1078
1079!
1080!-- TODO: check if the following idea needs to be done
1081!-- Sollte funktionieren, Problem mit MPI implementation
1082!-- https://www.lrz.de/services/software/parallel/mpi/onesided
1083!-- CALL MPI_Free_mem (remindw, ierr)
1084
1085 END SUBROUTINE set_pe_index_list
1086
1087#endif
1088 END MODULE pmc_parent
Note: See TracBrowser for help on using the repository browser.