source: palm/trunk/SOURCE/palm.f90 @ 1683

Last change on this file since 1683 was 1683, checked in by knoop, 6 years ago

last commit documented

  • Property svn:keywords set to Id
File size: 13.5 KB
Line 
1!> @file palm.f90
2!--------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the terms
6! of the GNU General Public License as published by the Free Software Foundation,
7! either version 3 of the License, or (at your option) any later version.
8!
9! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
10! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
11! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
12!
13! You should have received a copy of the GNU General Public License along with
14! PALM. If not, see <http://www.gnu.org/licenses/>.
15!
16! Copyright 1997-2014 Leibniz Universitaet Hannover
17!--------------------------------------------------------------------------------!
18!
19! Current revisions:
20! -----------------
21!
22!
23! Former revisions:
24! -----------------
25! $Id: palm.f90 1683 2015-10-07 23:57:51Z knoop $
26!
27! 1682 2015-10-07 23:56:08Z knoop
28! Code annotations made doxygen readable
29!
30! 1668 2015-09-23 13:45:36Z raasch
31! warning replaced by abort in case of failed user interface check
32!
33! 1666 2015-09-23 07:31:10Z raasch
34! check for user's interface version added
35!
36! 1482 2014-10-18 12:34:45Z raasch
37! adjustments for using CUDA-aware OpenMPI
38!
39! 1468 2014-09-24 14:06:57Z maronga
40! Adapted for use on up to 6-digit processor cores
41!
42! 1402 2014-05-09 14:25:13Z raasch
43! location messages added
44!
45! 1374 2014-04-25 12:55:07Z raasch
46! bugfix: various modules added
47!
48! 1320 2014-03-20 08:40:49Z raasch
49! ONLY-attribute added to USE-statements,
50! kind-parameters added to all INTEGER and REAL declaration statements,
51! kinds are defined in new module kinds,
52! old module precision_kind is removed,
53! revision history before 2012 removed,
54! comment fields (!:) to be used for variable explanations added to
55! all variable declaration statements
56!
57! 1318 2014-03-17 13:35:16Z raasch
58! module interfaces removed
59!
60! 1241 2013-10-30 11:36:58Z heinze
61! initialization of nuding and large scale forcing from external file
62!
63! 1221 2013-09-10 08:59:13Z raasch
64! +wall_flags_00, rflags_invers, rflags_s_inner in copyin statement
65!
66! 1212 2013-08-15 08:46:27Z raasch
67! +tri in copyin statement
68!
69! 1179 2013-06-14 05:57:58Z raasch
70! ref_state added to copyin-list
71!
72! 1113 2013-03-10 02:48:14Z raasch
73! openACC statements modified
74!
75! 1111 2013-03-08 23:54:10Z raasch
76! openACC statements updated
77!
78! 1092 2013-02-02 11:24:22Z raasch
79! unused variables removed
80!
81! 1036 2012-10-22 13:43:42Z raasch
82! code put under GPL (PALM 3.9)
83!
84! 1015 2012-09-27 09:23:24Z raasch
85! Version number changed from 3.8 to 3.8a.
86! OpenACC statements added + code changes required for GPU optimization
87!
88! 849 2012-03-15 10:35:09Z raasch
89! write_particles renamed lpm_write_restart_file
90!
91! Revision 1.1  1997/07/24 11:23:35  raasch
92! Initial revision
93!
94!
95! Description:
96! ------------
97!> Large-Eddy Simulation (LES) model for the convective boundary layer,
98!> optimized for use on parallel machines (implementation realized using the
99!> Message Passing Interface (MPI)). The model can also be run on vector machines
100!> (less well optimized) and workstations. Versions for the different types of
101!> machines are controlled via cpp-directives.
102!> Model runs are only feasible using the ksh-script mrun.
103!------------------------------------------------------------------------------!
104 PROGRAM palm
105 
106
107    USE arrays_3d
108
109    USE control_parameters,                                                    &
110        ONLY:  coupling_char, coupling_mode, do2d_at_begin, do3d_at_begin,     &
111               io_blocks, io_group, large_scale_forcing, message_string,       &
112               nudging, simulated_time, simulated_time_chr,                    &
113               user_interface_current_revision,                                &
114               user_interface_required_revision, version, wall_heatflux,       &
115               write_binary
116
117    USE cpulog,                                                                &
118        ONLY:  cpu_log, log_point, cpu_statistics
119
120    USE grid_variables,                                                        &
121        ONLY:  fxm, fxp, fym, fyp, fwxm, fwxp, fwym, fwyp, wall_e_x, wall_e_y, &
122               wall_u, wall_v, wall_w_x, wall_w_y
123
124    USE indices,                                                               &
125        ONLY:  ngp_2dh, ngp_2dh_s_inner, nzb_diff_s_inner, nzb_diff_s_outer,   &
126               nzb_diff_u, nzb_diff_v, nzb_s_inner, nzb_s_outer, nzb_u_inner,  &
127               nzb_u_outer, nzb_v_inner, nzb_v_outer, nzb_w_inner,             &
128               nzb_w_outer, rflags_invers, rflags_s_inner, wall_flags_0,       &
129               wall_flags_00
130
131    USE kinds
132
133    USE ls_forcing_mod,                                                        &
134        ONLY:  init_ls_forcing
135
136    USE nudge_mod,                                                             &
137        ONLY:  init_nudge
138
139    USE particle_attributes,                                                   &
140        ONLY:  particle_advection
141
142    USE pegrid
143
144    USE statistics,                                                            &
145        ONLY:  hom, rmask, weight_pres, weight_substep
146
147#if defined( __openacc )
148    USE OPENACC
149#endif
150
151    IMPLICIT NONE
152
153!
154!-- Local variables
155    CHARACTER(LEN=9)  ::  time_to_string  !<
156    CHARACTER(LEN=10) ::  env_string      !< to store string of environment var
157    INTEGER(iwp)      ::  env_stat        !< to hold status of GET_ENV
158    INTEGER(iwp)      ::  i               !<
159    INTEGER(iwp)      ::  myid_openmpi    !< OpenMPI local rank for CUDA aware MPI
160#if defined( __openacc )
161    REAL(wp), DIMENSION(100) ::  acc_dum     !<
162#endif
163
164    version = 'PALM 4.0'
165    user_interface_required_revision = 'r1663'
166
167#if defined( __parallel )
168!
169!-- MPI initialisation. comm2d is preliminary set, because
170!-- it will be defined in init_pegrid but is used before in cpu_log.
171    CALL MPI_INIT( ierr )
172    CALL MPI_COMM_SIZE( MPI_COMM_WORLD, numprocs, ierr )
173    CALL MPI_COMM_RANK( MPI_COMM_WORLD, myid, ierr )
174    comm_palm = MPI_COMM_WORLD
175    comm2d    = MPI_COMM_WORLD
176
177!
178!-- Initialize PE topology in case of coupled runs
179    CALL init_coupling
180#endif
181
182#if defined( __openacc )
183!
184!-- Get the local MPI rank in case of CUDA aware OpenMPI. Important, if there
185!-- is more than one accelerator board on the node
186    CALL GET_ENVIRONMENT_VARIABLE('OMPI_COMM_WORLD_LOCAL_RANK',                &
187         VALUE=env_string, STATUS=env_stat )
188    READ( env_string, '(I1)' )  myid_openmpi
189    PRINT*, '### local_rank = ', myid_openmpi, '  status=',env_stat
190!
191!-- Get the number of accelerator boards per node and assign the MPI processes
192!-- to these boards
193    PRINT*, '*** ACC_DEVICE_NVIDIA = ', ACC_DEVICE_NVIDIA
194    num_acc_per_node  = ACC_GET_NUM_DEVICES( ACC_DEVICE_NVIDIA )
195    IF ( numprocs == 1  .AND.  num_acc_per_node > 0 )  num_acc_per_node = 1
196    PRINT*, '*** myid = ', myid_openmpi, ' num_acc_per_node = ', num_acc_per_node
197    acc_rank = MOD( myid_openmpi, num_acc_per_node )
198    CALL ACC_SET_DEVICE_NUM ( acc_rank, ACC_DEVICE_NVIDIA )
199!
200!-- Test output (to be removed later)
201    WRITE (*,'(A,I6,A,I3,A,I3,A,I3)') '*** Connect MPI-Task ', myid_openmpi,   &
202                                      ' to CPU ', acc_rank, ' Devices: ',      &
203                                      num_acc_per_node, ' connected to:',      &
204                                      ACC_GET_DEVICE_NUM( ACC_DEVICE_NVIDIA )
205#endif
206
207!
208!-- Ensure that OpenACC first attaches the GPU devices by copying a dummy data
209!-- region
210    !$acc data copyin( acc_dum )
211
212!
213!-- Initialize measuring of the CPU-time remaining to the run
214    CALL local_tremain_ini
215
216!
217!-- Start of total CPU time measuring.
218    CALL cpu_log( log_point(1), 'total', 'start' )
219    CALL cpu_log( log_point(2), 'initialisation', 'start' )
220
221!
222!-- Open a file for debug output
223    WRITE (myid_char,'(''_'',I6.6)')  myid
224    OPEN( 9, FILE='DEBUG'//TRIM( coupling_char )//myid_char, FORM='FORMATTED' )
225
226!
227!-- Initialize dvrp logging. Also, one PE maybe split from the global
228!-- communicator for doing the dvrp output. In that case, the number of
229!-- PEs available for PALM is reduced by one and communicator comm_palm
230!-- is changed respectively.
231#if defined( __parallel )
232    CALL MPI_COMM_RANK( comm_palm, myid, ierr )
233!
234!-- TEST OUTPUT (TO BE REMOVED)
235    WRITE(9,*) '*** coupling_mode = "', TRIM( coupling_mode ), '"'
236    CALL LOCAL_FLUSH( 9 )
237    IF ( TRIM( coupling_mode ) /= 'uncoupled' )  THEN
238       PRINT*, '*** PE', myid, ' Global target PE:', target_id, &
239               TRIM( coupling_mode )
240    ENDIF
241#endif
242
243    CALL init_dvrp_logging
244
245!
246!-- Read control parameters from NAMELIST files and read environment-variables
247    CALL parin
248
249!
250!-- Check for the user's interface version
251    IF ( user_interface_current_revision /= user_interface_required_revision )  &
252    THEN
253       message_string = 'current user-interface revision "' //                  &
254                        TRIM( user_interface_current_revision ) // '" does ' // &
255                        'not match the required revision ' //                   &
256                        TRIM( user_interface_required_revision )
257        CALL message( 'palm', 'PA0169', 1, 2, 0, 6, 0 )
258    ENDIF
259
260!
261!-- Determine processor topology and local array indices
262    CALL init_pegrid
263
264!
265!-- Generate grid parameters
266    CALL init_grid
267
268!
269!-- Initialize nudging if required
270    IF ( nudging )  THEN
271       CALL init_nudge
272    ENDIF
273
274!
275!-- Initialize reading of large scale forcing from external file - if required
276    IF ( large_scale_forcing )  THEN
277       CALL init_ls_forcing
278    ENDIF
279
280!
281!-- Check control parameters and deduce further quantities
282    CALL check_parameters
283
284!
285!-- Initialize all necessary variables
286    CALL init_3d_model
287
288!
289!-- Output of program header
290    IF ( myid == 0 )  CALL header
291
292    CALL cpu_log( log_point(2), 'initialisation', 'stop' )
293
294!
295!-- Set start time in format hh:mm:ss
296    simulated_time_chr = time_to_string( simulated_time )
297
298!
299!-- If required, output of initial arrays
300    IF ( do2d_at_begin )  THEN
301       CALL data_output_2d( 'xy', 0 )
302       CALL data_output_2d( 'xz', 0 )
303       CALL data_output_2d( 'yz', 0 )
304    ENDIF
305    IF ( do3d_at_begin )  THEN
306       CALL data_output_3d( 0 )
307    ENDIF
308
309!
310!-- Declare and initialize variables in the accelerator memory with their
311!-- host values
312    !$acc  data copyin( d, diss, e, e_p, kh, km, p, pt, pt_p, q, ql, tend, te_m, tpt_m, tu_m, tv_m, tw_m, u, u_p, v, vpt, v_p, w, w_p )          &
313    !$acc       copyin( tri, tric, dzu, ddzu, ddzw, dd2zu, l_grid, l_wall, ptdf_x, ptdf_y, pt_init, rdf, rdf_sc, ref_state, ug, u_init, vg, v_init, zu, zw )   &
314    !$acc       copyin( hom, qs, qsws, qswst, rif, rif_wall, shf, ts, tswst, us, usws, uswst, vsws, vswst, z0, z0h )      &
315    !$acc       copyin( fxm, fxp, fym, fyp, fwxm, fwxp, fwym, fwyp, nzb_diff_s_inner, nzb_diff_s_outer, nzb_diff_u )       &
316    !$acc       copyin( nzb_diff_v, nzb_s_inner, nzb_s_outer, nzb_u_inner )    &
317    !$acc       copyin( nzb_u_outer, nzb_v_inner, nzb_v_outer, nzb_w_inner )   &
318    !$acc       copyin( nzb_w_outer, rflags_invers, rflags_s_inner, rmask, wall_heatflux, wall_e_x, wall_e_y, wall_u, wall_v, wall_w_x, wall_w_y, wall_flags_0, wall_flags_00 )  &
319    !$acc       copyin( ngp_2dh, ngp_2dh_s_inner )  &
320    !$acc       copyin( weight_pres, weight_substep )
321!
322!-- Integration of the model equations using timestep-scheme
323    CALL time_integration
324
325!
326!-- If required, write binary data for restart runs
327    IF ( write_binary(1:4) == 'true' )  THEN
328
329       CALL cpu_log( log_point(22), 'write_3d_binary', 'start' )
330
331       CALL location_message( 'writing restart data', .FALSE. )
332
333       CALL check_open( 14 )
334
335       DO  i = 0, io_blocks-1
336          IF ( i == io_group )  THEN
337!
338!--          Write flow field data
339             CALL write_3d_binary
340          ENDIF
341#if defined( __parallel )
342          CALL MPI_BARRIER( comm2d, ierr )
343#endif
344       ENDDO
345
346       CALL location_message( 'finished', .TRUE. )
347
348       CALL cpu_log( log_point(22), 'write_3d_binary', 'stop' )
349
350!
351!--    If required, write particle data
352       IF ( particle_advection )  CALL lpm_write_restart_file
353    ENDIF
354
355!
356!-- If required, repeat output of header including the required CPU-time
357    IF ( myid == 0 )  CALL header
358!
359!-- If required, final user-defined actions, and
360!-- last actions on the open files and close files. Unit 14 was opened
361!-- in write_3d_binary but it is closed here, to allow writing on this
362!-- unit in routine user_last_actions.
363    CALL cpu_log( log_point(4), 'last actions', 'start' )
364    DO  i = 0, io_blocks-1
365       IF ( i == io_group )  THEN
366          CALL user_last_actions
367          IF ( write_binary(1:4) == 'true' )  CALL close_file( 14 )
368       ENDIF
369#if defined( __parallel )
370       CALL MPI_BARRIER( comm2d, ierr )
371#endif
372    ENDDO
373    CALL close_file( 0 )
374    CALL close_dvrp
375    CALL cpu_log( log_point(4), 'last actions', 'stop' )
376
377#if defined( __mpi2 )
378!
379!-- Test exchange via intercommunicator in case of a MPI-2 coupling
380    IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
381       i = 12345 + myid
382       CALL MPI_SEND( i, 1, MPI_INTEGER, myid, 11, comm_inter, ierr )
383    ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
384       CALL MPI_RECV( i, 1, MPI_INTEGER, myid, 11, comm_inter, status, ierr )
385       PRINT*, '### myid: ', myid, '   received from atmosphere:  i = ', i
386    ENDIF
387#endif
388
389!
390!-- Close the OpenACC dummy data region
391    !$acc end data
392    !$acc end data
393
394!
395!-- Take final CPU-time for CPU-time analysis
396    CALL cpu_log( log_point(1), 'total', 'stop' )
397    CALL cpu_statistics
398
399#if defined( __parallel )
400    CALL MPI_FINALIZE( ierr )
401#endif
402
403 END PROGRAM palm
Note: See TracBrowser for help on using the repository browser.