Home

Context Navigation

source: palm/trunk/SOURCE/advec_s_pw.f90 @ 3568

Last change on this file since 3568 was 3547, checked in by suehring, 6 years ago
variable description added some routines
Property svn:keywords set to `Id`
File size: 8.9 KB

Line
1	!> @file advec_s_pw.f90
2	!------------------------------------------------------------------------------!
3	! This file is part of the PALM model system.
4	!
5	! PALM is free software: you can redistribute it and/or modify it under the
6	! terms of the GNU General Public License as published by the Free Software
7	! Foundation, either version 3 of the License, or (at your option) any later
8	! version.
9	!
10	! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11	! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12	! A PARTICULAR PURPOSE. See the GNU General Public License for more details.
13	!
14	! You should have received a copy of the GNU General Public License along with
15	! PALM. If not, see <http://www.gnu.org/licenses/>.
16	!
17	! Copyright 1997-2018 Leibniz Universitaet Hannover
18	!------------------------------------------------------------------------------!
19	!
20	! Current revisions:
21	! -----------------
22	!
23	!
24	! Former revisions:
25	! -----------------
26	! $Id: advec_s_pw.f90 3547 2018-11-21 13:21:24Z raasch $
27	! variables documented
28	!
29	! 3538 2018-11-20 10:55:41Z suehring
30	! Remove unnecessary double-masking of topography
31	!
32	! 3302 2018-10-03 02:39:40Z raasch
33	! Stokes drift velocity added
34	!
35	! 2718 2018-01-02 08:49:38Z maronga
36	! Corrected "Former revisions" section
37	!
38	! 2696 2017-12-14 17:12:51Z kanani
39	! Change in file header (GPL part)
40	!
41	! 2233 2017-05-30 18:08:54Z suehring
42	!
43	! 2232 2017-05-30 17:47:52Z suehring
44	! topography representation via flags
45	!
46	! 2000 2016-08-20 18:09:15Z knoop
47	! Forced header and separation lines into 80 columns
48	!
49	! 1873 2016-04-18 14:50:06Z maronga
50	! Module renamed (removed _mod)
51	!
52	!
53	! 1850 2016-04-08 13:29:27Z maronga
54	! Module renamed
55	!
56	!
57	! 1682 2015-10-07 23:56:08Z knoop
58	! Code annotations made doxygen readable
59	!
60	! 1374 2014-04-25 12:55:07Z raasch
61	! missing variables added to ONLY list
62	!
63	! 1353 2014-04-08 15:21:23Z heinze
64	! REAL constants provided with KIND-attribute
65	!
66	! 1320 2014-03-20 08:40:49Z raasch
67	! ONLY-attribute added to USE-statements,
68	! kind-parameters added to all INTEGER and REAL declaration statements,
69	! kinds are defined in new module kinds,
70	! revision history before 2012 removed,
71	! comment fields (!:) to be used for variable explanations added to
72	! all variable declaration statements
73	!
74	! 1036 2012-10-22 13:43:42Z raasch
75	! code put under GPL (PALM 3.9)
76	!
77	! 1010 2012-09-20 07:59:54Z raasch
78	! cpp switch __nopointer added for pointer free version
79	!
80	! Revision 1.1 1997/08/29 08:54:20 raasch
81	! Initial revision
82	!
83	!
84	! Description:
85	! ------------
86	!> Advection term for scalar variables using the Piacsek and Williams scheme
87	!> (form C3). Contrary to PW itself, for reasons of accuracy their scheme is
88	!> slightly modified as follows: the values of those scalars that are used for
89	!> the computation of the flux divergence are reduced by the value of the
90	!> relevant scalar at the location where the difference is computed (sk(k,j,i)).
91	!> NOTE: at the first grid point above the surface computation still takes place!
92	!------------------------------------------------------------------------------!
93	MODULE advec_s_pw_mod
94
95
96	PRIVATE
97	PUBLIC advec_s_pw
98
99	INTERFACE advec_s_pw
100	MODULE PROCEDURE advec_s_pw
101	MODULE PROCEDURE advec_s_pw_ij
102	END INTERFACE
103
104	CONTAINS
105
106
107	!------------------------------------------------------------------------------!
108	! Description:
109	! ------------
110	!> Call for all grid points
111	!------------------------------------------------------------------------------!
112	SUBROUTINE advec_s_pw( sk )
113
114	USE arrays_3d, &
115	ONLY: dd2zu, tend, u, u_stokes_zu, v, v_stokes_zu, w
116
117	USE control_parameters, &
118	ONLY: u_gtrans, v_gtrans
119
120	USE grid_variables, &
121	ONLY: ddx, ddy
122
123	USE indices, &
124	ONLY: nxl, nxlg, nxr, nxrg, nyn, nyng, nys, nysg, nzb, nzt
125
126	USE kinds
127
128
129	IMPLICIT NONE
130
131	INTEGER(iwp) :: i !< grid index along x-direction
132	INTEGER(iwp) :: j !< grid index along y-direction
133	INTEGER(iwp) :: k !< grid index along z-direction
134
135	REAL(wp) :: gu !< local additional advective velocity
136	REAL(wp) :: gv !< local additional advective velocity
137
138	#if defined( __nopointer )
139	REAL(wp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) :: sk !<
140	#else
141	REAL(wp), DIMENSION(:,:,:), POINTER :: sk
142	#endif
143
144
145	DO i = nxl, nxr
146	DO j = nys, nyn
147	DO k = nzb+1, nzt
148
149	!
150	!-- Galilean transformation + Stokes drift velocity (ocean only)
151	gu = u_gtrans - u_stokes_zu(k)
152	gv = v_gtrans - v_stokes_zu(k)
153
154	tend(k,j,i) = tend(k,j,i) + &
155	( -0.5_wp * ( ( u(k,j,i+1) - gu ) * &
156	( sk(k,j,i+1) - sk(k,j,i) ) &
157	- ( u(k,j,i) - gu ) * &
158	( sk(k,j,i-1) - sk(k,j,i) ) &
159	) * ddx &
160	-0.5_wp * ( ( v(k,j+1,i) - gv ) * &
161	( sk(k,j+1,i) - sk(k,j,i) ) &
162	- ( v(k,j,i) - gv ) * &
163	( sk(k,j-1,i) - sk(k,j,i) ) &
164	) * ddy &
165	- ( w(k,j,i) * &
166	( sk(k+1,j,i) - sk(k,j,i) ) &
167	- w(k-1,j,i) * &
168	( sk(k-1,j,i) - sk(k,j,i) ) &
169	) * dd2zu(k) &
170	)
171	ENDDO
172	ENDDO
173	ENDDO
174
175	END SUBROUTINE advec_s_pw
176
177
178	!------------------------------------------------------------------------------!
179	! Description:
180	! ------------
181	!> Call for grid point i,j
182	!------------------------------------------------------------------------------!
183	SUBROUTINE advec_s_pw_ij( i, j, sk )
184
185	USE arrays_3d, &
186	ONLY: dd2zu, tend, u, u_stokes_zu, v, v_stokes_zu, w
187
188	USE control_parameters, &
189	ONLY: u_gtrans, v_gtrans
190
191	USE grid_variables, &
192	ONLY: ddx, ddy
193
194	USE indices, &
195	ONLY: nxlg, nxrg, nyng, nysg, nzb, nzt
196
197	USE kinds
198
199
200	IMPLICIT NONE
201
202	INTEGER(iwp) :: i !< grid index along x-direction
203	INTEGER(iwp) :: j !< grid index along y-direction
204	INTEGER(iwp) :: k !< grid index along z-direction
205
206	REAL(wp) :: gu !< local additional advective velocity
207	REAL(wp) :: gv !< local additional advective velocity
208
209	#if defined( __nopointer )
210	REAL(wp), DIMENSION(nzb:nzt+1,nysg:nyng,nxlg:nxrg) :: sk !<
211	#else
212	REAL(wp), DIMENSION(:,:,:), POINTER :: sk
213	#endif
214
215
216	DO k = nzb+1, nzt
217
218	!
219	!-- Galilean transformation + Stokes drift velocity (ocean only)
220	gu = u_gtrans - u_stokes_zu(k)
221	gv = v_gtrans - v_stokes_zu(k)
222
223	tend(k,j,i) = tend(k,j,i) + &
224	( -0.5_wp * ( ( u(k,j,i+1) - gu ) * &
225	( sk(k,j,i+1) - sk(k,j,i) ) &
226	- ( u(k,j,i) - gu ) * &
227	( sk(k,j,i-1) - sk(k,j,i) ) &
228	) * ddx &
229	-0.5_wp * ( ( v(k,j+1,i) - gv ) * &
230	( sk(k,j+1,i) - sk(k,j,i) ) &
231	- ( v(k,j,i) - gv ) * &
232	( sk(k,j-1,i) - sk(k,j,i) ) &
233	) * ddy &
234	- ( w(k,j,i) * &
235	( sk(k+1,j,i) - sk(k,j,i) ) &
236	- w(k-1,j,i) * &
237	( sk(k-1,j,i) - sk(k,j,i) ) &
238	) * dd2zu(k) &
239	)
240	ENDDO
241
242	END SUBROUTINE advec_s_pw_ij
243
244	END MODULE advec_s_pw_mod

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

| Impressum | ©Leibniz Universität Hannover |