Home

Context Navigation

source: palm/trunk/SOURCE/init_grid.f90 @ 3066

Last change on this file since 3066 was 3066, checked in by Giersch, 6 years ago
Error messages related to the new vertical grid stretching revised, Bugfix in IF statement before error message
Property svn:keywords set to `Id`
File size: 114.8 KB

Line
1	!> @file init_grid.f90
2	!------------------------------------------------------------------------------!
3	! This file is part of the PALM model system.
4	!
5	! PALM is free software: you can redistribute it and/or modify it under the
6	! terms of the GNU General Public License as published by the Free Software
7	! Foundation, either version 3 of the License, or (at your option) any later
8	! version.
9	!
10	! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11	! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12	! A PARTICULAR PURPOSE. See the GNU General Public License for more details.
13	!
14	! You should have received a copy of the GNU General Public License along with
15	! PALM. If not, see <http://www.gnu.org/licenses/>.
16	!
17	! Copyright 1997-2018 Leibniz Universitaet Hannover
18	!------------------------------------------------------------------------------!
19	!
20	! Current revisions:
21	! -----------------
22	!
23	!
24	! Former revisions:
25	! -----------------
26	! $Id: init_grid.f90 3066 2018-06-12 08:55:55Z Giersch $
27	! Bugfix in IF statement before error message
28	!
29	! 3065 2018-06-12 07:03:02Z Giersch
30	! New vertical stretching mechanism introduced
31	!
32	! 3051 2018-05-30 17:43:55Z suehring
33	! Minor bugfix concerning mapping 3D buildings on top of terrain
34	!
35	! 3045 2018-05-28 07:55:41Z Giersch
36	! Error messages revised
37	!
38	! 3045 2018-05-28 07:55:41Z Giersch
39	! Error messages revised
40	!
41	! 2968 2018-04-13 11:52:24Z suehring
42	! Bugfix in initialization in case of elevated model surface. Introduce
43	! index for minimum topography-top.
44	!
45	! 2955 2018-04-09 15:14:01Z suehring
46	! Improve topography filter routine and add ghost-point exchange for building
47	! ID and building type.
48	!
49	! 2927 2018-03-23 15:13:00Z suehring
50	! Bugfix, setting boundary conditions for topography index array.
51	!
52	! 2918 2018-03-21 15:52:14Z gronemeier
53	! Moved init_mixing_length to turbulence_closure_mod.f90
54	!
55	! 2897 2018-03-15 11:47:16Z suehring
56	! Relax restrictions for topography input, terrain and building heights can be
57	! input separately and are not mandatory any more.
58	!
59	! 2893 2018-03-14 16:20:52Z suehring
60	! Revise informative message concerning filtered topography (1 grid-point
61	! holes).
62	!
63	! 2892 2018-03-14 15:06:29Z suehring
64	! Bugfix, uninitialized array in case of single_building.
65	!
66	! 2867 2018-03-09 09:40:23Z suehring
67	! Revise mapping of 3D buildings onto onto orography.
68	!
69	! 2823 2018-02-20 15:31:45Z Giersch
70	! Set boundary conditions for 3D topography in case of non-cyclic boundary
71	! conditions
72	!
73	! 2796 2018-02-08 12:25:39Z suehring
74	! Bugfix in 3D building initialization
75	!
76	! 2747 2018-01-15 12:44:17Z suehring
77	! Bugfix, topography height is rounded to the nearest discrete grid level
78	!
79	! 2718 2018-01-02 08:49:38Z maronga
80	! Corrected "Former revisions" section
81	!
82	! 2701 2017-12-15 15:40:50Z suehring
83	! Changes from last commit documented
84	!
85	! 2698 2017-12-14 18:46:24Z suehring
86	! Bugfix in get_topography_top_index
87	!
88	! 2696 2017-12-14 17:12:51Z kanani
89	! Change in file header (GPL part)
90	! Revised topography input
91	! Set nzb_max not for the entire nest domain, only for boundary PEs
92	! Re-organize routine, split-up into several subroutines
93	! Modularize poismg_noopt
94	! Remove setting bit 26, 27, 28 in wall_flags_0, indicating former '_outer'
95	! arrays (not required any more).
96	! Bugfix in generic tunnel setup (MS)
97	!
98	! 2550 2017-10-16 17:12:01Z boeske
99	! Set lateral boundary conditions for topography on all three ghost layers
100	!
101	! 2478 2017-09-18 13:37:24Z suehring
102	! Bugfix, correct flag for use_top
103	!
104	! 2365 2017-08-21 14:59:59Z kanani
105	! Vertical nesting implemented (SadiqHuq)
106	!
107	! 2319 2017-07-20 17:33:17Z suehring
108	! Remove print statements
109	!
110	! 2318 2017-07-20 17:27:44Z suehring
111	! Get topography top index via Function call
112	!
113	! 2317 2017-07-20 17:27:19Z suehring
114	! Bugfixes in reading 3D topography from file
115	!
116	! 2274 2017-06-09 13:27:48Z Giersch
117	! Changed error messages
118	!
119	! 2233 2017-05-30 18:08:54Z suehring
120	!
121	! 2232 2017-05-30 17:47:52Z suehring
122	! - Adjustments according to new topography representation
123	! - Bugfix: Move determination of nzb_max behind topography modification in
124	! cell-edge case
125	! - Get rid off global arrays required for topography output
126	! - Enable topography input via netcdf
127	! - Generic tunnel set-up added
128	!
129	! 2200 2017-04-11 11:37:51Z suehring
130	! monotonic_adjustment removed
131	!
132	! 2169 2017-03-06 18:16:35Z suehring
133	! Bugfix, move setting for topography grid convention to init_grid, else, if no
134	! value is set, the simulation may abort in case of restarts
135	!
136	! 2128 2017-01-23 15:00:03Z suehring
137	! Bugfix in setting topography from file in case of ocean simulations
138	!
139	! 2088 2016-12-19 16:30:25Z suehring
140	! Bugfix in generic topography in case of ocean simulations
141	!
142	! 2037 2016-10-26 11:15:40Z knoop
143	! Anelastic approximation implemented
144	!
145	! 2021 2016-10-07 14:08:57Z suehring
146	! Bugfix: setting Neumann boundary conditions for topography required for
147	! topography flags in multigrid_noopt solver
148	!
149	! 2000 2016-08-20 18:09:15Z knoop
150	! Forced header and separation lines into 80 columns
151	!
152	! 1994 2016-08-15 09:52:21Z suehring
153	! Bugfix in definition of generic topography
154	!
155	! 1982 2016-08-01 11:04:48Z suehring
156	! Bugfix concering consistency check for topography
157	!
158	! 1968 2016-07-18 12:01:49Z suehring
159	! Changed: PE-wise reading of topography file in order to avoid global definition
160	! of arrays nzb_local and nzb_tmp. Thereby, topography definition for single
161	! buildings and street canyons has changed, as well as flag setting for
162	! multigrid scheme.
163	!
164	! Bugfix in checking l_grid anisotropy.
165	! Simplify initial computation of lwall and vertical_influence, i.e. remove
166	! nzb_s_inner as it is still zero at this point.
167	!
168	! 1942 2016-06-14 12:18:18Z suehring
169	! Topography filter implemented to fill holes resolved by only one grid point.
170	! Initialization of flags for ws-scheme moved to advec_ws.
171	!
172	! 1931 2016-06-10 12:06:59Z suehring
173	! Rename multigrid into multigrid_noopt and multigrid_fast into multigrid
174	!
175	! 1910 2016-05-26 06:49:46Z raasch
176	! Bugfix: if topography is read from file, Neumann conditions are used for the
177	! nzb_local array (instead of cyclic conditions) in case that non-cyclic
178	! boundary conditions are switched on for the run
179	!
180	! 1902 2016-05-09 11:18:56Z suehring
181	! Set topography flags for multigrid solver only (not for multigrid_fast)
182	!
183	! 1886 2016-04-21 11:20:47Z suehring
184	! Bugfix: setting advection flags near walls
185	! reformulated index values for nzb_v_inner
186	! variable discriptions added in declaration block
187	!
188	! 1845 2016-04-08 08:29:13Z raasch
189	! nzb_2d removed
190	!
191	! 1804 2016-04-05 16:30:18Z maronga
192	! Removed code for parameter file check (__check)
193	!
194	! 1779 2016-03-03 08:01:28Z raasch
195	! coupling_char is trimmed at every place it occurs, because it can have
196	! different length now
197	!
198	! 1762 2016-02-25 12:31:13Z hellstea
199	! Introduction of nested domain feature
200	!
201	! 1743 2016-01-13 10:23:51Z raasch
202	! Bugfix for calculation of nzb_s_outer and nzb_u_outer at north boundary of
203	! total domain
204	!
205	! 1691 2015-10-26 16:17:44Z maronga
206	! Renamed prandtl_layer to constant_flux_layer.
207	!
208	! 1682 2015-10-07 23:56:08Z knoop
209	! Code annotations made doxygen readable
210	!
211	! 1677 2015-10-02 13:25:23Z boeske
212	! Bugfix: Ghost points are included in wall_flags_0 and wall_flags_00
213	!
214	! 1675 2015-10-02 08:28:59Z gronemeier
215	! Bugfix: Definition of topography grid levels
216	!
217	! 1660 2015-09-21 08:15:16Z gronemeier
218	! Bugfix: Definition of topography grid levels if vertical grid stretching
219	! starts below the maximum topography height.
220	!
221	! 1580 2015-04-10 13:43:49Z suehring
222	! Bugfix: setting flags for 5th order scheme near buildings
223	!
224	! 1575 2015-03-27 09:56:27Z raasch
225	! adjustments for psolver-queries
226	!
227	! 1557 2015-03-05 16:43:04Z suehring
228	! Adjustment for monotoinic limiter
229	!
230	! 1418 2014-06-06 13:05:08Z fricke
231	! Bugfix: Change if-condition for stretched grid in the ocean, with the old
232	! condition and a negative value for dz_stretch_level the condition
233	! was always true for the whole model domain
234	!
235	! 1409 2014-05-23 12:11:32Z suehring
236	! Bugfix: set wall_flags_0 at inflow and outflow boundary also for i <= nxlu
237	! j <= nysv
238	!
239	! 1353 2014-04-08 15:21:23Z heinze
240	! REAL constants provided with KIND-attribute
241	!
242	! 1322 2014-03-20 16:38:49Z raasch
243	! REAL constants defined as wp-kind
244	!
245	! 1320 2014-03-20 08:40:49Z raasch
246	! ONLY-attribute added to USE-statements,
247	! kind-parameters added to all INTEGER and REAL declaration statements,
248	! kinds are defined in new module kinds,
249	! revision history before 2012 removed,
250	! comment fields (!:) to be used for variable explanations added to
251	! all variable declaration statements
252	!
253	! 1221 2013-09-10 08:59:13Z raasch
254	! wall_flags_00 introduced to hold bits 32-63,
255	! additional 3D-flag arrays for replacing the 2D-index array nzb_s_inner in
256	! loops optimized for openACC (pres + flow_statistics)
257	!
258	! 1092 2013-02-02 11:24:22Z raasch
259	! unused variables removed
260	!
261	! 1069 2012-11-28 16:18:43Z maronga
262	! bugfix: added coupling_char to TOPOGRAPHY_DATA to allow topography in the
263	! ocean model in case of coupled runs
264	!
265	! 1036 2012-10-22 13:43:42Z raasch
266	! code put under GPL (PALM 3.9)
267	!
268	! 1015 2012-09-27 09:23:24Z raasch
269	! lower index for calculating wall_flags_0 set to nzb_w_inner instead of
270	! nzb_w_inner+1
271	!
272	! 996 2012-09-07 10:41:47Z raasch
273	! little reformatting
274	!
275	! 978 2012-08-09 08:28:32Z fricke
276	! Bugfix: nzb_max is set to nzt at non-cyclic lateral boundaries
277	! Bugfix: Set wall_flags_0 for inflow boundary
278	!
279	! 927 2012-06-06 19:15:04Z raasch
280	! Wall flags are not set for multigrid method in case of masking method
281	!
282	! 864 2012-03-27 15:10:33Z gryschka
283	! In case of ocean and Dirichlet bottom bc for u and v dzu_mg and ddzu_pres
284	! were not correctly defined for k=1.
285	!
286	! 861 2012-03-26 14:18:34Z suehring
287	! Set wall_flags_0. The array is needed for degradation in ws-scheme near walls,
288	! inflow and outflow boundaries as well as near the bottom and the top of the
289	! model domain.!
290	! Initialization of nzb_s_inner and nzb_w_inner.
291	! gls has to be at least nbgp to do not exceed the array bounds of nzb_local
292	! while setting wall_flags_0
293	!
294	! 843 2012-02-29 15:16:21Z gryschka
295	! In case of ocean and dirichlet bc for u and v at the bottom
296	! the first u-level ist defined at same height as the first w-level
297	!
298	! 818 2012-02-08 16:11:23Z maronga
299	! Bugfix: topo_height is only required if topography is used. It is thus now
300	! allocated in the topography branch
301	!
302	! 809 2012-01-30 13:32:58Z maronga
303	! Bugfix: replaced .AND. and .NOT. with && and ! in the preprocessor directives
304	!
305	! 807 2012-01-25 11:53:51Z maronga
306	! New cpp directive "__check" implemented which is used by check_namelist_files
307	!
308	! Revision 1.1 1997/08/11 06:17:45 raasch
309	! Initial revision (Testversion)
310	!
311	!
312	! Description:
313	! -----------------------------------------------------------------------------!
314	!> Creating grid depending constants
315	!> @todo: Rearrange topo flag list
316	!> @todo: reference 3D buildings on top of orography is not tested and may need
317	!> further improvement for steep slopes
318	!> @todo: Use more advanced setting of building type at filled holes
319	!------------------------------------------------------------------------------!
320	SUBROUTINE init_grid
321
322	USE advec_ws, &
323	ONLY: ws_init_flags
324
325	USE arrays_3d, &
326	ONLY: dd2zu, ddzu, ddzu_pres, ddzw, dzu, dzw, zu, zw
327
328	USE control_parameters, &
329	ONLY: bc_lr_cyc, bc_ns_cyc, building_height, building_length_x, &
330	building_length_y, building_wall_left, building_wall_south, &
331	canyon_height, canyon_wall_left, canyon_wall_south, &
332	canyon_width_x, canyon_width_y, constant_flux_layer, &
333	dp_level_ind_b, dz, dz_max, dz_stretch_factor, &
334	dz_stretch_factor_array, dz_stretch_level, dz_stretch_level_end,&
335	dz_stretch_level_end_index, dz_stretch_level_start_index, &
336	dz_stretch_level_start, grid_level, &
337	force_bound_l, force_bound_r, force_bound_n, force_bound_s, &
338	ibc_uv_b, inflow_l, inflow_n, inflow_r, inflow_s, &
339	masking_method, maximum_grid_level, message_string, &
340	momentum_advec, nest_domain, nest_bound_l, &
341	nest_bound_n, nest_bound_r, nest_bound_s, &
342	number_stretch_level_end, number_stretch_level_start, ocean, &
343	outflow_l, outflow_n, outflow_r, outflow_s, psolver, &
344	scalar_advec, topography, topography_grid_convention, &
345	tunnel_height, tunnel_length, tunnel_width_x, tunnel_width_y, &
346	tunnel_wall_depth, use_surface_fluxes, use_top_fluxes, &
347	wall_adjustment_factor
348
349	USE grid_variables, &
350	ONLY: ddx, ddx2, ddy, ddy2, dx, dx2, dy, dy2, zu_s_inner, zw_w_inner
351
352	USE indices, &
353	ONLY: nbgp, nx, nxl, nxlg, nxr, nxrg, ny, nyn, nyng, nys, nysg, nz, &
354	nzb, nzb_diff, nzb_diff_s_inner, nzb_diff_s_outer, &
355	nzb_max, nzb_s_inner, nzb_s_outer, nzb_u_inner, &
356	nzb_u_outer, nzb_v_inner, nzb_v_outer, nzb_w_inner, &
357	nzb_w_outer, nzt, topo_min_level
358
359	USE kinds
360
361	USE pegrid
362
363	USE poismg_noopt_mod
364
365	USE surface_mod, &
366	ONLY: get_topography_top_index, get_topography_top_index_ji, init_bc
367
368	USE vertical_nesting_mod, &
369	ONLY: vnested, vnest_init_grid
370
371	IMPLICIT NONE
372
373	INTEGER(iwp) :: i !< index variable along x
374	INTEGER(iwp) :: j !< index variable along y
375	INTEGER(iwp) :: k !< index variable along z
376	INTEGER(iwp) :: k_top !< topography top index on local PE
377	INTEGER(iwp) :: n !< loop variable for stretching
378	INTEGER(iwp) :: number_dz !< number of user-specified dz values
379	INTEGER(iwp) :: nzb_local_max !< vertical grid index of maximum topography height
380	INTEGER(iwp) :: nzb_local_min !< vertical grid index of minimum topography height
381
382	INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE :: nzb_local !< index for topography top at cell-center
383	INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE :: nzb_tmp !< dummy to calculate topography indices on u- and v-grid
384
385	INTEGER(iwp), DIMENSION(:,:,:), ALLOCATABLE :: topo !< input array for 3D topography and dummy array for setting "outer"-flags
386
387	REAL(wp) :: dz_level_end !< distance between calculated height level for u/v-grid and user-specified end level for stretching
388	REAL(wp) :: dz_stretched !< stretched vertical grid spacing
389
390	REAL(wp), DIMENSION(:), ALLOCATABLE :: min_dz_stretch_level_end !< Array that contains all minimum heights where the stretching can end
391
392
393	!
394	!-- Calculation of horizontal array bounds including ghost layers
395	nxlg = nxl - nbgp
396	nxrg = nxr + nbgp
397	nysg = nys - nbgp
398	nyng = nyn + nbgp
399
400	!
401	!-- Allocate grid arrays
402	ALLOCATE( ddzu(1:nzt+1), ddzw(1:nzt+1), dd2zu(1:nzt), dzu(1:nzt+1), &
403	dzw(1:nzt+1), zu(nzb:nzt+1), zw(nzb:nzt+1) )
404
405	!
406	!-- Compute height of u-levels from constant grid length and dz stretch factors
407	IF ( dz(1) == -1.0_wp ) THEN
408	message_string = 'missing dz'
409	CALL message( 'init_grid', 'PA0200', 1, 2, 0, 6, 0 )
410	ELSEIF ( dz(1) <= 0.0_wp ) THEN
411	WRITE( message_string, * ) 'dz=',dz(1),' <= 0.0'
412	CALL message( 'init_grid', 'PA0201', 1, 2, 0, 6, 0 )
413	ENDIF
414
415	!
416	!-- Initialize dz_stretch_level_start with the value of dz_stretch_level
417	!-- if it was set by the user
418	IF ( dz_stretch_level /= -9999999.9_wp ) THEN
419	dz_stretch_level_start(1) = dz_stretch_level
420	ENDIF
421
422	!
423	!-- Determine number of dz values and stretching levels specified by the
424	!-- user to allow right controlling of the stretching mechanism and to
425	!-- perform error checks
426	number_dz = COUNT( dz /= -1.0_wp )
427	number_stretch_level_start = COUNT( dz_stretch_level_start /= &
428	-9999999.9_wp )
429	number_stretch_level_end = COUNT( dz_stretch_level_end /= &
430	9999999.9_wp )
431
432	!
433	!-- The number of specified end levels +1 has to be the same than the number
434	!-- of specified dz values
435	IF ( number_dz /= number_stretch_level_end + 1 ) THEN
436	WRITE( message_string, * ) 'The number of values for dz = ', &
437	number_dz, 'has to be the same than& ', &
438	'the number of values for ', &
439	'dz_stretch_level_end + 1 = ', &
440	number_stretch_level_end+1
441	CALL message( 'init_grid', 'PA0156', 1, 2, 0, 6, 0 )
442	ENDIF
443
444	!
445	!-- The number of specified start levels has to be the same or one less than
446	!-- the number of specified dz values
447	IF ( number_dz /= number_stretch_level_start + 1 .AND. &
448	number_dz /= number_stretch_level_start ) THEN
449	WRITE( message_string, * ) 'The number of values for dz = ', &
450	number_dz, 'has to be the same or one ', &
451	'more than& the number of values for ', &
452	'dz_stretch_level_start = ', &
453	number_stretch_level_start
454	CALL message( 'init_grid', 'PA0211', 1, 2, 0, 6, 0 )
455	ENDIF
456
457	!-- The number of specified start levels has to be the same or one more than
458	!-- the number of specified end levels
459	IF ( number_stretch_level_start /= number_stretch_level_end + 1 .AND. &
460	number_stretch_level_start /= number_stretch_level_end ) THEN
461	WRITE( message_string, * ) 'The number of values for ', &
462	'dz_stretch_level_start = ', &
463	dz_stretch_level_start, 'has to be the ',&
464	'same or one more than& the number of ', &
465	'values for dz_stretch_level_end = ', &
466	number_stretch_level_end
467	CALL message( 'init_grid', 'PA0216', 1, 2, 0, 6, 0 )
468	ENDIF
469
470	!
471	!-- Initialize dz for the free atmosphere with the value of dz_max
472	IF ( dz(number_stretch_level_start+1) == -1.0_wp .AND. &
473	number_stretch_level_start /= 0 ) THEN
474	dz(number_stretch_level_start+1) = dz_max
475	ENDIF
476
477	!
478	!-- Initialize the stretching factor if (infinitely) stretching in the free
479	!-- atmosphere is desired (dz_stretch_level_end was not specified for the
480	!-- free atmosphere)
481	IF ( number_stretch_level_start == number_stretch_level_end + 1 ) THEN
482	dz_stretch_factor_array(number_stretch_level_start) = &
483	dz_stretch_factor
484	ENDIF
485
486	!
487	!-- Allocation of arrays for stretching
488	ALLOCATE( min_dz_stretch_level_end(number_stretch_level_start) )
489
490	!
491	!-- Define the vertical grid levels
492	IF ( .NOT. ocean ) THEN
493
494	!
495	!-- The stretching region has to be large enough to allow for a smooth
496	!-- transition between two different grid spacings
497	DO n = 1, number_stretch_level_start
498	min_dz_stretch_level_end(n) = dz_stretch_level_start(n) + &
499	4 * MAX( dz(n),dz(n+1) )
500	ENDDO
501
502	IF ( ANY( min_dz_stretch_level_end(1:number_stretch_level_start) > &
503	dz_stretch_level_end(1:number_stretch_level_start) ) ) THEN
504	message_string= 'Eeach dz_stretch_level_end has to be larger ' // &
505	'than its corresponding value for &' // &
506	'dz_stretch_level_start + 4*MAX(dz(n),dz(n+1)) '//&
507	'to allow for smooth grid stretching'
508	CALL message( 'init_grid', 'PA0224', 1, 2, 0, 6, 0 )
509	ENDIF
510
511	!
512	!-- Stretching must not be applied within the prandtl_layer
513	!-- (first two grid points). For the default case dz_stretch_level_start
514	!-- is negative. Therefore the absolut value is checked here.
515	IF ( ANY( ABS( dz_stretch_level_start ) < dz(1) * 1.5_wp ) ) THEN
516	WRITE( message_string, * ) 'Eeach dz_stretch_level_start has to be ',&
517	'larger than ', dz(1) * 1.5
518	CALL message( 'init_grid', 'PA0226', 1, 2, 0, 6, 0 )
519	ENDIF
520
521	!
522	!-- The stretching has to start and end on a grid level. Therefore
523	!-- user-specified values have to ''interpolate'' to the next lowest level
524	IF ( number_stretch_level_start /= 0 ) THEN
525	dz_stretch_level_start(1) = INT( (dz_stretch_level_start(1) - &
526	dz(1)/2.0) / dz(1) ) &
527	* dz(1) + dz(1)/2.0
528	ENDIF
529
530	IF ( number_stretch_level_start > 1 ) THEN
531	DO n = 2, number_stretch_level_start
532	dz_stretch_level_start(n) = INT( dz_stretch_level_start(n) / &
533	dz(n) ) * dz(n)
534	ENDDO
535	ENDIF
536
537	IF ( number_stretch_level_end /= 0 ) THEN
538	DO n = 1, number_stretch_level_end
539	dz_stretch_level_end(n) = INT( dz_stretch_level_end(n) / &
540	dz(n+1) ) * dz(n+1)
541	ENDDO
542	ENDIF
543
544	!
545	!-- Determine stretching factor if necessary
546	IF ( number_stretch_level_end >= 1 ) THEN
547	CALL calculate_stretching_factor( number_stretch_level_end )
548	ENDIF
549
550	!
551	!-- Grid for atmosphere with surface at z=0 (k=0, w-grid).
552	!-- First compute the u- and v-levels. In case of dirichlet bc for u and v
553	!-- the first u/v- and w-level (k=0) are defined at same height (z=0).
554	!-- The second u-level (k=1) corresponds to the top of the
555	!-- Prandtl-layer.
556	IF ( ibc_uv_b == 0 .OR. ibc_uv_b == 2 ) THEN
557	zu(0) = 0.0_wp
558	ELSE
559	zu(0) = - dz(1) * 0.5_wp
560	ENDIF
561
562	zu(1) = dz(1) * 0.5_wp
563
564	!
565	!-- Determine u and v height levels considering the possibility of grid
566	!-- stretching in several heights.
567	n = 1
568	dz_stretch_level_start_index = nzt+1
569	dz_stretch_level_end_index = nzt+1
570	dz_stretched = dz(1)
571
572	!-- The default value of dz_stretch_level_start is negative, thus the first
573	!-- condition is always true. Hence, the second condition is necessary.
574	DO k = 2, nzt+1
575	IF ( dz_stretch_level_start(n) <= zu(k-1) .AND. &
576	dz_stretch_level_start(n) /= -9999999.9_wp ) THEN
577	dz_stretched = dz_stretched * dz_stretch_factor_array(n)
578
579	IF ( dz(n) > dz(n+1) ) THEN
580	dz_stretched = MAX( dz_stretched, dz(n+1) ) !Restrict dz_stretched to the user-specified (higher) dz
581	ELSE
582	dz_stretched = MIN( dz_stretched, dz(n+1) ) !Restrict dz_stretched to the user-specified (lower) dz
583	ENDIF
584
585	IF ( dz_stretch_level_start_index(n) == nzt+1 ) &
586	dz_stretch_level_start_index(n) = k-1
587
588	ENDIF
589
590	zu(k) = zu(k-1) + dz_stretched
591
592	!
593	!-- Make sure that the stretching ends exactly at dz_stretch_level_end
594	dz_level_end = ABS( zu(k) - dz_stretch_level_end(n) )
595
596	IF ( dz_level_end < dz(n+1)/3.0 ) THEN
597	zu(k) = dz_stretch_level_end(n)
598	dz_stretched = dz(n+1)
599	dz_stretch_level_end_index(n) = k
600	n = n + 1
601	ENDIF
602	ENDDO
603
604	!
605	!-- Compute the w-levels. They are always staggered half-way between the
606	!-- corresponding u-levels. In case of dirichlet bc for u and v at the
607	!-- ground the first u- and w-level (k=0) are defined at same height (z=0).
608	!-- The top w-level is extrapolated linearly.
609	zw(0) = 0.0_wp
610	DO k = 1, nzt
611	zw(k) = ( zu(k) + zu(k+1) ) * 0.5_wp
612	ENDDO
613	zw(nzt+1) = zw(nzt) + 2.0_wp * ( zu(nzt+1) - zw(nzt) )
614
615	ELSE
616
617	!
618	!-- The stretching region has to be large enough to allow for a smooth
619	!-- transition between two different grid spacings
620	DO n = 1, number_stretch_level_start
621	min_dz_stretch_level_end(n) = dz_stretch_level_start(n) - &
622	4 * MAX( dz(n),dz(n+1) )
623	ENDDO
624
625	IF ( ANY( min_dz_stretch_level_end (1:number_stretch_level_start) < &
626	dz_stretch_level_end(1:number_stretch_level_start) ) ) THEN
627	message_string= 'Eeach dz_stretch_level_end has to be less ' // &
628	'than its corresponding value for &' // &
629	'dz_stretch_level_start - 4*MAX(dz(n),dz(n+1)) '//&
630	'to allow for smooth grid stretching'
631	CALL message( 'init_grid', 'PA0224', 1, 2, 0, 6, 0 )
632	ENDIF
633
634	!
635	!-- Stretching must not be applied within the prandtl_layer
636	!-- (first two grid points). For the default case dz_stretch_level_start
637	!-- is negative. Therefore the absolut value is checked here.
638	IF ( ANY( dz_stretch_level_start > dz(1) * 1.5_wp ) ) THEN
639	WRITE( message_string, * ) 'Eeach dz_stretch_level_start has to be ',&
640	'less than ', dz(1) * 1.5
641	CALL message( 'init_grid', 'PA0226', 1, 2, 0, 6, 0 )
642	ENDIF
643
644	!
645	!-- The stretching has to start and end on a grid level. Therefore
646	!-- user-specified values have to ''interpolate'' to the next highest level
647	IF ( number_stretch_level_start /= 0 ) THEN
648	dz_stretch_level_start(1) = INT( (dz_stretch_level_start(1) + &
649	dz(1)/2.0) / dz(1) ) &
650	* dz(1) - dz(1)/2.0
651	ENDIF
652
653	IF ( number_stretch_level_start > 1 ) THEN
654	DO n = 2, number_stretch_level_start
655	dz_stretch_level_start(n) = INT( dz_stretch_level_start(n) / &
656	dz(n) ) * dz(n)
657	ENDDO
658	ENDIF
659
660	IF ( number_stretch_level_end /= 0 ) THEN
661	DO n = 1, number_stretch_level_end
662	dz_stretch_level_end(n) = INT( dz_stretch_level_end(n) / &
663	dz(n+1) ) * dz(n+1)
664	ENDDO
665	ENDIF
666
667	!
668	!-- Determine stretching factor if necessary
669	IF ( number_stretch_level_end >= 1 ) THEN
670	CALL calculate_stretching_factor( number_stretch_level_end )
671	ENDIF
672
673	!
674	!-- Grid for ocean with free water surface is at k=nzt (w-grid).
675	!-- In case of neumann bc at the ground the first first u-level (k=0) lies
676	!-- below the first w-level (k=0). In case of dirichlet bc the first u- and
677	!-- w-level are defined at same height, but staggered from the second level.
678	!-- The second u-level (k=1) corresponds to the top of the Prandtl-layer.
679	!-- z values are negative starting from z=0 (surface)
680	zu(nzt+1) = dz(1) * 0.5_wp
681	zu(nzt) = - dz(1) * 0.5_wp
682
683	!
684	!-- Determine u and v height levels considering the possibility of grid
685	!-- stretching in several heights.
686	n = 1
687	dz_stretch_level_start_index = 0
688	dz_stretch_level_end_index = 0
689	dz_stretched = dz(1)
690
691	DO k = nzt-1, 0, -1
692
693	IF ( dz_stretch_level_start(n) >= zu(k+1) ) THEN
694	dz_stretched = dz_stretched * dz_stretch_factor_array(n)
695
696	IF ( dz(n) > dz(n+1) ) THEN
697	dz_stretched = MAX( dz_stretched, dz(n+1) ) !Restrict dz_stretched to the user-specified (higher) dz
698	ELSE
699	dz_stretched = MIN( dz_stretched, dz(n+1) ) !Restrict dz_stretched to the user-specified (lower) dz
700	ENDIF
701
702	IF ( dz_stretch_level_start_index(n) == 0 ) &
703	dz_stretch_level_start_index(n) = k+1
704
705	ENDIF
706
707	zu(k) = zu(k+1) - dz_stretched
708
709	!
710	!-- Make sure that the stretching ends exactly at dz_stretch_level_end
711	dz_level_end = ABS( zu(k) - dz_stretch_level_end(n) )
712
713	IF ( dz_level_end < dz(n+1)/3.0 ) THEN
714	zu(k) = dz_stretch_level_end(n)
715	dz_stretched = dz(n+1)
716	dz_stretch_level_end_index(n) = k
717	n = n + 1
718	ENDIF
719	ENDDO
720
721	!
722	!-- Compute the w-levels. They are always staggered half-way between the
723	!-- corresponding u-levels, except in case of dirichlet bc for u and v
724	!-- at the ground. In this case the first u- and w-level are defined at
725	!-- same height. The top w-level (nzt+1) is not used but set for
726	!-- consistency, since w and all scalar variables are defined up tp nzt+1.
727	zw(nzt+1) = dz(1)
728	zw(nzt) = 0.0_wp
729	DO k = 0, nzt
730	zw(k) = ( zu(k) + zu(k+1) ) * 0.5_wp
731	ENDDO
732
733	!
734	!-- In case of dirichlet bc for u and v the first u- and w-level are defined
735	!-- at same height.
736	IF ( ibc_uv_b == 0 ) THEN
737	zu(0) = zw(0)
738	ENDIF
739
740	ENDIF
741
742	!
743	!-- Compute grid lengths.
744	DO k = 1, nzt+1
745	dzu(k) = zu(k) - zu(k-1)
746	ddzu(k) = 1.0_wp / dzu(k)
747	dzw(k) = zw(k) - zw(k-1)
748	ddzw(k) = 1.0_wp / dzw(k)
749	ENDDO
750
751	DO k = 1, nzt
752	dd2zu(k) = 1.0_wp / ( dzu(k) + dzu(k+1) )
753	ENDDO
754
755	!
756	!-- The FFT- SOR-pressure solvers assume grid spacings of a staggered grid
757	!-- everywhere. For the actual grid, the grid spacing at the lowest level
758	!-- is only dz/2, but should be dz. Therefore, an additional array
759	!-- containing with appropriate grid information is created for these
760	!-- solvers.
761	IF ( psolver(1:9) /= 'multigrid' ) THEN
762	ALLOCATE( ddzu_pres(1:nzt+1) )
763	ddzu_pres = ddzu
764	ddzu_pres(1) = ddzu_pres(2) ! change for lowest level
765	ENDIF
766
767	!
768	!-- Compute the reciprocal values of the horizontal grid lengths.
769	ddx = 1.0_wp / dx
770	ddy = 1.0_wp / dy
771	dx2 = dx * dx
772	dy2 = dy * dy
773	ddx2 = 1.0_wp / dx2
774	ddy2 = 1.0_wp / dy2
775
776	!
777	!-- Allocate 3D array to set topography
778	ALLOCATE( topo(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
779	topo = 0
780	!
781	!-- Initialize topography by generic topography or read from topography from file.
782	CALL init_topo( topo )
783	!
784	!-- Set flags to mask topography on the grid.
785	CALL set_topo_flags( topo )
786	!
787	!-- Calculate wall flag arrays for the multigrid method.
788	!-- Please note, wall flags are only applied in the non-optimized version.
789	IF ( psolver == 'multigrid_noopt' ) CALL poismg_noopt_init
790
791	!
792	!-- Init flags for ws-scheme to degrade order of the numerics near walls, i.e.
793	!-- to decrease the numerical stencil appropriately.
794	IF ( momentum_advec == 'ws-scheme' .OR. scalar_advec == 'ws-scheme' ) &
795	CALL ws_init_flags
796
797	!
798	!-- Determine the maximum level of topography. It is used for
799	!-- steering the degradation of order of the applied advection scheme,
800	!-- as well in the lpm.
801	!-- In case of non-cyclic lateral boundaries, the order of the advection
802	!-- scheme has to be reduced up to nzt (required at the lateral boundaries).
803	k_top = 0
804	DO i = nxl, nxr
805	DO j = nys, nyn
806	DO k = nzb, nzt + 1
807	k_top = MAX( k_top, MERGE( k, 0, &
808	.NOT. BTEST( topo(k,j,i), 0 ) ) )
809	ENDDO
810	ENDDO
811	ENDDO
812	#if defined( __parallel )
813	CALL MPI_ALLREDUCE( k_top + 1, nzb_max, 1, MPI_INTEGER, & !is +1 really necessary here?
814	MPI_MAX, comm2d, ierr )
815	#else
816	nzb_max = k_top + 1
817	#endif
818	IF ( inflow_l .OR. outflow_l .OR. force_bound_l .OR. nest_bound_l .OR.&
819	inflow_r .OR. outflow_r .OR. force_bound_r .OR. nest_bound_r .OR.&
820	inflow_n .OR. outflow_n .OR. force_bound_n .OR. nest_bound_n .OR.&
821	inflow_s .OR. outflow_s .OR. force_bound_s .OR. nest_bound_s ) &
822	nzb_max = nzt
823	!
824	!-- Finally, if topography extents up to the model top, limit nzb_max to nzt.
825	nzb_max = MIN( nzb_max, nzt )
826	!
827	!-- Determine minimum index of topography. Usually, this will be nzb. In case
828	!-- there is elevated topography, however, the lowest topography will be higher.
829	!-- This index is e.g. used to calculate mean first-grid point atmosphere
830	!-- temperature, surface pressure and density, etc. .
831	topo_min_level = 0
832	#if defined( __parallel )
833	CALL MPI_ALLREDUCE( MINVAL( get_topography_top_index( 's' ) ), &
834	topo_min_level, 1, MPI_INTEGER, MPI_MIN, comm2d, ierr )
835	#else
836	topo_min_level = MINVAL( get_topography_top_index( 's' ) )
837	#endif
838	!
839	!-- Initialize boundary conditions via surface type
840	CALL init_bc
841	!
842	!-- Allocate and set topography height arrays required for data output
843	IF ( TRIM( topography ) /= 'flat' ) THEN
844	!
845	!-- Allocate and set the arrays containing the topography height
846	IF ( nxr == nx .AND. nyn /= ny ) THEN
847	ALLOCATE( zu_s_inner(nxl:nxr+1,nys:nyn), &
848	zw_w_inner(nxl:nxr+1,nys:nyn) )
849	ELSEIF ( nxr /= nx .AND. nyn == ny ) THEN
850	ALLOCATE( zu_s_inner(nxl:nxr,nys:nyn+1), &
851	zw_w_inner(nxl:nxr,nys:nyn+1) )
852	ELSEIF ( nxr == nx .AND. nyn == ny ) THEN
853	ALLOCATE( zu_s_inner(nxl:nxr+1,nys:nyn+1), &
854	zw_w_inner(nxl:nxr+1,nys:nyn+1) )
855	ELSE
856	ALLOCATE( zu_s_inner(nxl:nxr,nys:nyn), &
857	zw_w_inner(nxl:nxr,nys:nyn) )
858	ENDIF
859
860	zu_s_inner = 0.0_wp
861	zw_w_inner = 0.0_wp
862	!
863	!-- Determine local topography height on scalar and w-grid. Note, setting
864	!-- lateral boundary values is not necessary, realized via wall_flags_0
865	!-- array. Further, please note that loop bounds are different from
866	!-- nxl to nxr and nys to nyn on south and right model boundary, hence,
867	!-- use intrinsic lbound and ubound functions to infer array bounds.
868	DO i = LBOUND(zu_s_inner, 1), UBOUND(zu_s_inner, 1)
869	DO j = LBOUND(zu_s_inner, 2), UBOUND(zu_s_inner, 2)
870	!
871	!-- Topography height on scalar grid. Therefore, determine index of
872	!-- upward-facing surface element on scalar grid.
873	zu_s_inner(i,j) = zu( get_topography_top_index_ji( j, i, 's' ) )
874	!
875	!-- Topography height on w grid. Therefore, determine index of
876	!-- upward-facing surface element on w grid.
877	zw_w_inner(i,j) = zw( get_topography_top_index_ji( j, i, 's' ) )
878	ENDDO
879	ENDDO
880	ENDIF
881
882	!
883	!-- In the following, calculate 2D index arrays. Note, these will be removed
884	!-- soon.
885	!-- Allocate outer and inner index arrays for topography and set
886	!-- defaults.
887	ALLOCATE( nzb_s_inner(nysg:nyng,nxlg:nxrg), &
888	nzb_s_outer(nysg:nyng,nxlg:nxrg), &
889	nzb_u_inner(nysg:nyng,nxlg:nxrg), &
890	nzb_u_outer(nysg:nyng,nxlg:nxrg), &
891	nzb_v_inner(nysg:nyng,nxlg:nxrg), &
892	nzb_v_outer(nysg:nyng,nxlg:nxrg), &
893	nzb_w_inner(nysg:nyng,nxlg:nxrg), &
894	nzb_w_outer(nysg:nyng,nxlg:nxrg), &
895	nzb_diff_s_inner(nysg:nyng,nxlg:nxrg), &
896	nzb_diff_s_outer(nysg:nyng,nxlg:nxrg), &
897	nzb_local(nysg:nyng,nxlg:nxrg), &
898	nzb_tmp(nysg:nyng,nxlg:nxrg) )
899	!
900	!-- Initialize 2D-index arrays. Note, these will be removed soon!
901	nzb_local(nys:nyn,nxl:nxr) = get_topography_top_index( 's' )
902	CALL exchange_horiz_2d_int( nzb_local, nys, nyn, nxl, nxr, nbgp )
903	!
904	!-- Check topography for consistency with model domain. Therefore, use
905	!-- maximum and minium topography-top indices. Note, minimum topography top
906	!-- index is already calculated.
907	IF ( TRIM( topography ) /= 'flat' ) THEN
908	#if defined( __parallel )
909	CALL MPI_ALLREDUCE( MAXVAL( get_topography_top_index( 's' ) ), &
910	nzb_local_max, 1, MPI_INTEGER, MPI_MAX, comm2d, ierr )
911	#else
912	nzb_local_max = MAXVAL( get_topography_top_index( 's' ) )
913	#endif
914	nzb_local_min = topo_min_level
915	!
916	!-- Consistency checks
917	IF ( nzb_local_min < 0 .OR. nzb_local_max > nz + 1 ) THEN
918	WRITE( message_string, * ) 'nzb_local values are outside the', &
919	' model domain', &
920	'&MINVAL( nzb_local ) = ', nzb_local_min, &
921	'&MAXVAL( nzb_local ) = ', nzb_local_max
922	CALL message( 'init_grid', 'PA0210', 1, 2, 0, 6, 0 )
923	ENDIF
924	ENDIF
925
926	nzb_s_inner = nzb; nzb_s_outer = nzb
927	nzb_u_inner = nzb; nzb_u_outer = nzb
928	nzb_v_inner = nzb; nzb_v_outer = nzb
929	nzb_w_inner = nzb; nzb_w_outer = nzb
930
931	!
932	!-- Define vertical gridpoint from (or to) which on the usual finite difference
933	!-- form (which does not use surface fluxes) is applied
934	IF ( constant_flux_layer .OR. use_surface_fluxes ) THEN
935	nzb_diff = nzb + 2
936	ELSE
937	nzb_diff = nzb + 1
938	ENDIF
939
940	nzb_diff_s_inner = nzb_diff; nzb_diff_s_outer = nzb_diff
941	!
942	!-- Set Neumann conditions for topography. Will be removed soon.
943	IF ( .NOT. bc_ns_cyc ) THEN
944	IF ( nys == 0 ) THEN
945	DO i = 1, nbgp
946	nzb_local(nys-i,:) = nzb_local(nys,:)
947	ENDDO
948	ELSEIF ( nyn == ny ) THEN
949	DO i = 1, nbgp
950	nzb_local(ny+i,:) = nzb_local(ny,:)
951	ENDDO
952	ENDIF
953	ENDIF
954
955	IF ( .NOT. bc_lr_cyc ) THEN
956	IF ( nxl == 0 ) THEN
957	DO i = 1, nbgp
958	nzb_local(:,nxl-i) = nzb_local(:,nxl)
959	ENDDO
960	ELSEIF ( nxr == nx ) THEN
961	DO i = 1, nbgp
962	nzb_local(:,nx+i) = nzb_local(:,nx)
963	ENDDO
964	ENDIF
965	ENDIF
966	!
967	!-- Initialization of 2D index arrays, will be removed soon!
968	!-- Initialize nzb_s_inner and nzb_w_inner
969	nzb_s_inner = nzb_local
970	nzb_w_inner = nzb_local
971
972	!
973	!-- Initialize remaining index arrays:
974	!-- first pre-initialize them with nzb_s_inner...
975	nzb_u_inner = nzb_s_inner
976	nzb_u_outer = nzb_s_inner
977	nzb_v_inner = nzb_s_inner
978	nzb_v_outer = nzb_s_inner
979	nzb_w_outer = nzb_s_inner
980	nzb_s_outer = nzb_s_inner
981
982	!
983	!-- nzb_s_outer:
984	!-- extend nzb_local east-/westwards first, then north-/southwards
985	nzb_tmp = nzb_local
986	DO j = nys, nyn
987	DO i = nxl, nxr
988	nzb_tmp(j,i) = MAX( nzb_local(j,i-1), nzb_local(j,i), &
989	nzb_local(j,i+1) )
990	ENDDO
991	ENDDO
992
993	CALL exchange_horiz_2d_int( nzb_tmp, nys, nyn, nxl, nxr, nbgp )
994
995	DO i = nxl, nxr
996	DO j = nys, nyn
997	nzb_s_outer(j,i) = MAX( nzb_tmp(j-1,i), nzb_tmp(j,i), &
998	nzb_tmp(j+1,i) )
999	ENDDO
1000	!
1001	!-- non-cyclic boundary conditions (overwritten by call of
1002	!-- exchange_horiz_2d_int below in case of cyclic boundary conditions)
1003	IF ( nys == 0 ) THEN
1004	j = -1
1005	nzb_s_outer(j,i) = MAX( nzb_tmp(j+1,i), nzb_tmp(j,i) )
1006	ENDIF
1007	IF ( nyn == ny ) THEN
1008	j = ny + 1
1009	nzb_s_outer(j,i) = MAX( nzb_tmp(j-1,i), nzb_tmp(j,i) )
1010	ENDIF
1011	ENDDO
1012	!
1013	!-- nzb_w_outer:
1014	!-- identical to nzb_s_outer
1015	nzb_w_outer = nzb_s_outer
1016	!
1017	!-- nzb_u_inner:
1018	!-- extend nzb_local rightwards only
1019	nzb_tmp = nzb_local
1020	DO j = nys, nyn
1021	DO i = nxl, nxr
1022	nzb_tmp(j,i) = MAX( nzb_local(j,i-1), nzb_local(j,i) )
1023	ENDDO
1024	ENDDO
1025
1026	CALL exchange_horiz_2d_int( nzb_tmp, nys, nyn, nxl, nxr, nbgp )
1027
1028	nzb_u_inner = nzb_tmp
1029	!
1030	!-- nzb_u_outer:
1031	!-- extend current nzb_tmp (nzb_u_inner) north-/southwards
1032	DO i = nxl, nxr
1033	DO j = nys, nyn
1034	nzb_u_outer(j,i) = MAX( nzb_tmp(j-1,i), nzb_tmp(j,i), &
1035	nzb_tmp(j+1,i) )
1036	ENDDO
1037	!
1038	!-- non-cyclic boundary conditions (overwritten by call of
1039	!-- exchange_horiz_2d_int below in case of cyclic boundary conditions)
1040	IF ( nys == 0 ) THEN
1041	j = -1
1042	nzb_u_outer(j,i) = MAX( nzb_tmp(j+1,i), nzb_tmp(j,i) )
1043	ENDIF
1044	IF ( nyn == ny ) THEN
1045	j = ny + 1
1046	nzb_u_outer(j,i) = MAX( nzb_tmp(j-1,i), nzb_tmp(j,i) )
1047	ENDIF
1048	ENDDO
1049
1050	!
1051	!-- nzb_v_inner:
1052	!-- extend nzb_local northwards only
1053	nzb_tmp = nzb_local
1054	DO i = nxl, nxr
1055	DO j = nys, nyn
1056	nzb_tmp(j,i) = MAX( nzb_local(j-1,i), nzb_local(j,i) )
1057	ENDDO
1058	ENDDO
1059
1060	CALL exchange_horiz_2d_int( nzb_tmp, nys, nyn, nxl, nxr, nbgp )
1061	nzb_v_inner = nzb_tmp
1062
1063	!
1064	!-- nzb_v_outer:
1065	!-- extend current nzb_tmp (nzb_v_inner) right-/leftwards
1066	DO j = nys, nyn
1067	DO i = nxl, nxr
1068	nzb_v_outer(j,i) = MAX( nzb_tmp(j,i-1), nzb_tmp(j,i), &
1069	nzb_tmp(j,i+1) )
1070	ENDDO
1071	!
1072	!-- non-cyclic boundary conditions (overwritten by call of
1073	!-- exchange_horiz_2d_int below in case of cyclic boundary conditions)
1074	IF ( nxl == 0 ) THEN
1075	i = -1
1076	nzb_v_outer(j,i) = MAX( nzb_tmp(j,i+1), nzb_tmp(j,i) )
1077	ENDIF
1078	IF ( nxr == nx ) THEN
1079	i = nx + 1
1080	nzb_v_outer(j,i) = MAX( nzb_tmp(j,i-1), nzb_tmp(j,i) )
1081	ENDIF
1082	ENDDO
1083
1084	!
1085	!-- Exchange of lateral boundary values (parallel computers) and cyclic
1086	!-- boundary conditions, if applicable.
1087	!-- Since nzb_s_inner and nzb_w_inner are derived directly from nzb_local
1088	!-- they do not require exchange and are not included here.
1089	CALL exchange_horiz_2d_int( nzb_u_inner, nys, nyn, nxl, nxr, nbgp )
1090	CALL exchange_horiz_2d_int( nzb_u_outer, nys, nyn, nxl, nxr, nbgp )
1091	CALL exchange_horiz_2d_int( nzb_v_inner, nys, nyn, nxl, nxr, nbgp )
1092	CALL exchange_horiz_2d_int( nzb_v_outer, nys, nyn, nxl, nxr, nbgp )
1093	CALL exchange_horiz_2d_int( nzb_w_outer, nys, nyn, nxl, nxr, nbgp )
1094	CALL exchange_horiz_2d_int( nzb_s_outer, nys, nyn, nxl, nxr, nbgp )
1095
1096	!
1097	!-- Set the individual index arrays which define the k index from which on
1098	!-- the usual finite difference form (which does not use surface fluxes) is
1099	!-- applied
1100	IF ( constant_flux_layer .OR. use_surface_fluxes ) THEN
1101	nzb_diff_s_inner = nzb_s_inner + 2
1102	nzb_diff_s_outer = nzb_s_outer + 2
1103	ELSE
1104	nzb_diff_s_inner = nzb_s_inner + 1
1105	nzb_diff_s_outer = nzb_s_outer + 1
1106	ENDIF
1107	!
1108	!-- Vertical nesting: communicate vertical grid level arrays between fine and
1109	!-- coarse grid
1110	IF ( vnested ) CALL vnest_init_grid
1111
1112	END SUBROUTINE init_grid
1113
1114
1115	! Description:
1116	! -----------------------------------------------------------------------------!
1117	!> Calculation of the stretching factor through an iterative method. Ideas were
1118	!> taken from the paper "Regional stretched grid generation and its application
1119	!> to the NCAR RegCM (1999)". Normally, no analytic solution exists because the
1120	!> system of equations has two variables (r,l) but four requirements
1121	!> (l=integer, r=[0,88;1,2], Eq(6), Eq(5) starting from index j=1) which
1122	!> results into an overdetermined system.
1123	!------------------------------------------------------------------------------!
1124	SUBROUTINE calculate_stretching_factor( number_end )
1125
1126	USE control_parameters, &
1127	ONLY: dz, dz_stretch_factor, dz_stretch_factor_array, &
1128	dz_stretch_level_end, dz_stretch_level_start, message_string
1129
1130	USE kinds
1131
1132	IMPLICIT NONE
1133
1134	INTEGER(iwp) :: iterations !< number of iterations until stretch_factor_lower/upper_limit is reached
1135	INTEGER(iwp) :: l_rounded !< after l_rounded grid levels dz(n) is strechted to dz(n+1) with stretch_factor_2
1136	INTEGER(iwp) :: n !< loop variable for stretching
1137
1138	INTEGER(iwp), INTENT(IN) :: number_end !< number of user-specified end levels for stretching
1139
1140	REAL(wp) :: delta_l !< absolute difference between l and l_rounded
1141	REAL(wp) :: delta_stretch_factor !< absolute difference between stretch_factor_1 and stretch_factor_2
1142	REAL(wp) :: delta_total_new !< sum of delta_l and delta_stretch_factor for the next iteration (should be as small as possible)
1143	REAL(wp) :: delta_total_old !< sum of delta_l and delta_stretch_factor for the last iteration
1144	REAL(wp) :: distance !< distance between dz_stretch_level_start and dz_stretch_level_end (stretching region)
1145	REAL(wp) :: l !< value that fulfil Eq. (5) in the paper mentioned above together with stretch_factor_1 exactly
1146	REAL(wp) :: numerator !< numerator of the quotient
1147	REAL(wp) :: stretch_factor_1 !< stretching factor that fulfil Eq. (5) togehter with l exactly
1148	REAL(wp) :: stretch_factor_2 !< stretching factor that fulfil Eq. (6) togehter with l_rounded exactly
1149
1150	REAL(wp), PARAMETER :: stretch_factor_interval = 1.0E-06 !< interval for sampling possible stretching factors
1151	REAL(wp), PARAMETER :: stretch_factor_lower_limit = 0.88 !< lowest possible stretching factor
1152	REAL(wp), PARAMETER :: stretch_factor_upper_limit = 1.12 !< highest possible stretching factor
1153
1154
1155	l = 0
1156	DO n = 1, number_end
1157
1158	iterations = 1
1159	stretch_factor_1 = 1.0
1160	stretch_factor_2 = 1.0
1161	delta_total_old = 1.0
1162
1163	IF ( dz(n) > dz(n+1) ) THEN
1164	DO WHILE ( stretch_factor_1 >= stretch_factor_lower_limit )
1165
1166	stretch_factor_1 = 1.0 - iterations * stretch_factor_interval
1167	distance = ABS( dz_stretch_level_end(n) - &
1168	dz_stretch_level_start(n) )
1169	numerator = distance*stretch_factor_1/dz(n) + &
1170	stretch_factor_1 - distance/dz(n)
1171
1172	IF ( numerator > 0.0 ) THEN
1173	l = LOG( numerator ) / LOG( stretch_factor_1 ) - 1.0
1174	l_rounded = NINT( l )
1175	delta_l = ABS( l_rounded - l ) / l
1176	ENDIF
1177
1178	stretch_factor_2 = EXP( LOG( dz(n+1)/dz(n) ) / (l_rounded) )
1179
1180	delta_stretch_factor = ABS( stretch_factor_1 - &
1181	stretch_factor_2 ) / &
1182	stretch_factor_2
1183
1184	delta_total_new = delta_l + delta_stretch_factor
1185
1186	!
1187	!-- stretch_factor_1 is taken to guarantee that the stretching
1188	!-- procedure ends as close as possible to dz_stretch_level_end.
1189	!-- stretch_factor_2 would guarantee that the stretched dz(n) is
1190	!-- equal to dz(n+1) after l_rounded grid levels.
1191	IF (delta_total_new < delta_total_old) THEN
1192	dz_stretch_factor_array(n) = stretch_factor_1
1193	delta_total_old = delta_total_new
1194	ENDIF
1195
1196	iterations = iterations + 1
1197
1198	ENDDO
1199
1200	ELSEIF ( dz(n) < dz(n+1) ) THEN
1201	DO WHILE ( stretch_factor_1 <= stretch_factor_upper_limit )
1202
1203	stretch_factor_1 = 1.0 + iterations * stretch_factor_interval
1204	distance = ABS( dz_stretch_level_end(n) - &
1205	dz_stretch_level_start(n) )
1206	numerator = distance*stretch_factor_1/dz(n) + &
1207	stretch_factor_1 - distance/dz(n)
1208
1209	l = LOG( numerator ) / LOG( stretch_factor_1 ) - 1.0
1210	l_rounded = NINT( l )
1211	delta_l = ABS( l_rounded - l ) / l
1212
1213	stretch_factor_2 = EXP( LOG( dz(n+1)/dz(n) ) / (l_rounded) )
1214
1215	delta_stretch_factor = ABS( stretch_factor_1 - &
1216	stretch_factor_2 ) / &
1217	stretch_factor_2
1218
1219	delta_total_new = delta_l + delta_stretch_factor
1220
1221	!
1222	!-- stretch_factor_1 is taken to guarantee that the stretching
1223	!-- procedure ends as close as possible to dz_stretch_level_end.
1224	!-- stretch_factor_2 would guarantee that the stretched dz(n) is
1225	!-- equal to dz(n+1) after l_rounded grid levels.
1226	IF (delta_total_new < delta_total_old) THEN
1227	dz_stretch_factor_array(n) = stretch_factor_1
1228	delta_total_old = delta_total_new
1229	ENDIF
1230
1231	iterations = iterations + 1
1232	ENDDO
1233
1234	ELSE
1235	message_string= 'Two adjacent values of dz must be different'
1236	CALL message( 'init_grid', 'PA0228', 1, 2, 0, 6, 0 )
1237
1238	ENDIF
1239	ENDDO
1240
1241	END SUBROUTINE calculate_stretching_factor
1242
1243
1244	! Description:
1245	! -----------------------------------------------------------------------------!
1246	!> Set temporary topography flags and reference buildings on top of underlying
1247	!> orography.
1248	!------------------------------------------------------------------------------!
1249	SUBROUTINE process_topography( topo_3d )
1250
1251	USE arrays_3d, &
1252	ONLY: zu, zw
1253
1254	USE control_parameters, &
1255	ONLY: bc_lr_cyc, bc_ns_cyc, land_surface, ocean, urban_surface
1256
1257	USE indices, &
1258	ONLY: nbgp, nx, nxl, nxlg, nxr, nxrg, ny, nyn, nyng, nys, nysg, nzb, &
1259	nzt
1260
1261	USE netcdf_data_input_mod, &
1262	ONLY: buildings_f, building_id_f, input_pids_static, &
1263	terrain_height_f
1264
1265	USE kinds
1266
1267	USE pegrid
1268
1269	IMPLICIT NONE
1270
1271	INTEGER(iwp) :: i !< running index along x-direction
1272	INTEGER(iwp) :: j !< running index along y-direction
1273	INTEGER(iwp) :: k !< running index along z-direction with respect to numeric grid
1274	INTEGER(iwp) :: k2 !< running index along z-direction with respect to netcdf grid
1275	INTEGER(iwp) :: nr !< index variable indication maximum terrain height for respective building ID
1276	INTEGER(iwp) :: num_build !< counter for number of buildings
1277	INTEGER(iwp) :: topo_top_index !< orography top index, used to map 3D buildings onto terrain
1278
1279	INTEGER(iwp), DIMENSION(:), ALLOCATABLE :: displace_dum !< displacements of start addresses, used for MPI_ALLGATHERV
1280	INTEGER(iwp), DIMENSION(:), ALLOCATABLE :: build_ids !< building IDs on entire model domain
1281	INTEGER(iwp), DIMENSION(:), ALLOCATABLE :: build_ids_final !< building IDs on entire model domain, multiple occurences are sorted out
1282	INTEGER(iwp), DIMENSION(:), ALLOCATABLE :: build_ids_final_tmp !< temporary array used for resizing
1283	INTEGER(iwp), DIMENSION(:), ALLOCATABLE :: build_ids_l !< building IDs on local subdomain
1284	INTEGER(iwp), DIMENSION(:), ALLOCATABLE :: build_ids_l_tmp !< temporary array used to resize array of building IDs
1285
1286	INTEGER(iwp), DIMENSION(0:numprocs-1) :: num_buildings !< number of buildings with different ID on entire model domain
1287	INTEGER(iwp), DIMENSION(0:numprocs-1) :: num_buildings_l !< number of buildings with different ID on local subdomain
1288
1289	INTEGER(iwp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) :: topo_3d !< input array for 3D topography and dummy array for setting "outer"-flags
1290
1291	REAL(wp) :: ocean_offset !< offset to consider inverse vertical coordinate at topography definition
1292	REAL(wp), DIMENSION(:), ALLOCATABLE :: oro_max !< maximum terrain height occupied by an building with certain id
1293	REAL(wp), DIMENSION(:), ALLOCATABLE :: oro_max_l !< maximum terrain height occupied by an building with certain id, on local subdomain
1294
1295	!
1296	!-- In the following, buildings and orography are further preprocessed
1297	!-- before they are mapped on the LES grid.
1298	!-- Buildings are mapped on top of the orography by maintaining the roof
1299	!-- shape of the building. This can be achieved by referencing building on
1300	!-- top of the maximum terrain height within the area occupied by the
1301	!-- respective building. As buildings and terrain height are defined PE-wise,
1302	!-- parallelization of this referencing is required (a building can be
1303	!-- distributed between different PEs).
1304	!-- In a first step, determine the number of buildings with different
1305	!-- building id on each PE. In a next step, all building ids are gathered
1306	!-- into one array which is present to all PEs. For each building ID,
1307	!-- the maximum terrain height occupied by the respective building is
1308	!-- computed and distributed to each PE.
1309	!-- Finally, for each building id and its respective reference orography,
1310	!-- builidings are mapped on top.
1311	!--
1312	!-- First, pre-set topography flags, bit 1 indicates orography, bit 2
1313	!-- buildings
1314	!-- classify the respective surfaces.
1315	topo_3d = IBSET( topo_3d, 0 )
1316	topo_3d(nzb,:,:) = IBCLR( topo_3d(nzb,:,:), 0 )
1317	!
1318	!-- In order to map topography on PALM grid also in case of ocean simulations,
1319	!-- pre-calculate an offset value.
1320	ocean_offset = MERGE( zw(0), 0.0_wp, ocean )
1321	!
1322	!-- Reference buildings on top of orography. This is not necessary
1323	!-- if topography is read from ASCII file as no distinction between buildings
1324	!-- and terrain height can be made. Moreover, this is also not necessary if
1325	!-- urban-surface and land-surface model are used at the same time.
1326	IF ( input_pids_static ) THEN
1327
1328	IF ( buildings_f%from_file ) THEN
1329	num_buildings_l = 0
1330	num_buildings = 0
1331	!
1332	!-- Allocate at least one element for building ids,
1333	ALLOCATE( build_ids_l(1) )
1334	DO i = nxl, nxr
1335	DO j = nys, nyn
1336	IF ( building_id_f%var(j,i) /= building_id_f%fill ) THEN
1337	IF ( num_buildings_l(myid) > 0 ) THEN
1338	IF ( ANY( building_id_f%var(j,i) .EQ. build_ids_l ) ) &
1339	THEN
1340	CYCLE
1341	ELSE
1342	num_buildings_l(myid) = num_buildings_l(myid) + 1
1343	!
1344	!-- Resize array with different local building ids
1345	ALLOCATE( build_ids_l_tmp(1:SIZE(build_ids_l)) )
1346	build_ids_l_tmp = build_ids_l
1347	DEALLOCATE( build_ids_l )
1348	ALLOCATE( build_ids_l(1:num_buildings_l(myid)) )
1349	build_ids_l(1:num_buildings_l(myid)-1) = &
1350	build_ids_l_tmp(1:num_buildings_l(myid)-1)
1351	build_ids_l(num_buildings_l(myid)) = building_id_f%var(j,i)
1352	DEALLOCATE( build_ids_l_tmp )
1353	ENDIF
1354	!
1355	!-- First occuring building id on PE
1356	ELSE
1357	num_buildings_l(myid) = num_buildings_l(myid) + 1
1358	build_ids_l(1) = building_id_f%var(j,i)
1359	ENDIF
1360	ENDIF
1361	ENDDO
1362	ENDDO
1363	!
1364	!-- Determine number of different building ids for the entire domain
1365	#if defined( __parallel )
1366	CALL MPI_ALLREDUCE( num_buildings_l, num_buildings, numprocs, &
1367	MPI_INTEGER, MPI_SUM, comm2d, ierr )
1368	#else
1369	num_buildings = num_buildings_l
1370	#endif
1371	!
1372	!-- Gather all buildings ids on each PEs.
1373	!-- First, allocate array encompassing all building ids in model domain.
1374	ALLOCATE( build_ids(1:SUM(num_buildings)) )
1375	#if defined( __parallel )
1376	!
1377	!-- Allocate array for displacements.
1378	!-- As each PE may has a different number of buildings, so that
1379	!-- the block sizes send by each PE may not be equal. Hence,
1380	!-- information about the respective displacement is required, indicating
1381	!-- the respective adress where each MPI-task writes into the receive
1382	!-- buffer array
1383	ALLOCATE( displace_dum(0:numprocs-1) )
1384	displace_dum(0) = 0
1385	DO i = 1, numprocs-1
1386	displace_dum(i) = displace_dum(i-1) + num_buildings(i-1)
1387	ENDDO
1388
1389	CALL MPI_ALLGATHERV( build_ids_l(1:num_buildings_l(myid)), &
1390	num_buildings(myid), &
1391	MPI_INTEGER, &
1392	build_ids, &
1393	num_buildings, &
1394	displace_dum, &
1395	MPI_INTEGER, &
1396	comm2d, ierr )
1397
1398	DEALLOCATE( displace_dum )
1399
1400	#else
1401	build_ids = build_ids_l
1402	#endif
1403
1404	!
1405	!-- Note, in parallel mode building ids can occure mutliple times, as
1406	!-- each PE has send its own ids. Therefore, sort out building ids which
1407	!-- appear more than one time.
1408	num_build = 0
1409	DO nr = 1, SIZE(build_ids)
1410
1411	IF ( ALLOCATED(build_ids_final) ) THEN
1412	IF ( ANY( build_ids(nr) .EQ. build_ids_final ) ) THEN
1413	CYCLE
1414	ELSE
1415	num_build = num_build + 1
1416	!
1417	!-- Resize
1418	ALLOCATE( build_ids_final_tmp(1:num_build) )
1419	build_ids_final_tmp(1:num_build-1) = build_ids_final(1:num_build-1)
1420	DEALLOCATE( build_ids_final )
1421	ALLOCATE( build_ids_final(1:num_build) )
1422	build_ids_final(1:num_build-1) = build_ids_final_tmp(1:num_build-1)
1423	build_ids_final(num_build) = build_ids(nr)
1424	DEALLOCATE( build_ids_final_tmp )
1425	ENDIF
1426	ELSE
1427	num_build = num_build + 1
1428	ALLOCATE( build_ids_final(1:num_build) )
1429	build_ids_final(num_build) = build_ids(nr)
1430	ENDIF
1431	ENDDO
1432
1433	!
1434	!-- Determine maximumum terrain height occupied by the respective
1435	!-- building and temporalily store on oro_max
1436	ALLOCATE( oro_max_l(1:SIZE(build_ids_final)) )
1437	ALLOCATE( oro_max(1:SIZE(build_ids_final)) )
1438	oro_max_l = 0.0_wp
1439
1440	DO nr = 1, SIZE(build_ids_final)
1441	oro_max_l(nr) = MAXVAL( &
1442	MERGE( terrain_height_f%var, 0.0_wp, &
1443	building_id_f%var(nys:nyn,nxl:nxr) .EQ. &
1444	build_ids_final(nr) ) )
1445	ENDDO
1446
1447	#if defined( __parallel )
1448	IF ( SIZE(build_ids_final) >= 1 ) THEN
1449	CALL MPI_ALLREDUCE( oro_max_l, oro_max, SIZE( oro_max ), MPI_REAL, &
1450	MPI_MAX, comm2d, ierr )
1451	ENDIF
1452	#else
1453	oro_max = oro_max_l
1454	#endif
1455	!
1456	!-- Finally, determine discrete grid height of maximum orography occupied
1457	!-- by a building. Use all-or-nothing approach, i.e. a grid box is either
1458	oro_max_l = 0.0
1459	DO nr = 1, SIZE(build_ids_final)
1460	DO k = nzb, nzt
1461	IF ( zu(k) - ocean_offset <= oro_max(nr) ) &
1462	oro_max_l = zw(k) - ocean_offset
1463	ENDDO
1464	oro_max = oro_max_l
1465	ENDDO
1466	ENDIF
1467	!
1468	!-- Map orography as well as buildings onto grid.
1469	DO i = nxl, nxr
1470	DO j = nys, nyn
1471	topo_top_index = 0
1472	DO k = nzb, nzt
1473	!
1474	!-- In a first step, if grid point is below or equal the given
1475	!-- terrain height, grid point is flagged to be of type natural.
1476	!-- Please note, in case there is also a building which is lower
1477	!-- than the vertical grid spacing, initialization of surface
1478	!-- attributes will not be correct as given surface information
1479	!-- will not be in accordance to the classified grid points.
1480	!-- Hence, in this case, de-flag the grid point and give it
1481	!-- urban type instead.
1482	IF ( zu(k) - ocean_offset <= terrain_height_f%var(j,i) ) THEN
1483	topo_3d(k,j,i) = IBCLR( topo_3d(k,j,i), 0 )
1484	topo_3d(k,j,i) = IBSET( topo_3d(k,j,i), 1 )
1485	topo_top_index = k ! topo_top_index + 1
1486	ENDIF
1487	!
1488	!-- Set building grid points. Here, only consider 2D buildings.
1489	!-- 3D buildings require separate treatment.
1490	IF ( buildings_f%from_file .AND. buildings_f%lod == 1 ) THEN
1491	IF ( building_id_f%var(j,i) /= building_id_f%fill ) THEN
1492	!
1493	!-- Determine index where maximum terrain height occupied by
1494	!-- the respective building height is stored.
1495	nr = MINLOC( ABS( build_ids_final - &
1496	building_id_f%var(j,i) ), DIM = 1 )
1497
1498	IF ( zu(k) - ocean_offset <= &
1499	oro_max(nr) + buildings_f%var_2d(j,i) ) THEN
1500	topo_3d(k,j,i) = IBCLR( topo_3d(k,j,i), 0 )
1501	topo_3d(k,j,i) = IBSET( topo_3d(k,j,i), 2 )
1502	!
1503	!-- De-flag grid point of type natural. See comment above.
1504	topo_3d(k,j,i) = IBCLR( topo_3d(k,j,i), 1 )
1505	ENDIF
1506	ENDIF
1507	ENDIF
1508	ENDDO
1509	!
1510	!-- Map 3D buildings onto terrain height.
1511	!-- In case of any slopes, map building on top of maximum terrain
1512	!-- height covered by the building. In other words, extend
1513	!-- building down to the respective local terrain-surface height.
1514	IF ( buildings_f%from_file .AND. buildings_f%lod == 2 ) THEN
1515	IF ( building_id_f%var(j,i) /= building_id_f%fill ) THEN
1516	!
1517	!-- Determine index for maximum-terrain-height array.
1518	nr = MINLOC( ABS( build_ids_final - &
1519	building_id_f%var(j,i) ), DIM = 1 )
1520	!
1521	!-- Extend building down to the terrain surface, i.e. fill-up
1522	!-- surface irregularities below a building. Note, oro_max
1523	!-- is already a discrete height according to the all-or-nothing
1524	!-- approach, i.e. grid box is either topography or atmosphere,
1525	!-- terrain top is defined at upper bound of the grid box.
1526	!-- Hence, check for zw in this case.
1527	DO k = topo_top_index + 1, nzt + 1
1528	IF ( zw(k) - ocean_offset <= oro_max(nr) ) THEN
1529	topo_3d(k,j,i) = IBCLR( topo_3d(k,j,i), 0 )
1530	topo_3d(k,j,i) = IBSET( topo_3d(k,j,i), 2 )
1531	ENDIF
1532	ENDDO
1533	!
1534	!-- After surface irregularities are smoothen, determine lower
1535	!-- start index where building starts.
1536	DO k = nzb, nzt
1537	IF ( zw(k) - ocean_offset <= oro_max(nr) ) &
1538	topo_top_index = k
1539	ENDDO
1540	!
1541	!-- Finally, map building on top.
1542	k2 = 0
1543	DO k = topo_top_index, nzt + 1
1544	IF ( k2 <= buildings_f%nz-1 ) THEN
1545	IF ( buildings_f%var_3d(k2,j,i) == 1 ) THEN
1546	topo_3d(k,j,i) = IBCLR( topo_3d(k,j,i), 0 )
1547	topo_3d(k,j,i) = IBCLR( topo_3d(k,j,i), 1 )
1548	topo_3d(k,j,i) = IBSET( topo_3d(k,j,i), 2 )
1549	ENDIF
1550	ENDIF
1551	k2 = k2 + 1
1552	ENDDO
1553	ENDIF
1554	ENDIF
1555	ENDDO
1556	ENDDO
1557	!
1558	!-- Deallocate temporary arrays required for processing and reading data
1559	IF ( ALLOCATED( oro_max ) ) DEALLOCATE( oro_max )
1560	IF ( ALLOCATED( oro_max_l ) ) DEALLOCATE( oro_max_l )
1561	IF ( ALLOCATED( build_ids_final ) ) DEALLOCATE( build_ids_final )
1562	!
1563	!-- Topography input via ASCII format.
1564	ELSE
1565	ocean_offset = MERGE( zw(0), 0.0_wp, ocean )
1566	topo_3d = IBSET( topo_3d, 0 )
1567	topo_3d(nzb,:,:) = IBCLR( topo_3d(nzb,:,:), 0 )
1568	DO i = nxl, nxr
1569	DO j = nys, nyn
1570	DO k = nzb, nzt
1571	IF ( zu(k) - ocean_offset <= buildings_f%var_2d(j,i) ) THEN
1572	topo_3d(k,j,i) = IBCLR( topo_3d(k,j,i), 0 )
1573	topo_3d(k,j,i) = IBSET( topo_3d(k,j,i), 2 ) !indicates terrain
1574	ENDIF
1575	ENDDO
1576	ENDDO
1577	ENDDO
1578	ENDIF
1579
1580	CALL exchange_horiz_int( topo_3d, nys, nyn, nxl, nxr, nzt, nbgp )
1581
1582	IF ( .NOT. bc_ns_cyc ) THEN
1583	IF ( nys == 0 ) topo_3d(:,-1,:) = topo_3d(:,0,:)
1584	IF ( nyn == ny ) topo_3d(:,ny+1,:) = topo_3d(:,ny,:)
1585	ENDIF
1586
1587	IF ( .NOT. bc_lr_cyc ) THEN
1588	IF ( nxl == 0 ) topo_3d(:,:,-1) = topo_3d(:,:,0)
1589	IF ( nxr == nx ) topo_3d(:,:,nx+1) = topo_3d(:,:,nx)
1590	ENDIF
1591
1592	END SUBROUTINE process_topography
1593
1594
1595	! Description:
1596	! -----------------------------------------------------------------------------!
1597	!> Filter topography, i.e. fill holes resolved by only one grid point.
1598	!> Such holes are suspected to lead to velocity blow-ups as continuity
1599	!> equation on discrete grid cannot be fulfilled in such case.
1600	!------------------------------------------------------------------------------!
1601	SUBROUTINE filter_topography( topo_3d )
1602
1603	USE control_parameters, &
1604	ONLY: bc_lr_cyc, bc_ns_cyc, message_string
1605
1606	USE indices, &
1607	ONLY: nbgp, nx, nxl, nxlg, nxr, nxrg, ny, nyn, nyng, nys, nysg, nzb, nzt
1608
1609	USE netcdf_data_input_mod, &
1610	ONLY: building_id_f, building_type_f
1611
1612	USE pegrid
1613
1614	IMPLICIT NONE
1615
1616	LOGICAL :: filled = .FALSE. !< flag indicating if holes were filled
1617
1618	INTEGER(iwp) :: i !< running index along x-direction
1619	INTEGER(iwp) :: j !< running index along y-direction
1620	INTEGER(iwp) :: k !< running index along z-direction
1621	INTEGER(iwp) :: num_hole !< number of holes (in topography) resolved by only one grid point
1622	INTEGER(iwp) :: num_hole_l !< number of holes (in topography) resolved by only one grid point on local PE
1623	INTEGER(iwp) :: num_wall !< number of surrounding vertical walls for a single grid point
1624
1625	INTEGER(iwp), DIMENSION(nysg:nyng,nxlg:nxrg) :: var_exchange_int !< dummy array for exchanging ghost-points
1626	INTEGER(iwp), DIMENSION(:,:,:), ALLOCATABLE :: topo_tmp !< temporary 3D-topography used to fill holes
1627	INTEGER(iwp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) :: topo_3d !< 3D-topography array merging buildings and orography
1628	!
1629	!-- Before checking for holes, set lateral boundary conditions for
1630	!-- topography. After hole-filling, boundary conditions must be set again.
1631	!-- Several iterations are performed, in order to fill holes which might
1632	!-- emerge by the filling-algorithm itself.
1633	ALLOCATE( topo_tmp(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
1634	topo_tmp = 0
1635
1636	num_hole = 99999
1637	DO WHILE ( num_hole > 0 )
1638
1639	num_hole = 0
1640	CALL exchange_horiz_int( topo_3d, nys, nyn, nxl, nxr, nzt, nbgp )
1641	!
1642	!-- Exchange also building ID and type. Note, building_type is an one-byte
1643	!-- variable.
1644	IF ( building_id_f%from_file ) &
1645	CALL exchange_horiz_2d_int( building_id_f%var, nys, nyn, nxl, nxr, nbgp )
1646	IF ( building_type_f%from_file ) THEN
1647	var_exchange_int = INT( building_type_f%var, KIND = 4 )
1648	CALL exchange_horiz_2d_int( var_exchange_int, nys, nyn, nxl, nxr, nbgp )
1649	building_type_f%var = INT( var_exchange_int, KIND = 1 )
1650	ENDIF
1651
1652	topo_tmp = topo_3d
1653	!
1654	!-- In case of non-cyclic lateral boundaries, assume lateral boundary to be
1655	!-- a solid wall. Thus, intermediate spaces of one grid point between
1656	!-- boundary and some topographic structure will be filled.
1657	IF ( .NOT. bc_ns_cyc ) THEN
1658	IF ( nys == 0 ) topo_tmp(:,-1,:) = IBCLR( topo_tmp(:,0,:), 0 )
1659	IF ( nyn == ny ) topo_tmp(:,ny+1,:) = IBCLR( topo_tmp(:,ny,:), 0 )
1660	ENDIF
1661
1662	IF ( .NOT. bc_lr_cyc ) THEN
1663	IF ( nxl == 0 ) topo_tmp(:,:,-1) = IBCLR( topo_tmp(:,:,0), 0 )
1664	IF ( nxr == nx ) topo_tmp(:,:,nx+1) = IBCLR( topo_tmp(:,:,nx), 0 )
1665	ENDIF
1666
1667	num_hole_l = 0
1668	DO i = nxl, nxr
1669	DO j = nys, nyn
1670	DO k = nzb+1, nzt
1671	IF ( BTEST( topo_tmp(k,j,i), 0 ) ) THEN
1672	num_wall = 0
1673	IF ( .NOT. BTEST( topo_tmp(k,j-1,i), 0 ) ) &
1674	num_wall = num_wall + 1
1675	IF ( .NOT. BTEST( topo_tmp(k,j+1,i), 0 ) ) &
1676	num_wall = num_wall + 1
1677	IF ( .NOT. BTEST( topo_tmp(k,j,i-1), 0 ) ) &
1678	num_wall = num_wall + 1
1679	IF ( .NOT. BTEST( topo_tmp(k,j,i+1), 0 ) ) &
1680	num_wall = num_wall + 1
1681	IF ( .NOT. BTEST( topo_tmp(k-1,j,i), 0 ) ) &
1682	num_wall = num_wall + 1
1683	IF ( .NOT. BTEST( topo_tmp(k+1,j,i), 0 ) ) &
1684	num_wall = num_wall + 1
1685
1686	IF ( num_wall >= 4 ) THEN
1687	num_hole_l = num_hole_l + 1
1688	!
1689	!-- Clear flag 0 and set special flag ( bit 3) to indicate
1690	!-- that new topography point is a result of filtering process.
1691	topo_3d(k,j,i) = IBCLR( topo_3d(k,j,i), 0 )
1692	topo_3d(k,j,i) = IBSET( topo_3d(k,j,i), 3 )
1693	!
1694	!-- If filled grid point is occupied by a building, classify
1695	!-- it as building grid point.
1696	IF ( building_type_f%from_file ) THEN
1697	IF ( building_type_f%var(j,i) /= &
1698	building_type_f%fill .OR. &
1699	building_type_f%var(j+1,i) /= &
1700	building_type_f%fill .OR. &
1701	building_type_f%var(j-1,i) /= &
1702	building_type_f%fill .OR. &
1703	building_type_f%var(j,i+1) /= &
1704	building_type_f%fill .OR. &
1705	building_type_f%var(j,i-1) /= &
1706	building_type_f%fill ) THEN
1707	!
1708	!-- Set flag indicating building surfaces
1709	topo_3d(k,j,i) = IBSET( topo_3d(k,j,i), 2 )
1710	!
1711	!-- Set building_type and ID at this position if not
1712	!-- already set. This is required for proper
1713	!-- initialization of urban-surface energy balance
1714	!-- solver.
1715	IF ( building_type_f%var(j,i) == &
1716	building_type_f%fill ) THEN
1717
1718	IF ( building_type_f%var(j+1,i) /= &
1719	building_type_f%fill ) THEN
1720	building_type_f%var(j,i) = &
1721	building_type_f%var(j+1,i)
1722	building_id_f%var(j,i) = &
1723	building_id_f%var(j+1,i)
1724	ELSEIF ( building_type_f%var(j-1,i) /= &
1725	building_type_f%fill ) THEN
1726	building_type_f%var(j,i) = &
1727	building_type_f%var(j-1,i)
1728	building_id_f%var(j,i) = &
1729	building_id_f%var(j-1,i)
1730	ELSEIF ( building_type_f%var(j,i+1) /= &
1731	building_type_f%fill ) THEN
1732	building_type_f%var(j,i) = &
1733	building_type_f%var(j,i+1)
1734	building_id_f%var(j,i) = &
1735	building_id_f%var(j,i+1)
1736	ELSEIF ( building_type_f%var(j,i-1) /= &
1737	building_type_f%fill ) THEN
1738	building_type_f%var(j,i) = &
1739	building_type_f%var(j,i-1)
1740	building_id_f%var(j,i) = &
1741	building_id_f%var(j,i-1)
1742	ENDIF
1743	ENDIF
1744	ENDIF
1745	ENDIF
1746	!
1747	!-- If filled grid point is already classified as building
1748	!-- everything is fine, else classify this grid point as
1749	!-- natural type grid point. This case, values for the
1750	!-- surface type are already set.
1751	IF ( .NOT. BTEST( topo_3d(k,j,i), 2 ) ) THEN
1752	topo_3d(k,j,i) = IBSET( topo_3d(k,j,i), 1 )
1753	ENDIF
1754	ENDIF
1755	ENDIF
1756	ENDDO
1757	ENDDO
1758	ENDDO
1759	!
1760	!-- Count the total number of holes, required for informative message.
1761	#if defined( __parallel )
1762	CALL MPI_ALLREDUCE( num_hole_l, num_hole, 1, MPI_INTEGER, MPI_SUM, &
1763	comm2d, ierr )
1764	#else
1765	num_hole = num_hole_l
1766	#endif
1767	IF ( num_hole > 0 .AND. .NOT. filled ) filled = .TRUE.
1768
1769	ENDDO
1770	!
1771	!-- Create an informative message if any holes were filled.
1772	IF ( filled ) THEN
1773	WRITE( message_string, * ) 'Topography was filtered, i.e. holes ' // &
1774	'resolved by only one grid point ' // &
1775	'were filled during initialization.'
1776	CALL message( 'init_grid', 'PA0430', 0, 0, 0, 6, 0 )
1777	ENDIF
1778
1779	DEALLOCATE( topo_tmp )
1780	!
1781	!-- Finally, exchange topo_3d array again and if necessary set Neumann boundary
1782	!-- condition in case of non-cyclic lateral boundaries.
1783	CALL exchange_horiz_int( topo_3d, nys, nyn, nxl, nxr, nzt, nbgp )
1784
1785	IF ( .NOT. bc_ns_cyc ) THEN
1786	IF ( nys == 0 ) topo_3d(:,-1,:) = topo_3d(:,0,:)
1787	IF ( nyn == ny ) topo_3d(:,ny+1,:) = topo_3d(:,ny,:)
1788	ENDIF
1789
1790	IF ( .NOT. bc_lr_cyc ) THEN
1791	IF ( nxl == 0 ) topo_3d(:,:,-1) = topo_3d(:,:,0)
1792	IF ( nxr == nx ) topo_3d(:,:,nx+1) = topo_3d(:,:,nx)
1793	ENDIF
1794	!
1795	!-- Exchange building ID and type. Note, building_type is an one-byte variable.
1796	IF ( building_id_f%from_file ) &
1797	CALL exchange_horiz_2d_int( building_id_f%var, nys, nyn, nxl, nxr, nbgp )
1798	IF ( building_type_f%from_file ) THEN
1799	var_exchange_int = INT( building_type_f%var, KIND = 4 )
1800	CALL exchange_horiz_2d_int( var_exchange_int, nys, nyn, nxl, nxr, nbgp )
1801	building_type_f%var = INT( var_exchange_int, KIND = 1 )
1802	ENDIF
1803
1804	END SUBROUTINE filter_topography
1805
1806
1807	! Description:
1808	! -----------------------------------------------------------------------------!
1809	!> Reads topography information from file or sets generic topography. Moreover,
1810	!> all topography-relevant topography arrays are initialized, and grid flags
1811	!> are set.
1812	!------------------------------------------------------------------------------!
1813	SUBROUTINE init_topo( topo )
1814
1815	USE arrays_3d, &
1816	ONLY: zw
1817
1818	USE control_parameters, &
1819	ONLY: bc_lr_cyc, bc_ns_cyc, building_height, building_length_x, &
1820	building_length_y, building_wall_left, building_wall_south, &
1821	canyon_height, canyon_wall_left, canyon_wall_south, &
1822	canyon_width_x, canyon_width_y, dp_level_ind_b, dz, &
1823	message_string, ocean, topography, topography_grid_convention, &
1824	tunnel_height, tunnel_length, tunnel_width_x, tunnel_width_y, &
1825	tunnel_wall_depth
1826
1827	USE grid_variables, &
1828	ONLY: dx, dy
1829
1830	USE indices, &
1831	ONLY: nbgp, nx, nxl, nxlg, nxr, nxrg, ny, nyn, nyng, nys, nysg, nz, &
1832	nzb, nzt
1833
1834	USE kinds
1835
1836	USE pegrid
1837
1838	USE surface_mod, &
1839	ONLY: get_topography_top_index, get_topography_top_index_ji
1840
1841	IMPLICIT NONE
1842
1843	INTEGER(iwp) :: bh !< temporary vertical index of building height
1844	INTEGER(iwp) :: blx !< grid point number of building size along x
1845	INTEGER(iwp) :: bly !< grid point number of building size along y
1846	INTEGER(iwp) :: bxl !< index for left building wall
1847	INTEGER(iwp) :: bxr !< index for right building wall
1848	INTEGER(iwp) :: byn !< index for north building wall
1849	INTEGER(iwp) :: bys !< index for south building wall
1850	INTEGER(iwp) :: ch !< temporary vertical index for canyon height
1851	INTEGER(iwp) :: cwx !< grid point number of canyon size along x
1852	INTEGER(iwp) :: cwy !< grid point number of canyon size along y
1853	INTEGER(iwp) :: cxl !< index for left canyon wall
1854	INTEGER(iwp) :: cxr !< index for right canyon wall
1855	INTEGER(iwp) :: cyn !< index for north canyon wall
1856	INTEGER(iwp) :: cys !< index for south canyon wall
1857	INTEGER(iwp) :: i !< index variable along x
1858	INTEGER(iwp) :: j !< index variable along y
1859	INTEGER(iwp) :: k !< index variable along z
1860	INTEGER(iwp) :: hv_in !< heavyside function to model inner tunnel surface
1861	INTEGER(iwp) :: hv_out !< heavyside function to model outer tunnel surface
1862	INTEGER(iwp) :: txe_out !< end position of outer tunnel wall in x
1863	INTEGER(iwp) :: txs_out !< start position of outer tunnel wall in x
1864	INTEGER(iwp) :: tye_out !< end position of outer tunnel wall in y
1865	INTEGER(iwp) :: tys_out !< start position of outer tunnel wall in y
1866	INTEGER(iwp) :: txe_in !< end position of inner tunnel wall in x
1867	INTEGER(iwp) :: txs_in !< start position of inner tunnel wall in x
1868	INTEGER(iwp) :: tye_in !< end position of inner tunnel wall in y
1869	INTEGER(iwp) :: tys_in !< start position of inner tunnel wall in y
1870	INTEGER(iwp) :: td !< tunnel wall depth
1871	INTEGER(iwp) :: th !< height of outer tunnel wall
1872
1873	INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE :: nzb_local !< index for topography top at cell-center
1874	INTEGER(iwp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) :: topo !< input array for 3D topography and dummy array for setting "outer"-flags
1875
1876
1877	!
1878	!-- Set outer and inner index arrays for non-flat topography.
1879	!-- Here consistency checks concerning domain size and periodicity are
1880	!-- necessary.
1881	!-- Within this SELECT CASE structure only nzb_local is initialized
1882	!-- individually depending on the chosen topography type, all other index
1883	!-- arrays are initialized further below.
1884	SELECT CASE ( TRIM( topography ) )
1885
1886	CASE ( 'flat' )
1887	!
1888	!-- Initialilize 3D topography array, used later for initializing flags
1889	topo(nzb+1:nzt+1,:,:) = IBSET( topo(nzb+1:nzt+1,:,:), 0 )
1890
1891	CASE ( 'single_building' )
1892	!
1893	!-- Single rectangular building, by default centered in the middle of the
1894	!-- total domain
1895	blx = NINT( building_length_x / dx )
1896	bly = NINT( building_length_y / dy )
1897	bh = MINLOC( ABS( zw - building_height ), 1 ) - 1
1898	IF ( ABS( zw(bh) - building_height ) == &
1899	ABS( zw(bh+1) - building_height ) ) bh = bh + 1
1900	IF ( building_wall_left == 9999999.9_wp ) THEN
1901	building_wall_left = ( nx + 1 - blx ) / 2 * dx
1902	ENDIF
1903	bxl = NINT( building_wall_left / dx )
1904	bxr = bxl + blx
1905
1906	IF ( building_wall_south == 9999999.9_wp ) THEN
1907	building_wall_south = ( ny + 1 - bly ) / 2 * dy
1908	ENDIF
1909	bys = NINT( building_wall_south / dy )
1910	byn = bys + bly
1911
1912	!
1913	!-- Building size has to meet some requirements
1914	IF ( ( bxl < 1 ) .OR. ( bxr > nx-1 ) .OR. ( bxr < bxl+3 ) .OR. &
1915	( bys < 1 ) .OR. ( byn > ny-1 ) .OR. ( byn < bys+3 ) ) THEN
1916	WRITE( message_string, * ) 'inconsistent building parameters:', &
1917	'&bxl=', bxl, 'bxr=', bxr, 'bys=', bys, &
1918	'byn=', byn, 'nx=', nx, 'ny=', ny
1919	CALL message( 'init_grid', 'PA0203', 1, 2, 0, 6, 0 )
1920	ENDIF
1921
1922	ALLOCATE( nzb_local(nysg:nyng,nxlg:nxrg) )
1923	nzb_local = 0
1924	!
1925	!-- Define the building.
1926	IF ( bxl <= nxr .AND. bxr >= nxl .AND. &
1927	bys <= nyn .AND. byn >= nys ) &
1928	nzb_local(MAX(nys,bys):MIN(nyn,byn),MAX(nxl,bxl):MIN(nxr,bxr)) = bh
1929	!
1930	!-- Set bit array on basis of nzb_local
1931	DO i = nxl, nxr
1932	DO j = nys, nyn
1933	topo(nzb_local(j,i)+1:nzt+1,j,i) = &
1934	IBSET( topo(nzb_local(j,i)+1:nzt+1,j,i), 0 )
1935	ENDDO
1936	ENDDO
1937
1938	DEALLOCATE( nzb_local )
1939
1940	CALL exchange_horiz_int( topo, nys, nyn, nxl, nxr, nzt, nbgp )
1941	!
1942	!-- Set boundary conditions also for flags. Can be interpreted as Neumann
1943	!-- boundary conditions for topography.
1944	IF ( .NOT. bc_ns_cyc ) THEN
1945	IF ( nys == 0 ) THEN
1946	DO i = 1, nbgp
1947	topo(:,nys-i,:) = topo(:,nys,:)
1948	ENDDO
1949	ENDIF
1950	IF ( nyn == ny ) THEN
1951	DO i = 1, nbgp
1952	topo(:,nyn+i,:) = topo(:,nyn,:)
1953	ENDDO
1954	ENDIF
1955	ENDIF
1956	IF ( .NOT. bc_lr_cyc ) THEN
1957	IF ( nxl == 0 ) THEN
1958	DO i = 1, nbgp
1959	topo(:,:,nxl-i) = topo(:,:,nxl)
1960	ENDDO
1961	ENDIF
1962	IF ( nxr == nx ) THEN
1963	DO i = 1, nbgp
1964	topo(:,:,nxr+i) = topo(:,:,nxr)
1965	ENDDO
1966	ENDIF
1967	ENDIF
1968
1969	CASE ( 'single_street_canyon' )
1970	!
1971	!-- Single quasi-2D street canyon of infinite length in x or y direction.
1972	!-- The canyon is centered in the other direction by default.
1973	IF ( canyon_width_x /= 9999999.9_wp ) THEN
1974	!
1975	!-- Street canyon in y direction
1976	cwx = NINT( canyon_width_x / dx )
1977	IF ( canyon_wall_left == 9999999.9_wp ) THEN
1978	canyon_wall_left = ( nx + 1 - cwx ) / 2 * dx
1979	ENDIF
1980	cxl = NINT( canyon_wall_left / dx )
1981	cxr = cxl + cwx
1982	ELSEIF ( canyon_width_y /= 9999999.9_wp ) THEN
1983	!
1984	!-- Street canyon in x direction
1985	cwy = NINT( canyon_width_y / dy )
1986	IF ( canyon_wall_south == 9999999.9_wp ) THEN
1987	canyon_wall_south = ( ny + 1 - cwy ) / 2 * dy
1988	ENDIF
1989	cys = NINT( canyon_wall_south / dy )
1990	cyn = cys + cwy
1991
1992	ELSE
1993
1994	message_string = 'no street canyon width given'
1995	CALL message( 'init_grid', 'PA0204', 1, 2, 0, 6, 0 )
1996
1997	ENDIF
1998
1999	ch = MINLOC( ABS( zw - canyon_height ), 1 ) - 1
2000	IF ( ABS( zw(ch) - canyon_height ) == &
2001	ABS( zw(ch+1) - canyon_height ) ) ch = ch + 1
2002	dp_level_ind_b = ch
2003	!
2004	!-- Street canyon size has to meet some requirements
2005	IF ( canyon_width_x /= 9999999.9_wp ) THEN
2006	IF ( ( cxl < 1 ) .OR. ( cxr > nx-1 ) .OR. ( cwx < 3 ) .OR. &
2007	( ch < 3 ) ) THEN
2008	WRITE( message_string, * ) 'inconsistent canyon parameters:', &
2009	'&cxl=', cxl, ' cxr=', cxr, &
2010	' cwx=', cwx, &
2011	' ch=', ch, ' nx=', nx, ' ny=', ny
2012	CALL message( 'init_grid', 'PA0205', 1, 2, 0, 6, 0 )
2013	ENDIF
2014	ELSEIF ( canyon_width_y /= 9999999.9_wp ) THEN
2015	IF ( ( cys < 1 ) .OR. ( cyn > ny-1 ) .OR. ( cwy < 3 ) .OR. &
2016	( ch < 3 ) ) THEN
2017	WRITE( message_string, * ) 'inconsistent canyon parameters:', &
2018	'&cys=', cys, ' cyn=', cyn, &
2019	' cwy=', cwy, &
2020	' ch=', ch, ' nx=', nx, ' ny=', ny
2021	CALL message( 'init_grid', 'PA0206', 1, 2, 0, 6, 0 )
2022	ENDIF
2023	ENDIF
2024	IF ( canyon_width_x /= 9999999.9_wp .AND. &
2025	canyon_width_y /= 9999999.9_wp ) THEN
2026	message_string = 'inconsistent canyon parameters:' // &
2027	'&street canyon can only be oriented' // &
2028	' either in x- or in y-direction'
2029	CALL message( 'init_grid', 'PA0207', 1, 2, 0, 6, 0 )
2030	ENDIF
2031
2032	ALLOCATE( nzb_local(nysg:nyng,nxlg:nxrg) )
2033	nzb_local = ch
2034	IF ( canyon_width_x /= 9999999.9_wp ) THEN
2035	IF ( cxl <= nxr .AND. cxr >= nxl ) &
2036	nzb_local(:,MAX(nxl,cxl+1):MIN(nxr,cxr-1)) = 0
2037	ELSEIF ( canyon_width_y /= 9999999.9_wp ) THEN
2038	IF ( cys <= nyn .AND. cyn >= nys ) &
2039	nzb_local(MAX(nys,cys+1):MIN(nyn,cyn-1),:) = 0
2040	ENDIF
2041	!
2042	!-- Set bit array on basis of nzb_local
2043	DO i = nxl, nxr
2044	DO j = nys, nyn
2045	topo(nzb_local(j,i)+1:nzt+1,j,i) = &
2046	IBSET( topo(nzb_local(j,i)+1:nzt+1,j,i), 0 )
2047	ENDDO
2048	ENDDO
2049	DEALLOCATE( nzb_local )
2050
2051	CALL exchange_horiz_int( topo, nys, nyn, nxl, nxr, nzt, nbgp )
2052	!
2053	!-- Set boundary conditions also for flags. Can be interpreted as Neumann
2054	!-- boundary conditions for topography.
2055	IF ( .NOT. bc_ns_cyc ) THEN
2056	IF ( nys == 0 ) THEN
2057	DO i = 1, nbgp
2058	topo(:,nys-i,:) = topo(:,nys,:)
2059	ENDDO
2060	ENDIF
2061	IF ( nyn == ny ) THEN
2062	DO i = 1, nbgp
2063	topo(:,nyn+i,:) = topo(:,nyn,:)
2064	ENDDO
2065	ENDIF
2066	ENDIF
2067	IF ( .NOT. bc_lr_cyc ) THEN
2068	IF ( nxl == 0 ) THEN
2069	DO i = 1, nbgp
2070	topo(:,:,nxl-i) = topo(:,:,nxl)
2071	ENDDO
2072	ENDIF
2073	IF ( nxr == nx ) THEN
2074	DO i = 1, nbgp
2075	topo(:,:,nxr+i) = topo(:,:,nxr)
2076	ENDDO
2077	ENDIF
2078	ENDIF
2079
2080	CASE ( 'tunnel' )
2081
2082	!
2083	!-- Tunnel height
2084	IF ( tunnel_height == 9999999.9_wp ) THEN
2085	th = zw( INT( 0.2 * nz) )
2086	ELSE
2087	th = tunnel_height
2088	ENDIF
2089	!
2090	!-- Tunnel-wall depth
2091	IF ( tunnel_wall_depth == 9999999.9_wp ) THEN
2092	td = MAX ( dx, dy, dz(1) )
2093	ELSE
2094	td = tunnel_wall_depth
2095	ENDIF
2096	!
2097	!-- Check for tunnel width
2098	IF ( tunnel_width_x == 9999999.9_wp .AND. &
2099	tunnel_width_y == 9999999.9_wp ) THEN
2100	message_string = 'No tunnel width is given. '
2101	CALL message( 'init_grid', 'PA0280', 1, 2, 0, 6, 0 )
2102	ENDIF
2103	IF ( tunnel_width_x /= 9999999.9_wp .AND. &
2104	tunnel_width_y /= 9999999.9_wp ) THEN
2105	message_string = 'Inconsistent tunnel parameters:' // &
2106	'tunnel can only be oriented' // &
2107	'either in x- or in y-direction.'
2108	CALL message( 'init_grid', 'PA0281', 1, 2, 0, 6, 0 )
2109	ENDIF
2110	!
2111	!-- Tunnel axis along y
2112	IF ( tunnel_width_x /= 9999999.9_wp ) THEN
2113	IF ( tunnel_width_x > ( nx + 1 ) * dx ) THEN
2114	message_string = 'Tunnel width too large'
2115	CALL message( 'init_grid', 'PA0282', 1, 2, 0, 6, 0 )
2116	ENDIF
2117
2118	txs_out = INT( ( nx + 1 ) * 0.5_wp * dx - tunnel_width_x * 0.5_wp )
2119	txe_out = INT( ( nx + 1 ) * 0.5_wp * dx + tunnel_width_x * 0.5_wp )
2120	txs_in = INT( ( nx + 1 ) * 0.5_wp * dx - &
2121	( tunnel_width_x * 0.5_wp - td ) )
2122	txe_in = INT( ( nx + 1 ) * 0.5_wp * dx + &
2123	( tunnel_width_x * 0.5_wp - td ) )
2124
2125	tys_out = INT( ( ny + 1 ) * 0.5_wp * dy - tunnel_length * 0.5_wp )
2126	tye_out = INT( ( ny + 1 ) * 0.5_wp * dy + tunnel_length * 0.5_wp )
2127	tys_in = tys_out
2128	tye_in = tye_out
2129	ENDIF
2130	IF ( tunnel_width_x /= 9999999.9_wp .AND. &
2131	tunnel_width_x - 2.0_wp * td <= 2.0_wp * dx ) &
2132	THEN
2133	message_string = 'Tunnel width too small'
2134	CALL message( 'init_grid', 'PA0175', 1, 2, 0, 6, 0 )
2135	ENDIF
2136	IF ( tunnel_width_y /= 9999999.9_wp .AND. &
2137	tunnel_width_y - 2.0_wp * td <= 2.0_wp * dy ) &
2138	THEN
2139	message_string = 'Tunnel width too small'
2140	CALL message( 'init_grid', 'PA0455', 1, 2, 0, 6, 0 )
2141	ENDIF
2142	!
2143	!-- Tunnel axis along x
2144	IF ( tunnel_width_y /= 9999999.9_wp ) THEN
2145	IF ( tunnel_width_y > ( ny + 1 ) * dy ) THEN
2146	message_string = 'Tunnel width too large'
2147	CALL message( 'init_grid', 'PA0456', 1, 2, 0, 6, 0 )
2148	ENDIF
2149
2150	txs_out = INT( ( nx + 1 ) * 0.5_wp * dx - tunnel_length * 0.5_wp )
2151	txe_out = INT( ( nx + 1 ) * 0.5_wp * dx + tunnel_length * 0.5_wp )
2152	txs_in = txs_out
2153	txe_in = txe_out
2154
2155	tys_out = INT( ( ny + 1 ) * 0.5_wp * dy - tunnel_width_y * 0.5_wp )
2156	tye_out = INT( ( ny + 1 ) * 0.5_wp * dy + tunnel_width_y * 0.5_wp )
2157	tys_in = INT( ( ny + 1 ) * 0.5_wp * dy - &
2158	( tunnel_width_y * 0.5_wp - td ) )
2159	tye_in = INT( ( ny + 1 ) * 0.5_wp * dy + &
2160	( tunnel_width_y * 0.5_wp - td ) )
2161	ENDIF
2162
2163	topo = 0
2164	DO i = nxl, nxr
2165	DO j = nys, nyn
2166	!
2167	!-- Use heaviside function to model outer tunnel surface
2168	hv_out = th * 0.5_wp * &
2169	( ( SIGN( 1.0_wp, i * dx - txs_out ) + 1.0_wp ) &
2170	- ( SIGN( 1.0_wp, i * dx - txe_out ) + 1.0_wp ) )
2171
2172	hv_out = hv_out * 0.5_wp * &
2173	( ( SIGN( 1.0_wp, j * dy - tys_out ) + 1.0_wp ) &
2174	- ( SIGN( 1.0_wp, j * dy - tye_out ) + 1.0_wp ) )
2175	!
2176	!-- Use heaviside function to model inner tunnel surface
2177	hv_in = ( th - td ) * 0.5_wp * &
2178	( ( SIGN( 1.0_wp, i * dx - txs_in ) + 1.0_wp ) &
2179	- ( SIGN( 1.0_wp, i * dx - txe_in ) + 1.0_wp ) )
2180
2181	hv_in = hv_in * 0.5_wp * &
2182	( ( SIGN( 1.0_wp, j * dy - tys_in ) + 1.0_wp ) &
2183	- ( SIGN( 1.0_wp, j * dy - tye_in ) + 1.0_wp ) )
2184	!
2185	!-- Set flags at x-y-positions without any tunnel surface
2186	IF ( hv_out - hv_in == 0.0_wp ) THEN
2187	topo(nzb+1:nzt+1,j,i) = IBSET( topo(nzb+1:nzt+1,j,i), 0 )
2188	!
2189	!-- Set flags at x-y-positions with tunnel surfaces
2190	ELSE
2191	DO k = nzb + 1, nzt + 1
2192	!
2193	!-- Inner tunnel
2194	IF ( hv_out - hv_in == th ) THEN
2195	IF ( zw(k) <= hv_out ) THEN
2196	topo(k,j,i) = IBCLR( topo(k,j,i), 0 )
2197	ELSE
2198	topo(k,j,i) = IBSET( topo(k,j,i), 0 )
2199	ENDIF
2200	ENDIF
2201	!
2202	!-- Lateral tunnel walls
2203	IF ( hv_out - hv_in == td ) THEN
2204	IF ( zw(k) <= hv_in ) THEN
2205	topo(k,j,i) = IBSET( topo(k,j,i), 0 )
2206	ELSEIF ( zw(k) > hv_in .AND. zw(k) <= hv_out ) THEN
2207	topo(k,j,i) = IBCLR( topo(k,j,i), 0 )
2208	ELSEIF ( zw(k) > hv_out ) THEN
2209	topo(k,j,i) = IBSET( topo(k,j,i), 0 )
2210	ENDIF
2211	ENDIF
2212	ENDDO
2213	ENDIF
2214	ENDDO
2215	ENDDO
2216
2217	CALL exchange_horiz_int( topo, nys, nyn, nxl, nxr, nzt, nbgp )
2218	!
2219	!-- Set boundary conditions also for flags. Can be interpreted as Neumann
2220	!-- boundary conditions for topography.
2221	IF ( .NOT. bc_ns_cyc ) THEN
2222	IF ( nys == 0 ) THEN
2223	DO i = 1, nbgp
2224	topo(:,nys-i,:) = topo(:,nys,:)
2225	ENDDO
2226	ENDIF
2227	IF ( nyn == ny ) THEN
2228	DO i = 1, nbgp
2229	topo(:,nyn+i,:) = topo(:,nyn,:)
2230	ENDDO
2231	ENDIF
2232	ENDIF
2233	IF ( .NOT. bc_lr_cyc ) THEN
2234	IF ( nxl == 0 ) THEN
2235	DO i = 1, nbgp
2236	topo(:,:,nxl-i) = topo(:,:,nxl)
2237	ENDDO
2238	ENDIF
2239	IF ( nxr == nx ) THEN
2240	DO i = 1, nbgp
2241	topo(:,:,nxr+i) = topo(:,:,nxr)
2242	ENDDO
2243	ENDIF
2244	ENDIF
2245
2246	CASE ( 'read_from_file' )
2247	!
2248	!-- Note, topography information have been already read.
2249	!-- If required, further process topography, i.e. reference buildings on
2250	!-- top of orography and set temporary 3D topography array, which is
2251	!-- used later to set grid flags. Calling of this rouinte is also
2252	!-- required in case of ASCII input, even though no distinction between
2253	!-- terrain- and building height is made in this case.
2254	CALL process_topography( topo )
2255	!
2256	!-- Filter holes resolved by only one grid-point
2257	CALL filter_topography( topo )
2258	!
2259	!-- Exchange ghost-points, as well as add cyclic or Neumann boundary
2260	!-- conditions.
2261	CALL exchange_horiz_int( topo, nys, nyn, nxl, nxr, nzt, nbgp )
2262	!
2263	!-- Set lateral boundary conditions for topography on all ghost layers
2264	IF ( .NOT. bc_ns_cyc ) THEN
2265	IF ( nys == 0 ) THEN
2266	DO i = 1, nbgp
2267	topo(:,nys-i,:) = topo(:,nys,:)
2268	ENDDO
2269	ENDIF
2270	IF ( nyn == ny ) THEN
2271	DO i = 1, nbgp
2272	topo(:,nyn+i,:) = topo(:,nyn,:)
2273	ENDDO
2274	ENDIF
2275	ENDIF
2276
2277	IF ( .NOT. bc_lr_cyc ) THEN
2278	IF ( nxl == 0 ) THEN
2279	DO i = 1, nbgp
2280	topo(:,:,nxl-i) = topo(:,:,nxl)
2281	ENDDO
2282	ENDIF
2283	IF ( nxr == nx ) THEN
2284	DO i = 1, nbgp
2285	topo(:,:,nxr+i) = topo(:,:,nxr)
2286	ENDDO
2287	ENDIF
2288	ENDIF
2289
2290
2291	CASE DEFAULT
2292	!
2293	!-- The DEFAULT case is reached either if the parameter topography
2294	!-- contains a wrong character string or if the user has defined a special
2295	!-- case in the user interface. There, the subroutine user_init_grid
2296	!-- checks which of these two conditions applies.
2297	CALL user_init_grid( topo )
2298	CALL filter_topography( topo )
2299
2300	END SELECT
2301	!
2302	!-- Consistency checks and index array initialization are only required for
2303	!-- non-flat topography.
2304	IF ( TRIM( topography ) /= 'flat' ) THEN
2305	!
2306	!-- In case of non-flat topography, check whether the convention how to
2307	!-- define the topography grid has been set correctly, or whether the default
2308	!-- is applicable. If this is not possible, abort.
2309	IF ( TRIM( topography_grid_convention ) == ' ' ) THEN
2310	IF ( TRIM( topography ) /= 'single_building' .AND. &
2311	TRIM( topography ) /= 'single_street_canyon' .AND. &
2312	TRIM( topography ) /= 'tunnel' .AND. &
2313	TRIM( topography ) /= 'read_from_file') THEN
2314	!-- The default value is not applicable here, because it is only valid
2315	!-- for the four standard cases 'single_building',
2316	!-- 'single_street_canyon', 'tunnel' and 'read_from_file'
2317	!-- defined in init_grid.
2318	WRITE( message_string, * ) &
2319	'The value for "topography_grid_convention" ', &
2320	'is not set. Its default value is & only valid for ', &
2321	'"topography" = ''single_building'', ''tunnel'' ', &
2322	'''single_street_canyon'' & or ''read_from_file''.', &
2323	'& Choose ''cell_edge'' or ''cell_center''.'
2324	CALL message( 'init_grid', 'PA0239', 1, 2, 0, 6, 0 )
2325	ELSE
2326	!-- The default value is applicable here.
2327	!-- Set convention according to topography.
2328	IF ( TRIM( topography ) == 'single_building' .OR. &
2329	TRIM( topography ) == 'single_street_canyon' ) THEN
2330	topography_grid_convention = 'cell_edge'
2331	ELSEIF ( TRIM( topography ) == 'read_from_file' .OR. &
2332	TRIM( topography ) == 'tunnel') THEN
2333	topography_grid_convention = 'cell_center'
2334	ENDIF
2335	ENDIF
2336	ELSEIF ( TRIM( topography_grid_convention ) /= 'cell_edge' .AND. &
2337	TRIM( topography_grid_convention ) /= 'cell_center' ) THEN
2338	WRITE( message_string, * ) &
2339	'The value for "topography_grid_convention" is ', &
2340	'not recognized.& Choose ''cell_edge'' or ''cell_center''.'
2341	CALL message( 'init_grid', 'PA0240', 1, 2, 0, 6, 0 )
2342	ENDIF
2343
2344
2345	IF ( topography_grid_convention == 'cell_edge' ) THEN
2346	!
2347	!-- The array nzb_local as defined using the 'cell_edge' convention
2348	!-- describes the actual total size of topography which is defined at the
2349	!-- cell edges where u=0 on the topography walls in x-direction and v=0
2350	!-- on the topography walls in y-direction. However, PALM uses individual
2351	!-- arrays nzb_u\|v\|w\|s_inner\|outer that are based on nzb_s_inner.
2352	!-- Therefore, the extent of topography in nzb_local is now reduced by
2353	!-- 1dx at the E topography walls and by 1dy at the N topography walls
2354	!-- to form the basis for nzb_s_inner.
2355	!-- Note, the reverse memory access (i-j instead of j-i) is absolutely
2356	!-- required at this point.
2357	DO j = nys+1, nyn+1
2358	DO i = nxl-1, nxr
2359	DO k = nzb, nzt+1
2360	IF ( BTEST( topo(k,j,i), 0 ) .OR. &
2361	BTEST( topo(k,j,i+1), 0 ) ) &
2362	topo(k,j,i) = IBSET( topo(k,j,i), 0 )
2363	ENDDO
2364	ENDDO
2365	ENDDO
2366	CALL exchange_horiz_int( topo, nys, nyn, nxl, nxr, nzt, nbgp )
2367
2368	DO i = nxl, nxr+1
2369	DO j = nys-1, nyn
2370	DO k = nzb, nzt+1
2371	IF ( BTEST( topo(k,j,i), 0 ) .OR. &
2372	BTEST( topo(k,j+1,i), 0 ) ) &
2373	topo(k,j,i) = IBSET( topo(k,j,i), 0 )
2374	ENDDO
2375	ENDDO
2376	ENDDO
2377	CALL exchange_horiz_int( topo, nys, nyn, nxl, nxr, nzt, nbgp )
2378
2379	ENDIF
2380	ENDIF
2381
2382
2383	END SUBROUTINE init_topo
2384
2385	SUBROUTINE set_topo_flags(topo)
2386
2387	USE control_parameters, &
2388	ONLY: bc_lr_cyc, bc_ns_cyc, constant_flux_layer, land_surface, &
2389	use_surface_fluxes, use_top_fluxes, urban_surface
2390
2391	USE indices, &
2392	ONLY: nbgp, nx, nxl, nxlg, nxr, nxrg, ny, nyn, nyng, nys, nysg, nz, &
2393	nzb, nzt, wall_flags_0
2394
2395	USE kinds
2396
2397	IMPLICIT NONE
2398
2399	INTEGER(iwp) :: i !< index variable along x
2400	INTEGER(iwp) :: j !< index variable along y
2401	INTEGER(iwp) :: k !< index variable along z
2402
2403	INTEGER(iwp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) :: topo !< input array for 3D topography and dummy array for setting "outer"-flags
2404
2405	ALLOCATE( wall_flags_0(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
2406	wall_flags_0 = 0
2407	!
2408	!-- Set-up topography flags. First, set flags only for s, u, v and w-grid.
2409	!-- Further special flags will be set in following loops.
2410	DO i = nxl, nxr
2411	DO j = nys, nyn
2412	DO k = nzb, nzt+1
2413	!
2414	!-- scalar grid
2415	IF ( BTEST( topo(k,j,i), 0 ) ) &
2416	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 0 )
2417	!
2418	!-- u grid
2419	IF ( BTEST( topo(k,j,i), 0 ) .AND. &
2420	BTEST( topo(k,j,i-1), 0 ) ) &
2421	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 1 )
2422	!
2423	!-- v grid
2424	IF ( BTEST( topo(k,j,i), 0 ) .AND. &
2425	BTEST( topo(k,j-1,i), 0 ) ) &
2426	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 2 )
2427
2428	ENDDO
2429
2430	DO k = nzb, nzt
2431	!
2432	!-- w grid
2433	IF ( BTEST( topo(k,j,i), 0 ) .AND. &
2434	BTEST( topo(k+1,j,i), 0 ) ) &
2435	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 3 )
2436	ENDDO
2437	wall_flags_0(nzt+1,j,i) = IBSET( wall_flags_0(nzt+1,j,i), 3 )
2438
2439	ENDDO
2440	ENDDO
2441
2442	CALL exchange_horiz_int( wall_flags_0, nys, nyn, nxl, nxr, nzt, nbgp )
2443	!
2444	!-- Set outer array for scalars to mask near-surface grid points in
2445	!-- production_e
2446	DO i = nxl, nxr
2447	DO j = nys, nyn
2448	DO k = nzb, nzt+1
2449	IF ( BTEST( wall_flags_0(k,j-1,i), 0 ) .AND. &
2450	BTEST( wall_flags_0(k,j+1,i), 0 ) .AND. &
2451	BTEST( wall_flags_0(k,j,i-1), 0 ) .AND. &
2452	BTEST( wall_flags_0(k,j-1,i-1), 0 ) .AND. &
2453	BTEST( wall_flags_0(k,j+1,i-1), 0 ) .AND. &
2454	BTEST( wall_flags_0(k,j-1,i+1), 0 ) .AND. &
2455	BTEST( wall_flags_0(k,j+1,i+1), 0 ) ) &
2456	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 24 )
2457	ENDDO
2458	ENDDO
2459	ENDDO
2460	!
2461	!-- Set further special flags
2462	DO i = nxl, nxr
2463	DO j = nys, nyn
2464	DO k = nzb, nzt+1
2465	!
2466	!-- scalar grid, former nzb_diff_s_inner.
2467	!-- Note, use this flag also to mask topography in diffusion_u and
2468	!-- diffusion_v along the vertical direction. In case of
2469	!-- use_surface_fluxes, fluxes are calculated via MOST, else, simple
2470	!-- gradient approach is applied. Please note, in case of u- and v-
2471	!-- diffuison, a small error is made at edges (on the east side for u,
2472	!-- at the north side for v), since topography on scalar grid point
2473	!-- is used instead of topography on u/v-grid. As number of topography grid
2474	!-- points on uv-grid is different than s-grid, different number of
2475	!-- surface elements would be required. In order to avoid this,
2476	!-- treat edges (u(k,j,i+1)) simply by a gradient approach, i.e. these
2477	!-- points are not masked within diffusion_u. Tests had shown that the
2478	!-- effect on the flow is negligible.
2479	IF ( constant_flux_layer .OR. use_surface_fluxes ) THEN
2480	IF ( BTEST( wall_flags_0(k,j,i), 0 ) ) &
2481	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 8 )
2482	ELSE
2483	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 8 )
2484	ENDIF
2485
2486	ENDDO
2487	!
2488	!-- Special flag to control vertical diffusion at model top - former
2489	!-- nzt_diff
2490	wall_flags_0(:,j,i) = IBSET( wall_flags_0(:,j,i), 9 )
2491	IF ( use_top_fluxes ) &
2492	wall_flags_0(nzt+1,j,i) = IBCLR( wall_flags_0(nzt+1,j,i), 9 )
2493
2494
2495	DO k = nzb+1, nzt
2496	!
2497	!-- Special flag on u grid, former nzb_u_inner + 1, required
2498	!-- for disturb_field and initialization. Do not disturb directly at
2499	!-- topography, as well as initialize u with zero one grid point outside
2500	!-- of topography.
2501	IF ( BTEST( wall_flags_0(k-1,j,i), 1 ) .AND. &
2502	BTEST( wall_flags_0(k,j,i), 1 ) .AND. &
2503	BTEST( wall_flags_0(k+1,j,i), 1 ) ) &
2504	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 20 )
2505	!
2506	!-- Special flag on v grid, former nzb_v_inner + 1, required
2507	!-- for disturb_field and initialization. Do not disturb directly at
2508	!-- topography, as well as initialize v with zero one grid point outside
2509	!-- of topography.
2510	IF ( BTEST( wall_flags_0(k-1,j,i), 2 ) .AND. &
2511	BTEST( wall_flags_0(k,j,i), 2 ) .AND. &
2512	BTEST( wall_flags_0(k+1,j,i), 2 ) ) &
2513	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 21 )
2514	!
2515	!-- Special flag on scalar grid, former nzb_s_inner+1. Used for
2516	!-- lpm_sgs_tke
2517	IF ( BTEST( wall_flags_0(k,j,i), 0 ) .AND. &
2518	BTEST( wall_flags_0(k-1,j,i), 0 ) .AND. &
2519	BTEST( wall_flags_0(k+1,j,i), 0 ) ) &
2520	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 25 )
2521	!
2522	!-- Special flag on scalar grid, nzb_diff_s_outer - 1, required in
2523	!-- in production_e
2524	IF ( constant_flux_layer .OR. use_surface_fluxes ) THEN
2525	IF ( BTEST( wall_flags_0(k,j,i), 24 ) .AND. &
2526	BTEST( wall_flags_0(k-1,j,i), 24 ) .AND. &
2527	BTEST( wall_flags_0(k+1,j,i), 0 ) ) &
2528	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 29 )
2529	ELSE
2530	IF ( BTEST( wall_flags_0(k,j,i), 0 ) ) &
2531	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 29 )
2532	ENDIF
2533	!
2534	!-- Special flag on scalar grid, nzb_diff_s_outer - 1, required in
2535	!-- in production_e
2536	IF ( constant_flux_layer .OR. use_surface_fluxes ) THEN
2537	IF ( BTEST( wall_flags_0(k,j,i), 0 ) .AND. &
2538	BTEST( wall_flags_0(k-1,j,i), 0 ) .AND. &
2539	BTEST( wall_flags_0(k+1,j,i), 0 ) ) &
2540	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 30 )
2541	ELSE
2542	IF ( BTEST( wall_flags_0(k,j,i), 0 ) ) &
2543	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 30 )
2544	ENDIF
2545	ENDDO
2546	!
2547	!-- Flags indicating downward facing walls
2548	DO k = nzb+1, nzt
2549	!
2550	!-- Scalar grid
2551	IF ( BTEST( wall_flags_0(k-1,j,i), 0 ) .AND. &
2552	.NOT. BTEST( wall_flags_0(k,j,i), 0 ) ) &
2553	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 13 )
2554	!
2555	!-- Downward facing wall on u grid
2556	IF ( BTEST( wall_flags_0(k-1,j,i), 1 ) .AND. &
2557	.NOT. BTEST( wall_flags_0(k,j,i), 1 ) ) &
2558	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 15 )
2559	!
2560	!-- Downward facing wall on v grid
2561	IF ( BTEST( wall_flags_0(k-1,j,i), 2 ) .AND. &
2562	.NOT. BTEST( wall_flags_0(k,j,i), 2 ) ) &
2563	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 17 )
2564	!
2565	!-- Downward facing wall on w grid
2566	IF ( BTEST( wall_flags_0(k-1,j,i), 3 ) .AND. &
2567	.NOT. BTEST( wall_flags_0(k,j,i), 3 ) ) &
2568	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 19 )
2569	ENDDO
2570	!
2571	!-- Flags indicating upward facing walls
2572	DO k = nzb, nzt
2573	!
2574	!-- Upward facing wall on scalar grid
2575	IF ( .NOT. BTEST( wall_flags_0(k,j,i), 0 ) .AND. &
2576	BTEST( wall_flags_0(k+1,j,i), 0 ) ) &
2577	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 12 )
2578	!
2579	!-- Upward facing wall on u grid
2580	IF ( .NOT. BTEST( wall_flags_0(k,j,i), 1 ) .AND. &
2581	BTEST( wall_flags_0(k+1,j,i), 1 ) ) &
2582	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 14 )
2583
2584	!
2585	!-- Upward facing wall on v grid
2586	IF ( .NOT. BTEST( wall_flags_0(k,j,i), 2 ) .AND. &
2587	BTEST( wall_flags_0(k+1,j,i), 2 ) ) &
2588	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 16 )
2589
2590	!
2591	!-- Upward facing wall on w grid
2592	IF ( .NOT. BTEST( wall_flags_0(k,j,i), 3 ) .AND. &
2593	BTEST( wall_flags_0(k+1,j,i), 3 ) ) &
2594	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 18 )
2595	!
2596	!-- Special flag on scalar grid, former nzb_s_inner
2597	IF ( BTEST( wall_flags_0(k,j,i), 0 ) .OR. &
2598	BTEST( wall_flags_0(k,j,i), 12 ) .OR. &
2599	BTEST( wall_flags_0(k,j,i), 13 ) ) &
2600	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 22 )
2601	!
2602	!-- Special flag on scalar grid, nzb_diff_s_inner - 1, required for
2603	!-- flow_statistics
2604	IF ( constant_flux_layer .OR. use_surface_fluxes ) THEN
2605	IF ( BTEST( wall_flags_0(k,j,i), 0 ) .AND. &
2606	BTEST( wall_flags_0(k+1,j,i), 0 ) ) &
2607	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 23 )
2608	ELSE
2609	IF ( BTEST( wall_flags_0(k,j,i), 22 ) ) &
2610	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 23 )
2611	ENDIF
2612
2613
2614	ENDDO
2615	wall_flags_0(nzt+1,j,i) = IBSET( wall_flags_0(nzt+1,j,i), 22 )
2616	wall_flags_0(nzt+1,j,i) = IBSET( wall_flags_0(nzt+1,j,i), 23 )
2617	ENDDO
2618	ENDDO
2619	!
2620	!-- Finally, set identification flags indicating natural terrain or buildings.
2621	!-- Natural terrain grid points.
2622	IF ( land_surface ) THEN
2623	DO i = nxl, nxr
2624	DO j = nys, nyn
2625	DO k = nzb, nzt+1
2626	!
2627	!-- Natural terrain grid point
2628	IF ( BTEST( topo(k,j,i), 1 ) ) &
2629	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 5 )
2630	ENDDO
2631	ENDDO
2632	ENDDO
2633	ENDIF
2634	!
2635	!-- Building grid points.
2636	IF ( urban_surface ) THEN
2637	DO i = nxl, nxr
2638	DO j = nys, nyn
2639	DO k = nzb, nzt+1
2640	IF ( BTEST( topo(k,j,i), 2 ) ) &
2641	wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 6 )
2642	ENDDO
2643	ENDDO
2644	ENDDO
2645	ENDIF
2646	!
2647	!-- Exchange ghost points for wall flags
2648	CALL exchange_horiz_int( wall_flags_0, nys, nyn, nxl, nxr, nzt, nbgp )
2649	!
2650	!-- Set boundary conditions also for flags. Can be interpreted as Neumann
2651	!-- boundary conditions for topography.
2652	IF ( .NOT. bc_ns_cyc ) THEN
2653	IF ( nys == 0 ) THEN
2654	DO i = 1, nbgp
2655	wall_flags_0(:,nys-i,:) = wall_flags_0(:,nys,:)
2656	ENDDO
2657	ENDIF
2658	IF ( nyn == ny ) THEN
2659	DO i = 1, nbgp
2660	wall_flags_0(:,nyn+i,:) = wall_flags_0(:,nyn,:)
2661	ENDDO
2662	ENDIF
2663	ENDIF
2664	IF ( .NOT. bc_lr_cyc ) THEN
2665	IF ( nxl == 0 ) THEN
2666	DO i = 1, nbgp
2667	wall_flags_0(:,:,nxl-i) = wall_flags_0(:,:,nxl)
2668	ENDDO
2669	ENDIF
2670	IF ( nxr == nx ) THEN
2671	DO i = 1, nbgp
2672	wall_flags_0(:,:,nxr+i) = wall_flags_0(:,:,nxr)
2673	ENDDO
2674	ENDIF
2675	ENDIF
2676
2677
2678	END SUBROUTINE set_topo_flags
2679
2680
2681

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

| Impressum | ©Leibniz Universität Hannover |