source: palm/trunk/SOURCE/init_pegrid.f90 @ 2716

Last change on this file since 2716 was 2716, checked in by kanani, 6 years ago

Correction of "Former revisions" section

  • Property svn:keywords set to Id
File size: 49.7 KB
Line 
1!> @file init_pegrid.f90
2!------------------------------------------------------------------------------!
3! This file is part of the PALM model system.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2017 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! ------------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: init_pegrid.f90 2716 2017-12-29 16:35:59Z kanani $
27! Corrected "Former revisions" section
28!
29! 2696 2017-12-14 17:12:51Z kanani
30! Change in file header (GPL part)
31! 3D-Integer exchange on multigrid level (MS)
32! Forcing implemented (MS)
33!
34! 2600 2017-11-01 14:11:20Z raasch
35! calculation of block-I/O quantitites removed (is now done in parin)
36!
37! 2516 2017-10-04 11:03:04Z suehring
38! Remove tabs
39!
40! 2514 2017-10-04 09:52:37Z suehring
41! Redundant preprocessor directives removed
42!
43! 2372 2017-08-25 12:37:32Z sward
44! Shifted cyclic boundary conditions implemented
45!
46! 2365 2017-08-21 14:59:59Z kanani
47! Vertical nesting implemented (SadiqHuq)
48!
49! 2300 2017-06-29 13:31:14Z raasch
50! host-specific settings removed
51!
52! 2298 2017-06-29 09:28:18Z raasch
53! MPI2 related parts removed
54!
55! 2271 2017-06-09 12:34:55Z sward
56! Error message changed
57!
58! 2259 2017-06-08 09:09:11Z gronemeier
59! Implemented synthetic turbulence generator
60!
61! 2238 2017-05-31 16:49:16Z suehring
62! Remove unnecessary module load of pmc_interface
63!
64! 2231 2017-05-30 16:44:33Z suehring
65!
66! 2200 2017-04-11 11:37:51Z suehring
67! monotonic_adjustment removed
68!
69! 2197 2017-03-24 02:25:00Z raasch
70! bugfix: do not allow odd values for nz at the coarsest grid level in case of
71! optimized multigrid solver
72!
73! 2180 2017-03-17 13:33:05Z hellstea
74! Checks to ensure (2178) that pdims match the grid dimensions in the
75! automatic determination of pdims are canceled as unnecessary
76!
77! 2178 2017-03-17 11:07:39Z hellstea
78! Checks to ensure that pdims match the grid dimensions are added in the
79! automatic determination of pdims
80!
81! 2050 2016-11-08 15:00:55Z gronemeier
82! Implement turbulent outflow condition
83!
84! 2000 2016-08-20 18:09:15Z knoop
85! Forced header and separation lines into 80 columns
86!
87! 1968 2016-07-18 12:01:49Z suehring
88! Extent MPI-datatypes for exchange of 2D-INTEGER arrays on coarser multigrid
89! level 
90!
91! 1964 2016-07-14 15:35:18Z hellstea
92! Bugfix: erroneous setting of nest_bound_l/r/s/n = .TRUE. for vertical nesting mode removed.
93!
94! 1923 2016-05-31 16:37:07Z boeske
95! Initial version of purely vertical nesting introduced.
96!
97! 1922 2016-05-31 16:36:08Z boeske
98! Bugfix: array transposition checks restricted to cases if a fourier
99! transform is used , removed unused variable nnx_z
100!
101! 1833 2016-04-07 14:23:03Z raasch
102! spectra related variables moved to spectra_mod
103!
104! 1815 2016-04-06 13:49:59Z raasch
105! cpp-directives for intel openmp bug removed
106!
107! 1804 2016-04-05 16:30:18Z maronga
108! Removed code for parameter file check (__check)
109!
110! 1779 2016-03-03 08:01:28Z raasch
111! changes regarding nested domain removed: virtual PE grid will be automatically
112! calculated for nested runs too
113!
114! 1764 2016-02-28 12:45:19Z raasch
115! cpp-statements for nesting removed
116!
117! 1762 2016-02-25 12:31:13Z hellstea
118! Introduction of nested domain feature
119!
120! 1682 2015-10-07 23:56:08Z knoop
121! Code annotations made doxygen readable
122!
123! 1677 2015-10-02 13:25:23Z boeske
124! New MPI-data types for exchange of 3D integer arrays.
125!
126! 1575 2015-03-27 09:56:27Z raasch
127! adjustments for psolver-queries, calculation of ngp_xz added
128!
129! 1565 2015-03-09 20:59:31Z suehring
130! Refine if-clause for setting nbgp.
131!
132! 1557 2015-03-05 16:43:04Z suehring
133! Adjustment for monotonic limiter
134!
135! 1468 2014-09-24 14:06:57Z maronga
136! Adapted for use on up to 6-digit processor cores
137!
138! 1435 2014-07-21 10:37:02Z keck
139! bugfix: added missing parameter coupling_mode_remote to ONLY-attribute
140!
141! 1402 2014-05-09 14:25:13Z raasch
142! location messages modified
143!
144! 1384 2014-05-02 14:31:06Z raasch
145! location messages added
146!
147! 1353 2014-04-08 15:21:23Z heinze
148! REAL constants provided with KIND-attribute
149!
150! 1322 2014-03-20 16:38:49Z raasch
151! REAL functions provided with KIND-attribute
152!
153! 1320 2014-03-20 08:40:49Z raasch
154! ONLY-attribute added to USE-statements,
155! kind-parameters added to all INTEGER and REAL declaration statements,
156! kinds are defined in new module kinds,
157! revision history before 2012 removed,
158! comment fields (!:) to be used for variable explanations added to
159! all variable declaration statements
160!
161! 1304 2014-03-12 10:29:42Z raasch
162! bugfix: single core MPI runs missed some settings of transpose indices
163!
164! 1212 2013-08-15 08:46:27Z raasch
165! error message for poisfft_hybrid removed
166!
167! 1159 2013-05-21 11:58:22Z fricke
168! dirichlet/neumann and neumann/dirichlet removed
169!
170! 1139 2013-04-18 07:25:03Z raasch
171! bugfix for calculating the id of the PE carrying the recycling plane
172!
173! 1111 2013-03-08 23:54:10Z raasch
174! initialization of poisfft moved to module poisfft
175!
176! 1092 2013-02-02 11:24:22Z raasch
177! unused variables removed
178!
179! 1056 2012-11-16 15:28:04Z raasch
180! Indices for arrays n.._mg start from zero due to definition of arrays f2 and
181! p2 as automatic arrays in recursive subroutine next_mg_level
182!
183! 1041 2012-11-06 02:36:29Z raasch
184! a 2d virtual processor topology is used by default for all machines
185!
186! 1036 2012-10-22 13:43:42Z raasch
187! code put under GPL (PALM 3.9)
188!
189! 1003 2012-09-14 14:35:53Z raasch
190! subdomains must have identical size (grid matching = "match" removed)
191!
192! 1001 2012-09-13 14:08:46Z raasch
193! all actions concerning upstream-spline-method removed
194!
195! 978 2012-08-09 08:28:32Z fricke
196! dirichlet/neumann and neumann/dirichlet added
197! nxlu and nysv are also calculated for inflow boundary
198!
199! 809 2012-01-30 13:32:58Z maronga
200! Bugfix: replaced .AND. and .NOT. with && and ! in the preprocessor directives
201!
202! 807 2012-01-25 11:53:51Z maronga
203! New cpp directive "__check" implemented which is used by check_namelist_files
204!
205! Revision 1.1  1997/07/24 11:15:09  raasch
206! Initial revision
207!
208!
209! Description:
210! ------------
211!> Determination of the virtual processor topology (if not prescribed by the
212!> user)and computation of the grid point number and array bounds of the local
213!> domains.
214!> @todo: remove MPI-data types for 2D exchange on coarse multigrid level (not
215!>        used any more)
216!------------------------------------------------------------------------------!
217 SUBROUTINE init_pegrid
218 
219
220    USE control_parameters,                                                    &
221        ONLY:  bc_lr, bc_ns, coupling_mode, coupling_mode_remote,              &
222               coupling_topology, force_bound_l, force_bound_n, force_bound_r, &
223               force_bound_s, gathered_size, grid_level,                       &
224               grid_level_count, inflow_l, inflow_n, inflow_r, inflow_s,       &
225               maximum_grid_level, message_string,                             &
226               mg_switch_to_pe0_level, momentum_advec, nest_bound_l,           &
227               nest_bound_n, nest_bound_r, nest_bound_s, nest_domain, neutral, &
228               psolver, outflow_l, outflow_n, outflow_r, outflow_s,            &
229               outflow_source_plane, recycling_width, scalar_advec,            &
230               subdomain_size, turbulent_outflow, y_shift
231
232    USE grid_variables,                                                        &
233        ONLY:  dx
234       
235    USE indices,                                                               &
236        ONLY:  mg_loc_ind, nbgp, nnx, nny, nnz, nx, nx_a, nx_o, nxl, nxl_mg,   &
237               nxlu, nxr, nxr_mg, ny, ny_a, ny_o, nyn, nyn_mg, nys, nys_mg,    &
238               nysv, nz, nzb, nzt, nzt_mg, wall_flags_1, wall_flags_2,         &
239               wall_flags_3, wall_flags_4, wall_flags_5, wall_flags_6,         &
240               wall_flags_7, wall_flags_8, wall_flags_9, wall_flags_10
241
242    USE kinds
243     
244    USE pegrid
245     
246    USE spectra_mod,                                                           &
247        ONLY:  calculate_spectra, dt_dosp
248
249    USE synthetic_turbulence_generator_mod,                                    &
250        ONLY:  use_synthetic_turbulence_generator
251
252    USE transpose_indices,                                                     &
253        ONLY:  nxl_y, nxl_yd, nxl_z, nxr_y, nxr_yd, nxr_z, nyn_x, nyn_z, nys_x,&
254               nys_z, nzb_x, nzb_y, nzb_yd, nzt_x, nzt_yd, nzt_y
255
256    USE vertical_nesting_mod,                                                  &
257        ONLY:  vnested, vnest_init_pegrid_domain, vnest_init_pegrid_rank
258
259    IMPLICIT NONE
260
261    INTEGER(iwp) ::  i                        !<
262    INTEGER(iwp) ::  id_inflow_l              !<
263    INTEGER(iwp) ::  id_outflow_l             !< local value of id_outflow
264    INTEGER(iwp) ::  id_outflow_source_l      !< local value of id_outflow_source
265    INTEGER(iwp) ::  id_recycling_l           !<
266    INTEGER(iwp) ::  ind(5)                   !<
267    INTEGER(iwp) ::  j                        !<
268    INTEGER(iwp) ::  k                        !<
269    INTEGER(iwp) ::  maximum_grid_level_l     !<
270    INTEGER(iwp) ::  mg_levels_x              !<
271    INTEGER(iwp) ::  mg_levels_y              !<
272    INTEGER(iwp) ::  mg_levels_z              !<
273    INTEGER(iwp) ::  mg_switch_to_pe0_level_l !<
274    INTEGER(iwp) ::  nnx_y                    !<
275    INTEGER(iwp) ::  nnx_z                    !<
276    INTEGER(iwp) ::  nny_x                    !<
277    INTEGER(iwp) ::  nny_z                    !<
278    INTEGER(iwp) ::  nnz_x                    !<
279    INTEGER(iwp) ::  nnz_y                    !<
280    INTEGER(iwp) ::  numproc_sqr              !<
281    INTEGER(iwp) ::  nxl_l                    !<
282    INTEGER(iwp) ::  nxr_l                    !<
283    INTEGER(iwp) ::  nyn_l                    !<
284    INTEGER(iwp) ::  nys_l                    !<
285    INTEGER(iwp) ::  nzb_l                    !<
286    INTEGER(iwp) ::  nzt_l                    !<
287    INTEGER(iwp) ::  omp_get_num_threads      !<
288
289    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  ind_all !<
290    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nxlf    !<
291    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nxrf    !<
292    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nynf    !<
293    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nysf    !<
294
295    INTEGER(iwp), DIMENSION(2) ::  pdims_remote         !<
296    INTEGER(iwp)               ::  lcoord(2)            !< PE coordinates of left neighbor along x and y
297    INTEGER(iwp)               ::  rcoord(2)            !< PE coordinates of right neighbor along x and y
298
299!
300!-- Get the number of OpenMP threads
301    !$OMP PARALLEL
302!$  threads_per_task = omp_get_num_threads()
303    !$OMP END PARALLEL
304
305
306#if defined( __parallel )
307
308    CALL location_message( 'creating virtual PE grids + MPI derived data types', &
309                           .FALSE. )
310
311!
312!-- Determine the processor topology or check it, if prescribed by the user
313    IF ( npex == -1  .AND.  npey == -1 )  THEN
314
315!
316!--    Automatic determination of the topology
317       numproc_sqr = SQRT( REAL( numprocs, KIND=wp ) )
318       pdims(1)    = MAX( numproc_sqr , 1 )
319       DO  WHILE ( MOD( numprocs , pdims(1) ) /= 0 )
320          pdims(1) = pdims(1) - 1
321       ENDDO
322       pdims(2) = numprocs / pdims(1)
323
324    ELSEIF ( npex /= -1  .AND.  npey /= -1 )  THEN
325
326!
327!--    Prescribed by user. Number of processors on the prescribed topology
328!--    must be equal to the number of PEs available to the job
329       IF ( ( npex * npey ) /= numprocs )  THEN
330          WRITE( message_string, * ) 'number of PEs of the prescribed ',   &
331              'topology (', npex*npey,') does not match & the number of ', &
332              'PEs available to the job (', numprocs, ')'
333          CALL message( 'init_pegrid', 'PA0221', 1, 2, 0, 6, 0 )
334       ENDIF
335       pdims(1) = npex
336       pdims(2) = npey
337
338    ELSE
339!
340!--    If the processor topology is prescribed by the user, the number of
341!--    PEs must be given in both directions
342       message_string = 'if the processor topology is prescribed by th' //  &
343                'e user& both values of "npex" and "npey" must be given' // &
344                ' in the &NAMELIST-parameter file'
345       CALL message( 'init_pegrid', 'PA0222', 1, 2, 0, 6, 0 )
346
347    ENDIF
348
349!
350!-- If necessary, set horizontal boundary conditions to non-cyclic
351    IF ( bc_lr /= 'cyclic' )  cyclic(1) = .FALSE.
352    IF ( bc_ns /= 'cyclic' )  cyclic(2) = .FALSE.
353
354
355!
356!-- Create the virtual processor grid
357    CALL MPI_CART_CREATE( comm_palm, ndim, pdims, cyclic, reorder, &
358                          comm2d, ierr )
359    CALL MPI_COMM_RANK( comm2d, myid, ierr )
360    WRITE (myid_char,'(''_'',I6.6)')  myid
361
362    CALL MPI_CART_COORDS( comm2d, myid, ndim, pcoord, ierr )
363    CALL MPI_CART_SHIFT( comm2d, 0, 1, pleft, pright, ierr )
364    CALL MPI_CART_SHIFT( comm2d, 1, 1, psouth, pnorth, ierr )
365!
366!-- In case of cyclic boundary conditions, a y-shift at the boundaries in
367!-- x-direction can be introduced via parameter y_shift. The shift is done
368!-- by modifying the processor grid in such a way that processors located
369!-- at the x-boundary communicate across it to processors with y-coordinate
370!-- shifted by y_shift relative to their own. This feature can not be used
371!-- in combination with an fft pressure solver. It has been implemented to
372!-- counter the effect of streak structures in case of cyclic boundary
373!-- conditions. For a description of these see Munters
374!-- (2016; dx.doi.org/10.1063/1.4941912)
375!--
376!-- Get coordinates of left and right neighbor on PE grid
377    IF ( y_shift /= 0 ) THEN
378
379       IF ( bc_lr /= 'cyclic'  .OR.  bc_ns /= 'cyclic' )  THEN
380          message_string = 'y_shift /= 0 is only allowed for cyclic ' //       &
381                           'boundary conditions in both directions '
382          CALL message( 'check_parameters', 'PA0467', 1, 2, 0, 6, 0 )
383       ENDIF
384       IF ( TRIM( psolver ) /= 'multigrid' .AND.                               &
385            TRIM( psolver ) /= 'multigrid_noopt')                              &
386       THEN
387          message_string = 'y_shift /= 0 requires a multigrid pressure solver '
388          CALL message( 'check_parameters', 'PA0468', 1, 2, 0, 6, 0 )
389       ENDIF
390
391       CALL MPI_CART_COORDS( comm2d, pright, ndim, rcoord, ierr )
392       CALL MPI_CART_COORDS( comm2d, pleft, ndim, lcoord, ierr )
393
394!
395!--    If the x(y)-coordinate of the right (left) neighbor is smaller (greater)
396!--    than that of the calling process, then the calling process is located on
397!--    the right (left) boundary of the processor grid. In that case,
398!--    the y-coordinate of that neighbor is increased (decreased) by y_shift.
399!--    The rank of the process with that coordinate is then inquired and the
400!--    neighbor rank for MPI_SENDRECV, pright (pleft) is set to it.
401!--    In this way, the calling process receives a new right (left) neighbor
402!--    for all future MPI_SENDRECV calls. That neighbor has a y-coordinate
403!--    of y+(-)y_shift, where y is the original right (left) neighbor's
404!--    y-coordinate. The modulo-operation ensures that if the neighbor's
405!--    y-coordinate exceeds the grid-boundary, it will be relocated to
406!--    the opposite part of the grid cyclicly.
407       IF ( rcoord(1) < pcoord(1) ) THEN
408          rcoord(2) = MODULO( rcoord(2) + y_shift, pdims(2) )
409          CALL MPI_CART_RANK( comm2d, rcoord, pright, ierr )
410       ENDIF
411
412       IF ( lcoord(1) > pcoord(1) ) THEN
413          lcoord(2) = MODULO( lcoord(2) - y_shift, pdims(2) )
414          CALL MPI_CART_RANK( comm2d, lcoord, pleft, ierr )
415       ENDIF
416    ENDIF
417!
418!-- Vertical nesting: store four lists that identify partner ranks to exchange
419!-- data
420    IF ( vnested )  CALL vnest_init_pegrid_rank
421
422!
423!-- Determine sub-topologies for transpositions
424!-- Transposition from z to x:
425    remain_dims(1) = .TRUE.
426    remain_dims(2) = .FALSE.
427    CALL MPI_CART_SUB( comm2d, remain_dims, comm1dx, ierr )
428    CALL MPI_COMM_RANK( comm1dx, myidx, ierr )
429!
430!-- Transposition from x to y
431    remain_dims(1) = .FALSE.
432    remain_dims(2) = .TRUE.
433    CALL MPI_CART_SUB( comm2d, remain_dims, comm1dy, ierr )
434    CALL MPI_COMM_RANK( comm1dy, myidy, ierr )
435
436
437!
438!-- Calculate array bounds along x-direction for every PE.
439    ALLOCATE( nxlf(0:pdims(1)-1), nxrf(0:pdims(1)-1), nynf(0:pdims(2)-1), &
440              nysf(0:pdims(2)-1) )
441
442    IF ( MOD( nx+1 , pdims(1) ) /= 0 )  THEN
443       WRITE( message_string, * ) 'x-direction: gridpoint number (',nx+1,') ',&
444                               'is not an& integral divisor of the number ',  &
445                               'processors (', pdims(1),')'
446       CALL message( 'init_pegrid', 'PA0225', 1, 2, 0, 6, 0 )
447    ELSE
448       nnx  = ( nx + 1 ) / pdims(1)
449       IF ( nnx*pdims(1) - ( nx + 1) > nnx )  THEN
450          WRITE( message_string, * ) 'x-direction: nx does not match the',    & 
451                       'requirements given by the number of PEs &used',       &
452                       '& please use nx = ', nx - ( pdims(1) - ( nnx*pdims(1) &
453                                      - ( nx + 1 ) ) ), ' instead of nx =', nx
454          CALL message( 'init_pegrid', 'PA0226', 1, 2, 0, 6, 0 )
455       ENDIF
456    ENDIF   
457
458!
459!-- Left and right array bounds, number of gridpoints
460    DO  i = 0, pdims(1)-1
461       nxlf(i)   = i * nnx
462       nxrf(i)   = ( i + 1 ) * nnx - 1
463    ENDDO
464
465!
466!-- Calculate array bounds in y-direction for every PE.
467    IF ( MOD( ny+1 , pdims(2) ) /= 0 )  THEN
468       WRITE( message_string, * ) 'y-direction: gridpoint number (',ny+1,') ', &
469                           'is not an& integral divisor of the number of',     &
470                           'processors (', pdims(2),')'
471       CALL message( 'init_pegrid', 'PA0227', 1, 2, 0, 6, 0 )
472    ELSE
473       nny  = ( ny + 1 ) / pdims(2)
474       IF ( nny*pdims(2) - ( ny + 1) > nny )  THEN
475          WRITE( message_string, * ) 'y-direction: ny does not match the',    &
476                       'requirements given by the number of PEs &used ',      &
477                       '& please use ny = ', ny - ( pdims(2) - ( nnx*pdims(2) &
478                                     - ( ny + 1 ) ) ), ' instead of ny =', ny
479          CALL message( 'init_pegrid', 'PA0228', 1, 2, 0, 6, 0 )
480       ENDIF
481    ENDIF   
482
483!
484!-- South and north array bounds
485    DO  j = 0, pdims(2)-1
486       nysf(j)   = j * nny
487       nynf(j)   = ( j + 1 ) * nny - 1
488    ENDDO
489
490!
491!-- Local array bounds of the respective PEs
492    nxl = nxlf(pcoord(1))
493    nxr = nxrf(pcoord(1))
494    nys = nysf(pcoord(2))
495    nyn = nynf(pcoord(2))
496    nzb = 0
497    nzt = nz
498    nnz = nz
499
500!
501!-- Set switches to define if the PE is situated at the border of the virtual
502!-- processor grid
503    IF ( nxl == 0 )   left_border_pe  = .TRUE.
504    IF ( nxr == nx )  right_border_pe = .TRUE.
505    IF ( nys == 0 )   south_border_pe = .TRUE.
506    IF ( nyn == ny )  north_border_pe = .TRUE.
507
508!
509!-- Calculate array bounds and gridpoint numbers for the transposed arrays
510!-- (needed in the pressure solver)
511!-- For the transposed arrays, cyclic boundaries as well as top and bottom
512!-- boundaries are omitted, because they are obstructive to the transposition
513
514!
515!-- 1. transposition  z --> x
516!-- This transposition is not neccessary in case of a 1d-decomposition along x
517    IF ( psolver == 'poisfft'  .OR.  calculate_spectra  .OR.                   &
518         use_synthetic_turbulence_generator )  THEN
519
520       IF ( pdims(2) /= 1 )  THEN
521          IF ( MOD( nz , pdims(1) ) /= 0 )  THEN
522             WRITE( message_string, * ) 'transposition z --> x:',              &
523                       '&nz=',nz,' is not an integral divisior of pdims(1)=',  &
524                                                                   pdims(1)
525             CALL message( 'init_pegrid', 'PA0230', 1, 2, 0, 6, 0 )
526          ENDIF
527       ENDIF
528
529       nys_x = nys
530       nyn_x = nyn
531       nny_x = nny
532       nnz_x = nz / pdims(1)
533       nzb_x = 1 + myidx * nnz_x
534       nzt_x = ( myidx + 1 ) * nnz_x
535       sendrecvcount_zx = nnx * nny * nnz_x
536
537    ENDIF
538
539
540    IF ( psolver == 'poisfft' )  THEN 
541!
542!--    2. transposition  x --> y
543       IF ( MOD( nx+1 , pdims(2) ) /= 0 )  THEN
544          WRITE( message_string, * ) 'transposition x --> y:',                 &
545                            '&nx+1=',nx+1,' is not an integral divisor of ',   &
546                            'pdims(2)=',pdims(2)
547          CALL message( 'init_pegrid', 'PA0231', 1, 2, 0, 6, 0 )
548       ENDIF
549
550       nnz_y = nnz_x
551       nzb_y = nzb_x
552       nzt_y = nzt_x
553       nnx_y = (nx+1) / pdims(2)
554       nxl_y = myidy * nnx_y
555       nxr_y = ( myidy + 1 ) * nnx_y - 1
556       sendrecvcount_xy = nnx_y * nny_x * nnz_y
557!
558!--    3. transposition  y --> z 
559!--    (ELSE:  x --> y  in case of 1D-decomposition along x)
560       nxl_z = nxl_y
561       nxr_z = nxr_y
562       nny_z = (ny+1) / pdims(1)
563       nys_z = myidx * nny_z
564       nyn_z = ( myidx + 1 ) * nny_z - 1
565       sendrecvcount_yz = nnx_y * nny_z * nnz_y
566
567       IF ( pdims(2) /= 1 )  THEN
568!
569!--       y --> z
570!--       This transposition is not neccessary in case of a 1d-decomposition
571!--       along x, except that the uptream-spline method is switched on
572          IF ( MOD( ny+1 , pdims(1) ) /= 0 )  THEN
573             WRITE( message_string, * ) 'transposition y --> z:',              &
574                               '& ny+1=',ny+1,' is not an integral divisor of',&
575                               ' pdims(1)=',pdims(1)
576             CALL message( 'init_pegrid', 'PA0232', 1, 2, 0, 6, 0 )
577          ENDIF
578
579       ELSE
580!
581!--       x --> y
582!--       This condition must be fulfilled for a 1D-decomposition along x
583          IF ( MOD( ny+1 , pdims(1) ) /= 0 )  THEN
584             WRITE( message_string, * ) 'transposition x --> y:',              &
585                               '& ny+1=',ny+1,' is not an integral divisor of',&
586                               ' pdims(1)=',pdims(1)
587             CALL message( 'init_pegrid', 'PA0233', 1, 2, 0, 6, 0 )
588          ENDIF
589
590       ENDIF
591
592    ENDIF
593
594!
595!-- Indices for direct transpositions z --> y (used for calculating spectra)
596    IF ( calculate_spectra )  THEN
597       IF ( MOD( nz, pdims(2) ) /= 0 )  THEN
598          WRITE( message_string, * ) 'direct transposition z --> y (needed ',  &
599                    'for spectra):& nz=',nz,' is not an integral divisor of ', &
600                    'pdims(2)=',pdims(2)
601          CALL message( 'init_pegrid', 'PA0234', 1, 2, 0, 6, 0 )
602       ELSE
603          nxl_yd = nxl
604          nxr_yd = nxr
605          nzb_yd = 1 + myidy * ( nz / pdims(2) )
606          nzt_yd = ( myidy + 1 ) * ( nz / pdims(2) )
607          sendrecvcount_zyd = nnx * nny * ( nz / pdims(2) )
608       ENDIF
609    ENDIF
610
611    IF ( psolver == 'poisfft'  .OR.  calculate_spectra )  THEN
612!
613!--    Indices for direct transpositions y --> x
614!--    (they are only possible in case of a 1d-decomposition along x)
615       IF ( pdims(2) == 1 )  THEN
616          nny_x = nny / pdims(1)
617          nys_x = myid * nny_x
618          nyn_x = ( myid + 1 ) * nny_x - 1
619          nzb_x = 1
620          nzt_x = nz
621          sendrecvcount_xy = nnx * nny_x * nz
622       ENDIF
623
624    ENDIF
625
626    IF ( psolver == 'poisfft' )  THEN
627!
628!--    Indices for direct transpositions x --> y
629!--    (they are only possible in case of a 1d-decomposition along y)
630       IF ( pdims(1) == 1 )  THEN
631          nnx_y = nnx / pdims(2)
632          nxl_y = myid * nnx_y
633          nxr_y = ( myid + 1 ) * nnx_y - 1
634          nzb_y = 1
635          nzt_y = nz
636          sendrecvcount_xy = nnx_y * nny * nz
637       ENDIF
638
639    ENDIF
640
641!
642!-- Arrays for storing the array bounds are needed any more
643    DEALLOCATE( nxlf , nxrf , nynf , nysf )
644
645
646!
647!-- Collect index bounds from other PEs (to be written to restart file later)
648    ALLOCATE( hor_index_bounds(4,0:numprocs-1) )
649
650    IF ( myid == 0 )  THEN
651
652       hor_index_bounds(1,0) = nxl
653       hor_index_bounds(2,0) = nxr
654       hor_index_bounds(3,0) = nys
655       hor_index_bounds(4,0) = nyn
656
657!
658!--    Receive data from all other PEs
659       DO  i = 1, numprocs-1
660          CALL MPI_RECV( ibuf, 4, MPI_INTEGER, i, MPI_ANY_TAG, comm2d, status, &
661                         ierr )
662          hor_index_bounds(:,i) = ibuf(1:4)
663       ENDDO
664
665    ELSE
666!
667!--    Send index bounds to PE0
668       ibuf(1) = nxl
669       ibuf(2) = nxr
670       ibuf(3) = nys
671       ibuf(4) = nyn
672       CALL MPI_SEND( ibuf, 4, MPI_INTEGER, 0, myid, comm2d, ierr )
673
674    ENDIF
675
676
677#if defined( __print )
678!
679!-- Control output
680    IF ( myid == 0 )  THEN
681       PRINT*, '*** processor topology ***'
682       PRINT*, ' '
683       PRINT*, 'myid   pcoord    left right  south north  idx idy   nxl: nxr',&
684               &'   nys: nyn'
685       PRINT*, '------------------------------------------------------------',&
686               &'-----------'
687       WRITE (*,1000)  0, pcoord(1), pcoord(2), pleft, pright, psouth, pnorth, &
688                       myidx, myidy, nxl, nxr, nys, nyn
6891000   FORMAT (I4,2X,'(',I3,',',I3,')',3X,I4,2X,I4,3X,I4,2X,I4,2X,I3,1X,I3, &
690               2(2X,I4,':',I4))
691
692!
693!--    Receive data from the other PEs
694       DO  i = 1,numprocs-1
695          CALL MPI_RECV( ibuf, 12, MPI_INTEGER, i, MPI_ANY_TAG, comm2d, status, &
696                         ierr )
697          WRITE (*,1000)  i, ( ibuf(j) , j = 1,12 )
698       ENDDO
699    ELSE
700
701!
702!--    Send data to PE0
703       ibuf(1) = pcoord(1); ibuf(2) = pcoord(2); ibuf(3) = pleft
704       ibuf(4) = pright; ibuf(5) = psouth; ibuf(6) = pnorth; ibuf(7) = myidx
705       ibuf(8) = myidy; ibuf(9) = nxl; ibuf(10) = nxr; ibuf(11) = nys
706       ibuf(12) = nyn
707       CALL MPI_SEND( ibuf, 12, MPI_INTEGER, 0, myid, comm2d, ierr )       
708    ENDIF
709#endif
710
711!
712!-- Determine the number of ghost point layers
713    IF ( ( scalar_advec == 'ws-scheme' .AND. .NOT. neutral ) .OR.             &
714         momentum_advec == 'ws-scheme' )  THEN
715       nbgp = 3
716    ELSE
717       nbgp = 1
718    ENDIF 
719
720!
721!-- Create a new MPI derived datatype for the exchange of surface (xy) data,
722!-- which is needed for coupled atmosphere-ocean runs.
723!-- First, calculate number of grid points of an xy-plane.
724    ngp_xy  = ( nxr - nxl + 1 + 2 * nbgp ) * ( nyn - nys + 1 + 2 * nbgp )
725    CALL MPI_TYPE_VECTOR( ngp_xy, 1, nzt-nzb+2, MPI_REAL, type_xy, ierr )
726    CALL MPI_TYPE_COMMIT( type_xy, ierr )
727
728    IF ( TRIM( coupling_mode ) /= 'uncoupled' .AND. .NOT. vnested )  THEN
729   
730!
731!--    Pass the number of grid points of the atmosphere model to
732!--    the ocean model and vice versa
733       IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
734
735          nx_a = nx
736          ny_a = ny
737
738          IF ( myid == 0 )  THEN
739
740             CALL MPI_SEND( nx_a, 1, MPI_INTEGER, numprocs, 1, comm_inter,  &
741                            ierr )
742             CALL MPI_SEND( ny_a, 1, MPI_INTEGER, numprocs, 2, comm_inter,  &
743                            ierr )
744             CALL MPI_SEND( pdims, 2, MPI_INTEGER, numprocs, 3, comm_inter, &
745                            ierr )
746             CALL MPI_RECV( nx_o, 1, MPI_INTEGER, numprocs, 4, comm_inter,  &
747                            status, ierr )
748             CALL MPI_RECV( ny_o, 1, MPI_INTEGER, numprocs, 5, comm_inter,  &
749                            status, ierr )
750             CALL MPI_RECV( pdims_remote, 2, MPI_INTEGER, numprocs, 6,      &
751                            comm_inter, status, ierr )
752          ENDIF
753
754          CALL MPI_BCAST( nx_o, 1, MPI_INTEGER, 0, comm2d, ierr )
755          CALL MPI_BCAST( ny_o, 1, MPI_INTEGER, 0, comm2d, ierr ) 
756          CALL MPI_BCAST( pdims_remote, 2, MPI_INTEGER, 0, comm2d, ierr )
757       
758       ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
759
760          nx_o = nx
761          ny_o = ny 
762
763          IF ( myid == 0 ) THEN
764
765             CALL MPI_RECV( nx_a, 1, MPI_INTEGER, 0, 1, comm_inter, status, &
766                            ierr )
767             CALL MPI_RECV( ny_a, 1, MPI_INTEGER, 0, 2, comm_inter, status, &
768                            ierr )
769             CALL MPI_RECV( pdims_remote, 2, MPI_INTEGER, 0, 3, comm_inter, &
770                            status, ierr )
771             CALL MPI_SEND( nx_o, 1, MPI_INTEGER, 0, 4, comm_inter, ierr )
772             CALL MPI_SEND( ny_o, 1, MPI_INTEGER, 0, 5, comm_inter, ierr )
773             CALL MPI_SEND( pdims, 2, MPI_INTEGER, 0, 6, comm_inter, ierr )
774          ENDIF
775
776          CALL MPI_BCAST( nx_a, 1, MPI_INTEGER, 0, comm2d, ierr)
777          CALL MPI_BCAST( ny_a, 1, MPI_INTEGER, 0, comm2d, ierr) 
778          CALL MPI_BCAST( pdims_remote, 2, MPI_INTEGER, 0, comm2d, ierr) 
779
780       ENDIF
781 
782       ngp_a = ( nx_a+1 + 2 * nbgp ) * ( ny_a+1 + 2 * nbgp )
783       ngp_o = ( nx_o+1 + 2 * nbgp ) * ( ny_o+1 + 2 * nbgp )
784
785!
786!--    Determine if the horizontal grid and the number of PEs in ocean and
787!--    atmosphere is same or not
788       IF ( nx_o == nx_a  .AND.  ny_o == ny_a  .AND.  &
789            pdims(1) == pdims_remote(1) .AND. pdims(2) == pdims_remote(2) ) &
790       THEN
791          coupling_topology = 0
792       ELSE
793          coupling_topology = 1
794       ENDIF 
795
796!
797!--    Determine the target PEs for the exchange between ocean and
798!--    atmosphere (comm2d)
799       IF ( coupling_topology == 0 )  THEN
800!
801!--       In case of identical topologies, every atmosphere PE has exactly one
802!--       ocean PE counterpart and vice versa
803          IF ( TRIM( coupling_mode ) == 'atmosphere_to_ocean' ) THEN
804             target_id = myid + numprocs
805          ELSE
806             target_id = myid 
807          ENDIF
808
809       ELSE
810!
811!--       In case of nonequivalent topology in ocean and atmosphere only for
812!--       PE0 in ocean and PE0 in atmosphere a target_id is needed, since
813!--       data echxchange between ocean and atmosphere will be done only
814!--       between these PEs.   
815          IF ( myid == 0 )  THEN
816
817             IF ( TRIM( coupling_mode ) == 'atmosphere_to_ocean' )  THEN
818                target_id = numprocs 
819             ELSE
820                target_id = 0
821             ENDIF
822
823          ENDIF
824
825       ENDIF
826
827    ENDIF
828
829!
830!-- Store partner grid point co-ordinates as lists.
831!-- Create custom MPI vector datatypes for contiguous data transfer
832    IF ( vnested )  CALL vnest_init_pegrid_domain
833
834#else
835
836!
837!-- Array bounds when running on a single PE (respectively a non-parallel
838!-- machine)
839    nxl = 0
840    nxr = nx
841    nnx = nxr - nxl + 1
842    nys = 0
843    nyn = ny
844    nny = nyn - nys + 1
845    nzb = 0
846    nzt = nz
847    nnz = nz
848
849    ALLOCATE( hor_index_bounds(4,0:0) )
850    hor_index_bounds(1,0) = nxl
851    hor_index_bounds(2,0) = nxr
852    hor_index_bounds(3,0) = nys
853    hor_index_bounds(4,0) = nyn
854
855!
856!-- Array bounds for the pressure solver (in the parallel code, these bounds
857!-- are the ones for the transposed arrays)
858    nys_x = nys
859    nyn_x = nyn
860    nzb_x = nzb + 1
861    nzt_x = nzt
862
863    nxl_y = nxl
864    nxr_y = nxr
865    nzb_y = nzb + 1
866    nzt_y = nzt
867
868    nxl_z = nxl
869    nxr_z = nxr
870    nys_z = nys
871    nyn_z = nyn
872
873#endif
874
875!
876!-- Calculate number of grid levels necessary for the multigrid poisson solver
877!-- as well as the gridpoint indices on each level
878    IF ( psolver(1:9) == 'multigrid' )  THEN
879
880!
881!--    First calculate number of possible grid levels for the subdomains
882       mg_levels_x = 1
883       mg_levels_y = 1
884       mg_levels_z = 1
885
886       i = nnx
887       DO WHILE ( MOD( i, 2 ) == 0  .AND.  i /= 2 )
888          i = i / 2
889          mg_levels_x = mg_levels_x + 1
890       ENDDO
891
892       j = nny
893       DO WHILE ( MOD( j, 2 ) == 0  .AND.  j /= 2 )
894          j = j / 2
895          mg_levels_y = mg_levels_y + 1
896       ENDDO
897
898       k = nz    ! do not use nnz because it might be > nz due to transposition
899                 ! requirements
900       DO WHILE ( MOD( k, 2 ) == 0  .AND.  k /= 2 )
901          k = k / 2
902          mg_levels_z = mg_levels_z + 1
903       ENDDO
904!
905!--    The optimized MG-solver does not allow odd values for nz at the coarsest
906!--    grid level
907       IF ( TRIM( psolver ) /= 'multigrid_noopt' )  THEN
908          IF ( MOD( k, 2 ) /= 0 )  mg_levels_z = mg_levels_z - 1
909       ENDIF
910
911       maximum_grid_level = MIN( mg_levels_x, mg_levels_y, mg_levels_z )
912
913!
914!--    Find out, if the total domain allows more levels. These additional
915!--    levels are identically processed on all PEs.
916       IF ( numprocs > 1  .AND.  mg_switch_to_pe0_level /= -1 )  THEN
917
918          IF ( mg_levels_z > MIN( mg_levels_x, mg_levels_y ) )  THEN
919
920             mg_switch_to_pe0_level_l = maximum_grid_level
921
922             mg_levels_x = 1
923             mg_levels_y = 1
924
925             i = nx+1
926             DO WHILE ( MOD( i, 2 ) == 0  .AND.  i /= 2 )
927                i = i / 2
928                mg_levels_x = mg_levels_x + 1
929             ENDDO
930
931             j = ny+1
932             DO WHILE ( MOD( j, 2 ) == 0  .AND.  j /= 2 )
933                j = j / 2
934                mg_levels_y = mg_levels_y + 1
935             ENDDO
936
937             maximum_grid_level_l = MIN( mg_levels_x, mg_levels_y, mg_levels_z )
938
939             IF ( maximum_grid_level_l > mg_switch_to_pe0_level_l )  THEN
940                mg_switch_to_pe0_level_l = maximum_grid_level_l - &
941                                           mg_switch_to_pe0_level_l + 1
942             ELSE
943                mg_switch_to_pe0_level_l = 0
944             ENDIF
945
946          ELSE
947             mg_switch_to_pe0_level_l = 0
948             maximum_grid_level_l = maximum_grid_level
949
950          ENDIF
951
952!
953!--       Use switch level calculated above only if it is not pre-defined
954!--       by user
955          IF ( mg_switch_to_pe0_level == 0 )  THEN
956             IF ( mg_switch_to_pe0_level_l /= 0 )  THEN
957                mg_switch_to_pe0_level = mg_switch_to_pe0_level_l
958                maximum_grid_level     = maximum_grid_level_l
959             ENDIF
960
961          ELSE
962!
963!--          Check pre-defined value and reset to default, if neccessary
964             IF ( mg_switch_to_pe0_level < mg_switch_to_pe0_level_l  .OR.  &
965                  mg_switch_to_pe0_level >= maximum_grid_level_l )  THEN
966                message_string = 'mg_switch_to_pe0_level ' // &
967                                 'out of range and reset to 0'
968                CALL message( 'init_pegrid', 'PA0235', 0, 1, 0, 6, 0 )
969                mg_switch_to_pe0_level = 0
970             ELSE
971!
972!--             Use the largest number of possible levels anyway and recalculate
973!--             the switch level to this largest number of possible values
974                maximum_grid_level = maximum_grid_level_l
975
976             ENDIF
977
978          ENDIF
979
980       ENDIF
981
982       ALLOCATE( grid_level_count(maximum_grid_level),                       &
983                 nxl_mg(0:maximum_grid_level), nxr_mg(0:maximum_grid_level), &
984                 nyn_mg(0:maximum_grid_level), nys_mg(0:maximum_grid_level), &
985                 nzt_mg(0:maximum_grid_level) )
986
987       grid_level_count = 0
988!
989!--    Index zero required as dummy due to definition of arrays f2 and p2 in
990!--    recursive subroutine next_mg_level
991       nxl_mg(0) = 0; nxr_mg(0) = 0; nyn_mg(0) = 0; nys_mg(0) = 0; nzt_mg(0) = 0
992
993       nxl_l = nxl; nxr_l = nxr; nys_l = nys; nyn_l = nyn; nzt_l = nzt
994
995       DO  i = maximum_grid_level, 1 , -1
996
997          IF ( i == mg_switch_to_pe0_level )  THEN
998#if defined( __parallel )
999!
1000!--          Save the grid size of the subdomain at the switch level, because
1001!--          it is needed in poismg.
1002             ind(1) = nxl_l; ind(2) = nxr_l
1003             ind(3) = nys_l; ind(4) = nyn_l
1004             ind(5) = nzt_l
1005             ALLOCATE( ind_all(5*numprocs), mg_loc_ind(5,0:numprocs-1) )
1006             CALL MPI_ALLGATHER( ind, 5, MPI_INTEGER, ind_all, 5, &
1007                                 MPI_INTEGER, comm2d, ierr )
1008             DO  j = 0, numprocs-1
1009                DO  k = 1, 5
1010                   mg_loc_ind(k,j) = ind_all(k+j*5)
1011                ENDDO
1012             ENDDO
1013             DEALLOCATE( ind_all )
1014!
1015!--          Calculate the grid size of the total domain
1016             nxr_l = ( nxr_l-nxl_l+1 ) * pdims(1) - 1
1017             nxl_l = 0
1018             nyn_l = ( nyn_l-nys_l+1 ) * pdims(2) - 1
1019             nys_l = 0
1020!
1021!--          The size of this gathered array must not be larger than the
1022!--          array tend, which is used in the multigrid scheme as a temporary
1023!--          array. Therefore the subdomain size of an PE is calculated and
1024!--          the size of the gathered grid. These values are used in 
1025!--          routines pres and poismg
1026             subdomain_size = ( nxr - nxl + 2 * nbgp + 1 ) * &
1027                              ( nyn - nys + 2 * nbgp + 1 ) * ( nzt - nzb + 2 )
1028             gathered_size  = ( nxr_l - nxl_l + 3 ) * ( nyn_l - nys_l + 3 ) * &
1029                              ( nzt_l - nzb + 2 )
1030
1031#else
1032             message_string = 'multigrid gather/scatter impossible ' // &
1033                          'in non parallel mode'
1034             CALL message( 'init_pegrid', 'PA0237', 1, 2, 0, 6, 0 )
1035#endif
1036          ENDIF
1037
1038          nxl_mg(i) = nxl_l
1039          nxr_mg(i) = nxr_l
1040          nys_mg(i) = nys_l
1041          nyn_mg(i) = nyn_l
1042          nzt_mg(i) = nzt_l
1043
1044          nxl_l = nxl_l / 2 
1045          nxr_l = nxr_l / 2
1046          nys_l = nys_l / 2 
1047          nyn_l = nyn_l / 2 
1048          nzt_l = nzt_l / 2 
1049
1050       ENDDO
1051
1052!
1053!--    Temporary problem: Currently calculation of maxerror iin routine poismg crashes
1054!--    if grid data are collected on PE0 already on the finest grid level.
1055!--    To be solved later.
1056       IF ( maximum_grid_level == mg_switch_to_pe0_level )  THEN
1057          message_string = 'grid coarsening on subdomain level cannot be performed'
1058          CALL message( 'poismg', 'PA0236', 1, 2, 0, 6, 0 )
1059       ENDIF
1060
1061    ELSE
1062
1063       maximum_grid_level = 0
1064
1065    ENDIF
1066
1067!
1068!-- Default level 0 tells exchange_horiz that all ghost planes have to be
1069!-- exchanged. grid_level is adjusted in poismg, where only one ghost plane
1070!-- is required.
1071    grid_level = 0
1072
1073#if defined( __parallel )
1074!
1075!-- Gridpoint number for the exchange of ghost points (y-line for 2D-arrays)
1076    ngp_y  = nyn - nys + 1 + 2 * nbgp
1077
1078!
1079!-- Define new MPI derived datatypes for the exchange of ghost points in
1080!-- x- and y-direction for 2D-arrays (line)
1081    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp, ngp_y, MPI_REAL, type_x,     &
1082                          ierr )
1083    CALL MPI_TYPE_COMMIT( type_x, ierr )
1084
1085    CALL MPI_TYPE_VECTOR( nbgp, ngp_y, ngp_y, MPI_REAL, type_y, ierr )
1086    CALL MPI_TYPE_COMMIT( type_y, ierr )
1087!
1088!-- Define new MPI derived datatypes for the exchange of ghost points in
1089!-- x- and y-direction for 2D-INTEGER arrays (line) - on normal grid
1090    ALLOCATE( type_x_int(0:maximum_grid_level),                                &
1091              type_y_int(0:maximum_grid_level) )
1092
1093    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp, ngp_y, MPI_INTEGER,          &
1094                          type_x_int(0), ierr )
1095    CALL MPI_TYPE_COMMIT( type_x_int(0), ierr )
1096
1097    CALL MPI_TYPE_VECTOR( nbgp, ngp_y, ngp_y, MPI_INTEGER, type_y_int(0), ierr )
1098    CALL MPI_TYPE_COMMIT( type_y_int(0), ierr )
1099!
1100!-- Calculate gridpoint numbers for the exchange of ghost points along x
1101!-- (yz-plane for 3D-arrays) and define MPI derived data type(s) for the
1102!-- exchange of ghost points in y-direction (xz-plane).
1103!-- Do these calculations for the model grid and (if necessary) also
1104!-- for the coarser grid levels used in the multigrid method
1105    ALLOCATE ( ngp_xz(0:maximum_grid_level),                                   &
1106               ngp_xz_int(0:maximum_grid_level),                               &
1107               ngp_yz(0:maximum_grid_level),                                   &
1108               ngp_yz_int(0:maximum_grid_level),                               &
1109               type_xz(0:maximum_grid_level),                                  &
1110               type_xz_int(0:maximum_grid_level),                              &
1111               type_yz(0:maximum_grid_level),                                  &
1112               type_yz_int(0:maximum_grid_level) )
1113
1114    nxl_l = nxl; nxr_l = nxr; nys_l = nys; nyn_l = nyn; nzb_l = nzb; nzt_l = nzt
1115
1116!
1117!-- Discern between the model grid, which needs nbgp ghost points and
1118!-- grid levels for the multigrid scheme. In the latter case only one
1119!-- ghost point is necessary.
1120!-- First definition of MPI-datatypes for exchange of ghost layers on normal
1121!-- grid. The following loop is needed for data exchange in poismg.f90.
1122!
1123!-- Determine number of grid points of yz-layer for exchange
1124    ngp_yz(0) = (nzt - nzb + 2) * (nyn - nys + 1 + 2 * nbgp)
1125
1126!
1127!-- Define an MPI-datatype for the exchange of left/right boundaries.
1128!-- Although data are contiguous in physical memory (which does not
1129!-- necessarily require an MPI-derived datatype), the data exchange between
1130!-- left and right PE's using the MPI-derived type is 10% faster than without.
1131    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp*(nzt-nzb+2), ngp_yz(0), &
1132                          MPI_REAL, type_xz(0), ierr )
1133    CALL MPI_TYPE_COMMIT( type_xz(0), ierr )
1134
1135    CALL MPI_TYPE_VECTOR( nbgp, ngp_yz(0), ngp_yz(0), MPI_REAL, type_yz(0), &
1136                          ierr ) 
1137    CALL MPI_TYPE_COMMIT( type_yz(0), ierr )
1138
1139!
1140!-- Define data types for exchange of 3D Integer arrays.
1141    ngp_yz_int(0) = (nzt - nzb + 2) * (nyn - nys + 1 + 2 * nbgp)
1142
1143    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp*(nzt-nzb+2), ngp_yz_int(0),   &
1144                          MPI_INTEGER, type_xz_int(0), ierr )
1145    CALL MPI_TYPE_COMMIT( type_xz_int(0), ierr )
1146
1147    CALL MPI_TYPE_VECTOR( nbgp, ngp_yz_int(0), ngp_yz_int(0), MPI_INTEGER,     &
1148                          type_yz_int(0), ierr )
1149    CALL MPI_TYPE_COMMIT( type_yz_int(0), ierr )
1150
1151!
1152!-- Definition of MPI-datatypes for multigrid method (coarser level grids)
1153    IF ( psolver(1:9) == 'multigrid' )  THEN
1154!   
1155!--    Definition of MPI-datatyoe as above, but only 1 ghost level is used
1156       DO  i = maximum_grid_level, 1 , -1
1157!
1158!--       For 3D-exchange on different multigrid level, one ghost point for
1159!--       REAL arrays, two ghost points for INTEGER arrays
1160          ngp_xz(i) = (nzt_l - nzb_l + 2) * (nxr_l - nxl_l + 3)
1161          ngp_yz(i) = (nzt_l - nzb_l + 2) * (nyn_l - nys_l + 3)
1162
1163          ngp_xz_int(i) = (nzt_l - nzb_l + 2) * (nxr_l - nxl_l + 3)
1164          ngp_yz_int(i) = (nzt_l - nzb_l + 2) * (nyn_l - nys_l + 3)
1165!
1166!--       MPI data type for REAL arrays, for xz-layers
1167          CALL MPI_TYPE_VECTOR( nxr_l-nxl_l+3, nzt_l-nzb_l+2, ngp_yz(i),       &
1168                                MPI_REAL, type_xz(i), ierr )
1169          CALL MPI_TYPE_COMMIT( type_xz(i), ierr )
1170
1171!
1172!--       MPI data type for INTEGER arrays, for xz-layers
1173          CALL MPI_TYPE_VECTOR( nxr_l-nxl_l+3, nzt_l-nzb_l+2, ngp_yz_int(i),   &
1174                                MPI_INTEGER, type_xz_int(i), ierr )
1175          CALL MPI_TYPE_COMMIT( type_xz_int(i), ierr )
1176
1177!
1178!--       MPI data type for REAL arrays, for yz-layers
1179          CALL MPI_TYPE_VECTOR( 1, ngp_yz(i), ngp_yz(i), MPI_REAL, type_yz(i), &
1180                                ierr )
1181          CALL MPI_TYPE_COMMIT( type_yz(i), ierr )
1182!
1183!--       MPI data type for INTEGER arrays, for yz-layers
1184          CALL MPI_TYPE_VECTOR( 1, ngp_yz_int(i), ngp_yz_int(i), MPI_INTEGER,  &
1185                                type_yz_int(i), ierr )
1186          CALL MPI_TYPE_COMMIT( type_yz_int(i), ierr )
1187
1188
1189!--       For 2D-exchange of INTEGER arrays on coarser grid level, where 2 ghost
1190!--       points need to be exchanged.
1191          CALL MPI_TYPE_VECTOR( nxr_l-nxl_l+5, 2, nyn_l-nys_l+5, MPI_INTEGER,          &
1192                                type_x_int(i), ierr )
1193          CALL MPI_TYPE_COMMIT( type_x_int(i), ierr )
1194
1195
1196          CALL MPI_TYPE_VECTOR( 2, nyn_l-nys_l+5, nyn_l-nys_l+5, MPI_INTEGER,          &
1197                                type_y_int(i), ierr )
1198          CALL MPI_TYPE_COMMIT( type_y_int(i), ierr )
1199
1200          nxl_l = nxl_l / 2
1201          nxr_l = nxr_l / 2
1202          nys_l = nys_l / 2
1203          nyn_l = nyn_l / 2
1204          nzt_l = nzt_l / 2
1205
1206       ENDDO
1207
1208    ENDIF
1209
1210#endif
1211
1212#if defined( __parallel )
1213!
1214!-- Setting of flags for inflow/outflow/nesting conditions.
1215    IF ( pleft == MPI_PROC_NULL )  THEN
1216       IF ( bc_lr == 'dirichlet/radiation' )  THEN
1217          inflow_l  = .TRUE.
1218       ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1219          outflow_l = .TRUE.
1220       ELSEIF ( bc_lr == 'nested' )  THEN
1221          nest_bound_l = .TRUE.
1222       ELSEIF ( bc_lr == 'forcing' )  THEN
1223          force_bound_l = .TRUE.
1224       ENDIF
1225    ENDIF
1226 
1227    IF ( pright == MPI_PROC_NULL )  THEN
1228       IF ( bc_lr == 'dirichlet/radiation' )  THEN
1229          outflow_r = .TRUE.
1230       ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1231          inflow_r  = .TRUE.
1232       ELSEIF ( bc_lr == 'nested' )  THEN
1233          nest_bound_r = .TRUE.
1234       ELSEIF ( bc_lr == 'forcing' )  THEN
1235          force_bound_r = .TRUE.
1236       ENDIF
1237    ENDIF
1238
1239    IF ( psouth == MPI_PROC_NULL )  THEN
1240       IF ( bc_ns == 'dirichlet/radiation' )  THEN
1241          outflow_s = .TRUE.
1242       ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1243          inflow_s  = .TRUE.
1244       ELSEIF ( bc_ns == 'nested' )  THEN
1245          nest_bound_s = .TRUE.
1246       ELSEIF ( bc_ns == 'forcing' )  THEN
1247          force_bound_s = .TRUE.
1248       ENDIF
1249    ENDIF
1250
1251    IF ( pnorth == MPI_PROC_NULL )  THEN
1252       IF ( bc_ns == 'dirichlet/radiation' )  THEN
1253          inflow_n  = .TRUE.
1254       ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1255          outflow_n = .TRUE.
1256       ELSEIF ( bc_ns == 'nested' )  THEN
1257          nest_bound_n = .TRUE.
1258       ELSEIF ( bc_ns == 'forcing' )  THEN
1259          force_bound_n = .TRUE.
1260       ENDIF
1261    ENDIF
1262
1263!
1264!-- Broadcast the id of the inflow PE
1265    IF ( inflow_l )  THEN
1266       id_inflow_l = myidx
1267    ELSE
1268       id_inflow_l = 0
1269    ENDIF
1270    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1271    CALL MPI_ALLREDUCE( id_inflow_l, id_inflow, 1, MPI_INTEGER, MPI_SUM, &
1272                        comm1dx, ierr )
1273
1274!
1275!-- Broadcast the id of the recycling plane
1276!-- WARNING: needs to be adjusted in case of inflows other than from left side!
1277    IF ( NINT( recycling_width / dx ) >= nxl  .AND. &
1278         NINT( recycling_width / dx ) <= nxr )  THEN
1279       id_recycling_l = myidx
1280    ELSE
1281       id_recycling_l = 0
1282    ENDIF
1283    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1284    CALL MPI_ALLREDUCE( id_recycling_l, id_recycling, 1, MPI_INTEGER, MPI_SUM, &
1285                        comm1dx, ierr )
1286
1287!
1288!-- Broadcast the id of the outflow PE and outflow-source plane
1289    IF ( turbulent_outflow )  THEN
1290
1291       IF ( outflow_r )  THEN
1292          id_outflow_l = myidx
1293       ELSE
1294          id_outflow_l = 0
1295       ENDIF
1296       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1297       CALL MPI_ALLREDUCE( id_outflow_l, id_outflow, 1, MPI_INTEGER, MPI_SUM, &
1298                           comm1dx, ierr )
1299
1300       IF ( NINT( outflow_source_plane / dx ) >= nxl  .AND. &
1301            NINT( outflow_source_plane / dx ) <= nxr )  THEN
1302          id_outflow_source_l = myidx
1303       ELSE
1304          id_outflow_source_l = 0
1305       ENDIF
1306       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1307       CALL MPI_ALLREDUCE( id_outflow_source_l, id_outflow_source, 1, &
1308                           MPI_INTEGER, MPI_SUM, comm1dx, ierr )
1309
1310    ENDIF
1311
1312    CALL location_message( 'finished', .TRUE. )
1313
1314#else
1315    IF ( bc_lr == 'dirichlet/radiation' )  THEN
1316       inflow_l  = .TRUE.
1317       outflow_r = .TRUE.
1318    ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1319       outflow_l = .TRUE.
1320       inflow_r  = .TRUE.
1321    ENDIF
1322
1323    IF ( bc_ns == 'dirichlet/radiation' )  THEN
1324       inflow_n  = .TRUE.
1325       outflow_s = .TRUE.
1326    ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1327       outflow_n = .TRUE.
1328       inflow_s  = .TRUE.
1329    ENDIF
1330#endif
1331
1332!
1333!-- At the inflow or outflow, u or v, respectively, have to be calculated for
1334!-- one more grid point.
1335    IF ( inflow_l .OR. outflow_l .OR. nest_bound_l .OR. force_bound_l )  THEN
1336       nxlu = nxl + 1
1337    ELSE
1338       nxlu = nxl
1339    ENDIF
1340    IF ( inflow_s .OR. outflow_s .OR. nest_bound_s .OR. force_bound_s )  THEN
1341       nysv = nys + 1
1342    ELSE
1343       nysv = nys
1344    ENDIF
1345
1346!
1347!-- Allocate wall flag arrays used in the multigrid solver
1348    IF ( psolver(1:9) == 'multigrid' )  THEN
1349
1350       DO  i = maximum_grid_level, 1, -1
1351
1352           SELECT CASE ( i )
1353
1354              CASE ( 1 )
1355                 ALLOCATE( wall_flags_1(nzb:nzt_mg(i)+1,         &
1356                                        nys_mg(i)-1:nyn_mg(i)+1, &
1357                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1358
1359              CASE ( 2 )
1360                 ALLOCATE( wall_flags_2(nzb:nzt_mg(i)+1,         &
1361                                        nys_mg(i)-1:nyn_mg(i)+1, &
1362                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1363
1364              CASE ( 3 )
1365                 ALLOCATE( wall_flags_3(nzb:nzt_mg(i)+1,         &
1366                                        nys_mg(i)-1:nyn_mg(i)+1, &
1367                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1368
1369              CASE ( 4 )
1370                 ALLOCATE( wall_flags_4(nzb:nzt_mg(i)+1,         &
1371                                        nys_mg(i)-1:nyn_mg(i)+1, &
1372                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1373
1374              CASE ( 5 )
1375                 ALLOCATE( wall_flags_5(nzb:nzt_mg(i)+1,         &
1376                                        nys_mg(i)-1:nyn_mg(i)+1, &
1377                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1378
1379              CASE ( 6 )
1380                 ALLOCATE( wall_flags_6(nzb:nzt_mg(i)+1,         &
1381                                        nys_mg(i)-1:nyn_mg(i)+1, &
1382                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1383
1384              CASE ( 7 )
1385                 ALLOCATE( wall_flags_7(nzb:nzt_mg(i)+1,         &
1386                                        nys_mg(i)-1:nyn_mg(i)+1, &
1387                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1388
1389              CASE ( 8 )
1390                 ALLOCATE( wall_flags_8(nzb:nzt_mg(i)+1,         &
1391                                        nys_mg(i)-1:nyn_mg(i)+1, &
1392                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1393
1394              CASE ( 9 )
1395                 ALLOCATE( wall_flags_9(nzb:nzt_mg(i)+1,         &
1396                                        nys_mg(i)-1:nyn_mg(i)+1, &
1397                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1398
1399              CASE ( 10 )
1400                 ALLOCATE( wall_flags_10(nzb:nzt_mg(i)+1,        &
1401                                        nys_mg(i)-1:nyn_mg(i)+1, &
1402                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1403
1404              CASE DEFAULT
1405                 message_string = 'more than 10 multigrid levels'
1406                 CALL message( 'init_pegrid', 'PA0238', 1, 2, 0, 6, 0 )
1407
1408          END SELECT
1409
1410       ENDDO
1411
1412    ENDIF
1413
1414 END SUBROUTINE init_pegrid
Note: See TracBrowser for help on using the repository browser.