source: palm/trunk/SOURCE/advec_s_up.f90 @ 4180

Last change on this file since 4180 was 4180, checked in by scharf, 22 months ago

removed comments in 'Former revisions' section that are older than 01.01.2019

  • Property svn:keywords set to Id
File size: 7.2 KB
Line 
1!> @file advec_s_up.f90
2!------------------------------------------------------------------------------!
3! This file is part of the PALM model system.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2019 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: advec_s_up.f90 4180 2019-08-21 14:37:54Z scharf $
27! pointer attribute removed from scalar 3d-array for performance reasons
28!
29! 3665 2019-01-10 08:28:24Z raasch
30! unused variables removed
31!
32! 3655 2019-01-07 16:51:22Z knoop
33! nopointer option removed
34!
35!
36! Description:
37! ------------
38!> Advection term for scalar quantities using the Upstream scheme.
39!> NOTE: vertical advection at k=1 still has wrong grid spacing for w>0!
40!>       The same problem occurs for all topography boundaries!
41!------------------------------------------------------------------------------!
42 MODULE advec_s_up_mod
43 
44
45    PRIVATE
46    PUBLIC advec_s_up
47
48    INTERFACE advec_s_up
49       MODULE PROCEDURE advec_s_up
50       MODULE PROCEDURE advec_s_up_ij
51    END INTERFACE advec_s_up
52
53 CONTAINS
54
55
56!------------------------------------------------------------------------------!
57! Description:
58! ------------
59!> Call for all grid points
60!------------------------------------------------------------------------------!
61    SUBROUTINE advec_s_up( sk )
62
63       USE arrays_3d,                                                          &
64           ONLY:  ddzu, tend, u, v, w
65
66       USE control_parameters,                                                 &
67           ONLY:  u_gtrans, v_gtrans
68
69       USE grid_variables,                                                     &
70           ONLY:  ddx, ddy
71
72       USE indices,                                                            &
73           ONLY:  nxl, nxlg, nxr, nxrg, nyn, nyng, nys, nysg, nzb, nzt
74
75       USE kinds
76
77
78       IMPLICIT NONE
79
80       INTEGER(iwp) ::  i !< grid index along x-direction
81       INTEGER(iwp) ::  j !< grid index along y-direction
82       INTEGER(iwp) ::  k !< grid index along z-direction
83
84       REAL(wp) ::  ukomp !< advection velocity along x-direction
85       REAL(wp) ::  vkomp !< advection velocity along y-direction
86       REAL(wp) ::  wkomp !< advection velocity along z-direction
87
88       REAL(wp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) ::  sk !< treated scalar
89
90
91       DO  i = nxl, nxr
92          DO  j = nys, nyn
93             DO  k = nzb+1, nzt
94!
95!--             x-direction
96                ukomp = 0.5_wp * ( u(k,j,i) + u(k,j,i+1) ) - u_gtrans
97                IF ( ukomp > 0.0_wp )  THEN
98                   tend(k,j,i) = tend(k,j,i) - ukomp *                         &
99                                         ( sk(k,j,i) - sk(k,j,i-1) ) * ddx
100                ELSE
101                   tend(k,j,i) = tend(k,j,i) - ukomp *                         &
102                                         ( sk(k,j,i+1) - sk(k,j,i) ) * ddx
103                ENDIF
104!
105!--             y-direction
106                vkomp = 0.5_wp * ( v(k,j,i) + v(k,j+1,i) ) - v_gtrans
107                IF ( vkomp > 0.0_wp )  THEN
108                   tend(k,j,i) = tend(k,j,i) - vkomp *                         &
109                                         ( sk(k,j,i) - sk(k,j-1,i) ) * ddy
110                ELSE
111                   tend(k,j,i) = tend(k,j,i) - vkomp *                         &
112                                         ( sk(k,j+1,i) - sk(k,j,i) ) * ddy
113                ENDIF
114!
115!--             z-direction
116                wkomp = 0.5_wp * ( w(k,j,i) + w(k-1,j,i) )
117                IF ( wkomp > 0.0_wp )  THEN
118                   tend(k,j,i) = tend(k,j,i) - wkomp *                         &
119                                         ( sk(k,j,i) - sk(k-1,j,i) ) * ddzu(k)
120                ELSE
121                   tend(k,j,i) = tend(k,j,i) - wkomp *                         &
122                                         ( sk(k+1,j,i)-sk(k,j,i) ) * ddzu(k+1)
123                ENDIF
124
125             ENDDO
126          ENDDO
127       ENDDO
128
129    END SUBROUTINE advec_s_up
130
131
132!------------------------------------------------------------------------------!
133! Description:
134! ------------
135!> Call for grid point i,j
136!------------------------------------------------------------------------------!
137    SUBROUTINE advec_s_up_ij( i, j, sk )
138
139       USE arrays_3d,                                                          &
140           ONLY:  ddzu, tend, u, v, w
141
142       USE control_parameters,                                                 &
143           ONLY:  u_gtrans, v_gtrans
144
145       USE grid_variables,                                                     &
146           ONLY:  ddx, ddy
147
148       USE indices,                                                            &
149           ONLY:  nxlg, nxrg, nyng, nysg, nzb, nzt
150
151       USE kinds
152
153
154       IMPLICIT NONE
155
156       INTEGER(iwp) ::  i !< grid index along x-direction
157       INTEGER(iwp) ::  j !< grid index along y-direction
158       INTEGER(iwp) ::  k !< grid index along z-direction
159
160       REAL(wp) ::  ukomp !< advection velocity along x-direction
161       REAL(wp) ::  vkomp !< advection velocity along y-direction
162       REAL(wp) ::  wkomp !< advection velocity along z-direction
163       
164       REAL(wp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) ::  sk !< treated scalar
165
166
167       DO  k = nzb+1, nzt
168!
169!--       x-direction
170          ukomp = 0.5_wp * ( u(k,j,i) + u(k,j,i+1) ) - u_gtrans
171          IF ( ukomp > 0.0_wp )  THEN
172             tend(k,j,i) = tend(k,j,i) - ukomp *                               &
173                                         ( sk(k,j,i) - sk(k,j,i-1) ) * ddx
174          ELSE
175             tend(k,j,i) = tend(k,j,i) - ukomp *                               &
176                                         ( sk(k,j,i+1) - sk(k,j,i) ) * ddx
177          ENDIF
178!
179!--       y-direction
180          vkomp = 0.5_wp * ( v(k,j,i) + v(k,j+1,i) ) - v_gtrans
181          IF ( vkomp > 0.0_wp )  THEN
182             tend(k,j,i) = tend(k,j,i) - vkomp *                               &
183                                         ( sk(k,j,i) - sk(k,j-1,i) ) * ddy
184          ELSE
185             tend(k,j,i) = tend(k,j,i) - vkomp *                               &
186                                         ( sk(k,j+1,i) - sk(k,j,i) ) * ddy
187          ENDIF
188!
189!--       z-direction
190          wkomp = 0.5_wp * ( w(k,j,i) + w(k-1,j,i) )
191          IF ( wkomp > 0.0_wp )  THEN
192             tend(k,j,i) = tend(k,j,i) - wkomp *                               &
193                                         ( sk(k,j,i) - sk(k-1,j,i) ) * ddzu(k)
194          ELSE
195             tend(k,j,i) = tend(k,j,i) - wkomp *                               &
196                                         ( sk(k+1,j,i)-sk(k,j,i) ) * ddzu(k+1)
197          ENDIF
198
199       ENDDO
200
201    END SUBROUTINE advec_s_up_ij
202
203 END MODULE advec_s_up_mod
Note: See TracBrowser for help on using the repository browser.