source: palm/trunk/SOURCE/init_pt_anomaly.f90 @ 6

 SUBROUTINE init_pt_anomaly

!------------------------------------------------------------------------------!
! Actual revisions:
! -----------------
! 
!
! Former revisions:
! -----------------
! $Id: init_pt_anomaly.f90 4 2007-02-13 11:33:16Z raasch $
! RCS Log replace by Id keyword, revision history cleaned up
!
! Revision 1.7  2005/03/26 20:36:55  raasch
! Arguments for non-cyclic boundary conditions added to argument list of
! routine exchange_horiz
!
! Revision 1.1  1997/08/29 08:58:56  raasch
! Initial revision
!
!
! Description:
! ------------
! Impose a temperature perturbation for an advection test.
!------------------------------------------------------------------------------!

    USE arrays_3d
    USE constants
    USE grid_variables
    USE indices
    USE control_parameters

    IMPLICIT NONE

    INTEGER ::  i, ic, j, jc, k, kc
    REAL    ::  betrag, radius, rc, x, y, z

!
!-- Defaults: radius rc, strength z,
!--           position of centre: ic, jc, kc
    rc =  10.0 * dx
    ic =  ( nx+1 ) / 2
    jc =  ic
    kc = nzt / 2

!
!-- Compute the perturbation.
    DO  i = nxl, nxr
       DO  j = nys, nyn
          DO  k = nzb+1, nzt-1
             x = ( i - ic ) * dx
             y = ( j - jc ) * dy
             z = ABS( zu(k) - zu(kc) )
             radius = SQRT( x**2 + y**2 + z**2 )
             IF ( radius <= rc )  THEN
                betrag = 5.0 * EXP( -( radius / 2.0 )**2 )
             ELSE
                betrag = 0.0
             ENDIF

             pt(k,j,i) = pt(k,j,i) + betrag

          ENDDO
       ENDDO
    ENDDO

!
!-- Exchange of boundary values for temperature
    CALL exchange_horiz( pt, 0, 0 )


 END SUBROUTINE init_pt_anomaly