source: palm/trunk/SOURCE/advec_v_pw.f90 @ 1

 MODULE advec_v_pw_mod

!------------------------------------------------------------------------------!
! Actual revisions:
! -----------------
! 
!
! Former revisions:
! -----------------
! $Log: advec_v_pw.f90,v $
! Revision 1.15  2006/02/23 09:46:08  raasch
! nzb_2d replaced by nzb_v_inner
!
! Revision 1.14  2005/03/26 14:52:51  raasch
! Extension of horizontal loop upper bounds for non-cyclic boundary conditions
!
! Revision 1.13  2004/01/30 10:12:25  raasch
! Scalar lower k index nzb replaced by 2d-array nzb_2d
!
! Revision 1.12  2003/03/12 16:18:19  raasch
! Full code replaced in the call for all gridpoints instead of calling the
! _ij version (required by NEC, because otherwise no vectorization)
!
! Revision 1.11  2002/06/11 12:26:18  raasch
! Former subroutine changed to a module which allows to be called for all grid
! points of a single vertical column with index i,j or for all grid points by
! using function overloading.
!
! Revision 1.10  2001/03/29 17:36:06  raasch
! Translation of remaining German identifiers (variables, subroutines, etc.)
!
! Revision 1.9  2001/01/22 05:14:48  raasch
! Module test_variables removed
!
! Revision 1.8  2000/01/20 10:16:37  letzel
! All comments translated into English
!
! Revision 1.7  1998/08/05 06:49:43  raasch
! Alle Gitterpunkte gleich behandelt (keine zentralen Differenzenquotienten mehr
! bei Vertikaladvektion bei k=1)
!
! Revision 1.1  1997/08/11 06:09:57  raasch
! Initial revision
!
!
! Description:
! ------------
! Advection term for v velocity-component using Piacsek and Williams.
! Vertical advection at the first grid point above the surface is done with
! normal centred differences, because otherwise no information from the surface
! would be communicated upwards due to w=0 at K=nzb.
!------------------------------------------------------------------------------!

    PRIVATE
    PUBLIC advec_v_pw

    INTERFACE advec_v_pw
       MODULE PROCEDURE advec_v_pw
       MODULE PROCEDURE advec_v_pw_ij
    END INTERFACE advec_v_pw
 
 CONTAINS


!------------------------------------------------------------------------------!
! Call for all grid points
!------------------------------------------------------------------------------!
    SUBROUTINE advec_v_pw

       USE arrays_3d
       USE control_parameters
       USE grid_variables
       USE indices

       IMPLICIT NONE

       INTEGER ::  i, j, k
       REAL    ::  gu, gv
 

       gu = 2.0 * u_gtrans
       gv = 2.0 * v_gtrans
       DO  i = nxl, nxr
          DO  j = nys, nyn+vynp
             DO  k = nzb_v_inner(j,i)+1, nzt
                tend(k,j,i) = tend(k,j,i) - 0.25 * (                           &
                         ( v(k,j,i+1) * ( u(k,j-1,i+1) + u(k,j,i+1) - gu )     &
                         - v(k,j,i-1) * ( u(k,j-1,i) + u(k,j,i) - gu ) ) * ddx &
                       + ( v(k,j+1,i) * ( v(k,j+1,i) + v(k,j,i) - gv )         &
                         - v(k,j-1,i) * ( v(k,j,i) + v(k,j-1,i) - gv ) ) * ddy &
                       + ( v(k+1,j,i) * ( w(k,j-1,i) + w(k,j,i) )              &
                         - v(k-1,j,i) * ( w(k-1,j-1,i) + w(k-1,j,i) ) )        &
                                                                  * ddzw(k)    &
                                                   )
             ENDDO
          ENDDO
       ENDDO

    END SUBROUTINE advec_v_pw


!------------------------------------------------------------------------------!
! Call for grid point i,j
!------------------------------------------------------------------------------!
    SUBROUTINE advec_v_pw_ij( i, j )

       USE arrays_3d
       USE control_parameters
       USE grid_variables
       USE indices

       IMPLICIT NONE

       INTEGER ::  i, j, k
       REAL    ::  gu, gv


       gu = 2.0 * u_gtrans
       gv = 2.0 * v_gtrans
       DO  k = nzb_v_inner(j,i)+1, nzt
          tend(k,j,i) = tend(k,j,i) - 0.25 * (                              &
                         ( v(k,j,i+1) * ( u(k,j-1,i+1) + u(k,j,i+1) - gu )     &
                         - v(k,j,i-1) * ( u(k,j-1,i) + u(k,j,i) - gu ) ) * ddx &
                       + ( v(k,j+1,i) * ( v(k,j+1,i) + v(k,j,i) - gv )         &
                         - v(k,j-1,i) * ( v(k,j,i) + v(k,j-1,i) - gv ) ) * ddy &
                       + ( v(k+1,j,i) * ( w(k,j-1,i) + w(k,j,i) )              &
                         - v(k-1,j,i) * ( w(k-1,j-1,i) + w(k-1,j,i) ) )        &
                                                                  * ddzw(k)    &
                                             )
       ENDDO
 
    END SUBROUTINE advec_v_pw_ij

 END MODULE advec_v_pw_mod