source: palm/trunk/SOURCE/advec_u_pw.f90 @ 712

 MODULE advec_u_pw_mod

!------------------------------------------------------------------------------!
! Current revisions:
! -----------------
! 
!
! Former revisions:
! -----------------
! $Id: advec_u_pw.f90 484 2010-02-05 07:36:54Z raasch $
!
! 106 2007-08-16 14:30:26Z raasch
! i loop is starting from nxlu (needed for non-cyclic boundary conditions)
!
! 75 2007-03-22 09:54:05Z raasch
! uxrp eliminated
!
! RCS Log replace by Id keyword, revision history cleaned up
!
! Revision 1.15  2006/02/23 09:44:21  raasch
! nzb_2d replaced by nzb_u_inner
!
! Revision 1.1  1997/08/11 06:09:21  raasch
! Initial revision
!
!
! Description:
! ------------
! Advection term for u velocity-component using Piacsek and Williams.
! Vertical advection at the first grid point above the surface is done with
! normal centred differences, because otherwise no information from the surface
! would be communicated upwards due to w=0 at K=nzb.
!------------------------------------------------------------------------------!

    PRIVATE
    PUBLIC advec_u_pw

    INTERFACE advec_u_pw
       MODULE PROCEDURE advec_u_pw
       MODULE PROCEDURE advec_u_pw_ij
    END INTERFACE advec_u_pw
 
 CONTAINS


!------------------------------------------------------------------------------!
! Call for all grid points
!------------------------------------------------------------------------------!
    SUBROUTINE advec_u_pw

       USE arrays_3d
       USE control_parameters
       USE grid_variables
       USE indices

       IMPLICIT NONE

       INTEGER ::  i, j, k
       REAL    ::  gu, gv
 
       gu = 2.0 * u_gtrans
       gv = 2.0 * v_gtrans
       DO  i = nxlu, nxr
          DO  j = nys, nyn
             DO  k = nzb_u_inner(j,i)+1, nzt
                tend(k,j,i) = tend(k,j,i) - 0.25 * (                           &
                         ( u(k,j,i+1) * ( u(k,j,i+1) + u(k,j,i) - gu )         &
                         - u(k,j,i-1) * ( u(k,j,i) + u(k,j,i-1) - gu ) ) * ddx &
                       + ( u(k,j+1,i) * ( v(k,j+1,i) + v(k,j+1,i-1) - gv )     &
                         - u(k,j-1,i) * ( v(k,j,i) + v(k,j,i-1) - gv ) ) * ddy &
                       + ( u(k+1,j,i) * ( w(k,j,i) + w(k,j,i-1) )              &
                         - u(k-1,j,i) * ( w(k-1,j,i) + w(k-1,j,i-1) ) )        &
                                                                  * ddzw(k)    &
                                                   )
             ENDDO
          ENDDO
       ENDDO

    END SUBROUTINE advec_u_pw


!------------------------------------------------------------------------------!
! Call for grid point i,j
!------------------------------------------------------------------------------!
    SUBROUTINE advec_u_pw_ij( i, j )

       USE arrays_3d
       USE control_parameters
       USE grid_variables
       USE indices

       IMPLICIT NONE

       INTEGER ::  i, j, k
       REAL    ::  gu, gv

       gu = 2.0 * u_gtrans
       gv = 2.0 * v_gtrans
       DO  k = nzb_u_inner(j,i)+1, nzt
          tend(k,j,i) = tend(k,j,i) - 0.25 * (                                 &
                         ( u(k,j,i+1) * ( u(k,j,i+1) + u(k,j,i) - gu )         &
                         - u(k,j,i-1) * ( u(k,j,i) + u(k,j,i-1) - gu ) ) * ddx &
                       + ( u(k,j+1,i) * ( v(k,j+1,i) + v(k,j+1,i-1) - gv )     &
                         - u(k,j-1,i) * ( v(k,j,i) + v(k,j,i-1) - gv ) ) * ddy &
                       + ( u(k+1,j,i) * ( w(k,j,i) + w(k,j,i-1) )              &
                         - u(k-1,j,i) * ( w(k-1,j,i) + w(k-1,j,i-1) ) )        &
                                                                  * ddzw(k)    &
                                             )
       ENDDO

    END SUBROUTINE advec_u_pw_ij

 END MODULE advec_u_pw_mod