source: palm/trunk/SOURCE/init_grid.f90 @ 1682

Last change on this file since 1682 was 1682, checked in by knoop, 6 years ago

Code annotations made doxygen readable

  • Property svn:keywords set to Id
File size: 65.0 KB
Line 
1!> @file init_grid.f90
2!--------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the terms
6! of the GNU General Public License as published by the Free Software Foundation,
7! either version 3 of the License, or (at your option) any later version.
8!
9! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
10! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
11! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
12!
13! You should have received a copy of the GNU General Public License along with
14! PALM. If not, see <http://www.gnu.org/licenses/>.
15!
16! Copyright 1997-2014 Leibniz Universitaet Hannover
17!--------------------------------------------------------------------------------!
18!
19! Current revisions:
20! -----------------
21! Code annotations made doxygen readable
22!
23! Former revisions:
24! -----------------
25! $Id: init_grid.f90 1682 2015-10-07 23:56:08Z knoop $
26!
27! 1677 2015-10-02 13:25:23Z boeske
28! Bugfix: Ghost points are included in wall_flags_0 and wall_flags_00
29!
30! 1675 2015-10-02 08:28:59Z gronemeier
31! Bugfix: Definition of topography grid levels
32!
33! 1660 2015-09-21 08:15:16Z gronemeier
34! Bugfix: Definition of topography grid levels if vertical grid stretching
35!         starts below the maximum topography height.
36!
37! 1580 2015-04-10 13:43:49Z suehring
38! Bugfix: setting flags for 5th order scheme near buildings
39!
40! 1575 2015-03-27 09:56:27Z raasch
41! adjustments for psolver-queries
42!
43! 1557 2015-03-05 16:43:04Z suehring
44! Adjustment for monotoinic limiter
45!
46! 1418 2014-06-06 13:05:08Z fricke
47! Bugfix: Change if-condition for stretched grid in the ocean, with the old
48!          condition and a negative value for dz_stretch_level the condition
49!          was always true for the whole model domain
50!
51! 1409 2014-05-23 12:11:32Z suehring
52! Bugfix: set wall_flags_0 at inflow and outflow boundary also for i <= nxlu
53! j <= nysv
54!
55! 1353 2014-04-08 15:21:23Z heinze
56! REAL constants provided with KIND-attribute
57!
58! 1322 2014-03-20 16:38:49Z raasch
59! REAL constants defined as wp-kind
60!
61! 1320 2014-03-20 08:40:49Z raasch
62! ONLY-attribute added to USE-statements,
63! kind-parameters added to all INTEGER and REAL declaration statements,
64! kinds are defined in new module kinds,
65! revision history before 2012 removed,
66! comment fields (!:) to be used for variable explanations added to
67! all variable declaration statements
68!
69! 1221 2013-09-10 08:59:13Z raasch
70! wall_flags_00 introduced to hold bits 32-63,
71! additional 3D-flag arrays for replacing the 2D-index array nzb_s_inner in
72! loops optimized for openACC (pres + flow_statistics)
73!
74! 1092 2013-02-02 11:24:22Z raasch
75! unused variables removed
76!
77! 1069 2012-11-28 16:18:43Z maronga
78! bugfix: added coupling_char to TOPOGRAPHY_DATA to allow topography in the ocean
79!          model in case of coupled runs
80!
81! 1036 2012-10-22 13:43:42Z raasch
82! code put under GPL (PALM 3.9)
83!
84! 1015 2012-09-27 09:23:24Z raasch
85! lower index for calculating wall_flags_0 set to nzb_w_inner instead of
86! nzb_w_inner+1
87!
88! 996 2012-09-07 10:41:47Z raasch
89! little reformatting
90!
91! 978 2012-08-09 08:28:32Z fricke
92! Bugfix: nzb_max is set to nzt at non-cyclic lateral boundaries
93! Bugfix: Set wall_flags_0 for inflow boundary
94!
95! 927 2012-06-06 19:15:04Z raasch
96! Wall flags are not set for multigrid method in case of masking method
97!
98! 864 2012-03-27 15:10:33Z gryschka
99! In case of ocean and Dirichlet bottom bc for u and v dzu_mg and ddzu_pres
100! were not correctly defined for k=1.
101!
102! 861 2012-03-26 14:18:34Z suehring
103! Set wall_flags_0. The array is needed for degradation in ws-scheme near walls,
104! inflow and outflow boundaries as well as near the bottom and the top of the
105! model domain.!
106! Initialization of nzb_s_inner and nzb_w_inner.
107! gls has to be at least nbgp to do not exceed the array bounds of nzb_local
108! while setting wall_flags_0
109!
110! 843 2012-02-29 15:16:21Z gryschka
111! In case of ocean and dirichlet bc for u and v at the bottom
112! the first u-level ist defined at same height as the first w-level
113!
114! 818 2012-02-08 16:11:23Z maronga
115! Bugfix: topo_height is only required if topography is used. It is thus now
116! allocated in the topography branch
117!
118! 809 2012-01-30 13:32:58Z maronga
119! Bugfix: replaced .AND. and .NOT. with && and ! in the preprocessor directives
120!
121! 807 2012-01-25 11:53:51Z maronga
122! New cpp directive "__check" implemented which is used by check_namelist_files
123!
124! Revision 1.1  1997/08/11 06:17:45  raasch
125! Initial revision (Testversion)
126!
127!
128! Description:
129! ------------
130!> Creating grid depending constants
131!------------------------------------------------------------------------------!
132 SUBROUTINE init_grid
133 
134
135    USE arrays_3d,                                                             &
136        ONLY:  dd2zu, ddzu, ddzu_pres, ddzw, dzu, dzu_mg, dzw, dzw_mg, f1_mg,  &
137               f2_mg, f3_mg, l_grid, l_wall, zu, zw
138       
139    USE control_parameters,                                                    &
140        ONLY:  bc_lr, bc_ns, building_height, building_length_x,               &
141               building_length_y, building_wall_left, building_wall_south,     &
142               canyon_height, canyon_wall_left, canyon_wall_south,             &
143               canyon_width_x, canyon_width_y, coupling_char, dp_level_ind_b,  &
144               dz, dz_max, dz_stretch_factor, dz_stretch_level,                &
145               dz_stretch_level_index, ibc_uv_b, io_blocks, io_group,          &
146               inflow_l, inflow_n, inflow_r, inflow_s, masking_method,         &
147               maximum_grid_level, message_string, momentum_advec, ocean,      &
148               outflow_l, outflow_n, outflow_r, outflow_s, prandtl_layer,      &
149               psolver, scalar_advec, topography, topography_grid_convention,  &
150               use_surface_fluxes, use_top_fluxes, wall_adjustment_factor
151       
152    USE grid_variables,                                                        &
153        ONLY:  ddx, ddx2, ddx2_mg, ddy, ddy2, ddy2_mg, dx, dx2, dy, dy2, fwxm, &
154               fwxp, fwym, fwyp, fxm, fxp, fym, fyp, wall_e_x, wall_e_y,       &
155               wall_u, wall_v, wall_w_x, wall_w_y, zu_s_inner, zw_w_inner
156       
157    USE indices,                                                               &
158        ONLY:  flags, nbgp, nx, nxl, nxlg, nxlu, nxl_mg, nxr, nxrg, nxr_mg,    &
159               ny, nyn, nyng, nyn_mg, nys, nysv, nys_mg, nysg, nz, nzb,        &
160               nzb_2d, nzb_diff, nzb_diff_s_inner, nzb_diff_s_outer,           &
161               nzb_diff_u, nzb_diff_v, nzb_max, nzb_s_inner, nzb_s_outer,      &
162               nzb_u_inner, nzb_u_outer, nzb_v_inner, nzb_v_outer,             &
163               nzb_w_inner, nzb_w_outer, nzt, nzt_diff, nzt_mg, rflags_invers, &
164               rflags_s_inner, wall_flags_0, wall_flags_00, wall_flags_1,      &
165               wall_flags_10, wall_flags_2, wall_flags_3,  wall_flags_4,       &
166               wall_flags_5, wall_flags_6, wall_flags_7, wall_flags_8,         &
167               wall_flags_9
168   
169    USE kinds
170   
171    USE pegrid
172
173    IMPLICIT NONE
174
175    INTEGER(iwp) ::  bh      !<
176    INTEGER(iwp) ::  blx     !<
177    INTEGER(iwp) ::  bly     !<
178    INTEGER(iwp) ::  bxl     !<
179    INTEGER(iwp) ::  bxr     !<
180    INTEGER(iwp) ::  byn     !<
181    INTEGER(iwp) ::  bys     !<
182    INTEGER(iwp) ::  ch      !<
183    INTEGER(iwp) ::  cwx     !<
184    INTEGER(iwp) ::  cwy     !<
185    INTEGER(iwp) ::  cxl     !<
186    INTEGER(iwp) ::  cxr     !<
187    INTEGER(iwp) ::  cyn     !<
188    INTEGER(iwp) ::  cys     !<
189    INTEGER(iwp) ::  gls     !<
190    INTEGER(iwp) ::  i       !<
191    INTEGER(iwp) ::  ii      !<
192    INTEGER(iwp) ::  inc     !<
193    INTEGER(iwp) ::  j       !<
194    INTEGER(iwp) ::  k       !<
195    INTEGER(iwp) ::  l       !<
196    INTEGER(iwp) ::  nxl_l   !<
197    INTEGER(iwp) ::  nxr_l   !<
198    INTEGER(iwp) ::  nyn_l   !<
199    INTEGER(iwp) ::  nys_l   !<
200    INTEGER(iwp) ::  nzb_si  !<
201    INTEGER(iwp) ::  nzt_l   !<
202    INTEGER(iwp) ::  vi      !<
203
204    INTEGER(iwp), DIMENSION(:), ALLOCATABLE   ::  vertical_influence  !<
205
206    INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE ::  corner_nl  !<
207    INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE ::  corner_nr  !<
208    INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE ::  corner_sl  !<
209    INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE ::  corner_sr  !<
210    INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE ::  wall_l     !<
211    INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE ::  wall_n     !<
212    INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE ::  wall_r     !<
213    INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE ::  wall_s     !<
214    INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE ::  nzb_local  !<
215    INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE ::  nzb_tmp    !<
216
217    LOGICAL :: flag_set = .FALSE.  !<
218
219    REAL(wp) ::  dx_l          !<
220    REAL(wp) ::  dy_l          !<
221    REAL(wp) ::  dz_stretched  !<
222
223    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  topo_height  !<
224
225   
226!
227!-- Calculation of horizontal array bounds including ghost layers
228    nxlg = nxl - nbgp
229    nxrg = nxr + nbgp
230    nysg = nys - nbgp
231    nyng = nyn + nbgp
232
233!
234!-- Allocate grid arrays
235    ALLOCATE( ddzu(1:nzt+1), ddzw(1:nzt+1), dd2zu(1:nzt), dzu(1:nzt+1),        &
236              dzw(1:nzt+1), l_grid(1:nzt), zu(nzb:nzt+1), zw(nzb:nzt+1) )
237
238!
239!-- Compute height of u-levels from constant grid length and dz stretch factors
240    IF ( dz == -1.0_wp )  THEN
241       message_string = 'missing dz'
242       CALL message( 'init_grid', 'PA0200', 1, 2, 0, 6, 0 ) 
243    ELSEIF ( dz <= 0.0_wp )  THEN
244       WRITE( message_string, * ) 'dz=',dz,' <= 0.0'
245       CALL message( 'init_grid', 'PA0201', 1, 2, 0, 6, 0 )
246    ENDIF
247
248!
249!-- Define the vertical grid levels
250    IF ( .NOT. ocean )  THEN
251!
252!--    Grid for atmosphere with surface at z=0 (k=0, w-grid).
253!--    The second u-level (k=1) corresponds to the top of the
254!--    Prandtl-layer.
255
256       IF ( ibc_uv_b == 0 .OR. ibc_uv_b == 2 ) THEN
257          zu(0) = 0.0_wp
258      !    zu(0) = - dz * 0.5_wp
259       ELSE
260          zu(0) = - dz * 0.5_wp
261       ENDIF
262       zu(1) =   dz * 0.5_wp
263
264       dz_stretch_level_index = nzt+1
265       dz_stretched = dz
266       DO  k = 2, nzt+1
267          IF ( dz_stretch_level <= zu(k-1)  .AND.  dz_stretched < dz_max )  THEN
268             dz_stretched = dz_stretched * dz_stretch_factor
269             dz_stretched = MIN( dz_stretched, dz_max )
270             IF ( dz_stretch_level_index == nzt+1 ) dz_stretch_level_index = k-1
271          ENDIF
272          zu(k) = zu(k-1) + dz_stretched
273       ENDDO
274
275!
276!--    Compute the w-levels. They are always staggered half-way between the
277!--    corresponding u-levels. In case of dirichlet bc for u and v at the
278!--    ground the first u- and w-level (k=0) are defined at same height (z=0).
279!--    The top w-level is extrapolated linearly.
280       zw(0) = 0.0_wp
281       DO  k = 1, nzt
282          zw(k) = ( zu(k) + zu(k+1) ) * 0.5_wp
283       ENDDO
284       zw(nzt+1) = zw(nzt) + 2.0_wp * ( zu(nzt+1) - zw(nzt) )
285
286    ELSE
287!
288!--    Grid for ocean with free water surface is at k=nzt (w-grid).
289!--    In case of neumann bc at the ground the first first u-level (k=0) lies
290!--    below the first w-level (k=0). In case of dirichlet bc the first u- and
291!--    w-level are defined at same height, but staggered from the second level.
292!--    The second u-level (k=1) corresponds to the top of the Prandtl-layer.
293       zu(nzt+1) =   dz * 0.5_wp
294       zu(nzt)   = - dz * 0.5_wp
295
296       dz_stretch_level_index = 0
297       dz_stretched = dz
298       DO  k = nzt-1, 0, -1
299!
300!--       The default value of dz_stretch_level is positive, thus the first
301!--       condition is always true. Hence, the second condition is necessary.
302          IF ( dz_stretch_level >= zu(k+1)  .AND.  dz_stretch_level <= 0.0  &
303               .AND.  dz_stretched < dz_max )  THEN
304             dz_stretched = dz_stretched * dz_stretch_factor
305             dz_stretched = MIN( dz_stretched, dz_max )
306             IF ( dz_stretch_level_index == 0 ) dz_stretch_level_index = k+1
307          ENDIF
308          zu(k) = zu(k+1) - dz_stretched
309       ENDDO
310
311!
312!--    Compute the w-levels. They are always staggered half-way between the
313!--    corresponding u-levels, except in case of dirichlet bc for u and v
314!--    at the ground. In this case the first u- and w-level are defined at
315!--    same height. The top w-level (nzt+1) is not used but set for
316!--    consistency, since w and all scalar variables are defined up tp nzt+1.
317       zw(nzt+1) = dz
318       zw(nzt)   = 0.0_wp
319       DO  k = 0, nzt
320          zw(k) = ( zu(k) + zu(k+1) ) * 0.5_wp
321       ENDDO
322
323!
324!--    In case of dirichlet bc for u and v the first u- and w-level are defined
325!--    at same height.
326       IF ( ibc_uv_b == 0 ) THEN
327          zu(0) = zw(0)
328       ENDIF
329
330    ENDIF
331
332!
333!-- Compute grid lengths.
334    DO  k = 1, nzt+1
335       dzu(k)  = zu(k) - zu(k-1)
336       ddzu(k) = 1.0_wp / dzu(k)
337       dzw(k)  = zw(k) - zw(k-1)
338       ddzw(k) = 1.0_wp / dzw(k)
339    ENDDO
340
341    DO  k = 1, nzt
342       dd2zu(k) = 1.0_wp / ( dzu(k) + dzu(k+1) )
343    ENDDO
344   
345!   
346!-- The FFT- SOR-pressure solvers assume grid spacings of a staggered grid
347!-- everywhere. For the actual grid, the grid spacing at the lowest level
348!-- is only dz/2, but should be dz. Therefore, an additional array
349!-- containing with appropriate grid information is created for these
350!-- solvers.
351    IF ( psolver(1:9) /= 'multigrid' )  THEN
352       ALLOCATE( ddzu_pres(1:nzt+1) )
353       ddzu_pres = ddzu
354       ddzu_pres(1) = ddzu_pres(2)  ! change for lowest level
355    ENDIF   
356
357!
358!-- In case of multigrid method, compute grid lengths and grid factors for the
359!-- grid levels
360    IF ( psolver(1:9) == 'multigrid' )  THEN
361
362       ALLOCATE( ddx2_mg(maximum_grid_level), ddy2_mg(maximum_grid_level), &
363                 dzu_mg(nzb+1:nzt+1,maximum_grid_level),                   &
364                 dzw_mg(nzb+1:nzt+1,maximum_grid_level),                   &
365                 f1_mg(nzb+1:nzt,maximum_grid_level),                      &
366                 f2_mg(nzb+1:nzt,maximum_grid_level),                      &
367                 f3_mg(nzb+1:nzt,maximum_grid_level) )
368
369       dzu_mg(:,maximum_grid_level) = dzu
370!       
371!--    Next line to ensure an equally spaced grid.
372       dzu_mg(1,maximum_grid_level) = dzu(2)
373
374       dzw_mg(:,maximum_grid_level) = dzw
375       nzt_l = nzt
376       DO  l = maximum_grid_level-1, 1, -1
377           dzu_mg(nzb+1,l) = 2.0_wp * dzu_mg(nzb+1,l+1)
378           dzw_mg(nzb+1,l) = 2.0_wp * dzw_mg(nzb+1,l+1)
379           nzt_l = nzt_l / 2
380           DO  k = 2, nzt_l+1
381              dzu_mg(k,l) = dzu_mg(2*k-2,l+1) + dzu_mg(2*k-1,l+1)
382              dzw_mg(k,l) = dzw_mg(2*k-2,l+1) + dzw_mg(2*k-1,l+1)
383           ENDDO
384       ENDDO
385
386       nzt_l = nzt
387       dx_l  = dx
388       dy_l  = dy
389       DO  l = maximum_grid_level, 1, -1
390          ddx2_mg(l) = 1.0_wp / dx_l**2
391          ddy2_mg(l) = 1.0_wp / dy_l**2
392          DO  k = nzb+1, nzt_l
393             f2_mg(k,l) = 1.0_wp / ( dzu_mg(k+1,l) * dzw_mg(k,l) )
394             f3_mg(k,l) = 1.0_wp / ( dzu_mg(k,l)   * dzw_mg(k,l) )
395             f1_mg(k,l) = 2.0_wp * ( ddx2_mg(l) + ddy2_mg(l) ) + &
396                          f2_mg(k,l) + f3_mg(k,l)
397          ENDDO
398          nzt_l = nzt_l / 2
399          dx_l  = dx_l * 2.0_wp
400          dy_l  = dy_l * 2.0_wp
401       ENDDO
402
403    ENDIF
404
405!
406!-- Compute the reciprocal values of the horizontal grid lengths.
407    ddx = 1.0_wp / dx
408    ddy = 1.0_wp / dy
409    dx2 = dx * dx
410    dy2 = dy * dy
411    ddx2 = 1.0_wp / dx2
412    ddy2 = 1.0_wp / dy2
413
414!
415!-- Compute the grid-dependent mixing length.
416    DO  k = 1, nzt
417       l_grid(k)  = ( dx * dy * dzw(k) )**0.33333333333333_wp
418    ENDDO
419
420!
421!-- Allocate outer and inner index arrays for topography and set
422!-- defaults.
423!-- nzb_local has to contain additional layers of ghost points for calculating
424!-- the flag arrays needed for the multigrid method
425    gls = 2**( maximum_grid_level )
426    IF ( gls < nbgp )  gls = nbgp
427
428    ALLOCATE( corner_nl(nys:nyn,nxl:nxr), corner_nr(nys:nyn,nxl:nxr),       &
429              corner_sl(nys:nyn,nxl:nxr), corner_sr(nys:nyn,nxl:nxr),       &
430              nzb_local(-gls:ny+gls,-gls:nx+gls),                                   &
431              nzb_tmp(-nbgp:ny+nbgp,-nbgp:nx+nbgp),                         &
432              wall_l(nys:nyn,nxl:nxr), wall_n(nys:nyn,nxl:nxr),             &
433              wall_r(nys:nyn,nxl:nxr), wall_s(nys:nyn,nxl:nxr) )
434    ALLOCATE( fwxm(nysg:nyng,nxlg:nxrg), fwxp(nysg:nyng,nxlg:nxrg),         &
435              fwym(nysg:nyng,nxlg:nxrg), fwyp(nysg:nyng,nxlg:nxrg),         &
436              fxm(nysg:nyng,nxlg:nxrg), fxp(nysg:nyng,nxlg:nxrg),           &
437              fym(nysg:nyng,nxlg:nxrg), fyp(nysg:nyng,nxlg:nxrg),           &
438              nzb_s_inner(nysg:nyng,nxlg:nxrg),                             &
439              nzb_s_outer(nysg:nyng,nxlg:nxrg),                             &
440              nzb_u_inner(nysg:nyng,nxlg:nxrg),                             &
441              nzb_u_outer(nysg:nyng,nxlg:nxrg),                             &
442              nzb_v_inner(nysg:nyng,nxlg:nxrg),                             &
443              nzb_v_outer(nysg:nyng,nxlg:nxrg),                             &
444              nzb_w_inner(nysg:nyng,nxlg:nxrg),                             &
445              nzb_w_outer(nysg:nyng,nxlg:nxrg),                             &
446              nzb_diff_s_inner(nysg:nyng,nxlg:nxrg),                        &
447              nzb_diff_s_outer(nysg:nyng,nxlg:nxrg),                        &
448              nzb_diff_u(nysg:nyng,nxlg:nxrg),                              &
449              nzb_diff_v(nysg:nyng,nxlg:nxrg),                              &
450              nzb_2d(nysg:nyng,nxlg:nxrg),                                  &
451              rflags_s_inner(nzb:nzt+2,nysg:nyng,nxlg:nxrg),                &
452              rflags_invers(nysg:nyng,nxlg:nxrg,nzb:nzt+2),                 &
453              wall_e_x(nysg:nyng,nxlg:nxrg),                                &
454              wall_e_y(nysg:nyng,nxlg:nxrg),                                &
455              wall_u(nysg:nyng,nxlg:nxrg),                                  &
456              wall_v(nysg:nyng,nxlg:nxrg),                                  &
457              wall_w_x(nysg:nyng,nxlg:nxrg),                                &
458              wall_w_y(nysg:nyng,nxlg:nxrg) )
459
460
461
462    ALLOCATE( l_wall(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
463
464
465    nzb_s_inner = nzb;  nzb_s_outer = nzb
466    nzb_u_inner = nzb;  nzb_u_outer = nzb
467    nzb_v_inner = nzb;  nzb_v_outer = nzb
468    nzb_w_inner = nzb;  nzb_w_outer = nzb
469
470    rflags_s_inner = 1.0_wp
471    rflags_invers  = 1.0_wp
472
473!
474!-- Define vertical gridpoint from (or to) which on the usual finite difference
475!-- form (which does not use surface fluxes) is applied
476    IF ( prandtl_layer  .OR.  use_surface_fluxes )  THEN
477       nzb_diff = nzb + 2
478    ELSE
479       nzb_diff = nzb + 1
480    ENDIF
481    IF ( use_top_fluxes )  THEN
482       nzt_diff = nzt - 1
483    ELSE
484       nzt_diff = nzt
485    ENDIF
486
487    nzb_diff_s_inner = nzb_diff;  nzb_diff_s_outer = nzb_diff
488    nzb_diff_u = nzb_diff;  nzb_diff_v = nzb_diff
489
490    wall_e_x = 0.0_wp;  wall_e_y = 0.0_wp;  wall_u = 0.0_wp;  wall_v = 0.0_wp
491    wall_w_x = 0.0_wp;  wall_w_y = 0.0_wp
492    fwxp = 1.0_wp;  fwxm = 1.0_wp;  fwyp = 1.0_wp;  fwym = 1.0_wp
493    fxp  = 1.0_wp;  fxm  = 1.0_wp;  fyp  = 1.0_wp;  fym  = 1.0_wp
494
495!
496!-- Initialize near-wall mixing length l_wall only in the vertical direction
497!-- for the moment,
498!-- multiplication with wall_adjustment_factor near the end of this routine
499    l_wall(nzb,:,:)   = l_grid(1)
500    DO  k = nzb+1, nzt
501       l_wall(k,:,:)  = l_grid(k)
502    ENDDO
503    l_wall(nzt+1,:,:) = l_grid(nzt)
504
505    ALLOCATE ( vertical_influence(nzb:nzt) )
506    DO  k = 1, nzt
507       vertical_influence(k) = MIN ( INT( l_grid(k) / &
508                     ( wall_adjustment_factor * dzw(k) ) + 0.5_wp ), nzt - k )
509    ENDDO
510
511    DO  k = 1, MAXVAL( nzb_s_inner )
512       IF ( l_grid(k) > 1.5_wp * dx * wall_adjustment_factor .OR.  &
513            l_grid(k) > 1.5_wp * dy * wall_adjustment_factor )  THEN
514          WRITE( message_string, * ) 'grid anisotropy exceeds ', &
515                                     'threshold given by only local', &
516                                     ' &horizontal reduction of near_wall ', &
517                                     'mixing length l_wall', &
518                                     ' &starting from height level k = ', k, '.'
519          CALL message( 'init_grid', 'PA0202', 0, 1, 0, 6, 0 )
520          EXIT
521       ENDIF
522    ENDDO
523    vertical_influence(0) = vertical_influence(1)
524
525    DO  i = nxlg, nxrg
526       DO  j = nysg, nyng
527          DO  k = nzb_s_inner(j,i) + 1, &
528                  nzb_s_inner(j,i) + vertical_influence(nzb_s_inner(j,i))
529             l_wall(k,j,i) = zu(k) - zw(nzb_s_inner(j,i))
530          ENDDO
531       ENDDO
532    ENDDO
533
534!
535!-- Set outer and inner index arrays for non-flat topography.
536!-- Here consistency checks concerning domain size and periodicity are
537!-- necessary.
538!-- Within this SELECT CASE structure only nzb_local is initialized
539!-- individually depending on the chosen topography type, all other index
540!-- arrays are initialized further below.
541    SELECT CASE ( TRIM( topography ) )
542
543       CASE ( 'flat' )
544!
545!--       nzb_local is required for the multigrid solver
546          nzb_local = 0
547
548       CASE ( 'single_building' )
549!
550!--       Single rectangular building, by default centered in the middle of the
551!--       total domain
552          blx = NINT( building_length_x / dx )
553          bly = NINT( building_length_y / dy )
554          bh  = MINLOC( ABS( zw - building_height ), 1 ) - 1
555          IF ( ABS( zw(bh  ) - building_height ) == &
556               ABS( zw(bh+1) - building_height )    )  bh = bh + 1
557
558          IF ( building_wall_left == 9999999.9_wp )  THEN
559             building_wall_left = ( nx + 1 - blx ) / 2 * dx
560          ENDIF
561          bxl = NINT( building_wall_left / dx )
562          bxr = bxl + blx
563
564          IF ( building_wall_south == 9999999.9_wp )  THEN
565             building_wall_south = ( ny + 1 - bly ) / 2 * dy
566          ENDIF
567          bys = NINT( building_wall_south / dy )
568          byn = bys + bly
569
570!
571!--       Building size has to meet some requirements
572          IF ( ( bxl < 1 ) .OR. ( bxr > nx-1 ) .OR. ( bxr < bxl+3 ) .OR.  &
573               ( bys < 1 ) .OR. ( byn > ny-1 ) .OR. ( byn < bys+3 ) )  THEN
574             WRITE( message_string, * ) 'inconsistent building parameters:',   &
575                                      '& bxl=', bxl, 'bxr=', bxr, 'bys=', bys, &
576                                      'byn=', byn, 'nx=', nx, 'ny=', ny
577             CALL message( 'init_grid', 'PA0203', 1, 2, 0, 6, 0 )
578          ENDIF
579
580!
581!--       Define the building.
582          nzb_local = 0
583          nzb_local(bys:byn,bxl:bxr) = bh
584
585       CASE ( 'single_street_canyon' )
586!
587!--       Single quasi-2D street canyon of infinite length in x or y direction.
588!--       The canyon is centered in the other direction by default.
589          IF ( canyon_width_x /= 9999999.9_wp )  THEN
590!
591!--          Street canyon in y direction
592             cwx = NINT( canyon_width_x / dx )
593             IF ( canyon_wall_left == 9999999.9_wp )  THEN
594                canyon_wall_left = ( nx + 1 - cwx ) / 2 * dx
595             ENDIF
596             cxl = NINT( canyon_wall_left / dx )
597             cxr = cxl + cwx
598
599          ELSEIF ( canyon_width_y /= 9999999.9_wp )  THEN
600!
601!--          Street canyon in x direction
602             cwy = NINT( canyon_width_y / dy )
603             IF ( canyon_wall_south == 9999999.9_wp )  THEN
604                canyon_wall_south = ( ny + 1 - cwy ) / 2 * dy
605             ENDIF
606             cys = NINT( canyon_wall_south / dy )
607             cyn = cys + cwy
608
609          ELSE
610             
611             message_string = 'no street canyon width given'
612             CALL message( 'init_grid', 'PA0204', 1, 2, 0, 6, 0 )
613 
614          ENDIF
615
616          ch  = MINLOC( ABS( zw - canyon_height ), 1 ) - 1
617          IF ( ABS( zw(ch  ) - canyon_height ) == &
618               ABS( zw(ch+1) - canyon_height )    )  ch = ch + 1
619
620          dp_level_ind_b = ch
621!
622!--       Street canyon size has to meet some requirements
623          IF ( canyon_width_x /= 9999999.9_wp )  THEN
624             IF ( ( cxl < 1 ) .OR. ( cxr > nx-1 ) .OR. ( cwx < 3 ) .OR.        &
625               ( ch < 3 ) )  THEN
626                WRITE( message_string, * ) 'inconsistent canyon parameters:',  &
627                                           '&cxl=', cxl, 'cxr=', cxr,          &
628                                           'cwx=', cwx,                        &
629                                           'ch=', ch, 'nx=', nx, 'ny=', ny
630                CALL message( 'init_grid', 'PA0205', 1, 2, 0, 6, 0 ) 
631             ENDIF
632          ELSEIF ( canyon_width_y /= 9999999.9_wp )  THEN
633             IF ( ( cys < 1 ) .OR. ( cyn > ny-1 ) .OR. ( cwy < 3 ) .OR.        &
634               ( ch < 3 ) )  THEN
635                WRITE( message_string, * ) 'inconsistent canyon parameters:',  &
636                                           '&cys=', cys, 'cyn=', cyn,          &
637                                           'cwy=', cwy,                        &
638                                           'ch=', ch, 'nx=', nx, 'ny=', ny
639                CALL message( 'init_grid', 'PA0206', 1, 2, 0, 6, 0 ) 
640             ENDIF
641          ENDIF
642          IF ( canyon_width_x /= 9999999.9_wp .AND.                            &                 
643               canyon_width_y /= 9999999.9_wp )  THEN
644             message_string = 'inconsistent canyon parameters:' //             &   
645                              '&street canyon can only be oriented' //         &
646                              '&either in x- or in y-direction'
647             CALL message( 'init_grid', 'PA0207', 1, 2, 0, 6, 0 )
648          ENDIF
649
650          nzb_local = ch
651          IF ( canyon_width_x /= 9999999.9_wp )  THEN
652             nzb_local(:,cxl+1:cxr-1) = 0
653          ELSEIF ( canyon_width_y /= 9999999.9_wp )  THEN
654             nzb_local(cys+1:cyn-1,:) = 0
655          ENDIF
656
657       CASE ( 'read_from_file' )
658
659          ALLOCATE ( topo_height(0:ny,0:nx) )
660
661          DO  ii = 0, io_blocks-1
662             IF ( ii == io_group )  THEN
663
664!
665!--             Arbitrary irregular topography data in PALM format (exactly
666!--             matching the grid size and total domain size)
667                OPEN( 90, FILE='TOPOGRAPHY_DATA'//coupling_char, STATUS='OLD', &
668                      FORM='FORMATTED', ERR=10 )
669                DO  j = ny, 0, -1
670                   READ( 90, *, ERR=11, END=11 )  ( topo_height(j,i), i = 0,nx )
671                ENDDO
672
673                GOTO 12
674         
675 10             message_string = 'file TOPOGRAPHY'//coupling_char//' does not exist'
676                CALL message( 'init_grid', 'PA0208', 1, 2, 0, 6, 0 )
677
678 11             message_string = 'errors in file TOPOGRAPHY_DATA'//coupling_char
679                CALL message( 'init_grid', 'PA0209', 1, 2, 0, 6, 0 )
680
681 12             CLOSE( 90 )
682
683             ENDIF
684#if defined( __parallel ) && ! defined ( __check )
685             CALL MPI_BARRIER( comm2d, ierr )
686#endif
687          ENDDO
688
689!
690!--       Calculate the index height of the topography
691          DO  i = 0, nx
692             DO  j = 0, ny
693                nzb_local(j,i) = MINLOC( ABS( zw - topo_height(j,i) ), 1 ) - 1
694                IF ( ABS( zw(nzb_local(j,i)  ) - topo_height(j,i) ) == &
695                     ABS( zw(nzb_local(j,i)+1) - topo_height(j,i) )    )  &
696                   nzb_local(j,i) = nzb_local(j,i) + 1
697             ENDDO
698          ENDDO
699
700          DEALLOCATE ( topo_height )
701!
702!--       Add cyclic boundaries (additional layers are for calculating
703!--       flag arrays needed for the multigrid sover)
704          nzb_local(-gls:-1,0:nx)     = nzb_local(ny-gls+1:ny,0:nx)
705          nzb_local(ny+1:ny+gls,0:nx) = nzb_local(0:gls-1,0:nx)
706          nzb_local(:,-gls:-1)        = nzb_local(:,nx-gls+1:nx)
707          nzb_local(:,nx+1:nx+gls)    = nzb_local(:,0:gls-1)
708
709       CASE DEFAULT
710!
711!--       The DEFAULT case is reached either if the parameter topography
712!--       contains a wrong character string or if the user has defined a special
713!--       case in the user interface. There, the subroutine user_init_grid
714!--       checks which of these two conditions applies.
715          CALL user_init_grid( gls, nzb_local )
716
717    END SELECT
718!
719!-- Determine the maximum level of topography. Furthermore it is used for
720!-- steering the degradation of order of the applied advection scheme.
721!-- In case of non-cyclic lateral boundaries, the order of the advection
722!-- scheme have to be reduced up to nzt (required at the lateral boundaries).
723    nzb_max = MAXVAL( nzb_local ) + 1
724    IF ( inflow_l .OR. outflow_l .OR. inflow_r .OR. outflow_r .OR.             &
725         inflow_n .OR. outflow_n .OR. inflow_s .OR. outflow_s )  THEN
726         nzb_max = nzt
727    ENDIF
728
729!
730!-- Consistency checks and index array initialization are only required for
731!-- non-flat topography, also the initialization of topography height arrays
732!-- zu_s_inner and zw_w_inner
733    IF ( TRIM( topography ) /= 'flat' )  THEN
734
735!
736!--    Consistency checks
737       IF ( MINVAL( nzb_local ) < 0  .OR.  MAXVAL( nzb_local ) > nz + 1 )  THEN
738          WRITE( message_string, * ) 'nzb_local values are outside the',       &
739                                'model domain',                                &
740                                '&MINVAL( nzb_local ) = ', MINVAL(nzb_local),  &
741                                '&MAXVAL( nzb_local ) = ', MAXVAL(nzb_local)
742          CALL message( 'init_grid', 'PA0210', 1, 2, 0, 6, 0 )
743       ENDIF
744
745       IF ( bc_lr == 'cyclic' )  THEN
746          IF ( ANY( nzb_local(:,-1) /= nzb_local(:,nx)   )  .OR.               &
747               ANY( nzb_local(:,0)  /= nzb_local(:,nx+1) ) )  THEN
748             message_string = 'nzb_local does not fulfill cyclic' //           &
749                              ' boundary condition in x-direction'
750             CALL message( 'init_grid', 'PA0211', 1, 2, 0, 6, 0 )
751          ENDIF
752       ENDIF
753       IF ( bc_ns == 'cyclic' )  THEN
754          IF ( ANY( nzb_local(-1,:) /= nzb_local(ny,:)   )  .OR.               &
755               ANY( nzb_local(0,:)  /= nzb_local(ny+1,:) ) )  THEN
756             message_string = 'nzb_local does not fulfill cyclic' //           &
757                              ' boundary condition in y-direction'
758             CALL message( 'init_grid', 'PA0212', 1, 2, 0, 6, 0 )
759          ENDIF
760       ENDIF
761
762       IF ( topography_grid_convention == 'cell_edge' )  THEN
763!
764!--       The array nzb_local as defined using the 'cell_edge' convention
765!--       describes the actual total size of topography which is defined at the
766!--       cell edges where u=0 on the topography walls in x-direction and v=0
767!--       on the topography walls in y-direction. However, PALM uses individual
768!--       arrays nzb_u|v|w|s_inner|outer that are based on nzb_s_inner.
769!--       Therefore, the extent of topography in nzb_local is now reduced by
770!--       1dx at the E topography walls and by 1dy at the N topography walls
771!--       to form the basis for nzb_s_inner.
772          DO  j = -gls, ny + gls
773             DO  i = -gls, nx
774                nzb_local(j,i) = MIN( nzb_local(j,i), nzb_local(j,i+1) )
775             ENDDO
776          ENDDO
777!--       apply cyclic boundary conditions in x-direction
778!(ist das erforderlich? Ursache von Seung Bus Fehler?)
779          nzb_local(:,nx+1:nx+gls) = nzb_local(:,0:gls-1)
780          DO  i = -gls, nx + gls
781             DO  j = -gls, ny
782                nzb_local(j,i) = MIN( nzb_local(j,i), nzb_local(j+1,i) )
783             ENDDO
784          ENDDO
785!--       apply cyclic boundary conditions in y-direction
786!(ist das erforderlich? Ursache von Seung Bus Fehler?)
787          nzb_local(ny+1:ny+gls,:) = nzb_local(0:gls-1,:)
788       ENDIF
789
790!
791!--    Initialize index arrays nzb_s_inner and nzb_w_inner
792       nzb_s_inner = nzb_local(nysg:nyng,nxlg:nxrg)
793       nzb_w_inner = nzb_local(nysg:nyng,nxlg:nxrg)
794
795!
796!--    Initialize remaining index arrays:
797!--    first pre-initialize them with nzb_s_inner...
798       nzb_u_inner = nzb_s_inner
799       nzb_u_outer = nzb_s_inner
800       nzb_v_inner = nzb_s_inner
801       nzb_v_outer = nzb_s_inner
802       nzb_w_outer = nzb_s_inner
803       nzb_s_outer = nzb_s_inner
804
805!
806!--    ...then extend pre-initialized arrays in their according directions
807!--    based on nzb_local using nzb_tmp as a temporary global index array
808
809!
810!--    nzb_s_outer:
811!--    extend nzb_local east-/westwards first, then north-/southwards
812       nzb_tmp = nzb_local(-nbgp:ny+nbgp,-nbgp:nx+nbgp)
813       DO  j = -1, ny + 1
814          DO  i = 0, nx
815             nzb_tmp(j,i) = MAX( nzb_local(j,i-1), nzb_local(j,i),             &
816                                 nzb_local(j,i+1) )
817          ENDDO
818       ENDDO
819       DO  i = nxl, nxr
820          DO  j = nys, nyn
821             nzb_s_outer(j,i) = MAX( nzb_tmp(j-1,i), nzb_tmp(j,i),             &
822                                     nzb_tmp(j+1,i) )
823          ENDDO
824!
825!--       non-cyclic boundary conditions (overwritten by call of
826!--       exchange_horiz_2d_int below in case of cyclic boundary conditions)
827          IF ( nys == 0 )  THEN
828             j = -1
829             nzb_s_outer(j,i) = MAX( nzb_tmp(j+1,i), nzb_tmp(j,i) )
830          ENDIF
831          IF ( nys == ny )  THEN
832             j = ny + 1
833             nzb_s_outer(j,i) = MAX( nzb_tmp(j-1,i), nzb_tmp(j,i) )
834          ENDIF
835       ENDDO
836!
837!--    nzb_w_outer:
838!--    identical to nzb_s_outer
839       nzb_w_outer = nzb_s_outer
840
841!
842!--    nzb_u_inner:
843!--    extend nzb_local rightwards only
844       nzb_tmp = nzb_local(-nbgp:ny+nbgp,-nbgp:nx+nbgp)
845       DO  j = -1, ny + 1
846          DO  i = 0, nx + 1
847             nzb_tmp(j,i) = MAX( nzb_local(j,i-1), nzb_local(j,i) )
848          ENDDO
849       ENDDO
850       nzb_u_inner = nzb_tmp(nysg:nyng,nxlg:nxrg)
851
852!
853!--    nzb_u_outer:
854!--    extend current nzb_tmp (nzb_u_inner) north-/southwards
855       DO  i = nxl, nxr
856          DO  j = nys, nyn
857             nzb_u_outer(j,i) = MAX( nzb_tmp(j-1,i), nzb_tmp(j,i),             &
858                                     nzb_tmp(j+1,i) )
859          ENDDO
860!
861!--       non-cyclic boundary conditions (overwritten by call of
862!--       exchange_horiz_2d_int below in case of cyclic boundary conditions)
863          IF ( nys == 0 )  THEN
864             j = -1
865             nzb_u_outer(j,i) = MAX( nzb_tmp(j+1,i), nzb_tmp(j,i) )
866          ENDIF
867          IF ( nys == ny )  THEN
868             j = ny + 1
869             nzb_u_outer(j,i) = MAX( nzb_tmp(j-1,i), nzb_tmp(j,i) )
870          ENDIF
871       ENDDO
872
873!
874!--    nzb_v_inner:
875!--    extend nzb_local northwards only
876       nzb_tmp = nzb_local(-nbgp:ny+nbgp,-nbgp:nx+nbgp)
877       DO  i = -1, nx + 1
878          DO  j = 0, ny + 1
879             nzb_tmp(j,i) = MAX( nzb_local(j-1,i), nzb_local(j,i) )
880          ENDDO
881       ENDDO
882       nzb_v_inner = nzb_tmp(nys-nbgp:nyn+nbgp,nxl-nbgp:nxr+nbgp)
883
884!
885!--    nzb_v_outer:
886!--    extend current nzb_tmp (nzb_v_inner) right-/leftwards
887       DO  j = nys, nyn
888          DO  i = nxl, nxr
889             nzb_v_outer(j,i) = MAX( nzb_tmp(j,i-1), nzb_tmp(j,i),             &
890                                     nzb_tmp(j,i+1) )
891          ENDDO
892!
893!--       non-cyclic boundary conditions (overwritten by call of
894!--       exchange_horiz_2d_int below in case of cyclic boundary conditions)
895          IF ( nxl == 0 )  THEN
896             i = -1
897             nzb_v_outer(j,i) = MAX( nzb_tmp(j,i+1), nzb_tmp(j,i) )
898          ENDIF
899          IF ( nxr == nx )  THEN
900             i = nx + 1
901             nzb_v_outer(j,i) = MAX( nzb_tmp(j,i-1), nzb_tmp(j,i) )
902          ENDIF
903       ENDDO
904#if ! defined ( __check )
905!
906!--    Exchange of lateral boundary values (parallel computers) and cyclic
907!--    boundary conditions, if applicable.
908!--    Since nzb_s_inner and nzb_w_inner are derived directly from nzb_local
909!--    they do not require exchange and are not included here.
910       CALL exchange_horiz_2d_int( nzb_u_inner )
911       CALL exchange_horiz_2d_int( nzb_u_outer )
912       CALL exchange_horiz_2d_int( nzb_v_inner )
913       CALL exchange_horiz_2d_int( nzb_v_outer )
914       CALL exchange_horiz_2d_int( nzb_w_outer )
915       CALL exchange_horiz_2d_int( nzb_s_outer )
916
917!
918!--    Allocate and set the arrays containing the topography height
919       IF ( myid == 0 )  THEN
920
921          ALLOCATE( zu_s_inner(0:nx+1,0:ny+1), zw_w_inner(0:nx+1,0:ny+1) )
922
923          DO  i = 0, nx + 1
924             DO  j = 0, ny + 1
925                zu_s_inner(i,j) = zu(nzb_local(j,i))
926                zw_w_inner(i,j) = zw(nzb_local(j,i))
927             ENDDO
928          ENDDO
929         
930       ENDIF
931!
932!--    Set flag arrays to be used for masking of grid points
933       DO  i = nxlg, nxrg
934          DO  j = nysg, nyng
935             DO  k = nzb, nzt+1
936                IF ( k <= nzb_s_inner(j,i) )  rflags_s_inner(k,j,i) = 0.0_wp
937                IF ( k <= nzb_s_inner(j,i) )  rflags_invers(j,i,k)  = 0.0_wp
938             ENDDO
939          ENDDO
940       ENDDO
941#endif
942    ENDIF
943
944#if ! defined ( __check )
945!
946!-- Preliminary: to be removed after completion of the topography code!
947!-- Set the former default k index arrays nzb_2d
948    nzb_2d      = nzb
949
950!
951!-- Set the individual index arrays which define the k index from which on
952!-- the usual finite difference form (which does not use surface fluxes) is
953!-- applied
954    IF ( prandtl_layer  .OR.  use_surface_fluxes )  THEN
955       nzb_diff_u         = nzb_u_inner + 2
956       nzb_diff_v         = nzb_v_inner + 2
957       nzb_diff_s_inner   = nzb_s_inner + 2
958       nzb_diff_s_outer   = nzb_s_outer + 2
959    ELSE
960       nzb_diff_u         = nzb_u_inner + 1
961       nzb_diff_v         = nzb_v_inner + 1
962       nzb_diff_s_inner   = nzb_s_inner + 1
963       nzb_diff_s_outer   = nzb_s_outer + 1
964    ENDIF
965
966!
967!-- Calculation of wall switches and factors required by diffusion_u/v.f90 and
968!-- for limitation of near-wall mixing length l_wall further below
969    corner_nl = 0
970    corner_nr = 0
971    corner_sl = 0
972    corner_sr = 0
973    wall_l    = 0
974    wall_n    = 0
975    wall_r    = 0
976    wall_s    = 0
977
978    DO  i = nxl, nxr
979       DO  j = nys, nyn
980!
981!--       u-component
982          IF ( nzb_u_outer(j,i) > nzb_u_outer(j+1,i) )  THEN
983             wall_u(j,i) = 1.0_wp   ! north wall (location of adjacent fluid)
984             fym(j,i)    = 0.0_wp
985             fyp(j,i)    = 1.0_wp
986          ELSEIF ( nzb_u_outer(j,i) > nzb_u_outer(j-1,i) )  THEN
987             wall_u(j,i) = 1.0_wp   ! south wall (location of adjacent fluid)
988             fym(j,i)    = 1.0_wp
989             fyp(j,i)    = 0.0_wp
990          ENDIF
991!
992!--       v-component
993          IF ( nzb_v_outer(j,i) > nzb_v_outer(j,i+1) )  THEN
994             wall_v(j,i) = 1.0_wp   ! rigth wall (location of adjacent fluid)
995             fxm(j,i)    = 0.0_wp
996             fxp(j,i)    = 1.0_wp
997          ELSEIF ( nzb_v_outer(j,i) > nzb_v_outer(j,i-1) )  THEN
998             wall_v(j,i) = 1.0_wp   ! left wall (location of adjacent fluid)
999             fxm(j,i)    = 1.0_wp
1000             fxp(j,i)    = 0.0_wp
1001          ENDIF
1002!
1003!--       w-component, also used for scalars, separate arrays for shear
1004!--       production of tke
1005          IF ( nzb_w_outer(j,i) > nzb_w_outer(j+1,i) )  THEN
1006             wall_e_y(j,i) =  1.0_wp   ! north wall (location of adjacent fluid)
1007             wall_w_y(j,i) =  1.0_wp
1008             fwym(j,i)     =  0.0_wp
1009             fwyp(j,i)     =  1.0_wp
1010          ELSEIF ( nzb_w_outer(j,i) > nzb_w_outer(j-1,i) )  THEN
1011             wall_e_y(j,i) = -1.0_wp   ! south wall (location of adjacent fluid)
1012             wall_w_y(j,i) =  1.0_wp
1013             fwym(j,i)     =  1.0_wp
1014             fwyp(j,i)     =  0.0_wp
1015          ENDIF
1016          IF ( nzb_w_outer(j,i) > nzb_w_outer(j,i+1) )  THEN
1017             wall_e_x(j,i) =  1.0_wp   ! right wall (location of adjacent fluid)
1018             wall_w_x(j,i) =  1.0_wp
1019             fwxm(j,i)     =  0.0_wp
1020             fwxp(j,i)     =  1.0_wp
1021          ELSEIF ( nzb_w_outer(j,i) > nzb_w_outer(j,i-1) )  THEN
1022             wall_e_x(j,i) = -1.0_wp   ! left wall (location of adjacent fluid)
1023             wall_w_x(j,i) =  1.0_wp
1024             fwxm(j,i)     =  1.0_wp
1025             fwxp(j,i)     =  0.0_wp
1026          ENDIF
1027!
1028!--       Wall and corner locations inside buildings for limitation of
1029!--       near-wall mixing length l_wall
1030          IF ( nzb_s_inner(j,i) > nzb_s_inner(j+1,i) )  THEN
1031
1032             wall_n(j,i) = nzb_s_inner(j+1,i) + 1            ! North wall
1033
1034             IF ( nzb_s_inner(j,i) > nzb_s_inner(j,i-1) )  THEN
1035                corner_nl(j,i) = MAX( nzb_s_inner(j+1,i),  & ! Northleft corner
1036                                      nzb_s_inner(j,i-1) ) + 1
1037             ENDIF
1038
1039             IF ( nzb_s_inner(j,i) > nzb_s_inner(j,i+1) )  THEN
1040                corner_nr(j,i) = MAX( nzb_s_inner(j+1,i),  & ! Northright corner
1041                                      nzb_s_inner(j,i+1) ) + 1
1042             ENDIF
1043
1044          ENDIF
1045
1046          IF ( nzb_s_inner(j,i) > nzb_s_inner(j-1,i) )  THEN
1047
1048             wall_s(j,i) = nzb_s_inner(j-1,i) + 1            ! South wall
1049             IF ( nzb_s_inner(j,i) > nzb_s_inner(j,i-1) )  THEN
1050                corner_sl(j,i) = MAX( nzb_s_inner(j-1,i),  & ! Southleft corner
1051                                      nzb_s_inner(j,i-1) ) + 1
1052             ENDIF
1053
1054             IF ( nzb_s_inner(j,i) > nzb_s_inner(j,i+1) )  THEN
1055                corner_sr(j,i) = MAX( nzb_s_inner(j-1,i),  & ! Southright corner
1056                                      nzb_s_inner(j,i+1) ) + 1
1057             ENDIF
1058
1059          ENDIF
1060
1061          IF ( nzb_s_inner(j,i) > nzb_s_inner(j,i-1) )  THEN
1062             wall_l(j,i) = nzb_s_inner(j,i-1) + 1            ! Left wall
1063          ENDIF
1064
1065          IF ( nzb_s_inner(j,i) > nzb_s_inner(j,i+1) )  THEN
1066             wall_r(j,i) = nzb_s_inner(j,i+1) + 1            ! Right wall
1067          ENDIF
1068
1069       ENDDO
1070    ENDDO
1071
1072!
1073!-- Calculate wall flag arrays for the multigrid method
1074    IF ( psolver(1:9) == 'multigrid' )  THEN
1075!
1076!--    Gridpoint increment of the current level
1077       inc = 1
1078
1079       DO  l = maximum_grid_level, 1 , -1
1080
1081          nxl_l = nxl_mg(l)
1082          nxr_l = nxr_mg(l)
1083          nys_l = nys_mg(l)
1084          nyn_l = nyn_mg(l)
1085          nzt_l = nzt_mg(l)
1086
1087!
1088!--       Assign the flag level to be calculated
1089          SELECT CASE ( l )
1090             CASE ( 1 )
1091                flags => wall_flags_1
1092             CASE ( 2 )
1093                flags => wall_flags_2
1094             CASE ( 3 )
1095                flags => wall_flags_3
1096             CASE ( 4 )
1097                flags => wall_flags_4
1098             CASE ( 5 )
1099                flags => wall_flags_5
1100             CASE ( 6 )
1101                flags => wall_flags_6
1102             CASE ( 7 )
1103                flags => wall_flags_7
1104             CASE ( 8 )
1105                flags => wall_flags_8
1106             CASE ( 9 )
1107                flags => wall_flags_9
1108             CASE ( 10 )
1109                flags => wall_flags_10
1110          END SELECT
1111
1112!
1113!--       Depending on the grid level, set the respective bits in case of
1114!--       neighbouring walls
1115!--       Bit 0:  wall to the bottom
1116!--       Bit 1:  wall to the top (not realized in remaining PALM code so far)
1117!--       Bit 2:  wall to the south
1118!--       Bit 3:  wall to the north
1119!--       Bit 4:  wall to the left
1120!--       Bit 5:  wall to the right
1121!--       Bit 6:  inside building
1122
1123          flags = 0
1124
1125!
1126!--       In case of masking method, flags are not set and multigrid method
1127!--       works like FFT-solver
1128          IF ( .NOT. masking_method )  THEN
1129
1130             DO  i = nxl_l-1, nxr_l+1
1131                DO  j = nys_l-1, nyn_l+1
1132                   DO  k = nzb, nzt_l+1
1133                         
1134!
1135!--                   Inside/outside building (inside building does not need
1136!--                   further tests for walls)
1137                      IF ( k*inc <= nzb_local(j*inc,i*inc) )  THEN
1138
1139                         flags(k,j,i) = IBSET( flags(k,j,i), 6 )
1140
1141                      ELSE
1142!
1143!--                      Bottom wall
1144                         IF ( (k-1)*inc <= nzb_local(j*inc,i*inc) )  THEN
1145                            flags(k,j,i) = IBSET( flags(k,j,i), 0 )
1146                         ENDIF
1147!
1148!--                      South wall
1149                         IF ( k*inc <= nzb_local((j-1)*inc,i*inc) )  THEN
1150                            flags(k,j,i) = IBSET( flags(k,j,i), 2 )
1151                         ENDIF
1152!
1153!--                      North wall
1154                         IF ( k*inc <= nzb_local((j+1)*inc,i*inc) )  THEN
1155                            flags(k,j,i) = IBSET( flags(k,j,i), 3 )
1156                         ENDIF
1157!
1158!--                      Left wall
1159                         IF ( k*inc <= nzb_local(j*inc,(i-1)*inc) )  THEN
1160                            flags(k,j,i) = IBSET( flags(k,j,i), 4 )
1161                         ENDIF
1162!
1163!--                      Right wall
1164                         IF ( k*inc <= nzb_local(j*inc,(i+1)*inc) )  THEN
1165                            flags(k,j,i) = IBSET( flags(k,j,i), 5 )
1166                         ENDIF
1167
1168                      ENDIF
1169                           
1170                   ENDDO
1171                ENDDO
1172             ENDDO
1173
1174          ENDIF
1175
1176!
1177!--       Test output of flag arrays
1178!          i = nxl_l
1179!          WRITE (9,*)  ' '
1180!          WRITE (9,*)  '*** mg level ', l, ' ***', mg_switch_to_pe0_level
1181!          WRITE (9,*)  '    inc=', inc, '  i =', nxl_l
1182!          WRITE (9,*)  '    nxl_l',nxl_l,' nxr_l=',nxr_l,' nys_l=',nys_l,' nyn_l=',nyn_l
1183!          DO  k = nzt_l+1, nzb, -1
1184!             WRITE (9,'(194(1X,I2))')  ( flags(k,j,i), j = nys_l-1, nyn_l+1 )
1185!          ENDDO
1186
1187          inc = inc * 2
1188
1189       ENDDO
1190
1191    ENDIF
1192!
1193!-- Allocate flags needed for masking walls.
1194    ALLOCATE( wall_flags_0(nzb:nzt+1,nysg:nyng,nxlg:nxrg),                     &
1195              wall_flags_00(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
1196    wall_flags_0  = 0
1197    wall_flags_00 = 0
1198
1199    IF ( scalar_advec == 'ws-scheme' .OR.                                     &
1200         scalar_advec == 'ws-scheme-mono' )  THEN
1201!
1202!--    Set flags to steer the degradation of the advection scheme in advec_ws
1203!--    near topography, inflow- and outflow boundaries as well as bottom and
1204!--    top of model domain. wall_flags_0 remains zero for all non-prognostic
1205!--    grid points.
1206       DO  i = nxl, nxr
1207          DO  j = nys, nyn
1208             DO  k = nzb_s_inner(j,i)+1, nzt
1209!
1210!--             scalar - x-direction
1211!--             WS1 (0), WS3 (1), WS5 (2)
1212                IF ( k <= nzb_s_inner(j,i+1) .OR. ( ( inflow_l .OR. outflow_l )&
1213                     .AND. i == nxl ) .OR. ( ( inflow_r .OR. outflow_r )       &
1214                     .AND. i == nxr ) )  THEN
1215                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 0 )
1216                ELSEIF ( k <= nzb_s_inner(j,i+2) .OR. k <= nzb_s_inner(j,i-1)  &
1217                         .OR. ( ( inflow_r .OR. outflow_r ) .AND. i == nxr-1 ) &
1218                         .OR. ( ( inflow_l .OR. outflow_l ) .AND. i == nxlu  ) &
1219                       )  THEN
1220                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 1 )
1221                ELSE
1222                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 2 )
1223                ENDIF
1224!
1225!--             scalar - y-direction
1226!--             WS1 (3), WS3 (4), WS5 (5)
1227                IF ( k <= nzb_s_inner(j+1,i) .OR. ( ( inflow_s .OR. outflow_s )&
1228                     .AND. j == nys ) .OR. ( ( inflow_n .OR. outflow_n )       &
1229                     .AND. j == nyn ) )  THEN
1230                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 3 )
1231!--             WS3
1232                ELSEIF ( k <= nzb_s_inner(j+2,i) .OR. k <= nzb_s_inner(j-1,i)  &
1233                         .OR. ( ( inflow_s .OR. outflow_s ) .AND. j == nysv  ) &
1234                         .OR. ( ( inflow_n .OR. outflow_n ) .AND. j == nyn-1 ) &
1235                       )  THEN
1236                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 4 )
1237!--             WS5
1238                ELSE
1239                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 5 )
1240                ENDIF
1241!
1242!--             scalar - z-direction
1243!--             WS1 (6), WS3 (7), WS5 (8)
1244                flag_set = .FALSE.
1245                IF ( k == nzb_s_inner(j,i) + 1 .OR. k == nzt )  THEN
1246                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 6 )
1247                   flag_set = .TRUE.
1248                ELSEIF ( k == nzb_s_inner(j,i) + 2 .OR. k == nzt - 1 )  THEN
1249                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 7 )
1250                   flag_set = .TRUE.
1251                ELSEIF ( k > nzb_s_inner(j,i) .AND. .NOT. flag_set )  THEN
1252                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 8 )
1253                ENDIF
1254             ENDDO
1255          ENDDO
1256       ENDDO
1257    ENDIF
1258
1259    IF ( momentum_advec == 'ws-scheme' )  THEN
1260!
1261!--    Set wall_flags_0 to steer the degradation of the advection scheme in advec_ws
1262!--    near topography, inflow- and outflow boundaries as well as bottom and
1263!--    top of model domain. wall_flags_0 remains zero for all non-prognostic
1264!--    grid points.
1265       DO  i = nxl, nxr
1266          DO  j = nys, nyn
1267             DO  k = nzb+1, nzt
1268!
1269!--             At first, set flags to WS1.
1270!--             Since fluxes are swapped in advec_ws.f90, this is necessary to
1271!--             in order to handle the left/south flux.
1272!--             near vertical walls.
1273                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 9 )
1274                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 12 )
1275!
1276!--             u component - x-direction
1277!--             WS1 (9), WS3 (10), WS5 (11)
1278                IF ( k <= nzb_u_inner(j,i+1)                                  &
1279                     .OR. ( ( inflow_l .OR. outflow_l ) .AND. i <= nxlu )     &
1280                     .OR. ( ( inflow_r .OR. outflow_r ) .AND. i == nxr  )     &
1281                   )  THEN
1282                    wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 9 )
1283                ELSEIF ( k <= nzb_u_inner(j,i+2) .OR. k <= nzb_u_inner(j,i-1) &
1284                         .OR. ( ( inflow_r .OR. outflow_r ) .AND. i == nxr-1 )&
1285                         .OR. ( ( inflow_l .OR. outflow_l ) .AND. i == nxlu+1)&
1286                       )  THEN
1287                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 10 )
1288!
1289!--                Clear flag for WS1
1290                   wall_flags_0(k,j,i) = IBCLR( wall_flags_0(k,j,i), 9 )
1291                ELSE
1292                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 11 )
1293!
1294!--                Clear flag for WS1
1295                   wall_flags_0(k,j,i) = IBCLR( wall_flags_0(k,j,i), 9 )
1296                ENDIF
1297!
1298!--             u component - y-direction
1299!--             WS1 (12), WS3 (13), WS5 (14)
1300                IF ( k <= nzb_u_inner(j+1,i) .OR. ( ( inflow_s .OR. outflow_s )&
1301                     .AND. j == nys ) .OR. ( ( inflow_n .OR. outflow_n )       &
1302                     .AND. j == nyn ) )  THEN
1303                    wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 12 )
1304                ELSEIF ( k <= nzb_u_inner(j+2,i) .OR. k <= nzb_u_inner(j-1,i)  &
1305                         .OR. ( ( inflow_s .OR. outflow_s ) .AND. j == nysv  ) &
1306                         .OR. ( ( inflow_n .OR. outflow_n ) .AND. j == nyn-1 ) &
1307                       )  THEN
1308                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 13 )
1309!
1310!--                Clear flag for WS1
1311                   wall_flags_0(k,j,i) = IBCLR( wall_flags_0(k,j,i), 12 )
1312                ELSE
1313                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 14 )
1314!
1315!--                Clear flag for WS1
1316                   wall_flags_0(k,j,i) = IBCLR( wall_flags_0(k,j,i), 12 )
1317                ENDIF
1318!
1319!--             u component - z-direction
1320!--             WS1 (15), WS3 (16), WS5 (17)
1321                flag_set = .FALSE.
1322                IF ( k == nzb_u_inner(j,i) + 1 .OR. k == nzt )  THEN
1323                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 15 )
1324                   flag_set = .TRUE.
1325                ELSEIF ( k == nzb_u_inner(j,i) + 2 .OR. k == nzt - 1 )  THEN
1326                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 16 )
1327                   flag_set = .TRUE.
1328                ELSEIF ( k > nzb_u_inner(j,i) .AND. .NOT. flag_set )  THEN
1329                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 17 )
1330                ENDIF
1331
1332             ENDDO
1333          ENDDO
1334       ENDDO
1335
1336       DO  i = nxl, nxr
1337          DO  j = nys, nyn
1338             DO  k = nzb+1, nzt
1339!
1340!--             At first, set flags to WS1.
1341!--             Since fluxes are swapped in advec_ws.f90, this is necessary to
1342!--             in order to handle the left/south flux.
1343                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 18 )
1344                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 21 )
1345!
1346!--             v component - x-direction
1347!--             WS1 (18), WS3 (19), WS5 (20)
1348                IF ( k <= nzb_v_inner(j,i+1) .OR. ( ( inflow_l .OR. outflow_l )&
1349                     .AND. i == nxl ) .OR. (( inflow_r .OR. outflow_r )        &
1350                     .AND. i == nxr ) )  THEN
1351                     wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 18 )
1352!--             WS3
1353                ELSEIF ( k <= nzb_v_inner(j,i+2) .OR. k <= nzb_v_inner(j,i-1)  &
1354                         .OR. ( ( inflow_r .OR. outflow_r ) .AND. i == nxr-1 ) &
1355                         .OR. ( ( inflow_l .OR. outflow_l ) .AND. i == nxlu  ) &
1356                       )  THEN
1357                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 19 )
1358!
1359!--                Clear flag for WS1
1360                   wall_flags_0(k,j,i) = IBCLR( wall_flags_0(k,j,i), 18 )
1361                ELSE
1362                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 20 )
1363!
1364!--                Clear flag for WS1
1365                   wall_flags_0(k,j,i) = IBCLR( wall_flags_0(k,j,i), 18 )
1366                ENDIF
1367!
1368!--             v component - y-direction
1369!--             WS1 (21), WS3 (22), WS5 (23)
1370                IF ( k <= nzb_v_inner(j+1,i)                                   &
1371                     .OR. ( ( inflow_s .OR. outflow_s ) .AND. j <= nysv )      &
1372                     .OR. ( ( inflow_n .OR. outflow_n ) .AND. j == nyn  )      &
1373                   )  THEN
1374                    wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 21 )
1375                ELSEIF ( k <= nzb_v_inner(j+2,i) .OR. k <= nzb_v_inner(j-1,i)  &
1376                         .OR. ( ( inflow_s .OR. outflow_s ) .AND. j == nysv+1 )&
1377                         .OR. ( ( inflow_n .OR. outflow_n ) .AND. j == nyn-1  )&
1378                       )  THEN
1379                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 22 )
1380!
1381!--                Clear flag for WS1
1382                   wall_flags_0(k,j,i) = IBCLR( wall_flags_0(k,j,i), 21 )
1383                ELSE
1384                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 23 )
1385!
1386!--                Clear flag for WS1
1387                   wall_flags_0(k,j,i) = IBCLR( wall_flags_0(k,j,i), 21 )
1388                ENDIF
1389!
1390!--             v component - z-direction
1391!--             WS1 (24), WS3 (25), WS5 (26)
1392                flag_set = .FALSE.
1393                IF ( k == nzb_v_inner(j,i) + 1 .OR. k == nzt )  THEN
1394                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 24 )
1395                   flag_set = .TRUE.
1396                ELSEIF ( k == nzb_v_inner(j,i) + 2 .OR. k == nzt - 1 )  THEN
1397                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 25 )
1398                   flag_set = .TRUE.
1399                ELSEIF ( k > nzb_v_inner(j,i) .AND. .NOT. flag_set )  THEN
1400                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 26 )
1401                ENDIF
1402
1403             ENDDO
1404          ENDDO
1405       ENDDO
1406       DO  i = nxl, nxr
1407          DO  j = nys, nyn
1408             DO  k = nzb+1, nzt
1409!
1410!--             At first, set flags to WS1.
1411!--             Since fluxes are swapped in advec_ws.f90, this is necessary to
1412!--             in order to handle the left/south flux.
1413                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 27 )
1414                wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 30 )
1415!
1416!--             w component - x-direction
1417!--             WS1 (27), WS3 (28), WS5 (29)
1418                IF ( k <= nzb_w_inner(j,i+1) .OR. ( ( inflow_l .OR. outflow_l )&
1419                     .AND. i == nxl ) .OR. ( ( inflow_r .OR. outflow_r )       &
1420                     .AND. i == nxr ) )  THEN
1421                    wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 27 )
1422                ELSEIF ( k <= nzb_w_inner(j,i+2) .OR. k <= nzb_w_inner(j,i-1)  &
1423                         .OR. ( ( inflow_r .OR. outflow_r ) .AND. i == nxr-1 ) &
1424                         .OR. ( ( inflow_l .OR. outflow_l ) .AND. i == nxlu  ) &
1425                       )  THEN
1426                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 28 )
1427!
1428!--                Clear flag for WS1
1429                   wall_flags_0(k,j,i) = IBCLR( wall_flags_0(k,j,i), 27 )
1430                ELSE
1431                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i),29 )
1432!
1433!--                Clear flag for WS1
1434                   wall_flags_0(k,j,i) = IBCLR( wall_flags_0(k,j,i), 27 )
1435                ENDIF
1436!
1437!--             w component - y-direction
1438!--             WS1 (30), WS3 (31), WS5 (32)
1439                IF ( k <= nzb_w_inner(j+1,i) .OR. ( ( inflow_s .OR. outflow_s )&
1440                     .AND. j == nys ) .OR. ( ( inflow_n .OR. outflow_n )       &
1441                     .AND. j == nyn ) )  THEN
1442                    wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 30 )
1443                ELSEIF ( k <= nzb_w_inner(j+2,i) .OR. k <= nzb_w_inner(j-1,i)  &
1444                         .OR. ( ( inflow_s .OR. outflow_s ) .AND. j == nysv  ) &
1445                         .OR. ( ( inflow_n .OR. outflow_n ) .AND. j == nyn-1 ) &
1446                       )  THEN
1447                   wall_flags_0(k,j,i) = IBSET( wall_flags_0(k,j,i), 31 )
1448!
1449!--                Clear flag for WS1
1450                   wall_flags_0(k,j,i) = IBCLR( wall_flags_0(k,j,i), 30 )
1451                ELSE
1452                   wall_flags_00(k,j,i) = IBSET( wall_flags_00(k,j,i), 0 )
1453!
1454!--                Clear flag for WS1
1455                   wall_flags_0(k,j,i) = IBCLR( wall_flags_0(k,j,i), 30 )
1456                ENDIF
1457!
1458!--             w component - z-direction
1459!--             WS1 (33), WS3 (34), WS5 (35)
1460                flag_set = .FALSE.
1461                IF ( k == nzb_w_inner(j,i) .OR. k == nzb_w_inner(j,i) + 1      &
1462                                           .OR. k == nzt )  THEN
1463!
1464!--                Please note, at k == nzb_w_inner(j,i) a flag is explictely
1465!--                set, although this is not a prognostic level. However,
1466!--                contrary to the advection of u,v and s this is necessary
1467!--                because flux_t(nzb_w_inner(j,i)) is used for the tendency
1468!--                at k == nzb_w_inner(j,i)+1.
1469                   wall_flags_00(k,j,i) = IBSET( wall_flags_00(k,j,i), 1 )
1470                   flag_set = .TRUE.
1471                ELSEIF ( k == nzb_w_inner(j,i) + 2 .OR. k == nzt - 1 )  THEN
1472                   wall_flags_00(k,j,i) = IBSET( wall_flags_00(k,j,i), 2 )
1473                   flag_set = .TRUE.
1474                ELSEIF ( k > nzb_w_inner(j,i) .AND. .NOT. flag_set )  THEN
1475                   wall_flags_00(k,j,i) = IBSET( wall_flags_00(k,j,i), 3 )
1476                ENDIF
1477
1478             ENDDO
1479          ENDDO
1480       ENDDO
1481
1482    ENDIF
1483
1484!
1485!-- Exchange 3D integer wall_flags.
1486    IF ( momentum_advec == 'ws-scheme' .OR. scalar_advec == 'ws-scheme'     &
1487    .OR. scalar_advec == 'ws-scheme-mono' )  THEN 
1488!
1489!--    Exchange ghost points for advection flags
1490       CALL exchange_horiz_int( wall_flags_0,  nbgp )
1491       CALL exchange_horiz_int( wall_flags_00, nbgp )
1492!
1493!--    Set boundary flags at inflow and outflow boundary in case of
1494!--    non-cyclic boundary conditions.
1495       IF ( inflow_l .OR. outflow_l )  THEN
1496          wall_flags_0(:,:,nxl-1)  = wall_flags_0(:,:,nxl)
1497          wall_flags_00(:,:,nxl-1) = wall_flags_00(:,:,nxl)
1498       ENDIF
1499
1500       IF ( inflow_r .OR. outflow_r )  THEN
1501          wall_flags_0(:,:,nxr+1)  = wall_flags_0(:,:,nxr)
1502          wall_flags_00(:,:,nxr+1) = wall_flags_00(:,:,nxr)
1503       ENDIF
1504
1505       IF ( inflow_n .OR. outflow_n )  THEN
1506          wall_flags_0(:,nyn+1,:)  = wall_flags_0(:,nyn,:)
1507          wall_flags_00(:,nyn+1,:) = wall_flags_00(:,nyn,:)
1508       ENDIF
1509
1510       IF ( inflow_s .OR. outflow_s )  THEN
1511          wall_flags_0(:,nys-1,:)  = wall_flags_0(:,nys,:)
1512          wall_flags_00(:,nys-1,:) = wall_flags_00(:,nys,:)
1513       ENDIF
1514
1515    ENDIF
1516
1517!
1518!-- In case of topography: limit near-wall mixing length l_wall further:
1519!-- Go through all points of the subdomain one by one and look for the closest
1520!-- surface
1521    IF ( TRIM(topography) /= 'flat' )  THEN
1522       DO  i = nxl, nxr
1523          DO  j = nys, nyn
1524
1525             nzb_si = nzb_s_inner(j,i)
1526             vi     = vertical_influence(nzb_si)
1527
1528             IF ( wall_n(j,i) > 0 )  THEN
1529!
1530!--             North wall (y distance)
1531                DO  k = wall_n(j,i), nzb_si
1532                   l_wall(k,j+1,i) = MIN( l_wall(k,j+1,i), 0.5_wp * dy )
1533                ENDDO
1534!
1535!--             Above North wall (yz distance)
1536                DO  k = nzb_si + 1, nzb_si + vi
1537                   l_wall(k,j+1,i) = MIN( l_wall(k,j+1,i),                     &
1538                                          SQRT( 0.25_wp * dy**2 +              &
1539                                          ( zu(k) - zw(nzb_si) )**2 ) )
1540                ENDDO
1541!
1542!--             Northleft corner (xy distance)
1543                IF ( corner_nl(j,i) > 0 )  THEN
1544                   DO  k = corner_nl(j,i), nzb_si
1545                      l_wall(k,j+1,i-1) = MIN( l_wall(k,j+1,i-1), &
1546                                               0.5_wp * SQRT( dx**2 + dy**2 ) )
1547                   ENDDO
1548!
1549!--                Above Northleft corner (xyz distance)
1550                   DO  k = nzb_si + 1, nzb_si + vi
1551                      l_wall(k,j+1,i-1) = MIN( l_wall(k,j+1,i-1),              &
1552                                            SQRT( 0.25_wp * (dx**2 + dy**2) +  &
1553                                            ( zu(k) - zw(nzb_si) )**2 ) )
1554                   ENDDO
1555                ENDIF
1556!
1557!--             Northright corner (xy distance)
1558                IF ( corner_nr(j,i) > 0 )  THEN
1559                   DO  k = corner_nr(j,i), nzb_si
1560                       l_wall(k,j+1,i+1) = MIN( l_wall(k,j+1,i+1),             &
1561                                                0.5_wp * SQRT( dx**2 + dy**2 ) )
1562                   ENDDO
1563!
1564!--                Above northright corner (xyz distance)
1565                   DO  k = nzb_si + 1, nzb_si + vi
1566                      l_wall(k,j+1,i+1) = MIN( l_wall(k,j+1,i+1),              &
1567                                            SQRT( 0.25_wp * (dx**2 + dy**2) +  &
1568                                            ( zu(k) - zw(nzb_si) )**2 ) )
1569                   ENDDO
1570                ENDIF
1571             ENDIF
1572
1573             IF ( wall_s(j,i) > 0 )  THEN
1574!
1575!--             South wall (y distance)
1576                DO  k = wall_s(j,i), nzb_si
1577                   l_wall(k,j-1,i) = MIN( l_wall(k,j-1,i), 0.5_wp * dy )
1578                ENDDO
1579!
1580!--             Above south wall (yz distance)
1581                DO  k = nzb_si + 1, nzb_si + vi
1582                   l_wall(k,j-1,i) = MIN( l_wall(k,j-1,i),                     &
1583                                          SQRT( 0.25_wp * dy**2 +              &
1584                                          ( zu(k) - zw(nzb_si) )**2 ) )
1585                ENDDO
1586!
1587!--             Southleft corner (xy distance)
1588                IF ( corner_sl(j,i) > 0 )  THEN
1589                   DO  k = corner_sl(j,i), nzb_si
1590                      l_wall(k,j-1,i-1) = MIN( l_wall(k,j-1,i-1),              &
1591                                               0.5_wp * SQRT( dx**2 + dy**2 ) )
1592                   ENDDO
1593!
1594!--                Above southleft corner (xyz distance)
1595                   DO  k = nzb_si + 1, nzb_si + vi
1596                      l_wall(k,j-1,i-1) = MIN( l_wall(k,j-1,i-1),              &
1597                                            SQRT( 0.25_wp * (dx**2 + dy**2) +  &
1598                                            ( zu(k) - zw(nzb_si) )**2 ) )
1599                   ENDDO
1600                ENDIF
1601!
1602!--             Southright corner (xy distance)
1603                IF ( corner_sr(j,i) > 0 )  THEN
1604                   DO  k = corner_sr(j,i), nzb_si
1605                      l_wall(k,j-1,i+1) = MIN( l_wall(k,j-1,i+1),              &
1606                                               0.5_wp * SQRT( dx**2 + dy**2 ) )
1607                   ENDDO
1608!
1609!--                Above southright corner (xyz distance)
1610                   DO  k = nzb_si + 1, nzb_si + vi
1611                      l_wall(k,j-1,i+1) = MIN( l_wall(k,j-1,i+1),              &
1612                                            SQRT( 0.25_wp * (dx**2 + dy**2) +  &
1613                                            ( zu(k) - zw(nzb_si) )**2 ) )
1614                   ENDDO
1615                ENDIF
1616
1617             ENDIF
1618
1619             IF ( wall_l(j,i) > 0 )  THEN
1620!
1621!--             Left wall (x distance)
1622                DO  k = wall_l(j,i), nzb_si
1623                   l_wall(k,j,i-1) = MIN( l_wall(k,j,i-1), 0.5_wp * dx )
1624                ENDDO
1625!
1626!--             Above left wall (xz distance)
1627                DO  k = nzb_si + 1, nzb_si + vi
1628                   l_wall(k,j,i-1) = MIN( l_wall(k,j,i-1),                     &
1629                                       SQRT( 0.25_wp * dx**2 +                 &
1630                                       ( zu(k) - zw(nzb_si) )**2 ) )
1631                ENDDO
1632             ENDIF
1633
1634             IF ( wall_r(j,i) > 0 )  THEN
1635!
1636!--             Right wall (x distance)
1637                DO  k = wall_r(j,i), nzb_si
1638                   l_wall(k,j,i+1) = MIN( l_wall(k,j,i+1), 0.5_wp * dx )
1639                ENDDO
1640!
1641!--             Above right wall (xz distance)
1642                DO  k = nzb_si + 1, nzb_si + vi
1643                   l_wall(k,j,i+1) = MIN( l_wall(k,j,i+1),                     &
1644                                          SQRT( 0.25_wp * dx**2 +              &
1645                                          ( zu(k) - zw(nzb_si) )**2 ) )
1646                ENDDO
1647
1648             ENDIF
1649
1650          ENDDO
1651       ENDDO
1652
1653    ENDIF
1654
1655!
1656!-- Multiplication with wall_adjustment_factor
1657    l_wall = wall_adjustment_factor * l_wall
1658
1659!
1660!-- Set lateral boundary conditions for l_wall
1661    CALL exchange_horiz( l_wall, nbgp )
1662
1663    DEALLOCATE( corner_nl, corner_nr, corner_sl, corner_sr, nzb_local, &
1664                nzb_tmp, vertical_influence, wall_l, wall_n, wall_r, wall_s )
1665
1666#endif
1667
1668 END SUBROUTINE init_grid
Note: See TracBrowser for help on using the repository browser.