source: palm/trunk/SOURCE/palm.f90 @ 2718

Last change on this file since 2718 was 2718, checked in by maronga, 3 years ago

deleting of deprecated files; headers updated where needed

  • Property svn:keywords set to Id
File size: 17.9 KB
Line 
1!> @file palm.f90
2!------------------------------------------------------------------------------!
3! This file is part of the PALM model system.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2018 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: palm.f90 2718 2018-01-02 08:49:38Z maronga $
27! Corrected "Former revisions" section
28!
29! 2696 2017-12-14 17:12:51Z kanani
30! Change in file header (GPL part)
31! Implementation of chemistry module (FK)
32! Introduce input-data standard
33! Rename lsm_last_actions into lsm_write_restart_data
34! Move usm_write_restart_data into io_blocks loop (MS)
35!
36! 2512 2017-10-04 08:26:59Z raasch
37! user interface required revision updated
38!
39! 2320 2017-07-21 12:47:43Z suehring
40! Modularize large-scale forcing and nudging
41!
42! 2298 2017-06-29 09:28:18Z raasch
43! type of write_binary changed from CHARACTER to LOGICAL,
44! user interface required revision updated, MPI2 related part removed
45!
46! 2296 2017-06-28 07:53:56Z maronga
47! Added call to new spinup routine
48!
49! 2292 2017-06-20 09:51:42Z schwenkel
50! Implementation of new microphysic scheme: cloud_scheme = 'morrison'
51! includes two more prognostic equations for cloud drop concentration (nc) 
52! and cloud water content (qc).
53!
54! 2261 2017-06-08 14:25:57Z raasch
55! output of run number for mrun to create unified cycle numbers
56!
57! 2233 2017-05-30 18:08:54Z suehring
58!
59! 2232 2017-05-30 17:47:52Z suehring
60! Renamed wall_flags_0 and wall_flags_00 into advc_flags_1 and advc_flags_2,
61! respectively, within copyin statement. Moreover, introduced further flag
62! array wall_flags_0.
63! Remove unused variables from ONLY list.
64!
65! 2178 2017-03-17 11:07:39Z hellstea
66! Calls for pmci_ensure_nest_mass_conservation and pres are added after
67! the nest initialization
68!
69! 2118 2017-01-17 16:38:49Z raasch
70! OpenACC directives and related code removed
71!
72! 2011 2016-09-19 17:29:57Z kanani
73! Flag urban_surface is now defined in module control_parameters.
74!
75! 2007 2016-08-24 15:47:17Z kanani
76! Temporarily added CALL for writing of restart data for urban surface model
77!
78! 2000 2016-08-20 18:09:15Z knoop
79! Forced header and separation lines into 80 columns
80!
81! 1976 2016-07-27 13:28:04Z maronga
82! Added call to radiation_last_actions for binary output of land surface model
83! data
84!
85! 1972 2016-07-26 07:52:02Z maronga
86! Added call to lsm_last_actions for binary output of land surface model data
87!
88! 1960 2016-07-12 16:34:24Z suehring
89! Separate humidity and passive scalar
90!
91! 1834 2016-04-07 14:34:20Z raasch
92! Initial version of purely vertical nesting introduced.
93!
94! 1833 2016-04-07 14:23:03Z raasch
95! required user interface version changed
96!
97! 1808 2016-04-05 19:44:00Z raasch
98! routine local_flush replaced by FORTRAN statement
99!
100! 1783 2016-03-06 18:36:17Z raasch
101! required user interface version changed
102!
103! 1781 2016-03-03 15:12:23Z raasch
104! pmc initialization moved from time_integration to here
105!
106! 1779 2016-03-03 08:01:28Z raasch
107! setting of nest_domain and coupling_char moved to the pmci
108!
109! 1764 2016-02-28 12:45:19Z raasch
110! cpp-statements for nesting removed, communicator settings cleaned up
111!
112! 1762 2016-02-25 12:31:13Z hellstea
113! Introduction of nested domain feature
114!
115! 1747 2016-02-08 12:25:53Z raasch
116! OpenACC-adjustment for new surface layer parameterization
117!
118! 1682 2015-10-07 23:56:08Z knoop
119! Code annotations made doxygen readable
120!
121! 1668 2015-09-23 13:45:36Z raasch
122! warning replaced by abort in case of failed user interface check
123!
124! 1666 2015-09-23 07:31:10Z raasch
125! check for user's interface version added
126!
127! 1482 2014-10-18 12:34:45Z raasch
128! adjustments for using CUDA-aware OpenMPI
129!
130! 1468 2014-09-24 14:06:57Z maronga
131! Adapted for use on up to 6-digit processor cores
132!
133! 1402 2014-05-09 14:25:13Z raasch
134! location messages added
135!
136! 1374 2014-04-25 12:55:07Z raasch
137! bugfix: various modules added
138!
139! 1320 2014-03-20 08:40:49Z raasch
140! ONLY-attribute added to USE-statements,
141! kind-parameters added to all INTEGER and REAL declaration statements,
142! kinds are defined in new module kinds,
143! old module precision_kind is removed,
144! revision history before 2012 removed,
145! comment fields (!:) to be used for variable explanations added to
146! all variable declaration statements
147!
148! 1318 2014-03-17 13:35:16Z raasch
149! module interfaces removed
150!
151! 1241 2013-10-30 11:36:58Z heinze
152! initialization of nuding and large scale forcing from external file
153!
154! 1221 2013-09-10 08:59:13Z raasch
155! +wall_flags_00, rflags_invers, rflags_s_inner in copyin statement
156!
157! 1212 2013-08-15 08:46:27Z raasch
158! +tri in copyin statement
159!
160! 1179 2013-06-14 05:57:58Z raasch
161! ref_state added to copyin-list
162!
163! 1113 2013-03-10 02:48:14Z raasch
164! openACC statements modified
165!
166! 1111 2013-03-08 23:54:10Z raasch
167! openACC statements updated
168!
169! 1092 2013-02-02 11:24:22Z raasch
170! unused variables removed
171!
172! 1036 2012-10-22 13:43:42Z raasch
173! code put under GPL (PALM 3.9)
174!
175! 1015 2012-09-27 09:23:24Z raasch
176! Version number changed from 3.8 to 3.8a.
177! OpenACC statements added + code changes required for GPU optimization
178!
179! 849 2012-03-15 10:35:09Z raasch
180! write_particles renamed lpm_write_restart_file
181!
182! Revision 1.1  1997/07/24 11:23:35  raasch
183! Initial revision
184!
185!
186! Description:
187! ------------
188!> Large-Eddy Simulation (LES) model for the convective boundary layer,
189!> optimized for use on parallel machines (implementation realized using the
190!> Message Passing Interface (MPI)). The model can also be run on vector machines
191!> (less well optimized) and workstations. Versions for the different types of
192!> machines are controlled via cpp-directives.
193!> Model runs are only feasible using the ksh-script mrun.
194!>
195!> @todo create routine last_actions instead of calling lsm_last_actions etc.
196!> @todo eventually move CALL usm_write_restart_data to suitable location
197!> @todo move chem_init call to init_3d_model or to check_parameters
198!------------------------------------------------------------------------------!
199 PROGRAM palm
200 
201
202    USE arrays_3d
203
204#if defined( __chem )
205    USE chemistry_model_mod,                                                   &
206        ONLY:  chem_init, chem_last_actions
207    USE chem_photolysis_mod,                                                   &
208        ONLY:  photolysis_init
209#endif
210
211    USE control_parameters,                                                    &
212        ONLY:  air_chemistry,                                                  &
213               cloud_physics, constant_diffusion, coupling_char, coupling_mode,&
214               do2d_at_begin, do3d_at_begin, humidity, initializing_actions,   &
215               io_blocks, io_group, land_surface, large_scale_forcing,         &
216               message_string, microphysics_morrison, microphysics_seifert,    &
217               nest_domain, neutral, nudging, passive_scalar, runnr,           &
218               simulated_time, simulated_time_chr, spinup, urban_surface,      &
219               user_interface_current_revision,                                &
220               user_interface_required_revision, version, wall_heatflux,       &
221               write_binary
222
223    USE cpulog,                                                                &
224        ONLY:  cpu_log, log_point, cpu_statistics
225
226    USE indices,                                                               &
227        ONLY:  nbgp
228
229    USE netcdf_data_input_mod,                                                 &
230        ONLY:  netcdf_data_input_inquire_file, netcdf_data_input_init,         &
231               netcdf_data_input_surface_data, netcdf_data_input_topo
232
233    USE kinds
234
235    USE land_surface_model_mod,                                                &
236        ONLY:  lsm_write_restart_data
237
238    USE particle_attributes,                                                   &
239        ONLY:  particle_advection
240
241    USE pegrid
242
243    USE pmc_interface,                                                         &
244        ONLY:  cpl_id, nested_run, pmci_child_initialize, pmci_init,           &
245               pmci_modelconfiguration, pmci_parent_initialize,                &
246               pmci_ensure_nest_mass_conservation
247
248    USE radiation_model_mod,                                                   &
249        ONLY:  radiation, radiation_last_actions
250       
251    USE urban_surface_mod,                                                     &
252        ONLY:  usm_write_restart_data       
253
254    IMPLICIT NONE
255
256!
257!-- Local variables
258    CHARACTER(LEN=9)  ::  time_to_string  !<
259    CHARACTER(LEN=10) ::  env_string      !< to store string of environment var
260    INTEGER(iwp)      ::  env_stat        !< to hold status of GET_ENV
261    INTEGER(iwp)      ::  i               !<
262    INTEGER(iwp)      ::  myid_openmpi    !< OpenMPI local rank for CUDA aware MPI
263
264    version = 'PALM 4.0'
265    user_interface_required_revision = 'r2512'
266
267#if defined( __parallel )
268!
269!-- MPI initialisation. comm2d is preliminary set, because
270!-- it will be defined in init_pegrid but is used before in cpu_log.
271    CALL MPI_INIT( ierr )
272
273!
274!-- Initialize the coupling for nested-domain runs
275!-- comm_palm is the communicator which includes all PEs (MPI processes)
276!-- available for this (nested) model. If it is not a nested run, comm_palm
277!-- is returned as MPI_COMM_WORLD
278    CALL pmci_init( comm_palm )
279    comm2d = comm_palm
280!
281!-- Get the (preliminary) number of MPI processes and the local PE-id (in case
282!-- of a further communicator splitting in init_coupling, these numbers will
283!-- be changed in init_pegrid).
284    IF ( nested_run )  THEN
285
286       CALL MPI_COMM_SIZE( comm_palm, numprocs, ierr )
287       CALL MPI_COMM_RANK( comm_palm, myid, ierr )
288
289    ELSE
290
291       CALL MPI_COMM_SIZE( MPI_COMM_WORLD, numprocs, ierr )
292       CALL MPI_COMM_RANK( MPI_COMM_WORLD, myid, ierr )
293!
294!--    Initialize PE topology in case of coupled atmosphere-ocean runs (comm_palm
295!--    will be splitted in init_coupling)
296       CALL init_coupling
297    ENDIF
298#endif
299
300!
301!-- Initialize measuring of the CPU-time remaining to the run
302    CALL local_tremain_ini
303
304!
305!-- Start of total CPU time measuring.
306    CALL cpu_log( log_point(1), 'total', 'start' )
307    CALL cpu_log( log_point(2), 'initialisation', 'start' )
308
309!
310!-- Open a file for debug output
311    WRITE (myid_char,'(''_'',I6.6)')  myid
312    OPEN( 9, FILE='DEBUG'//TRIM( coupling_char )//myid_char, FORM='FORMATTED' )
313
314!
315!-- Initialize dvrp logging. Also, one PE maybe split from the global
316!-- communicator for doing the dvrp output. In that case, the number of
317!-- PEs available for PALM is reduced by one and communicator comm_palm
318!-- is changed respectively.
319#if defined( __parallel )
320    CALL MPI_COMM_RANK( comm_palm, myid, ierr )
321!
322!-- TEST OUTPUT (TO BE REMOVED)
323    WRITE(9,*) '*** coupling_mode = "', TRIM( coupling_mode ), '"'
324    FLUSH( 9 )
325    IF ( TRIM( coupling_mode ) /= 'uncoupled' )  THEN
326       PRINT*, '*** PE', myid, ' Global target PE:', target_id, &
327               TRIM( coupling_mode )
328    ENDIF
329#endif
330
331    CALL init_dvrp_logging
332
333!
334!-- Read control parameters from NAMELIST files and read environment-variables
335    CALL parin
336
337!
338!-- Check for the user's interface version
339    IF ( user_interface_current_revision /= user_interface_required_revision )  &
340    THEN
341       message_string = 'current user-interface revision "' //                  &
342                        TRIM( user_interface_current_revision ) // '" does ' // &
343                        'not match the required revision ' //                   &
344                        TRIM( user_interface_required_revision )
345        CALL message( 'palm', 'PA0169', 1, 2, 0, 6, 0 )
346    ENDIF
347
348!
349!-- Determine processor topology and local array indices
350    CALL init_pegrid
351!
352!-- Check if input file according to input-data standard exists
353    CALL netcdf_data_input_inquire_file
354!
355!-- Read topography input data if required. This is required before the
356!-- numerical grid is finally created in init_grid
357    CALL netcdf_data_input_topo 
358!
359!-- Generate grid parameters, initialize generic topography and further process
360!-- topography information if required
361    CALL init_grid
362!
363!-- Read global attributes if available. 
364    CALL netcdf_data_input_init
365!
366!-- Read surface classification data, e.g. vegetation and soil types, water
367!-- surfaces, etc., if available. Some of these data is required before
368!-- check parameters is invoked.     
369    CALL netcdf_data_input_surface_data
370!
371!-- Initialize chemistry (called before check_parameters due to dependencies)
372!-- --> Needs to be moved!! What is the dependency about?
373#if defined( __chem )
374! IF (  TRIM( initializing_actions ) /= 'read_restart_data' )  THEN
375    IF ( air_chemistry )  THEN
376       CALL chem_init
377       CALL photolysis_init   ! probably also required for restart
378    ENDIF
379! END IF
380#endif
381!
382!-- Check control parameters and deduce further quantities
383    CALL check_parameters
384
385!
386!-- Initialize all necessary variables
387    CALL init_3d_model
388
389!
390!-- Coupling protocol setup for nested-domain runs
391    IF ( nested_run )  THEN
392       CALL pmci_modelconfiguration
393!
394!--    Receive and interpolate initial data on children.
395!--    Child initialization must be made first if the model is both child and
396!--    parent if necessary
397       IF ( TRIM( initializing_actions ) /= 'read_restart_data' )  THEN
398          CALL pmci_child_initialize
399!
400!--       Send initial condition data from parent to children
401          CALL pmci_parent_initialize
402!
403!--    Exchange_horiz is needed after the nest initialization
404          IF ( nest_domain )  THEN
405             CALL exchange_horiz( u, nbgp )
406             CALL exchange_horiz( v, nbgp )
407             CALL exchange_horiz( w, nbgp )
408             IF ( .NOT. neutral )  THEN
409                CALL exchange_horiz( pt, nbgp )
410             ENDIF
411             IF ( .NOT. constant_diffusion )  CALL exchange_horiz( e, nbgp )
412             IF ( humidity )  THEN
413                CALL exchange_horiz( q, nbgp )
414                IF ( cloud_physics  .AND.  microphysics_morrison )  THEN
415                  CALL exchange_horiz( qc, nbgp )
416                  CALL exchange_horiz( nc, nbgp )
417                ENDIF
418                IF ( cloud_physics  .AND.  microphysics_seifert )  THEN
419                   CALL exchange_horiz( qr, nbgp ) 
420                   CALL exchange_horiz( nr, nbgp )
421                ENDIF
422             ENDIF
423             IF ( passive_scalar )  CALL exchange_horiz( s, nbgp )
424
425             CALL pmci_ensure_nest_mass_conservation
426             CALL pres
427          ENDIF
428       ENDIF
429
430    ENDIF
431
432!
433!-- Output of program header
434    IF ( myid == 0 )  CALL header
435
436    CALL cpu_log( log_point(2), 'initialisation', 'stop' )
437
438!
439!-- Integration of the non-atmospheric equations (land surface model, urban
440!-- surface model)
441    IF ( spinup )  THEN
442       CALL time_integration_spinup
443    ENDIF
444
445!
446!-- Set start time in format hh:mm:ss
447    simulated_time_chr = time_to_string( simulated_time )
448
449!
450!-- If required, output of initial arrays
451    IF ( do2d_at_begin )  THEN
452       CALL data_output_2d( 'xy', 0 )
453       CALL data_output_2d( 'xz', 0 )
454       CALL data_output_2d( 'yz', 0 )
455    ENDIF
456
457    IF ( do3d_at_begin )  THEN
458       CALL data_output_3d( 0 )
459    ENDIF
460
461!
462!-- Integration of the model equations using timestep-scheme
463    CALL time_integration
464
465!
466!-- If required, write binary data for restart runs
467    IF ( write_binary )  THEN
468
469       CALL cpu_log( log_point(22), 'write_3d_binary', 'start' )
470
471       CALL location_message( 'writing restart data', .FALSE. )
472
473       CALL check_open( 14 )
474
475       DO  i = 0, io_blocks-1
476          IF ( i == io_group )  THEN
477!
478!--          Write flow field data
479             CALL write_3d_binary
480          ENDIF
481#if defined( __parallel )
482          CALL MPI_BARRIER( comm2d, ierr )
483#endif
484       ENDDO
485
486       CALL location_message( 'finished', .TRUE. )
487
488       CALL cpu_log( log_point(22), 'write_3d_binary', 'stop' )
489
490!
491!--    If required, write particle data
492       IF ( particle_advection )  CALL lpm_write_restart_file
493       
494    ENDIF
495
496!
497!-- If required, repeat output of header including the required CPU-time
498    IF ( myid == 0 )  CALL header
499!
500!-- If required, final land surface and user-defined actions, and
501!-- last actions on the open files and close files. Unit 14 was opened
502!-- in write_3d_binary but it is closed here, to allow writing on this
503!-- unit in routine user_last_actions.
504    CALL cpu_log( log_point(4), 'last actions', 'start' )
505    DO  i = 0, io_blocks-1
506       IF ( i == io_group )  THEN
507
508          IF ( urban_surface )  THEN
509             CALL usm_write_restart_data
510          ENDIF
511          IF ( land_surface )  THEN
512             CALL lsm_write_restart_data
513          ENDIF
514          IF ( radiation )  THEN
515             CALL radiation_last_actions
516          ENDIF
517#if defined( __chem )
518          IF ( air_chemistry )  THEN
519             CALL chem_last_actions
520          ENDIF
521#endif
522         
523          CALL user_last_actions
524          IF ( write_binary )  CALL close_file( 14 )
525       ENDIF
526#if defined( __parallel )
527       CALL MPI_BARRIER( comm2d, ierr )
528#endif
529    ENDDO
530    CALL close_file( 0 )
531    CALL close_dvrp
532    CALL cpu_log( log_point(4), 'last actions', 'stop' )
533
534!
535!-- Write run number to file (used by mrun to create unified cycle numbers for
536!-- output files
537    IF ( myid == 0  .AND.  runnr > 0 )  THEN
538       OPEN( 90, FILE='RUN_NUMBER', FORM='FORMATTED' )
539       WRITE( 90, '(I4)' )  runnr
540       CLOSE( 90 )
541    ENDIF
542
543!
544!-- Take final CPU-time for CPU-time analysis
545    CALL cpu_log( log_point(1), 'total', 'stop' )
546    CALL cpu_statistics
547
548#if defined( __parallel )
549    CALL MPI_FINALIZE( ierr )
550#endif
551
552 END PROGRAM palm
Note: See TracBrowser for help on using the repository browser.