source: palm/trunk/SOURCE/init_ocean.f90 @ 115

 SUBROUTINE init_ocean

!------------------------------------------------------------------------------!
! Actual revisions:
! -----------------
! 
!
! Former revisions:
! ------------------
! $Id: init_ocean.f90 98 2007-06-21 09:36:33Z letzel $
!
! 97 2007-06-21 08:23:15Z raasch
! Initial revision
!
! Description:
! ------------
! Initialization of quantities needed for the ocean version
!------------------------------------------------------------------------------!

    USE arrays_3d
    USE control_parameters
    USE eqn_state_seawater_mod
    USE grid_variables
    USE indices

    IMPLICIT NONE

    INTEGER ::  k

    REAL    ::  sa_l, pt_l, rho_l

    ALLOCATE( hyp(nzb:nzt+1) )

!
!-- Set water density near the ocean surface
    rho_surface = 1027.62

!
!-- Calculate initial vertical profile of hydrostatic pressure (in Pa)
!-- and the reference density (used later in buoyancy term)
    hyp(nzt+1) = surface_pressure * 100.0

    hyp(nzt)      = hyp(nzt+1) + rho_surface * g * 0.5 * dzu(nzt+1)
    rho_reference = rho_surface * 0.5 * dzu(nzt+1)

    DO  k = nzt-1, 0, -1

       sa_l = 0.5 * ( sa_init(k) + sa_init(k+1) )
       pt_l = 0.5 * ( pt_init(k) + pt_init(k+1) )

       rho_l = eqn_state_seawater_func( hyp(k+1), pt_l, sa_l )

       hyp(k)        = hyp(k+1) + rho_l * g * dzu(k+1)
       rho_reference = rho_reference + rho_l * dzu(k+1)

    ENDDO

    rho_reference = rho_reference / ( zw(nzt) - zu(nzb) )

!
!-- Calculate the reference potential density
    prho_reference = 0.0
    DO  k = 0, nzt

       sa_l = 0.5 * ( sa_init(k) + sa_init(k+1) )
       pt_l = 0.5 * ( pt_init(k) + pt_init(k+1) )

       prho_reference = prho_reference + dzu(k+1) * &
                        eqn_state_seawater_func( hyp(0), pt_l, sa_l )

    ENDDO

    prho_reference = prho_reference / ( zu(nzt) - zu(nzb) )


 END SUBROUTINE init_ocean