source: palm/trunk/SOURCE/palm.f90 @ 1781

Last change on this file since 1781 was 1781, checked in by raasch, 5 years ago

some pmc calls completely removed, some moved from time_integration to main program, t_..m arrays removed from pmc

  • Property svn:keywords set to Id
File size: 15.8 KB
Line 
1!> @file palm.f90
2!--------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the terms
6! of the GNU General Public License as published by the Free Software Foundation,
7! either version 3 of the License, or (at your option) any later version.
8!
9! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
10! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
11! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
12!
13! You should have received a copy of the GNU General Public License along with
14! PALM. If not, see <http://www.gnu.org/licenses/>.
15!
16! Copyright 1997-2014 Leibniz Universitaet Hannover
17!--------------------------------------------------------------------------------!
18!
19! Current revisions:
20! -----------------
21! pmc initialization moved from time_integration to here
22!
23! Former revisions:
24! -----------------
25! $Id: palm.f90 1781 2016-03-03 15:12:23Z raasch $
26!
27! 1779 2016-03-03 08:01:28Z raasch
28! setting of nest_domain and coupling_char moved to the pmci
29!
30! 1764 2016-02-28 12:45:19Z raasch
31! cpp-statements for nesting removed, communicator settings cleaned up
32!
33! 1762 2016-02-25 12:31:13Z hellstea
34! Introduction of nested domain feature
35!
36! 1747 2016-02-08 12:25:53Z raasch
37! OpenACC-adjustment for new surface layer parameterization
38!
39! 1682 2015-10-07 23:56:08Z knoop
40! Code annotations made doxygen readable
41!
42! 1668 2015-09-23 13:45:36Z raasch
43! warning replaced by abort in case of failed user interface check
44!
45! 1666 2015-09-23 07:31:10Z raasch
46! check for user's interface version added
47!
48! 1482 2014-10-18 12:34:45Z raasch
49! adjustments for using CUDA-aware OpenMPI
50!
51! 1468 2014-09-24 14:06:57Z maronga
52! Adapted for use on up to 6-digit processor cores
53!
54! 1402 2014-05-09 14:25:13Z raasch
55! location messages added
56!
57! 1374 2014-04-25 12:55:07Z raasch
58! bugfix: various modules added
59!
60! 1320 2014-03-20 08:40:49Z raasch
61! ONLY-attribute added to USE-statements,
62! kind-parameters added to all INTEGER and REAL declaration statements,
63! kinds are defined in new module kinds,
64! old module precision_kind is removed,
65! revision history before 2012 removed,
66! comment fields (!:) to be used for variable explanations added to
67! all variable declaration statements
68!
69! 1318 2014-03-17 13:35:16Z raasch
70! module interfaces removed
71!
72! 1241 2013-10-30 11:36:58Z heinze
73! initialization of nuding and large scale forcing from external file
74!
75! 1221 2013-09-10 08:59:13Z raasch
76! +wall_flags_00, rflags_invers, rflags_s_inner in copyin statement
77!
78! 1212 2013-08-15 08:46:27Z raasch
79! +tri in copyin statement
80!
81! 1179 2013-06-14 05:57:58Z raasch
82! ref_state added to copyin-list
83!
84! 1113 2013-03-10 02:48:14Z raasch
85! openACC statements modified
86!
87! 1111 2013-03-08 23:54:10Z raasch
88! openACC statements updated
89!
90! 1092 2013-02-02 11:24:22Z raasch
91! unused variables removed
92!
93! 1036 2012-10-22 13:43:42Z raasch
94! code put under GPL (PALM 3.9)
95!
96! 1015 2012-09-27 09:23:24Z raasch
97! Version number changed from 3.8 to 3.8a.
98! OpenACC statements added + code changes required for GPU optimization
99!
100! 849 2012-03-15 10:35:09Z raasch
101! write_particles renamed lpm_write_restart_file
102!
103! Revision 1.1  1997/07/24 11:23:35  raasch
104! Initial revision
105!
106!
107! Description:
108! ------------
109!> Large-Eddy Simulation (LES) model for the convective boundary layer,
110!> optimized for use on parallel machines (implementation realized using the
111!> Message Passing Interface (MPI)). The model can also be run on vector machines
112!> (less well optimized) and workstations. Versions for the different types of
113!> machines are controlled via cpp-directives.
114!> Model runs are only feasible using the ksh-script mrun.
115!------------------------------------------------------------------------------!
116 PROGRAM palm
117 
118
119    USE arrays_3d
120
121    USE control_parameters,                                                    &
122        ONLY:  constant_diffusion, coupling_char, coupling_mode,               &
123               do2d_at_begin, do3d_at_begin, humidity, io_blocks, io_group,    &
124               large_scale_forcing, message_string, nest_domain, nudging,      &
125               passive_scalar, simulated_time, simulated_time_chr,             &
126               user_interface_current_revision,                                &
127               user_interface_required_revision, version, wall_heatflux,       &
128               write_binary
129
130    USE cpulog,                                                                &
131        ONLY:  cpu_log, log_point, cpu_statistics
132
133    USE grid_variables,                                                        &
134        ONLY:  fxm, fxp, fym, fyp, fwxm, fwxp, fwym, fwyp, wall_e_x, wall_e_y, &
135               wall_u, wall_v, wall_w_x, wall_w_y
136
137    USE indices,                                                               &
138        ONLY:  nbgp, ngp_2dh, ngp_2dh_s_inner, nzb_diff_s_inner, nzb_diff_s_outer,   &
139               nzb_diff_u, nzb_diff_v, nzb_s_inner, nzb_s_outer, nzb_u_inner,  &
140               nzb_u_outer, nzb_v_inner, nzb_v_outer, nzb_w_inner,             &
141               nzb_w_outer, rflags_invers, rflags_s_inner, wall_flags_0,       &
142               wall_flags_00
143
144    USE kinds
145
146    USE ls_forcing_mod,                                                        &
147        ONLY:  init_ls_forcing
148
149    USE nudge_mod,                                                             &
150        ONLY:  init_nudge
151
152    USE particle_attributes,                                                   &
153        ONLY:  particle_advection
154
155    USE pegrid
156
157    USE pmc_interface,                                                         &
158        ONLY:  cpl_id, nested_run, pmci_client_initialize, pmci_init,          &
159               pmci_modelconfiguration, pmci_server_initialize
160
161    USE statistics,                                                            &
162        ONLY:  hom, rmask, weight_pres, weight_substep
163
164    USE surface_layer_fluxes_mod,                                              &
165        ONLY:  pt1, qv1, uv_total
166
167#if defined( __openacc )
168    USE OPENACC
169#endif
170
171    IMPLICIT NONE
172
173!
174!-- Local variables
175    CHARACTER(LEN=9)  ::  time_to_string  !<
176    CHARACTER(LEN=10) ::  env_string      !< to store string of environment var
177    INTEGER(iwp)      ::  env_stat        !< to hold status of GET_ENV
178    INTEGER(iwp)      ::  i               !<
179    INTEGER(iwp)      ::  myid_openmpi    !< OpenMPI local rank for CUDA aware MPI
180#if defined( __openacc )
181    REAL(wp), DIMENSION(100) ::  acc_dum     !<
182#endif
183
184    version = 'PALM 4.0'
185    user_interface_required_revision = 'r1663'
186
187#if defined( __parallel )
188!
189!-- MPI initialisation. comm2d is preliminary set, because
190!-- it will be defined in init_pegrid but is used before in cpu_log.
191    CALL MPI_INIT( ierr )
192
193!
194!-- Initialize the coupling for nested-domain runs
195!-- comm_palm is the communicator which includes all PEs (MPI processes)
196!-- available for this (nested) model. If it is not a nested run, comm_palm
197!-- is returned as MPI_COMM_WORLD
198    CALL pmci_init( comm_palm )
199    comm2d = comm_palm
200!
201!-- Get the (preliminary) number of MPI processes and the local PE-id (in case
202!-- of a further communicator splitting in init_coupling, these numbers will
203!-- be changed in init_pegrid).
204    IF ( nested_run )  THEN
205
206       CALL MPI_COMM_SIZE( comm_palm, numprocs, ierr )
207       CALL MPI_COMM_RANK( comm_palm, myid, ierr )
208
209    ELSE
210
211       CALL MPI_COMM_SIZE( MPI_COMM_WORLD, numprocs, ierr )
212       CALL MPI_COMM_RANK( MPI_COMM_WORLD, myid, ierr )
213!
214!--    Initialize PE topology in case of coupled atmosphere-ocean runs (comm_palm
215!--    will be splitted in init_coupling)
216       CALL init_coupling
217    ENDIF
218#endif
219
220#if defined( __openacc )
221!
222!-- Get the local MPI rank in case of CUDA aware OpenMPI. Important, if there
223!-- is more than one accelerator board on the node
224    CALL GET_ENVIRONMENT_VARIABLE('OMPI_COMM_WORLD_LOCAL_RANK',                &
225         VALUE=env_string, STATUS=env_stat )
226    READ( env_string, '(I1)' )  myid_openmpi
227    PRINT*, '### local_rank = ', myid_openmpi, '  status=',env_stat
228!
229!-- Get the number of accelerator boards per node and assign the MPI processes
230!-- to these boards
231    PRINT*, '*** ACC_DEVICE_NVIDIA = ', ACC_DEVICE_NVIDIA
232    num_acc_per_node  = ACC_GET_NUM_DEVICES( ACC_DEVICE_NVIDIA )
233    IF ( numprocs == 1  .AND.  num_acc_per_node > 0 )  num_acc_per_node = 1
234    PRINT*, '*** myid = ', myid_openmpi, ' num_acc_per_node = ', num_acc_per_node
235    acc_rank = MOD( myid_openmpi, num_acc_per_node )
236    CALL ACC_SET_DEVICE_NUM ( acc_rank, ACC_DEVICE_NVIDIA )
237!
238!-- Test output (to be removed later)
239    WRITE (*,'(A,I6,A,I3,A,I3,A,I3)') '*** Connect MPI-Task ', myid_openmpi,   &
240                                      ' to CPU ', acc_rank, ' Devices: ',      &
241                                      num_acc_per_node, ' connected to:',      &
242                                      ACC_GET_DEVICE_NUM( ACC_DEVICE_NVIDIA )
243#endif
244
245!
246!-- Ensure that OpenACC first attaches the GPU devices by copying a dummy data
247!-- region
248    !$acc data copyin( acc_dum )
249
250!
251!-- Initialize measuring of the CPU-time remaining to the run
252    CALL local_tremain_ini
253
254!
255!-- Start of total CPU time measuring.
256    CALL cpu_log( log_point(1), 'total', 'start' )
257    CALL cpu_log( log_point(2), 'initialisation', 'start' )
258
259!
260!-- Open a file for debug output
261    WRITE (myid_char,'(''_'',I6.6)')  myid
262    OPEN( 9, FILE='DEBUG'//TRIM( coupling_char )//myid_char, FORM='FORMATTED' )
263
264!
265!-- Initialize dvrp logging. Also, one PE maybe split from the global
266!-- communicator for doing the dvrp output. In that case, the number of
267!-- PEs available for PALM is reduced by one and communicator comm_palm
268!-- is changed respectively.
269#if defined( __parallel )
270    CALL MPI_COMM_RANK( comm_palm, myid, ierr )
271!
272!-- TEST OUTPUT (TO BE REMOVED)
273    WRITE(9,*) '*** coupling_mode = "', TRIM( coupling_mode ), '"'
274    CALL LOCAL_FLUSH( 9 )
275    IF ( TRIM( coupling_mode ) /= 'uncoupled' )  THEN
276       PRINT*, '*** PE', myid, ' Global target PE:', target_id, &
277               TRIM( coupling_mode )
278    ENDIF
279#endif
280
281    CALL init_dvrp_logging
282
283!
284!-- Read control parameters from NAMELIST files and read environment-variables
285    CALL parin
286
287!
288!-- Check for the user's interface version
289    IF ( user_interface_current_revision /= user_interface_required_revision )  &
290    THEN
291       message_string = 'current user-interface revision "' //                  &
292                        TRIM( user_interface_current_revision ) // '" does ' // &
293                        'not match the required revision ' //                   &
294                        TRIM( user_interface_required_revision )
295        CALL message( 'palm', 'PA0169', 1, 2, 0, 6, 0 )
296    ENDIF
297
298!
299!-- Determine processor topology and local array indices
300    CALL init_pegrid
301
302!
303!-- Generate grid parameters
304    CALL init_grid
305
306!
307!-- Initialize nudging if required
308    IF ( nudging )  THEN
309       CALL init_nudge
310    ENDIF
311
312!
313!-- Initialize reading of large scale forcing from external file - if required
314    IF ( large_scale_forcing )  THEN
315       CALL init_ls_forcing
316    ENDIF
317
318!
319!-- Check control parameters and deduce further quantities
320    CALL check_parameters
321
322!
323!-- Initialize all necessary variables
324    CALL init_3d_model
325
326!
327!-- Coupling protocol setup for nested-domain runs
328    IF ( nested_run )  THEN
329       CALL pmci_modelconfiguration
330!
331!--    Receive and interpolate initial data on client.
332!--    Client initialization must be made first if the model is both client and
333!--    server
334       CALL pmci_client_initialize
335!
336!--    Send initial condition data from server to client
337       CALL pmci_server_initialize
338!
339!--    Exchange_horiz is needed after the nest initialization
340       IF ( nest_domain )  THEN
341          CALL exchange_horiz( u, nbgp )
342          CALL exchange_horiz( v, nbgp )
343          CALL exchange_horiz( w, nbgp )
344          CALL exchange_horiz( pt, nbgp )
345          IF ( .NOT. constant_diffusion )  CALL exchange_horiz( e, nbgp )
346          IF (humidity  .OR.  passive_scalar)  THEN
347             CALL exchange_horiz( q, nbgp )
348          ENDIF
349       ENDIF
350
351    ENDIF
352
353
354!
355!-- Output of program header
356    IF ( myid == 0 )  CALL header
357
358    CALL cpu_log( log_point(2), 'initialisation', 'stop' )
359
360!
361!-- Set start time in format hh:mm:ss
362    simulated_time_chr = time_to_string( simulated_time )
363
364!
365!-- If required, output of initial arrays
366    IF ( do2d_at_begin )  THEN
367       CALL data_output_2d( 'xy', 0 )
368       CALL data_output_2d( 'xz', 0 )
369       CALL data_output_2d( 'yz', 0 )
370    ENDIF
371    IF ( do3d_at_begin )  THEN
372       CALL data_output_3d( 0 )
373    ENDIF
374
375!
376!-- Declare and initialize variables in the accelerator memory with their
377!-- host values
378    !$acc  data copyin( d, diss, e, e_p, kh, km, p, pt, pt_p, q, ql, tend, te_m, tpt_m, tu_m, tv_m, tw_m, u, u_p, v, vpt, v_p, w, w_p )          &
379    !$acc       copyin( tri, tric, dzu, ddzu, ddzw, dd2zu, l_grid, l_wall, ptdf_x, ptdf_y, pt_init, rdf, rdf_sc, ref_state, ug, u_init, vg, v_init, zu, zw )   &
380    !$acc       copyin( hom, ol, pt1, qs, qsws, qswst, qv1, rif_wall, shf, ts, tswst, us, usws, uswst, uv_total, vsws, vswst, z0, z0h )      &
381    !$acc       copyin( fxm, fxp, fym, fyp, fwxm, fwxp, fwym, fwyp, nzb_diff_s_inner, nzb_diff_s_outer, nzb_diff_u )       &
382    !$acc       copyin( nzb_diff_v, nzb_s_inner, nzb_s_outer, nzb_u_inner )    &
383    !$acc       copyin( nzb_u_outer, nzb_v_inner, nzb_v_outer, nzb_w_inner )   &
384    !$acc       copyin( nzb_w_outer, rflags_invers, rflags_s_inner, rmask, wall_heatflux, wall_e_x, wall_e_y, wall_u, wall_v, wall_w_x, wall_w_y, wall_flags_0, wall_flags_00 )  &
385    !$acc       copyin( ngp_2dh, ngp_2dh_s_inner )  &
386    !$acc       copyin( weight_pres, weight_substep )
387!
388!-- Integration of the model equations using timestep-scheme
389    CALL time_integration
390
391!
392!-- If required, write binary data for restart runs
393    IF ( write_binary(1:4) == 'true' )  THEN
394
395       CALL cpu_log( log_point(22), 'write_3d_binary', 'start' )
396
397       CALL location_message( 'writing restart data', .FALSE. )
398
399       CALL check_open( 14 )
400
401       DO  i = 0, io_blocks-1
402          IF ( i == io_group )  THEN
403!
404!--          Write flow field data
405             CALL write_3d_binary
406          ENDIF
407#if defined( __parallel )
408          CALL MPI_BARRIER( comm2d, ierr )
409#endif
410       ENDDO
411
412       CALL location_message( 'finished', .TRUE. )
413
414       CALL cpu_log( log_point(22), 'write_3d_binary', 'stop' )
415
416!
417!--    If required, write particle data
418       IF ( particle_advection )  CALL lpm_write_restart_file
419    ENDIF
420
421!
422!-- If required, repeat output of header including the required CPU-time
423    IF ( myid == 0 )  CALL header
424!
425!-- If required, final user-defined actions, and
426!-- last actions on the open files and close files. Unit 14 was opened
427!-- in write_3d_binary but it is closed here, to allow writing on this
428!-- unit in routine user_last_actions.
429    CALL cpu_log( log_point(4), 'last actions', 'start' )
430    DO  i = 0, io_blocks-1
431       IF ( i == io_group )  THEN
432          CALL user_last_actions
433          IF ( write_binary(1:4) == 'true' )  CALL close_file( 14 )
434       ENDIF
435#if defined( __parallel )
436       CALL MPI_BARRIER( comm2d, ierr )
437#endif
438    ENDDO
439    CALL close_file( 0 )
440    CALL close_dvrp
441    CALL cpu_log( log_point(4), 'last actions', 'stop' )
442
443#if defined( __mpi2 )
444!
445!-- Test exchange via intercommunicator in case of a MPI-2 coupling
446    IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
447       i = 12345 + myid
448       CALL MPI_SEND( i, 1, MPI_INTEGER, myid, 11, comm_inter, ierr )
449    ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
450       CALL MPI_RECV( i, 1, MPI_INTEGER, myid, 11, comm_inter, status, ierr )
451       PRINT*, '### myid: ', myid, '   received from atmosphere:  i = ', i
452    ENDIF
453#endif
454
455!
456!-- Close the OpenACC dummy data region
457    !$acc end data
458    !$acc end data
459
460!
461!-- Take final CPU-time for CPU-time analysis
462    CALL cpu_log( log_point(1), 'total', 'stop' )
463    CALL cpu_statistics
464
465#if defined( __parallel )
466    CALL MPI_FINALIZE( ierr )
467#endif
468
469 END PROGRAM palm
Note: See TracBrowser for help on using the repository browser.