source: palm/trunk/SOURCE/init_pegrid.f90 @ 1765

Last change on this file since 1765 was 1765, checked in by raasch, 5 years ago

last commit documented

  • Property svn:keywords set to Id
File size: 43.3 KB
Line 
1!> @file init_pegrid.f90
2!--------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the terms
6! of the GNU General Public License as published by the Free Software Foundation,
7! either version 3 of the License, or (at your option) any later version.
8!
9! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
10! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
11! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
12!
13! You should have received a copy of the GNU General Public License along with
14! PALM. If not, see <http://www.gnu.org/licenses/>.
15!
16! Copyright 1997-2014 Leibniz Universitaet Hannover
17!--------------------------------------------------------------------------------!
18!
19! Current revisions:
20! ------------------
21!
22!
23! Former revisions:
24! -----------------
25! $Id: init_pegrid.f90 1765 2016-02-28 13:30:40Z raasch $
26!
27! 1764 2016-02-28 12:45:19Z raasch
28! cpp-statements for nesting removed
29!
30! 1762 2016-02-25 12:31:13Z hellstea
31! Introduction of nested domain feature
32!
33! 1682 2015-10-07 23:56:08Z knoop
34! Code annotations made doxygen readable
35!
36! 1677 2015-10-02 13:25:23Z boeske
37! New MPI-data types for exchange of 3D integer arrays.
38!
39! 1575 2015-03-27 09:56:27Z raasch
40! adjustments for psolver-queries, calculation of ngp_xz added
41!
42! 1565 2015-03-09 20:59:31Z suehring
43! Refine if-clause for setting nbgp.
44!
45! 1557 2015-03-05 16:43:04Z suehring
46! Adjustment for monotonic limiter
47!
48! 1468 2014-09-24 14:06:57Z maronga
49! Adapted for use on up to 6-digit processor cores
50!
51! 1435 2014-07-21 10:37:02Z keck
52! bugfix: added missing parameter coupling_mode_remote to ONLY-attribute
53!
54! 1402 2014-05-09 14:25:13Z raasch
55! location messages modified
56!
57! 1384 2014-05-02 14:31:06Z raasch
58! location messages added
59!
60! 1353 2014-04-08 15:21:23Z heinze
61! REAL constants provided with KIND-attribute
62!
63! 1322 2014-03-20 16:38:49Z raasch
64! REAL functions provided with KIND-attribute
65!
66! 1320 2014-03-20 08:40:49Z raasch
67! ONLY-attribute added to USE-statements,
68! kind-parameters added to all INTEGER and REAL declaration statements,
69! kinds are defined in new module kinds,
70! revision history before 2012 removed,
71! comment fields (!:) to be used for variable explanations added to
72! all variable declaration statements
73!
74! 1304 2014-03-12 10:29:42Z raasch
75! bugfix: single core MPI runs missed some settings of transpose indices
76!
77! 1212 2013-08-15 08:46:27Z raasch
78! error message for poisfft_hybrid removed
79!
80! 1159 2013-05-21 11:58:22Z fricke
81! dirichlet/neumann and neumann/dirichlet removed
82!
83! 1139 2013-04-18 07:25:03Z raasch
84! bugfix for calculating the id of the PE carrying the recycling plane
85!
86! 1111 2013-03-08 23:54:10Z raasch
87! initialization of poisfft moved to module poisfft
88!
89! 1092 2013-02-02 11:24:22Z raasch
90! unused variables removed
91!
92! 1056 2012-11-16 15:28:04Z raasch
93! Indices for arrays n.._mg start from zero due to definition of arrays f2 and
94! p2 as automatic arrays in recursive subroutine next_mg_level
95!
96! 1041 2012-11-06 02:36:29Z raasch
97! a 2d virtual processor topology is used by default for all machines
98!
99! 1036 2012-10-22 13:43:42Z raasch
100! code put under GPL (PALM 3.9)
101!
102! 1003 2012-09-14 14:35:53Z raasch
103! subdomains must have identical size (grid matching = "match" removed)
104!
105! 1001 2012-09-13 14:08:46Z raasch
106! all actions concerning upstream-spline-method removed
107!
108! 978 2012-08-09 08:28:32Z fricke
109! dirichlet/neumann and neumann/dirichlet added
110! nxlu and nysv are also calculated for inflow boundary
111!
112! 809 2012-01-30 13:32:58Z maronga
113! Bugfix: replaced .AND. and .NOT. with && and ! in the preprocessor directives
114!
115! 807 2012-01-25 11:53:51Z maronga
116! New cpp directive "__check" implemented which is used by check_namelist_files
117!
118! Revision 1.1  1997/07/24 11:15:09  raasch
119! Initial revision
120!
121!
122! Description:
123! ------------
124!> Determination of the virtual processor topology (if not prescribed by the
125!> user)and computation of the grid point number and array bounds of the local
126!> domains.
127!------------------------------------------------------------------------------!
128 SUBROUTINE init_pegrid
129 
130
131    USE control_parameters,                                                    &
132        ONLY:  bc_lr, bc_ns, coupling_mode, coupling_mode_remote,              &
133               coupling_topology, dt_dosp, gathered_size, grid_level,          &
134               grid_level_count, host, inflow_l, inflow_n, inflow_r, inflow_s, &
135               io_blocks, io_group, maximum_grid_level,                        &
136               maximum_parallel_io_streams, message_string,                    &
137               mg_switch_to_pe0_level, momentum_advec, nest_bound_l,           &
138               nest_bound_n, nest_bound_r, nest_bound_s, neutral, psolver,     &
139               outflow_l, outflow_n, outflow_r, outflow_s, recycling_width,    &
140               scalar_advec, subdomain_size
141
142    USE grid_variables,                                                        &
143        ONLY:  dx
144       
145    USE indices,                                                               &
146        ONLY:  mg_loc_ind, nbgp, nnx, nny, nnz, nx, nx_a, nx_o, nxl, nxl_mg,   &
147               nxlu, nxr, nxr_mg, ny, ny_a, ny_o, nyn, nyn_mg, nys, nys_mg,    &
148               nysv, nz, nzb, nzt, nzt_mg, wall_flags_1, wall_flags_2,         &
149               wall_flags_3, wall_flags_4, wall_flags_5, wall_flags_6,         &
150               wall_flags_7, wall_flags_8, wall_flags_9, wall_flags_10
151
152    USE kinds
153     
154    USE pegrid
155 
156    USE pmc_interface,                                                         &
157        ONLY:  cpl_npex, cpl_npey, nested_run
158
159    USE transpose_indices,                                                     &
160        ONLY:  nxl_y, nxl_yd, nxl_z, nxr_y, nxr_yd, nxr_z, nyn_x, nyn_z, nys_x,&
161               nys_z, nzb_x, nzb_y, nzb_yd, nzt_x, nzt_yd, nzt_y
162
163    IMPLICIT NONE
164
165    INTEGER(iwp) ::  i                        !<
166    INTEGER(iwp) ::  id_inflow_l              !<
167    INTEGER(iwp) ::  id_recycling_l           !<
168    INTEGER(iwp) ::  ind(5)                   !<
169    INTEGER(iwp) ::  j                        !<
170    INTEGER(iwp) ::  k                        !<
171    INTEGER(iwp) ::  maximum_grid_level_l     !<
172    INTEGER(iwp) ::  mg_levels_x              !<
173    INTEGER(iwp) ::  mg_levels_y              !<
174    INTEGER(iwp) ::  mg_levels_z              !<
175    INTEGER(iwp) ::  mg_switch_to_pe0_level_l !<
176    INTEGER(iwp) ::  nnx_y                    !<
177    INTEGER(iwp) ::  nnx_z                    !<
178    INTEGER(iwp) ::  nny_x                    !<
179    INTEGER(iwp) ::  nny_z                    !<
180    INTEGER(iwp) ::  nnz_x                    !<
181    INTEGER(iwp) ::  nnz_y                    !<
182    INTEGER(iwp) ::  numproc_sqr              !<
183    INTEGER(iwp) ::  nxl_l                    !<
184    INTEGER(iwp) ::  nxr_l                    !<
185    INTEGER(iwp) ::  nyn_l                    !<
186    INTEGER(iwp) ::  nys_l                    !<
187    INTEGER(iwp) ::  nzb_l                    !<
188    INTEGER(iwp) ::  nzt_l                    !<
189    INTEGER(iwp) ::  omp_get_num_threads      !<
190
191    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  ind_all !<
192    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nxlf    !<
193    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nxrf    !<
194    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nynf    !<
195    INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  nysf    !<
196
197    INTEGER(iwp), DIMENSION(2) :: pdims_remote          !<
198
199#if defined( __mpi2 )
200    LOGICAL ::  found                                   !<
201#endif
202
203!
204!-- Get the number of OpenMP threads
205    !$OMP PARALLEL
206#if defined( __intel_openmp_bug )
207    threads_per_task = omp_get_num_threads()
208#else
209!$  threads_per_task = omp_get_num_threads()
210#endif
211    !$OMP END PARALLEL
212
213
214#if defined( __parallel )
215
216    CALL location_message( 'creating virtual PE grids + MPI derived data types', &
217                           .FALSE. )
218
219    IF ( nested_run )  THEN
220!
221!--    In case of nested-domain runs, the processor grid is explicitly given
222!--    by the user in the nestpar-NAMELIST
223       pdims(1) = cpl_npex
224       pdims(2) = cpl_npey
225
226    ELSE
227!
228!--    Determine the processor topology or check it, if prescribed by the user
229       IF ( npex == -1  .AND.  npey == -1 )  THEN
230
231!
232!--       Automatic determination of the topology
233          numproc_sqr = SQRT( REAL( numprocs, KIND=wp ) )
234          pdims(1)    = MAX( numproc_sqr , 1 )
235          DO  WHILE ( MOD( numprocs , pdims(1) ) /= 0 )
236             pdims(1) = pdims(1) - 1
237          ENDDO
238          pdims(2) = numprocs / pdims(1)
239
240       ELSEIF ( npex /= -1  .AND.  npey /= -1 )  THEN
241
242!
243!--       Prescribed by user. Number of processors on the prescribed topology
244!--       must be equal to the number of PEs available to the job
245          IF ( ( npex * npey ) /= numprocs )  THEN
246             WRITE( message_string, * ) 'number of PEs of the prescribed ',   &
247                 'topology (', npex*npey,') does not match & the number of ', & 
248                 'PEs available to the job (', numprocs, ')'
249             CALL message( 'init_pegrid', 'PA0221', 1, 2, 0, 6, 0 )
250          ENDIF
251          pdims(1) = npex
252          pdims(2) = npey
253
254       ELSE
255!
256!--       If the processor topology is prescribed by the user, the number of
257!--       PEs must be given in both directions
258          message_string = 'if the processor topology is prescribed by th' //  &
259                   'e user& both values of "npex" and "npey" must be given' // &
260                   ' in the &NAMELIST-parameter file'
261          CALL message( 'init_pegrid', 'PA0222', 1, 2, 0, 6, 0 )
262
263       ENDIF
264
265    ENDIF
266
267
268!
269!-- For communication speedup, set barriers in front of collective
270!-- communications by default on SGI-type systems
271    IF ( host(3:5) == 'sgi' )  collective_wait = .TRUE.
272
273!
274!-- If necessary, set horizontal boundary conditions to non-cyclic
275    IF ( bc_lr /= 'cyclic' )  cyclic(1) = .FALSE.
276    IF ( bc_ns /= 'cyclic' )  cyclic(2) = .FALSE.
277
278
279#if ! defined( __check)
280!
281!-- Create the virtual processor grid
282    CALL MPI_CART_CREATE( comm_palm, ndim, pdims, cyclic, reorder, &
283                          comm2d, ierr )
284    CALL MPI_COMM_RANK( comm2d, myid, ierr )
285    WRITE (myid_char,'(''_'',I6.6)')  myid
286
287    CALL MPI_CART_COORDS( comm2d, myid, ndim, pcoord, ierr )
288    CALL MPI_CART_SHIFT( comm2d, 0, 1, pleft, pright, ierr )
289    CALL MPI_CART_SHIFT( comm2d, 1, 1, psouth, pnorth, ierr )
290
291!
292!-- Determine sub-topologies for transpositions
293!-- Transposition from z to x:
294    remain_dims(1) = .TRUE.
295    remain_dims(2) = .FALSE.
296    CALL MPI_CART_SUB( comm2d, remain_dims, comm1dx, ierr )
297    CALL MPI_COMM_RANK( comm1dx, myidx, ierr )
298!
299!-- Transposition from x to y
300    remain_dims(1) = .FALSE.
301    remain_dims(2) = .TRUE.
302    CALL MPI_CART_SUB( comm2d, remain_dims, comm1dy, ierr )
303    CALL MPI_COMM_RANK( comm1dy, myidy, ierr )
304
305#endif
306
307!
308!-- Calculate array bounds along x-direction for every PE.
309    ALLOCATE( nxlf(0:pdims(1)-1), nxrf(0:pdims(1)-1), nynf(0:pdims(2)-1), &
310              nysf(0:pdims(2)-1) )
311
312    IF ( MOD( nx+1 , pdims(1) ) /= 0 )  THEN
313       WRITE( message_string, * ) 'x-direction: gridpoint number (',nx+1,') ',&
314                               'is not an& integral divisor of the number ',  &
315                               'processors (', pdims(1),')'
316       CALL message( 'init_pegrid', 'PA0225', 1, 2, 0, 6, 0 )
317    ELSE
318       nnx  = ( nx + 1 ) / pdims(1)
319       IF ( nnx*pdims(1) - ( nx + 1) > nnx )  THEN
320          WRITE( message_string, * ) 'x-direction: nx does not match the',    & 
321                       'requirements given by the number of PEs &used',       &
322                       '& please use nx = ', nx - ( pdims(1) - ( nnx*pdims(1) &
323                                   - ( nx + 1 ) ) ), ' instead of nx =', nx
324          CALL message( 'init_pegrid', 'PA0226', 1, 2, 0, 6, 0 )
325       ENDIF
326    ENDIF   
327
328!
329!-- Left and right array bounds, number of gridpoints
330    DO  i = 0, pdims(1)-1
331       nxlf(i)   = i * nnx
332       nxrf(i)   = ( i + 1 ) * nnx - 1
333    ENDDO
334
335!
336!-- Calculate array bounds in y-direction for every PE.
337    IF ( MOD( ny+1 , pdims(2) ) /= 0 )  THEN
338       WRITE( message_string, * ) 'y-direction: gridpoint number (',ny+1,') ', &
339                           'is not an& integral divisor of the number of',     &
340                           'processors (', pdims(2),')'
341       CALL message( 'init_pegrid', 'PA0227', 1, 2, 0, 6, 0 )
342    ELSE
343       nny  = ( ny + 1 ) / pdims(2)
344       IF ( nny*pdims(2) - ( ny + 1) > nny )  THEN
345          WRITE( message_string, * ) 'y-direction: ny does not match the',    &
346                       'requirements given by the number of PEs &used ',      &
347                       '& please use ny = ', ny - ( pdims(2) - ( nnx*pdims(2) &
348                                     - ( ny + 1 ) ) ), ' instead of ny =', ny
349          CALL message( 'init_pegrid', 'PA0228', 1, 2, 0, 6, 0 )
350       ENDIF
351    ENDIF   
352
353!
354!-- South and north array bounds
355    DO  j = 0, pdims(2)-1
356       nysf(j)   = j * nny
357       nynf(j)   = ( j + 1 ) * nny - 1
358    ENDDO
359
360!
361!-- Local array bounds of the respective PEs
362    nxl = nxlf(pcoord(1))
363    nxr = nxrf(pcoord(1))
364    nys = nysf(pcoord(2))
365    nyn = nynf(pcoord(2))
366    nzb = 0
367    nzt = nz
368    nnz = nz
369
370!
371!-- Set switches to define if the PE is situated at the border of the virtual
372!-- processor grid
373    IF ( nxl == 0 )   left_border_pe  = .TRUE.
374    IF ( nxr == nx )  right_border_pe = .TRUE.
375    IF ( nys == 0 )   south_border_pe = .TRUE.
376    IF ( nyn == ny )  north_border_pe = .TRUE.
377
378!
379!-- Calculate array bounds and gridpoint numbers for the transposed arrays
380!-- (needed in the pressure solver)
381!-- For the transposed arrays, cyclic boundaries as well as top and bottom
382!-- boundaries are omitted, because they are obstructive to the transposition
383
384!
385!-- 1. transposition  z --> x
386!-- This transposition is not neccessary in case of a 1d-decomposition along x
387    nys_x = nys
388    nyn_x = nyn
389    nny_x = nny
390    nnz_x = nz / pdims(1)
391    nzb_x = 1 + myidx * nnz_x
392    nzt_x = ( myidx + 1 ) * nnz_x
393    sendrecvcount_zx = nnx * nny * nnz_x
394
395    IF ( pdims(2) /= 1 )  THEN
396       IF ( MOD( nz , pdims(1) ) /= 0 )  THEN
397          WRITE( message_string, * ) 'transposition z --> x:',                &
398                       '&nz=',nz,' is not an integral divisior of pdims(1)=', &
399                                                                   pdims(1)
400          CALL message( 'init_pegrid', 'PA0230', 1, 2, 0, 6, 0 )
401       ENDIF
402    ENDIF
403
404!
405!-- 2. transposition  x --> y
406    nnz_y = nnz_x
407    nzb_y = nzb_x
408    nzt_y = nzt_x
409    IF ( MOD( nx+1 , pdims(2) ) /= 0 )  THEN
410       WRITE( message_string, * ) 'transposition x --> y:',                &
411                         '&nx+1=',nx+1,' is not an integral divisor of ',&
412                         'pdims(2)=',pdims(2)
413       CALL message( 'init_pegrid', 'PA0231', 1, 2, 0, 6, 0 )
414    ENDIF
415    nnx_y = (nx+1) / pdims(2)
416    nxl_y = myidy * nnx_y
417    nxr_y = ( myidy + 1 ) * nnx_y - 1
418    sendrecvcount_xy = nnx_y * nny_x * nnz_y
419
420!
421!-- 3. transposition  y --> z  (ELSE:  x --> y  in case of 1D-decomposition
422!-- along x)
423    nnx_z = nnx_y
424    nxl_z = nxl_y
425    nxr_z = nxr_y
426    nny_z = (ny+1) / pdims(1)
427    nys_z = myidx * nny_z
428    nyn_z = ( myidx + 1 ) * nny_z - 1
429    sendrecvcount_yz = nnx_y * nny_z * nnz_y
430
431    IF ( pdims(2) /= 1 )  THEN
432!
433!--    y --> z
434!--    This transposition is not neccessary in case of a 1d-decomposition
435!--    along x, except that the uptream-spline method is switched on
436       IF ( MOD( ny+1 , pdims(1) ) /= 0 )  THEN
437          WRITE( message_string, * ) 'transposition y --> z:',            &
438                            '& ny+1=',ny+1,' is not an integral divisor of ',&
439                            'pdims(1)=',pdims(1)
440          CALL message( 'init_pegrid', 'PA0232', 1, 2, 0, 6, 0 )
441       ENDIF
442
443    ELSE
444!
445!--    x --> y. This condition must be fulfilled for a 1D-decomposition along x
446       IF ( MOD( ny+1 , pdims(1) ) /= 0 )  THEN
447          WRITE( message_string, * ) 'transposition x --> y:',               &
448                            '& ny+1=',ny+1,' is not an integral divisor of ',&
449                            'pdims(1)=',pdims(1)
450          CALL message( 'init_pegrid', 'PA0233', 1, 2, 0, 6, 0 )
451       ENDIF
452
453    ENDIF
454
455!
456!-- Indices for direct transpositions z --> y (used for calculating spectra)
457    IF ( dt_dosp /= 9999999.9_wp )  THEN
458       IF ( MOD( nz, pdims(2) ) /= 0 )  THEN
459          WRITE( message_string, * ) 'direct transposition z --> y (needed ', &
460                    'for spectra):& nz=',nz,' is not an integral divisor of ',&
461                    'pdims(2)=',pdims(2)
462          CALL message( 'init_pegrid', 'PA0234', 1, 2, 0, 6, 0 )
463       ELSE
464          nxl_yd = nxl
465          nxr_yd = nxr
466          nzb_yd = 1 + myidy * ( nz / pdims(2) )
467          nzt_yd = ( myidy + 1 ) * ( nz / pdims(2) )
468          sendrecvcount_zyd = nnx * nny * ( nz / pdims(2) )
469       ENDIF
470    ENDIF
471
472!
473!-- Indices for direct transpositions y --> x (they are only possible in case
474!-- of a 1d-decomposition along x)
475    IF ( pdims(2) == 1 )  THEN
476       nny_x = nny / pdims(1)
477       nys_x = myid * nny_x
478       nyn_x = ( myid + 1 ) * nny_x - 1
479       nzb_x = 1
480       nzt_x = nz
481       sendrecvcount_xy = nnx * nny_x * nz
482    ENDIF
483
484!
485!-- Indices for direct transpositions x --> y (they are only possible in case
486!-- of a 1d-decomposition along y)
487    IF ( pdims(1) == 1 )  THEN
488       nnx_y = nnx / pdims(2)
489       nxl_y = myid * nnx_y
490       nxr_y = ( myid + 1 ) * nnx_y - 1
491       nzb_y = 1
492       nzt_y = nz
493       sendrecvcount_xy = nnx_y * nny * nz
494    ENDIF
495
496!
497!-- Arrays for storing the array bounds are needed any more
498    DEALLOCATE( nxlf , nxrf , nynf , nysf )
499
500
501#if ! defined( __check)
502!
503!-- Collect index bounds from other PEs (to be written to restart file later)
504    ALLOCATE( hor_index_bounds(4,0:numprocs-1) )
505
506    IF ( myid == 0 )  THEN
507
508       hor_index_bounds(1,0) = nxl
509       hor_index_bounds(2,0) = nxr
510       hor_index_bounds(3,0) = nys
511       hor_index_bounds(4,0) = nyn
512
513!
514!--    Receive data from all other PEs
515       DO  i = 1, numprocs-1
516          CALL MPI_RECV( ibuf, 4, MPI_INTEGER, i, MPI_ANY_TAG, comm2d, status, &
517                         ierr )
518          hor_index_bounds(:,i) = ibuf(1:4)
519       ENDDO
520
521    ELSE
522!
523!--    Send index bounds to PE0
524       ibuf(1) = nxl
525       ibuf(2) = nxr
526       ibuf(3) = nys
527       ibuf(4) = nyn
528       CALL MPI_SEND( ibuf, 4, MPI_INTEGER, 0, myid, comm2d, ierr )
529
530    ENDIF
531
532#endif
533
534#if defined( __print )
535!
536!-- Control output
537    IF ( myid == 0 )  THEN
538       PRINT*, '*** processor topology ***'
539       PRINT*, ' '
540       PRINT*, 'myid   pcoord    left right  south north  idx idy   nxl: nxr',&
541               &'   nys: nyn'
542       PRINT*, '------------------------------------------------------------',&
543               &'-----------'
544       WRITE (*,1000)  0, pcoord(1), pcoord(2), pleft, pright, psouth, pnorth, &
545                       myidx, myidy, nxl, nxr, nys, nyn
5461000   FORMAT (I4,2X,'(',I3,',',I3,')',3X,I4,2X,I4,3X,I4,2X,I4,2X,I3,1X,I3, &
547               2(2X,I4,':',I4))
548
549!
550!--    Receive data from the other PEs
551       DO  i = 1,numprocs-1
552          CALL MPI_RECV( ibuf, 12, MPI_INTEGER, i, MPI_ANY_TAG, comm2d, status, &
553                         ierr )
554          WRITE (*,1000)  i, ( ibuf(j) , j = 1,12 )
555       ENDDO
556    ELSE
557
558!
559!--    Send data to PE0
560       ibuf(1) = pcoord(1); ibuf(2) = pcoord(2); ibuf(3) = pleft
561       ibuf(4) = pright; ibuf(5) = psouth; ibuf(6) = pnorth; ibuf(7) = myidx
562       ibuf(8) = myidy; ibuf(9) = nxl; ibuf(10) = nxr; ibuf(11) = nys
563       ibuf(12) = nyn
564       CALL MPI_SEND( ibuf, 12, MPI_INTEGER, 0, myid, comm2d, ierr )       
565    ENDIF
566#endif
567
568#if defined( __parallel ) && ! defined( __check)
569#if defined( __mpi2 )
570!
571!-- In case of coupled runs, get the port name on PE0 of the atmosphere model
572!-- and pass it to PE0 of the ocean model
573    IF ( myid == 0 )  THEN
574
575       IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
576
577          CALL MPI_OPEN_PORT( MPI_INFO_NULL, port_name, ierr )
578
579          CALL MPI_PUBLISH_NAME( 'palm_coupler', MPI_INFO_NULL, port_name, &
580                                 ierr )
581
582!
583!--       Write a flag file for the ocean model and the other atmosphere
584!--       processes.
585!--       There seems to be a bug in MPICH2 which causes hanging processes
586!--       in case that execution of LOOKUP_NAME is continued too early
587!--       (i.e. before the port has been created)
588          OPEN( 90, FILE='COUPLING_PORT_OPENED', FORM='FORMATTED' )
589          WRITE ( 90, '(''TRUE'')' )
590          CLOSE ( 90 )
591
592       ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
593
594!
595!--       Continue only if the atmosphere model has created the port.
596!--       There seems to be a bug in MPICH2 which causes hanging processes
597!--       in case that execution of LOOKUP_NAME is continued too early
598!--       (i.e. before the port has been created)
599          INQUIRE( FILE='COUPLING_PORT_OPENED', EXIST=found )
600          DO WHILE ( .NOT. found )
601             INQUIRE( FILE='COUPLING_PORT_OPENED', EXIST=found )
602          ENDDO
603
604          CALL MPI_LOOKUP_NAME( 'palm_coupler', MPI_INFO_NULL, port_name, ierr )
605
606       ENDIF
607
608    ENDIF
609
610!
611!-- In case of coupled runs, establish the connection between the atmosphere
612!-- and the ocean model and define the intercommunicator (comm_inter)
613    CALL MPI_BARRIER( comm2d, ierr )
614    IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
615
616       CALL MPI_COMM_ACCEPT( port_name, MPI_INFO_NULL, 0, MPI_COMM_WORLD, &
617                             comm_inter, ierr )
618       coupling_mode_remote = 'ocean_to_atmosphere'
619
620    ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
621
622       CALL MPI_COMM_CONNECT( port_name, MPI_INFO_NULL, 0, MPI_COMM_WORLD, &
623                              comm_inter, ierr )
624       coupling_mode_remote = 'atmosphere_to_ocean'
625
626    ENDIF
627#endif
628
629!
630!-- Determine the number of ghost point layers
631    IF ( ( scalar_advec == 'ws-scheme' .AND. .NOT. neutral ) .OR.             &
632         scalar_advec == 'ws-scheme-mono' .OR.                                &
633         momentum_advec == 'ws-scheme' )  THEN
634       nbgp = 3
635    ELSE
636       nbgp = 1
637    ENDIF
638
639!
640!-- Create a new MPI derived datatype for the exchange of surface (xy) data,
641!-- which is needed for coupled atmosphere-ocean runs.
642!-- First, calculate number of grid points of an xy-plane.
643    ngp_xy  = ( nxr - nxl + 1 + 2 * nbgp ) * ( nyn - nys + 1 + 2 * nbgp )
644    CALL MPI_TYPE_VECTOR( ngp_xy, 1, nzt-nzb+2, MPI_REAL, type_xy, ierr )
645    CALL MPI_TYPE_COMMIT( type_xy, ierr )
646
647    IF ( TRIM( coupling_mode ) /= 'uncoupled' )  THEN
648   
649!
650!--    Pass the number of grid points of the atmosphere model to
651!--    the ocean model and vice versa
652       IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
653
654          nx_a = nx
655          ny_a = ny
656
657          IF ( myid == 0 )  THEN
658
659             CALL MPI_SEND( nx_a, 1, MPI_INTEGER, numprocs, 1, comm_inter,  &
660                            ierr )
661             CALL MPI_SEND( ny_a, 1, MPI_INTEGER, numprocs, 2, comm_inter,  &
662                            ierr )
663             CALL MPI_SEND( pdims, 2, MPI_INTEGER, numprocs, 3, comm_inter, &
664                            ierr )
665             CALL MPI_RECV( nx_o, 1, MPI_INTEGER, numprocs, 4, comm_inter,  &
666                            status, ierr )
667             CALL MPI_RECV( ny_o, 1, MPI_INTEGER, numprocs, 5, comm_inter,  &
668                            status, ierr )
669             CALL MPI_RECV( pdims_remote, 2, MPI_INTEGER, numprocs, 6,      &
670                            comm_inter, status, ierr )
671          ENDIF
672
673          CALL MPI_BCAST( nx_o, 1, MPI_INTEGER, 0, comm2d, ierr )
674          CALL MPI_BCAST( ny_o, 1, MPI_INTEGER, 0, comm2d, ierr ) 
675          CALL MPI_BCAST( pdims_remote, 2, MPI_INTEGER, 0, comm2d, ierr )
676       
677       ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
678
679          nx_o = nx
680          ny_o = ny
681
682          IF ( myid == 0 ) THEN
683
684             CALL MPI_RECV( nx_a, 1, MPI_INTEGER, 0, 1, comm_inter, status, &
685                            ierr )
686             CALL MPI_RECV( ny_a, 1, MPI_INTEGER, 0, 2, comm_inter, status, &
687                            ierr )
688             CALL MPI_RECV( pdims_remote, 2, MPI_INTEGER, 0, 3, comm_inter, &
689                            status, ierr )
690             CALL MPI_SEND( nx_o, 1, MPI_INTEGER, 0, 4, comm_inter, ierr )
691             CALL MPI_SEND( ny_o, 1, MPI_INTEGER, 0, 5, comm_inter, ierr )
692             CALL MPI_SEND( pdims, 2, MPI_INTEGER, 0, 6, comm_inter, ierr )
693          ENDIF
694
695          CALL MPI_BCAST( nx_a, 1, MPI_INTEGER, 0, comm2d, ierr)
696          CALL MPI_BCAST( ny_a, 1, MPI_INTEGER, 0, comm2d, ierr) 
697          CALL MPI_BCAST( pdims_remote, 2, MPI_INTEGER, 0, comm2d, ierr) 
698
699       ENDIF
700 
701       ngp_a = ( nx_a+1 + 2 * nbgp ) * ( ny_a+1 + 2 * nbgp )
702       ngp_o = ( nx_o+1 + 2 * nbgp ) * ( ny_o+1 + 2 * nbgp )
703
704!
705!--    Determine if the horizontal grid and the number of PEs in ocean and
706!--    atmosphere is same or not
707       IF ( nx_o == nx_a  .AND.  ny_o == ny_a  .AND.  &
708            pdims(1) == pdims_remote(1) .AND. pdims(2) == pdims_remote(2) ) &
709       THEN
710          coupling_topology = 0
711       ELSE
712          coupling_topology = 1
713       ENDIF
714
715!
716!--    Determine the target PEs for the exchange between ocean and
717!--    atmosphere (comm2d)
718       IF ( coupling_topology == 0 )  THEN
719!
720!--       In case of identical topologies, every atmosphere PE has exactly one
721!--       ocean PE counterpart and vice versa
722          IF ( TRIM( coupling_mode ) == 'atmosphere_to_ocean' ) THEN
723             target_id = myid + numprocs
724          ELSE
725             target_id = myid
726          ENDIF
727
728       ELSE
729!
730!--       In case of nonequivalent topology in ocean and atmosphere only for
731!--       PE0 in ocean and PE0 in atmosphere a target_id is needed, since
732!--       data echxchange between ocean and atmosphere will be done only
733!--       between these PEs.   
734          IF ( myid == 0 )  THEN
735
736             IF ( TRIM( coupling_mode ) == 'atmosphere_to_ocean' )  THEN
737                target_id = numprocs
738             ELSE
739                target_id = 0
740             ENDIF
741
742          ENDIF
743
744       ENDIF
745
746    ENDIF
747
748
749#endif
750
751#else
752
753!
754!-- Array bounds when running on a single PE (respectively a non-parallel
755!-- machine)
756    nxl = 0
757    nxr = nx
758    nnx = nxr - nxl + 1
759    nys = 0
760    nyn = ny
761    nny = nyn - nys + 1
762    nzb = 0
763    nzt = nz
764    nnz = nz
765
766    ALLOCATE( hor_index_bounds(4,0:0) )
767    hor_index_bounds(1,0) = nxl
768    hor_index_bounds(2,0) = nxr
769    hor_index_bounds(3,0) = nys
770    hor_index_bounds(4,0) = nyn
771
772!
773!-- Array bounds for the pressure solver (in the parallel code, these bounds
774!-- are the ones for the transposed arrays)
775    nys_x = nys
776    nyn_x = nyn
777    nzb_x = nzb + 1
778    nzt_x = nzt
779
780    nxl_y = nxl
781    nxr_y = nxr
782    nzb_y = nzb + 1
783    nzt_y = nzt
784
785    nxl_z = nxl
786    nxr_z = nxr
787    nys_z = nys
788    nyn_z = nyn
789
790#endif
791
792!
793!-- Calculate number of grid levels necessary for the multigrid poisson solver
794!-- as well as the gridpoint indices on each level
795    IF ( psolver(1:9) == 'multigrid' )  THEN
796
797!
798!--    First calculate number of possible grid levels for the subdomains
799       mg_levels_x = 1
800       mg_levels_y = 1
801       mg_levels_z = 1
802
803       i = nnx
804       DO WHILE ( MOD( i, 2 ) == 0  .AND.  i /= 2 )
805          i = i / 2
806          mg_levels_x = mg_levels_x + 1
807       ENDDO
808
809       j = nny
810       DO WHILE ( MOD( j, 2 ) == 0  .AND.  j /= 2 )
811          j = j / 2
812          mg_levels_y = mg_levels_y + 1
813       ENDDO
814
815       k = nz    ! do not use nnz because it might be > nz due to transposition
816                 ! requirements
817       DO WHILE ( MOD( k, 2 ) == 0  .AND.  k /= 2 )
818          k = k / 2
819          mg_levels_z = mg_levels_z + 1
820       ENDDO
821
822       maximum_grid_level = MIN( mg_levels_x, mg_levels_y, mg_levels_z )
823
824!
825!--    Find out, if the total domain allows more levels. These additional
826!--    levels are identically processed on all PEs.
827       IF ( numprocs > 1  .AND.  mg_switch_to_pe0_level /= -1 )  THEN
828
829          IF ( mg_levels_z > MIN( mg_levels_x, mg_levels_y ) )  THEN
830
831             mg_switch_to_pe0_level_l = maximum_grid_level
832
833             mg_levels_x = 1
834             mg_levels_y = 1
835
836             i = nx+1
837             DO WHILE ( MOD( i, 2 ) == 0  .AND.  i /= 2 )
838                i = i / 2
839                mg_levels_x = mg_levels_x + 1
840             ENDDO
841
842             j = ny+1
843             DO WHILE ( MOD( j, 2 ) == 0  .AND.  j /= 2 )
844                j = j / 2
845                mg_levels_y = mg_levels_y + 1
846             ENDDO
847
848             maximum_grid_level_l = MIN( mg_levels_x, mg_levels_y, mg_levels_z )
849
850             IF ( maximum_grid_level_l > mg_switch_to_pe0_level_l )  THEN
851                mg_switch_to_pe0_level_l = maximum_grid_level_l - &
852                                           mg_switch_to_pe0_level_l + 1
853             ELSE
854                mg_switch_to_pe0_level_l = 0
855             ENDIF
856
857          ELSE
858             mg_switch_to_pe0_level_l = 0
859             maximum_grid_level_l = maximum_grid_level
860
861          ENDIF
862
863!
864!--       Use switch level calculated above only if it is not pre-defined
865!--       by user
866          IF ( mg_switch_to_pe0_level == 0 )  THEN
867             IF ( mg_switch_to_pe0_level_l /= 0 )  THEN
868                mg_switch_to_pe0_level = mg_switch_to_pe0_level_l
869                maximum_grid_level     = maximum_grid_level_l
870             ENDIF
871
872          ELSE
873!
874!--          Check pre-defined value and reset to default, if neccessary
875             IF ( mg_switch_to_pe0_level < mg_switch_to_pe0_level_l  .OR.  &
876                  mg_switch_to_pe0_level >= maximum_grid_level_l )  THEN
877                message_string = 'mg_switch_to_pe0_level ' // &
878                                 'out of range and reset to default (=0)'
879                CALL message( 'init_pegrid', 'PA0235', 0, 1, 0, 6, 0 )
880                mg_switch_to_pe0_level = 0
881             ELSE
882!
883!--             Use the largest number of possible levels anyway and recalculate
884!--             the switch level to this largest number of possible values
885                maximum_grid_level = maximum_grid_level_l
886
887             ENDIF
888
889          ENDIF
890
891       ENDIF
892
893       ALLOCATE( grid_level_count(maximum_grid_level),                       &
894                 nxl_mg(0:maximum_grid_level), nxr_mg(0:maximum_grid_level), &
895                 nyn_mg(0:maximum_grid_level), nys_mg(0:maximum_grid_level), &
896                 nzt_mg(0:maximum_grid_level) )
897
898       grid_level_count = 0
899!
900!--    Index zero required as dummy due to definition of arrays f2 and p2 in
901!--    recursive subroutine next_mg_level
902       nxl_mg(0) = 0; nxr_mg(0) = 0; nyn_mg(0) = 0; nys_mg(0) = 0; nzt_mg(0) = 0
903
904       nxl_l = nxl; nxr_l = nxr; nys_l = nys; nyn_l = nyn; nzt_l = nzt
905
906       DO  i = maximum_grid_level, 1 , -1
907
908          IF ( i == mg_switch_to_pe0_level )  THEN
909#if defined( __parallel ) && ! defined( __check )
910!
911!--          Save the grid size of the subdomain at the switch level, because
912!--          it is needed in poismg.
913             ind(1) = nxl_l; ind(2) = nxr_l
914             ind(3) = nys_l; ind(4) = nyn_l
915             ind(5) = nzt_l
916             ALLOCATE( ind_all(5*numprocs), mg_loc_ind(5,0:numprocs-1) )
917             CALL MPI_ALLGATHER( ind, 5, MPI_INTEGER, ind_all, 5, &
918                                 MPI_INTEGER, comm2d, ierr )
919             DO  j = 0, numprocs-1
920                DO  k = 1, 5
921                   mg_loc_ind(k,j) = ind_all(k+j*5)
922                ENDDO
923             ENDDO
924             DEALLOCATE( ind_all )
925!
926!--          Calculate the grid size of the total domain
927             nxr_l = ( nxr_l-nxl_l+1 ) * pdims(1) - 1
928             nxl_l = 0
929             nyn_l = ( nyn_l-nys_l+1 ) * pdims(2) - 1
930             nys_l = 0
931!
932!--          The size of this gathered array must not be larger than the
933!--          array tend, which is used in the multigrid scheme as a temporary
934!--          array. Therefore the subdomain size of an PE is calculated and
935!--          the size of the gathered grid. These values are used in 
936!--          routines pres and poismg
937             subdomain_size = ( nxr - nxl + 2 * nbgp + 1 ) * &
938                              ( nyn - nys + 2 * nbgp + 1 ) * ( nzt - nzb + 2 )
939             gathered_size  = ( nxr_l - nxl_l + 3 ) * ( nyn_l - nys_l + 3 ) * &
940                              ( nzt_l - nzb + 2 )
941
942#elif ! defined ( __parallel )
943             message_string = 'multigrid gather/scatter impossible ' // &
944                          'in non parallel mode'
945             CALL message( 'init_pegrid', 'PA0237', 1, 2, 0, 6, 0 )
946#endif
947          ENDIF
948
949          nxl_mg(i) = nxl_l
950          nxr_mg(i) = nxr_l
951          nys_mg(i) = nys_l
952          nyn_mg(i) = nyn_l
953          nzt_mg(i) = nzt_l
954
955          nxl_l = nxl_l / 2 
956          nxr_l = nxr_l / 2
957          nys_l = nys_l / 2 
958          nyn_l = nyn_l / 2 
959          nzt_l = nzt_l / 2 
960
961       ENDDO
962
963!
964!--    Temporary problem: Currently calculation of maxerror iin routine poismg crashes
965!--    if grid data are collected on PE0 already on the finest grid level.
966!--    To be solved later.
967       IF ( maximum_grid_level == mg_switch_to_pe0_level )  THEN
968          message_string = 'grid coarsening on subdomain level cannot be performed'
969          CALL message( 'poismg', 'PA0236', 1, 2, 0, 6, 0 )
970       ENDIF
971
972    ELSE
973
974       maximum_grid_level = 0
975
976    ENDIF
977
978!
979!-- Default level 0 tells exchange_horiz that all ghost planes have to be
980!-- exchanged. grid_level is adjusted in poismg, where only one ghost plane
981!-- is required.
982    grid_level = 0
983
984#if defined( __parallel ) && ! defined ( __check )
985!
986!-- Gridpoint number for the exchange of ghost points (y-line for 2D-arrays)
987    ngp_y  = nyn - nys + 1 + 2 * nbgp
988
989!
990!-- Define new MPI derived datatypes for the exchange of ghost points in
991!-- x- and y-direction for 2D-arrays (line)
992    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp, ngp_y, MPI_REAL, type_x, &
993                          ierr )
994    CALL MPI_TYPE_COMMIT( type_x, ierr )
995    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp, ngp_y, MPI_INTEGER, &
996                          type_x_int, ierr )
997    CALL MPI_TYPE_COMMIT( type_x_int, ierr )
998
999    CALL MPI_TYPE_VECTOR( nbgp, ngp_y, ngp_y, MPI_REAL, type_y, ierr )
1000    CALL MPI_TYPE_COMMIT( type_y, ierr )
1001    CALL MPI_TYPE_VECTOR( nbgp, ngp_y, ngp_y, MPI_INTEGER, type_y_int, ierr )
1002    CALL MPI_TYPE_COMMIT( type_y_int, ierr )
1003
1004
1005!
1006!-- Calculate gridpoint numbers for the exchange of ghost points along x
1007!-- (yz-plane for 3D-arrays) and define MPI derived data type(s) for the
1008!-- exchange of ghost points in y-direction (xz-plane).
1009!-- Do these calculations for the model grid and (if necessary) also
1010!-- for the coarser grid levels used in the multigrid method
1011    ALLOCATE ( ngp_xz(0:maximum_grid_level), ngp_yz(0:maximum_grid_level),     &
1012               type_xz(0:maximum_grid_level), type_yz(0:maximum_grid_level) )
1013
1014    nxl_l = nxl; nxr_l = nxr; nys_l = nys; nyn_l = nyn; nzb_l = nzb; nzt_l = nzt
1015
1016!
1017!-- Discern between the model grid, which needs nbgp ghost points and
1018!-- grid levels for the multigrid scheme. In the latter case only one
1019!-- ghost point is necessary.
1020!-- First definition of MPI-datatypes for exchange of ghost layers on normal
1021!-- grid. The following loop is needed for data exchange in poismg.f90.
1022!
1023!-- Determine number of grid points of yz-layer for exchange
1024    ngp_yz(0) = (nzt - nzb + 2) * (nyn - nys + 1 + 2 * nbgp)
1025
1026!
1027!-- Define an MPI-datatype for the exchange of left/right boundaries.
1028!-- Although data are contiguous in physical memory (which does not
1029!-- necessarily require an MPI-derived datatype), the data exchange between
1030!-- left and right PE's using the MPI-derived type is 10% faster than without.
1031    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp*(nzt-nzb+2), ngp_yz(0), &
1032                          MPI_REAL, type_xz(0), ierr )
1033    CALL MPI_TYPE_COMMIT( type_xz(0), ierr )
1034
1035    CALL MPI_TYPE_VECTOR( nbgp, ngp_yz(0), ngp_yz(0), MPI_REAL, type_yz(0), &
1036                          ierr ) 
1037    CALL MPI_TYPE_COMMIT( type_yz(0), ierr )
1038
1039!
1040!-- Definition of MPI-datatypes for multigrid method (coarser level grids)
1041    IF ( psolver(1:9) == 'multigrid' )  THEN
1042!   
1043!--    Definition of MPI-datatyoe as above, but only 1 ghost level is used
1044       DO  i = maximum_grid_level, 1 , -1
1045
1046          ngp_xz(i) = (nzt_l - nzb_l + 2) * (nxr_l - nxl_l + 3)
1047          ngp_yz(i) = (nzt_l - nzb_l + 2) * (nyn_l - nys_l + 3)
1048
1049          CALL MPI_TYPE_VECTOR( nxr_l-nxl_l+3, nzt_l-nzb_l+2, ngp_yz(i), &
1050                                MPI_REAL, type_xz(i), ierr )
1051          CALL MPI_TYPE_COMMIT( type_xz(i), ierr )
1052
1053          CALL MPI_TYPE_VECTOR( 1, ngp_yz(i), ngp_yz(i), MPI_REAL, type_yz(i), &
1054                                ierr )
1055          CALL MPI_TYPE_COMMIT( type_yz(i), ierr )
1056
1057          nxl_l = nxl_l / 2
1058          nxr_l = nxr_l / 2
1059          nys_l = nys_l / 2
1060          nyn_l = nyn_l / 2
1061          nzt_l = nzt_l / 2
1062
1063       ENDDO
1064
1065    ENDIF
1066!
1067!-- Define data types for exchange of 3D Integer arrays.
1068    ngp_yz_int = (nzt - nzb + 2) * (nyn - nys + 1 + 2 * nbgp)
1069
1070    CALL MPI_TYPE_VECTOR( nxr-nxl+1+2*nbgp, nbgp*(nzt-nzb+2), ngp_yz_int, &
1071                          MPI_INTEGER, type_xz_int, ierr )
1072    CALL MPI_TYPE_COMMIT( type_xz_int, ierr )
1073
1074    CALL MPI_TYPE_VECTOR( nbgp, ngp_yz_int, ngp_yz_int, MPI_INTEGER, type_yz_int, &
1075                          ierr )
1076    CALL MPI_TYPE_COMMIT( type_yz_int, ierr )
1077
1078#endif
1079
1080#if defined( __parallel ) && ! defined ( __check )
1081!
1082!-- Setting of flags for inflow/outflow/nesting conditions in case of non-cyclic
1083!-- horizontal boundary conditions.
1084    IF ( pleft == MPI_PROC_NULL )  THEN
1085       IF ( bc_lr == 'dirichlet/radiation' )  THEN
1086          inflow_l  = .TRUE.
1087       ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1088          outflow_l = .TRUE.
1089       ELSEIF ( bc_lr == 'nested' )  THEN
1090          nest_bound_l = .TRUE.
1091       ENDIF
1092    ENDIF
1093
1094    IF ( pright == MPI_PROC_NULL )  THEN
1095       IF ( bc_lr == 'dirichlet/radiation' )  THEN
1096          outflow_r = .TRUE.
1097       ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1098          inflow_r  = .TRUE.
1099       ELSEIF ( bc_lr == 'nested' )  THEN
1100          nest_bound_r = .TRUE.
1101       ENDIF
1102    ENDIF
1103
1104    IF ( psouth == MPI_PROC_NULL )  THEN
1105       IF ( bc_ns == 'dirichlet/radiation' )  THEN
1106          outflow_s = .TRUE.
1107       ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1108          inflow_s  = .TRUE.
1109       ELSEIF ( bc_ns == 'nested' )  THEN
1110          nest_bound_s = .TRUE.
1111       ENDIF
1112    ENDIF
1113
1114    IF ( pnorth == MPI_PROC_NULL )  THEN
1115       IF ( bc_ns == 'dirichlet/radiation' )  THEN
1116          inflow_n  = .TRUE.
1117       ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1118          outflow_n = .TRUE.
1119       ELSEIF ( bc_ns == 'nested' )  THEN
1120          nest_bound_n = .TRUE.
1121       ENDIF
1122    ENDIF
1123
1124!
1125!-- Broadcast the id of the inflow PE
1126    IF ( inflow_l )  THEN
1127       id_inflow_l = myidx
1128    ELSE
1129       id_inflow_l = 0
1130    ENDIF
1131    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1132    CALL MPI_ALLREDUCE( id_inflow_l, id_inflow, 1, MPI_INTEGER, MPI_SUM, &
1133                        comm1dx, ierr )
1134
1135!
1136!-- Broadcast the id of the recycling plane
1137!-- WARNING: needs to be adjusted in case of inflows other than from left side!
1138    IF ( NINT( recycling_width / dx ) >= nxl  .AND. &
1139         NINT( recycling_width / dx ) <= nxr )  THEN
1140       id_recycling_l = myidx
1141    ELSE
1142       id_recycling_l = 0
1143    ENDIF
1144    IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1145    CALL MPI_ALLREDUCE( id_recycling_l, id_recycling, 1, MPI_INTEGER, MPI_SUM, &
1146                        comm1dx, ierr )
1147
1148    CALL location_message( 'finished', .TRUE. )
1149
1150#elif ! defined ( __parallel )
1151    IF ( bc_lr == 'dirichlet/radiation' )  THEN
1152       inflow_l  = .TRUE.
1153       outflow_r = .TRUE.
1154    ELSEIF ( bc_lr == 'radiation/dirichlet' )  THEN
1155       outflow_l = .TRUE.
1156       inflow_r  = .TRUE.
1157    ENDIF
1158
1159    IF ( bc_ns == 'dirichlet/radiation' )  THEN
1160       inflow_n  = .TRUE.
1161       outflow_s = .TRUE.
1162    ELSEIF ( bc_ns == 'radiation/dirichlet' )  THEN
1163       outflow_n = .TRUE.
1164       inflow_s  = .TRUE.
1165    ENDIF
1166#endif
1167
1168!
1169!-- At the inflow or outflow, u or v, respectively, have to be calculated for
1170!-- one more grid point.
1171    IF ( inflow_l .OR. outflow_l .OR. nest_bound_l )  THEN
1172       nxlu = nxl + 1
1173    ELSE
1174       nxlu = nxl
1175    ENDIF
1176    IF ( inflow_s .OR. outflow_s .OR. nest_bound_s )  THEN
1177       nysv = nys + 1
1178    ELSE
1179       nysv = nys
1180    ENDIF
1181
1182!
1183!-- Allocate wall flag arrays used in the multigrid solver
1184    IF ( psolver(1:9) == 'multigrid' )  THEN
1185
1186       DO  i = maximum_grid_level, 1, -1
1187
1188           SELECT CASE ( i )
1189
1190              CASE ( 1 )
1191                 ALLOCATE( wall_flags_1(nzb:nzt_mg(i)+1,         &
1192                                        nys_mg(i)-1:nyn_mg(i)+1, &
1193                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1194
1195              CASE ( 2 )
1196                 ALLOCATE( wall_flags_2(nzb:nzt_mg(i)+1,         &
1197                                        nys_mg(i)-1:nyn_mg(i)+1, &
1198                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1199
1200              CASE ( 3 )
1201                 ALLOCATE( wall_flags_3(nzb:nzt_mg(i)+1,         &
1202                                        nys_mg(i)-1:nyn_mg(i)+1, &
1203                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1204
1205              CASE ( 4 )
1206                 ALLOCATE( wall_flags_4(nzb:nzt_mg(i)+1,         &
1207                                        nys_mg(i)-1:nyn_mg(i)+1, &
1208                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1209
1210              CASE ( 5 )
1211                 ALLOCATE( wall_flags_5(nzb:nzt_mg(i)+1,         &
1212                                        nys_mg(i)-1:nyn_mg(i)+1, &
1213                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1214
1215              CASE ( 6 )
1216                 ALLOCATE( wall_flags_6(nzb:nzt_mg(i)+1,         &
1217                                        nys_mg(i)-1:nyn_mg(i)+1, &
1218                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1219
1220              CASE ( 7 )
1221                 ALLOCATE( wall_flags_7(nzb:nzt_mg(i)+1,         &
1222                                        nys_mg(i)-1:nyn_mg(i)+1, &
1223                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1224
1225              CASE ( 8 )
1226                 ALLOCATE( wall_flags_8(nzb:nzt_mg(i)+1,         &
1227                                        nys_mg(i)-1:nyn_mg(i)+1, &
1228                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1229
1230              CASE ( 9 )
1231                 ALLOCATE( wall_flags_9(nzb:nzt_mg(i)+1,         &
1232                                        nys_mg(i)-1:nyn_mg(i)+1, &
1233                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1234
1235              CASE ( 10 )
1236                 ALLOCATE( wall_flags_10(nzb:nzt_mg(i)+1,        &
1237                                        nys_mg(i)-1:nyn_mg(i)+1, &
1238                                        nxl_mg(i)-1:nxr_mg(i)+1) )
1239
1240              CASE DEFAULT
1241                 message_string = 'more than 10 multigrid levels'
1242                 CALL message( 'init_pegrid', 'PA0238', 1, 2, 0, 6, 0 )
1243
1244          END SELECT
1245
1246       ENDDO
1247
1248    ENDIF
1249
1250!
1251!-- Calculate the number of groups into which parallel I/O is split.
1252!-- The default for files which are opened by all PEs (or where each
1253!-- PE opens his own independent file) is, that all PEs are doing input/output
1254!-- in parallel at the same time. This might cause performance or even more
1255!-- severe problems depending on the configuration of the underlying file
1256!-- system.
1257!-- First, set the default:
1258    IF ( maximum_parallel_io_streams == -1  .OR. &
1259         maximum_parallel_io_streams > numprocs )  THEN
1260       maximum_parallel_io_streams = numprocs
1261    ENDIF
1262
1263!
1264!-- Now calculate the number of io_blocks and the io_group to which the
1265!-- respective PE belongs. I/O of the groups is done in serial, but in parallel
1266!-- for all PEs belonging to the same group. A preliminary setting with myid
1267!-- based on MPI_COMM_WORLD has been done in parin.
1268    io_blocks = numprocs / maximum_parallel_io_streams
1269    io_group  = MOD( myid+1, io_blocks )
1270   
1271
1272 END SUBROUTINE init_pegrid
Note: See TracBrowser for help on using the repository browser.