source: palm/trunk/SOURCE/parin.f90 @ 1933

Last change on this file since 1933 was 1933, checked in by hellstea, 5 years ago

last commit documented

  • Property svn:keywords set to Id
File size: 24.9 KB
Line 
1!> @file parin.f90
2!--------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the terms
6! of the GNU General Public License as published by the Free Software Foundation,
7! either version 3 of the License, or (at your option) any later version.
8!
9! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
10! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
11! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
12!
13! You should have received a copy of the GNU General Public License along with
14! PALM. If not, see <http://www.gnu.org/licenses/>.
15!
16! Copyright 1997-2016 Leibniz Universitaet Hannover
17!--------------------------------------------------------------------------------!
18!
19! Current revisions:
20! -----------------
21!
22!
23! Former revisions:
24! -----------------
25! $Id: parin.f90 1933 2016-06-13 07:12:51Z hellstea $
26!
27! 1917 2016-05-27 14:28:12Z witha
28! Initial version of purely vertical nesting introduced.
29!
30! 1914 2016-05-26 14:44:07Z witha
31! Added call to wind turbine model for reading of &wind_turbine_par
32!
33! 1849 2016-04-08 11:33:18Z hoffmann
34! Adapted for modularization of microphysics
35!
36! 1833 2016-04-07 14:23:03Z raasch
37! call of spectra_parin
38!
39! 1831 2016-04-07 13:15:51Z hoffmann
40! turbulence renamed collision_turbulence, drizzle renamed
41! cloud_water_sedimentation
42! curvature_solution_effects removed
43!
44! 1826 2016-04-07 12:01:39Z maronga
45! Added call to radiation model for reading of &radiation_par.
46! Added call to plant canopy model for reading of &canopy_par.
47!
48! 1817 2016-04-06 15:44:20Z maronga
49! Added call to land surface model for reading of &lsm_par
50!
51! 1804 2016-04-05 16:30:18Z maronga
52! Removed code for parameter file check (__check)
53!
54! 1783 2016-03-06 18:36:17Z raasch
55! +netcdf_deflate in d3par, netcdf module and variable names changed
56!
57! 1764 2016-02-28 12:45:19Z raasch
58! cpp-statements for nesting removed, explicit settings of boundary conditions
59! in nest domains,
60! bugfix: npex/npey message moved from inipar to d3par
61! bugfix: check of lateral boundary conditions from check_parameters to here,
62! because they will be already used in init_pegrid and init_grid
63!
64! 1762 2016-02-25 12:31:13Z hellstea
65! Introduction of nested domain feature
66!
67! 1691 2015-10-26 16:17:44Z maronga
68! Added parameter most_method. Renamed prandtl_layer to constant_flux_layer.
69!
70! 1682 2015-10-07 23:56:08Z knoop
71! Code annotations made doxygen readable
72!
73! 1560 2015-03-06 10:48:54Z keck
74! +recycling_yshift
75!
76! 1496 2014-12-02 17:25:50Z maronga
77! Renamed: "radiation -> "cloud_top_radiation"
78!
79! 1484 2014-10-21 10:53:05Z kanani
80! Changes due to new module structure of the plant canopy model:
81!   canopy-model related parameters moved to new package canopy_par in
82!   subroutine package_parin
83!
84! 1429 2014-07-15 12:53:45Z knoop
85! +ensemble_member_nr to prepare the random_generator for ensemble runs
86!
87! 1402 2014-05-09 14:25:13Z raasch
88! location messages modified, batch_job included in envpar-NAMELIST
89!
90! 1384 2014-05-02 14:31:06Z raasch
91! location messages added
92!
93! 1365 2014-04-22 15:03:56Z boeske
94! Usage of large scale forcing enabled:
95! +use_subsidence_tendencies
96!
97! 1361 2014-04-16 15:17:48Z hoffmann
98! +call_microphysics_at_all_substeps
99!
100! 1359 2014-04-11 17:15:14Z hoffmann
101! REAL constants provided with KIND-attribute
102!
103! 1353 2014-04-08 15:21:23Z heinze
104! REAL constants provided with KIND-attribute
105!
106! 1327 2014-03-21 11:00:16Z raasch
107! -data_output_format, do3d_compress, do3d_comp_prec
108!
109! 1320 2014-03-20 08:40:49Z raasch
110! ONLY-attribute added to USE-statements,
111! kind-parameters added to all INTEGER and REAL declaration statements,
112! kinds are defined in new module kinds,
113! old module precision_kind is removed,
114! revision history before 2012 removed,
115! comment fields (!:) to be used for variable explanations added to
116! all variable declaration statements
117!
118! 1318 2014-03-17 13:35:16Z raasch
119! +cpu_log_barrierwait in d3par
120!
121! 1301 2014-03-06 13:29:46Z heinze
122! +large_scale_subsidence
123!
124! 1241 2013-10-30 11:36:58Z heinze
125! +nudging
126! +large_scale_forcing
127!
128! 1216 2013-08-26 09:31:42Z raasch
129! +transpose_compute_overlap in inipar
130!
131! 1195 2013-07-01 12:27:57Z heinze
132! Bugfix: allocate ref_state
133!
134! 1179 2013-06-14 05:57:58Z raasch
135! +reference_state in inipar
136!
137! 1159 2013-05-21 11:58:22Z fricke
138! +use_cmax
139!
140! 1128 2013-04-12 06:19:32Z raasch
141! +background_communication in inipar
142!
143! 1115 2013-03-26 18:16:16Z hoffmann
144! unused variables removed
145!
146! 1092 2013-02-02 11:24:22Z raasch
147! unused variables removed
148!
149! 1065 2012-11-22 17:42:36Z hoffmann
150! +nc, c_sedimentation, limiter_sedimentation, turbulence
151! -mu_constant, mu_constant_value
152!
153! 1053 2012-11-13 17:11:03Z hoffmann
154! necessary expansions according to the two new prognostic equations (nr, qr)
155! of the two-moment cloud physics scheme and steering parameters:
156! +*_init, *_surface, *_surface_initial_change, *_vertical_gradient,
157! +*_vertical_gradient_level, surface_waterflux_*,
158! +cloud_scheme, drizzle, mu_constant, mu_constant_value, ventilation_effect
159!
160! 1036 2012-10-22 13:43:42Z raasch
161! code put under GPL (PALM 3.9)
162!
163! 1015 2012-09-27 09:23:24Z raasch
164! -adjust_mixing_length
165!
166! 1003 2012-09-14 14:35:53Z raasch
167! -grid_matching
168!
169! 1001 2012-09-13 14:08:46Z raasch
170! -cut_spline_overshoot, long_filter_factor, overshoot_limit_*, ups_limit_*
171!
172! 996 2012-09-07 10:41:47Z raasch
173! -use_prior_plot1d_parameters
174!
175! 978 2012-08-09 08:28:32Z fricke
176! -km_damp_max, outflow_damping_width
177! +pt_damping_factor, pt_damping_width
178! +z0h_factor
179!
180! 964 2012-07-26 09:14:24Z raasch
181! -cross_normalized_x, cross_normalized_y, cross_xtext, z_max_do1d,
182! z_max_do1d_normalized
183!
184! 940 2012-07-09 14:31:00Z raasch
185! +neutral in inipar
186!
187! 927 2012-06-06 19:15:04Z raasch
188! +masking_method in inipar
189!
190! 824 2012-02-17 09:09:57Z raasch
191! +curvature_solution_effects in inipar
192!
193! 809 2012-01-30 13:32:58Z maronga
194! Bugfix: replaced .AND. and .NOT. with && and ! in the preprocessor directives
195!
196! 807 2012-01-25 11:53:51Z maronga
197! New cpp directive "__check" implemented which is used by check_namelist_files
198!
199! Revision 1.1  1997/07/24 11:22:50  raasch
200! Initial revision
201!
202!
203! Description:
204! ------------
205!> This subroutine reads variables controling the run from the NAMELIST files
206!------------------------------------------------------------------------------!
207 SUBROUTINE parin
208 
209
210    USE arrays_3d,                                                             &
211        ONLY:  pt_init, q_init, ref_state, sa_init, ug, u_init, v_init,        &
212               vg
213
214    USE plant_canopy_model_mod,                                                &
215         ONLY: pcm_parin 
216
217    USE control_parameters
218
219    USE cpulog,                                                                &
220        ONLY:  cpu_log_barrierwait
221
222    USE dvrp_variables,                                                        &
223        ONLY:  local_dvrserver_running
224
225    USE grid_variables,                                                        &
226        ONLY:  dx, dy
227
228    USE indices,                                                               &
229        ONLY:  nx, ny, nz
230
231    USE kinds
232
233    USE land_surface_model_mod,                                                &
234        ONLY: lsm_parin
235
236    USE microphysics_mod,                                                      &
237        ONLY:  c_sedimentation, cloud_water_sedimentation,                     &
238               collision_turbulence, limiter_sedimentation, nc_const,          &
239               ventilation_effect
240
241    USE model_1d,                                                              &
242        ONLY:  damp_level_1d, dt_pr_1d, dt_run_control_1d, end_time_1d
243
244    USE pegrid
245
246    USE netcdf_interface,                                                      &
247        ONLY:  netcdf_data_format, netcdf_deflate, netcdf_precision
248
249    USE pmc_interface,                                                         &
250        ONLY:  nested_run, nesting_mode
251
252    USE profil_parameter,                                                      &
253        ONLY:  cross_profiles, cross_ts_uymax, cross_ts_uymin,                 &
254               profile_columns, profile_rows
255
256    USE progress_bar,                                                          &
257        ONLY :  batch_job
258
259    USE radiation_model_mod,                                                   &
260        ONLY: radiation_parin 
261
262    USE spectra_mod,                                                           &
263        ONLY :  spectra_parin
264
265    USE statistics,                                                            &
266        ONLY:  hom, hom_sum, pr_palm, region, statistic_regions
267
268    USE wind_turbine_model_mod,                                                &
269        ONLY:  wtm_parin
270
271
272    IMPLICIT NONE
273
274    INTEGER(iwp) ::  i   !<
275
276
277    NAMELIST /inipar/  alpha_surface, background_communication, bc_e_b, bc_lr, &
278                       bc_ns, bc_p_b, bc_p_t, bc_pt_b, bc_pt_t, bc_q_b,        &
279             bc_q_t,bc_s_b, bc_s_t, bc_sa_t, bc_uv_b, bc_uv_t,                 &
280             bottom_salinityflux, building_height, building_length_x,          &
281             building_length_y, building_wall_left, building_wall_south,       &
282             call_psolver_at_all_substeps, call_microphysics_at_all_substeps,  &
283             canyon_height,                                                    &
284             canyon_width_x, canyon_width_y, canyon_wall_left,                 &
285             canyon_wall_south, c_sedimentation, cfl_factor, cloud_droplets,   &
286             cloud_physics, cloud_scheme, cloud_top_radiation,                 &
287             cloud_water_sedimentation,                                        &
288             collective_wait, collision_turbulence, conserve_volume_flow,      &
289             conserve_volume_flow_mode, constant_flux_layer,                   &
290             coupling_start_time,                                              &
291             cycle_mg, damp_level_1d,                                          &
292             dissipation_1d,                                                   &
293             dp_external, dp_level_b, dp_smooth, dpdxy,                        &
294             dt, dt_pr_1d, dt_run_control_1d, dx, dy, dz, dz_max,              &
295             dz_stretch_factor, dz_stretch_level, end_time_1d,                 &
296             ensemble_member_nr,                                               &
297             e_init, e_min, fft_method, galilei_transformation, humidity,      &
298             inflow_damping_height, inflow_damping_width,                      &
299             inflow_disturbance_begin, inflow_disturbance_end,                 &
300             initializing_actions, km_constant,                                &
301             large_scale_forcing, large_scale_subsidence,                      &
302             limiter_sedimentation,                                            &
303             loop_optimization, masking_method, mg_cycles,                     &
304             mg_switch_to_pe0_level, mixing_length_1d, momentum_advec,         &
305             most_method, nc_const, netcdf_precision, neutral, ngsrb,          &
306             nsor, nsor_ini, nudging, nx, ny, nz, ocean, omega, omega_sor,     &
307             passive_scalar, phi,                                              &
308             prandtl_number, precipitation, psolver, pt_damping_factor,        &
309             pt_damping_width, pt_reference, pt_surface,                       &
310             pt_surface_initial_change, pt_vertical_gradient,                  &
311             pt_vertical_gradient_level, q_surface, q_surface_initial_change,  &
312             q_vertical_gradient, q_vertical_gradient_level,                   &
313             random_generator, random_heatflux,                                &
314             rayleigh_damping_factor, rayleigh_damping_height,                 &
315             recycling_width, recycling_yshift,                                &
316             reference_state, residual_limit,                                  &
317             roughness_length, sa_surface,                                     &
318             sa_vertical_gradient, sa_vertical_gradient_level, scalar_advec,   &
319             scalar_rayleigh_damping,                                          &
320             statistic_regions, subs_vertical_gradient,                        &
321             subs_vertical_gradient_level, surface_heatflux, surface_pressure, &
322             surface_scalarflux, surface_waterflux,                            &
323             s_surface, s_surface_initial_change, s_vertical_gradient,         &
324             s_vertical_gradient_level, timestep_scheme,                       &
325             topography, topography_grid_convention, top_heatflux,             &
326             top_momentumflux_u, top_momentumflux_v, top_salinityflux,         &
327             transpose_compute_overlap, turbulent_inflow,                      &
328             use_subsidence_tendencies, ug_surface, ug_vertical_gradient,      &
329             ug_vertical_gradient_level, use_surface_fluxes, use_cmax,         &
330             use_top_fluxes, use_ug_for_galilei_tr, use_upstream_for_tke,      &
331             uv_heights, u_bulk, u_profile, vg_surface, vg_vertical_gradient,  &
332             vg_vertical_gradient_level, v_bulk, v_profile, ventilation_effect,&
333             wall_adjustment, wall_heatflux, wall_humidityflux,                &
334             wall_scalarflux, zeta_max, zeta_min, z0h_factor
335     
336    NAMELIST /d3par/  averaging_interval, averaging_interval_pr,               &
337             cpu_log_barrierwait, create_disturbances,                         &
338             cross_profiles, cross_ts_uymax, cross_ts_uymin,                   &
339             data_output, data_output_masks,                                   &
340             data_output_pr, data_output_2d_on_each_pe, disturbance_amplitude, &
341             disturbance_energy_limit, disturbance_level_b,                    &
342             disturbance_level_t, do2d_at_begin, do3d_at_begin,                &
343             dt, dt_averaging_input, dt_averaging_input_pr,                    &
344             dt_coupling, dt_data_output, dt_data_output_av, dt_disturb,       &
345             dt_domask, dt_dopr, dt_dopr_listing, dt_dots, dt_do2d_xy,         &
346             dt_do2d_xz, dt_do2d_yz, dt_do3d, dt_max, dt_restart,              &
347             dt_run_control,end_time, force_print_header, mask_scale_x,        &
348             mask_scale_y, mask_scale_z, mask_x, mask_y, mask_z, mask_x_loop,  &
349             mask_y_loop, mask_z_loop, netcdf_data_format, netcdf_deflate,     &
350             normalizing_region, npex, npey, nz_do3d,                          &
351             precipitation_amount_interval, profile_columns, profile_rows,     &
352             restart_time, section_xy, section_xz, section_yz,                 &
353             skip_time_data_output, skip_time_data_output_av, skip_time_dopr,  &
354             skip_time_do2d_xy, skip_time_do2d_xz, skip_time_do2d_yz,          &
355             skip_time_do3d, skip_time_domask, synchronous_exchange,           &
356             termination_time_needed, z_max_do2d
357
358
359    NAMELIST /envpar/  batch_job, host, local_dvrserver_running,               &
360                       maximum_cpu_time_allowed, maximum_parallel_io_streams,  &
361                       revision, return_addres, return_username,               &
362                       run_identifier, tasks_per_node, write_binary
363
364!
365!-- First read values of environment variables (this NAMELIST file is
366!-- generated by mrun)
367    CALL location_message( 'reading environment parameters from ENVPAR', .FALSE. )
368    OPEN ( 90, FILE='ENVPAR', STATUS='OLD', FORM='FORMATTED', ERR=30 )
369    READ ( 90, envpar, ERR=31, END=32 )
370    CLOSE ( 90 )
371    CALL location_message( 'finished', .TRUE. )
372
373!
374!-- Calculate the number of groups into which parallel I/O is split.
375!-- The default for files which are opened by all PEs (or where each
376!-- PE opens his own independent file) is, that all PEs are doing input/output
377!-- in parallel at the same time. This might cause performance or even more
378!-- severe problems depending on the configuration of the underlying file
379!-- system.
380!-- First, set the default:
381    IF ( maximum_parallel_io_streams == -1  .OR.                               &
382         maximum_parallel_io_streams > numprocs )  THEN
383       maximum_parallel_io_streams = numprocs
384    ENDIF
385!
386!-- Now calculate the number of io_blocks and the io_group to which the
387!-- respective PE belongs. I/O of the groups is done in serial, but in parallel
388!-- for all PEs belonging to the same group.
389!-- These settings are repeated in init_pegrid for the communicator comm2d,
390!-- which is not available here
391    io_blocks = numprocs / maximum_parallel_io_streams
392    io_group  = MOD( myid+1, io_blocks )
393
394    CALL location_message( 'reading NAMELIST parameters from PARIN', .FALSE. )
395!
396!-- Data is read in parallel by groups of PEs
397    DO  i = 0, io_blocks-1
398       IF ( i == io_group )  THEN
399
400!
401!--       Open the NAMELIST-file which is send with this job
402          CALL check_open( 11 )
403
404!
405!--       Read the control parameters for initialization.
406!--       The namelist "inipar" must be provided in the NAMELIST-file.
407          READ ( 11, inipar, ERR=10, END=11 )
408
409          GOTO 12
410
411 10       message_string = 'errors in \$inipar &or no \$inipar-namelist ' //   &
412                           'found (CRAY-machines only)'
413          CALL message( 'parin', 'PA0271', 1, 2, 0, 6, 0 )
414
415 11       message_string = 'no \$inipar-namelist found'
416          CALL message( 'parin', 'PA0272', 1, 2, 0, 6, 0 )
417
418!
419!--       If required, read control parameters from restart file (produced by
420!--       a prior run). All PEs are reading from file created by PE0 (see
421!--       check_open)
422 12       IF ( TRIM( initializing_actions ) == 'read_restart_data' )  THEN
423             CALL read_var_list
424!
425!--          The restart file will be reopened when reading the subdomain data
426             CALL close_file( 13 )
427
428!
429!--          Increment the run count
430             runnr = runnr + 1
431          ENDIF
432
433!
434!--       In case of nested runs, explicitly set nesting boundary conditions.
435!--       This will overwrite the user settings. bc_lr and bc_ns always need
436!--       to be cyclic for vertical nesting.
437          IF ( nesting_mode == 'vertical' )  THEN
438             IF (bc_lr /= 'cyclic' .OR. bc_ns /= 'cyclic' )  THEN
439                WRITE ( message_string, *)  'bc_lr and bc_ns were set to ,',   &
440                                      'cyclic for vertical nesting'
441                CALL message( 'parin', 'PA0428', 0, 0, 0, 6, 0 )
442                bc_lr   = 'cyclic'
443                bc_ns   = 'cyclic'
444             ENDIF
445             IF ( nest_domain )  THEN
446                bc_uv_t = 'nested'
447                bc_pt_t = 'nested'
448                bc_q_t  = 'nested'
449                bc_p_t  = 'neumann'
450             ENDIF
451          ELSE
452         
453!
454!--       For other nesting modes only set boundary conditions for
455!--       nested domains.
456             IF ( nest_domain )  THEN
457                bc_lr   = 'nested'
458                bc_ns   = 'nested'
459                bc_uv_t = 'nested'
460                bc_pt_t = 'nested'
461                bc_q_t  = 'nested'
462                bc_p_t  = 'neumann'
463             ENDIF
464          ENDIF
465           
466!
467!--       Check validity of lateral boundary conditions. This has to be done
468!--       here because they are already used in init_pegrid and init_grid and
469!--       therefore cannot be check in check_parameters
470          IF ( bc_lr /= 'cyclic'  .AND.  bc_lr /= 'dirichlet/radiation'  .AND. &
471               bc_lr /= 'radiation/dirichlet'  .AND.  bc_lr /= 'nested' )  THEN
472             message_string = 'unknown boundary condition: bc_lr = "' // &
473                              TRIM( bc_lr ) // '"'
474             CALL message( 'check_parameters', 'PA0049', 1, 2, 0, 6, 0 )
475          ENDIF
476          IF ( bc_ns /= 'cyclic'  .AND.  bc_ns /= 'dirichlet/radiation'  .AND. &
477               bc_ns /= 'radiation/dirichlet'  .AND.  bc_ns /= 'nested' )  THEN
478             message_string = 'unknown boundary condition: bc_ns = "' // &
479                              TRIM( bc_ns ) // '"'
480             CALL message( 'check_parameters', 'PA0050', 1, 2, 0, 6, 0 )
481          ENDIF
482
483!
484!--       Set internal variables used for speed optimization in if clauses
485          IF ( bc_lr /= 'cyclic' )               bc_lr_cyc    = .FALSE.
486          IF ( bc_lr == 'dirichlet/radiation' )  bc_lr_dirrad = .TRUE.
487          IF ( bc_lr == 'radiation/dirichlet' )  bc_lr_raddir = .TRUE.
488          IF ( bc_ns /= 'cyclic' )               bc_ns_cyc    = .FALSE.
489          IF ( bc_ns == 'dirichlet/radiation' )  bc_ns_dirrad = .TRUE.
490          IF ( bc_ns == 'radiation/dirichlet' )  bc_ns_raddir = .TRUE.
491
492!
493!--       Definition of names of areas used for computing statistics. They must
494!--       be defined at this place, because they are allowed to be redefined by
495!--       the user in user_parin.
496          region = 'total domain'
497
498!
499!--       Read runtime parameters given by the user for this run (namelist
500!--       "d3par"). The namelist "d3par" can be omitted. In that case, default
501!--       values are used for the parameters.
502          READ ( 11, d3par, END=20 )
503
504          IF ( nested_run )  THEN
505!
506!--          In nested domains, npex or npey can not be given in the d3par-
507!--          NAMELIST because here the PE-grids are always defined in the
508!--          nestpar-NAMELIST. Settings will be ignored.
509             IF ( ( npex /= -1 ) .OR. ( npey /= -1 ) )  THEN
510                message_string = 'npex or npey can not be given in \$d3par ' // &
511                                 'for nested runs & they will be ignored'
512                CALL message( 'parin', 'PA0352', 0, 1, 0, 6, 0 )
513             ENDIF
514          ENDIF
515
516!
517!--       Check if land surface model is used and read &lsm_par if required
518          CALL lsm_parin
519
520!
521!--       Check if spectra shall be calculated and read spectra_par if required
522          CALL spectra_parin
523
524!
525!--       Check if radiation model is used and read &radiation_par if required
526          CALL radiation_parin
527 
528 
529!--       Check if plant canopy model is used and read &canopy_par if required
530          CALL pcm_parin
531 
532!
533!--       Read control parameters for optionally used model software packages
534 20       CALL package_parin
535
536!
537!--       Check if wind turbine model is used and read &wind_turbine_par if
538!--       required
539          CALL wtm_parin
540
541!
542!--       Read user-defined variables
543          CALL user_parin
544
545!
546!--       Check in case of initial run, if the grid point numbers are well
547!--       defined and allocate some arrays which are already needed in
548!--       init_pegrid or check_parameters. During restart jobs, these arrays
549!--       will be allocated in read_var_list. All other arrays are allocated
550!--       in init_3d_model.
551          IF ( TRIM( initializing_actions ) /= 'read_restart_data' )  THEN
552
553             IF ( nx <= 0 )  THEN
554                WRITE( message_string, * ) 'no value or wrong value given',    &
555                                           ' for nx: nx=', nx
556                CALL message( 'parin', 'PA0273', 1, 2, 0, 6, 0 )
557             ENDIF
558             IF ( ny <= 0 )  THEN
559                WRITE( message_string, * ) 'no value or wrong value given',    &
560                                           ' for ny: ny=', ny
561                CALL message( 'parin', 'PA0274', 1, 2, 0, 6, 0 )
562             ENDIF
563             IF ( nz <= 0 )  THEN
564                WRITE( message_string, * ) 'no value or wrong value given',    &
565                                           ' for nz: nz=', nz
566                CALL message( 'parin', 'PA0275', 1, 2, 0, 6, 0 )
567             ENDIF
568!
569!--          ATTENTION: in case of changes to the following statement please
570!--                  also check the allocate statement in routine read_var_list
571             ALLOCATE( pt_init(0:nz+1), q_init(0:nz+1),                       &
572                       ref_state(0:nz+1), sa_init(0:nz+1), ug(0:nz+1),         &
573                       u_init(0:nz+1), v_init(0:nz+1), vg(0:nz+1),             &
574                       hom(0:nz+1,2,pr_palm+max_pr_user,0:statistic_regions),  &
575                       hom_sum(0:nz+1,pr_palm+max_pr_user,0:statistic_regions) )
576
577             hom = 0.0_wp
578
579          ENDIF
580
581!
582!--       NAMELIST-file is not needed anymore
583          CALL close_file( 11 )
584
585       ENDIF
586#if defined( __parallel )
587       CALL MPI_BARRIER( MPI_COMM_WORLD, ierr )
588#endif
589    ENDDO
590
591    CALL location_message( 'finished', .TRUE. )
592
593    RETURN
594
595 30 message_string = 'local file ENVPAR not found' //                          &
596                     '&some variables for steering may not be properly set'
597    CALL message( 'parin', 'PA0276', 0, 1, 0, 6, 0 )
598    RETURN
599
600 31 message_string = 'errors in local file ENVPAR' //                          &
601                     '&some variables for steering may not be properly set'
602    CALL message( 'parin', 'PA0277', 0, 1, 0, 6, 0 )
603    RETURN
604
605 32 message_string = 'no envpar-NAMELIST found in local file ENVPAR'  //       &
606                     '&some variables for steering may not be properly set'
607    CALL message( 'parin', 'PA0278', 0, 1, 0, 6, 0 )
608
609 END SUBROUTINE parin
Note: See TracBrowser for help on using the repository browser.