source: palm/trunk/SOURCE/init_cloud_physics.f90 @ 966

 SUBROUTINE init_cloud_physics

!------------------------------------------------------------------------------!
! Current revisions:
! -----------------
! 
!
! Former revisions:
! ------------------
! $Id: init_cloud_physics.f90 826 2012-02-19 03:41:34Z raasch $
!
! 824 2012-02-17 09:09:57Z raasch
! calculation of b_cond replaced by calculation of bfactor
!
! 221 2009-01-12 15:32:23Z raasch
! Bugfix: abort in case that absolute temperature is below zero
!
! 95 2007-06-02 16:48:38Z raasch
! hydro_press renamed hyp
!
! February 2007
! RCS Log replace by Id keyword, revision history cleaned up
!
! Revision 1.5  2005/06/26 19:55:58  raasch
! Initialization of cloud droplet constants, gas_constant renamed r_d,
! latent_heat renamed l_v
!
! Revision 1.1  2000/04/13 14:37:22  schroeter
! Initial revision
!
!
! Description:
! ------------
! Initialization of parameters for handling cloud-physics
!------------------------------------------------------------------------------!

    USE arrays_3d
    USE cloud_parameters
    USE constants
    USE control_parameters
    USE grid_variables
    USE indices

    IMPLICIT NONE

    INTEGER ::  k
    REAL    ::  t_surface

    ALLOCATE( hyp(nzb:nzt+1), pt_d_t(nzb:nzt+1), t_d_pt(nzb:nzt+1) )

!
!-- Calculate frequently used parameters
    l_d_cp = l_v / cp
    l_d_r  = l_v / r_d
    l_d_rv = l_v / r_v
!
!-- Calculate factor used in equation for droplet growth by condensation
    bfactor = 3.0 * vanthoff * mass_of_solute * molecular_weight_of_water &
              / ( 4.0 * pi * rho_l * molecular_weight_of_solute )
!
!-- Calculate:
!-- pt / t : ratio of potential and actual temperature (pt_d_t)
!-- t / pt : ratio of actual and potential temperature (t_d_pt)
!-- p_0(z) : vertical profile of the hydrostatic pressure (hyp)
    t_surface = pt_surface * ( surface_pressure / 1000.0 )**0.286
    DO  k = nzb, nzt+1
!
!--    Check temperature in case of too large domain height
       IF ( ( t_surface - g/cp * zu(k) ) < 0.0 )  THEN
          WRITE( message_string, * )  'absolute temperature < 0.0 at zu(', k, &
                                      ') = ', zu(k)
          CALL message( 'init_cloud_physics', 'PA0142', 1, 2, 0, 6, 0 )
       ENDIF
       hyp(k)    = surface_pressure * 100.0 * &
                   ( (t_surface - g/cp * zu(k)) / t_surface )**(1.0/0.286)
       pt_d_t(k) = ( 100000.0 / hyp(k) )**0.286
       t_d_pt(k) = 1.0 / pt_d_t(k)       
    ENDDO

!
!-- Compute reference density
    rho_surface = surface_pressure * 100.0 / ( r_d * t_surface )


 END SUBROUTINE init_cloud_physics