source: palm/trunk/SOURCE/init_pegrid.f90 @ 3045

Last change on this file since 3045 was 3045, checked in by Giersch, 3 years ago

Code adjusted according to coding standards, renamed namelists, error messages revised until PA0347, output CASE 108 disabled

  • Property svn:keywords set to Id
File size: 51.3 KB
Line 
1!> @file init_pegrid.f90
2!------------------------------------------------------------------------------!
3! This file is part of the PALM model system.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2018 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! ------------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: init_pegrid.f90 3045 2018-05-28 07:55:41Z Giersch $
27! Error messages revised
28!
29! 2938 2018-03-27 15:52:42Z suehring
30! - No checks for domain decomposition in case of turbulence generator
31!  (is done in stg module)
32! - Introduce ids to indicate lateral processors for turbulence generator
33!
34! 2936 2018-03-27 14:49:27Z suehring
35! Variable use_synthetic_turbulence_generator has been abbreviated
36!
37! 2718 2018-01-02 08:49:38Z maronga
38! Corrected "Former revisions" section
39!
40! 2696 2017-12-14 17:12:51Z kanani
41! Change in file header (GPL part)
42! 3D-Integer exchange on multigrid level (MS)
43! Forcing implemented (MS)
44!
45! 2600 2017-11-01 14:11:20Z raasch
46! calculation of block-I/O quantitites removed (is now done in parin)
47!
48! 2516 2017-10-04 11:03:04Z suehring
49! Remove tabs
50!
51! 2514 2017-10-04 09:52:37Z suehring
52! Redundant preprocessor directives removed
53!
54! 2372 2017-08-25 12:37:32Z sward
55! Shifted cyclic boundary conditions implemented
56!
57! 2365 2017-08-21 14:59:59Z kanani
58! Vertical nesting implemented (SadiqHuq)
59!
60! 2300 2017-06-29 13:31:14Z raasch
61! host-specific settings removed
62!
63! 2298 2017-06-29 09:28:18Z raasch
64! MPI2 related parts removed
65!
66! 2271 2017-06-09 12:34:55Z sward
67! Error message changed
68!
69! 2259 2017-06-08 09:09:11Z gronemeier
70! Implemented synthetic turbulence generator
71!
72! 2238 2017-05-31 16:49:16Z suehring
73! Remove unnecessary module load of pmc_interface
74!
75! 2231 2017-05-30 16:44:33Z suehring
76!
77! 2200 2017-04-11 11:37:51Z suehring
78! monotonic_adjustment removed
79!
80! 2197 2017-03-24 02:25:00Z raasch
81! bugfix: do not allow odd values for nz at the coarsest grid level in case of
82! optimized multigrid solver
83!
84! 2180 2017-03-17 13:33:05Z hellstea
85! Checks to ensure (2178) that pdims match the grid dimensions in the
86! automatic determination of pdims are canceled as unnecessary
87!
88! 2178 2017-03-17 11:07:39Z hellstea
89! Checks to ensure that pdims match the grid dimensions are added in the
90! automatic determination of pdims
91!
92! 2050 2016-11-08 15:00:55Z gronemeier
93! Implement turbulent outflow condition
94!
95! 2000 2016-08-20 18:09:15Z knoop
96! Forced header and separation lines into 80 columns
97!
98! 1968 2016-07-18 12:01:49Z suehring
99! Extent MPI-datatypes for exchange of 2D-INTEGER arrays on coarser multigrid
100! level 
101!
102! 1964 2016-07-14 15:35:18Z hellstea
103! Bugfix: erroneous setting of nest_bound_l/r/s/n = .TRUE. for vertical nesting mode removed.
104!
105! 1923 2016-05-31 16:37:07Z boeske
106! Initial version of purely vertical nesting introduced.
107!
108! 1922 2016-05-31 16:36:08Z boeske
109! Bugfix: array transposition checks restricted to cases if a fourier
110! transform is used , removed unused variable nnx_z
111!
112! 1833 2016-04-07 14:23:03Z raasch
113! spectra related variables moved to spectra_mod
114!
115! 1815 2016-04-06 13:49:59Z raasch
116! cpp-directives for intel openmp bug removed
117!
118! 1804 2016-04-05 16:30:18Z maronga
119! Removed code for parameter file check (__check)
120!
121! 1779 2016-03-03 08:01:28Z raasch
122! changes regarding nested domain removed: virtual PE grid will be automatically
123! calculated for nested runs too
124!
125! 1764 2016-02-28 12:45:19Z raasch
126! cpp-statements for nesting removed
127!
128! 1762 2016-02-25 12:31:13Z hellstea
129! Introduction of nested domain feature
130!
131! 1682 2015-10-07 23:56:08Z knoop
132! Code annotations made doxygen readable
133!
134! 1677 2015-10-02 13:25:23Z boeske
135! New MPI-data types for exchange of 3D integer arrays.
136!
137! 1575 2015-03-27 09:56:27Z raasch
138! adjustments for psolver-queries, calculation of ngp_xz added
139!
140! 1565 2015-03-09 20:59:31Z suehring
141! Refine if-clause for setting nbgp.
142!
143! 1557 2015-03-05 16:43:04Z suehring
144! Adjustment for monotonic limiter
145!
146! 1468 2014-09-24 14:06:57Z maronga
147! Adapted for use on up to 6-digit processor cores
148!
149! 1435 2014-07-21 10:37:02Z keck
150! bugfix: added missing parameter coupling_mode_remote to ONLY-attribute
151!
152! 1402 2014-05-09 14:25:13Z raasch
153! location messages modified
154!
155! 1384 2014-05-02 14:31:06Z raasch
156! location messages added
157!
158! 1353 2014-04-08 15:21:23Z heinze
159! REAL constants provided with KIND-attribute
160!
161! 1322 2014-03-20 16:38:49Z raasch
162! REAL functions provided with KIND-attribute
163!
164! 1320 2014-03-20 08:40:49Z raasch
165! ONLY-attribute added to USE-statements,
166! kind-parameters added to all INTEGER and REAL declaration statements,
167! kinds are defined in new module kinds,
168! revision history before 2012 removed,
169! comment fields (!:) to be used for variable explanations added to
170! all variable declaration statements
171!
172! 1304 2014-03-12 10:29:42Z raasch
173! bugfix: single core MPI runs missed some settings of transpose indices
174!
175! 1212 2013-08-15 08:46:27Z raasch
176! error message for poisfft_hybrid removed
177!
178! 1159 2013-05-21 11:58:22Z fricke
179! dirichlet/neumann and neumann/dirichlet removed
180!
181! 1139 2013-04-18 07:25:03Z raasch
182! bugfix for calculating the id of the PE carrying the recycling plane
183!
184! 1111 2013-03-08 23:54:10Z raasch
185! initialization of poisfft moved to module poisfft
186!
187! 1092 2013-02-02 11:24:22Z raasch
188! unused variables removed
189!
190! 1056 2012-11-16 15:28:04Z raasch
191! Indices for arrays n.._mg start from zero due to definition of arrays f2 and
192! p2 as automatic arrays in recursive subroutine next_mg_level
193!
194! 1041 2012-11-06 02:36:29Z raasch
195! a 2d virtual processor topology is used by default for all machines
196!
197! 1036 2012-10-22 13:43:42Z raasch
198! code put under GPL (PALM 3.9)
199!
200! 1003 2012-09-14 14:35:53Z raasch
201! subdomains must have identical size (grid matching = "match" removed)
202!
203! 1001 2012-09-13 14:08:46Z raasch
204! all actions concerning upstream-spline-method removed
205!
206! 978 2012-08-09 08:28:32Z fricke
207! dirichlet/neumann and neumann/dirichlet added
208! nxlu and nysv are also calculated for inflow boundary
209!
210! 809 2012-01-30 13:32:58Z maronga
211! Bugfix: replaced .AND. and .NOT. with && and ! in the preprocessor directives
212!
213! 807 2012-01-25 11:53:51Z maronga
214! New cpp directive "__check" implemented which is used by check_namelist_files
215!
216! Revision 1.1  1997/07/24 11:15:09  raasch
217! Initial revision
218!
219!
220! Description:
221! ------------
222!> Determination of the virtual processor topology (if not prescribed by the
223!> user)and computation of the grid point number and array bounds of the local
224!> domains.
225!> @todo: remove MPI-data types for 2D exchange on coarse multigrid level (not
226!>        used any more)
227!------------------------------------------------------------------------------!
228 SUBROUTINE init_pegrid
229 
230
231    USE control_parameters,                                                    &
232        ONLY:  bc_lr, bc_ns, coupling_mode, coupling_mode_remote,              &
233               coupling_topology, force_bound_l, force_bound_n, force_bound_r, &
234               force_bound_s, gathered_size, grid_level,                       &
235               grid_level_count, inflow_l, inflow_n, inflow_r, inflow_s,       &
236               maximum_grid_level, message_string,                             &
237               mg_switch_to_pe0_level, momentum_advec, nest_bound_l,           &
238               nest_bound_n, nest_bound_r, nest_bound_s, nest_domain, neutral, &
239               psolver, outflow_l, outflow_n, outflow_r, outflow_s,            &
240               outflow_source_plane, recycling_width, scalar_advec,            &
241               subdomain_size, turbulent_outflow, y_shift
242
243    USE grid_variables,                                                        &
244        ONLY:  dx
245       
246    USE indices,                                                               &
247        ONLY:  mg_loc_ind, nbgp, nnx, nny, nnz, nx, nx_a, nx_o, nxl, nxl_mg,   &
248               nxlu, nxr, nxr_mg, ny, ny_a, ny_o, nyn, nyn_mg, nys, nys_mg,    &
249               nysv, nz, nzb, nzt, nzt_mg, wall_flags_1, wall_flags_2,         &
250               wall_flags_3, wall_flags_4, wall_flags_5, wall_flags_6,         &
251               wall_flags_7, wall_flags_8, wall_flags_9, wall_flags_10
252
253    USE kinds
254     
255    USE pegrid
256     
257    USE spectra_mod,                                                           &
258        ONLY:  calculate_spectra, dt_dosp
259
260    USE synthetic_turbulence_generator_mod,                                    &
261        ONLY:  id_stg_left, id_stg_north, id_stg_right, id_stg_south,          &
262               use_syn_turb_gen
263
264    USE transpose_indices,                                                     &
265        ONLY:  nxl_y, nxl_yd, nxl_z, nxr_y, nxr_yd, nxr_z, nyn_x, nyn_z, nys_x,&
266               nys_z, nzb_x, nzb_y, nzb_yd, nzt_x, nzt_yd, nzt_y
267
268    USE vertical_nesting_mod,                                                  &
269        ONLY:  vnested, vnest_init_pegrid_domain, vnest_init_pegrid_rank
270
271    IMPLICIT NONE
272
273    INTEGER(iwp) ::  i                        !<
274    INTEGER(iwp) ::  id_inflow_l              !<
275    INTEGER(iwp) ::  id_outflow_l             !< local value of id_outflow
276    INTEGER(iwp) ::  id_outflow_source_l      !< local value of id_outflow_source
277    INTEGER(iwp) ::  id_recycling_l           !<
278    INTEGER(iwp) ::  id_stg_left_l            !< left lateral boundary local core id in case of turbulence generator 
279    INTEGER(iwp) ::  id_stg_north_l           !< north lateral boundary local core id in case of turbulence generator 
280    INTEGER(iwp) ::  id_stg_right_l           !< right lateral boundary local core id in case of turbulence generator 
281    INTEGER(iwp) ::  id_stg_south_l           !< south lateral boundary local core id in case of turbulence generator 
282    INTEGER(iwp) ::  ind(5)                   !<
283    INTEGER(iwp) ::  j                        !<
284    INTEGER(iwp) ::  k                        !<
285    INTEGER(iwp) ::  maximum_grid_level_l     !<
286    INTEGER(iwp) ::  mg_levels_x              !<
287    INTEGER(iwp) ::  mg_levels_y              !<
288    INTEGER(iwp) ::  mg_levels_z              !<
289    INTEGER(iwp) ::  mg_switch_to_pe0_level_l !<
290    INTEGER(iwp) ::  nnx_y                    !<
291    INTEGER(iwp) ::  nnx_z                    !<
292    INTEGER(iwp) ::  nny_x                    !<
293    INTEGER(iwp) ::  nny_z                    !<
294    INTEGER(iwp) ::  nnz_x                    !<
295    INTEGER(iwp) ::  nnz_y                    !<
296    INTEGER(iwp) ::  numproc_sqr              !<
297    INTEGER(iwp) ::  nxl_l                    !<
298    INTEGER(iwp) ::  nxr_l                    !<
299    INTEGER(iwp) ::  nyn_l                    !<
300    INTEGER(iwp) ::  nys_l                    !<
301    INTEGER(iwp) ::  nzb_l                    !<
302    INTEGER(iwp) ::  nzt_l                    !<
303    INTEGER(iwp) ::  omp_get_num_threads      !<
304
305    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  ind_all !<
306    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nxlf    !<
307    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nxrf    !<
308    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nynf    !<
309    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nysf    !<
310
311    INTEGER(iwp), DIMENSION(2) ::  pdims_remote         !<
312    INTEGER(iwp)               ::  lcoord(2)            !< PE coordinates of left neighbor along x and y
313    INTEGER(iwp)               ::  rcoord(2)            !< PE coordinates of right neighbor along x and y
314
315!
316!-- Get the number of OpenMP threads
317    !$OMP PARALLEL
318!$  threads_per_task = omp_get_num_threads()
319    !$OMP END PARALLEL
320
321
322#if defined( __parallel )
323
324    CALL location_message( 'creating virtual PE grids + MPI derived data types', &
325                           .FALSE. )
326
327!
328!-- Determine the processor topology or check it, if prescribed by the user
329    IF ( npex == -1  .AND.  npey == -1 )  THEN
330
331!
332!--    Automatic determination of the topology
333       numproc_sqr = SQRT( REAL( numprocs, KIND=wp ) )
334       pdims(1)    = MAX( numproc_sqr , 1 )
335       DO  WHILE ( MOD( numprocs , pdims(1) ) /= 0 )
336          pdims(1) = pdims(1) - 1
337       ENDDO
338       pdims(2) = numprocs / pdims(1)
339
340    ELSEIF ( npex /= -1  .AND.  npey /= -1 )  THEN
341
342!
343!--    Prescribed by user. Number of processors on the prescribed topology
344!--    must be equal to the number of PEs available to the job
345       IF ( ( npex * npey ) /= numprocs )  THEN
346          WRITE( message_string, * ) 'number of PEs of the prescribed ',       &
347              'topology (', npex*npey,') does not match the number of ',       &
348              'PEs available to the job (', numprocs, ')'
349          CALL message( 'init_pegrid', 'PA0221', 1, 2, 0, 6, 0 )
350       ENDIF
351       pdims(1) = npex
352       pdims(2) = npey
353
354    ELSE
355!
356!--    If the processor topology is prescribed by the user, the number of
357!--    PEs must be given in both directions
358       message_string = 'if the processor topology is prescribed by th' //     &
359                'e user both values of "npex" and "npey" must be given' //     &
360                ' in the &NAMELIST-parameter file'
361       CALL message( 'init_pegrid', 'PA0222', 1, 2, 0, 6, 0 )
362
363    ENDIF
364
365!
366!-- If necessary, set horizontal boundary conditions to non-cyclic
367    IF ( bc_lr /= 'cyclic' )  cyclic(1) = .FALSE.
368    IF ( bc_ns /= 'cyclic' )  cyclic(2) = .FALSE.
369
370
371!
372!-- Create the virtual processor grid
373    CALL MPI_CART_CREATE( comm_palm, ndim, pdims, cyclic, reorder, &
374                          comm2d, ierr )
375    CALL MPI_COMM_RANK( comm2d, myid, ierr )
376    WRITE (myid_char,'(''_'',I6.6)')  myid
377
378    CALL MPI_CART_COORDS( comm2d, myid, ndim, pcoord, ierr )
379    CALL MPI_CART_SHIFT( comm2d, 0, 1, pleft, pright, ierr )
380    CALL MPI_CART_SHIFT( comm2d, 1, 1, psouth, pnorth, ierr )
381!
382!-- In case of cyclic boundary conditions, a y-shift at the boundaries in
383!-- x-direction can be introduced via parameter y_shift. The shift is done
384!-- by modifying the processor grid in such a way that processors located
385!-- at the x-boundary communicate across it to processors with y-coordinate
386!-- shifted by y_shift relative to their own. This feature can not be used
387!-- in combination with an fft pressure solver. It has been implemented to
388!-- counter the effect of streak structures in case of cyclic boundary
389!-- conditions. For a description of these see Munters
390!-- (2016; dx.doi.org/10.1063/1.4941912)
391!--
392!-- Get coordinates of left and right neighbor on PE grid
393    IF ( y_shift /= 0 ) THEN
394
395       IF ( bc_lr /= 'cyclic'  .OR.  bc_ns /= 'cyclic' )  THEN
396          message_string = 'y_shift /= 0 is only allowed for cyclic ' //       &
397                           'boundary conditions in both directions '
398          CALL message( 'check_parameters', 'PA0467', 1, 2, 0, 6, 0 )
399       ENDIF
400       IF ( TRIM( psolver ) /= 'multigrid' .AND.                               &
401            TRIM( psolver ) /= 'multigrid_noopt')                              &
402       THEN
403          message_string = 'y_shift /= 0 requires a multigrid pressure solver '
404          CALL message( 'check_parameters', 'PA0468', 1, 2, 0, 6, 0 )
405       ENDIF
406
407       CALL MPI_CART_COORDS( comm2d, pright, ndim, rcoord, ierr )
408       CALL MPI_CART_COORDS( comm2d, pleft, ndim, lcoord, ierr )
409
410!
411!--    If the x(y)-coordinate of the right (left) neighbor is smaller (greater)
412!--    than that of the calling process, then the calling process is located on
413!--    the right (left) boundary of the processor grid. In that case,
414!--    the y-coordinate of that neighbor is increased (decreased) by y_shift.
415!--    The rank of the process with that coordinate is then inquired and the
416!--    neighbor rank for MPI_SENDRECV, pright (pleft) is set to it.
417!--    In this way, the calling process receives a new right (left) neighbor
418!--    for all future MPI_SENDRECV calls. That neighbor has a y-coordinate
419!--    of y+(-)y_shift, where y is the original right (left) neighbor's
420!--    y-coordinate. The modulo-operation ensures that if the neighbor's
421!--    y-coordinate exceeds the grid-boundary, it will be relocated to
422!--    the opposite part of the grid cyclicly.
423       IF ( rcoord(1) < pcoord(1) ) THEN
424          rcoord(2) = MODULO( rcoord(2) + y_shift, pdims(2) )
425          CALL MPI_CART_RANK( comm2d, rcoord, pright, ierr )
426       ENDIF
427
428       IF ( lcoord(1) > pcoord(1) ) THEN
429          lcoord(2) = MODULO( lcoord(2) - y_shift, pdims(2) )
430          CALL MPI_CART_RANK( comm2d, lcoord, pleft, ierr )
431       ENDIF
432    ENDIF
433!
434!-- Vertical nesting: store four lists that identify partner ranks to exchange
435!-- data
436    IF ( vnested )  CALL vnest_init_pegrid_rank
437
438!
439!-- Determine sub-topologies for transpositions
440!-- Transposition from z to x:
441    remain_dims(1) = .TRUE.
442    remain_dims(2) = .FALSE.
443    CALL MPI_CART_SUB( comm2d, remain_dims, comm1dx, ierr )
444    CALL MPI_COMM_RANK( comm1dx, myidx, ierr )
445!
446!-- Transposition from x to y
447    remain_dims(1) = .FALSE.
448    remain_dims(2) = .TRUE.
449    CALL MPI_CART_SUB( comm2d, remain_dims, comm1dy, ierr )
450    CALL MPI_COMM_RANK( comm1dy, myidy, ierr )
451
452
453!
454!-- Calculate array bounds along x-direction for every PE.
455    ALLOCATE( nxlf(0:pdims(1)-1), nxrf(0:pdims(1)-1), nynf(0:pdims(2)-1),      &
456              nysf(0:pdims(2)-1) )
457
458    IF ( MOD( nx+1 , pdims(1) ) /= 0 )  THEN
459       WRITE( message_string, * ) 'x-direction: gridpoint number (',nx+1,') ', &
460                               'is not an integral divisor of the number ',    &
461                               'of processors (', pdims(1),')'
462       CALL message( 'init_pegrid', 'PA0225', 1, 2, 0, 6, 0 )
463    ELSE
464       nnx  = ( nx + 1 ) / pdims(1)
465    ENDIF   
466
467!
468!-- Left and right array bounds, number of gridpoints
469    DO  i = 0, pdims(1)-1
470       nxlf(i)   = i * nnx
471       nxrf(i)   = ( i + 1 ) * nnx - 1
472    ENDDO
473
474!
475!-- Calculate array bounds in y-direction for every PE.
476    IF ( MOD( ny+1 , pdims(2) ) /= 0 )  THEN
477       WRITE( message_string, * ) 'y-direction: gridpoint number (',ny+1,') ', &
478                           'is not an integral divisor of the number of',      &
479                           'processors (', pdims(2),')'
480       CALL message( 'init_pegrid', 'PA0227', 1, 2, 0, 6, 0 )
481    ELSE
482       nny  = ( ny + 1 ) / pdims(2)
483    ENDIF   
484
485!
486!-- South and north array bounds
487    DO  j = 0, pdims(2)-1
488       nysf(j)   = j * nny
489       nynf(j)   = ( j + 1 ) * nny - 1
490    ENDDO
491
492!
493!-- Local array bounds of the respective PEs
494    nxl = nxlf(pcoord(1))
495    nxr = nxrf(pcoord(1))
496    nys = nysf(pcoord(2))
497    nyn = nynf(pcoord(2))
498    nzb = 0
499    nzt = nz
500    nnz = nz
501
502!
503!-- Set switches to define if the PE is situated at the border of the virtual
504!-- processor grid
505    IF ( nxl == 0 )   left_border_pe  = .TRUE.
506    IF ( nxr == nx )  right_border_pe = .TRUE.
507    IF ( nys == 0 )   south_border_pe = .TRUE.
508    IF ( nyn == ny )  north_border_pe = .TRUE.
509
510!
511!-- Calculate array bounds and gridpoint numbers for the transposed arrays
512!-- (needed in the pressure solver)
513!-- For the transposed arrays, cyclic boundaries as well as top and bottom
514!-- boundaries are omitted, because they are obstructive to the transposition
515
516!
517!-- 1. transposition  z --> x
518!-- This transposition is not neccessary in case of a 1d-decomposition along x
519    IF ( psolver == 'poisfft'  .OR.  calculate_spectra )  THEN
520
521       IF ( pdims(2) /= 1 )  THEN
522          IF ( MOD( nz , pdims(1) ) /= 0 )  THEN
523             WRITE( message_string, * ) 'transposition z --> x:',              &
524                       ' nz=',nz,' is not an integral divisior of pdims(1)=',  &
525                                                                   pdims(1)
526             CALL message( 'init_pegrid', 'PA0230', 1, 2, 0, 6, 0 )
527          ENDIF
528       ENDIF
529
530       nys_x = nys
531       nyn_x = nyn
532       nny_x = nny
533       nnz_x = nz / pdims(1)
534       nzb_x = 1 + myidx * nnz_x
535       nzt_x = ( myidx + 1 ) * nnz_x
536       sendrecvcount_zx = nnx * nny * nnz_x
537
538    ENDIF
539
540
541    IF ( psolver == 'poisfft' )  THEN 
542!
543!--    2. transposition  x --> y
544       IF ( MOD( nx+1 , pdims(2) ) /= 0 )  THEN
545          WRITE( message_string, * ) 'transposition x --> y:',                 &
546                            ' nx+1=',nx+1,' is not an integral divisor of ',   &
547                            'pdims(2)=',pdims(2)
548          CALL message( 'init_pegrid', 'PA0231', 1, 2, 0, 6, 0 )
549       ENDIF
550
551       nnz_y = nnz_x
552       nzb_y = nzb_x
553       nzt_y = nzt_x
554       nnx_y = (nx+1) / pdims(2)
555       nxl_y = myidy * nnx_y
556       nxr_y = ( myidy + 1 ) * nnx_y - 1
557       sendrecvcount_xy = nnx_y * nny_x * nnz_y
558!
559!--    3. transposition  y --> z 
560!--    (ELSE:  x --> y  in case of 1D-decomposition along x)
561       nxl_z = nxl_y
562       nxr_z = nxr_y
563       nny_z = (ny+1) / pdims(1)
564       nys_z = myidx * nny_z
565       nyn_z = ( myidx + 1 ) * nny_z - 1
566       sendrecvcount_yz = nnx_y * nny_z * nnz_y
567
568       IF ( pdims(2) /= 1 )  THEN
569!
570!--       y --> z
571!--       This transposition is not neccessary in case of a 1d-decomposition
572!--       along x, except that the uptream-spline method is switched on
573          IF ( MOD( ny+1 , pdims(1) ) /= 0 )  THEN
574             WRITE( message_string, * ) 'transposition y --> z:',              &
575                               ' ny+1=',ny+1,' is not an integral divisor of', &
576                               ' pdims(1)=',pdims(1)
577             CALL message( 'init_pegrid', 'PA0232', 1, 2, 0, 6, 0 )
578          ENDIF
579
580       ELSE
581!
582!--       x --> y
583!--       This condition must be fulfilled for a 1D-decomposition along x
584          IF ( MOD( ny+1 , pdims(1) ) /= 0 )  THEN
585             WRITE( message_string, * ) 'transposition x --> y:',              &
586                               ' ny+1=',ny+1,' is not an integral divisor of', &
587                               ' pdims(1)=',pdims(1)
588             CALL message( 'init_pegrid', 'PA0233', 1, 2, 0, 6, 0 )
589          ENDIF
590
591       ENDIF
592
593    ENDIF
594
595!
596!-- Indices for direct transpositions z --> y (used for calculating spectra)
597    IF ( calculate_spectra )  THEN
598       IF ( MOD( nz, pdims(2) ) /= 0 )  THEN
599          WRITE( message_string, * ) 'direct transposition z --> y (needed ',  &
600                    'for spectra): nz=',nz,' is not an integral divisor of ',  &
601                    'pdims(2)=',pdims(2)
602          CALL message( 'init_pegrid', 'PA0234', 1, 2, 0, 6, 0 )
603       ELSE
604          nxl_yd = nxl
605          nxr_yd = nxr
606          nzb_yd = 1 + myidy * ( nz / pdims(2) )
607          nzt_yd = ( myidy + 1 ) * ( nz / pdims(2) )
608          sendrecvcount_zyd = nnx * nny * ( nz / pdims(2) )
609       ENDIF
610    ENDIF
611
612    IF ( psolver == 'poisfft'  .OR.  calculate_spectra )  THEN
613!
614!--    Indices for direct transpositions y --> x
615!--    (they are only possible in case of a 1d-decomposition along x)
616       IF ( pdims(2) == 1 )  THEN
617          nny_x = nny / pdims(1)
618          nys_x = myid * nny_x
619          nyn_x = ( myid + 1 ) * nny_x - 1
620          nzb_x = 1
621          nzt_x = nz
622          sendrecvcount_xy = nnx * nny_x * nz
623       ENDIF
624
625    ENDIF
626
627    IF ( psolver == 'poisfft' )  THEN
628!
629!--    Indices for direct transpositions x --> y
630!--    (they are only possible in case of a 1d-decomposition along y)
631       IF ( pdims(1) == 1 )  THEN
632          nnx_y = nnx / pdims(2)
633          nxl_y = myid * nnx_y
634          nxr_y = ( myid + 1 ) * nnx_y - 1
635          nzb_y = 1
636          nzt_y = nz
637          sendrecvcount_xy = nnx_y * nny * nz
638       ENDIF
639
640    ENDIF
641
642!
643!-- Arrays for storing the array bounds are needed any more
644    DEALLOCATE( nxlf , nxrf , nynf , nysf )
645
646
647!
648!-- Collect index bounds from other PEs (to be written to restart file later)
649    ALLOCATE( hor_index_bounds(4,0:numprocs-1) )
650
651    IF ( myid == 0 )  THEN
652
653       hor_index_bounds(1,0) = nxl
654       hor_index_bounds(2,0) = nxr
655       hor_index_bounds(3,0) = nys
656       hor_index_bounds(4,0) = nyn
657
658!
659!--    Receive data from all other PEs
660       DO  i = 1, numprocs-1
661          CALL MPI_RECV( ibuf, 4, MPI_INTEGER, i, MPI_ANY_TAG, comm2d, status, &
662                         ierr )
663          hor_index_bounds(:,i) = ibuf(1:4)
664       ENDDO
665
666    ELSE
667!
668!--    Send index bounds to PE0
669       ibuf(1) = nxl
670       ibuf(2) = nxr
671       ibuf(3) = nys
672       ibuf(4) = nyn
673       CALL MPI_SEND( ibuf, 4, MPI_INTEGER, 0, myid, comm2d, ierr )
674
675    ENDIF
676
677
678#if defined( __print )
679!
680!-- Control output
681    IF ( myid == 0 )  THEN
682       PRINT*, '*** processor topology ***'
683       PRINT*, ' '
684       PRINT*, 'myid   pcoord    left right  south north  idx idy   nxl: nxr',&
685               &'   nys: nyn'
686       PRINT*, '------------------------------------------------------------',&
687               &'-----------'
688       WRITE (*,1000)  0, pcoord(1), pcoord(2), pleft, pright, psouth, pnorth, &
689                       myidx, myidy, nxl, nxr, nys, nyn
6901000   FORMAT (I4,2X,'(',I3,',',I3,')',3X,I4,2X,I4,3X,I4,2X,I4,2X,I3,1X,I3, &
691               2(2X,I4,':',I4))
692
693!
694!--    Receive data from the other PEs
695       DO  i = 1,numprocs-1
696          CALL MPI_RECV( ibuf, 12, MPI_INTEGER, i, MPI_ANY_TAG, comm2d, status, &
697                         ierr )
698          WRITE (*,1000)  i, ( ibuf(j) , j = 1,12 )
699       ENDDO
700    ELSE
701
702!
703!--    Send data to PE0
704       ibuf(1) = pcoord(1); ibuf(2) = pcoord(2); ibuf(3) = pleft
705       ibuf(4) = pright; ibuf(5) = psouth; ibuf(6) = pnorth; ibuf(7) = myidx
706       ibuf(8) = myidy; ibuf(9) = nxl; ibuf(10) = nxr; ibuf(11) = nys
707       ibuf(12) = nyn
708       CALL MPI_SEND( ibuf, 12, MPI_INTEGER, 0, myid, comm2d, ierr )       
709    ENDIF
710#endif
711
712!
713!-- Determine the number of ghost point layers
714    IF ( ( scalar_advec == 'ws-scheme' .AND. .NOT. neutral ) .OR.             &
715         momentum_advec == 'ws-scheme' )  THEN
716       nbgp = 3
717    ELSE
718       nbgp = 1
719    ENDIF
720
721!
722!-- Create a new MPI derived datatype for the exchange of surface (xy) data,
723!-- which is needed for coupled atmosphere-ocean runs.
724!-- First, calculate number of grid points of an xy-plane.
725    ngp_xy  = ( nxr - nxl + 1 + 2 * nbgp ) * ( nyn - nys + 1 + 2 * nbgp )
726    CALL MPI_TYPE_VECTOR( ngp_xy, 1, nzt-nzb+2, MPI_REAL, type_xy, ierr )
727    CALL MPI_TYPE_COMMIT( type_xy, ierr )
728
729    IF ( TRIM( coupling_mode ) /= 'uncoupled' .AND. .NOT. vnested )  THEN
730   
731!
732!--    Pass the number of grid points of the atmosphere model to
733!--    the ocean model and vice versa
734       IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
735
736          nx_a = nx
737          ny_a = ny
738
739          IF ( myid == 0 )  THEN
740
741             CALL MPI_SEND( nx_a, 1, MPI_INTEGER, numprocs, 1, comm_inter,  &
742                            ierr )
743             CALL MPI_SEND( ny_a, 1, MPI_INTEGER, numprocs, 2, comm_inter,  &
744                            ierr )
745             CALL MPI_SEND( pdims, 2, MPI_INTEGER, numprocs, 3, comm_inter, &
746                            ierr )
747             CALL MPI_RECV( nx_o, 1, MPI_INTEGER, numprocs, 4, comm_inter,  &
748                            status, ierr )
749             CALL MPI_RECV( ny_o, 1, MPI_INTEGER, numprocs, 5, comm_inter,  &
750                            status, ierr )
751             CALL MPI_RECV( pdims_remote, 2, MPI_INTEGER, numprocs, 6,      &
752                            comm_inter, status, ierr )
753          ENDIF
754
755          CALL MPI_BCAST( nx_o, 1, MPI_INTEGER, 0, comm2d, ierr )
756          CALL MPI_BCAST( ny_o, 1, MPI_INTEGER, 0, comm2d, ierr ) 
757          CALL MPI_BCAST( pdims_remote, 2, MPI_INTEGER, 0, comm2d, ierr )
758       
759       ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
760
761          nx_o = nx
762          ny_o = ny
763
764          IF ( myid == 0 ) THEN
765
766             CALL MPI_RECV( nx_a, 1, MPI_INTEGER, 0, 1, comm_inter, status, &
767                            ierr )
768             CALL MPI_RECV( ny_a, 1, MPI_INTEGER, 0, 2, comm_inter, status, &
769                            ierr )
770             CALL MPI_RECV( pdims_remote, 2, MPI_INTEGER, 0, 3, comm_inter, &
771                            status, ierr )
772             CALL MPI_SEND( nx_o, 1, MPI_INTEGER, 0, 4, comm_inter, ierr )
773             CALL MPI_SEND( ny_o, 1, MPI_INTEGER, 0, 5, comm_inter, ierr )
774             CALL MPI_SEND( pdims, 2, MPI_INTEGER, 0, 6, comm_inter, ierr )
775          ENDIF
776
777          CALL MPI_BCAST( nx_a, 1, MPI_INTEGER, 0, comm2d, ierr)
778          CALL MPI_BCAST( ny_a, 1, MPI_INTEGER, 0, comm2d, ierr) 
779          CALL MPI_BCAST( pdims_remote, 2, MPI_INTEGER, 0, comm2d, ierr) 
780
781       ENDIF
782 
783       ngp_a = ( nx_a+1 + 2 * nbgp ) * ( ny_a+1 + 2 * nbgp )
784       ngp_o = ( nx_o+1 + 2 * nbgp ) * ( ny_o+1 + 2 * nbgp )
785
786!
787!--    Determine if the horizontal grid and the number of PEs in ocean and
788!--    atmosphere is same or not
789       IF ( nx_o == nx_a  .AND.  ny_o == ny_a  .AND.  &
790            pdims(1) == pdims_remote(1) .AND. pdims(2) == pdims_remote(2) ) &
791       THEN
792          coupling_topology = 0
793       ELSE
794          coupling_topology = 1
795       ENDIF
796
797!
798!--    Determine the target PEs for the exchange between ocean and
799!--    atmosphere (comm2d)
800       IF ( coupling_topology == 0 )  THEN
801!
802!--       In case of identical topologies, every atmosphere PE has exactly one
803!--       ocean PE counterpart and vice versa
804          IF ( TRIM( coupling_mode ) == 'atmosphere_to_ocean' ) THEN
805             target_id = myid + numprocs
806          ELSE
807             target_id = myid
808          ENDIF
809
810       ELSE
811!
812!--       In case of nonequivalent topology in ocean and atmosphere only for
813!--       PE0 in ocean and PE0 in atmosphere a target_id is needed, since
814!--       data echxchange between ocean and atmosphere will be done only
815!--       between these PEs.   
816          IF ( myid == 0 )  THEN
817
818             IF ( TRIM( coupling_mode ) == 'atmosphere_to_ocean' )  THEN
819                target_id = numprocs
820             ELSE
821                target_id = 0
822             ENDIF
823
824          ENDIF
825
826       ENDIF
827
828    ENDIF
829
830!
831!-- Store partner grid point co-ordinates as lists.
832!-- Create custom MPI vector datatypes for contiguous data transfer
833    IF ( vnested )  CALL vnest_init_pegrid_domain
834
835#else
836
837!
838!-- Array bounds when running on a single PE (respectively a non-parallel
839!-- machine)
840    nxl = 0
841    nxr = nx
842    nnx = nxr - nxl + 1
843    nys = 0
844    nyn = ny
845    nny = nyn - nys + 1
846    nzb = 0
847    nzt = nz
848    nnz = nz
849
850    ALLOCATE( hor_index_bounds(4,0:0) )
851    hor_index_bounds(1,0) = nxl
852    hor_index_bounds(2,0) = nxr
853    hor_index_bounds(3,0) = nys
854    hor_index_bounds(4,0) = nyn
855
856!
857!-- Array bounds for the pressure solver (in the parallel code, these bounds
858!-- are the ones for the transposed arrays)
859    nys_x = nys
860    nyn_x = nyn
861    nzb_x = nzb + 1
862    nzt_x = nzt
863
864    nxl_y = nxl
865    nxr_y = nxr
866    nzb_y = nzb + 1
867    nzt_y = nzt
868
869    nxl_z = nxl
870    nxr_z = nxr
871    nys_z = nys
872    nyn_z = nyn
873
874#endif
875
876!
877!-- Calculate number of grid levels necessary for the multigrid poisson solver
878!-- as well as the gridpoint indices on each level
879    IF ( psolver(1:9) == 'multigrid' )  THEN
880
881!
882!--    First calculate number of possible grid levels for the subdomains
883       mg_levels_x = 1
884       mg_levels_y = 1
885       mg_levels_z = 1
886
887       i = nnx
888       DO WHILE ( MOD( i, 2 ) == 0  .AND.  i /= 2 )
889          i = i / 2
890          mg_levels_x = mg_levels_x + 1
891       ENDDO
892
893       j = nny
894       DO WHILE ( MOD( j, 2 ) == 0  .AND.  j /= 2 )
895          j = j / 2
896          mg_levels_y = mg_levels_y + 1
897       ENDDO
898
899       k = nz    ! do not use nnz because it might be > nz due to transposition
900                 ! requirements
901       DO WHILE ( MOD( k, 2 ) == 0  .AND.  k /= 2 )
902          k = k / 2
903          mg_levels_z = mg_levels_z + 1
904       ENDDO
905!
906!--    The optimized MG-solver does not allow odd values for nz at the coarsest
907!--    grid level
908       IF ( TRIM( psolver ) /= 'multigrid_noopt' )  THEN
909          IF ( MOD( k, 2 ) /= 0 )  mg_levels_z = mg_levels_z - 1
910       ENDIF
911
912       maximum_grid_level = MIN( mg_levels_x, mg_levels_y, mg_levels_z )
913
914!
915!--    Find out, if the total domain allows more levels. These additional
916!--    levels are identically processed on all PEs.
917       IF ( numprocs > 1  .AND.  mg_switch_to_pe0_level /= -1 )  THEN
918
919          IF ( mg_levels_z > MIN( mg_levels_x, mg_levels_y ) )  THEN
920
921             mg_switch_to_pe0_level_l = maximum_grid_level
922
923             mg_levels_x = 1
924             mg_levels_y = 1
925
926             i = nx+1
927             DO WHILE ( MOD( i, 2 ) == 0  .AND.  i /= 2 )
928                i = i / 2
929                mg_levels_x = mg_levels_x + 1
930             ENDDO
931
932             j = ny+1
933             DO WHILE ( MOD( j, 2 ) == 0  .AND.  j /= 2 )
934                j = j / 2
935                mg_levels_y = mg_levels_y + 1
936             ENDDO
937
938             maximum_grid_level_l = MIN( mg_levels_x, mg_levels_y, mg_levels_z )
939
940             IF ( maximum_grid_level_l > mg_switch_to_pe0_level_l )  THEN
941                mg_switch_to_pe0_level_l = maximum_grid_level_l - &
942                                           mg_switch_to_pe0_level_l + 1
943             ELSE
944                mg_switch_to_pe0_level_l = 0
945             ENDIF
946
947          ELSE
948             mg_switch_to_pe0_level_l = 0
949             maximum_grid_level_l = maximum_grid_level
950
951          ENDIF
952
953!
954!--       Use switch level calculated above only if it is not pre-defined
955!--       by user
956          IF ( mg_switch_to_pe0_level == 0 )  THEN
957             IF ( mg_switch_to_pe0_level_l /= 0 )  THEN
958                mg_switch_to_pe0_level = mg_switch_to_pe0_level_l
959                maximum_grid_level     = maximum_grid_level_l
960             ENDIF
961
962          ELSE
963!
964!--          Check pre-defined value and reset to default, if neccessary
965             IF ( mg_switch_to_pe0_level < mg_switch_to_pe0_level_l  .OR.      &
966                  mg_switch_to_pe0_level >= maximum_grid_level_l )  THEN
967                message_string = 'mg_switch_to_pe0_level ' //                  &
968                                 'out of range and reset to 0'
969                CALL message( 'init_pegrid', 'PA0235', 0, 1, 0, 6, 0 )
970                mg_switch_to_pe0_level = 0
971             ELSE
972!
973!--             Use the largest number of possible levels anyway and recalculate
974!--             the switch level to this largest number of possible values
975                maximum_grid_level = maximum_grid_level_l
976
977             ENDIF
978
979          ENDIF
980
981       ENDIF
982
983       ALLOCATE( grid_level_count(maximum_grid_level),                       &
984                 nxl_mg(0:maximum_grid_level), nxr_mg(0:maximum_grid_level), &
985                 nyn_mg(0:maximum_grid_level), nys_mg(0:maximum_grid_level), &
986                 nzt_mg(0:maximum_grid_level) )
987
988       grid_level_count = 0
989!
990!--    Index zero required as dummy due to definition of arrays f2 and p2 in
991!--    recursive subroutine next_mg_level
992       nxl_mg(0) = 0; nxr_mg(0) = 0; nyn_mg(0) = 0; nys_mg(0) = 0; nzt_mg(0) = 0
993
994       nxl_l = nxl; nxr_l = nxr; nys_l = nys; nyn_l = nyn; nzt_l = nzt
995
996       DO  i = maximum_grid_level, 1 , -1
997
998          IF ( i == mg_switch_to_pe0_level )  THEN
999#if defined( __parallel )
1000!
1001!--          Save the grid size of the subdomain at the switch level, because
1002!--          it is needed in poismg.
1003             ind(1) = nxl_l; ind(2) = nxr_l
1004             ind(3) = nys_l; ind(4) = nyn_l
1005             ind(5) = nzt_l
1006             ALLOCATE( ind_all(5*numprocs), mg_loc_ind(5,0:numprocs-1) )
1007             CALL MPI_ALLGATHER( ind, 5, MPI_INTEGER, ind_all, 5, &
1008                                 MPI_INTEGER, comm2d, ierr )
1009             DO  j = 0, numprocs-1
1010                DO  k = 1, 5
1011                   mg_loc_ind(k,j) = ind_all(k+j*5)
1012                ENDDO
1013             ENDDO
1014             DEALLOCATE( ind_all )
1015!
1016!--          Calculate the grid size of the total domain
1017             nxr_l = ( nxr_l-nxl_l+1 ) * pdims(1) - 1
1018             nxl_l = 0
1019             nyn_l = ( nyn_l-nys_l+1 ) * pdims(2) - 1
1020             nys_l = 0
1021!
1022!--          The size of this gathered array must not be larger than the
1023!--          array tend, which is used in the multigrid scheme as a temporary
1024!--          array. Therefore the subdomain size of an PE is calculated and
1025!--          the size of the gathered grid. These values are used in 
1026!--          routines pres and poismg
1027             subdomain_size = ( nxr - nxl + 2 * nbgp + 1 ) * &
1028                              ( nyn - nys + 2 * nbgp + 1 ) * ( nzt - nzb + 2 )
1029             gathered_size  = ( nxr_l - nxl_l + 3 ) * ( nyn_l - nys_l + 3 ) *  &
1030                              ( nzt_l - nzb + 2 )
1031
1032#else
1033             message_string = 'multigrid gather/scatter impossible ' //        &
1034                          'in non parallel mode'
1035             CALL message( 'init_pegrid', 'PA0237', 1, 2, 0, 6, 0 )
1036#endif
1037          ENDIF
1038
1039          nxl_mg(i) = nxl_l
1040          nxr_mg(i) = nxr_l
1041          nys_mg(i) = nys_l
1042          nyn_mg(i) = nyn_l
1043          nzt_mg(i) = nzt_l
1044
1045          nxl_l = nxl_l / 2 
1046          nxr_l = nxr_l / 2
1047          nys_l = nys_l / 2 
1048          nyn_l = nyn_l / 2 
1049          nzt_l = nzt_l / 2 
1050
1051       ENDDO
1052
1053!
1054!--    Temporary problem: Currently calculation of maxerror in routine poismg crashes
1055!--    if grid data are collected on PE0 already on the finest grid level.
1056!--    To be solved later.
1057       IF ( maximum_grid_level == mg_switch_to_pe0_level )  THEN
1058          message_string = 'grid coarsening on subdomain level cannot be performed'
1059          CALL message( 'poismg', 'PA0236', 1, 2, 0, 6, 0 )
1060       ENDIF
1061
1062    ELSE
1063
1064       maximum_grid_level = 0
1065
1066    ENDIF
1067
1068!
1069!-- Default level 0 tells exchange_horiz that all ghost planes have to be
1070!-- exchanged. grid_level is adjusted in poismg, where only one ghost plane
1071!-- is required.
1072    grid_level = 0
1073
1074#if defined( __parallel )
1075!
1076!-- Gridpoint number for the exchange of ghost points (y-line for 2D-arrays)
1077    ngp_y  = nyn - nys + 1 + 2 * nbgp
1078
1079!
1080!-- Define new MPI derived datatypes for the exchange of ghost points in
1081!-- x- and y-direction for 2D-arrays (line)
1082    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp, ngp_y, MPI_REAL, type_x,     &
1083                          ierr )
1084    CALL MPI_TYPE_COMMIT( type_x, ierr )
1085
1086    CALL MPI_TYPE_VECTOR( nbgp, ngp_y, ngp_y, MPI_REAL, type_y, ierr )
1087    CALL MPI_TYPE_COMMIT( type_y, ierr )
1088!
1089!-- Define new MPI derived datatypes for the exchange of ghost points in
1090!-- x- and y-direction for 2D-INTEGER arrays (line) - on normal grid
1091    ALLOCATE( type_x_int(0:maximum_grid_level),                                &
1092              type_y_int(0:maximum_grid_level) )
1093
1094    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp, ngp_y, MPI_INTEGER,          &
1095                          type_x_int(0), ierr )
1096    CALL MPI_TYPE_COMMIT( type_x_int(0), ierr )
1097
1098    CALL MPI_TYPE_VECTOR( nbgp, ngp_y, ngp_y, MPI_INTEGER, type_y_int(0), ierr )
1099    CALL MPI_TYPE_COMMIT( type_y_int(0), ierr )
1100!
1101!-- Calculate gridpoint numbers for the exchange of ghost points along x
1102!-- (yz-plane for 3D-arrays) and define MPI derived data type(s) for the
1103!-- exchange of ghost points in y-direction (xz-plane).
1104!-- Do these calculations for the model grid and (if necessary) also
1105!-- for the coarser grid levels used in the multigrid method
1106    ALLOCATE ( ngp_xz(0:maximum_grid_level),                                   &
1107               ngp_xz_int(0:maximum_grid_level),                               &
1108               ngp_yz(0:maximum_grid_level),                                   &
1109               ngp_yz_int(0:maximum_grid_level),                               &
1110               type_xz(0:maximum_grid_level),                                  &
1111               type_xz_int(0:maximum_grid_level),                              &
1112               type_yz(0:maximum_grid_level),                                  &
1113               type_yz_int(0:maximum_grid_level) )
1114
1115    nxl_l = nxl; nxr_l = nxr; nys_l = nys; nyn_l = nyn; nzb_l = nzb; nzt_l = nzt
1116
1117!
1118!-- Discern between the model grid, which needs nbgp ghost points and
1119!-- grid levels for the multigrid scheme. In the latter case only one
1120!-- ghost point is necessary.
1121!-- First definition of MPI-datatypes for exchange of ghost layers on normal
1122!-- grid. The following loop is needed for data exchange in poismg.f90.
1123!
1124!-- Determine number of grid points of yz-layer for exchange
1125    ngp_yz(0) = (nzt - nzb + 2) * (nyn - nys + 1 + 2 * nbgp)
1126
1127!
1128!-- Define an MPI-datatype for the exchange of left/right boundaries.
1129!-- Although data are contiguous in physical memory (which does not
1130!-- necessarily require an MPI-derived datatype), the data exchange between
1131!-- left and right PE's using the MPI-derived type is 10% faster than without.
1132    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp*(nzt-nzb+2), ngp_yz(0), &
1133                          MPI_REAL, type_xz(0), ierr )
1134    CALL MPI_TYPE_COMMIT( type_xz(0), ierr )
1135
1136    CALL MPI_TYPE_VECTOR( nbgp, ngp_yz(0), ngp_yz(0), MPI_REAL, type_yz(0), &
1137                          ierr ) 
1138    CALL MPI_TYPE_COMMIT( type_yz(0), ierr )
1139
1140!
1141!-- Define data types for exchange of 3D Integer arrays.
1142    ngp_yz_int(0) = (nzt - nzb + 2) * (nyn - nys + 1 + 2 * nbgp)
1143
1144    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp*(nzt-nzb+2), ngp_yz_int(0),   &
1145                          MPI_INTEGER, type_xz_int(0), ierr )
1146    CALL MPI_TYPE_COMMIT( type_xz_int(0), ierr )
1147
1148    CALL MPI_TYPE_VECTOR( nbgp, ngp_yz_int(0), ngp_yz_int(0), MPI_INTEGER,     &
1149                          type_yz_int(0), ierr )
1150    CALL MPI_TYPE_COMMIT( type_yz_int(0), ierr )
1151
1152!
1153!-- Definition of MPI-datatypes for multigrid method (coarser level grids)
1154    IF ( psolver(1:9) == 'multigrid' )  THEN
1155!   
1156!--    Definition of MPI-datatyoe as above, but only 1 ghost level is used
1157       DO  i = maximum_grid_level, 1 , -1
1158!
1159!--       For 3D-exchange on different multigrid level, one ghost point for
1160!--       REAL arrays, two ghost points for INTEGER arrays
1161          ngp_xz(i) = (nzt_l - nzb_l + 2) * (nxr_l - nxl_l + 3)
1162          ngp_yz(i) = (nzt_l - nzb_l + 2) * (nyn_l - nys_l + 3)
1163
1164          ngp_xz_int(i) = (nzt_l - nzb_l + 2) * (nxr_l - nxl_l + 3)
1165          ngp_yz_int(i) = (nzt_l - nzb_l + 2) * (nyn_l - nys_l + 3)
1166!
1167!--       MPI data type for REAL arrays, for xz-layers
1168          CALL MPI_TYPE_VECTOR( nxr_l-nxl_l+3, nzt_l-nzb_l+2, ngp_yz(i),       &
1169                                MPI_REAL, type_xz(i), ierr )
1170          CALL MPI_TYPE_COMMIT( type_xz(i), ierr )
1171
1172!
1173!--       MPI data type for INTEGER arrays, for xz-layers
1174          CALL MPI_TYPE_VECTOR( nxr_l-nxl_l+3, nzt_l-nzb_l+2, ngp_yz_int(i),   &
1175                                MPI_INTEGER, type_xz_int(i), ierr )
1176          CALL MPI_TYPE_COMMIT( type_xz_int(i), ierr )
1177
1178!
1179!--       MPI data type for REAL arrays, for yz-layers
1180          CALL MPI_TYPE_VECTOR( 1, ngp_yz(i), ngp_yz(i), MPI_REAL, type_yz(i), &
1181                                ierr )
1182          CALL MPI_TYPE_COMMIT( type_yz(i), ierr )
1183!
1184!--       MPI data type for INTEGER arrays, for yz-layers
1185          CALL MPI_TYPE_VECTOR( 1, ngp_yz_int(i), ngp_yz_int(i), MPI_INTEGER,  &
1186                                type_yz_int(i), ierr )
1187          CALL MPI_TYPE_COMMIT( type_yz_int(i), ierr )
1188
1189
1190!--       For 2D-exchange of INTEGER arrays on coarser grid level, where 2 ghost
1191!--       points need to be exchanged.
1192          CALL MPI_TYPE_VECTOR( nxr_l-nxl_l+5, 2, nyn_l-nys_l+5, MPI_INTEGER,          &
1193                                type_x_int(i), ierr )
1194          CALL MPI_TYPE_COMMIT( type_x_int(i), ierr )
1195
1196
1197          CALL MPI_TYPE_VECTOR( 2, nyn_l-nys_l+5, nyn_l-nys_l+5, MPI_INTEGER,          &
1198                                type_y_int(i), ierr )
1199          CALL MPI_TYPE_COMMIT( type_y_int(i), ierr )
1200
1201          nxl_l = nxl_l / 2
1202          nxr_l = nxr_l / 2
1203          nys_l = nys_l / 2
1204          nyn_l = nyn_l / 2
1205          nzt_l = nzt_l / 2
1206
1207       ENDDO
1208
1209    ENDIF
1210
1211#endif
1212
1213#if defined( __parallel )
1214!
1215!-- Setting of flags for inflow/outflow/nesting conditions.
1216    IF ( pleft == MPI_PROC_NULL )  THEN
1217       IF ( bc_lr == 'dirichlet/radiation' )  THEN
1218          inflow_l  = .TRUE.
1219       ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1220          outflow_l = .TRUE.
1221       ELSEIF ( bc_lr == 'nested' )  THEN
1222          nest_bound_l = .TRUE.
1223       ELSEIF ( bc_lr == 'forcing' )  THEN
1224          force_bound_l = .TRUE.
1225       ENDIF
1226    ENDIF
1227 
1228    IF ( pright == MPI_PROC_NULL )  THEN
1229       IF ( bc_lr == 'dirichlet/radiation' )  THEN
1230          outflow_r = .TRUE.
1231       ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1232          inflow_r  = .TRUE.
1233       ELSEIF ( bc_lr == 'nested' )  THEN
1234          nest_bound_r = .TRUE.
1235       ELSEIF ( bc_lr == 'forcing' )  THEN
1236          force_bound_r = .TRUE.
1237       ENDIF
1238    ENDIF
1239
1240    IF ( psouth == MPI_PROC_NULL )  THEN
1241       IF ( bc_ns == 'dirichlet/radiation' )  THEN
1242          outflow_s = .TRUE.
1243       ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1244          inflow_s  = .TRUE.
1245       ELSEIF ( bc_ns == 'nested' )  THEN
1246          nest_bound_s = .TRUE.
1247       ELSEIF ( bc_ns == 'forcing' )  THEN
1248          force_bound_s = .TRUE.
1249       ENDIF
1250    ENDIF
1251
1252    IF ( pnorth == MPI_PROC_NULL )  THEN
1253       IF ( bc_ns == 'dirichlet/radiation' )  THEN
1254          inflow_n  = .TRUE.
1255       ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1256          outflow_n = .TRUE.
1257       ELSEIF ( bc_ns == 'nested' )  THEN
1258          nest_bound_n = .TRUE.
1259       ELSEIF ( bc_ns == 'forcing' )  THEN
1260          force_bound_n = .TRUE.
1261       ENDIF
1262    ENDIF
1263!
1264!-- In case of synthetic turbulence geneartor determine ids.
1265!-- Please note, if no forcing or nesting is applied, the generator is applied
1266!-- only at the left lateral boundary.
1267    IF ( use_syn_turb_gen )  THEN
1268       IF ( force_bound_l  .OR.  nest_bound_l  .OR.  inflow_l )  THEN
1269          id_stg_left_l = myidx
1270       ELSE
1271          id_stg_left_l = 0
1272       ENDIF
1273       IF ( force_bound_r  .OR.  nest_bound_r )  THEN
1274          id_stg_right_l = myidx
1275       ELSE
1276          id_stg_right_l = 0
1277       ENDIF
1278       IF ( force_bound_s  .OR.  nest_bound_s )  THEN
1279          id_stg_south_l = myidy
1280       ELSE
1281          id_stg_south_l = 0
1282       ENDIF
1283       IF ( force_bound_n  .OR.  nest_bound_n )  THEN
1284          id_stg_north_l = myidy
1285       ELSE
1286          id_stg_north_l = 0
1287       ENDIF
1288
1289       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1290       CALL MPI_ALLREDUCE( id_stg_left_l, id_stg_left,   1, MPI_INTEGER,       &
1291                           MPI_SUM, comm1dx, ierr )
1292
1293       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1294       CALL MPI_ALLREDUCE( id_stg_right_l, id_stg_right, 1, MPI_INTEGER,       &
1295                           MPI_SUM, comm1dx, ierr )
1296
1297       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1298       CALL MPI_ALLREDUCE( id_stg_south_l, id_stg_south, 1, MPI_INTEGER,       &
1299                           MPI_SUM, comm1dy, ierr )
1300
1301       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1302       CALL MPI_ALLREDUCE( id_stg_north_l, id_stg_north, 1, MPI_INTEGER,       &
1303                           MPI_SUM, comm1dy, ierr )
1304
1305    ENDIF
1306 
1307!
1308!-- Broadcast the id of the inflow PE
1309    IF ( inflow_l )  THEN
1310       id_inflow_l = myidx
1311    ELSE
1312       id_inflow_l = 0
1313    ENDIF
1314    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1315    CALL MPI_ALLREDUCE( id_inflow_l, id_inflow, 1, MPI_INTEGER, MPI_SUM, &
1316                        comm1dx, ierr )
1317
1318!
1319!-- Broadcast the id of the recycling plane
1320!-- WARNING: needs to be adjusted in case of inflows other than from left side!
1321    IF ( NINT( recycling_width / dx ) >= nxl  .AND. &
1322         NINT( recycling_width / dx ) <= nxr )  THEN
1323       id_recycling_l = myidx
1324    ELSE
1325       id_recycling_l = 0
1326    ENDIF
1327    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1328    CALL MPI_ALLREDUCE( id_recycling_l, id_recycling, 1, MPI_INTEGER, MPI_SUM, &
1329                        comm1dx, ierr )
1330
1331!
1332!-- Broadcast the id of the outflow PE and outflow-source plane
1333    IF ( turbulent_outflow )  THEN
1334
1335       IF ( outflow_r )  THEN
1336          id_outflow_l = myidx
1337       ELSE
1338          id_outflow_l = 0
1339       ENDIF
1340       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1341       CALL MPI_ALLREDUCE( id_outflow_l, id_outflow, 1, MPI_INTEGER, MPI_SUM, &
1342                           comm1dx, ierr )
1343
1344       IF ( NINT( outflow_source_plane / dx ) >= nxl  .AND. &
1345            NINT( outflow_source_plane / dx ) <= nxr )  THEN
1346          id_outflow_source_l = myidx
1347       ELSE
1348          id_outflow_source_l = 0
1349       ENDIF
1350       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1351       CALL MPI_ALLREDUCE( id_outflow_source_l, id_outflow_source, 1, &
1352                           MPI_INTEGER, MPI_SUM, comm1dx, ierr )
1353
1354    ENDIF
1355
1356    CALL location_message( 'finished', .TRUE. )
1357
1358#else
1359    IF ( bc_lr == 'dirichlet/radiation' )  THEN
1360       inflow_l  = .TRUE.
1361       outflow_r = .TRUE.
1362    ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1363       outflow_l = .TRUE.
1364       inflow_r  = .TRUE.
1365    ENDIF
1366
1367    IF ( bc_ns == 'dirichlet/radiation' )  THEN
1368       inflow_n  = .TRUE.
1369       outflow_s = .TRUE.
1370    ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1371       outflow_n = .TRUE.
1372       inflow_s  = .TRUE.
1373    ENDIF
1374#endif
1375
1376!
1377!-- At the inflow or outflow, u or v, respectively, have to be calculated for
1378!-- one more grid point.
1379    IF ( inflow_l .OR. outflow_l .OR. nest_bound_l .OR. force_bound_l )  THEN
1380       nxlu = nxl + 1
1381    ELSE
1382       nxlu = nxl
1383    ENDIF
1384    IF ( inflow_s .OR. outflow_s .OR. nest_bound_s .OR. force_bound_s )  THEN
1385       nysv = nys + 1
1386    ELSE
1387       nysv = nys
1388    ENDIF
1389
1390!
1391!-- Allocate wall flag arrays used in the multigrid solver
1392    IF ( psolver(1:9) == 'multigrid' )  THEN
1393
1394       DO  i = maximum_grid_level, 1, -1
1395
1396           SELECT CASE ( i )
1397
1398              CASE ( 1 )
1399                 ALLOCATE( wall_flags_1(nzb:nzt_mg(i)+1,         &
1400                                        nys_mg(i)-1:nyn_mg(i)+1, &
1401                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1402
1403              CASE ( 2 )
1404                 ALLOCATE( wall_flags_2(nzb:nzt_mg(i)+1,         &
1405                                        nys_mg(i)-1:nyn_mg(i)+1, &
1406                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1407
1408              CASE ( 3 )
1409                 ALLOCATE( wall_flags_3(nzb:nzt_mg(i)+1,         &
1410                                        nys_mg(i)-1:nyn_mg(i)+1, &
1411                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1412
1413              CASE ( 4 )
1414                 ALLOCATE( wall_flags_4(nzb:nzt_mg(i)+1,         &
1415                                        nys_mg(i)-1:nyn_mg(i)+1, &
1416                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1417
1418              CASE ( 5 )
1419                 ALLOCATE( wall_flags_5(nzb:nzt_mg(i)+1,         &
1420                                        nys_mg(i)-1:nyn_mg(i)+1, &
1421                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1422
1423              CASE ( 6 )
1424                 ALLOCATE( wall_flags_6(nzb:nzt_mg(i)+1,         &
1425                                        nys_mg(i)-1:nyn_mg(i)+1, &
1426                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1427
1428              CASE ( 7 )
1429                 ALLOCATE( wall_flags_7(nzb:nzt_mg(i)+1,         &
1430                                        nys_mg(i)-1:nyn_mg(i)+1, &
1431                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1432
1433              CASE ( 8 )
1434                 ALLOCATE( wall_flags_8(nzb:nzt_mg(i)+1,         &
1435                                        nys_mg(i)-1:nyn_mg(i)+1, &
1436                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1437
1438              CASE ( 9 )
1439                 ALLOCATE( wall_flags_9(nzb:nzt_mg(i)+1,         &
1440                                        nys_mg(i)-1:nyn_mg(i)+1, &
1441                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1442
1443              CASE ( 10 )
1444                 ALLOCATE( wall_flags_10(nzb:nzt_mg(i)+1,        &
1445                                        nys_mg(i)-1:nyn_mg(i)+1, &
1446                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1447
1448              CASE DEFAULT
1449                 message_string = 'more than 10 multigrid levels'
1450                 CALL message( 'init_pegrid', 'PA0238', 1, 2, 0, 6, 0 )
1451
1452          END SELECT
1453
1454       ENDDO
1455
1456    ENDIF
1457
1458 END SUBROUTINE init_pegrid
Note: See TracBrowser for help on using the repository browser.