| 1 | !> @file diffusion_u.f90 |
|---|
| 2 | !--------------------------------------------------------------------------------! |
|---|
| 3 | ! This file is part of PALM. |
|---|
| 4 | ! |
|---|
| 5 | ! PALM is free software: you can redistribute it and/or modify it under the terms |
|---|
| 6 | ! of the GNU General Public License as published by the Free Software Foundation, |
|---|
| 7 | ! either version 3 of the License, or (at your option) any later version. |
|---|
| 8 | ! |
|---|
| 9 | ! PALM is distributed in the hope that it will be useful, but WITHOUT ANY |
|---|
| 10 | ! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR |
|---|
| 11 | ! A PARTICULAR PURPOSE. See the GNU General Public License for more details. |
|---|
| 12 | ! |
|---|
| 13 | ! You should have received a copy of the GNU General Public License along with |
|---|
| 14 | ! PALM. If not, see <http://www.gnu.org/licenses/>. |
|---|
| 15 | ! |
|---|
| 16 | ! Copyright 1997-2015 Leibniz Universitaet Hannover |
|---|
| 17 | !--------------------------------------------------------------------------------! |
|---|
| 18 | ! |
|---|
| 19 | ! Current revisions: |
|---|
| 20 | ! ----------------- |
|---|
| 21 | ! unnecessary calculations of kmzm and kmzp in wall bounded parts removed |
|---|
| 22 | ! |
|---|
| 23 | ! Former revisions: |
|---|
| 24 | ! ----------------- |
|---|
| 25 | ! $Id: diffusion_u.f90 1740 2016-01-13 08:19:40Z raasch $ |
|---|
| 26 | ! |
|---|
| 27 | ! 1691 2015-10-26 16:17:44Z maronga |
|---|
| 28 | ! Formatting corrections. |
|---|
| 29 | ! |
|---|
| 30 | ! 1682 2015-10-07 23:56:08Z knoop |
|---|
| 31 | ! Code annotations made doxygen readable |
|---|
| 32 | ! |
|---|
| 33 | ! 1340 2014-03-25 19:45:13Z kanani |
|---|
| 34 | ! REAL constants defined as wp-kind |
|---|
| 35 | ! |
|---|
| 36 | ! 1320 2014-03-20 08:40:49Z raasch |
|---|
| 37 | ! ONLY-attribute added to USE-statements, |
|---|
| 38 | ! kind-parameters added to all INTEGER and REAL declaration statements, |
|---|
| 39 | ! kinds are defined in new module kinds, |
|---|
| 40 | ! revision history before 2012 removed, |
|---|
| 41 | ! comment fields (!:) to be used for variable explanations added to |
|---|
| 42 | ! all variable declaration statements |
|---|
| 43 | ! |
|---|
| 44 | ! 1257 2013-11-08 15:18:40Z raasch |
|---|
| 45 | ! openacc loop and loop vector clauses removed, declare create moved after |
|---|
| 46 | ! the FORTRAN declaration statement |
|---|
| 47 | ! |
|---|
| 48 | ! 1128 2013-04-12 06:19:32Z raasch |
|---|
| 49 | ! loop index bounds in accelerator version replaced by i_left, i_right, j_south, |
|---|
| 50 | ! j_north |
|---|
| 51 | ! |
|---|
| 52 | ! 1036 2012-10-22 13:43:42Z raasch |
|---|
| 53 | ! code put under GPL (PALM 3.9) |
|---|
| 54 | ! |
|---|
| 55 | ! 1015 2012-09-27 09:23:24Z raasch |
|---|
| 56 | ! accelerator version (*_acc) added |
|---|
| 57 | ! |
|---|
| 58 | ! 1001 2012-09-13 14:08:46Z raasch |
|---|
| 59 | ! arrays comunicated by module instead of parameter list |
|---|
| 60 | ! |
|---|
| 61 | ! 978 2012-08-09 08:28:32Z fricke |
|---|
| 62 | ! outflow damping layer removed |
|---|
| 63 | ! kmym_x/_y and kmyp_x/_y change to kmym and kmyp |
|---|
| 64 | ! |
|---|
| 65 | ! Revision 1.1 1997/09/12 06:23:51 raasch |
|---|
| 66 | ! Initial revision |
|---|
| 67 | ! |
|---|
| 68 | ! |
|---|
| 69 | ! Description: |
|---|
| 70 | ! ------------ |
|---|
| 71 | !> Diffusion term of the u-component |
|---|
| 72 | !> @todo additional damping (needed for non-cyclic bc) causes bad vectorization |
|---|
| 73 | !> and slows down the speed on NEC about 5-10% |
|---|
| 74 | !------------------------------------------------------------------------------! |
|---|
| 75 | MODULE diffusion_u_mod |
|---|
| 76 | |
|---|
| 77 | |
|---|
| 78 | USE wall_fluxes_mod |
|---|
| 79 | |
|---|
| 80 | PRIVATE |
|---|
| 81 | PUBLIC diffusion_u, diffusion_u_acc |
|---|
| 82 | |
|---|
| 83 | INTERFACE diffusion_u |
|---|
| 84 | MODULE PROCEDURE diffusion_u |
|---|
| 85 | MODULE PROCEDURE diffusion_u_ij |
|---|
| 86 | END INTERFACE diffusion_u |
|---|
| 87 | |
|---|
| 88 | INTERFACE diffusion_u_acc |
|---|
| 89 | MODULE PROCEDURE diffusion_u_acc |
|---|
| 90 | END INTERFACE diffusion_u_acc |
|---|
| 91 | |
|---|
| 92 | CONTAINS |
|---|
| 93 | |
|---|
| 94 | |
|---|
| 95 | !------------------------------------------------------------------------------! |
|---|
| 96 | ! Description: |
|---|
| 97 | ! ------------ |
|---|
| 98 | !> Call for all grid points |
|---|
| 99 | !------------------------------------------------------------------------------! |
|---|
| 100 | SUBROUTINE diffusion_u |
|---|
| 101 | |
|---|
| 102 | USE arrays_3d, & |
|---|
| 103 | ONLY: ddzu, ddzw, km, tend, u, usws, uswst, v, w |
|---|
| 104 | |
|---|
| 105 | USE control_parameters, & |
|---|
| 106 | ONLY: constant_top_momentumflux, topography, use_surface_fluxes, & |
|---|
| 107 | use_top_fluxes |
|---|
| 108 | |
|---|
| 109 | USE grid_variables, & |
|---|
| 110 | ONLY: ddx, ddx2, ddy, fym, fyp, wall_u |
|---|
| 111 | |
|---|
| 112 | USE indices, & |
|---|
| 113 | ONLY: nxl, nxlu, nxr, nyn, nys, nzb, nzb_diff_u, nzb_u_inner, & |
|---|
| 114 | nzb_u_outer, nzt, nzt_diff |
|---|
| 115 | |
|---|
| 116 | USE kinds |
|---|
| 117 | |
|---|
| 118 | IMPLICIT NONE |
|---|
| 119 | |
|---|
| 120 | INTEGER(iwp) :: i !< |
|---|
| 121 | INTEGER(iwp) :: j !< |
|---|
| 122 | INTEGER(iwp) :: k !< |
|---|
| 123 | REAL(wp) :: kmym !< |
|---|
| 124 | REAL(wp) :: kmyp !< |
|---|
| 125 | REAL(wp) :: kmzm !< |
|---|
| 126 | REAL(wp) :: kmzp !< |
|---|
| 127 | |
|---|
| 128 | REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) :: usvs !< |
|---|
| 129 | |
|---|
| 130 | ! |
|---|
| 131 | !-- First calculate horizontal momentum flux u'v' at vertical walls, |
|---|
| 132 | !-- if neccessary |
|---|
| 133 | IF ( topography /= 'flat' ) THEN |
|---|
| 134 | CALL wall_fluxes( usvs, 1.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, nzb_u_inner, & |
|---|
| 135 | nzb_u_outer, wall_u ) |
|---|
| 136 | ENDIF |
|---|
| 137 | |
|---|
| 138 | DO i = nxlu, nxr |
|---|
| 139 | DO j = nys, nyn |
|---|
| 140 | ! |
|---|
| 141 | !-- Compute horizontal diffusion |
|---|
| 142 | DO k = nzb_u_outer(j,i)+1, nzt |
|---|
| 143 | ! |
|---|
| 144 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 145 | kmyp = 0.25_wp * & |
|---|
| 146 | ( km(k,j,i)+km(k,j+1,i)+km(k,j,i-1)+km(k,j+1,i-1) ) |
|---|
| 147 | kmym = 0.25_wp * & |
|---|
| 148 | ( km(k,j,i)+km(k,j-1,i)+km(k,j,i-1)+km(k,j-1,i-1) ) |
|---|
| 149 | |
|---|
| 150 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 151 | & + 2.0_wp * ( & |
|---|
| 152 | & km(k,j,i) * ( u(k,j,i+1) - u(k,j,i) ) & |
|---|
| 153 | & - km(k,j,i-1) * ( u(k,j,i) - u(k,j,i-1) ) & |
|---|
| 154 | & ) * ddx2 & |
|---|
| 155 | & + ( kmyp * ( u(k,j+1,i) - u(k,j,i) ) * ddy & |
|---|
| 156 | & + kmyp * ( v(k,j+1,i) - v(k,j+1,i-1) ) * ddx & |
|---|
| 157 | & - kmym * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 158 | & - kmym * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 159 | & ) * ddy |
|---|
| 160 | ENDDO |
|---|
| 161 | |
|---|
| 162 | ! |
|---|
| 163 | !-- Wall functions at the north and south walls, respectively |
|---|
| 164 | IF ( wall_u(j,i) /= 0.0_wp ) THEN |
|---|
| 165 | |
|---|
| 166 | DO k = nzb_u_inner(j,i)+1, nzb_u_outer(j,i) |
|---|
| 167 | kmyp = 0.25_wp * & |
|---|
| 168 | ( km(k,j,i)+km(k,j+1,i)+km(k,j,i-1)+km(k,j+1,i-1) ) |
|---|
| 169 | kmym = 0.25_wp * & |
|---|
| 170 | ( km(k,j,i)+km(k,j-1,i)+km(k,j,i-1)+km(k,j-1,i-1) ) |
|---|
| 171 | |
|---|
| 172 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 173 | + 2.0_wp * ( & |
|---|
| 174 | km(k,j,i) * ( u(k,j,i+1) - u(k,j,i) ) & |
|---|
| 175 | - km(k,j,i-1) * ( u(k,j,i) - u(k,j,i-1) ) & |
|---|
| 176 | ) * ddx2 & |
|---|
| 177 | + ( fyp(j,i) * ( & |
|---|
| 178 | kmyp * ( u(k,j+1,i) - u(k,j,i) ) * ddy & |
|---|
| 179 | + kmyp * ( v(k,j+1,i) - v(k,j+1,i-1) ) * ddx & |
|---|
| 180 | ) & |
|---|
| 181 | - fym(j,i) * ( & |
|---|
| 182 | kmym * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 183 | + kmym * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 184 | ) & |
|---|
| 185 | + wall_u(j,i) * usvs(k,j,i) & |
|---|
| 186 | ) * ddy |
|---|
| 187 | ENDDO |
|---|
| 188 | ENDIF |
|---|
| 189 | |
|---|
| 190 | ! |
|---|
| 191 | !-- Compute vertical diffusion. In case of simulating a Prandtl layer, |
|---|
| 192 | !-- index k starts at nzb_u_inner+2. |
|---|
| 193 | DO k = nzb_diff_u(j,i), nzt_diff |
|---|
| 194 | ! |
|---|
| 195 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 196 | kmzp = 0.25_wp * & |
|---|
| 197 | ( km(k,j,i)+km(k+1,j,i)+km(k,j,i-1)+km(k+1,j,i-1) ) |
|---|
| 198 | kmzm = 0.25_wp * & |
|---|
| 199 | ( km(k,j,i)+km(k-1,j,i)+km(k,j,i-1)+km(k-1,j,i-1) ) |
|---|
| 200 | |
|---|
| 201 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 202 | & + ( kmzp * ( ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1) & |
|---|
| 203 | & + ( w(k,j,i) - w(k,j,i-1) ) * ddx & |
|---|
| 204 | & ) & |
|---|
| 205 | & - kmzm * ( ( u(k,j,i) - u(k-1,j,i) ) * ddzu(k) & |
|---|
| 206 | & + ( w(k-1,j,i) - w(k-1,j,i-1) ) * ddx & |
|---|
| 207 | & ) & |
|---|
| 208 | & ) * ddzw(k) |
|---|
| 209 | ENDDO |
|---|
| 210 | |
|---|
| 211 | ! |
|---|
| 212 | !-- Vertical diffusion at the first grid point above the surface, |
|---|
| 213 | !-- if the momentum flux at the bottom is given by the Prandtl law or |
|---|
| 214 | !-- if it is prescribed by the user. |
|---|
| 215 | !-- Difference quotient of the momentum flux is not formed over half |
|---|
| 216 | !-- of the grid spacing (2.0*ddzw(k)) any more, since the comparison |
|---|
| 217 | !-- with other (LES) models showed that the values of the momentum |
|---|
| 218 | !-- flux becomes too large in this case. |
|---|
| 219 | !-- The term containing w(k-1,..) (see above equation) is removed here |
|---|
| 220 | !-- because the vertical velocity is assumed to be zero at the surface. |
|---|
| 221 | IF ( use_surface_fluxes ) THEN |
|---|
| 222 | k = nzb_u_inner(j,i)+1 |
|---|
| 223 | ! |
|---|
| 224 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 225 | kmzp = 0.25_wp * & |
|---|
| 226 | ( km(k,j,i)+km(k+1,j,i)+km(k,j,i-1)+km(k+1,j,i-1) ) |
|---|
| 227 | |
|---|
| 228 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 229 | & + ( kmzp * ( w(k,j,i) - w(k,j,i-1) ) * ddx & |
|---|
| 230 | & ) * ddzw(k) & |
|---|
| 231 | & + ( kmzp * ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1) & |
|---|
| 232 | & + usws(j,i) & |
|---|
| 233 | & ) * ddzw(k) |
|---|
| 234 | ENDIF |
|---|
| 235 | |
|---|
| 236 | ! |
|---|
| 237 | !-- Vertical diffusion at the first gridpoint below the top boundary, |
|---|
| 238 | !-- if the momentum flux at the top is prescribed by the user |
|---|
| 239 | IF ( use_top_fluxes .AND. constant_top_momentumflux ) THEN |
|---|
| 240 | k = nzt |
|---|
| 241 | ! |
|---|
| 242 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 243 | kmzm = 0.25_wp * & |
|---|
| 244 | ( km(k,j,i)+km(k-1,j,i)+km(k,j,i-1)+km(k-1,j,i-1) ) |
|---|
| 245 | |
|---|
| 246 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 247 | & - ( kmzm * ( w(k-1,j,i) - w(k-1,j,i-1) ) * ddx & |
|---|
| 248 | & ) * ddzw(k) & |
|---|
| 249 | & + ( -uswst(j,i) & |
|---|
| 250 | & - kmzm * ( u(k,j,i) - u(k-1,j,i) ) * ddzu(k) & |
|---|
| 251 | & ) * ddzw(k) |
|---|
| 252 | ENDIF |
|---|
| 253 | |
|---|
| 254 | ENDDO |
|---|
| 255 | ENDDO |
|---|
| 256 | |
|---|
| 257 | END SUBROUTINE diffusion_u |
|---|
| 258 | |
|---|
| 259 | |
|---|
| 260 | !------------------------------------------------------------------------------! |
|---|
| 261 | ! Description: |
|---|
| 262 | ! ------------ |
|---|
| 263 | !> Call for all grid points - accelerator version |
|---|
| 264 | !------------------------------------------------------------------------------! |
|---|
| 265 | SUBROUTINE diffusion_u_acc |
|---|
| 266 | |
|---|
| 267 | USE arrays_3d, & |
|---|
| 268 | ONLY: ddzu, ddzw, km, tend, u, usws, uswst, v, w |
|---|
| 269 | |
|---|
| 270 | USE control_parameters, & |
|---|
| 271 | ONLY: constant_top_momentumflux, topography, use_surface_fluxes, & |
|---|
| 272 | use_top_fluxes |
|---|
| 273 | |
|---|
| 274 | USE grid_variables, & |
|---|
| 275 | ONLY: ddx, ddx2, ddy, fym, fyp, wall_u |
|---|
| 276 | |
|---|
| 277 | USE indices, & |
|---|
| 278 | ONLY: i_left, i_right, j_north, j_south, nxl, nxr, nyn, nys, nzb, & |
|---|
| 279 | nzb_diff_u, nzb_u_inner, nzb_u_outer, nzt, nzt_diff |
|---|
| 280 | |
|---|
| 281 | USE kinds |
|---|
| 282 | |
|---|
| 283 | IMPLICIT NONE |
|---|
| 284 | |
|---|
| 285 | INTEGER(iwp) :: i !< |
|---|
| 286 | INTEGER(iwp) :: j !< |
|---|
| 287 | INTEGER(iwp) :: k !< |
|---|
| 288 | REAL(wp) :: kmym !< |
|---|
| 289 | REAL(wp) :: kmyp !< |
|---|
| 290 | REAL(wp) :: kmzm !< |
|---|
| 291 | REAL(wp) :: kmzp !< |
|---|
| 292 | |
|---|
| 293 | REAL(wp), DIMENSION(nzb:nzt+1,nys:nyn,nxl:nxr) :: usvs !< |
|---|
| 294 | !$acc declare create ( usvs ) |
|---|
| 295 | |
|---|
| 296 | ! |
|---|
| 297 | !-- First calculate horizontal momentum flux u'v' at vertical walls, |
|---|
| 298 | !-- if neccessary |
|---|
| 299 | IF ( topography /= 'flat' ) THEN |
|---|
| 300 | CALL wall_fluxes_acc( usvs, 1.0_wp, 0.0_wp, 0.0_wp, 0.0_wp, & |
|---|
| 301 | nzb_u_inner, nzb_u_outer, wall_u ) |
|---|
| 302 | ENDIF |
|---|
| 303 | |
|---|
| 304 | !$acc kernels present ( u, v, w, km, tend, usws, uswst ) & |
|---|
| 305 | !$acc present ( ddzu, ddzw, fym, fyp, wall_u ) & |
|---|
| 306 | !$acc present ( nzb_u_inner, nzb_u_outer, nzb_diff_u ) |
|---|
| 307 | DO i = i_left, i_right |
|---|
| 308 | DO j = j_south, j_north |
|---|
| 309 | ! |
|---|
| 310 | !-- Compute horizontal diffusion |
|---|
| 311 | DO k = 1, nzt |
|---|
| 312 | IF ( k > nzb_u_outer(j,i) ) THEN |
|---|
| 313 | ! |
|---|
| 314 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 315 | kmyp = 0.25_wp * & |
|---|
| 316 | ( km(k,j,i)+km(k,j+1,i)+km(k,j,i-1)+km(k,j+1,i-1) ) |
|---|
| 317 | kmym = 0.25_wp * & |
|---|
| 318 | ( km(k,j,i)+km(k,j-1,i)+km(k,j,i-1)+km(k,j-1,i-1) ) |
|---|
| 319 | |
|---|
| 320 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 321 | & + 2.0_wp * ( & |
|---|
| 322 | & km(k,j,i) * ( u(k,j,i+1) - u(k,j,i) ) & |
|---|
| 323 | & - km(k,j,i-1) * ( u(k,j,i) - u(k,j,i-1) ) & |
|---|
| 324 | & ) * ddx2 & |
|---|
| 325 | & + ( kmyp * ( u(k,j+1,i) - u(k,j,i) ) * ddy & |
|---|
| 326 | & + kmyp * ( v(k,j+1,i) - v(k,j+1,i-1) ) * ddx & |
|---|
| 327 | & - kmym * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 328 | & - kmym * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 329 | & ) * ddy |
|---|
| 330 | ENDIF |
|---|
| 331 | ENDDO |
|---|
| 332 | |
|---|
| 333 | ! |
|---|
| 334 | !-- Wall functions at the north and south walls, respectively |
|---|
| 335 | DO k = 1, nzt |
|---|
| 336 | IF( k > nzb_u_inner(j,i) .AND. k <= nzb_u_outer(j,i) .AND. & |
|---|
| 337 | wall_u(j,i) /= 0.0_wp ) THEN |
|---|
| 338 | |
|---|
| 339 | kmyp = 0.25_wp * & |
|---|
| 340 | ( km(k,j,i)+km(k,j+1,i)+km(k,j,i-1)+km(k,j+1,i-1) ) |
|---|
| 341 | kmym = 0.25_wp * & |
|---|
| 342 | ( km(k,j,i)+km(k,j-1,i)+km(k,j,i-1)+km(k,j-1,i-1) ) |
|---|
| 343 | |
|---|
| 344 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 345 | + 2.0_wp * ( & |
|---|
| 346 | km(k,j,i) * ( u(k,j,i+1) - u(k,j,i) ) & |
|---|
| 347 | - km(k,j,i-1) * ( u(k,j,i) - u(k,j,i-1) ) & |
|---|
| 348 | ) * ddx2 & |
|---|
| 349 | + ( fyp(j,i) * ( & |
|---|
| 350 | kmyp * ( u(k,j+1,i) - u(k,j,i) ) * ddy & |
|---|
| 351 | + kmyp * ( v(k,j+1,i) - v(k,j+1,i-1) ) * ddx & |
|---|
| 352 | ) & |
|---|
| 353 | - fym(j,i) * ( & |
|---|
| 354 | kmym * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 355 | + kmym * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 356 | ) & |
|---|
| 357 | + wall_u(j,i) * usvs(k,j,i) & |
|---|
| 358 | ) * ddy |
|---|
| 359 | ENDIF |
|---|
| 360 | ENDDO |
|---|
| 361 | |
|---|
| 362 | ! |
|---|
| 363 | !-- Compute vertical diffusion. In case of simulating a Prandtl layer, |
|---|
| 364 | !-- index k starts at nzb_u_inner+2. |
|---|
| 365 | DO k = 1, nzt_diff |
|---|
| 366 | IF ( k >= nzb_diff_u(j,i) ) THEN |
|---|
| 367 | ! |
|---|
| 368 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 369 | kmzp = 0.25_wp * & |
|---|
| 370 | ( km(k,j,i)+km(k+1,j,i)+km(k,j,i-1)+km(k+1,j,i-1) ) |
|---|
| 371 | kmzm = 0.25_wp * & |
|---|
| 372 | ( km(k,j,i)+km(k-1,j,i)+km(k,j,i-1)+km(k-1,j,i-1) ) |
|---|
| 373 | |
|---|
| 374 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 375 | & + ( kmzp * ( ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1)& |
|---|
| 376 | & + ( w(k,j,i) - w(k,j,i-1) ) * ddx & |
|---|
| 377 | & ) & |
|---|
| 378 | & - kmzm * ( ( u(k,j,i) - u(k-1,j,i) ) * ddzu(k)& |
|---|
| 379 | & + ( w(k-1,j,i) - w(k-1,j,i-1) ) * ddx & |
|---|
| 380 | & ) & |
|---|
| 381 | & ) * ddzw(k) |
|---|
| 382 | ENDIF |
|---|
| 383 | ENDDO |
|---|
| 384 | |
|---|
| 385 | ENDDO |
|---|
| 386 | ENDDO |
|---|
| 387 | |
|---|
| 388 | ! |
|---|
| 389 | !-- Vertical diffusion at the first grid point above the surface, |
|---|
| 390 | !-- if the momentum flux at the bottom is given by the Prandtl law or |
|---|
| 391 | !-- if it is prescribed by the user. |
|---|
| 392 | !-- Difference quotient of the momentum flux is not formed over half |
|---|
| 393 | !-- of the grid spacing (2.0*ddzw(k)) any more, since the comparison |
|---|
| 394 | !-- with other (LES) models showed that the values of the momentum |
|---|
| 395 | !-- flux becomes too large in this case. |
|---|
| 396 | !-- The term containing w(k-1,..) (see above equation) is removed here |
|---|
| 397 | !-- because the vertical velocity is assumed to be zero at the surface. |
|---|
| 398 | IF ( use_surface_fluxes ) THEN |
|---|
| 399 | |
|---|
| 400 | DO i = i_left, i_right |
|---|
| 401 | DO j = j_south, j_north |
|---|
| 402 | |
|---|
| 403 | k = nzb_u_inner(j,i)+1 |
|---|
| 404 | ! |
|---|
| 405 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 406 | kmzp = 0.25_wp * & |
|---|
| 407 | ( km(k,j,i)+km(k+1,j,i)+km(k,j,i-1)+km(k+1,j,i-1) ) |
|---|
| 408 | |
|---|
| 409 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 410 | & + ( kmzp * ( w(k,j,i) - w(k,j,i-1) ) * ddx & |
|---|
| 411 | & ) * ddzw(k) & |
|---|
| 412 | & + ( kmzp * ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1) & |
|---|
| 413 | & + usws(j,i) & |
|---|
| 414 | & ) * ddzw(k) |
|---|
| 415 | ENDDO |
|---|
| 416 | ENDDO |
|---|
| 417 | |
|---|
| 418 | ENDIF |
|---|
| 419 | |
|---|
| 420 | ! |
|---|
| 421 | !-- Vertical diffusion at the first gridpoint below the top boundary, |
|---|
| 422 | !-- if the momentum flux at the top is prescribed by the user |
|---|
| 423 | IF ( use_top_fluxes .AND. constant_top_momentumflux ) THEN |
|---|
| 424 | |
|---|
| 425 | k = nzt |
|---|
| 426 | |
|---|
| 427 | DO i = i_left, i_right |
|---|
| 428 | DO j = j_south, j_north |
|---|
| 429 | |
|---|
| 430 | ! |
|---|
| 431 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 432 | kmzm = 0.25_wp * & |
|---|
| 433 | ( km(k,j,i)+km(k-1,j,i)+km(k,j,i-1)+km(k-1,j,i-1) ) |
|---|
| 434 | |
|---|
| 435 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 436 | & - ( kmzm * ( w(k-1,j,i) - w(k-1,j,i-1) ) * ddx & |
|---|
| 437 | & ) * ddzw(k) & |
|---|
| 438 | & + ( -uswst(j,i) & |
|---|
| 439 | & - kmzm * ( u(k,j,i) - u(k-1,j,i) ) * ddzu(k) & |
|---|
| 440 | & ) * ddzw(k) |
|---|
| 441 | ENDDO |
|---|
| 442 | ENDDO |
|---|
| 443 | |
|---|
| 444 | ENDIF |
|---|
| 445 | !$acc end kernels |
|---|
| 446 | |
|---|
| 447 | END SUBROUTINE diffusion_u_acc |
|---|
| 448 | |
|---|
| 449 | |
|---|
| 450 | !------------------------------------------------------------------------------! |
|---|
| 451 | ! Description: |
|---|
| 452 | ! ------------ |
|---|
| 453 | !> Call for grid point i,j |
|---|
| 454 | !------------------------------------------------------------------------------! |
|---|
| 455 | SUBROUTINE diffusion_u_ij( i, j ) |
|---|
| 456 | |
|---|
| 457 | USE arrays_3d, & |
|---|
| 458 | ONLY: ddzu, ddzw, km, tend, u, usws, uswst, v, w |
|---|
| 459 | |
|---|
| 460 | USE control_parameters, & |
|---|
| 461 | ONLY: constant_top_momentumflux, use_surface_fluxes, use_top_fluxes |
|---|
| 462 | |
|---|
| 463 | USE grid_variables, & |
|---|
| 464 | ONLY: ddx, ddx2, ddy, fym, fyp, wall_u |
|---|
| 465 | |
|---|
| 466 | USE indices, & |
|---|
| 467 | ONLY: nzb, nzb_diff_u, nzb_u_inner, nzb_u_outer, nzt, nzt_diff |
|---|
| 468 | |
|---|
| 469 | USE kinds |
|---|
| 470 | |
|---|
| 471 | IMPLICIT NONE |
|---|
| 472 | |
|---|
| 473 | INTEGER(iwp) :: i !< |
|---|
| 474 | INTEGER(iwp) :: j !< |
|---|
| 475 | INTEGER(iwp) :: k !< |
|---|
| 476 | REAL(wp) :: kmym !< |
|---|
| 477 | REAL(wp) :: kmyp !< |
|---|
| 478 | REAL(wp) :: kmzm !< |
|---|
| 479 | REAL(wp) :: kmzp !< |
|---|
| 480 | |
|---|
| 481 | REAL(wp), DIMENSION(nzb:nzt+1) :: usvs !< |
|---|
| 482 | |
|---|
| 483 | ! |
|---|
| 484 | !-- Compute horizontal diffusion |
|---|
| 485 | DO k = nzb_u_outer(j,i)+1, nzt |
|---|
| 486 | ! |
|---|
| 487 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 488 | kmyp = 0.25_wp * ( km(k,j,i)+km(k,j+1,i)+km(k,j,i-1)+km(k,j+1,i-1) ) |
|---|
| 489 | kmym = 0.25_wp * ( km(k,j,i)+km(k,j-1,i)+km(k,j,i-1)+km(k,j-1,i-1) ) |
|---|
| 490 | |
|---|
| 491 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 492 | & + 2.0_wp * ( & |
|---|
| 493 | & km(k,j,i) * ( u(k,j,i+1) - u(k,j,i) ) & |
|---|
| 494 | & - km(k,j,i-1) * ( u(k,j,i) - u(k,j,i-1) ) & |
|---|
| 495 | & ) * ddx2 & |
|---|
| 496 | & + ( kmyp * ( u(k,j+1,i) - u(k,j,i) ) * ddy & |
|---|
| 497 | & + kmyp * ( v(k,j+1,i) - v(k,j+1,i-1) ) * ddx & |
|---|
| 498 | & - kmym * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 499 | & - kmym * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 500 | & ) * ddy |
|---|
| 501 | ENDDO |
|---|
| 502 | |
|---|
| 503 | ! |
|---|
| 504 | !-- Wall functions at the north and south walls, respectively |
|---|
| 505 | IF ( wall_u(j,i) /= 0.0_wp ) THEN |
|---|
| 506 | |
|---|
| 507 | ! |
|---|
| 508 | !-- Calculate the horizontal momentum flux u'v' |
|---|
| 509 | CALL wall_fluxes( i, j, nzb_u_inner(j,i)+1, nzb_u_outer(j,i), & |
|---|
| 510 | usvs, 1.0_wp, 0.0_wp, 0.0_wp, 0.0_wp ) |
|---|
| 511 | |
|---|
| 512 | DO k = nzb_u_inner(j,i)+1, nzb_u_outer(j,i) |
|---|
| 513 | kmyp = 0.25_wp * ( km(k,j,i)+km(k,j+1,i)+km(k,j,i-1)+km(k,j+1,i-1) ) |
|---|
| 514 | kmym = 0.25_wp * ( km(k,j,i)+km(k,j-1,i)+km(k,j,i-1)+km(k,j-1,i-1) ) |
|---|
| 515 | |
|---|
| 516 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 517 | + 2.0_wp * ( & |
|---|
| 518 | km(k,j,i) * ( u(k,j,i+1) - u(k,j,i) ) & |
|---|
| 519 | - km(k,j,i-1) * ( u(k,j,i) - u(k,j,i-1) ) & |
|---|
| 520 | ) * ddx2 & |
|---|
| 521 | + ( fyp(j,i) * ( & |
|---|
| 522 | kmyp * ( u(k,j+1,i) - u(k,j,i) ) * ddy & |
|---|
| 523 | + kmyp * ( v(k,j+1,i) - v(k,j+1,i-1) ) * ddx & |
|---|
| 524 | ) & |
|---|
| 525 | - fym(j,i) * ( & |
|---|
| 526 | kmym * ( u(k,j,i) - u(k,j-1,i) ) * ddy & |
|---|
| 527 | + kmym * ( v(k,j,i) - v(k,j,i-1) ) * ddx & |
|---|
| 528 | ) & |
|---|
| 529 | + wall_u(j,i) * usvs(k) & |
|---|
| 530 | ) * ddy |
|---|
| 531 | ENDDO |
|---|
| 532 | ENDIF |
|---|
| 533 | |
|---|
| 534 | ! |
|---|
| 535 | !-- Compute vertical diffusion. In case of simulating a Prandtl layer, |
|---|
| 536 | !-- index k starts at nzb_u_inner+2. |
|---|
| 537 | DO k = nzb_diff_u(j,i), nzt_diff |
|---|
| 538 | ! |
|---|
| 539 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 540 | kmzp = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j,i-1)+km(k+1,j,i-1) ) |
|---|
| 541 | kmzm = 0.25_wp * ( km(k,j,i)+km(k-1,j,i)+km(k,j,i-1)+km(k-1,j,i-1) ) |
|---|
| 542 | |
|---|
| 543 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 544 | & + ( kmzp * ( ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1) & |
|---|
| 545 | & + ( w(k,j,i) - w(k,j,i-1) ) * ddx & |
|---|
| 546 | & ) & |
|---|
| 547 | & - kmzm * ( ( u(k,j,i) - u(k-1,j,i) ) * ddzu(k) & |
|---|
| 548 | & + ( w(k-1,j,i) - w(k-1,j,i-1) ) * ddx & |
|---|
| 549 | & ) & |
|---|
| 550 | & ) * ddzw(k) |
|---|
| 551 | ENDDO |
|---|
| 552 | |
|---|
| 553 | ! |
|---|
| 554 | !-- Vertical diffusion at the first grid point above the surface, if the |
|---|
| 555 | !-- momentum flux at the bottom is given by the Prandtl law or if it is |
|---|
| 556 | !-- prescribed by the user. |
|---|
| 557 | !-- Difference quotient of the momentum flux is not formed over half of |
|---|
| 558 | !-- the grid spacing (2.0*ddzw(k)) any more, since the comparison with |
|---|
| 559 | !-- other (LES) models showed that the values of the momentum flux becomes |
|---|
| 560 | !-- too large in this case. |
|---|
| 561 | !-- The term containing w(k-1,..) (see above equation) is removed here |
|---|
| 562 | !-- because the vertical velocity is assumed to be zero at the surface. |
|---|
| 563 | IF ( use_surface_fluxes ) THEN |
|---|
| 564 | k = nzb_u_inner(j,i)+1 |
|---|
| 565 | ! |
|---|
| 566 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 567 | kmzp = 0.25_wp * ( km(k,j,i)+km(k+1,j,i)+km(k,j,i-1)+km(k+1,j,i-1) ) |
|---|
| 568 | |
|---|
| 569 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 570 | & + ( kmzp * ( w(k,j,i) - w(k,j,i-1) ) * ddx & |
|---|
| 571 | & ) * ddzw(k) & |
|---|
| 572 | & + ( kmzp * ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1) & |
|---|
| 573 | & + usws(j,i) & |
|---|
| 574 | & ) * ddzw(k) |
|---|
| 575 | ENDIF |
|---|
| 576 | |
|---|
| 577 | ! |
|---|
| 578 | !-- Vertical diffusion at the first gridpoint below the top boundary, |
|---|
| 579 | !-- if the momentum flux at the top is prescribed by the user |
|---|
| 580 | IF ( use_top_fluxes .AND. constant_top_momentumflux ) THEN |
|---|
| 581 | k = nzt |
|---|
| 582 | ! |
|---|
| 583 | !-- Interpolate eddy diffusivities on staggered gridpoints |
|---|
| 584 | kmzm = 0.25_wp * & |
|---|
| 585 | ( km(k,j,i)+km(k-1,j,i)+km(k,j,i-1)+km(k-1,j,i-1) ) |
|---|
| 586 | |
|---|
| 587 | tend(k,j,i) = tend(k,j,i) & |
|---|
| 588 | & - ( kmzm * ( w(k-1,j,i) - w(k-1,j,i-1) ) * ddx & |
|---|
| 589 | & ) * ddzw(k) & |
|---|
| 590 | & + ( -uswst(j,i) & |
|---|
| 591 | & - kmzm * ( u(k,j,i) - u(k-1,j,i) ) * ddzu(k) & |
|---|
| 592 | & ) * ddzw(k) |
|---|
| 593 | ENDIF |
|---|
| 594 | |
|---|
| 595 | END SUBROUTINE diffusion_u_ij |
|---|
| 596 | |
|---|
| 597 | END MODULE diffusion_u_mod |
|---|
