| 1 | !> @file diffusion_w.f90 |
|---|
| 2 | !------------------------------------------------------------------------------! |
|---|
| 3 | ! This file is part of PALM. |
|---|
| 4 | ! |
|---|
| 5 | ! PALM is free software: you can redistribute it and/or modify it under the |
|---|
| 6 | ! terms of the GNU General Public License as published by the Free Software |
|---|
| 7 | ! Foundation, either version 3 of the License, or (at your option) any later |
|---|
| 8 | ! version. |
|---|
| 9 | ! |
|---|
| 10 | ! PALM is distributed in the hope that it will be useful, but WITHOUT ANY |
|---|
| 11 | ! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR |
|---|
| 12 | ! A PARTICULAR PURPOSE. See the GNU General Public License for more details. |
|---|
| 13 | ! |
|---|
| 14 | ! You should have received a copy of the GNU General Public License along with |
|---|
| 15 | ! PALM. If not, see <http://www.gnu.org/licenses/>. |
|---|
| 16 | ! |
|---|
| 17 | ! Copyright 1997-2016 Leibniz Universitaet Hannover |
|---|
| 18 | !------------------------------------------------------------------------------! |
|---|
| 19 | ! |
|---|
| 20 | ! Current revisions: |
|---|
| 21 | ! ----------------- |
|---|
| 22 | ! Forced header and separation lines into 80 columns |
|---|
| 23 | ! |
|---|
| 24 | ! Former revisions: |
|---|
| 25 | ! ----------------- |
|---|
| 26 | ! $Id: diffusion_w.f90 2000 2016-08-20 18:09:15Z knoop $ |
|---|
| 27 | ! |
|---|
| 28 | ! 1873 2016-04-18 14:50:06Z maronga |
|---|
| 29 | ! Module renamed (removed _mod) |
|---|
| 30 | ! |
|---|
| 31 | ! |
|---|
| 32 | ! 1850 2016-04-08 13:29:27Z maronga |
|---|
| 33 | ! Module renamed |
|---|
| 34 | ! |
|---|
| 35 | ! |
|---|
| 36 | ! 1682 2015-10-07 23:56:08Z knoop |
|---|
| 37 | ! Code annotations made doxygen readable |
|---|
| 38 | ! |
|---|
| 39 | ! 1374 2014-04-25 12:55:07Z raasch |
|---|
| 40 | ! vsws + vswst removed from acc-present-list |
|---|
| 41 | ! |
|---|
| 42 | ! 1353 2014-04-08 15:21:23Z heinze |
|---|
| 43 | ! REAL constants provided with KIND-attribute |
|---|
| 44 | ! |
|---|
| 45 | ! 1340 2014-03-25 19:45:13Z kanani |
|---|
| 46 | ! REAL constants defined as wp-kind |
|---|
| 47 | ! |
|---|
| 48 | ! 1322 2014-03-20 16:38:49Z raasch |
|---|
| 49 | ! REAL constants defined as wp-kind |
|---|
| 50 | ! |
|---|
| 51 | ! 1320 2014-03-20 08:40:49Z raasch |
|---|
| 52 | ! ONLY-attribute added to USE-statements, |
|---|
| 53 | ! kind-parameters added to all INTEGER and REAL declaration statements, |
|---|
| 54 | ! kinds are defined in new module kinds, |
|---|
| 55 | ! revision history before 2012 removed, |
|---|
| 56 | ! comment fields (!:) to be used for variable explanations added to |
|---|
| 57 | ! all variable declaration statements |
|---|
| 58 | ! |
|---|
| 59 | ! 1257 2013-11-08 15:18:40Z raasch |
|---|
| 60 | ! openacc loop and loop vector clauses removed, declare create moved after |
|---|
| 61 | ! the FORTRAN declaration statement |
|---|
| 62 | ! |
|---|
| 63 | ! 1128 2013-04-12 06:19:32Z raasch |
|---|
| 64 | ! loop index bounds in accelerator version replaced by i_left, i_right, j_south, |
|---|
| 65 | ! j_north |
|---|
| 66 | ! |
|---|
| 67 | ! 1036 2012-10-22 13:43:42Z raasch |
|---|
| 68 | ! code put under GPL (PALM 3.9) |
|---|
| 69 | ! |
|---|
| 70 | ! 1015 2012-09-27 09:23:24Z raasch |
|---|
| 71 | ! accelerator version (*_acc) added |
|---|
| 72 | ! |
|---|
| 73 | ! 1001 2012-09-13 14:08:46Z raasch |
|---|
| 74 | ! arrays comunicated by module instead of parameter list |
|---|
| 75 | ! |
|---|
| 76 | ! 978 2012-08-09 08:28:32Z fricke |
|---|
| 77 | ! outflow damping layer removed |
|---|
| 78 | ! kmxm_x/_z and kmxp_x/_z change to kmxm and kmxp |
|---|
| 79 | ! kmym_y/_z and kmyp_y/_z change to kmym and kmyp |
|---|
| 80 | ! |
|---|
| 81 | ! Revision 1.1 1997/09/12 06:24:11 raasch |
|---|
| 82 | ! Initial revision |
|---|
| 83 | ! |
|---|
| 84 | ! |
|---|
| 85 | ! Description: |
|---|
| 86 | ! ------------ |
|---|
| 87 | !> Diffusion term of the w-component |
|---|
| 88 | !------------------------------------------------------------------------------! |
|---|
| 89 | MODULE diffusion_w_mod |
|---|
| 90 | |
|---|
| 91 | |
|---|
| 92 | USE wall_fluxes_mod, & |
|---|
| 93 | ONLY : wall_fluxes, wall_fluxes_acc |
|---|
| 94 | |
|---|
| 95 | PRIVATE |
|---|
| 96 | PUBLIC diffusion_w, diffusion_w_acc |
|---|
| 97 | |
|---|
| 98 | INTERFACE diffusion_w |
|---|
| 99 | MODULE PROCEDURE diffusion_w |
|---|
| 100 | MODULE PROCEDURE diffusion_w_ij |
|---|
| 101 | END INTERFACE diffusion_w |
|---|
| 102 | |
|---|
| 103 | INTERFACE diffusion_w_acc |
|---|
| 104 | MODULE PROCEDURE diffusion_w_acc |
|---|
| 105 | END INTERFACE diffusion_w_acc |
|---|
| 106 | |
|---|
| 107 | CONTAINS |
|---|
| 108 | |
|---|
| 109 | |
|---|
| 110 | !------------------------------------------------------------------------------! |
|---|
| 111 | ! Description: |
|---|
| 112 | ! ------------ |
|---|
| 113 | !> Call for all grid points |
|---|
| 114 | !------------------------------------------------------------------------------! |
|---|
| 115 | SUBROUTINE diffusion_w |
|---|
| 116 | |
|---|
| 117 | USE arrays_3d, & |
|---|
| 118 | ONLY : ddzu, ddzw, km, tend, u, v, w |
|---|
| 119 | |
|---|
| 120 | USE control_parameters, & |
|---|
| 121 | ONLY : topography |
|---|
| 122 | |
|---|
| 123 | USE grid_variables, & |
|---|
| 124 | ONLY : ddx, ddy, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y |
|---|
| 125 | |
|---|
| 126 | USE indices, & |
|---|
| 127 | ONLY : nxl, nxr, nyn, nys, nzb, nzb_w_inner, nzb_w_outer, nzt |
|---|
| 128 | |
|---|
| 129 | USE kinds |
|---|
| 130 | |
|---|
| 131 | IMPLICIT NONE |
|---|
| 132 | |
|---|
| 133 | INTEGER(iwp) :: i !< |
|---|
| 134 | INTEGER(iwp) :: j !< |
|---|
| 135 | INTEGER(iwp) :: k !< |
|---|
| 136 | |
|---|
| 137 | REAL(wp) :: kmxm !< |
|---|
| 138 | REAL(wp) :: kmxp !< |
|---|
| 139 | REAL(wp) :: kmym !< |
|---|
| 140 | REAL(wp) :: kmyp !< |
|---|
| 141 | |
|---|
| 142 | REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) :: wsus !< |
|---|
| 143 | REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) :: wsvs !< |
|---|
| 144 | |
|---|
| 145 | |
|---|
| 146 | ! |
|---|
| 147 | !-- First calculate horizontal momentum flux w'u' and/or w'v' at vertical |
|---|
| 148 | !-- walls, if neccessary |
|---|
| 149 | IF ( topography /= 'flat' ) THEN |
|---|
| 150 | CALL wall_fluxes( wsus, 0.0_wp, 0.0_wp, 0.0_wp, 1.0_wp, nzb_w_inner, & |
|---|
| 151 | nzb_w_outer, wall_w_x ) |
|---|
| 152 | CALL wall_fluxes( wsvs, 0.0_wp, 0.0_wp, 1.0_wp, 0.0_wp, nzb_w_inner, & |
|---|
| 153 | nzb_w_outer, wall_w_y ) |
|---|
| 154 | ENDIF |
|---|
| 155 | |
|---|
| 156 | DO i = nxl, nxr |
|---|
| 157 | DO j = nys, nyn |
|---|
| 158 | DO k = nzb_w_outer(j,i)+1, nzt-1 |
|---|
| 159 | ! |
|---|
| 160 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 161 | kmxp = 0.25_wp * & |
|---|
| 162 | ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) ) |
|---|
| 163 | kmxm = 0.25_wp * & |
|---|
| 164 | ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) ) |
|---|
| 165 | kmyp = 0.25_wp * & |
|---|
| 166 | ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) ) |
|---|
| 167 | kmym = 0.25_wp * & |
|---|
| 168 | ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) ) |
|---|
| 169 | |
|---|
| 170 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 171 | & + ( kmxp * ( w(k,j,i+1) - w(k,j,i) ) * ddx & |
|---|
| 172 | & + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1) & |
|---|
| 173 | & - kmxm * ( w(k,j,i) - w(k,j,i-1) ) * ddx & |
|---|
| 174 | & - kmxm * ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1) & |
|---|
| 175 | & ) * ddx & |
|---|
| 176 | & + ( kmyp * ( w(k,j+1,i) - w(k,j,i) ) * ddy & |
|---|
| 177 | & + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1) & |
|---|
| 178 | & - kmym * ( w(k,j,i) - w(k,j-1,i) ) * ddy & |
|---|
| 179 | & - kmym * ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1) & |
|---|
| 180 | & ) * ddy & |
|---|
| 181 | & + 2.0_wp * ( & |
|---|
| 182 | & km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1) & |
|---|
| 183 | & - km(k,j,i) * ( w(k,j,i) - w(k-1,j,i) ) * ddzw(k) & |
|---|
| 184 | & ) * ddzu(k+1) |
|---|
| 185 | ENDDO |
|---|
| 186 | |
|---|
| 187 | ! |
|---|
| 188 | !-- Wall functions at all vertical walls, where necessary |
|---|
| 189 | IF ( wall_w_x(j,i) /= 0.0_wp .OR. wall_w_y(j,i) /= 0.0_wp ) THEN |
|---|
| 190 | |
|---|
| 191 | DO k = nzb_w_inner(j,i)+1, nzb_w_outer(j,i) |
|---|
| 192 | ! |
|---|
| 193 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 194 | kmxp = 0.25_wp * & |
|---|
| 195 | ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) ) |
|---|
| 196 | kmxm = 0.25_wp * & |
|---|
| 197 | ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) ) |
|---|
| 198 | kmyp = 0.25_wp * & |
|---|
| 199 | ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) ) |
|---|
| 200 | kmym = 0.25_wp * & |
|---|
| 201 | ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) ) |
|---|
| 202 | |
|---|
| 203 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 204 | + ( fwxp(j,i) * ( & |
|---|
| 205 | kmxp * ( w(k,j,i+1) - w(k,j,i) ) * ddx & |
|---|
| 206 | + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1) & |
|---|
| 207 | ) & |
|---|
| 208 | - fwxm(j,i) * ( & |
|---|
| 209 | kmxm * ( w(k,j,i) - w(k,j,i-1) ) * ddx & |
|---|
| 210 | + kmxm * ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1) & |
|---|
| 211 | ) & |
|---|
| 212 | + wall_w_x(j,i) * wsus(k,j,i) & |
|---|
| 213 | ) * ddx & |
|---|
| 214 | + ( fwyp(j,i) * ( & |
|---|
| 215 | kmyp * ( w(k,j+1,i) - w(k,j,i) ) * ddy & |
|---|
| 216 | + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1) & |
|---|
| 217 | ) & |
|---|
| 218 | - fwym(j,i) * ( & |
|---|
| 219 | kmym * ( w(k,j,i) - w(k,j-1,i) ) * ddy & |
|---|
| 220 | + kmym * ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1) & |
|---|
| 221 | ) & |
|---|
| 222 | + wall_w_y(j,i) * wsvs(k,j,i) & |
|---|
| 223 | ) * ddy & |
|---|
| 224 | + 2.0_wp * ( & |
|---|
| 225 | km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1) & |
|---|
| 226 | - km(k,j,i) * ( w(k,j,i) - w(k-1,j,i) ) * ddzw(k) & |
|---|
| 227 | ) * ddzu(k+1) |
|---|
| 228 | ENDDO |
|---|
| 229 | ENDIF |
|---|
| 230 | |
|---|
| 231 | ENDDO |
|---|
| 232 | ENDDO |
|---|
| 233 | |
|---|
| 234 | END SUBROUTINE diffusion_w |
|---|
| 235 | |
|---|
| 236 | |
|---|
| 237 | !------------------------------------------------------------------------------! |
|---|
| 238 | ! Description: |
|---|
| 239 | ! ------------ |
|---|
| 240 | !> Call for all grid points - accelerator version |
|---|
| 241 | !------------------------------------------------------------------------------! |
|---|
| 242 | SUBROUTINE diffusion_w_acc |
|---|
| 243 | |
|---|
| 244 | USE arrays_3d, & |
|---|
| 245 | ONLY : ddzu, ddzw, km, tend, u, v, w |
|---|
| 246 | |
|---|
| 247 | USE control_parameters, & |
|---|
| 248 | ONLY : topography |
|---|
| 249 | |
|---|
| 250 | USE grid_variables, & |
|---|
| 251 | ONLY : ddx, ddy, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y |
|---|
| 252 | |
|---|
| 253 | USE indices, & |
|---|
| 254 | ONLY : i_left, i_right, j_north, j_south, nxl, nxr, nyn, nys, nzb, & |
|---|
| 255 | nzb_w_inner, nzb_w_outer, nzt |
|---|
| 256 | |
|---|
| 257 | USE kinds |
|---|
| 258 | |
|---|
| 259 | IMPLICIT NONE |
|---|
| 260 | |
|---|
| 261 | INTEGER(iwp) :: i !< |
|---|
| 262 | INTEGER(iwp) :: j !< |
|---|
| 263 | INTEGER(iwp) :: k !< |
|---|
| 264 | |
|---|
| 265 | REAL(wp) :: kmxm !< |
|---|
| 266 | REAL(wp) :: kmxp !< |
|---|
| 267 | REAL(wp) :: kmym !< |
|---|
| 268 | REAL(wp) :: kmyp !< |
|---|
| 269 | |
|---|
| 270 | REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) :: wsus !< |
|---|
| 271 | REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) :: wsvs !< |
|---|
| 272 | !$acc declare create ( wsus, wsvs ) |
|---|
| 273 | |
|---|
| 274 | ! |
|---|
| 275 | !-- First calculate horizontal momentum flux w'u' and/or w'v' at vertical |
|---|
| 276 | !-- walls, if neccessary |
|---|
| 277 | IF ( topography /= 'flat' ) THEN |
|---|
| 278 | CALL wall_fluxes_acc( wsus, 0.0_wp, 0.0_wp, 0.0_wp, 1.0_wp, & |
|---|
| 279 | nzb_w_inner, nzb_w_outer, wall_w_x ) |
|---|
| 280 | CALL wall_fluxes_acc( wsvs, 0.0_wp, 0.0_wp, 0.0_wp, 1.0_wp, & |
|---|
| 281 | nzb_w_inner, nzb_w_outer, wall_w_y ) |
|---|
| 282 | ENDIF |
|---|
| 283 | |
|---|
| 284 | !$acc kernels present ( u, v, w, km, tend ) & |
|---|
| 285 | !$acc present ( ddzu, ddzw, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y ) & |
|---|
| 286 | !$acc present ( nzb_w_inner, nzb_w_outer ) |
|---|
| 287 | DO i = i_left, i_right |
|---|
| 288 | DO j = j_south, j_north |
|---|
| 289 | DO k = 1, nzt |
|---|
| 290 | IF ( k > nzb_w_outer(j,i) ) THEN |
|---|
| 291 | ! |
|---|
| 292 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 293 | kmxp = 0.25_wp * & |
|---|
| 294 | ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) ) |
|---|
| 295 | kmxm = 0.25_wp * & |
|---|
| 296 | ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) ) |
|---|
| 297 | kmyp = 0.25_wp * & |
|---|
| 298 | ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) ) |
|---|
| 299 | kmym = 0.25_wp * & |
|---|
| 300 | ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) ) |
|---|
| 301 | |
|---|
| 302 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 303 | & + ( kmxp * ( w(k,j,i+1) - w(k,j,i) ) * ddx & |
|---|
| 304 | & + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1) & |
|---|
| 305 | & - kmxm * ( w(k,j,i) - w(k,j,i-1) ) * ddx & |
|---|
| 306 | & - kmxm * ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1) & |
|---|
| 307 | & ) * ddx & |
|---|
| 308 | & + ( kmyp * ( w(k,j+1,i) - w(k,j,i) ) * ddy & |
|---|
| 309 | & + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1) & |
|---|
| 310 | & - kmym * ( w(k,j,i) - w(k,j-1,i) ) * ddy & |
|---|
| 311 | & - kmym * ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1) & |
|---|
| 312 | & ) * ddy & |
|---|
| 313 | & + 2.0_wp * ( & |
|---|
| 314 | & km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1) & |
|---|
| 315 | & - km(k,j,i) * ( w(k,j,i) - w(k-1,j,i) ) * ddzw(k) & |
|---|
| 316 | & ) * ddzu(k+1) |
|---|
| 317 | ENDIF |
|---|
| 318 | ENDDO |
|---|
| 319 | |
|---|
| 320 | ! |
|---|
| 321 | !-- Wall functions at all vertical walls, where necessary |
|---|
| 322 | DO k = 1,nzt |
|---|
| 323 | |
|---|
| 324 | IF ( k > nzb_w_inner(j,i) .AND. k <= nzb_w_outer(j,i) .AND. & |
|---|
| 325 | wall_w_x(j,i) /= 0.0_wp .AND. wall_w_y(j,i) /= 0.0_wp ) THEN |
|---|
| 326 | ! |
|---|
| 327 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 328 | kmxp = 0.25_wp * & |
|---|
| 329 | ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) ) |
|---|
| 330 | kmxm = 0.25_wp * & |
|---|
| 331 | ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) ) |
|---|
| 332 | kmyp = 0.25_wp * & |
|---|
| 333 | ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) ) |
|---|
| 334 | kmym = 0.25_wp * & |
|---|
| 335 | ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) ) |
|---|
| 336 | |
|---|
| 337 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 338 | + ( fwxp(j,i) * ( & |
|---|
| 339 | kmxp * ( w(k,j,i+1) - w(k,j,i) ) * ddx & |
|---|
| 340 | + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1) & |
|---|
| 341 | ) & |
|---|
| 342 | - fwxm(j,i) * ( & |
|---|
| 343 | kmxm * ( w(k,j,i) - w(k,j,i-1) ) * ddx & |
|---|
| 344 | + kmxm * ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1) & |
|---|
| 345 | ) & |
|---|
| 346 | + wall_w_x(j,i) * wsus(k,j,i) & |
|---|
| 347 | ) * ddx & |
|---|
| 348 | + ( fwyp(j,i) * ( & |
|---|
| 349 | kmyp * ( w(k,j+1,i) - w(k,j,i) ) * ddy & |
|---|
| 350 | + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1) & |
|---|
| 351 | ) & |
|---|
| 352 | - fwym(j,i) * ( & |
|---|
| 353 | kmym * ( w(k,j,i) - w(k,j-1,i) ) * ddy & |
|---|
| 354 | + kmym * ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1) & |
|---|
| 355 | ) & |
|---|
| 356 | + wall_w_y(j,i) * wsvs(k,j,i) & |
|---|
| 357 | ) * ddy & |
|---|
| 358 | + 2.0_wp * ( & |
|---|
| 359 | km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1) & |
|---|
| 360 | - km(k,j,i) * ( w(k,j,i) - w(k-1,j,i) ) * ddzw(k) & |
|---|
| 361 | ) * ddzu(k+1) |
|---|
| 362 | ENDIF |
|---|
| 363 | ENDDO |
|---|
| 364 | |
|---|
| 365 | ENDDO |
|---|
| 366 | ENDDO |
|---|
| 367 | !$acc end kernels |
|---|
| 368 | |
|---|
| 369 | END SUBROUTINE diffusion_w_acc |
|---|
| 370 | |
|---|
| 371 | |
|---|
| 372 | !------------------------------------------------------------------------------! |
|---|
| 373 | ! Description: |
|---|
| 374 | ! ------------ |
|---|
| 375 | !> Call for grid point i,j |
|---|
| 376 | !------------------------------------------------------------------------------! |
|---|
| 377 | SUBROUTINE diffusion_w_ij( i, j ) |
|---|
| 378 | |
|---|
| 379 | USE arrays_3d, & |
|---|
| 380 | ONLY : ddzu, ddzw, km, tend, u, v, w |
|---|
| 381 | |
|---|
| 382 | USE control_parameters, & |
|---|
| 383 | ONLY : topography |
|---|
| 384 | |
|---|
| 385 | USE grid_variables, & |
|---|
| 386 | ONLY : ddx, ddy, fwxm, fwxp, fwym, fwyp, wall_w_x, wall_w_y |
|---|
| 387 | |
|---|
| 388 | USE indices, & |
|---|
| 389 | ONLY : nxl, nxr, nyn, nys, nzb, nzb_w_inner, nzb_w_outer, nzt |
|---|
| 390 | |
|---|
| 391 | USE kinds |
|---|
| 392 | |
|---|
| 393 | IMPLICIT NONE |
|---|
| 394 | |
|---|
| 395 | INTEGER(iwp) :: i !< |
|---|
| 396 | INTEGER(iwp) :: j !< |
|---|
| 397 | INTEGER(iwp) :: k !< |
|---|
| 398 | |
|---|
| 399 | REAL(wp) :: kmxm !< |
|---|
| 400 | REAL(wp) :: kmxp !< |
|---|
| 401 | REAL(wp) :: kmym !< |
|---|
| 402 | REAL(wp) :: kmyp !< |
|---|
| 403 | |
|---|
| 404 | REAL(wp), DIMENSION(nzb:nzt+1) :: wsus |
|---|
| 405 | REAL(wp), DIMENSION(nzb:nzt+1) :: wsvs |
|---|
| 406 | |
|---|
| 407 | |
|---|
| 408 | DO k = nzb_w_outer(j,i)+1, nzt-1 |
|---|
| 409 | ! |
|---|
| 410 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 411 | kmxp = 0.25_wp * ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) ) |
|---|
| 412 | kmxm = 0.25_wp * ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) ) |
|---|
| 413 | kmyp = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) ) |
|---|
| 414 | kmym = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) ) |
|---|
| 415 | |
|---|
| 416 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 417 | & + ( kmxp * ( w(k,j,i+1) - w(k,j,i) ) * ddx & |
|---|
| 418 | & + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1) & |
|---|
| 419 | & - kmxm * ( w(k,j,i) - w(k,j,i-1) ) * ddx & |
|---|
| 420 | & - kmxm * ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1) & |
|---|
| 421 | & ) * ddx & |
|---|
| 422 | & + ( kmyp * ( w(k,j+1,i) - w(k,j,i) ) * ddy & |
|---|
| 423 | & + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1) & |
|---|
| 424 | & - kmym * ( w(k,j,i) - w(k,j-1,i) ) * ddy & |
|---|
| 425 | & - kmym * ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1) & |
|---|
| 426 | & ) * ddy & |
|---|
| 427 | & + 2.0_wp * ( & |
|---|
| 428 | & km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1) & |
|---|
| 429 | & - km(k,j,i) * ( w(k,j,i) - w(k-1,j,i) ) * ddzw(k) & |
|---|
| 430 | & ) * ddzu(k+1) |
|---|
| 431 | ENDDO |
|---|
| 432 | |
|---|
| 433 | ! |
|---|
| 434 | !-- Wall functions at all vertical walls, where necessary |
|---|
| 435 | IF ( wall_w_x(j,i) /= 0.0_wp .OR. wall_w_y(j,i) /= 0.0_wp ) THEN |
|---|
| 436 | |
|---|
| 437 | ! |
|---|
| 438 | !-- Calculate the horizontal momentum fluxes w'u' and/or w'v' |
|---|
| 439 | IF ( wall_w_x(j,i) /= 0.0_wp ) THEN |
|---|
| 440 | CALL wall_fluxes( i, j, nzb_w_inner(j,i)+1, nzb_w_outer(j,i), & |
|---|
| 441 | wsus, 0.0_wp, 0.0_wp, 0.0_wp, 1.0_wp ) |
|---|
| 442 | ELSE |
|---|
| 443 | wsus = 0.0_wp |
|---|
| 444 | ENDIF |
|---|
| 445 | |
|---|
| 446 | IF ( wall_w_y(j,i) /= 0.0_wp ) THEN |
|---|
| 447 | CALL wall_fluxes( i, j, nzb_w_inner(j,i)+1, nzb_w_outer(j,i), & |
|---|
| 448 | wsvs, 0.0_wp, 0.0_wp, 1.0_wp, 0.0_wp ) |
|---|
| 449 | ELSE |
|---|
| 450 | wsvs = 0.0_wp |
|---|
| 451 | ENDIF |
|---|
| 452 | |
|---|
| 453 | DO k = nzb_w_inner(j,i)+1, nzb_w_outer(j,i) |
|---|
| 454 | ! |
|---|
| 455 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 456 | kmxp = 0.25_wp * ( km(k,j,i)+km(k,j,i+1)+km(k+1,j,i)+km(k+1,j,i+1) ) |
|---|
| 457 | kmxm = 0.25_wp * ( km(k,j,i)+km(k,j,i-1)+km(k+1,j,i)+km(k+1,j,i-1) ) |
|---|
| 458 | kmyp = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j+1,i)+km(k+1,j+1,i) ) |
|---|
| 459 | kmym = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j-1,i)+km(k+1,j-1,i) ) |
|---|
| 460 | |
|---|
| 461 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 462 | + ( fwxp(j,i) * ( & |
|---|
| 463 | kmxp * ( w(k,j,i+1) - w(k,j,i) ) * ddx & |
|---|
| 464 | + kmxp * ( u(k+1,j,i+1) - u(k,j,i+1) ) * ddzu(k+1) & |
|---|
| 465 | ) & |
|---|
| 466 | - fwxm(j,i) * ( & |
|---|
| 467 | kmxm * ( w(k,j,i) - w(k,j,i-1) ) * ddx & |
|---|
| 468 | + kmxm * ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1) & |
|---|
| 469 | ) & |
|---|
| 470 | + wall_w_x(j,i) * wsus(k) & |
|---|
| 471 | ) * ddx & |
|---|
| 472 | + ( fwyp(j,i) * ( & |
|---|
| 473 | kmyp * ( w(k,j+1,i) - w(k,j,i) ) * ddy & |
|---|
| 474 | + kmyp * ( v(k+1,j+1,i) - v(k,j+1,i) ) * ddzu(k+1) & |
|---|
| 475 | ) & |
|---|
| 476 | - fwym(j,i) * ( & |
|---|
| 477 | kmym * ( w(k,j,i) - w(k,j-1,i) ) * ddy & |
|---|
| 478 | + kmym * ( v(k+1,j,i) - v(k,j,i) ) * ddzu(k+1) & |
|---|
| 479 | ) & |
|---|
| 480 | + wall_w_y(j,i) * wsvs(k) & |
|---|
| 481 | ) * ddy & |
|---|
| 482 | + 2.0_wp * ( & |
|---|
| 483 | km(k+1,j,i) * ( w(k+1,j,i) - w(k,j,i) ) * ddzw(k+1) & |
|---|
| 484 | - km(k,j,i) * ( w(k,j,i) - w(k-1,j,i) ) * ddzw(k) & |
|---|
| 485 | ) * ddzu(k+1) |
|---|
| 486 | ENDDO |
|---|
| 487 | ENDIF |
|---|
| 488 | |
|---|
| 489 | END SUBROUTINE diffusion_w_ij |
|---|
| 490 | |
|---|
| 491 | END MODULE diffusion_w_mod |
|---|
