source: palm/trunk/SOURCE/eqn_state_seawater.f90 @ 2232

Last change on this file since 2232 was 2232, checked in by suehring, 4 years ago

Adjustments according new topography and surface-modelling concept implemented

  • Property svn:keywords set to Id
File size: 13.5 KB
Line 
1!> @file eqn_state_seawater.f90
2!------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2017 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22! Adjustments to new topography and surface concept
23!
24! Former revisions:
25! -----------------
26! $Id: eqn_state_seawater.f90 2232 2017-05-30 17:47:52Z suehring $
27!
28! 2031 2016-10-21 15:11:58Z knoop
29! renamed variable rho to rho_ocean
30!
31! 2000 2016-08-20 18:09:15Z knoop
32! Forced header and separation lines into 80 columns
33!
34! 1873 2016-04-18 14:50:06Z maronga
35! Module renamed (removed _mod)
36!
37!
38! 1850 2016-04-08 13:29:27Z maronga
39! Module renamed
40!
41!
42! 1682 2015-10-07 23:56:08Z knoop
43! Code annotations made doxygen readable
44!
45! 1353 2014-04-08 15:21:23Z heinze
46! REAL constants provided with KIND-attribute
47!
48! 1320 2014-03-20 08:40:49Z raasch
49! ONLY-attribute added to USE-statements,
50! kind-parameters added to all INTEGER and REAL declaration statements,
51! kinds are defined in new module kinds,
52! revision history before 2012 removed,
53! comment fields (!:) to be used for variable explanations added to
54! all variable declaration statements
55!
56! 1036 2012-10-22 13:43:42Z raasch
57! code put under GPL (PALM 3.9)
58!
59! 97 2007-06-21 08:23:15Z raasch
60! Initial revision
61!
62!
63! Description:
64! ------------
65!> Equation of state for seawater as a function of potential temperature,
66!> salinity, and pressure.
67!> For coefficients see Jackett et al., 2006: J. Atm. Ocean Tech.
68!> eqn_state_seawater calculates the potential density referred at hyp(0).
69!> eqn_state_seawater_func calculates density.
70!------------------------------------------------------------------------------!
71 MODULE eqn_state_seawater_mod
72 
73   
74    USE kinds
75
76    IMPLICIT NONE
77
78    PRIVATE
79    PUBLIC eqn_state_seawater, eqn_state_seawater_func
80
81    REAL(wp), DIMENSION(12), PARAMETER ::  nom =                               &
82                          (/ 9.9984085444849347D2,   7.3471625860981584D0,     &
83                            -5.3211231792841769D-2,  3.6492439109814549D-4,    &
84                             2.5880571023991390D0,  -6.7168282786692354D-3,    &
85                             1.9203202055760151D-3,  1.1798263740430364D-2,    &
86                             9.8920219266399117D-8,  4.6996642771754730D-6,    &
87                            -2.5862187075154352D-8, -3.2921414007960662D-12 /)
88                          !<
89
90    REAL(wp), DIMENSION(13), PARAMETER ::  den =                               &
91                          (/ 1.0D0,                  7.2815210113327091D-3,    &
92                            -4.4787265461983921D-5,  3.3851002965802430D-7,    &
93                             1.3651202389758572D-10, 1.7632126669040377D-3,    &
94                            -8.8066583251206474D-6, -1.8832689434804897D-10,   &
95                             5.7463776745432097D-6,  1.4716275472242334D-9,    &
96                             6.7103246285651894D-6, -2.4461698007024582D-17,   &
97                            -9.1534417604289062D-18 /)
98                          !<
99
100    INTERFACE eqn_state_seawater
101       MODULE PROCEDURE eqn_state_seawater
102       MODULE PROCEDURE eqn_state_seawater_ij
103    END INTERFACE eqn_state_seawater
104 
105    INTERFACE eqn_state_seawater_func
106       MODULE PROCEDURE eqn_state_seawater_func
107    END INTERFACE eqn_state_seawater_func
108 
109 CONTAINS
110
111
112!------------------------------------------------------------------------------!
113! Description:
114! ------------
115!> Call for all grid points
116!------------------------------------------------------------------------------!
117    SUBROUTINE eqn_state_seawater
118
119       USE arrays_3d,                                                          &
120           ONLY:  hyp, prho, pt_p, rho_ocean, sa_p
121       USE indices,                                                            &
122           ONLY:  nxl, nxr, nyn, nys, nzb, nzt, wall_flags_0
123
124       USE surface_mod,                                                        &
125          ONLY :  bc_h
126
127       IMPLICIT NONE
128
129       INTEGER(iwp) ::  i       !< running index x direction
130       INTEGER(iwp) ::  j       !< running index y direction
131       INTEGER(iwp) ::  k       !< running index z direction
132       INTEGER(iwp) ::  l       !< running index of surface type, south- or north-facing wall
133       INTEGER(iwp) ::  m       !< running index surface elements
134       INTEGER(iwp) ::  surf_e  !< End index of surface elements at (j,i)-gridpoint
135       INTEGER(iwp) ::  surf_s  !< Start index of surface elements at (j,i)-gridpoint
136
137       REAL(wp) ::  flag   !< flag to mask topography grid points
138       REAL(wp) ::  pden   !<
139       REAL(wp) ::  pnom   !<
140       REAL(wp) ::  p1     !<
141       REAL(wp) ::  p2     !<
142       REAL(wp) ::  p3     !<
143       REAL(wp) ::  pt1    !<
144       REAL(wp) ::  pt2    !<
145       REAL(wp) ::  pt3    !<
146       REAL(wp) ::  pt4    !<
147       REAL(wp) ::  sa1    !<
148       REAL(wp) ::  sa15   !<
149       REAL(wp) ::  sa2    !<
150       
151                       
152
153       DO  i = nxl, nxr
154          DO  j = nys, nyn
155             DO  k = nzb+1, nzt
156!
157!--             Pressure is needed in dbar
158                p1 = hyp(k) * 1E-4_wp
159                p2 = p1 * p1
160                p3 = p2 * p1
161
162!
163!--             Temperature needed in degree Celsius
164                pt1 = pt_p(k,j,i) - 273.15_wp
165                pt2 = pt1 * pt1
166                pt3 = pt1 * pt2
167                pt4 = pt2 * pt2
168
169                sa1  = sa_p(k,j,i)
170                sa15 = sa1 * SQRT( sa1 )
171                sa2  = sa1 * sa1
172
173                pnom = nom(1)           + nom(2)*pt1     + nom(3)*pt2     +    &
174                       nom(4)*pt3       + nom(5)*sa1     + nom(6)*sa1*pt1 +    &
175                       nom(7)*sa2
176
177                pden = den(1)           + den(2)*pt1     + den(3)*pt2     +    &
178                       den(4)*pt3       + den(5)*pt4     + den(6)*sa1     +    &
179                       den(7)*sa1*pt1   + den(8)*sa1*pt3 + den(9)*sa15    +    &
180                       den(10)*sa15*pt2
181!
182!--             Predetermine flag to mask topography
183                flag = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_0(k,j,i), 0 ) )
184!
185!--             Potential density (without pressure terms)
186                prho(k,j,i) = pnom / pden * flag
187
188                pnom = pnom +             nom(8)*p1      + nom(9)*p1*pt2  +    &
189                       nom(10)*p1*sa1   + nom(11)*p2     + nom(12)*p2*pt2
190
191                pden = pden +             den(11)*p1     + den(12)*p2*pt3 +    &
192                       den(13)*p3*pt1
193
194!
195!--             In-situ density
196                rho_ocean(k,j,i) = pnom / pden * flag
197
198             ENDDO
199!
200!--          Neumann conditions are assumed at top boundary
201             prho(nzt+1,j,i)      = prho(nzt,j,i)
202             rho_ocean(nzt+1,j,i) = rho_ocean(nzt,j,i)
203
204          ENDDO
205       ENDDO
206!
207!--    Neumann conditions at up/downward-facing surfaces
208       !$OMP PARALLEL DO PRIVATE( i, j, k )
209       DO  m = 1, bc_h(0)%ns
210          i = bc_h(0)%i(m)           
211          j = bc_h(0)%j(m)
212          k = bc_h(0)%k(m)
213          prho(k-1,j,i)      = prho(k,j,i)
214          rho_ocean(k-1,j,i) = rho_ocean(k,j,i)
215       ENDDO
216!
217!--    Downward facing surfaces
218       !$OMP PARALLEL DO PRIVATE( i, j, k )
219       DO  m = 1, bc_h(1)%ns
220          i = bc_h(1)%i(m)           
221          j = bc_h(1)%j(m)
222          k = bc_h(1)%k(m)
223          prho(k+1,j,i)      = prho(k,j,i)
224          rho_ocean(k+1,j,i) = rho_ocean(k,j,i)
225       ENDDO
226
227    END SUBROUTINE eqn_state_seawater
228
229
230!------------------------------------------------------------------------------!
231! Description:
232! ------------
233!> Call for grid point i,j
234!------------------------------------------------------------------------------!
235    SUBROUTINE eqn_state_seawater_ij( i, j )
236
237       USE arrays_3d,                                                          &
238           ONLY:  hyp, prho, pt_p, rho_ocean, sa_p
239           
240       USE indices,                                                            &
241           ONLY:  nzb, nzt, wall_flags_0
242
243       USE surface_mod,                                                        &
244          ONLY :  bc_h
245
246       IMPLICIT NONE
247
248       INTEGER(iwp) ::  i       !< running index x direction
249       INTEGER(iwp) ::  j       !< running index y direction
250       INTEGER(iwp) ::  k       !< running index z direction
251       INTEGER(iwp) ::  l       !< running index of surface type, south- or north-facing wall
252       INTEGER(iwp) ::  m       !< running index surface elements
253       INTEGER(iwp) ::  surf_e  !< End index of surface elements at (j,i)-gridpoint
254       INTEGER(iwp) ::  surf_s  !< Start index of surface elements at (j,i)-gridpoint
255
256       REAL(wp) ::  flag   !< flag to mask topography grid points
257       REAL(wp) ::  pden   !<
258       REAL(wp) ::  pnom   !<
259       REAL(wp) ::  p1     !<
260       REAL(wp) ::  p2     !<
261       REAL(wp) ::  p3     !<
262       REAL(wp) ::  pt1    !<
263       REAL(wp) ::  pt2    !<
264       REAL(wp) ::  pt3    !<
265       REAL(wp) ::  pt4    !<
266       REAL(wp) ::  sa1    !<
267       REAL(wp) ::  sa15   !<
268       REAL(wp) ::  sa2    !<
269
270       DO  k = nzb+1, nzt
271!
272!--       Pressure is needed in dbar
273          p1 = hyp(k) * 1E-4_wp
274          p2 = p1 * p1
275          p3 = p2 * p1
276
277!
278!--       Temperature needed in degree Celsius
279          pt1 = pt_p(k,j,i) - 273.15_wp
280          pt2 = pt1 * pt1
281          pt3 = pt1 * pt2
282          pt4 = pt2 * pt2
283
284          sa1  = sa_p(k,j,i)
285          sa15 = sa1 * SQRT( sa1 )
286          sa2  = sa1 * sa1
287
288          pnom = nom(1)           + nom(2)*pt1     + nom(3)*pt2     +          &
289                 nom(4)*pt3       + nom(5)*sa1     + nom(6)*sa1*pt1 +          &
290                 nom(7)*sa2
291
292          pden = den(1)           + den(2)*pt1     + den(3)*pt2     +          &
293                 den(4)*pt3       + den(5)*pt4     + den(6)*sa1     +          &
294                 den(7)*sa1*pt1   + den(8)*sa1*pt3 + den(9)*sa15    +          &
295                 den(10)*sa15*pt2
296!
297!--       Predetermine flag to mask topography
298          flag = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_0(k,j,i), 0 ) )
299!
300!--       Potential density (without pressure terms)
301          prho(k,j,i) = pnom / pden * flag
302
303          pnom = pnom +             nom(8)*p1      + nom(9)*p1*pt2  +          &
304                 nom(10)*p1*sa1   + nom(11)*p2     + nom(12)*p2*pt2
305          pden = pden +             den(11)*p1     + den(12)*p2*pt3 +          &
306                 den(13)*p3*pt1
307
308!
309!--       In-situ density
310          rho_ocean(k,j,i) = pnom / pden * flag
311
312
313       ENDDO
314!
315!--    Neumann conditions at up/downward-facing walls
316       surf_s = bc_h(0)%start_index(j,i)   
317       surf_e = bc_h(0)%end_index(j,i)   
318       DO  m = surf_s, surf_e
319          k                  = bc_h(0)%k(m)
320          prho(k-1,j,i)      = prho(k,j,i)
321          rho_ocean(k-1,j,i) = rho_ocean(k,j,i)
322       ENDDO
323!
324!--    Downward facing surfaces
325       surf_s = bc_h(1)%start_index(j,i)   
326       surf_e = bc_h(1)%end_index(j,i)   
327       DO  m = surf_s, surf_e
328          k                  = bc_h(1)%k(m)
329          prho(k+1,j,i)      = prho(k,j,i)
330          rho_ocean(k+1,j,i) = rho_ocean(k,j,i)
331       ENDDO
332!
333!--    Neumann condition are assumed at top boundary
334       prho(nzt+1,j,i)      = prho(nzt,j,i)
335       rho_ocean(nzt+1,j,i) = rho_ocean(nzt,j,i)
336
337    END SUBROUTINE eqn_state_seawater_ij
338
339
340!------------------------------------------------------------------------------!
341! Description:
342! ------------
343!> Equation of state as a function
344!------------------------------------------------------------------------------!
345    REAL(wp) FUNCTION eqn_state_seawater_func( p, pt, sa )
346
347       IMPLICIT NONE
348
349       REAL(wp) ::  p      !<
350       REAL(wp) ::  p1     !<
351       REAL(wp) ::  p2     !<
352       REAL(wp) ::  p3     !<
353       REAL(wp) ::  pt     !<
354       REAL(wp) ::  pt1    !<
355       REAL(wp) ::  pt2    !<
356       REAL(wp) ::  pt3    !<
357       REAL(wp) ::  pt4    !<
358       REAL(wp) ::  sa     !<
359       REAL(wp) ::  sa15   !<
360       REAL(wp) ::  sa2    !<
361
362!
363!--    Pressure is needed in dbar
364       p1 = p  * 1E-4_wp
365       p2 = p1 * p1
366       p3 = p2 * p1
367
368!
369!--    Temperature needed in degree Celsius
370       pt1 = pt - 273.15_wp
371       pt2 = pt1 * pt1
372       pt3 = pt1 * pt2
373       pt4 = pt2 * pt2
374
375       sa15 = sa * SQRT( sa )
376       sa2  = sa * sa
377
378
379       eqn_state_seawater_func =                                               &
380         ( nom(1)        + nom(2)*pt1       + nom(3)*pt2    + nom(4)*pt3     + &
381           nom(5)*sa     + nom(6)*sa*pt1    + nom(7)*sa2    + nom(8)*p1      + &
382           nom(9)*p1*pt2 + nom(10)*p1*sa    + nom(11)*p2    + nom(12)*p2*pt2   &
383         ) /                                                                   &
384         ( den(1)        + den(2)*pt1       + den(3)*pt2    + den(4)*pt3     + &
385           den(5)*pt4    + den(6)*sa        + den(7)*sa*pt1 + den(8)*sa*pt3  + &
386           den(9)*sa15   + den(10)*sa15*pt2 + den(11)*p1    + den(12)*p2*pt3 + &
387           den(13)*p3*pt1                                                      &
388         )
389
390
391    END FUNCTION eqn_state_seawater_func
392
393 END MODULE eqn_state_seawater_mod
Note: See TracBrowser for help on using the repository browser.