source: palm/trunk/SOURCE/init_pegrid.f90 @ 1805

Last change on this file since 1805 was 1805, checked in by maronga, 5 years ago

last commit documented

  • Property svn:keywords set to Id
File size: 42.9 KB
Line 
1!> @file init_pegrid.f90
2!--------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the terms
6! of the GNU General Public License as published by the Free Software Foundation,
7! either version 3 of the License, or (at your option) any later version.
8!
9! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
10! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
11! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
12!
13! You should have received a copy of the GNU General Public License along with
14! PALM. If not, see <http://www.gnu.org/licenses/>.
15!
16! Copyright 1997-2014 Leibniz Universitaet Hannover
17!--------------------------------------------------------------------------------!
18!
19! Current revisions:
20! ------------------
21!
22!
23! Former revisions:
24! -----------------
25! $Id: init_pegrid.f90 1805 2016-04-05 16:32:34Z maronga $
26!
27! 1804 2016-04-05 16:30:18Z maronga
28! Removed code for parameter file check (__check)
29!
30! 1779 2016-03-03 08:01:28Z raasch
31! changes regarding nested domain removed: virtual PE grid will be automatically
32! calculated for nested runs too
33!
34! 1764 2016-02-28 12:45:19Z raasch
35! cpp-statements for nesting removed
36!
37! 1762 2016-02-25 12:31:13Z hellstea
38! Introduction of nested domain feature
39!
40! 1682 2015-10-07 23:56:08Z knoop
41! Code annotations made doxygen readable
42!
43! 1677 2015-10-02 13:25:23Z boeske
44! New MPI-data types for exchange of 3D integer arrays.
45!
46! 1575 2015-03-27 09:56:27Z raasch
47! adjustments for psolver-queries, calculation of ngp_xz added
48!
49! 1565 2015-03-09 20:59:31Z suehring
50! Refine if-clause for setting nbgp.
51!
52! 1557 2015-03-05 16:43:04Z suehring
53! Adjustment for monotonic limiter
54!
55! 1468 2014-09-24 14:06:57Z maronga
56! Adapted for use on up to 6-digit processor cores
57!
58! 1435 2014-07-21 10:37:02Z keck
59! bugfix: added missing parameter coupling_mode_remote to ONLY-attribute
60!
61! 1402 2014-05-09 14:25:13Z raasch
62! location messages modified
63!
64! 1384 2014-05-02 14:31:06Z raasch
65! location messages added
66!
67! 1353 2014-04-08 15:21:23Z heinze
68! REAL constants provided with KIND-attribute
69!
70! 1322 2014-03-20 16:38:49Z raasch
71! REAL functions provided with KIND-attribute
72!
73! 1320 2014-03-20 08:40:49Z raasch
74! ONLY-attribute added to USE-statements,
75! kind-parameters added to all INTEGER and REAL declaration statements,
76! kinds are defined in new module kinds,
77! revision history before 2012 removed,
78! comment fields (!:) to be used for variable explanations added to
79! all variable declaration statements
80!
81! 1304 2014-03-12 10:29:42Z raasch
82! bugfix: single core MPI runs missed some settings of transpose indices
83!
84! 1212 2013-08-15 08:46:27Z raasch
85! error message for poisfft_hybrid removed
86!
87! 1159 2013-05-21 11:58:22Z fricke
88! dirichlet/neumann and neumann/dirichlet removed
89!
90! 1139 2013-04-18 07:25:03Z raasch
91! bugfix for calculating the id of the PE carrying the recycling plane
92!
93! 1111 2013-03-08 23:54:10Z raasch
94! initialization of poisfft moved to module poisfft
95!
96! 1092 2013-02-02 11:24:22Z raasch
97! unused variables removed
98!
99! 1056 2012-11-16 15:28:04Z raasch
100! Indices for arrays n.._mg start from zero due to definition of arrays f2 and
101! p2 as automatic arrays in recursive subroutine next_mg_level
102!
103! 1041 2012-11-06 02:36:29Z raasch
104! a 2d virtual processor topology is used by default for all machines
105!
106! 1036 2012-10-22 13:43:42Z raasch
107! code put under GPL (PALM 3.9)
108!
109! 1003 2012-09-14 14:35:53Z raasch
110! subdomains must have identical size (grid matching = "match" removed)
111!
112! 1001 2012-09-13 14:08:46Z raasch
113! all actions concerning upstream-spline-method removed
114!
115! 978 2012-08-09 08:28:32Z fricke
116! dirichlet/neumann and neumann/dirichlet added
117! nxlu and nysv are also calculated for inflow boundary
118!
119! 809 2012-01-30 13:32:58Z maronga
120! Bugfix: replaced .AND. and .NOT. with && and ! in the preprocessor directives
121!
122! 807 2012-01-25 11:53:51Z maronga
123! New cpp directive "__check" implemented which is used by check_namelist_files
124!
125! Revision 1.1  1997/07/24 11:15:09  raasch
126! Initial revision
127!
128!
129! Description:
130! ------------
131!> Determination of the virtual processor topology (if not prescribed by the
132!> user)and computation of the grid point number and array bounds of the local
133!> domains.
134!------------------------------------------------------------------------------!
135 SUBROUTINE init_pegrid
136 
137
138    USE control_parameters,                                                    &
139        ONLY:  bc_lr, bc_ns, coupling_mode, coupling_mode_remote,              &
140               coupling_topology, dt_dosp, gathered_size, grid_level,          &
141               grid_level_count, host, inflow_l, inflow_n, inflow_r, inflow_s, &
142               io_blocks, io_group, maximum_grid_level,                        &
143               maximum_parallel_io_streams, message_string,                    &
144               mg_switch_to_pe0_level, momentum_advec, nest_bound_l,           &
145               nest_bound_n, nest_bound_r, nest_bound_s, neutral, psolver,     &
146               outflow_l, outflow_n, outflow_r, outflow_s, recycling_width,    &
147               scalar_advec, subdomain_size
148
149    USE grid_variables,                                                        &
150        ONLY:  dx
151       
152    USE indices,                                                               &
153        ONLY:  mg_loc_ind, nbgp, nnx, nny, nnz, nx, nx_a, nx_o, nxl, nxl_mg,   &
154               nxlu, nxr, nxr_mg, ny, ny_a, ny_o, nyn, nyn_mg, nys, nys_mg,    &
155               nysv, nz, nzb, nzt, nzt_mg, wall_flags_1, wall_flags_2,         &
156               wall_flags_3, wall_flags_4, wall_flags_5, wall_flags_6,         &
157               wall_flags_7, wall_flags_8, wall_flags_9, wall_flags_10
158
159    USE kinds
160     
161    USE pegrid
162 
163    USE transpose_indices,                                                     &
164        ONLY:  nxl_y, nxl_yd, nxl_z, nxr_y, nxr_yd, nxr_z, nyn_x, nyn_z, nys_x,&
165               nys_z, nzb_x, nzb_y, nzb_yd, nzt_x, nzt_yd, nzt_y
166
167    IMPLICIT NONE
168
169    INTEGER(iwp) ::  i                        !<
170    INTEGER(iwp) ::  id_inflow_l              !<
171    INTEGER(iwp) ::  id_recycling_l           !<
172    INTEGER(iwp) ::  ind(5)                   !<
173    INTEGER(iwp) ::  j                        !<
174    INTEGER(iwp) ::  k                        !<
175    INTEGER(iwp) ::  maximum_grid_level_l     !<
176    INTEGER(iwp) ::  mg_levels_x              !<
177    INTEGER(iwp) ::  mg_levels_y              !<
178    INTEGER(iwp) ::  mg_levels_z              !<
179    INTEGER(iwp) ::  mg_switch_to_pe0_level_l !<
180    INTEGER(iwp) ::  nnx_y                    !<
181    INTEGER(iwp) ::  nnx_z                    !<
182    INTEGER(iwp) ::  nny_x                    !<
183    INTEGER(iwp) ::  nny_z                    !<
184    INTEGER(iwp) ::  nnz_x                    !<
185    INTEGER(iwp) ::  nnz_y                    !<
186    INTEGER(iwp) ::  numproc_sqr              !<
187    INTEGER(iwp) ::  nxl_l                    !<
188    INTEGER(iwp) ::  nxr_l                    !<
189    INTEGER(iwp) ::  nyn_l                    !<
190    INTEGER(iwp) ::  nys_l                    !<
191    INTEGER(iwp) ::  nzb_l                    !<
192    INTEGER(iwp) ::  nzt_l                    !<
193    INTEGER(iwp) ::  omp_get_num_threads      !<
194
195    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  ind_all !<
196    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nxlf    !<
197    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nxrf    !<
198    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nynf    !<
199    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nysf    !<
200
201    INTEGER(iwp), DIMENSION(2) :: pdims_remote          !<
202
203#if defined( __mpi2 )
204    LOGICAL ::  found                                   !<
205#endif
206
207!
208!-- Get the number of OpenMP threads
209    !$OMP PARALLEL
210#if defined( __intel_openmp_bug )
211    threads_per_task = omp_get_num_threads()
212#else
213!$  threads_per_task = omp_get_num_threads()
214#endif
215    !$OMP END PARALLEL
216
217
218#if defined( __parallel )
219
220    CALL location_message( 'creating virtual PE grids + MPI derived data types', &
221                           .FALSE. )
222
223!
224!--    Determine the processor topology or check it, if prescribed by the user
225    IF ( npex == -1  .AND.  npey == -1 )  THEN
226
227!
228!--       Automatic determination of the topology
229       numproc_sqr = SQRT( REAL( numprocs, KIND=wp ) )
230       pdims(1)    = MAX( numproc_sqr , 1 )
231       DO  WHILE ( MOD( numprocs , pdims(1) ) /= 0 )
232          pdims(1) = pdims(1) - 1
233       ENDDO
234       pdims(2) = numprocs / pdims(1)
235
236    ELSEIF ( npex /= -1  .AND.  npey /= -1 )  THEN
237
238!
239!--    Prescribed by user. Number of processors on the prescribed topology
240!--    must be equal to the number of PEs available to the job
241       IF ( ( npex * npey ) /= numprocs )  THEN
242          WRITE( message_string, * ) 'number of PEs of the prescribed ',   &
243              'topology (', npex*npey,') does not match & the number of ', &
244              'PEs available to the job (', numprocs, ')'
245          CALL message( 'init_pegrid', 'PA0221', 1, 2, 0, 6, 0 )
246       ENDIF
247       pdims(1) = npex
248       pdims(2) = npey
249
250    ELSE
251!
252!--    If the processor topology is prescribed by the user, the number of
253!--    PEs must be given in both directions
254       message_string = 'if the processor topology is prescribed by th' //  &
255                'e user& both values of "npex" and "npey" must be given' // &
256                ' in the &NAMELIST-parameter file'
257       CALL message( 'init_pegrid', 'PA0222', 1, 2, 0, 6, 0 )
258
259    ENDIF
260
261!
262!-- For communication speedup, set barriers in front of collective
263!-- communications by default on SGI-type systems
264    IF ( host(3:5) == 'sgi' )  collective_wait = .TRUE.
265
266!
267!-- If necessary, set horizontal boundary conditions to non-cyclic
268    IF ( bc_lr /= 'cyclic' )  cyclic(1) = .FALSE.
269    IF ( bc_ns /= 'cyclic' )  cyclic(2) = .FALSE.
270
271
272!
273!-- Create the virtual processor grid
274    CALL MPI_CART_CREATE( comm_palm, ndim, pdims, cyclic, reorder, &
275                          comm2d, ierr )
276    CALL MPI_COMM_RANK( comm2d, myid, ierr )
277    WRITE (myid_char,'(''_'',I6.6)')  myid
278
279    CALL MPI_CART_COORDS( comm2d, myid, ndim, pcoord, ierr )
280    CALL MPI_CART_SHIFT( comm2d, 0, 1, pleft, pright, ierr )
281    CALL MPI_CART_SHIFT( comm2d, 1, 1, psouth, pnorth, ierr )
282
283!
284!-- Determine sub-topologies for transpositions
285!-- Transposition from z to x:
286    remain_dims(1) = .TRUE.
287    remain_dims(2) = .FALSE.
288    CALL MPI_CART_SUB( comm2d, remain_dims, comm1dx, ierr )
289    CALL MPI_COMM_RANK( comm1dx, myidx, ierr )
290!
291!-- Transposition from x to y
292    remain_dims(1) = .FALSE.
293    remain_dims(2) = .TRUE.
294    CALL MPI_CART_SUB( comm2d, remain_dims, comm1dy, ierr )
295    CALL MPI_COMM_RANK( comm1dy, myidy, ierr )
296
297
298!
299!-- Calculate array bounds along x-direction for every PE.
300    ALLOCATE( nxlf(0:pdims(1)-1), nxrf(0:pdims(1)-1), nynf(0:pdims(2)-1), &
301              nysf(0:pdims(2)-1) )
302
303    IF ( MOD( nx+1 , pdims(1) ) /= 0 )  THEN
304       WRITE( message_string, * ) 'x-direction: gridpoint number (',nx+1,') ',&
305                               'is not an& integral divisor of the number ',  &
306                               'processors (', pdims(1),')'
307       CALL message( 'init_pegrid', 'PA0225', 1, 2, 0, 6, 0 )
308    ELSE
309       nnx  = ( nx + 1 ) / pdims(1)
310       IF ( nnx*pdims(1) - ( nx + 1) > nnx )  THEN
311          WRITE( message_string, * ) 'x-direction: nx does not match the',    & 
312                       'requirements given by the number of PEs &used',       &
313                       '& please use nx = ', nx - ( pdims(1) - ( nnx*pdims(1) &
314                                   - ( nx + 1 ) ) ), ' instead of nx =', nx
315          CALL message( 'init_pegrid', 'PA0226', 1, 2, 0, 6, 0 )
316       ENDIF
317    ENDIF   
318
319!
320!-- Left and right array bounds, number of gridpoints
321    DO  i = 0, pdims(1)-1
322       nxlf(i)   = i * nnx
323       nxrf(i)   = ( i + 1 ) * nnx - 1
324    ENDDO
325
326!
327!-- Calculate array bounds in y-direction for every PE.
328    IF ( MOD( ny+1 , pdims(2) ) /= 0 )  THEN
329       WRITE( message_string, * ) 'y-direction: gridpoint number (',ny+1,') ', &
330                           'is not an& integral divisor of the number of',     &
331                           'processors (', pdims(2),')'
332       CALL message( 'init_pegrid', 'PA0227', 1, 2, 0, 6, 0 )
333    ELSE
334       nny  = ( ny + 1 ) / pdims(2)
335       IF ( nny*pdims(2) - ( ny + 1) > nny )  THEN
336          WRITE( message_string, * ) 'y-direction: ny does not match the',    &
337                       'requirements given by the number of PEs &used ',      &
338                       '& please use ny = ', ny - ( pdims(2) - ( nnx*pdims(2) &
339                                     - ( ny + 1 ) ) ), ' instead of ny =', ny
340          CALL message( 'init_pegrid', 'PA0228', 1, 2, 0, 6, 0 )
341       ENDIF
342    ENDIF   
343
344!
345!-- South and north array bounds
346    DO  j = 0, pdims(2)-1
347       nysf(j)   = j * nny
348       nynf(j)   = ( j + 1 ) * nny - 1
349    ENDDO
350
351!
352!-- Local array bounds of the respective PEs
353    nxl = nxlf(pcoord(1))
354    nxr = nxrf(pcoord(1))
355    nys = nysf(pcoord(2))
356    nyn = nynf(pcoord(2))
357    nzb = 0
358    nzt = nz
359    nnz = nz
360
361!
362!-- Set switches to define if the PE is situated at the border of the virtual
363!-- processor grid
364    IF ( nxl == 0 )   left_border_pe  = .TRUE.
365    IF ( nxr == nx )  right_border_pe = .TRUE.
366    IF ( nys == 0 )   south_border_pe = .TRUE.
367    IF ( nyn == ny )  north_border_pe = .TRUE.
368
369!
370!-- Calculate array bounds and gridpoint numbers for the transposed arrays
371!-- (needed in the pressure solver)
372!-- For the transposed arrays, cyclic boundaries as well as top and bottom
373!-- boundaries are omitted, because they are obstructive to the transposition
374
375!
376!-- 1. transposition  z --> x
377!-- This transposition is not neccessary in case of a 1d-decomposition along x
378    nys_x = nys
379    nyn_x = nyn
380    nny_x = nny
381    nnz_x = nz / pdims(1)
382    nzb_x = 1 + myidx * nnz_x
383    nzt_x = ( myidx + 1 ) * nnz_x
384    sendrecvcount_zx = nnx * nny * nnz_x
385
386    IF ( pdims(2) /= 1 )  THEN
387       IF ( MOD( nz , pdims(1) ) /= 0 )  THEN
388          WRITE( message_string, * ) 'transposition z --> x:',                &
389                       '&nz=',nz,' is not an integral divisior of pdims(1)=', &
390                                                                   pdims(1)
391          CALL message( 'init_pegrid', 'PA0230', 1, 2, 0, 6, 0 )
392       ENDIF
393    ENDIF
394
395!
396!-- 2. transposition  x --> y
397    nnz_y = nnz_x
398    nzb_y = nzb_x
399    nzt_y = nzt_x
400    IF ( MOD( nx+1 , pdims(2) ) /= 0 )  THEN
401       WRITE( message_string, * ) 'transposition x --> y:',                &
402                         '&nx+1=',nx+1,' is not an integral divisor of ',&
403                         'pdims(2)=',pdims(2)
404       CALL message( 'init_pegrid', 'PA0231', 1, 2, 0, 6, 0 )
405    ENDIF
406    nnx_y = (nx+1) / pdims(2)
407    nxl_y = myidy * nnx_y
408    nxr_y = ( myidy + 1 ) * nnx_y - 1
409    sendrecvcount_xy = nnx_y * nny_x * nnz_y
410
411!
412!-- 3. transposition  y --> z  (ELSE:  x --> y  in case of 1D-decomposition
413!-- along x)
414    nnx_z = nnx_y
415    nxl_z = nxl_y
416    nxr_z = nxr_y
417    nny_z = (ny+1) / pdims(1)
418    nys_z = myidx * nny_z
419    nyn_z = ( myidx + 1 ) * nny_z - 1
420    sendrecvcount_yz = nnx_y * nny_z * nnz_y
421
422    IF ( pdims(2) /= 1 )  THEN
423!
424!--    y --> z
425!--    This transposition is not neccessary in case of a 1d-decomposition
426!--    along x, except that the uptream-spline method is switched on
427       IF ( MOD( ny+1 , pdims(1) ) /= 0 )  THEN
428          WRITE( message_string, * ) 'transposition y --> z:',            &
429                            '& ny+1=',ny+1,' is not an integral divisor of ',&
430                            'pdims(1)=',pdims(1)
431          CALL message( 'init_pegrid', 'PA0232', 1, 2, 0, 6, 0 )
432       ENDIF
433
434    ELSE
435!
436!--    x --> y. This condition must be fulfilled for a 1D-decomposition along x
437       IF ( MOD( ny+1 , pdims(1) ) /= 0 )  THEN
438          WRITE( message_string, * ) 'transposition x --> y:',               &
439                            '& ny+1=',ny+1,' is not an integral divisor of ',&
440                            'pdims(1)=',pdims(1)
441          CALL message( 'init_pegrid', 'PA0233', 1, 2, 0, 6, 0 )
442       ENDIF
443
444    ENDIF
445
446!
447!-- Indices for direct transpositions z --> y (used for calculating spectra)
448    IF ( dt_dosp /= 9999999.9_wp )  THEN
449       IF ( MOD( nz, pdims(2) ) /= 0 )  THEN
450          WRITE( message_string, * ) 'direct transposition z --> y (needed ', &
451                    'for spectra):& nz=',nz,' is not an integral divisor of ',&
452                    'pdims(2)=',pdims(2)
453          CALL message( 'init_pegrid', 'PA0234', 1, 2, 0, 6, 0 )
454       ELSE
455          nxl_yd = nxl
456          nxr_yd = nxr
457          nzb_yd = 1 + myidy * ( nz / pdims(2) )
458          nzt_yd = ( myidy + 1 ) * ( nz / pdims(2) )
459          sendrecvcount_zyd = nnx * nny * ( nz / pdims(2) )
460       ENDIF
461    ENDIF
462
463!
464!-- Indices for direct transpositions y --> x (they are only possible in case
465!-- of a 1d-decomposition along x)
466    IF ( pdims(2) == 1 )  THEN
467       nny_x = nny / pdims(1)
468       nys_x = myid * nny_x
469       nyn_x = ( myid + 1 ) * nny_x - 1
470       nzb_x = 1
471       nzt_x = nz
472       sendrecvcount_xy = nnx * nny_x * nz
473    ENDIF
474
475!
476!-- Indices for direct transpositions x --> y (they are only possible in case
477!-- of a 1d-decomposition along y)
478    IF ( pdims(1) == 1 )  THEN
479       nnx_y = nnx / pdims(2)
480       nxl_y = myid * nnx_y
481       nxr_y = ( myid + 1 ) * nnx_y - 1
482       nzb_y = 1
483       nzt_y = nz
484       sendrecvcount_xy = nnx_y * nny * nz
485    ENDIF
486
487!
488!-- Arrays for storing the array bounds are needed any more
489    DEALLOCATE( nxlf , nxrf , nynf , nysf )
490
491
492!
493!-- Collect index bounds from other PEs (to be written to restart file later)
494    ALLOCATE( hor_index_bounds(4,0:numprocs-1) )
495
496    IF ( myid == 0 )  THEN
497
498       hor_index_bounds(1,0) = nxl
499       hor_index_bounds(2,0) = nxr
500       hor_index_bounds(3,0) = nys
501       hor_index_bounds(4,0) = nyn
502
503!
504!--    Receive data from all other PEs
505       DO  i = 1, numprocs-1
506          CALL MPI_RECV( ibuf, 4, MPI_INTEGER, i, MPI_ANY_TAG, comm2d, status, &
507                         ierr )
508          hor_index_bounds(:,i) = ibuf(1:4)
509       ENDDO
510
511    ELSE
512!
513!--    Send index bounds to PE0
514       ibuf(1) = nxl
515       ibuf(2) = nxr
516       ibuf(3) = nys
517       ibuf(4) = nyn
518       CALL MPI_SEND( ibuf, 4, MPI_INTEGER, 0, myid, comm2d, ierr )
519
520    ENDIF
521
522
523#if defined( __print )
524!
525!-- Control output
526    IF ( myid == 0 )  THEN
527       PRINT*, '*** processor topology ***'
528       PRINT*, ' '
529       PRINT*, 'myid   pcoord    left right  south north  idx idy   nxl: nxr',&
530               &'   nys: nyn'
531       PRINT*, '------------------------------------------------------------',&
532               &'-----------'
533       WRITE (*,1000)  0, pcoord(1), pcoord(2), pleft, pright, psouth, pnorth, &
534                       myidx, myidy, nxl, nxr, nys, nyn
5351000   FORMAT (I4,2X,'(',I3,',',I3,')',3X,I4,2X,I4,3X,I4,2X,I4,2X,I3,1X,I3, &
536               2(2X,I4,':',I4))
537
538!
539!--    Receive data from the other PEs
540       DO  i = 1,numprocs-1
541          CALL MPI_RECV( ibuf, 12, MPI_INTEGER, i, MPI_ANY_TAG, comm2d, status, &
542                         ierr )
543          WRITE (*,1000)  i, ( ibuf(j) , j = 1,12 )
544       ENDDO
545    ELSE
546
547!
548!--    Send data to PE0
549       ibuf(1) = pcoord(1); ibuf(2) = pcoord(2); ibuf(3) = pleft
550       ibuf(4) = pright; ibuf(5) = psouth; ibuf(6) = pnorth; ibuf(7) = myidx
551       ibuf(8) = myidy; ibuf(9) = nxl; ibuf(10) = nxr; ibuf(11) = nys
552       ibuf(12) = nyn
553       CALL MPI_SEND( ibuf, 12, MPI_INTEGER, 0, myid, comm2d, ierr )       
554    ENDIF
555#endif
556
557#if defined( __parallel )
558#if defined( __mpi2 )
559!
560!-- In case of coupled runs, get the port name on PE0 of the atmosphere model
561!-- and pass it to PE0 of the ocean model
562    IF ( myid == 0 )  THEN
563
564       IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
565
566          CALL MPI_OPEN_PORT( MPI_INFO_NULL, port_name, ierr )
567
568          CALL MPI_PUBLISH_NAME( 'palm_coupler', MPI_INFO_NULL, port_name, &
569                                 ierr )
570
571!
572!--       Write a flag file for the ocean model and the other atmosphere
573!--       processes.
574!--       There seems to be a bug in MPICH2 which causes hanging processes
575!--       in case that execution of LOOKUP_NAME is continued too early
576!--       (i.e. before the port has been created)
577          OPEN( 90, FILE='COUPLING_PORT_OPENED', FORM='FORMATTED' )
578          WRITE ( 90, '(''TRUE'')' )
579          CLOSE ( 90 )
580
581       ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
582
583!
584!--       Continue only if the atmosphere model has created the port.
585!--       There seems to be a bug in MPICH2 which causes hanging processes
586!--       in case that execution of LOOKUP_NAME is continued too early
587!--       (i.e. before the port has been created)
588          INQUIRE( FILE='COUPLING_PORT_OPENED', EXIST=found )
589          DO WHILE ( .NOT. found )
590             INQUIRE( FILE='COUPLING_PORT_OPENED', EXIST=found )
591          ENDDO
592
593          CALL MPI_LOOKUP_NAME( 'palm_coupler', MPI_INFO_NULL, port_name, ierr )
594
595       ENDIF
596
597    ENDIF
598
599!
600!-- In case of coupled runs, establish the connection between the atmosphere
601!-- and the ocean model and define the intercommunicator (comm_inter)
602    CALL MPI_BARRIER( comm2d, ierr )
603    IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
604
605       CALL MPI_COMM_ACCEPT( port_name, MPI_INFO_NULL, 0, MPI_COMM_WORLD, &
606                             comm_inter, ierr )
607       coupling_mode_remote = 'ocean_to_atmosphere'
608
609    ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
610
611       CALL MPI_COMM_CONNECT( port_name, MPI_INFO_NULL, 0, MPI_COMM_WORLD, &
612                              comm_inter, ierr )
613       coupling_mode_remote = 'atmosphere_to_ocean'
614
615    ENDIF
616#endif
617
618!
619!-- Determine the number of ghost point layers
620    IF ( ( scalar_advec == 'ws-scheme' .AND. .NOT. neutral ) .OR.             &
621         scalar_advec == 'ws-scheme-mono' .OR.                                &
622         momentum_advec == 'ws-scheme' )  THEN
623       nbgp = 3
624    ELSE
625       nbgp = 1
626    ENDIF
627
628!
629!-- Create a new MPI derived datatype for the exchange of surface (xy) data,
630!-- which is needed for coupled atmosphere-ocean runs.
631!-- First, calculate number of grid points of an xy-plane.
632    ngp_xy  = ( nxr - nxl + 1 + 2 * nbgp ) * ( nyn - nys + 1 + 2 * nbgp )
633    CALL MPI_TYPE_VECTOR( ngp_xy, 1, nzt-nzb+2, MPI_REAL, type_xy, ierr )
634    CALL MPI_TYPE_COMMIT( type_xy, ierr )
635
636    IF ( TRIM( coupling_mode ) /= 'uncoupled' )  THEN
637   
638!
639!--    Pass the number of grid points of the atmosphere model to
640!--    the ocean model and vice versa
641       IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
642
643          nx_a = nx
644          ny_a = ny
645
646          IF ( myid == 0 )  THEN
647
648             CALL MPI_SEND( nx_a, 1, MPI_INTEGER, numprocs, 1, comm_inter,  &
649                            ierr )
650             CALL MPI_SEND( ny_a, 1, MPI_INTEGER, numprocs, 2, comm_inter,  &
651                            ierr )
652             CALL MPI_SEND( pdims, 2, MPI_INTEGER, numprocs, 3, comm_inter, &
653                            ierr )
654             CALL MPI_RECV( nx_o, 1, MPI_INTEGER, numprocs, 4, comm_inter,  &
655                            status, ierr )
656             CALL MPI_RECV( ny_o, 1, MPI_INTEGER, numprocs, 5, comm_inter,  &
657                            status, ierr )
658             CALL MPI_RECV( pdims_remote, 2, MPI_INTEGER, numprocs, 6,      &
659                            comm_inter, status, ierr )
660          ENDIF
661
662          CALL MPI_BCAST( nx_o, 1, MPI_INTEGER, 0, comm2d, ierr )
663          CALL MPI_BCAST( ny_o, 1, MPI_INTEGER, 0, comm2d, ierr ) 
664          CALL MPI_BCAST( pdims_remote, 2, MPI_INTEGER, 0, comm2d, ierr )
665       
666       ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
667
668          nx_o = nx
669          ny_o = ny
670
671          IF ( myid == 0 ) THEN
672
673             CALL MPI_RECV( nx_a, 1, MPI_INTEGER, 0, 1, comm_inter, status, &
674                            ierr )
675             CALL MPI_RECV( ny_a, 1, MPI_INTEGER, 0, 2, comm_inter, status, &
676                            ierr )
677             CALL MPI_RECV( pdims_remote, 2, MPI_INTEGER, 0, 3, comm_inter, &
678                            status, ierr )
679             CALL MPI_SEND( nx_o, 1, MPI_INTEGER, 0, 4, comm_inter, ierr )
680             CALL MPI_SEND( ny_o, 1, MPI_INTEGER, 0, 5, comm_inter, ierr )
681             CALL MPI_SEND( pdims, 2, MPI_INTEGER, 0, 6, comm_inter, ierr )
682          ENDIF
683
684          CALL MPI_BCAST( nx_a, 1, MPI_INTEGER, 0, comm2d, ierr)
685          CALL MPI_BCAST( ny_a, 1, MPI_INTEGER, 0, comm2d, ierr) 
686          CALL MPI_BCAST( pdims_remote, 2, MPI_INTEGER, 0, comm2d, ierr) 
687
688       ENDIF
689 
690       ngp_a = ( nx_a+1 + 2 * nbgp ) * ( ny_a+1 + 2 * nbgp )
691       ngp_o = ( nx_o+1 + 2 * nbgp ) * ( ny_o+1 + 2 * nbgp )
692
693!
694!--    Determine if the horizontal grid and the number of PEs in ocean and
695!--    atmosphere is same or not
696       IF ( nx_o == nx_a  .AND.  ny_o == ny_a  .AND.  &
697            pdims(1) == pdims_remote(1) .AND. pdims(2) == pdims_remote(2) ) &
698       THEN
699          coupling_topology = 0
700       ELSE
701          coupling_topology = 1
702       ENDIF
703
704!
705!--    Determine the target PEs for the exchange between ocean and
706!--    atmosphere (comm2d)
707       IF ( coupling_topology == 0 )  THEN
708!
709!--       In case of identical topologies, every atmosphere PE has exactly one
710!--       ocean PE counterpart and vice versa
711          IF ( TRIM( coupling_mode ) == 'atmosphere_to_ocean' ) THEN
712             target_id = myid + numprocs
713          ELSE
714             target_id = myid
715          ENDIF
716
717       ELSE
718!
719!--       In case of nonequivalent topology in ocean and atmosphere only for
720!--       PE0 in ocean and PE0 in atmosphere a target_id is needed, since
721!--       data echxchange between ocean and atmosphere will be done only
722!--       between these PEs.   
723          IF ( myid == 0 )  THEN
724
725             IF ( TRIM( coupling_mode ) == 'atmosphere_to_ocean' )  THEN
726                target_id = numprocs
727             ELSE
728                target_id = 0
729             ENDIF
730
731          ENDIF
732
733       ENDIF
734
735    ENDIF
736
737
738#endif
739
740#else
741
742!
743!-- Array bounds when running on a single PE (respectively a non-parallel
744!-- machine)
745    nxl = 0
746    nxr = nx
747    nnx = nxr - nxl + 1
748    nys = 0
749    nyn = ny
750    nny = nyn - nys + 1
751    nzb = 0
752    nzt = nz
753    nnz = nz
754
755    ALLOCATE( hor_index_bounds(4,0:0) )
756    hor_index_bounds(1,0) = nxl
757    hor_index_bounds(2,0) = nxr
758    hor_index_bounds(3,0) = nys
759    hor_index_bounds(4,0) = nyn
760
761!
762!-- Array bounds for the pressure solver (in the parallel code, these bounds
763!-- are the ones for the transposed arrays)
764    nys_x = nys
765    nyn_x = nyn
766    nzb_x = nzb + 1
767    nzt_x = nzt
768
769    nxl_y = nxl
770    nxr_y = nxr
771    nzb_y = nzb + 1
772    nzt_y = nzt
773
774    nxl_z = nxl
775    nxr_z = nxr
776    nys_z = nys
777    nyn_z = nyn
778
779#endif
780
781!
782!-- Calculate number of grid levels necessary for the multigrid poisson solver
783!-- as well as the gridpoint indices on each level
784    IF ( psolver(1:9) == 'multigrid' )  THEN
785
786!
787!--    First calculate number of possible grid levels for the subdomains
788       mg_levels_x = 1
789       mg_levels_y = 1
790       mg_levels_z = 1
791
792       i = nnx
793       DO WHILE ( MOD( i, 2 ) == 0  .AND.  i /= 2 )
794          i = i / 2
795          mg_levels_x = mg_levels_x + 1
796       ENDDO
797
798       j = nny
799       DO WHILE ( MOD( j, 2 ) == 0  .AND.  j /= 2 )
800          j = j / 2
801          mg_levels_y = mg_levels_y + 1
802       ENDDO
803
804       k = nz    ! do not use nnz because it might be > nz due to transposition
805                 ! requirements
806       DO WHILE ( MOD( k, 2 ) == 0  .AND.  k /= 2 )
807          k = k / 2
808          mg_levels_z = mg_levels_z + 1
809       ENDDO
810
811       maximum_grid_level = MIN( mg_levels_x, mg_levels_y, mg_levels_z )
812
813!
814!--    Find out, if the total domain allows more levels. These additional
815!--    levels are identically processed on all PEs.
816       IF ( numprocs > 1  .AND.  mg_switch_to_pe0_level /= -1 )  THEN
817
818          IF ( mg_levels_z > MIN( mg_levels_x, mg_levels_y ) )  THEN
819
820             mg_switch_to_pe0_level_l = maximum_grid_level
821
822             mg_levels_x = 1
823             mg_levels_y = 1
824
825             i = nx+1
826             DO WHILE ( MOD( i, 2 ) == 0  .AND.  i /= 2 )
827                i = i / 2
828                mg_levels_x = mg_levels_x + 1
829             ENDDO
830
831             j = ny+1
832             DO WHILE ( MOD( j, 2 ) == 0  .AND.  j /= 2 )
833                j = j / 2
834                mg_levels_y = mg_levels_y + 1
835             ENDDO
836
837             maximum_grid_level_l = MIN( mg_levels_x, mg_levels_y, mg_levels_z )
838
839             IF ( maximum_grid_level_l > mg_switch_to_pe0_level_l )  THEN
840                mg_switch_to_pe0_level_l = maximum_grid_level_l - &
841                                           mg_switch_to_pe0_level_l + 1
842             ELSE
843                mg_switch_to_pe0_level_l = 0
844             ENDIF
845
846          ELSE
847             mg_switch_to_pe0_level_l = 0
848             maximum_grid_level_l = maximum_grid_level
849
850          ENDIF
851
852!
853!--       Use switch level calculated above only if it is not pre-defined
854!--       by user
855          IF ( mg_switch_to_pe0_level == 0 )  THEN
856             IF ( mg_switch_to_pe0_level_l /= 0 )  THEN
857                mg_switch_to_pe0_level = mg_switch_to_pe0_level_l
858                maximum_grid_level     = maximum_grid_level_l
859             ENDIF
860
861          ELSE
862!
863!--          Check pre-defined value and reset to default, if neccessary
864             IF ( mg_switch_to_pe0_level < mg_switch_to_pe0_level_l  .OR.  &
865                  mg_switch_to_pe0_level >= maximum_grid_level_l )  THEN
866                message_string = 'mg_switch_to_pe0_level ' // &
867                                 'out of range and reset to default (=0)'
868                CALL message( 'init_pegrid', 'PA0235', 0, 1, 0, 6, 0 )
869                mg_switch_to_pe0_level = 0
870             ELSE
871!
872!--             Use the largest number of possible levels anyway and recalculate
873!--             the switch level to this largest number of possible values
874                maximum_grid_level = maximum_grid_level_l
875
876             ENDIF
877
878          ENDIF
879
880       ENDIF
881
882       ALLOCATE( grid_level_count(maximum_grid_level),                       &
883                 nxl_mg(0:maximum_grid_level), nxr_mg(0:maximum_grid_level), &
884                 nyn_mg(0:maximum_grid_level), nys_mg(0:maximum_grid_level), &
885                 nzt_mg(0:maximum_grid_level) )
886
887       grid_level_count = 0
888!
889!--    Index zero required as dummy due to definition of arrays f2 and p2 in
890!--    recursive subroutine next_mg_level
891       nxl_mg(0) = 0; nxr_mg(0) = 0; nyn_mg(0) = 0; nys_mg(0) = 0; nzt_mg(0) = 0
892
893       nxl_l = nxl; nxr_l = nxr; nys_l = nys; nyn_l = nyn; nzt_l = nzt
894
895       DO  i = maximum_grid_level, 1 , -1
896
897          IF ( i == mg_switch_to_pe0_level )  THEN
898#if defined( __parallel )
899!
900!--          Save the grid size of the subdomain at the switch level, because
901!--          it is needed in poismg.
902             ind(1) = nxl_l; ind(2) = nxr_l
903             ind(3) = nys_l; ind(4) = nyn_l
904             ind(5) = nzt_l
905             ALLOCATE( ind_all(5*numprocs), mg_loc_ind(5,0:numprocs-1) )
906             CALL MPI_ALLGATHER( ind, 5, MPI_INTEGER, ind_all, 5, &
907                                 MPI_INTEGER, comm2d, ierr )
908             DO  j = 0, numprocs-1
909                DO  k = 1, 5
910                   mg_loc_ind(k,j) = ind_all(k+j*5)
911                ENDDO
912             ENDDO
913             DEALLOCATE( ind_all )
914!
915!--          Calculate the grid size of the total domain
916             nxr_l = ( nxr_l-nxl_l+1 ) * pdims(1) - 1
917             nxl_l = 0
918             nyn_l = ( nyn_l-nys_l+1 ) * pdims(2) - 1
919             nys_l = 0
920!
921!--          The size of this gathered array must not be larger than the
922!--          array tend, which is used in the multigrid scheme as a temporary
923!--          array. Therefore the subdomain size of an PE is calculated and
924!--          the size of the gathered grid. These values are used in 
925!--          routines pres and poismg
926             subdomain_size = ( nxr - nxl + 2 * nbgp + 1 ) * &
927                              ( nyn - nys + 2 * nbgp + 1 ) * ( nzt - nzb + 2 )
928             gathered_size  = ( nxr_l - nxl_l + 3 ) * ( nyn_l - nys_l + 3 ) * &
929                              ( nzt_l - nzb + 2 )
930
931#else
932             message_string = 'multigrid gather/scatter impossible ' // &
933                          'in non parallel mode'
934             CALL message( 'init_pegrid', 'PA0237', 1, 2, 0, 6, 0 )
935#endif
936          ENDIF
937
938          nxl_mg(i) = nxl_l
939          nxr_mg(i) = nxr_l
940          nys_mg(i) = nys_l
941          nyn_mg(i) = nyn_l
942          nzt_mg(i) = nzt_l
943
944          nxl_l = nxl_l / 2 
945          nxr_l = nxr_l / 2
946          nys_l = nys_l / 2 
947          nyn_l = nyn_l / 2 
948          nzt_l = nzt_l / 2 
949
950       ENDDO
951
952!
953!--    Temporary problem: Currently calculation of maxerror iin routine poismg crashes
954!--    if grid data are collected on PE0 already on the finest grid level.
955!--    To be solved later.
956       IF ( maximum_grid_level == mg_switch_to_pe0_level )  THEN
957          message_string = 'grid coarsening on subdomain level cannot be performed'
958          CALL message( 'poismg', 'PA0236', 1, 2, 0, 6, 0 )
959       ENDIF
960
961    ELSE
962
963       maximum_grid_level = 0
964
965    ENDIF
966
967!
968!-- Default level 0 tells exchange_horiz that all ghost planes have to be
969!-- exchanged. grid_level is adjusted in poismg, where only one ghost plane
970!-- is required.
971    grid_level = 0
972
973#if defined( __parallel )
974!
975!-- Gridpoint number for the exchange of ghost points (y-line for 2D-arrays)
976    ngp_y  = nyn - nys + 1 + 2 * nbgp
977
978!
979!-- Define new MPI derived datatypes for the exchange of ghost points in
980!-- x- and y-direction for 2D-arrays (line)
981    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp, ngp_y, MPI_REAL, type_x, &
982                          ierr )
983    CALL MPI_TYPE_COMMIT( type_x, ierr )
984    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp, ngp_y, MPI_INTEGER, &
985                          type_x_int, ierr )
986    CALL MPI_TYPE_COMMIT( type_x_int, ierr )
987
988    CALL MPI_TYPE_VECTOR( nbgp, ngp_y, ngp_y, MPI_REAL, type_y, ierr )
989    CALL MPI_TYPE_COMMIT( type_y, ierr )
990    CALL MPI_TYPE_VECTOR( nbgp, ngp_y, ngp_y, MPI_INTEGER, type_y_int, ierr )
991    CALL MPI_TYPE_COMMIT( type_y_int, ierr )
992
993
994!
995!-- Calculate gridpoint numbers for the exchange of ghost points along x
996!-- (yz-plane for 3D-arrays) and define MPI derived data type(s) for the
997!-- exchange of ghost points in y-direction (xz-plane).
998!-- Do these calculations for the model grid and (if necessary) also
999!-- for the coarser grid levels used in the multigrid method
1000    ALLOCATE ( ngp_xz(0:maximum_grid_level), ngp_yz(0:maximum_grid_level),     &
1001               type_xz(0:maximum_grid_level), type_yz(0:maximum_grid_level) )
1002
1003    nxl_l = nxl; nxr_l = nxr; nys_l = nys; nyn_l = nyn; nzb_l = nzb; nzt_l = nzt
1004
1005!
1006!-- Discern between the model grid, which needs nbgp ghost points and
1007!-- grid levels for the multigrid scheme. In the latter case only one
1008!-- ghost point is necessary.
1009!-- First definition of MPI-datatypes for exchange of ghost layers on normal
1010!-- grid. The following loop is needed for data exchange in poismg.f90.
1011!
1012!-- Determine number of grid points of yz-layer for exchange
1013    ngp_yz(0) = (nzt - nzb + 2) * (nyn - nys + 1 + 2 * nbgp)
1014
1015!
1016!-- Define an MPI-datatype for the exchange of left/right boundaries.
1017!-- Although data are contiguous in physical memory (which does not
1018!-- necessarily require an MPI-derived datatype), the data exchange between
1019!-- left and right PE's using the MPI-derived type is 10% faster than without.
1020    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp*(nzt-nzb+2), ngp_yz(0), &
1021                          MPI_REAL, type_xz(0), ierr )
1022    CALL MPI_TYPE_COMMIT( type_xz(0), ierr )
1023
1024    CALL MPI_TYPE_VECTOR( nbgp, ngp_yz(0), ngp_yz(0), MPI_REAL, type_yz(0), &
1025                          ierr ) 
1026    CALL MPI_TYPE_COMMIT( type_yz(0), ierr )
1027
1028!
1029!-- Definition of MPI-datatypes for multigrid method (coarser level grids)
1030    IF ( psolver(1:9) == 'multigrid' )  THEN
1031!   
1032!--    Definition of MPI-datatyoe as above, but only 1 ghost level is used
1033       DO  i = maximum_grid_level, 1 , -1
1034
1035          ngp_xz(i) = (nzt_l - nzb_l + 2) * (nxr_l - nxl_l + 3)
1036          ngp_yz(i) = (nzt_l - nzb_l + 2) * (nyn_l - nys_l + 3)
1037
1038          CALL MPI_TYPE_VECTOR( nxr_l-nxl_l+3, nzt_l-nzb_l+2, ngp_yz(i), &
1039                                MPI_REAL, type_xz(i), ierr )
1040          CALL MPI_TYPE_COMMIT( type_xz(i), ierr )
1041
1042          CALL MPI_TYPE_VECTOR( 1, ngp_yz(i), ngp_yz(i), MPI_REAL, type_yz(i), &
1043                                ierr )
1044          CALL MPI_TYPE_COMMIT( type_yz(i), ierr )
1045
1046          nxl_l = nxl_l / 2
1047          nxr_l = nxr_l / 2
1048          nys_l = nys_l / 2
1049          nyn_l = nyn_l / 2
1050          nzt_l = nzt_l / 2
1051
1052       ENDDO
1053
1054    ENDIF
1055!
1056!-- Define data types for exchange of 3D Integer arrays.
1057    ngp_yz_int = (nzt - nzb + 2) * (nyn - nys + 1 + 2 * nbgp)
1058
1059    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp*(nzt-nzb+2), ngp_yz_int, &
1060                          MPI_INTEGER, type_xz_int, ierr )
1061    CALL MPI_TYPE_COMMIT( type_xz_int, ierr )
1062
1063    CALL MPI_TYPE_VECTOR( nbgp, ngp_yz_int, ngp_yz_int, MPI_INTEGER, type_yz_int, &
1064                          ierr )
1065    CALL MPI_TYPE_COMMIT( type_yz_int, ierr )
1066
1067#endif
1068
1069#if defined( __parallel )
1070!
1071!-- Setting of flags for inflow/outflow/nesting conditions in case of non-cyclic
1072!-- horizontal boundary conditions.
1073    IF ( pleft == MPI_PROC_NULL )  THEN
1074       IF ( bc_lr == 'dirichlet/radiation' )  THEN
1075          inflow_l  = .TRUE.
1076       ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1077          outflow_l = .TRUE.
1078       ELSEIF ( bc_lr == 'nested' )  THEN
1079          nest_bound_l = .TRUE.
1080       ENDIF
1081    ENDIF
1082
1083    IF ( pright == MPI_PROC_NULL )  THEN
1084       IF ( bc_lr == 'dirichlet/radiation' )  THEN
1085          outflow_r = .TRUE.
1086       ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1087          inflow_r  = .TRUE.
1088       ELSEIF ( bc_lr == 'nested' )  THEN
1089          nest_bound_r = .TRUE.
1090       ENDIF
1091    ENDIF
1092
1093    IF ( psouth == MPI_PROC_NULL )  THEN
1094       IF ( bc_ns == 'dirichlet/radiation' )  THEN
1095          outflow_s = .TRUE.
1096       ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1097          inflow_s  = .TRUE.
1098       ELSEIF ( bc_ns == 'nested' )  THEN
1099          nest_bound_s = .TRUE.
1100       ENDIF
1101    ENDIF
1102
1103    IF ( pnorth == MPI_PROC_NULL )  THEN
1104       IF ( bc_ns == 'dirichlet/radiation' )  THEN
1105          inflow_n  = .TRUE.
1106       ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1107          outflow_n = .TRUE.
1108       ELSEIF ( bc_ns == 'nested' )  THEN
1109          nest_bound_n = .TRUE.
1110       ENDIF
1111    ENDIF
1112
1113!
1114!-- Broadcast the id of the inflow PE
1115    IF ( inflow_l )  THEN
1116       id_inflow_l = myidx
1117    ELSE
1118       id_inflow_l = 0
1119    ENDIF
1120    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1121    CALL MPI_ALLREDUCE( id_inflow_l, id_inflow, 1, MPI_INTEGER, MPI_SUM, &
1122                        comm1dx, ierr )
1123
1124!
1125!-- Broadcast the id of the recycling plane
1126!-- WARNING: needs to be adjusted in case of inflows other than from left side!
1127    IF ( NINT( recycling_width / dx ) >= nxl  .AND. &
1128         NINT( recycling_width / dx ) <= nxr )  THEN
1129       id_recycling_l = myidx
1130    ELSE
1131       id_recycling_l = 0
1132    ENDIF
1133    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1134    CALL MPI_ALLREDUCE( id_recycling_l, id_recycling, 1, MPI_INTEGER, MPI_SUM, &
1135                        comm1dx, ierr )
1136
1137    CALL location_message( 'finished', .TRUE. )
1138
1139#else
1140    IF ( bc_lr == 'dirichlet/radiation' )  THEN
1141       inflow_l  = .TRUE.
1142       outflow_r = .TRUE.
1143    ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1144       outflow_l = .TRUE.
1145       inflow_r  = .TRUE.
1146    ENDIF
1147
1148    IF ( bc_ns == 'dirichlet/radiation' )  THEN
1149       inflow_n  = .TRUE.
1150       outflow_s = .TRUE.
1151    ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1152       outflow_n = .TRUE.
1153       inflow_s  = .TRUE.
1154    ENDIF
1155#endif
1156
1157!
1158!-- At the inflow or outflow, u or v, respectively, have to be calculated for
1159!-- one more grid point.
1160    IF ( inflow_l .OR. outflow_l .OR. nest_bound_l )  THEN
1161       nxlu = nxl + 1
1162    ELSE
1163       nxlu = nxl
1164    ENDIF
1165    IF ( inflow_s .OR. outflow_s .OR. nest_bound_s )  THEN
1166       nysv = nys + 1
1167    ELSE
1168       nysv = nys
1169    ENDIF
1170
1171!
1172!-- Allocate wall flag arrays used in the multigrid solver
1173    IF ( psolver(1:9) == 'multigrid' )  THEN
1174
1175       DO  i = maximum_grid_level, 1, -1
1176
1177           SELECT CASE ( i )
1178
1179              CASE ( 1 )
1180                 ALLOCATE( wall_flags_1(nzb:nzt_mg(i)+1,         &
1181                                        nys_mg(i)-1:nyn_mg(i)+1, &
1182                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1183
1184              CASE ( 2 )
1185                 ALLOCATE( wall_flags_2(nzb:nzt_mg(i)+1,         &
1186                                        nys_mg(i)-1:nyn_mg(i)+1, &
1187                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1188
1189              CASE ( 3 )
1190                 ALLOCATE( wall_flags_3(nzb:nzt_mg(i)+1,         &
1191                                        nys_mg(i)-1:nyn_mg(i)+1, &
1192                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1193
1194              CASE ( 4 )
1195                 ALLOCATE( wall_flags_4(nzb:nzt_mg(i)+1,         &
1196                                        nys_mg(i)-1:nyn_mg(i)+1, &
1197                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1198
1199              CASE ( 5 )
1200                 ALLOCATE( wall_flags_5(nzb:nzt_mg(i)+1,         &
1201                                        nys_mg(i)-1:nyn_mg(i)+1, &
1202                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1203
1204              CASE ( 6 )
1205                 ALLOCATE( wall_flags_6(nzb:nzt_mg(i)+1,         &
1206                                        nys_mg(i)-1:nyn_mg(i)+1, &
1207                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1208
1209              CASE ( 7 )
1210                 ALLOCATE( wall_flags_7(nzb:nzt_mg(i)+1,         &
1211                                        nys_mg(i)-1:nyn_mg(i)+1, &
1212                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1213
1214              CASE ( 8 )
1215                 ALLOCATE( wall_flags_8(nzb:nzt_mg(i)+1,         &
1216                                        nys_mg(i)-1:nyn_mg(i)+1, &
1217                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1218
1219              CASE ( 9 )
1220                 ALLOCATE( wall_flags_9(nzb:nzt_mg(i)+1,         &
1221                                        nys_mg(i)-1:nyn_mg(i)+1, &
1222                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1223
1224              CASE ( 10 )
1225                 ALLOCATE( wall_flags_10(nzb:nzt_mg(i)+1,        &
1226                                        nys_mg(i)-1:nyn_mg(i)+1, &
1227                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1228
1229              CASE DEFAULT
1230                 message_string = 'more than 10 multigrid levels'
1231                 CALL message( 'init_pegrid', 'PA0238', 1, 2, 0, 6, 0 )
1232
1233          END SELECT
1234
1235       ENDDO
1236
1237    ENDIF
1238
1239!
1240!-- Calculate the number of groups into which parallel I/O is split.
1241!-- The default for files which are opened by all PEs (or where each
1242!-- PE opens his own independent file) is, that all PEs are doing input/output
1243!-- in parallel at the same time. This might cause performance or even more
1244!-- severe problems depending on the configuration of the underlying file
1245!-- system.
1246!-- First, set the default:
1247    IF ( maximum_parallel_io_streams == -1  .OR. &
1248         maximum_parallel_io_streams > numprocs )  THEN
1249       maximum_parallel_io_streams = numprocs
1250    ENDIF
1251
1252!
1253!-- Now calculate the number of io_blocks and the io_group to which the
1254!-- respective PE belongs. I/O of the groups is done in serial, but in parallel
1255!-- for all PEs belonging to the same group. A preliminary setting with myid
1256!-- based on MPI_COMM_WORLD has been done in parin.
1257    io_blocks = numprocs / maximum_parallel_io_streams
1258    io_group  = MOD( myid+1, io_blocks )
1259   
1260
1261 END SUBROUTINE init_pegrid
Note: See TracBrowser for help on using the repository browser.