source: palm/trunk/SOURCE/palm.f90 @ 1961

Last change on this file since 1961 was 1961, checked in by suehring, 5 years ago

last commit documented

  • Property svn:keywords set to Id
File size: 16.3 KB
Line 
1!> @file palm.f90
2!--------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the terms
6! of the GNU General Public License as published by the Free Software Foundation,
7! either version 3 of the License, or (at your option) any later version.
8!
9! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
10! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
11! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
12!
13! You should have received a copy of the GNU General Public License along with
14! PALM. If not, see <http://www.gnu.org/licenses/>.
15!
16! Copyright 1997-2016 Leibniz Universitaet Hannover
17!--------------------------------------------------------------------------------!
18!
19! Current revisions:
20! -----------------
21!
22!
23! Former revisions:
24! -----------------
25! $Id: palm.f90 1961 2016-07-12 16:37:58Z suehring $
26!
27! 1960 2016-07-12 16:34:24Z suehring
28! Separate humidity and passive scalar
29!
30! 1834 2016-04-07 14:34:20Z raasch
31! Initial version of purely vertical nesting introduced.
32!
33! 1833 2016-04-07 14:23:03Z raasch
34! required user interface version changed
35!
36! 1808 2016-04-05 19:44:00Z raasch
37! routine local_flush replaced by FORTRAN statement
38!
39! 1783 2016-03-06 18:36:17Z raasch
40! required user interface version changed
41!
42! 1781 2016-03-03 15:12:23Z raasch
43! pmc initialization moved from time_integration to here
44!
45! 1779 2016-03-03 08:01:28Z raasch
46! setting of nest_domain and coupling_char moved to the pmci
47!
48! 1764 2016-02-28 12:45:19Z raasch
49! cpp-statements for nesting removed, communicator settings cleaned up
50!
51! 1762 2016-02-25 12:31:13Z hellstea
52! Introduction of nested domain feature
53!
54! 1747 2016-02-08 12:25:53Z raasch
55! OpenACC-adjustment for new surface layer parameterization
56!
57! 1682 2015-10-07 23:56:08Z knoop
58! Code annotations made doxygen readable
59!
60! 1668 2015-09-23 13:45:36Z raasch
61! warning replaced by abort in case of failed user interface check
62!
63! 1666 2015-09-23 07:31:10Z raasch
64! check for user's interface version added
65!
66! 1482 2014-10-18 12:34:45Z raasch
67! adjustments for using CUDA-aware OpenMPI
68!
69! 1468 2014-09-24 14:06:57Z maronga
70! Adapted for use on up to 6-digit processor cores
71!
72! 1402 2014-05-09 14:25:13Z raasch
73! location messages added
74!
75! 1374 2014-04-25 12:55:07Z raasch
76! bugfix: various modules added
77!
78! 1320 2014-03-20 08:40:49Z raasch
79! ONLY-attribute added to USE-statements,
80! kind-parameters added to all INTEGER and REAL declaration statements,
81! kinds are defined in new module kinds,
82! old module precision_kind is removed,
83! revision history before 2012 removed,
84! comment fields (!:) to be used for variable explanations added to
85! all variable declaration statements
86!
87! 1318 2014-03-17 13:35:16Z raasch
88! module interfaces removed
89!
90! 1241 2013-10-30 11:36:58Z heinze
91! initialization of nuding and large scale forcing from external file
92!
93! 1221 2013-09-10 08:59:13Z raasch
94! +wall_flags_00, rflags_invers, rflags_s_inner in copyin statement
95!
96! 1212 2013-08-15 08:46:27Z raasch
97! +tri in copyin statement
98!
99! 1179 2013-06-14 05:57:58Z raasch
100! ref_state added to copyin-list
101!
102! 1113 2013-03-10 02:48:14Z raasch
103! openACC statements modified
104!
105! 1111 2013-03-08 23:54:10Z raasch
106! openACC statements updated
107!
108! 1092 2013-02-02 11:24:22Z raasch
109! unused variables removed
110!
111! 1036 2012-10-22 13:43:42Z raasch
112! code put under GPL (PALM 3.9)
113!
114! 1015 2012-09-27 09:23:24Z raasch
115! Version number changed from 3.8 to 3.8a.
116! OpenACC statements added + code changes required for GPU optimization
117!
118! 849 2012-03-15 10:35:09Z raasch
119! write_particles renamed lpm_write_restart_file
120!
121! Revision 1.1  1997/07/24 11:23:35  raasch
122! Initial revision
123!
124!
125! Description:
126! ------------
127!> Large-Eddy Simulation (LES) model for the convective boundary layer,
128!> optimized for use on parallel machines (implementation realized using the
129!> Message Passing Interface (MPI)). The model can also be run on vector machines
130!> (less well optimized) and workstations. Versions for the different types of
131!> machines are controlled via cpp-directives.
132!> Model runs are only feasible using the ksh-script mrun.
133!------------------------------------------------------------------------------!
134 PROGRAM palm
135 
136
137    USE arrays_3d
138
139    USE control_parameters,                                                    &
140        ONLY:  constant_diffusion, coupling_char, coupling_mode,               &
141               do2d_at_begin, do3d_at_begin, humidity, io_blocks, io_group,    &
142               large_scale_forcing, message_string, nest_domain, neutral,      &
143               nudging, passive_scalar, simulated_time, simulated_time_chr,    &
144               user_interface_current_revision,                                &
145               user_interface_required_revision, version, wall_heatflux,       &
146               write_binary
147
148    USE cpulog,                                                                &
149        ONLY:  cpu_log, log_point, cpu_statistics
150
151    USE grid_variables,                                                        &
152        ONLY:  fxm, fxp, fym, fyp, fwxm, fwxp, fwym, fwyp, wall_e_x, wall_e_y, &
153               wall_u, wall_v, wall_w_x, wall_w_y
154
155    USE indices,                                                               &
156        ONLY:  nbgp, ngp_2dh, ngp_2dh_s_inner, nzb_diff_s_inner, nzb_diff_s_outer,   &
157               nzb_diff_u, nzb_diff_v, nzb_s_inner, nzb_s_outer, nzb_u_inner,  &
158               nzb_u_outer, nzb_v_inner, nzb_v_outer, nzb_w_inner,             &
159               nzb_w_outer, rflags_invers, rflags_s_inner, wall_flags_0,       &
160               wall_flags_00
161
162    USE kinds
163
164    USE ls_forcing_mod,                                                        &
165        ONLY:  init_ls_forcing
166
167    USE nudge_mod,                                                             &
168        ONLY:  init_nudge
169
170    USE particle_attributes,                                                   &
171        ONLY:  particle_advection
172
173    USE pegrid
174
175    USE pmc_interface,                                                         &
176        ONLY:  cpl_id, nested_run, pmci_child_initialize, pmci_init,           &
177               pmci_modelconfiguration, pmci_parent_initialize
178
179    USE statistics,                                                            &
180        ONLY:  hom, rmask, weight_pres, weight_substep
181
182    USE surface_layer_fluxes_mod,                                              &
183        ONLY:  pt1, qv1, uv_total
184
185#if defined( __openacc )
186    USE OPENACC
187#endif
188
189    IMPLICIT NONE
190
191!
192!-- Local variables
193    CHARACTER(LEN=9)  ::  time_to_string  !<
194    CHARACTER(LEN=10) ::  env_string      !< to store string of environment var
195    INTEGER(iwp)      ::  env_stat        !< to hold status of GET_ENV
196    INTEGER(iwp)      ::  i               !<
197    INTEGER(iwp)      ::  myid_openmpi    !< OpenMPI local rank for CUDA aware MPI
198#if defined( __openacc )
199    REAL(wp), DIMENSION(100) ::  acc_dum     !<
200#endif
201
202    version = 'PALM 4.0'
203    user_interface_required_revision = 'r1819'
204
205#if defined( __parallel )
206!
207!-- MPI initialisation. comm2d is preliminary set, because
208!-- it will be defined in init_pegrid but is used before in cpu_log.
209    CALL MPI_INIT( ierr )
210
211!
212!-- Initialize the coupling for nested-domain runs
213!-- comm_palm is the communicator which includes all PEs (MPI processes)
214!-- available for this (nested) model. If it is not a nested run, comm_palm
215!-- is returned as MPI_COMM_WORLD
216    CALL pmci_init( comm_palm )
217    comm2d = comm_palm
218!
219!-- Get the (preliminary) number of MPI processes and the local PE-id (in case
220!-- of a further communicator splitting in init_coupling, these numbers will
221!-- be changed in init_pegrid).
222    IF ( nested_run )  THEN
223
224       CALL MPI_COMM_SIZE( comm_palm, numprocs, ierr )
225       CALL MPI_COMM_RANK( comm_palm, myid, ierr )
226
227    ELSE
228
229       CALL MPI_COMM_SIZE( MPI_COMM_WORLD, numprocs, ierr )
230       CALL MPI_COMM_RANK( MPI_COMM_WORLD, myid, ierr )
231!
232!--    Initialize PE topology in case of coupled atmosphere-ocean runs (comm_palm
233!--    will be splitted in init_coupling)
234       CALL init_coupling
235    ENDIF
236#endif
237
238#if defined( __openacc )
239!
240!-- Get the local MPI rank in case of CUDA aware OpenMPI. Important, if there
241!-- is more than one accelerator board on the node
242    CALL GET_ENVIRONMENT_VARIABLE('OMPI_COMM_WORLD_LOCAL_RANK',                &
243         VALUE=env_string, STATUS=env_stat )
244    READ( env_string, '(I1)' )  myid_openmpi
245    PRINT*, '### local_rank = ', myid_openmpi, '  status=',env_stat
246!
247!-- Get the number of accelerator boards per node and assign the MPI processes
248!-- to these boards
249    PRINT*, '*** ACC_DEVICE_NVIDIA = ', ACC_DEVICE_NVIDIA
250    num_acc_per_node  = ACC_GET_NUM_DEVICES( ACC_DEVICE_NVIDIA )
251    IF ( numprocs == 1  .AND.  num_acc_per_node > 0 )  num_acc_per_node = 1
252    PRINT*, '*** myid = ', myid_openmpi, ' num_acc_per_node = ', num_acc_per_node
253    acc_rank = MOD( myid_openmpi, num_acc_per_node )
254    CALL ACC_SET_DEVICE_NUM ( acc_rank, ACC_DEVICE_NVIDIA )
255!
256!-- Test output (to be removed later)
257    WRITE (*,'(A,I6,A,I3,A,I3,A,I3)') '*** Connect MPI-Task ', myid_openmpi,   &
258                                      ' to CPU ', acc_rank, ' Devices: ',      &
259                                      num_acc_per_node, ' connected to:',      &
260                                      ACC_GET_DEVICE_NUM( ACC_DEVICE_NVIDIA )
261#endif
262
263!
264!-- Ensure that OpenACC first attaches the GPU devices by copying a dummy data
265!-- region
266    !$acc data copyin( acc_dum )
267
268!
269!-- Initialize measuring of the CPU-time remaining to the run
270    CALL local_tremain_ini
271
272!
273!-- Start of total CPU time measuring.
274    CALL cpu_log( log_point(1), 'total', 'start' )
275    CALL cpu_log( log_point(2), 'initialisation', 'start' )
276
277!
278!-- Open a file for debug output
279    WRITE (myid_char,'(''_'',I6.6)')  myid
280    OPEN( 9, FILE='DEBUG'//TRIM( coupling_char )//myid_char, FORM='FORMATTED' )
281
282!
283!-- Initialize dvrp logging. Also, one PE maybe split from the global
284!-- communicator for doing the dvrp output. In that case, the number of
285!-- PEs available for PALM is reduced by one and communicator comm_palm
286!-- is changed respectively.
287#if defined( __parallel )
288    CALL MPI_COMM_RANK( comm_palm, myid, ierr )
289!
290!-- TEST OUTPUT (TO BE REMOVED)
291    WRITE(9,*) '*** coupling_mode = "', TRIM( coupling_mode ), '"'
292    FLUSH( 9 )
293    IF ( TRIM( coupling_mode ) /= 'uncoupled' )  THEN
294       PRINT*, '*** PE', myid, ' Global target PE:', target_id, &
295               TRIM( coupling_mode )
296    ENDIF
297#endif
298
299    CALL init_dvrp_logging
300
301!
302!-- Read control parameters from NAMELIST files and read environment-variables
303    CALL parin
304
305!
306!-- Check for the user's interface version
307    IF ( user_interface_current_revision /= user_interface_required_revision )  &
308    THEN
309       message_string = 'current user-interface revision "' //                  &
310                        TRIM( user_interface_current_revision ) // '" does ' // &
311                        'not match the required revision ' //                   &
312                        TRIM( user_interface_required_revision )
313        CALL message( 'palm', 'PA0169', 1, 2, 0, 6, 0 )
314    ENDIF
315
316!
317!-- Determine processor topology and local array indices
318    CALL init_pegrid
319
320!
321!-- Generate grid parameters
322    CALL init_grid
323
324!
325!-- Initialize nudging if required
326    IF ( nudging )  THEN
327       CALL init_nudge
328    ENDIF
329
330!
331!-- Initialize reading of large scale forcing from external file - if required
332    IF ( large_scale_forcing )  THEN
333       CALL init_ls_forcing
334    ENDIF
335
336!
337!-- Check control parameters and deduce further quantities
338    CALL check_parameters
339
340!
341!-- Initialize all necessary variables
342    CALL init_3d_model
343
344!
345!-- Coupling protocol setup for nested-domain runs
346    IF ( nested_run )  THEN
347       CALL pmci_modelconfiguration
348!
349!--    Receive and interpolate initial data on children.
350!--    Child initialization must be made first if the model is both child and
351!--    parent
352       CALL pmci_child_initialize
353!
354!--    Send initial condition data from parent to children
355       CALL pmci_parent_initialize
356!
357!--    Exchange_horiz is needed after the nest initialization
358       IF ( nest_domain )  THEN
359          CALL exchange_horiz( u, nbgp )
360          CALL exchange_horiz( v, nbgp )
361          CALL exchange_horiz( w, nbgp )
362          IF ( .NOT. neutral )  THEN
363             CALL exchange_horiz( pt, nbgp )
364          ENDIF
365          IF ( .NOT. constant_diffusion )  CALL exchange_horiz( e, nbgp )
366          IF ( humidity       )  CALL exchange_horiz( q, nbgp )
367          IF ( passive_scalar )  CALL exchange_horiz( s, nbgp )
368       ENDIF
369
370    ENDIF
371
372
373!
374!-- Output of program header
375    IF ( myid == 0 )  CALL header
376
377    CALL cpu_log( log_point(2), 'initialisation', 'stop' )
378
379!
380!-- Set start time in format hh:mm:ss
381    simulated_time_chr = time_to_string( simulated_time )
382
383!
384!-- If required, output of initial arrays
385    IF ( do2d_at_begin )  THEN
386       CALL data_output_2d( 'xy', 0 )
387       CALL data_output_2d( 'xz', 0 )
388       CALL data_output_2d( 'yz', 0 )
389    ENDIF
390    IF ( do3d_at_begin )  THEN
391       CALL data_output_3d( 0 )
392    ENDIF
393
394!
395!-- Declare and initialize variables in the accelerator memory with their
396!-- host values
397    !$acc  data copyin( d, diss, e, e_p, kh, km, p, pt, pt_p, q, ql, tend, te_m, tpt_m, tu_m, tv_m, tw_m, u, u_p, v, vpt, v_p, w, w_p )          &
398    !$acc       copyin( tri, tric, dzu, ddzu, ddzw, dd2zu, l_grid, l_wall, ptdf_x, ptdf_y, pt_init, rdf, rdf_sc, ref_state, ug, u_init, vg, v_init, zu, zw )   &
399    !$acc       copyin( hom, ol, pt1, qs, qsws, qswst, qv1, rif_wall, shf, ts, tswst, us, usws, uswst, uv_total, vsws, vswst, z0, z0h )      &
400    !$acc       copyin( fxm, fxp, fym, fyp, fwxm, fwxp, fwym, fwyp, nzb_diff_s_inner, nzb_diff_s_outer, nzb_diff_u )       &
401    !$acc       copyin( nzb_diff_v, nzb_s_inner, nzb_s_outer, nzb_u_inner )    &
402    !$acc       copyin( nzb_u_outer, nzb_v_inner, nzb_v_outer, nzb_w_inner )   &
403    !$acc       copyin( nzb_w_outer, rflags_invers, rflags_s_inner, rmask, wall_heatflux, wall_e_x, wall_e_y, wall_u, wall_v, wall_w_x, wall_w_y, wall_flags_0, wall_flags_00 )  &
404    !$acc       copyin( ngp_2dh, ngp_2dh_s_inner )  &
405    !$acc       copyin( weight_pres, weight_substep )
406!
407!-- Integration of the model equations using timestep-scheme
408    CALL time_integration
409
410!
411!-- If required, write binary data for restart runs
412    IF ( write_binary(1:4) == 'true' )  THEN
413
414       CALL cpu_log( log_point(22), 'write_3d_binary', 'start' )
415
416       CALL location_message( 'writing restart data', .FALSE. )
417
418       CALL check_open( 14 )
419
420       DO  i = 0, io_blocks-1
421          IF ( i == io_group )  THEN
422!
423!--          Write flow field data
424             CALL write_3d_binary
425          ENDIF
426#if defined( __parallel )
427          CALL MPI_BARRIER( comm2d, ierr )
428#endif
429       ENDDO
430
431       CALL location_message( 'finished', .TRUE. )
432
433       CALL cpu_log( log_point(22), 'write_3d_binary', 'stop' )
434
435!
436!--    If required, write particle data
437       IF ( particle_advection )  CALL lpm_write_restart_file
438    ENDIF
439
440!
441!-- If required, repeat output of header including the required CPU-time
442    IF ( myid == 0 )  CALL header
443!
444!-- If required, final user-defined actions, and
445!-- last actions on the open files and close files. Unit 14 was opened
446!-- in write_3d_binary but it is closed here, to allow writing on this
447!-- unit in routine user_last_actions.
448    CALL cpu_log( log_point(4), 'last actions', 'start' )
449    DO  i = 0, io_blocks-1
450       IF ( i == io_group )  THEN
451          CALL user_last_actions
452          IF ( write_binary(1:4) == 'true' )  CALL close_file( 14 )
453       ENDIF
454#if defined( __parallel )
455       CALL MPI_BARRIER( comm2d, ierr )
456#endif
457    ENDDO
458    CALL close_file( 0 )
459    CALL close_dvrp
460    CALL cpu_log( log_point(4), 'last actions', 'stop' )
461
462#if defined( __mpi2 )
463!
464!-- Test exchange via intercommunicator in case of a MPI-2 coupling
465    IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
466       i = 12345 + myid
467       CALL MPI_SEND( i, 1, MPI_INTEGER, myid, 11, comm_inter, ierr )
468    ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
469       CALL MPI_RECV( i, 1, MPI_INTEGER, myid, 11, comm_inter, status, ierr )
470       PRINT*, '### myid: ', myid, '   received from atmosphere:  i = ', i
471    ENDIF
472#endif
473
474!
475!-- Close the OpenACC dummy data region
476    !$acc end data
477    !$acc end data
478
479!
480!-- Take final CPU-time for CPU-time analysis
481    CALL cpu_log( log_point(1), 'total', 'stop' )
482    CALL cpu_statistics
483
484#if defined( __parallel )
485    CALL MPI_FINALIZE( ierr )
486#endif
487
488 END PROGRAM palm
Note: See TracBrowser for help on using the repository browser.