source: palm/trunk/SOURCE/advec_u_up.f90 @ 1

 MODULE advec_u_up_mod

!------------------------------------------------------------------------------!
! Actual revisions:
! -----------------
! 
!
! Former revisions:
! -----------------
! $Log: advec_u_up.f90,v $
! Revision 1.12  2006/02/23 09:45:04  raasch
! nzb_2d replaced by nzb_u_inner
!
! Revision 1.11  2005/03/26 14:50:43  raasch
! Extension of horizontal loop upper bounds for non-cyclic boundary conditions
!
! Revision 1.10  2004/01/30 10:11:47  raasch
! Scalar lower k index nzb replaced by 2d-array nzb_2d
!
! Revision 1.9  2003/03/12 16:17:42  raasch
! Full code replaced in the call for all gridpoints instead of calling the
! _ij version (required by NEC, because otherwise no vectorization)
!
! Revision 1.8  2002/06/11 12:25:43  raasch
! Former subroutine changed to a module which allows to be called for all grid
! points of a single vertical column with index i,j or for all grid points by
! using function overloading.
!
! Revision 1.7  2001/03/29 17:35:08  raasch
! Translation of remaining German identifiers (variables, subroutines, etc.)
!
! Revision 1.6  2001/01/22 04:57:23  raasch
! Module test_variables removed
!
! Revision 1.5  2000/01/20 09:40:00  letzel
! All comments translated into English
!
! Revision 1.4  1998/07/06 12:04:43  raasch
! + USE test_variables
!
! Revision 1.3  1998/04/21 15:52:51  raasch
! Galilei-Transformation eingebaut
!
! Revision 1.2  1997/09/09 08:27:49  raasch
! Kehrwerte der Gitterweiten implementiert
!
! Revision 1.1  1997/08/29 08:55:25  raasch
! Initial revision
!
!
! Description:
! ------------
! Advection term for the u velocity-component using upstream scheme.
! NOTE: vertical advection at k=1 still has wrong grid spacing for w>0!
!       The same problem occurs for all topography boundaries!
!------------------------------------------------------------------------------!

    PRIVATE
    PUBLIC advec_u_up

    INTERFACE advec_u_up
       MODULE PROCEDURE advec_u_up
       MODULE PROCEDURE advec_u_up_ij
    END INTERFACE advec_u_up

 CONTAINS


!------------------------------------------------------------------------------!
! Call for all grid points
!------------------------------------------------------------------------------!
    SUBROUTINE advec_u_up

       USE arrays_3d
       USE control_parameters
       USE grid_variables
       USE indices

       IMPLICIT NONE

       INTEGER ::  i, j, k

       REAL ::  ukomp, vkomp, wkomp


       DO  i = nxl, nxr+uxrp
          DO  j = nys, nyn
             DO  k = nzb_u_inner(j,i)+1, nzt
!
!--             x-direction
                ukomp = u(k,j,i) - u_gtrans
                IF ( ukomp > 0.0 )  THEN
                   tend(k,j,i) = tend(k,j,i) - ukomp * &
                                         ( u(k,j,i) - u(k,j,i-1) ) * ddx
                ELSE
                   tend(k,j,i) = tend(k,j,i) - ukomp * &
                                          ( u(k,j,i+1) - u(k,j,i) ) * ddx
                ENDIF
!
!--             y-direction
                vkomp = 0.25 * ( v(k,j,i)   + v(k,j+1,i) + &
                                 v(k,j,i-1) + v(k,j+1,i-1) ) - v_gtrans
                IF ( vkomp > 0.0 )  THEN
                   tend(k,j,i) = tend(k,j,i) - vkomp * &
                                         ( u(k,j,i) - u(k,j-1,i) ) * ddy
                ELSE
                   tend(k,j,i) = tend(k,j,i) - vkomp * &
                                         ( u(k,j+1,i) - u(k,j,i) ) * ddy
                ENDIF
!
!--             z-direction
                wkomp = 0.25 * ( w(k,j,i)   + w(k-1,j,i) + &
                                 w(k,j,i-1) + w(k-1,j,i-1) )
                IF ( wkomp > 0.0 )  THEN
                   tend(k,j,i) = tend(k,j,i) - wkomp * &
                                         ( u(k,j,i) - u(k-1,j,i) ) * ddzu(k)
                ELSE
                   tend(k,j,i) = tend(k,j,i) - wkomp * &
                                         ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1)
                ENDIF

             ENDDO
          ENDDO
       ENDDO

    END SUBROUTINE advec_u_up


!------------------------------------------------------------------------------!
! Call for grid point i,j
!------------------------------------------------------------------------------!
    SUBROUTINE advec_u_up_ij( i, j )

       USE arrays_3d
       USE control_parameters
       USE grid_variables
       USE indices

       IMPLICIT NONE

       INTEGER ::  i, j, k

       REAL ::  ukomp, vkomp, wkomp


       DO  k = nzb_u_inner(j,i)+1, nzt
!
!--       x-direction
          ukomp = u(k,j,i) - u_gtrans
          IF ( ukomp > 0.0 )  THEN
             tend(k,j,i) = tend(k,j,i) - ukomp * &
                                         ( u(k,j,i) - u(k,j,i-1) ) * ddx
          ELSE
             tend(k,j,i) = tend(k,j,i) - ukomp * &
                                         ( u(k,j,i+1) - u(k,j,i) ) * ddx
          ENDIF
!
!--       y-direction
          vkomp = 0.25 * ( v(k,j,i) + v(k,j+1,i) + v(k,j,i-1) + v(k,j+1,i-1) &
                         ) - v_gtrans
          IF ( vkomp > 0.0 )  THEN
             tend(k,j,i) = tend(k,j,i) - vkomp * &
                                         ( u(k,j,i) - u(k,j-1,i) ) * ddy
          ELSE
             tend(k,j,i) = tend(k,j,i) - vkomp * &
                                         ( u(k,j+1,i) - u(k,j,i) ) * ddy
          ENDIF
!
!--       z-direction
          wkomp = 0.25 * ( w(k,j,i) + w(k-1,j,i) + w(k,j,i-1) + w(k-1,j,i-1) )
          IF ( wkomp > 0.0 )  THEN
             tend(k,j,i) = tend(k,j,i) - wkomp * &
                                         ( u(k,j,i) - u(k-1,j,i) ) * ddzu(k)
          ELSE
             tend(k,j,i) = tend(k,j,i) - wkomp * &
                                         ( u(k+1,j,i) - u(k,j,i) ) * ddzu(k+1)
          ENDIF

       ENDDO

    END SUBROUTINE advec_u_up_ij

 END MODULE advec_u_up_mod