Home

Context Navigation

source: palm/trunk/SOURCE/land_surface_model.f90 @ 1500

Last change on this file since 1500 was 1500, checked in by maronga, 10 years ago
bugfixes and adjustments in land surface model
Property svn:keywords set to `Id`
File size: 53.6 KB

Line
1	MODULE land_surface_model_mod
2
3	!--------------------------------------------------------------------------------!
4	! This file is part of PALM.
5	!
6	! PALM is free software: you can redistribute it and/or modify it under the terms
7	! of the GNU General Public License as published by the Free Software Foundation,
8	! either version 3 of the License, or (at your option) any later version.
9	!
10	! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11	! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12	! A PARTICULAR PURPOSE. See the GNU General Public License for more details.
13	!
14	! You should have received a copy of the GNU General Public License along with
15	! PALM. If not, see <http://www.gnu.org/licenses/>.
16	!
17	! Copyright 1997-2014 Leibniz Universitaet Hannover
18	!--------------------------------------------------------------------------------!
19	!
20	! Current revisions:
21	! -----------------
22	! Corrected calculation of aerodynamic resistance (r_a).
23	! Precipitation is now added to liquid water reservoir using LE_liq.
24	! Added support for dry runs.
25	!
26	! Former revisions:
27	! -----------------
28	! $Id: land_surface_model.f90 1500 2014-12-03 17:42:41Z maronga $
29	!
30	! 1496 2014-12-02 17:25:50Z maronga
31	! Initial revision
32	!
33	!
34	! Description:
35	! ------------
36	! Land surface model, consisting of a solver for the energy balance at the
37	! surface and a four layer soil scheme. The scheme is similar to the TESSEL
38	! scheme implemented in the ECMWF IFS model, with modifications according to
39	! H-TESSEL. The implementation is based on the formulation implemented in the
40	! DALES model.
41	!
42	! To do list:
43	! -----------
44	! - Add support for binary I/O support
45	! - Add support for lsm data output
46	! - Check for time step criterion
47	! - Check use with RK-2 and Euler time-stepping
48	! - Adaption for use with cloud physics (liquid water potential temperature)
49	! - Check reaction of plants at wilting point and at atmospheric saturation
50	! - Consider partial absorption of the net shortwave radiation by the skin layer
51	! - Allow for water surfaces, check performance for bare soils
52	!------------------------------------------------------------------------------!
53	USE arrays_3d, &
54	ONLY: pt, pt_p, q, q_p, qsws, rif, shf, ts, us, z0, z0h
55
56	USE cloud_parameters, &
57	ONLY: cp, l_d_r, l_v, precipitation_rate, rho_l, r_d, r_v
58
59	USE control_parameters, &
60	ONLY: dt_3d, humidity, intermediate_timestep_count, &
61	intermediate_timestep_count_max, precipitation, pt_surface, &
62	rho_surface, surface_pressure, timestep_scheme, tsc
63
64	USE indices, &
65	ONLY: nxlg, nxrg, nyng, nysg, nzb_s_inner
66
67	USE kinds
68
69	USE radiation_model_mod, &
70	ONLY: Rn, SW_in, sigma_SB
71
72
73	IMPLICIT NONE
74
75	!
76	!-- LSM model constants
77	INTEGER(iwp), PARAMETER :: soil_layers = 4 !: number of soil layers (fixed for now)
78
79	REAL(wp), PARAMETER :: &
80	b_CH = 6.04_wp, & ! Clapp & Hornberger exponent
81	lambda_h_dry = 0.19_wp, & ! heat conductivity for dry soil
82	lambda_h_sm = 3.44_wp, & ! heat conductivity of the soil matrix
83	lambda_h_water = 0.57_wp, & ! heat conductivity of water
84	psi_sat = -0.388_wp, & ! soil matrix potential at saturation
85	rhoC_soil = 2.19E6_wp, & ! volumetric heat capacity of soil
86	rhoC_water = 4.20E6_wp, & ! volumetric heat capacity of water
87	m_max_depth = 0.0002_wp ! Maximum capacity of the water reservoir (m)
88
89
90	!
91	!-- LSM variables
92	INTEGER(iwp) :: veg_type = 2, & !: vegetation type, 0: user-defined, 1-19: generic (see list)
93	soil_type = 3 !: soil type, 0: user-defined, 1-6: generic (see list)
94
95	LOGICAL :: conserve_water_content = .TRUE., & !: open or closed bottom surface for the soil model
96	land_surface = .FALSE. !: flag parameter indicating wheather the lsm is used
97
98	! value 9999999.9_wp -> generic available or user-defined value must be set
99	! otherwise -> no generic variable and user setting is optional
100	REAL(wp) :: alpha_VanGenuchten = 0.0_wp, & !: NAMELIST alpha_VG
101	canopy_resistance_coefficient = 0.0_wp, & !: NAMELIST gD
102	C_skin = 20000.0_wp, & !: Skin heat capacity
103	drho_l_lv, & !: (rho_l * l_v)**-1
104	exn, & !: value of the Exner function
105	e_s = 0.0_wp, & !: saturation water vapour pressure
106	field_capacity = 0.0_wp, & !: NAMELIST m_fc
107	f_shortwave_incoming = 9999999.9_wp, & !: NAMELIST f_SW_in
108	hydraulic_conductivity = 0.0_wp, & !: NAMELIST gamma_w_sat
109	Ke = 0.0_wp, & !: Kersten number
110	lambda_skin_stable = 9999999.9_wp, & !: NAMELIST lambda_skin_s
111	lambda_skin_unstable = 9999999.9_wp, & !: NAMELIST lambda_skin_u
112	leaf_area_index = 9999999.9_wp, & !: NAMELIST LAI
113	l_VanGenuchten = 0.0_WP, & !: NAMELIST l_VG
114	min_canopy_resistance = 110.0_wp, & !: NAMELIST r_s_min
115	m_total = 0.0_wp, & !: weighed total water content of the soil (m3/m3)
116	n_VanGenuchten = 0.0_WP, & !: NAMELIST n_VG
117	q_s = 0.0_wp, & !: saturation specific humidity
118	residual_moisture = 0.0_wp, & !: NAMELIST m_res
119	rho_cp, & !: rho_surface * cp
120	rho_lv, & !: rho * l_v
121	rd_d_rv, & !: r_d / r_v
122	saturation_moisture = 0.0_wp, & !: NAMELIST m_sat
123	vegetation_coverage = 9999999.9_wp, & !: NAMELIST c_veg
124	wilting_point = 0.0_wp !: NAMELIST m_wilt
125
126	REAL(wp), DIMENSION(0:soil_layers-1) :: &
127	ddz_soil, & !: 1/dz_soil
128	ddz_soil_stag, & !: 1/dz_soil_stag
129	dz_soil, & !: soil grid spacing (center-center)
130	dz_soil_stag, & !: soil grid spacing (edge-edge)
131	root_extr = 0.0_wp, & !: root extraction
132	root_fraction = (/0.35_wp, 0.38_wp, 0.23_wp, 0.04_wp/), & !: distribution of root surface area to the individual soil layers
133	soil_level = (/0.07_wp, 0.28_wp, 1.00_wp, 2.89_wp/), & !: soil layer depths (m)
134	soil_moisture = 0.0_wp !: soil moisture content (m3/m3)
135
136	REAL(wp), DIMENSION(0:soil_layers) :: &
137	soil_temperature = 9999999.9_wp !: soil temperature (K)
138
139	#if defined( __nopointer )
140	REAL(wp), DIMENSION(:,:), ALLOCATABLE, TARGET :: T_0, & !: skin temperature (K)
141	T_0_p, & !: progn. skin temperature (K)
142	m_liq, & !: liquid water reservoir (m)
143	m_liq_p !: progn. liquid water reservoir (m)
144	#else
145	REAL(wp), DIMENSION(:,:), POINTER :: T_0, &
146	T_0_p, &
147	m_liq, &
148	m_liq_p
149
150	REAL(wp), DIMENSION(:,:), ALLOCATABLE, TARGET :: T_0_1, T_0_2, &
151	m_liq_1, m_liq_2
152	#endif
153
154	!
155	!-- Temporal tendencies for time stepping
156	REAL(wp), DIMENSION(:,:), ALLOCATABLE :: tT_0_m, & !: skin temperature tendency (K)
157	tm_liq_m !: liquid water reservoir tendency (m)
158
159	!
160	!-- Energy balance variables
161	REAL(wp), DIMENSION(:,:), ALLOCATABLE :: &
162	alpha_VG, & !: coef. of Van Genuchten
163	c_liq, & !: liquid water coverage (of vegetated area)
164	c_veg, & !: vegetation coverage
165	f_SW_in, & !: ?
166	G, & !: surface soil heat flux
167	H, & !: surface flux of sensible heat
168	gamma_w_sat, & !: hydraulic conductivity at saturation
169	gD, & !: coefficient for dependence of r_canopy on water vapour pressure deficit
170	LAI, & !: leaf area index
171	LE, & !: surface flux of latent heat (total)
172	LE_veg, & !: surface flux of latent heat (vegetation portion)
173	LE_soil, & !: surface flux of latent heat (soil portion)
174	LE_liq, & !: surface flux of latent heat (liquid water portion)
175	lambda_h_sat, & !: heat conductivity for dry soil
176	lambda_skin_s, & !: coupling between skin and soil (depends on vegetation type)
177	lambda_skin_u, & !: coupling between skin and soil (depends on vegetation type)
178	l_VG, & !: coef. of Van Genuchten
179	m_fc, & !: soil moisture at field capacity (m3/m3)
180	m_res, & !: residual soil moisture
181	m_sat, & !: saturation soil moisture (m3/m3)
182	m_wilt, & !: soil moisture at permanent wilting point (m3/m3)
183	n_VG, & !: coef. Van Genuchten
184	r_a, & !: aerodynamic resistance
185	r_canopy, & !: canopy resistance
186	r_soil, & !: soil resitance
187	r_soil_min, & !: minimum soil resistance
188	r_s, & !: total surface resistance (combination of r_soil and r_canopy)
189	r_s_min !: minimum canopy resistance
190
191	REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: &
192	lambda_h, & !: heat conductivity of soil (?)
193	lambda_w, & !: hydraulic diffusivity of soil (?)
194	gamma_w, & !: hydraulic conductivity of soil (?)
195	rhoC_total !: volumetric heat capacity of the actual soil matrix (?)
196
197	#if defined( __nopointer )
198	REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, TARGET :: &
199	T_soil, & !: Soil temperature (K)
200	T_soil_p, & !: Prog. soil temperature (K)
201	m_soil, & !: Soil moisture (m3/m3)
202	m_soil_p !: Prog. soil moisture (m3/m3)
203	#else
204	REAL(wp), DIMENSION(:,:,:), POINTER :: &
205	T_soil, T_soil_p, &
206	m_soil, m_soil_p
207
208	REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, TARGET :: &
209	T_soil_1, T_soil_2, &
210	m_soil_1, m_soil_2
211
212
213	#endif
214
215
216	REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: &
217	tT_soil_m, & !: T_soil storage array
218	tm_soil_m, & !: m_soil storage array
219	root_fr !: root fraction (sum=1)
220
221	!
222	!-- Land surface parameters according to the following classes (veg_type)
223	!-- (0 user defined)
224	!-- 1 crops, mixed farming
225	!-- 2 short grass
226	!-- 3 evergreen needleleaf trees
227	!-- 4 deciduous needleleaf trees
228	!-- 5 evergreen broadleaf trees
229	!-- 6 deciduous broadleaf trees
230	!-- 7 tall grass
231	!-- 8 desert
232	!-- 9 tundra
233	!-- 10 irrigated crops
234	!-- 11 semidesert
235	!-- 12 ice caps and glaciers
236	!-- 13 bogs and marshes
237	!-- 14 inland water
238	!-- 15 ocean
239	!-- 16 evergreen shrubs
240	!-- 17 deciduous shrubs
241	!-- 18 mixed forest/woodland
242	!-- 19 interrupted forest
243
244	!
245	!-- Land surface parameters I r_s_min, LAI, c_veg, gD
246	REAL(wp), DIMENSION(0:3,1:19) :: veg_pars = RESHAPE( (/ &
247	180.0_wp, 3.00_wp, 0.90_wp, 0.00_wp, & ! 1
248	110.0_wp, 2.00_wp, 0.85_wp, 0.00_wp, & ! 2
249	500.0_wp, 5.00_wp, 0.90_wp, 0.03_wp, & ! 3
250	500.0_wp, 5.00_wp, 0.90_wp, 0.03_wp, & ! 4
251	175.0_wp, 5.00_wp, 0.90_wp, 0.03_wp, & ! 5
252	240.0_wp, 6.00_wp, 0.99_wp, 0.13_wp, & ! 6
253	100.0_wp, 2.00_wp, 0.70_wp, 0.00_wp, & ! 7
254	250.0_wp, 0.50_wp, 0.00_wp, 0.00_wp, & ! 8
255	80.0_wp, 1.00_wp, 0.50_wp, 0.00_wp, & ! 9
256	180.0_wp, 3.00_wp, 0.90_wp, 0.00_wp, & ! 10
257	150.0_wp, 0.50_wp, 0.10_wp, 0.00_wp, & ! 11
258	0.0_wp, 0.00_wp, 0.00_wp, 0.00_wp, & ! 12
259	240.0_wp, 4.00_wp, 0.60_wp, 0.00_wp, & ! 13
260	0.0_wp, 0.00_wp, 0.00_wp, 0.00_wp, & ! 14
261	0.0_wp, 0.00_wp, 0.00_wp, 0.00_wp, & ! 15
262	225.0_wp, 3.00_wp, 0.50_wp, 0.00_wp, & ! 16
263	225.0_wp, 1.50_wp, 0.50_wp, 0.00_wp, & ! 17
264	250.0_wp, 5.00_wp, 0.90_wp, 0.03_wp, & ! 18
265	175.0_wp, 2.50_wp, 0.90_wp, 0.03_wp & ! 19
266	/), (/ 4, 19 /) )
267
268	!
269	!-- Land surface parameters II z0, z0h
270	REAL(wp), DIMENSION(0:1,1:19) :: roughness_par = RESHAPE( (/ &
271	0.25_wp, 0.25E-2_wp, & ! 1
272	0.20_wp, 0.20E-2_wp, & ! 2
273	2.00_wp, 2.00_wp, & ! 3
274	2.00_wp, 2.00_wp, & ! 4
275	2.00_wp, 2.00_wp, & ! 5
276	2.00_wp, 2.00_wp, & ! 6
277	0.47_wp, 0.47E-2_wp, & ! 7
278	0.013_wp, 0.013E-2_wp, & ! 8
279	0.034_wp, 0.034E-2_wp, & ! 9
280	0.5_wp, 0.50E-2_wp, & ! 10
281	0.17_wp, 0.17E-2_wp, & ! 11
282	1.3E-3_wp, 1.3E-4_wp, & ! 12
283	0.83_wp, 0.83E-2_wp, & ! 13
284	0.00_wp, 0.00E-2_wp, & ! 14
285	0.00_wp, 0.00E-2_wp, & ! 15
286	0.10_wp, 0.10E-2_wp, & ! 16
287	0.25_wp, 0.25E-2_wp, & ! 17
288	2.00_wp, 2.00E-2_wp, & ! 18
289	1.10_wp, 1.10E-2_wp & ! 19
290	/), (/ 2, 19 /) )
291
292	!
293	!-- Land surface parameters III lambda_skin_s, lambda_skin_u, f_SW_in
294	REAL(wp), DIMENSION(0:2,1:19) :: skin_pars = RESHAPE( (/ &
295	10.0_wp, 10.0_wp, 0.05_wp, & ! 1
296	10.0_wp, 10.0_wp, 0.05_wp, & ! 2
297	20.0_wp, 15.0_wp, 0.03_wp, & ! 3
298	20.0_wp, 15.0_wp, 0.03_wp, & ! 4
299	20.0_wp, 15.0_wp, 0.03_wp, & ! 5
300	20.0_wp, 15.0_wp, 0.03_wp, & ! 6
301	10.0_wp, 10.0_wp, 0.05_wp, & ! 7
302	15.0_wp, 15.0_wp, 0.00_wp, & ! 8
303	10.0_wp, 10.0_wp, 0.05_wp, & ! 9
304	10.0_wp, 10.0_wp, 0.05_wp, & ! 10
305	10.0_wp, 10.0_wp, 0.05_wp, & ! 11
306	58.0_wp, 58.0_wp, 0.00_wp, & ! 12
307	10.0_wp, 10.0_wp, 0.05_wp, & ! 13
308	1.0E20_wp, 1.0E20_wp, 0.00_wp, & ! 14
309	1.0E20_wp, 1.0E20_wp, 0.00_wp, & ! 15
310	10.0_wp, 10.0_wp, 0.05_wp, & ! 16
311	10.0_wp, 10.0_wp, 0.05_wp, & ! 17
312	20.0_wp, 15.0_wp, 0.03_wp, & ! 18
313	20.0_wp, 15.0_wp, 0.03_wp & ! 19
314	/), (/ 3, 19 /) )
315
316	!
317	!-- Root distribution (sum = 1) level 1, level 2, level 3, level 4,
318	REAL(wp), DIMENSION(0:3,1:19) :: root_distribution = RESHAPE( (/ &
319	0.24_wp, 0.41_wp, 0.31_wp, 0.04_wp, & ! 1
320	0.35_wp, 0.38_wp, 0.23_wp, 0.04_wp, & ! 2
321	0.26_wp, 0.39_wp, 0.29_wp, 0.06_wp, & ! 3
322	0.26_wp, 0.38_wp, 0.29_wp, 0.07_wp, & ! 4
323	0.24_wp, 0.38_wp, 0.31_wp, 0.07_wp, & ! 5
324	0.25_wp, 0.34_wp, 0.27_wp, 0.14_wp, & ! 6
325	0.27_wp, 0.27_wp, 0.27_wp, 0.09_wp, & ! 7
326	1.00_wp, 0.00_wp, 0.00_wp, 0.00_wp, & ! 8
327	0.47_wp, 0.45_wp, 0.08_wp, 0.00_wp, & ! 9
328	0.24_wp, 0.41_wp, 0.31_wp, 0.04_wp, & ! 10
329	0.17_wp, 0.31_wp, 0.33_wp, 0.19_wp, & ! 11
330	0.00_wp, 0.00_wp, 0.00_wp, 0.00_wp, & ! 12
331	0.25_wp, 0.34_wp, 0.27_wp, 0.11_wp, & ! 13
332	0.00_wp, 0.00_wp, 0.00_wp, 0.00_wp, & ! 14
333	0.00_wp, 0.00_wp, 0.00_wp, 0.00_wp, & ! 15
334	0.23_wp, 0.36_wp, 0.30_wp, 0.11_wp, & ! 16
335	0.23_wp, 0.36_wp, 0.30_wp, 0.11_wp, & ! 17
336	0.19_wp, 0.35_wp, 0.36_wp, 0.10_wp, & ! 18
337	0.19_wp, 0.35_wp, 0.36_wp, 0.10_wp & ! 19
338	/), (/ 4, 19 /) )
339
340	!
341	!-- Soil parameters according to the following porosity classes (soil_type)
342	!-- (0 user defined)
343	!-- 1 coarse
344	!-- 2 medium
345	!-- 3 medium-fine
346	!-- 4 fine
347	!-- 5 very fine
348	!-- 6 organic
349	!
350	!-- Soil parameters I alpha_VG, l_VG, n_VG, gamma_w_sat
351	REAL(wp), DIMENSION(0:3,1:6) :: soil_pars = RESHAPE( (/ &
352	3.83_wp, 1.250_wp, 1.38_wp, 6.94E-6_wp, & ! 1
353	3.14_wp, -2.342_wp, 1.28_wp, 1.16E-6_wp, & ! 2
354	0.83_wp, -0.588_wp, 1.25_wp, 0.26E-6_wp, & ! 3
355	3.67_wp, -1.977_wp, 1.10_wp, 2.87E-6_wp, & ! 4
356	2.65_wp, 2.500_wp, 1.10_wp, 1.74E-6_wp, & ! 5
357	1.30_wp, 0.400_wp, 1.20_wp, 0.93E-6_wp & ! 6
358	/), (/ 4, 6 /) )
359
360	!
361	!-- Soil parameters II m_sat, m_fc, m_wilt, m_res
362	REAL(wp), DIMENSION(0:3,1:6) :: m_soil_pars = RESHAPE( (/ &
363	0.403_wp, 0.244_wp, 0.059_wp, 0.025_wp, & ! 1
364	0.439_wp, 0.347_wp, 0.151_wp, 0.010_wp, & ! 2
365	0.430_wp, 0.383_wp, 0.133_wp, 0.010_wp, & ! 3
366	0.520_wp, 0.448_wp, 0.279_wp, 0.010_wp, & ! 4
367	0.614_wp, 0.541_wp, 0.335_wp, 0.010_wp, & ! 5
368	0.766_wp, 0.663_wp, 0.267_wp, 0.010_wp & ! 6
369	/), (/ 4, 6 /) )
370
371
372	SAVE
373
374
375	PRIVATE
376
377
378	PUBLIC alpha_VanGenuchten, C_skin, canopy_resistance_coefficient, &
379	conserve_water_content, field_capacity, f_shortwave_incoming, &
380	hydraulic_conductivity, init_lsm, lambda_skin_stable, &
381	lambda_skin_unstable, land_surface, leaf_area_index, &
382	lsm_energy_balance, lsm_soil_model, l_VanGenuchten, &
383	min_canopy_resistance, n_VanGenuchten, residual_moisture, &
384	root_fraction, saturation_moisture, soil_level, soil_moisture, &
385	soil_temperature, soil_type, vegetation_coverage, veg_type, &
386	wilting_point
387
388	#if defined( __nopointer )
389	PUBLIC m_liq, m_liq_p, m_soil, m_soil_p, T_0, T_0_p, T_soil, T_soil_p
390	#else
391	PUBLIC m_liq, m_liq_1, m_liq_2, m_liq_p, m_soil, m_soil_1, m_soil_2, &
392	m_soil_p, T_0, T_0_1, T_0_2, T_0_p, T_soil, T_soil_1, T_soil_2, &
393	T_soil_p
394	#endif
395
396
397	INTERFACE init_lsm
398	MODULE PROCEDURE init_lsm
399	END INTERFACE init_lsm
400
401	INTERFACE lsm_energy_balance
402	MODULE PROCEDURE lsm_energy_balance
403	END INTERFACE lsm_energy_balance
404
405	INTERFACE lsm_soil_model
406	MODULE PROCEDURE lsm_soil_model
407	END INTERFACE lsm_soil_model
408
409
410	CONTAINS
411
412
413	!------------------------------------------------------------------------------!
414	! Description:
415	! ------------
416	!-- Initialization of the land surface model
417	!------------------------------------------------------------------------------!
418	SUBROUTINE init_lsm
419
420
421	IMPLICIT NONE
422
423	INTEGER(iwp) :: i !: running index
424	INTEGER(iwp) :: j !: running index
425	INTEGER(iwp) :: k !: running index
426
427
428	!
429	!-- Calculate frequently used parameters
430	rho_cp = cp * rho_surface
431	rd_d_rv = r_d / r_v
432	rho_lv = rho_surface * l_v
433	drho_l_lv = 1.0 / (rho_l * l_v)
434
435	!
436	!-- Allocate skin and soil temperature / humidity
437	#if defined( __nopointer )
438	ALLOCATE ( T_0(nysg:nyng,nxlg:nxrg) )
439	ALLOCATE ( T_0_p(nysg:nyng,nxlg:nxrg) )
440	#else
441	ALLOCATE ( T_0_1(nysg:nyng,nxlg:nxrg) )
442	ALLOCATE ( T_0_2(nysg:nyng,nxlg:nxrg) )
443	#endif
444
445	ALLOCATE ( tT_0_m(nysg:nyng,nxlg:nxrg) )
446
447	#if defined( __nopointer )
448	ALLOCATE ( T_soil(0:soil_layers,nysg:nyng,nxlg:nxrg) )
449	ALLOCATE ( T_soil_p(0:soil_layers,nysg:nyng,nxlg:nxrg) )
450	#else
451	ALLOCATE ( T_soil_1(0:soil_layers,nysg:nyng,nxlg:nxrg) )
452	ALLOCATE ( T_soil_2(0:soil_layers,nysg:nyng,nxlg:nxrg) )
453	#endif
454
455	ALLOCATE ( tT_soil_m(0:soil_layers-1,nysg:nyng,nxlg:nxrg) )
456
457	#if defined( __nopointer )
458	ALLOCATE ( m_liq(nysg:nyng,nxlg:nxrg) )
459	ALLOCATE ( m_liq_p(nysg:nyng,nxlg:nxrg) )
460	#else
461	ALLOCATE ( m_liq_1(nysg:nyng,nxlg:nxrg) )
462	ALLOCATE ( m_liq_2(nysg:nyng,nxlg:nxrg) )
463	#endif
464
465	ALLOCATE ( tm_liq_m(nysg:nyng,nxlg:nxrg) )
466
467	#if defined( __nopointer )
468	ALLOCATE ( m_soil(0:soil_layers-1,nysg:nyng,nxlg:nxrg) )
469	ALLOCATE ( m_soil_p(0:soil_layers-1,nysg:nyng,nxlg:nxrg) )
470	#else
471	ALLOCATE ( m_soil_1(0:soil_layers-1,nysg:nyng,nxlg:nxrg) )
472	ALLOCATE ( m_soil_2(0:soil_layers-1,nysg:nyng,nxlg:nxrg) )
473	#endif
474
475	ALLOCATE ( tm_soil_m(0:soil_layers-1,nysg:nyng,nxlg:nxrg) )
476
477
478	#if ! defined( __nopointer )
479	!
480	!-- Initial assignment of the pointers
481	T_soil => T_soil_1; T_soil_p => T_soil_2
482	T_0 => T_0_1; T_0_p => T_0_2
483	m_soil => m_soil_1; m_soil_p => m_soil_2
484	m_liq => m_liq_1; m_liq_p => m_liq_2
485	#endif
486
487	T_0 = 0.0_wp
488	T_0_p = 0.0_wp
489	tT_0_m = 0.0_wp
490
491	T_soil = 0.0_wp
492	T_soil_p = 0.0_wp
493	tT_soil_m = 0.0_wp
494
495	m_liq = 0.0_wp
496	m_liq_p = 0.0_wp
497	tm_liq_m = 0.0_wp
498
499	m_soil = 0.0_wp
500	m_soil_p = 0.0_wp
501	tm_soil_m = 0.0_wp
502
503	!
504	!-- Allocate 2D vegetation model arrays
505	ALLOCATE ( alpha_VG(nysg:nyng,nxlg:nxrg) )
506	ALLOCATE ( c_liq(nysg:nyng,nxlg:nxrg) )
507	ALLOCATE ( c_veg(nysg:nyng,nxlg:nxrg) )
508	ALLOCATE ( f_SW_in(nysg:nyng,nxlg:nxrg) )
509	ALLOCATE ( G(nysg:nyng,nxlg:nxrg) )
510	ALLOCATE ( H(nysg:nyng,nxlg:nxrg) )
511	ALLOCATE ( gamma_w_sat(nysg:nyng,nxlg:nxrg) )
512	ALLOCATE ( gD(nysg:nyng,nxlg:nxrg) )
513	ALLOCATE ( LAI(nysg:nyng,nxlg:nxrg) )
514	ALLOCATE ( LE(nysg:nyng,nxlg:nxrg) )
515	ALLOCATE ( LE_veg(nysg:nyng,nxlg:nxrg) )
516	ALLOCATE ( LE_soil(nysg:nyng,nxlg:nxrg) )
517	ALLOCATE ( LE_liq(nysg:nyng,nxlg:nxrg) )
518	ALLOCATE ( l_VG(nysg:nyng,nxlg:nxrg) )
519	ALLOCATE ( lambda_h_sat(nysg:nyng,nxlg:nxrg) )
520	ALLOCATE ( lambda_skin_u(nysg:nyng,nxlg:nxrg) )
521	ALLOCATE ( lambda_skin_s(nysg:nyng,nxlg:nxrg) )
522	ALLOCATE ( m_fc(nysg:nyng,nxlg:nxrg) )
523	ALLOCATE ( m_res(nysg:nyng,nxlg:nxrg) )
524	ALLOCATE ( m_sat(nysg:nyng,nxlg:nxrg) )
525	ALLOCATE ( m_wilt(nysg:nyng,nxlg:nxrg) )
526	ALLOCATE ( n_VG(nysg:nyng,nxlg:nxrg) )
527	ALLOCATE ( r_a(nysg:nyng,nxlg:nxrg) )
528	ALLOCATE ( r_canopy(nysg:nyng,nxlg:nxrg) )
529	ALLOCATE ( r_soil(nysg:nyng,nxlg:nxrg) )
530	ALLOCATE ( r_soil_min(nysg:nyng,nxlg:nxrg) )
531	ALLOCATE ( r_s(nysg:nyng,nxlg:nxrg) )
532	ALLOCATE ( r_s_min(nysg:nyng,nxlg:nxrg) )
533
534	!
535	!-- Set initial and default values
536	c_liq = 0.0_wp
537	c_veg = 0.0_wp
538	f_SW_in = 0.05_wp
539	gD = 0.0_wp
540	LAI = 0.0_wp
541	lambda_skin_u = 10.0_wp
542	lambda_skin_s = 10.0_wp
543
544
545	G = 0.0_wp
546	H = rho_cp * shf
547
548	IF ( humidity ) THEN
549	LE = rho_l * l_v * qsws
550	ELSE
551	LE = 0.0_wp
552	ENDIF
553
554	LE_veg = 0.0_wp
555	LE_soil = LE
556	LE_liq = 0.0_wp
557
558	r_a = 50.0_wp
559	r_canopy = 0.0_wp
560	r_soil = 0.0_wp
561	r_soil_min = 50.0_wp
562	r_s = 110.0_wp
563	r_s_min = min_canopy_resistance
564
565	!
566	!-- Allocate 3D soil model arrays
567	ALLOCATE ( root_fr(0:soil_layers-1,nysg:nyng,nxlg:nxrg) )
568	ALLOCATE ( lambda_h(0:soil_layers-1,nysg:nyng,nxlg:nxrg) )
569	ALLOCATE ( rhoC_total(0:soil_layers-1,nysg:nyng,nxlg:nxrg) )
570
571	lambda_h = 0.0_wp
572	!
573	!-- If required, allocate humidity-related variables for the soil model
574	IF ( humidity ) THEN
575	ALLOCATE ( lambda_w(0:soil_layers-1,nysg:nyng,nxlg:nxrg) )
576	ALLOCATE ( gamma_w(0:soil_layers-1,nysg:nyng,nxlg:nxrg) )
577
578	lambda_w = 0.0_wp
579	ENDIF
580
581	!
582	!-- Calculate grid spacings. Temperature and moisture are defined at
583	!-- the center of the soil layers, whereas gradients/fluxes are defined
584	!-- at the edges (_stag)
585	dz_soil_stag(0) = soil_level(0)
586
587	DO k = 1, soil_layers-1
588	dz_soil_stag(k) = soil_level(k) - soil_level(k-1)
589	ENDDO
590
591	DO k = 0, soil_layers-2
592	dz_soil(k) = 0.5 * (dz_soil_stag(k+1) + dz_soil_stag(k))
593	ENDDO
594	dz_soil(soil_layers-1) = dz_soil_stag(soil_layers-1)
595
596	ddz_soil = 1.0 / dz_soil
597	ddz_soil_stag = 1.0 / dz_soil_stag
598	!
599	!-- Initialize soil
600	IF ( soil_type .NE. 0 ) THEN
601	alpha_VG = soil_pars(0,soil_type)
602	l_VG = soil_pars(1,soil_type)
603	n_VG = soil_pars(2,soil_type)
604	gamma_w_sat = soil_pars(3,soil_type)
605	m_sat = m_soil_pars(0,soil_type)
606	m_fc = m_soil_pars(1,soil_type)
607	m_wilt = m_soil_pars(2,soil_type)
608	m_res = m_soil_pars(3,soil_type)
609	ELSE
610	alpha_VG = alpha_VanGenuchten
611	l_VG = l_VanGenuchten
612	n_VG = n_VanGenuchten
613	gamma_w_sat = hydraulic_conductivity
614	m_sat = saturation_moisture
615	m_fc = field_capacity
616	m_wilt = wilting_point
617	m_res = residual_moisture
618	ENDIF
619
620	!
621	!-- Map user settings of T and q for each soil layer
622	!-- (make sure that the soil moisture does not drop below the permanent
623	!-- wilting point) -> problems with devision by zero)
624	DO k = 0, soil_layers-1
625	T_soil(k,:,:) = soil_temperature(k)
626	m_soil(k,:,:) = MAX(soil_moisture(k),m_wilt(:,:))
627	ENDDO
628	T_soil(soil_layers,:,:) = soil_temperature(soil_layers)
629
630
631	exn = ( surface_pressure / 1000.0_wp )**0.286_wp
632	T_0 = pt_surface * exn
633
634	T_soil_p = T_soil
635	m_soil_p = m_soil
636
637	!
638	!-- Calculate saturation soil heat conductivity
639	lambda_h_sat(:,:) = lambda_h_sm ** (1.0_wp - m_sat(:,:)) * &
640	lambda_h_water ** m_sat(:,:)
641
642	!
643	!-- Initialize vegetation
644	IF ( veg_type .NE. 0 ) THEN
645
646	r_s_min = veg_pars(0,veg_type)
647	LAI = veg_pars(1,veg_type)
648	c_veg = veg_pars(2,veg_type)
649	gD = veg_pars(3,veg_type)
650	lambda_skin_s = skin_pars(0,veg_type)
651	lambda_skin_u = skin_pars(1,veg_type)
652	f_SW_in = skin_pars(2,veg_type)
653	z0 = roughness_par(0,veg_type)
654	z0h = roughness_par(1,veg_type)
655
656
657	DO k = 0, soil_layers-1
658	root_fr(k,:,:) = root_distribution(k,veg_type)
659	ENDDO
660
661	ELSE
662
663	DO k = 0, soil_layers-1
664	root_fr(k,:,:) = root_fraction(k)
665	ENDDO
666
667	ENDIF
668
669	!
670	!-- Possibly do user-defined actions (e.g. define heterogeneous land surface)
671	CALL user_init_land_surface
672
673	!
674	!-- Set artifical values for ts and us so that r_a has its initial value for
675	!-- the first time step
676	DO i = nxlg, nxrg
677	DO j = nysg, nyng
678	k = nzb_s_inner(j,i)
679	!
680	!-- Assure that r_a cannot be zero at model start
681	IF ( pt(k+1,j,i) == pt(k,j,i) ) pt(k+1,j,i) = pt(k+1,j,i) + 1.0E-10_wp
682
683	us(j,i) = 0.1_wp
684	ts(j,i) = (pt(k+1,j,i) - pt(k,j,i)) / r_a(j,i)
685	shf(j,i) = - us(j,i) * ts(j,i)
686	ENDDO
687	ENDDO
688
689	!
690	!-- Calculate humidity at the surface
691	IF ( humidity ) THEN
692	CALL calc_q0
693	ENDIF
694
695	RETURN
696
697	END SUBROUTINE init_lsm
698
699
700
701	!------------------------------------------------------------------------------!
702	! Description:
703	! ------------
704	!
705	!------------------------------------------------------------------------------!
706	SUBROUTINE lsm_energy_balance
707
708
709	IMPLICIT NONE
710
711	INTEGER(iwp) :: i !: running index
712	INTEGER(iwp) :: j !: running index
713	INTEGER(iwp) :: k, ks !: running index
714
715	REAL(wp) :: f1, & !: resistance correction term 1
716	f2, & !: resistance correction term 2
717	f3, & !: resistance correction term 3
718	m_min, & !: minimum soil moisture
719	T_1, & !: actual temperature at first grid point
720	e, & !: water vapour pressure
721	e_s, & !: water vapour saturation pressure
722	e_s_dT, & !: derivate of e_s with respect to T
723	tend, & !: tendency
724	dq_s_dT, & !: derivate of q_s with respect to T
725	coef_1, & !: coef. for prognostic equation
726	coef_2, & !: coef. for prognostic equation
727	f_LE, & !: factor for LE
728	f_LE_veg, & !: factor for LE_veg
729	f_LE_soil, & !: factor for LE_soil
730	f_LE_liq, & !: factor for LE_liq
731	f_H, & !: factor for H
732	lambda_skin, & !: Current value of lambda_skin
733	m_liq_max !: maxmimum value of the liquid water reservoir
734
735	!
736	!-- Calculate the exner function for the current time step
737	exn = ( surface_pressure / 1000.0_wp )**0.286_wp
738
739
740	DO i = nxlg, nxrg
741	DO j = nysg, nyng
742	k = nzb_s_inner(j,i)
743
744	!
745	!-- Set lambda_skin according to stratification
746	IF ( rif(j,i) >= 0.0_wp ) THEN
747	lambda_skin = lambda_skin_s(j,i)
748	ELSE
749	lambda_skin = lambda_skin_u(j,i)
750	ENDIF
751
752	!
753	!-- First step: calculate aerodyamic resistance. As pt, us, ts
754	!-- are not available for the prognostic time step, data from the last
755	!-- time step is used here. Note that this formulation is the
756	!-- equivalent to the ECMWF formulation using drag coefficients
757	r_a(j,i) = (pt(k+1,j,i) - pt(k,j,i)) / (ts(j,i) * us(j,i) + 1.0E-20)
758
759	!
760	!-- Second step: calculate canopy resistance r_canopy
761	!-- f1-f3 here are defined as 1/f1-f3 as in ECMWF documentation
762
763	!-- f1: correction for incoming shortwave radiation
764	f1 = MIN(1.0_wp, ( 0.004_wp * SW_in(j,i) + 0.05_wp ) / &
765	(0.81_wp * (0.004_wp * SW_in(j,i) + 1.0_wp) ) )
766
767	!
768	!-- f2: correction for soil moisture f2=0 for very dry soil
769	m_total = 0.0_wp
770	DO ks = 0, soil_layers-1
771	m_total = m_total + root_fr(ks,j,i) * m_soil(ks,j,i)
772	ENDDO
773
774	IF ( m_total .GT. m_wilt(j,i) .AND. m_total .LE. m_fc(j,i) ) THEN
775	f2 = ( m_total - m_wilt(j,i) ) / (m_fc(j,i) - m_wilt(j,i) )
776	ELSE
777	f2 = 1.0E-20_wp
778	ENDIF
779
780	!
781	!-- Calculate water vapour pressure at saturation
782	!-- (T_0 should be replaced by liquid water temp?!)
783	e_s = 0.01 * 610.78_wp * EXP( 17.269_wp * ( T_0(j,i) - 273.16_wp )&
784	/ ( T_0(j,i) - 35.86_wp ) )
785
786	!
787	!-- f3: correction for vapour pressure deficit
788	IF ( gD(j,i) .NE. 0.0_wp ) THEN
789	!
790	!-- Calculate vapour pressure
791	e = q_p(k+1,j,i) * surface_pressure / 0.622
792	f3 = EXP ( -gD(j,i) * (e_s - e) )
793	ELSE
794	f3 = 1.0_wp
795	ENDIF
796
797	!
798	!-- To do: check for very dry soil -> r_canopy goes to infinity
799	r_canopy(j,i) = r_s_min(j,i) / (LAI(j,i) * f1 * f2 * f3 + 1.0E-20)
800
801	!
802	!-- Third step: calculate bare soil resistance r_soil
803	m_min = c_veg(j,i) * m_wilt(j,i) + (1.0_wp - c_veg(j,i)) * &
804	m_res(j,i)
805
806	f2 = ( m_soil(0,j,i) - m_min ) / ( m_fc(j,i) - m_min )
807	f2 = MAX(f2,1.0E-20)
808
809	r_soil(j,i) = r_soil_min(j,i) / f2
810
811	!
812	!-- Calculate fraction of liquid water reservoir
813	m_liq_max = m_max_depth * LAI(j,i)
814	c_liq(j,i) = MIN(1.0, m_liq(j,i)/m_liq_max)
815
816	q_s = 0.622_wp * e_s / surface_pressure
817
818	!
819	!-- In case of dew fall, set resistances to zero.
820	!-- To do: what does that physically reasoning behind this?
821	IF ( humidity ) THEN
822	IF ( q_s .LE. q_p(k+1,j,i) ) THEN
823	r_canopy(j,i) = 0.0_wp
824	r_soil(j,i) = 0.0_wp
825	ENDIF
826	ENDIF
827
828
829	!
830	!-- Calculate coefficients for the total evapotranspiration
831	f_LE_veg = rho_lv * c_veg(j,i) * (1.0 - c_liq(j,i)) / (r_a(j,i) &
832	+ r_canopy(j,i))
833	f_LE_soil = rho_lv * (1.0 - c_veg(j,i)) / (r_a(j,i) + r_soil(j,i))
834	f_LE_liq = rho_lv * c_veg(j,i) * c_liq(j,i) / r_a(j,i)
835
836
837	!
838	!-- If soil moisture is below wilting point, plants do no longer
839	!-- transpirate.
840	IF ( m_soil(k,j,i) .LT. m_wilt(j,i) ) THEN
841	f_LE_veg = 0.0
842	ENDIF
843
844	f_H = rho_cp / r_a(j,i)
845	f_LE = f_LE_veg + f_LE_soil + f_LE_liq
846
847	!
848	!-- Calculate derivative of q_s for Taylor series expansion
849	e_s_dT = e_s * ( 17.269_wp / (T_0(j,i) - 35.86_wp) - &
850	17.269_wp*(T_0(j,i) - 273.16_wp) / (T_0(j,i) &
851	- 35.86_wp)**2 )
852
853	dq_s_dT = 0.622_wp * e_s_dT / surface_pressure
854
855	T_1 = pt_p(k+1,j,i) * exn
856
857	!
858	!-- Add LW up so that it can be removed in prognostic equation
859	Rn(j,i) = Rn(j,i) + sigma_SB * T_0(j,i) ** 4
860
861	IF ( humidity ) THEN
862
863	!
864	!-- Numerator of the prognostic equation
865	coef_1 = Rn(j,i) + 3.0_wp * sigma_SB * T_0(j,i) ** 4 + f_H &
866	/ exn * T_1 + f_LE * ( q_p(k+1,j,i) - q_s + dq_s_dT &
867	* T_0(j,i) ) + lambda_skin * T_soil(0,j,i)
868
869	!
870	!-- Denominator of the prognostic equation
871	coef_2 = 4.0_wp * sigma_SB * T_0(j,i) ** 3 + f_LE * dq_s_dT &
872	+ lambda_skin + f_H / exn
873
874	ELSE
875
876	!
877	!-- Numerator of the prognostic equation
878	coef_1 = Rn(j,i) + 3.0_wp * sigma_SB * T_0(j,i) ** 4 + f_H / &
879	exn * T_1 + lambda_skin * T_soil(0,j,i)
880
881	!
882	!-- Denominator of the prognostic equation
883	coef_2 = 4.0_wp * sigma_SB * T_0(j,i) ** 3 &
884	+ lambda_skin + f_H / exn
885
886	ENDIF
887
888	tend = 0.0_wp
889
890	!
891	!-- Implicit solution when the skin layer has no heat capacity,
892	!-- otherwise use RK3 scheme.
893	T_0_p(j,i) = ( coef_1 * dt_3d * tsc(2) + C_skin * T_0(j,i) ) / &
894	( C_skin + coef_2 * dt_3d * tsc(2) )
895
896	!
897	!-- Add RK3 term
898	T_0_p(j,i) = T_0_p(j,i) + dt_3d * tsc(3) * tT_soil_m(0,j,i)
899
900	!
901	!-- Calculate true tendency
902	tend = (T_0_p(j,i) - T_0(j,i) - tsc(3) * tT_0_m(j,i)) / (dt_3d &
903	* tsc(2))
904
905	!
906	!-- Calculate T_0 tendencies for the next Runge-Kutta step
907	IF ( timestep_scheme(1:5) == 'runge' ) THEN
908	IF ( intermediate_timestep_count == 1 ) THEN
909	tT_0_m(j,i) = tend
910	ELSEIF ( intermediate_timestep_count < &
911	intermediate_timestep_count_max ) THEN
912	tT_0_m(j,i) = -9.5625_wp * tend + 5.3125_wp * tT_0_m(j,i)
913	ENDIF
914	ENDIF
915
916	pt_p(k,j,i) = T_0_p(j,i) / exn
917	!
918	!-- Calculate fluxes
919	Rn(j,i) = Rn(j,i) + 3.0_wp * sigma_SB * T_0(j,i)**4 &
920	- 4.0_wp * sigma_SB * T_0(j,i)*3 T_0_p(j,i)
921	G(j,i) = lambda_skin * (T_0_p(j,i) - T_soil(0,j,i))
922	H(j,i) = - f_H * ( pt_p(k+1,j,i) - pt_p(k,j,i) )
923
924	IF ( humidity ) THEN
925	LE(j,i) = - f_LE * ( q_p(k+1,j,i) - q_s + dq_s_dT &
926	* T_0(j,i) - dq_s_dT * T_0_p(j,i) )
927
928	LE_veg(j,i) = - f_LE_veg * ( q_p(k+1,j,i) - q_s + dq_s_dT &
929	* T_0(j,i) - dq_s_dT * T_0_p(j,i) )
930	LE_soil(j,i) = - f_LE_soil * ( q_p(k+1,j,i) - q_s + dq_s_dT &
931	* T_0(j,i) - dq_s_dT * T_0_p(j,i) )
932	LE_liq(j,i) = - f_LE_liq * ( q_p(k+1,j,i) - q_s + dq_s_dT &
933	* T_0(j,i) - dq_s_dT * T_0_p(j,i) )
934	ENDIF
935
936	! IF ( i == 1 .AND. j == 1 ) THEN
937	! PRINT*, "Rn", Rn(j,i)
938	! PRINT*, "H", H(j,i)
939	! PRINT*, "LE", LE(j,i)
940	! PRINT*, "LE_liq", LE_liq(j,i)
941	! PRINT*, "LE_veg", LE_veg(j,i)
942	! PRINT*, "LE_soil", LE_soil(j,i)
943	! PRINT*, "G", G(j,i)
944	! ENDIF
945
946	!
947	!-- Calculate the true surface resistance
948	IF ( LE(j,i) .EQ. 0.0 ) THEN
949	r_s(j,i) = 1.0E10
950	ELSE
951	r_s(j,i) = - rho_lv * ( q_p(k+1,j,i) - q_s + dq_s_dT * T_0(j,i)&
952	- dq_s_dT * T_0_p(j,i) ) / LE(j,i) - r_a(j,i)
953	ENDIF
954
955	!
956	!-- Calculate fluxes in the atmosphere
957	shf(j,i) = H(j,i) / rho_cp
958
959	!
960	!-- Calculate change in liquid water reservoir due to dew fall or
961	!-- evaporation of liquid water
962	IF ( humidity ) THEN
963	!
964	!-- If precipitation is activated, add rain water to LE_liq.
965	!-- precipitation_rate is given in mm.
966	IF ( precipitation ) THEN
967	LE_liq(j,i) = LE_liq(j,i) + precipitation_rate(j,i) &
968	* 0.001_wp * rho_l * l_v
969	ENDIF
970	!
971	!-- If the air is saturated, check the reservoir water level
972	IF ( q_s .LE. q_p(k+1,j,i)) THEN
973	!
974	!-- Check if reservoir is full (avoid values > m_liq_max)
975	!-- In that case, LE_liq goes to LE_soil. In this case
976	!-- LE_veg is zero anyway (because c_liq = 1), so that tend is
977	!-- zero and no further check is needed
978	IF ( m_liq(j,i) .EQ. m_liq_max ) THEN
979	LE_soil(j,i) = LE_soil(j,i) + LE_liq(j,i)
980	LE_liq(j,i) = 0.0_wp
981	ENDIF
982
983	!
984	!-- In case LE_veg becomes negative (unphysical behavior), let
985	!-- the water enter the liquid water reservoir as dew on the
986	!-- plant
987	IF ( LE_veg(j,i) .LT. 0.0_wp ) THEN
988	LE_liq(j,i) = LE_liq(j,i) + LE_veg(j,i)
989	LE_veg(j,i) = 0.0_wp
990	ENDIF
991	ENDIF
992
993	tend = - LE_liq(j,i) * drho_l_lv
994
995	m_liq_p(j,i) = m_liq(j,i) + dt_3d * ( tsc(2) * tend &
996	+ tsc(3) * tm_liq_m(j,i) )
997
998	!
999	!-- Check if reservoir is overfull -> reduce to maximum
1000	!-- (conservation of water is violated here)
1001	m_liq_p(j,i) = MIN(m_liq_p(j,i),m_liq_max)
1002
1003	!
1004	!-- Check if reservoir is empty (avoid values < 0.0)
1005	!-- (conservation of water is violated here)
1006	m_liq_p(j,i) = MAX(m_liq_p(j,i),0.0_wp)
1007
1008
1009	!
1010	!-- Calculate m_liq tendencies for the next Runge-Kutta step
1011	IF ( timestep_scheme(1:5) == 'runge' ) THEN
1012	IF ( intermediate_timestep_count == 1 ) THEN
1013	tm_liq_m(j,i) = tend
1014	ELSEIF ( intermediate_timestep_count < &
1015	intermediate_timestep_count_max ) THEN
1016	tm_liq_m(j,i) = -9.5625_wp * tend + 5.3125_wp &
1017	* tm_liq_m(j,i)
1018	ENDIF
1019	ENDIF
1020
1021	!
1022	!-- Calculate moisture flux in the atmosphere
1023	qsws(j,i) = LE(j,i) / rho_lv
1024
1025	ENDIF
1026
1027	ENDDO
1028	ENDDO
1029
1030
1031
1032	END SUBROUTINE lsm_energy_balance
1033
1034
1035	!------------------------------------------------------------------------------!
1036	! Description:
1037	! ------------
1038	!
1039	!------------------------------------------------------------------------------!
1040	SUBROUTINE lsm_soil_model
1041
1042
1043	IMPLICIT NONE
1044
1045	INTEGER(iwp) :: i !: running index
1046	INTEGER(iwp) :: j !: running index
1047	INTEGER(iwp) :: k !: running index
1048
1049	REAL(wp) :: h_VG !: Van Genuchten coef. h
1050
1051	REAL(wp), DIMENSION(0:soil_layers-1) :: gamma_temp, & !: temp. gamma
1052	lambda_temp, & !: temp. lambda
1053	tend !: tendency
1054
1055	DO i = nxlg, nxrg
1056	DO j = nysg, nyng
1057	DO k = 0, soil_layers-1
1058	!
1059	!-- Calculate volumetric heat capacity of the soil, taking into
1060	!-- account water content
1061	rhoC_total(k,j,i) = (rhoC_soil * (1.0 - m_sat(j,i)) &
1062	+ rhoC_water * m_soil(k,j,i))
1063
1064	!
1065	!-- Calculate soil heat conductivity at the center of the soil
1066	!-- layers
1067	Ke = 1.0 + LOG10(MAX(0.1,m_soil(k,j,i) / m_sat(j,i)))
1068	lambda_temp(k) = Ke * (lambda_h_sat(j,i) + lambda_h_dry) + &
1069	lambda_h_dry
1070
1071	ENDDO
1072
1073	!
1074	!-- Calculate soil heat conductivity (lambda_h) at the _stag level
1075	!-- using linear interpolation
1076	DO k = 0, soil_layers-2
1077
1078	lambda_h(k,j,i) = lambda_temp(k) + &
1079	( lambda_temp(k+1) - lambda_temp(k) ) &
1080	* 0.5 * dz_soil_stag(k) * ddz_soil(k+1)
1081
1082	ENDDO
1083	lambda_h(soil_layers-1,j,i) = lambda_temp(soil_layers-1)
1084
1085	!
1086	!-- Prognostic equation for soil temperature T_soil
1087	tend(:) = 0.0_wp
1088	tend(0) = (1.0/rhoC_total(0,j,i)) * &
1089	( lambda_h(0,j,i) * ( T_soil(1,j,i) - T_soil(0,j,i) ) &
1090	* ddz_soil(0) + G(j,i) ) * ddz_soil_stag(0)
1091
1092	DO k = 1, soil_layers-1
1093	tend(k) = (1.0/rhoC_total(k,j,i)) &
1094	* ( lambda_h(k,j,i) &
1095	* ( T_soil(k+1,j,i) - T_soil(k,j,i) ) &
1096	* ddz_soil(k) &
1097	- lambda_h(k-1,j,i) &
1098	* ( T_soil(k,j,i) - T_soil(k-1,j,i) ) &
1099	* ddz_soil(k-1) &
1100	) * ddz_soil_stag(k)
1101	ENDDO
1102
1103	T_soil_p(0:soil_layers-1,j,i) = T_soil(0:soil_layers-1,j,i) &
1104	+ dt_3d * ( tsc(2) &
1105	* tend(:) + tsc(3) &
1106	* tT_soil_m(:,j,i) )
1107
1108	!
1109	!-- Calculate T_soil tendencies for the next Runge-Kutta step
1110	IF ( timestep_scheme(1:5) == 'runge' ) THEN
1111	IF ( intermediate_timestep_count == 1 ) THEN
1112	DO k = 0, soil_layers-1
1113	tT_soil_m(k,j,i) = tend(k)
1114	ENDDO
1115	ELSEIF ( intermediate_timestep_count < &
1116	intermediate_timestep_count_max ) THEN
1117	DO k = 0, soil_layers-1
1118	tT_soil_m(k,j,i) = -9.5625_wp * tend(k) + 5.3125_wp &
1119	* tT_soil_m(k,j,i)
1120	ENDDO
1121	ENDIF
1122	ENDIF
1123
1124
1125	DO k = 0, soil_layers-1
1126	!
1127	!-- Calculate soil diffusivity at the center of the soil layers
1128	lambda_temp(k) = (- b_CH * gamma_w_sat(j,i) * psi_sat &
1129	/ m_sat(j,i) ) * ( MAX(m_soil(k,j,i), &
1130	m_wilt(j,i)) / m_sat(j,i) )**(b_CH + 2.0_wp)
1131
1132	!
1133	!-- Calculate the hydraulic conductivity after Van Genuchten (1980)
1134	h_VG = ( ( (m_res(j,i) - m_sat(j,i)) / ( m_res(j,i) - &
1135	MAX(m_soil(k,j,i),m_wilt(j,i)) ) )**(n_VG(j,i) &
1136	/ (n_VG(j,i)-1.0_wp)) - 1.0_wp &
1137	)**(1.0_wp/n_VG(j,i)) / alpha_VG(j,i)
1138
1139	gamma_temp(k) = gamma_w_sat(j,i) * ( ( (1.0_wp + &
1140	(alpha_VG(j,i)h_VG)n_VG(j,i))*(1.0_wp &
1141	-1.0_wp/n_VG(j,i)) - (alpha_VG(j,i)*h_VG &
1142	)(n_VG(j,i)-1.0_wp))2 ) &
1143	/ ( (1.0_wp + (alpha_VG(j,i)h_VG)*n_VG(j,i) &
1144	)*((1.0_wp - 1.0_wp/n_VG(j,i))(l_VG(j,i) &
1145	+ 2.0)) )
1146
1147	ENDDO
1148
1149
1150	IF ( humidity ) THEN
1151	!
1152	!-- Calculate soil diffusivity (lambda_w) at the _stag level
1153	!-- using linear interpolation
1154	DO k = 0, soil_layers-2
1155
1156	lambda_w(k,j,i) = lambda_temp(k) + &
1157	( lambda_temp(k+1) - lambda_temp(k) ) &
1158	* 0.5 * dz_soil_stag(k) * ddz_soil(k+1)
1159	gamma_w(k,j,i) = gamma_temp(k) + &
1160	( gamma_temp(k+1) - gamma_temp(k) ) &
1161	* 0.5 * dz_soil_stag(k) * ddz_soil(k+1)
1162
1163	ENDDO
1164
1165	!
1166	!
1167	!-- In case of a closed bottom (= water content is conserved), set
1168	!-- hydraulic conductivity to zero to that no water will be lost
1169	!-- in the bottom layer.
1170	IF ( conserve_water_content ) THEN
1171	gamma_w(soil_layers-1,j,i) = 0.0_wp
1172	ELSE
1173	gamma_w(soil_layers-1,j,i) = lambda_temp(soil_layers-1)
1174	ENDIF
1175
1176	!-- The root extraction (= root_extr * LE_veg / (rho_l * l_v))
1177	!-- ensures the mass conservation for water. The transpiration of
1178	!-- plants equals the cumulative withdrawals by the roots in the
1179	!-- soil. The scheme takes into account the availability of water
1180	!-- in the soil layers as well as the root fraction in the
1181	!-- respective layer
1182
1183	!
1184	!-- Calculate the root extraction (ECMWF 7.69, with some
1185	!-- modifications)
1186	m_total = 0.0_wp
1187	DO k = 0, soil_layers-1
1188	m_total = m_total + root_fr(k,j,i) * m_soil(k,j,i) * &
1189	dz_soil_stag(k)
1190
1191	ENDDO
1192
1193	!
1194	!-- For conservation of mass, the sum of root_extr must be 1
1195	DO k = 0, soil_layers-1
1196	root_extr(k) = root_fr(k,j,i) * m_soil(k,j,i) &
1197	* dz_soil_stag(k) / m_total
1198	ENDDO
1199
1200
1201	!
1202	!-- Prognostic equation for soil water content m_soil
1203	tend(:) = 0.0_wp
1204	tend(0) = ( lambda_w(0,j,i) * ( m_soil(1,j,i) - m_soil(0,j,i) )&
1205	* ddz_soil(0) - gamma_w(0,j,i) - ( root_extr(0) &
1206	* LE_veg(j,i) + LE_soil(j,i) ) * drho_l_lv &
1207	) * ddz_soil_stag(0)
1208
1209	DO k = 1, soil_layers-2
1210	tend(k) = ( lambda_w(k,j,i) * ( m_soil(k+1,j,i) &
1211	- m_soil(k,j,i) ) * ddz_soil(k) - gamma_w(k,j,i)&
1212	- lambda_w(k-1,j,i) * (m_soil(k,j,i) - &
1213	m_soil(k-1,j,i)) * ddz_soil(k-1) &
1214	+ gamma_w(k-1,j,i) - (root_extr(k) * LE_veg(j,i)&
1215	* drho_l_lv) &
1216	) * ddz_soil_stag(k)
1217
1218	ENDDO
1219	tend(soil_layers-1) = ( - gamma_w(soil_layers-1,j,i) &
1220	- lambda_w(soil_layers-2,j,i) &
1221	* (m_soil(soil_layers-1,j,i) &
1222	- m_soil(soil_layers-2,j,i)) &
1223	* ddz_soil(soil_layers-2) &
1224	+ gamma_w(soil_layers-2,j,i) - ( &
1225	root_extr(soil_layers-1) &
1226	* LE_veg(j,i) * drho_l_lv ) &
1227	) * ddz_soil_stag(soil_layers-1)
1228
1229	m_soil_p(0:soil_layers-1,j,i) = m_soil(0:soil_layers-1,j,i) &
1230	+ dt_3d * ( tsc(2) * tend(:) &
1231	+ tsc(3) * tm_soil_m(:,j,i) )
1232
1233	!
1234	!-- Account for dry soils (find a better solution here!)
1235	m_soil_p(:,j,i) = MAX(m_soil_p(:,j,i),0.0_wp)
1236
1237	!
1238	!-- Calculate m_soil tendencies for the next Runge-Kutta step
1239	IF ( timestep_scheme(1:5) == 'runge' ) THEN
1240	IF ( intermediate_timestep_count == 1 ) THEN
1241	DO k = 0, soil_layers-1
1242	tm_soil_m(k,j,i) = tend(k)
1243	ENDDO
1244	ELSEIF ( intermediate_timestep_count < &
1245	intermediate_timestep_count_max ) THEN
1246	DO k = 0, soil_layers-1
1247	tm_soil_m(k,j,i) = -9.5625_wp * tend(k) + 5.3125_wp &
1248	* tm_soil_m(k,j,i)
1249	ENDDO
1250	ENDIF
1251	ENDIF
1252
1253	ENDIF
1254
1255	ENDDO
1256	ENDDO
1257
1258	!
1259	!-- Calculate surface specific humidity
1260	IF ( humidity ) THEN
1261	CALL calc_q0
1262	ENDIF
1263
1264
1265	END SUBROUTINE lsm_soil_model
1266
1267
1268	!------------------------------------------------------------------------------!
1269	! Description:
1270	! ------------
1271	!
1272	!------------------------------------------------------------------------------!
1273	SUBROUTINE calc_q0
1274
1275	IMPLICIT NONE
1276
1277	INTEGER :: i !: running index
1278	INTEGER :: j !: running index
1279	INTEGER :: k !: running index
1280	REAL(wp) :: resistance !: aerodynamic and soil resistance term
1281
1282	DO i = nxlg, nxrg
1283	DO j = nysg, nyng
1284	k = nzb_s_inner(j,i)
1285	!
1286	!-- Temporary solution as long as T_0 is prescribed
1287
1288	pt_p(k,j,i) = T_0(j,i) / exn
1289	!
1290	!-- Calculate water vapour pressure at saturation
1291	e_s = 0.01_wp * 610.78_wp * EXP( 17.269_wp * ( T_0(j,i) - &
1292	273.16_wp ) / ( T_0(j,i) - &
1293	35.86_wp ) )
1294
1295	!
1296	!-- Calculate specific humidity at saturation
1297	q_s = 0.622_wp * e_s / surface_pressure
1298
1299
1300	resistance = r_a(j,i) / (r_a(j,i) + r_s(j,i))
1301
1302	!
1303	!-- Calculate specific humidity at surface
1304	q_p(k,j,i) = resistance * q_s + (1.0_wp - resistance) &
1305	* q_p(k+1,j,i)
1306
1307	ENDDO
1308	ENDDO
1309
1310	END SUBROUTINE calc_q0
1311
1312
1313	END MODULE land_surface_model_mod

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

| Impressum | ©Leibniz Universität Hannover |