Home

Context Navigation

source: palm/trunk/SOURCE/init_masks.f90 @ 3054

Last change on this file since 3054 was 3049, checked in by Giersch, 7 years ago
Revision history corrected
Property svn:keywords set to `Id`
File size: 31.0 KB

Line
1	!> @file init_masks.f90
2	!------------------------------------------------------------------------------!
3	! This file is part of the PALM model system.
4	!
5	! PALM is free software: you can redistribute it and/or modify it under the
6	! terms of the GNU General Public License as published by the Free Software
7	! Foundation, either version 3 of the License, or (at your option) any later
8	! version.
9	!
10	! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11	! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12	! A PARTICULAR PURPOSE. See the GNU General Public License for more details.
13	!
14	! You should have received a copy of the GNU General Public License along with
15	! PALM. If not, see <http://www.gnu.org/licenses/>.
16	!
17	! Copyright 1997-2018 Leibniz Universitaet Hannover
18	!------------------------------------------------------------------------------!
19	!
20	! Current revisions:
21	! -----------------
22	!
23	!
24	! Former revisions:
25	! -----------------
26	! $Id: init_masks.f90 3049 2018-05-29 13:52:36Z gronemeier $
27	! Error messages revised
28	!
29	! 3045 2018-05-28 07:55:41Z Giersch
30	! Error messages revised
31	!
32	! 2718 2018-01-02 08:49:38Z maronga
33	! Corrected "Former revisions" section
34	!
35	! 2696 2017-12-14 17:12:51Z kanani
36	! Change in file header (GPL part)
37	!
38	! 2344 2017-08-09 11:00:34Z raasch
39	! explicit setting of initial values for array domask required due to a bug
40	! in the Cray compiler (appears only if option -eD is used)
41	!
42	! 2301 2017-06-29 16:41:21Z gronemeier
43	! Bugfix: set variable name length to global value
44	!
45	!
46	! Implementation of new microphysic scheme: cloud_scheme = 'morrison'
47	! includes two more prognostic equations for cloud drop concentration (nc)
48	! and cloud water content (qc).
49	!
50	! 2271 2017-06-09 12:34:55Z sward
51	! Changed error message
52	!
53	! 2101 2017-01-05 16:42:31Z suehring
54	!
55	! 2031 2016-10-21 15:11:58Z knoop
56	! renamed variable rho to rho_ocean
57	!
58	! 2000 2016-08-20 18:09:15Z knoop
59	! Forced header and separation lines into 80 columns
60	!
61	! 1822 2016-04-07 07:49:42Z hoffmann
62	! icloud_scheme replaced by microphysics_*
63	!
64	! 1804 2016-04-05 16:30:18Z maronga
65	! Removed code for parameter file check (__check)
66	!
67	! 1783 2016-03-06 18:36:17Z raasch
68	! netcdf module name changed + related changes
69	!
70	! 1682 2015-10-07 23:56:08Z knoop
71	! Code annotations made doxygen readable
72	!
73	! 1438 2014-07-22 14:14:06Z heinze
74	! +nr, qc, qr
75	!
76	! 1414 2014-05-31 11:19:48Z gronemeier
77	! Bugfix: first and last grid points as they appear in 3D volume data can now
78	! be included to masked data output
79	!
80	! 1353 2014-04-08 15:21:23Z heinze
81	! REAL constants provided with KIND-attribute
82	!
83	! 1324 2014-03-21 09:13:16Z suehring
84	! Bugfix: ONLY statement for module netcdf_control removed
85	!
86	! 1320 2014-03-20 08:40:49Z raasch
87	! ONLY-attribute added to USE-statements,
88	! kind-parameters added to all INTEGER and REAL declaration statements,
89	! kinds are defined in new module kinds,
90	! revision history before 2012 removed,
91	! comment fields (!:) to be used for variable explanations added to
92	! all variable declaration statements
93	!
94	! 1186 2013-06-18 06:22:52Z raasch
95	! bugfix: 0.0 replaced by zu(nzb) as the lowest default height level for masks,
96	! because a zero value does not work in case of ocean runs
97	!
98	! 1036 2012-10-22 13:43:42Z raasch
99	! code put under GPL (PALM 3.9)
100	!
101	! 1032 2012-10-21 13:03:21Z letzel
102	! mask locations determined based on scalar positions
103	!
104	! 1031 2012-10-19 14:35:30Z raasch
105	! netCDF4 without parallel file support implemented
106	!
107	! 996 2012-09-07 10:41:47Z raasch
108	! little reformatting
109	!
110	! 978 2012-08-09 08:28:32Z fricke
111	! +z0h*
112	!
113	! 809 2012-01-30 13:32:58Z maronga
114	! Bugfix: replaced .AND. and .NOT. with && and ! in the preprocessor directives
115	!
116	! 807 2012-01-25 11:53:51Z maronga
117	! New cpp directive "__check" implemented which is used by check_namelist_files
118	!
119	! 410 2009-12-04 17:05:40Z letzel
120	! Initial revision
121	!
122	!
123	! Description:
124	! ------------
125	!> Initialize masked data output
126	!------------------------------------------------------------------------------!
127	SUBROUTINE init_masks
128
129	USE arrays_3d, &
130	ONLY: zu, zw
131
132	USE control_parameters, &
133	ONLY: constant_diffusion, cloud_droplets, cloud_physics, &
134	data_output_masks, data_output_masks_user, &
135	doav, doav_n, domask, domask_no, dz, dz_stretch_level, humidity,&
136	mask, masks, mask_scale, mask_i, &
137	mask_i_global, mask_j, mask_j_global, mask_k, mask_k_global, &
138	mask_loop, mask_size, mask_size_l, mask_start_l, mask_x, &
139	mask_x_loop, mask_xyz_dimension, mask_y, mask_y_loop, mask_z, &
140	mask_z_loop, max_masks, message_string, mid, &
141	microphysics_morrison, microphysics_seifert, passive_scalar, &
142	ocean, varnamelength
143
144	USE grid_variables, &
145	ONLY: dx, dy
146
147	USE indices, &
148	ONLY: nx, nxl, nxr, ny, nyn, nys, nz, nzb, nzt
149
150	USE kinds
151
152	USE netcdf_interface, &
153	ONLY: domask_unit, netcdf_data_format
154
155	USE particle_attributes, &
156	ONLY: particle_advection
157
158	USE pegrid
159
160	IMPLICIT NONE
161
162	CHARACTER (LEN=varnamelength) :: var !<
163	CHARACTER (LEN=7) :: unit !<
164
165	CHARACTER (LEN=varnamelength), DIMENSION(max_masks,100) :: do_mask !<
166	CHARACTER (LEN=varnamelength), DIMENSION(max_masks,100) :: do_mask_user !<
167
168	INTEGER(iwp) :: i !<
169	INTEGER(iwp) :: ilen !<
170	INTEGER(iwp) :: ind(6) !<
171	INTEGER(iwp) :: ind_array(1) !<
172	INTEGER(iwp) :: j !<
173	INTEGER(iwp) :: k !<
174	INTEGER(iwp) :: n !<
175	INTEGER(iwp) :: sender !<
176
177	INTEGER(iwp), DIMENSION(:), ALLOCATABLE :: tmp_array !<
178
179	LOGICAL :: found !<
180
181	!
182	!-- Initial values are explicitly set here due to a bug in the Cray compiler
183	!-- in case of assignments of initial values in declaration statements for
184	!-- arrays with more than 9999 elements (appears with -eD only)
185	domask = ' '
186
187	!
188	!-- Allocation and initialization
189	ALLOCATE( tmp_array( MAX(nx,ny,nz)+2 ) )
190
191	ALLOCATE( mask_i(max_masks,nxr-nxl+2), &
192	mask_j(max_masks,nyn-nys+2), &
193	mask_k(max_masks,nzt-nzb+2) )
194	!
195	!-- internal mask arrays ("mask,dimension,selection")
196	ALLOCATE( mask(max_masks,3,mask_xyz_dimension), &
197	mask_loop(max_masks,3,3) )
198
199	!
200	!-- Parallel mask output not yet supported. In check_parameters data format
201	!-- is restricted and is switched back to non-parallel output. Therefore the
202	!-- following error can not occur at the moment.
203	IF ( netcdf_data_format > 4 ) THEN
204	message_string = 'netCDF file formats '// &
205	'5 and 6 (with parallel I/O support)'// &
206	' are currently not supported.'
207	CALL message( 'init_masks', 'PA0328', 1, 2, 0, 6, 0 )
208	ENDIF
209
210	!
211	!-- Store data output parameters for masked data output in few shared arrays
212	DO mid = 1, masks
213
214	do_mask (mid,:) = data_output_masks(mid,:)
215	do_mask_user(mid,:) = data_output_masks_user(mid,:)
216	mask (mid,1,:) = mask_x(mid,:)
217	mask (mid,2,:) = mask_y(mid,:)
218	mask (mid,3,:) = mask_z(mid,:)
219
220	IF ( mask_x_loop(mid,1) == -1.0_wp .AND. mask_x_loop(mid,2) == -1.0_wp&
221	.AND. mask_x_loop(mid,3) == -1.0_wp ) THEN
222	mask_loop(mid,1,1:2) = -1.0_wp
223	mask_loop(mid,1,3) = 0.0_wp
224	ELSE
225	mask_loop(mid,1,:) = mask_x_loop(mid,:)
226	ENDIF
227	IF ( mask_y_loop(mid,1) == -1.0_wp .AND. mask_y_loop(mid,2) == -1.0_wp&
228	.AND. mask_y_loop(mid,3) == -1.0_wp ) THEN
229	mask_loop(mid,2,1:2) = -1.0_wp
230	mask_loop(mid,2,3) = 0.0_wp
231	ELSE
232	mask_loop(mid,2,:) = mask_y_loop(mid,:)
233	ENDIF
234	IF ( mask_z_loop(mid,1) == -1.0_wp .AND. mask_z_loop(mid,2) == -1.0_wp&
235	.AND. mask_z_loop(mid,3) == -1.0_wp ) THEN
236	mask_loop(mid,3,1:2) = -1.0_wp
237	mask_loop(mid,3,3) = 0.0_wp
238	ELSE
239	mask_loop(mid,3,:) = mask_z_loop(mid,:)
240	ENDIF
241
242	ENDDO
243
244	mask_i = -1; mask_j = -1; mask_k = -1
245
246	!
247	!-- Global arrays are required by define_netcdf_header.
248	IF ( myid == 0 .OR. netcdf_data_format > 4 ) THEN
249	ALLOCATE( mask_i_global(max_masks,nx+2), &
250	mask_j_global(max_masks,ny+2), &
251	mask_k_global(max_masks,nz+2) )
252	mask_i_global = -1; mask_j_global = -1; mask_k_global = -1
253	ENDIF
254
255	!
256	!-- Determine variable names for each mask
257	DO mid = 1, masks
258	!
259	!-- Append user-defined data output variables to the standard data output
260	IF ( do_mask_user(mid,1) /= ' ' ) THEN
261	i = 1
262	DO WHILE ( do_mask(mid,i) /= ' ' .AND. i <= 100 )
263	i = i + 1
264	ENDDO
265	j = 1
266	DO WHILE ( do_mask_user(mid,j) /= ' ' .AND. j <= 100 )
267	IF ( i > 100 ) THEN
268	WRITE ( message_string, * ) 'number of output quantitities ', &
269	'given by data_output_mask and data_output_mask_user ', &
270	'exceeds the limit of 100'
271	CALL message( 'init_masks', 'PA0329', 1, 2, 0, 6, 0 )
272	ENDIF
273	do_mask(mid,i) = do_mask_user(mid,j)
274	i = i + 1
275	j = j + 1
276	ENDDO
277	ENDIF
278
279	!
280	!-- Check and set steering parameters for mask data output and averaging
281	i = 1
282	DO WHILE ( do_mask(mid,i) /= ' ' .AND. i <= 100 )
283	!
284	!-- Check for data averaging
285	ilen = LEN_TRIM( do_mask(mid,i) )
286	j = 0 ! no data averaging
287	IF ( ilen > 3 ) THEN
288	IF ( do_mask(mid,i)(ilen-2:ilen) == '_av' ) THEN
289	j = 1 ! data averaging
290	do_mask(mid,i) = do_mask(mid,i)(1:ilen-3)
291	ENDIF
292	ENDIF
293	var = TRIM( do_mask(mid,i) )
294	!
295	!-- Check for allowed value and set units
296	SELECT CASE ( TRIM( var ) )
297
298	CASE ( 'e' )
299	IF ( constant_diffusion ) THEN
300	WRITE ( message_string, * ) 'output of "', TRIM( var ), &
301	'" requires constant_diffusion = .FALSE.'
302	CALL message( 'init_masks', 'PA0103', 1, 2, 0, 6, 0 )
303	ENDIF
304	unit = 'm2/s2'
305
306	CASE ( 'lpt' )
307	IF ( .NOT. cloud_physics ) THEN
308	WRITE ( message_string, * ) 'output of "', TRIM( var ), &
309	'" requires cloud_physics = .TRUE.'
310	CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 )
311	ENDIF
312	unit = 'K'
313
314	CASE ( 'nc' )
315	IF ( .NOT. cloud_physics ) THEN
316	WRITE ( message_string, * ) 'output of "', TRIM( var ), &
317	'" requires cloud_physics = .TRUE.'
318	CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 )
319	ELSEIF ( .NOT. microphysics_morrison ) THEN
320	message_string = 'output of "' // TRIM( var ) // '" ' // &
321	'requires = morrison'
322	CALL message( 'check_parameters', 'PA0359', 1, 2, 0, 6, 0 )
323	ENDIF
324	unit = '1/m3'
325
326	CASE ( 'nr' )
327	IF ( .NOT. cloud_physics ) THEN
328	WRITE ( message_string, * ) 'output of "', TRIM( var ), &
329	'" requires cloud_physics = .TRUE.'
330	CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 )
331	ELSEIF ( .NOT. microphysics_seifert ) THEN
332	message_string = 'output of "' // TRIM( var ) // '"' // &
333	'requires cloud_scheme = seifert_beheng'
334	CALL message( 'check_parameters', 'PA0359', 1, 2, 0, 6, 0 )
335	ENDIF
336	unit = '1/m3'
337
338	CASE ( 'pc', 'pr' )
339	IF ( .NOT. particle_advection ) THEN
340	WRITE ( message_string, * ) 'output of "', TRIM( var ), &
341	'" requires a "particles_par"-NAMELIST in the ', &
342	'parameter file (PARIN)'
343	CALL message( 'init_masks', 'PA0104', 1, 2, 0, 6, 0 )
344	ENDIF
345	IF ( TRIM( var ) == 'pc' ) unit = 'number'
346	IF ( TRIM( var ) == 'pr' ) unit = 'm'
347
348	CASE ( 'q', 'vpt' )
349	IF ( .NOT. humidity ) THEN
350	WRITE ( message_string, * ) 'output of "', TRIM( var ), &
351	'" requires humidity = .TRUE.'
352	CALL message( 'init_masks', 'PA0105', 1, 2, 0, 6, 0 )
353	ENDIF
354	IF ( TRIM( var ) == 'q' ) unit = 'kg/kg'
355	IF ( TRIM( var ) == 'vpt' ) unit = 'K'
356
357	CASE ( 'qc' )
358	IF ( .NOT. cloud_physics ) THEN
359	message_string = 'output of "' // TRIM( var ) // '"' // &
360	'requires cloud_physics = .TRUE.'
361	CALL message( 'check_parameters', 'PA0108', 1, 2, 0, 6, 0 )
362	ENDIF
363	unit = 'kg/kg'
364
365	CASE ( 'ql' )
366	IF ( .NOT. ( cloud_physics .OR. cloud_droplets ) ) THEN
367	WRITE ( message_string, * ) 'output of "', TRIM( var ), &
368	'" requires cloud_physics = .TRUE. or cloud_droplets', &
369	' = .TRUE.'
370	CALL message( 'init_masks', 'PA0106', 1, 2, 0, 6, 0 )
371	ENDIF
372	unit = 'kg/kg'
373
374	CASE ( 'ql_c', 'ql_v', 'ql_vp' )
375	IF ( .NOT. cloud_droplets ) THEN
376	WRITE ( message_string, * ) 'output of "', TRIM( var ), &
377	'" requires cloud_droplets = .TRUE.'
378	CALL message( 'init_masks', 'PA0107', 1, 2, 0, 6, 0 )
379	ENDIF
380	IF ( TRIM( var ) == 'ql_c' ) unit = 'kg/kg'
381	IF ( TRIM( var ) == 'ql_v' ) unit = 'm3'
382	IF ( TRIM( var ) == 'ql_vp' ) unit = 'none'
383
384	CASE ( 'qv' )
385	IF ( .NOT. cloud_physics ) THEN
386	WRITE ( message_string, * ) 'output of "', TRIM( var ), &
387	'" requires cloud_physics = .TRUE.'
388	CALL message( 'init_masks', 'PA0108', 1, 2, 0, 6, 0 )
389	ENDIF
390	unit = 'kg/kg'
391
392	CASE ( 'qr' )
393	IF ( .NOT. cloud_physics ) THEN
394	message_string = 'output of "' // TRIM( var ) // '" ' // &
395	'requires cloud_physics = .TRUE.'
396	CALL message( 'check_parameters', 'PA0108', 1, 2, 0, 6, 0 )
397	ELSEIF ( .NOT. microphysics_seifert ) THEN
398	message_string = 'output of "' // TRIM( var ) // '" ' // &
399	'requires cloud_scheme = seifert_beheng'
400	CALL message( 'check_parameters', 'PA0359', 1, 2, 0, 6, 0 )
401	ENDIF
402	unit = 'kg/kg'
403
404	CASE ( 'rho_ocean' )
405	IF ( .NOT. ocean ) THEN
406	WRITE ( message_string, * ) 'output of "', TRIM( var ), &
407	'" requires ocean = .TRUE.'
408	CALL message( 'init_masks', 'PA0109', 1, 2, 0, 6, 0 )
409	ENDIF
410	unit = 'kg/m3'
411
412	CASE ( 's' )
413	IF ( .NOT. passive_scalar ) THEN
414	WRITE ( message_string, * ) 'output of "', TRIM( var ), &
415	'" requires passive_scalar = .TRUE.'
416	CALL message( 'init_masks', 'PA0110', 1, 2, 0, 6, 0 )
417	ENDIF
418	unit = 'conc'
419
420	CASE ( 'sa' )
421	IF ( .NOT. ocean ) THEN
422	WRITE ( message_string, * ) 'output of "', TRIM( var ), &
423	'" requires ocean = .TRUE.'
424	CALL message( 'init_masks', 'PA0109', 1, 2, 0, 6, 0 )
425	ENDIF
426	unit = 'psu'
427
428	CASE ( 'u', 't', 'lwp', 'pra', 'prr', 'z0', 'z0h*' )
429	WRITE ( message_string, * ) 'illegal value for data_', &
430	'output: "', TRIM( var ), '" is only allowed', &
431	'for horizontal cross section'
432	CALL message( 'init_masks', 'PA0111', 1, 2, 0, 6, 0 )
433
434	CASE ( 'p', 'pt', 'u', 'v', 'w' )
435	IF ( TRIM( var ) == 'p' ) unit = 'Pa'
436	IF ( TRIM( var ) == 'pt' ) unit = 'K'
437	IF ( TRIM( var ) == 'u' ) unit = 'm/s'
438	IF ( TRIM( var ) == 'v' ) unit = 'm/s'
439	IF ( TRIM( var ) == 'w' ) unit = 'm/s'
440	CONTINUE
441
442	CASE DEFAULT
443	CALL user_check_data_output( var, unit )
444
445	IF ( unit == 'illegal' ) THEN
446	IF ( do_mask_user(mid,1) /= ' ' ) THEN
447	WRITE ( message_string, * ) 'illegal value for data_', &
448	'output_masks or data_output_masks_user: "', &
449	TRIM( do_mask(mid,i) ), '"'
450	CALL message( 'init_masks', 'PA0018', 1, 2, 0, 6, 0 )
451	ELSE
452	WRITE ( message_string, * ) 'illegal value for data_', &
453	' output_masks : "', TRIM( do_mask(mid,i) ), '"'
454	CALL message( 'init_masks', 'PA0330', 1, 2, 0, 6, 0 )
455	ENDIF
456	ENDIF
457
458	END SELECT
459	!
460	!-- Set the internal steering parameters appropriately
461	domask_no(mid,j) = domask_no(mid,j) + 1
462	domask(mid,j,domask_no(mid,j)) = do_mask(mid,i)
463	domask_unit(mid,j,domask_no(mid,j)) = unit
464
465	IF ( j == 1 ) THEN
466	!
467	!-- Check, if variable is already subject to averaging
468	found = .FALSE.
469	DO k = 1, doav_n
470	IF ( TRIM( doav(k) ) == TRIM( var ) ) found = .TRUE.
471	ENDDO
472
473	IF ( .NOT. found ) THEN
474	doav_n = doav_n + 1
475	doav(doav_n) = var
476	ENDIF
477	ENDIF
478
479	i = i + 1
480
481	ENDDO ! do_mask(mid,i)
482	ENDDO ! mid
483
484
485	!
486	!-- Determine mask locations for each mask
487	DO mid = 1, masks
488	!
489	!-- Set local masks for each subdomain along all three dimensions
490	CALL set_mask_locations( 1, dx, 'dx', nx, 'nx', nxl, nxr )
491	CALL set_mask_locations( 2, dy, 'dy', ny, 'ny', nys, nyn )
492	CALL set_mask_locations( 3, dz, 'dz', nz, 'nz', nzb, nzt )
493	!
494	!-- Set global masks along all three dimensions (required by
495	!-- define_netcdf_header).
496	#if defined( __parallel )
497	!
498	!-- PE0 receives partial arrays from all processors of the respective mask
499	!-- and outputs them. Here a barrier has to be set, because otherwise
500	!-- "-MPI- FATAL: Remote protocol queue full" may occur.
501
502	CALL MPI_BARRIER( comm2d, ierr )
503
504	IF ( myid == 0 ) THEN
505	!
506	!-- Local arrays can be relocated directly.
507	mask_i_global(mid,mask_start_l(mid,1): &
508	mask_start_l(mid,1)+mask_size_l(mid,1)-1) = &
509	mask_i(mid,:mask_size_l(mid,1))
510	mask_j_global(mid,mask_start_l(mid,2): &
511	mask_start_l(mid,2)+mask_size_l(mid,2)-1) = &
512	mask_j(mid,:mask_size_l(mid,2))
513	mask_k_global(mid,mask_start_l(mid,3): &
514	mask_start_l(mid,3)+mask_size_l(mid,3)-1) = &
515	mask_k(mid,:mask_size_l(mid,3))
516	!
517	!-- Receive data from all other PEs.
518	DO n = 1, numprocs-1
519	!
520	!-- Receive index limits first, then arrays.
521	!-- Index limits are received in arbitrary order from the PEs.
522	CALL MPI_RECV( ind(1), 6, MPI_INTEGER, MPI_ANY_SOURCE, 0, &
523	comm2d, status, ierr )
524	!
525	!-- Not all PEs have data for the mask.
526	IF ( ind(1) /= -9999 ) THEN
527	sender = status(MPI_SOURCE)
528	CALL MPI_RECV( tmp_array(ind(1)), ind(2)-ind(1)+1, &
529	MPI_INTEGER, sender, 1, comm2d, status, ierr )
530	mask_i_global(mid,ind(1):ind(2)) = tmp_array(ind(1):ind(2))
531	CALL MPI_RECV( tmp_array(ind(3)), ind(4)-ind(3)+1, &
532	MPI_INTEGER, sender, 2, comm2d, status, ierr )
533	mask_j_global(mid,ind(3):ind(4)) = tmp_array(ind(3):ind(4))
534	CALL MPI_RECV( tmp_array(ind(5)), ind(6)-ind(5)+1, &
535	MPI_INTEGER, sender, 3, comm2d, status, ierr )
536	mask_k_global(mid,ind(5):ind(6)) = tmp_array(ind(5):ind(6))
537	ENDIF
538	ENDDO
539
540	ELSE
541	!
542	!-- If at least part of the mask resides on the PE, send the index limits
543	!-- for the target array, otherwise send -9999 to PE0.
544	IF ( mask_size_l(mid,1) > 0 .AND. mask_size_l(mid,2) > 0 .AND. &
545	mask_size_l(mid,3) > 0 ) THEN
546	ind(1) = mask_start_l(mid,1)
547	ind(2) = mask_start_l(mid,1) + mask_size_l(mid,1) - 1
548	ind(3) = mask_start_l(mid,2)
549	ind(4) = mask_start_l(mid,2) + mask_size_l(mid,2) - 1
550	ind(5) = mask_start_l(mid,3)
551	ind(6) = mask_start_l(mid,3) + mask_size_l(mid,3) - 1
552	ELSE
553	ind(1) = -9999; ind(2) = -9999
554	ind(3) = -9999; ind(4) = -9999
555	ind(5) = -9999; ind(6) = -9999
556	ENDIF
557	CALL MPI_SEND( ind(1), 6, MPI_INTEGER, 0, 0, comm2d, ierr )
558	!
559	!-- If applicable, send data to PE0.
560	IF ( ind(1) /= -9999 ) THEN
561	tmp_array(:mask_size_l(mid,1)) = mask_i(mid,:mask_size_l(mid,1))
562	CALL MPI_SEND( tmp_array(1), mask_size_l(mid,1), &
563	MPI_INTEGER, 0, 1, comm2d, ierr )
564	tmp_array(:mask_size_l(mid,2)) = mask_j(mid,:mask_size_l(mid,2))
565	CALL MPI_SEND( tmp_array(1), mask_size_l(mid,2), &
566	MPI_INTEGER, 0, 2, comm2d, ierr )
567	tmp_array(:mask_size_l(mid,3)) = mask_k(mid,:mask_size_l(mid,3))
568	CALL MPI_SEND( tmp_array(1), mask_size_l(mid,3), &
569	MPI_INTEGER, 0, 3, comm2d, ierr )
570	ENDIF
571	ENDIF
572	!
573	!-- A barrier has to be set, because otherwise some PEs may proceed too fast
574	!-- so that PE0 may receive wrong data on tag 0.
575	CALL MPI_BARRIER( comm2d, ierr )
576
577	IF ( netcdf_data_format > 4 ) THEN
578
579	CALL MPI_BCAST( mask_i_global(mid,:), nx+2, MPI_INTEGER, 0, comm2d, &
580	ierr )
581	CALL MPI_BCAST( mask_j_global(mid,:), ny+2, MPI_INTEGER, 0, comm2d, &
582	ierr )
583	CALL MPI_BCAST( mask_k_global(mid,:), nz+2, MPI_INTEGER, 0, comm2d, &
584	ierr )
585
586	ENDIF
587
588	#else
589	!
590	!-- Local arrays can be relocated directly.
591	mask_i_global(mid,:) = mask_i(mid,:)
592	mask_j_global(mid,:) = mask_j(mid,:)
593	mask_k_global(mid,:) = mask_k(mid,:)
594	#endif
595	ENDDO ! mid
596
597	DEALLOCATE( tmp_array )
598	!
599	!-- Internal mask arrays cannot be deallocated on PE 0 because they are
600	!-- required for header output on PE 0.
601	IF ( myid /= 0 ) DEALLOCATE( mask, mask_loop )
602
603	CONTAINS
604
605	!------------------------------------------------------------------------------!
606	! Description:
607	! ------------
608	!> Set local mask for each subdomain along 'dim' direction.
609	!------------------------------------------------------------------------------!
610	SUBROUTINE set_mask_locations( dim, dxyz, dxyz_string, nxyz, nxyz_string, &
611	lb, ub )
612
613	IMPLICIT NONE
614
615	CHARACTER (LEN=2) :: dxyz_string !<
616	CHARACTER (LEN=2) :: nxyz_string !<
617
618	INTEGER(iwp) :: count !<
619	INTEGER(iwp) :: count_l !<
620	INTEGER(iwp) :: dim !<
621	INTEGER(iwp) :: m !<
622	INTEGER(iwp) :: loop_begin !<
623	INTEGER(iwp) :: loop_end !<
624	INTEGER(iwp) :: loop_stride !<
625	INTEGER(iwp) :: lb !<
626	INTEGER(iwp) :: nxyz !<
627	INTEGER(iwp) :: ub !<
628
629	REAL(wp) :: dxyz !<
630	REAL(wp) :: ddxyz !<
631	REAL(wp) :: tmp1 !<
632	REAL(wp) :: tmp2 !<
633
634	count = 0; count_l = 0
635	ddxyz = 1.0_wp / dxyz
636	tmp1 = 0.0_wp
637	tmp2 = 0.0_wp
638
639	IF ( mask(mid,dim,1) >= 0.0_wp ) THEN
640	!
641	!-- use predefined mask_* array
642	DO WHILE ( mask(mid,dim,count+1) >= 0.0_wp )
643	count = count + 1
644	IF ( dim == 1 .OR. dim == 2 ) THEN
645	m = NINT( mask(mid,dim,count) * mask_scale(dim) * ddxyz - 0.5_wp )
646	IF ( m < 0 ) m = 0 ! avoid negative values
647	ELSEIF ( dim == 3 ) THEN
648	ind_array = &
649	MINLOC( ABS( mask(mid,dim,count) * mask_scale(dim) - zu ) )
650	m = ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1
651	ENDIF
652	IF ( m > (nxyz+1) ) THEN
653	WRITE ( message_string, '(I3,A,I3,A,I1,3A,I3)' ) &
654	m,' in mask ',mid,' along dimension ',dim, &
655	' exceeds (',nxyz_string,'+1) = ',nxyz+1
656	CALL message( 'init_masks', 'PA0331', 1, 2, 0, 6, 0 )
657	ENDIF
658	IF ( ( m >= lb .AND. m <= ub ) .OR. &
659	( m == (nxyz+1) .AND. ub == nxyz ) ) THEN
660	IF ( count_l == 0 ) mask_start_l(mid,dim) = count
661	count_l = count_l + 1
662	IF ( dim == 1 ) THEN
663	mask_i(mid,count_l) = m
664	ELSEIF ( dim == 2 ) THEN
665	mask_j(mid,count_l) = m
666	ELSEIF ( dim == 3 ) THEN
667	mask_k(mid,count_l) = m
668	ENDIF
669	ENDIF
670	IF ( count == mask_xyz_dimension ) EXIT
671	ENDDO
672	mask_size(mid,dim) = count
673	mask_size_l(mid,dim) = count_l
674
675	ELSE
676	!
677	!-- use predefined mask_loop_* array, or use the default (all grid points
678	!-- along this direction)
679	IF ( mask_loop(mid,dim,1) < 0.0_wp ) THEN
680	tmp1 = mask_loop(mid,dim,1)
681	mask_loop(mid,dim,1) = zw(nzb) ! lowest level (default)
682	ENDIF
683	IF ( dim == 1 .OR. dim == 2 ) THEN
684	IF ( mask_loop(mid,dim,2) < 0.0_wp ) THEN
685	tmp2 = mask_loop(mid,dim,2)
686	mask_loop(mid,dim,2) = (nxyz+1)*dxyz / mask_scale(dim) ! (default)
687	ENDIF
688	IF ( MAXVAL( mask_loop(mid,dim,1:2) ) &
689	> (nxyz+1) * dxyz / mask_scale(dim) ) THEN
690	WRITE ( message_string, '(2(A,I3,A,I1,A,F9.3),5A,I1,A,F9.3)' ) &
691	'mask_loop(',mid,',',dim,',1)=',mask_loop(mid,dim,1), &
692	' and/or mask_loop(',mid,',',dim,',2)=', &
693	mask_loop(mid,dim,2),' exceed (', &
694	nxyz_string,'+1)*',dxyz_string,'/mask_scale(',dim,')=', &
695	(nxyz+1)*dxyz/mask_scale(dim)
696	CALL message( 'init_masks', 'PA0332', 1, 2, 0, 6, 0 )
697	ENDIF
698	loop_begin = NINT( mask_loop(mid,dim,1) * mask_scale(dim) &
699	* ddxyz - 0.5_wp )
700	loop_end = NINT( mask_loop(mid,dim,2) * mask_scale(dim) &
701	* ddxyz - 0.5_wp )
702	loop_stride = NINT( mask_loop(mid,dim,3) * mask_scale(dim) &
703	* ddxyz )
704	IF ( loop_begin == -1 ) loop_begin = 0 ! avoid negative values
705	ELSEIF ( dim == 3 ) THEN
706	IF ( mask_loop(mid,dim,2) < 0.0_wp ) THEN
707	tmp2 = mask_loop(mid,dim,2)
708	mask_loop(mid,dim,2) = zu(nz+1) / mask_scale(dim) ! (default)
709	ENDIF
710	IF ( MAXVAL( mask_loop(mid,dim,1:2) ) &
711	> zu(nz+1) / mask_scale(dim) ) THEN
712	WRITE ( message_string, '(2(A,I3,A,I1,A,F9.3),A,I1,A,F9.3)' ) &
713	'mask_loop(',mid,',',dim,',1)=',mask_loop(mid,dim,1), &
714	' and/or mask_loop(',mid,',',dim,',2)=', &
715	mask_loop(mid,dim,2),' exceed zu(nz+1)/mask_scale(',dim, &
716	')=',zu(nz+1)/mask_scale(dim)
717	CALL message( 'init_masks', 'PA0333', 1, 2, 0, 6, 0 )
718	ENDIF
719	ind_array = &
720	MINLOC( ABS( mask_loop(mid,dim,1) * mask_scale(dim) - zu ) )
721	loop_begin = &
722	ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1
723	ind_array = &
724	MINLOC( ABS( mask_loop(mid,dim,2) * mask_scale(dim) - zu ) )
725	loop_end = ind_array(1) - 1 + nzb ! MINLOC uses lower array bound 1
726	!
727	!-- The following line assumes a constant vertical grid spacing within
728	!-- the vertical mask range; it fails for vertical grid stretching.
729	!-- Maybe revise later. Issue warning but continue execution.
730	loop_stride = NINT( mask_loop(mid,dim,3) * mask_scale(dim) * ddxyz )
731
732	IF ( mask_loop(mid,dim,2) * mask_scale(dim) > dz_stretch_level ) &
733	THEN
734	WRITE ( message_string, '(A,I3,A,I1,A,F9.3,A,F8.2,3A)' ) &
735	'mask_loop(',mid,',',dim,',2)=', mask_loop(mid,dim,2), &
736	' exceeds dz_stretch_level=',dz_stretch_level, &
737	'.&Vertical mask locations will not ', &
738	'match the desired heights within the stretching ', &
739	'region.'
740	CALL message( 'init_masks', 'PA0334', 0, 1, 0, 6, 0 )
741	ENDIF
742
743	ENDIF
744	!
745	!-- If necessary, reset mask_loop(mid,dim,1) and mask_loop(mid,dim,2).
746	IF ( tmp1 < 0.0_wp ) mask_loop(mid,dim,1) = tmp1
747	IF ( tmp2 < 0.0_wp ) mask_loop(mid,dim,2) = tmp2
748	!
749	!-- The default stride +/-1 (every grid point) applies if
750	!-- mask_loop(mid,dim,3) is not specified (its default is zero).
751	IF ( loop_stride == 0 ) THEN
752	IF ( loop_end >= loop_begin ) THEN
753	loop_stride = 1
754	ELSE
755	loop_stride = -1
756	ENDIF
757	ENDIF
758	DO m = loop_begin, loop_end, loop_stride
759	count = count + 1
760	IF ( ( m >= lb .AND. m <= ub ) .OR. &
761	( m == (nxyz+1) .AND. ub == nxyz ) ) THEN
762	IF ( count_l == 0 ) mask_start_l(mid,dim) = count
763	count_l = count_l + 1
764	IF ( dim == 1 ) THEN
765	mask_i(mid,count_l) = m
766	ELSEIF ( dim == 2 ) THEN
767	mask_j(mid,count_l) = m
768	ELSEIF ( dim == 3 ) THEN
769	mask_k(mid,count_l) = m
770	ENDIF
771	ENDIF
772	ENDDO
773	mask_size(mid,dim) = count
774	mask_size_l(mid,dim) = count_l
775
776	ENDIF
777
778	END SUBROUTINE set_mask_locations
779
780	END SUBROUTINE init_masks

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

| Impressum | ©Leibniz Universität Hannover |