source: palm/trunk/SOURCE/init_ocean.f90 @ 1202

 SUBROUTINE init_ocean

!--------------------------------------------------------------------------------!
! This file is part of PALM.
!
! PALM is free software: you can redistribute it and/or modify it under the terms
! of the GNU General Public License as published by the Free Software Foundation,
! either version 3 of the License, or (at your option) any later version.
!
! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
!
! You should have received a copy of the GNU General Public License along with
! PALM. If not, see <http://www.gnu.org/licenses/>.
!
! Copyright 1997-2012  Leibniz University Hannover
!--------------------------------------------------------------------------------!
!
! Current revisions:
! -----------------
!
!
! Former revisions:
! ------------------
! $Id: init_ocean.f90 1182 2013-06-14 09:07:24Z witha $
!
! 1179 2013-06-14 05:57:58Z raasch
! Initial density profile is stored in array hom
!
! 1036 2012-10-22 13:43:42Z raasch
! code put under GPL (PALM 3.9)
!
! 388 2009-09-23 09:40:33Z raasch
! Bugfix: Initial profiles of hydrostatic pressure and density are calculated
! iteratively. First calculation of hyp(0) changed.
!
! 124 2007-10-19 15:47:46Z raasch
! Bugfix: Initial density rho is calculated
!
! 97 2007-06-21 08:23:15Z raasch
! Initial revision
!
! Description:
! ------------
! Initialization of quantities needed for the ocean version
!------------------------------------------------------------------------------!

    USE arrays_3d
    USE control_parameters
    USE eqn_state_seawater_mod
    USE grid_variables
    USE indices
    USE pegrid
    USE statistics

    IMPLICIT NONE

    INTEGER ::  k, n

    REAL    ::  sa_l, pt_l

    REAL, DIMENSION(nzb:nzt+1) ::  rho_init

    ALLOCATE( hyp(nzb:nzt+1) )

!
!-- Set water density near the ocean surface
    rho_surface = 1027.62

!
!-- Calculate initial vertical profile of hydrostatic pressure (in Pa)
!-- and the reference density (used later in buoyancy term)
!-- First step: Calculate pressure using reference density
    hyp(nzt+1) = surface_pressure * 100.0

    hyp(nzt)      = hyp(nzt+1) + rho_surface * g * 0.5 * dzu(nzt+1)
    rho_init(nzt) = rho_surface

    DO  k = nzt-1, 1, -1
       hyp(k) = hyp(k+1) + rho_surface * g * dzu(k)
    ENDDO
    hyp(0) = hyp(1) + rho_surface * g * dzu(1)

!
!-- Second step: Iteratively calculate in situ density (based on presssure)
!-- and pressure (based on in situ density)
    DO  n = 1, 5

       rho_reference = rho_surface * 0.5 * dzu(nzt+1)

       DO  k = nzt-1, 0, -1

          sa_l = 0.5 * ( sa_init(k) + sa_init(k+1) )
          pt_l = 0.5 * ( pt_init(k) + pt_init(k+1) )

          rho_init(k) = eqn_state_seawater_func( hyp(k), pt_l, sa_l )

          rho_reference = rho_reference + rho_init(k) * dzu(k+1)

       ENDDO

       rho_reference = rho_reference / ( zw(nzt) - zu(nzb) )

       DO  k = nzt-1, 0, -1
          hyp(k) = hyp(k+1) + g * 0.5 * ( rho_init(k) + rho_init(k+1 ) ) * &
                              dzu(k+1)
       ENDDO

    ENDDO

!
!-- Calculate the reference potential density
    prho_reference = 0.0
    DO  k = 0, nzt

       sa_l = 0.5 * ( sa_init(k) + sa_init(k+1) )
       pt_l = 0.5 * ( pt_init(k) + pt_init(k+1) )

       prho_reference = prho_reference + dzu(k+1) * &
                        eqn_state_seawater_func( 0.0, pt_l, sa_l )

    ENDDO

    prho_reference = prho_reference / ( zu(nzt) - zu(nzb) )

!
!-- Calculate the 3d array of initial in situ and potential density,
!-- based on the initial temperature and salinity profile
    CALL eqn_state_seawater

!
!-- Store initial density profile
    hom(:,1,77,:)  = SPREAD( rho_init(:), 2, statistic_regions+1 )

!
!-- Set the reference state to be used in the buoyancy terms
    IF ( use_single_reference_value )  THEN
       ref_state(:) = prho_reference
    ELSE
       ref_state(:) = rho_init(:)
    ENDIF


 END SUBROUTINE init_ocean