doc/app/idl: check_palm_output.pro

;#######################################################################
;# Program language: IDL (Interactive Data Language), file-ending .pro #
;#                                                                     #
;# This program checks the content of netCDF-files generated by PALM   #
;# and displays it on the standard output (console).                   #
;# The program provides the following:                                 #
;#  1. Variables of the netCDF-file                                    #
;#  2. The Dimensions of the variables                                 #
;#  3. The type of the variable (float, double, ..)                    #
;#  4. The unit of the variable (e.g. m/s)                             #
;# (5. In case of timeseries-data (ts) the mean time step of the run)  #
;#                                                                     #
;#                                                   coder: F. Herbort #
;#######################################################################
;                                                                      #
; ENTER PARAMETERS:                                                    #
; =================                                                    #
;                                                                      #
; Host-Identifier:                                                     #
hostid = 'lcsgih'   ;                                                  #
;                                                                      #
; Name of run:                                                         #
name_of_run = 'example_cbl'   ; sub-folder of                          #
;                               ~/palm/current_version/JOBS            #
; Number for restart-files:                                            #
resnum = ' '   ; (blank if no restart-file is considered)              #
;                                                                      #
; Path to netCDF-file:                                                 #
netcdf_path = '/home/herbort/palm/current_version/JOBS/'+name_of_run+'/OUTPUT/' ;#
;                                                                      #
; Kind of data:                                                        #
kind_data = 'pr'   ;                                                   #
; ts    --> timeseries                                                 #
; pr    --> profiles                                                   #
; sp    --> spectra                                                    #
; xy    --> xy cross-section                                           #
; 3d    --> 3d data                                                    #
; 3d_av --> time-averaged 3d data                                      #
;  .           .                                                       #
;  .           .                                                       #
;                                                                      #
;#######################################################################

PRINT, ' '
PRINT, '========================================================'
PRINT, 'Program checks content of netCDF-files generated by PALM'
PRINT, '                                            [F. Herbort]'
PRINT, '========================================================'
PRINT, ' '

;=======================================================================
; Checking existence of file:
; ---------------------------

IF resnum EQ ' ' THEN datafile = hostid+'_'+name_of_run+'_'+kind_data+'.nc'
IF resnum NE ' ' THEN datafile = hostid+'_'+name_of_run+'_'+kind_data+'.'+resnum+'.nc'
input = netcdf_path+datafile

fileyn = FILE_TEST(input)

; Checking, wether filename is without hostid at the beginning of filename:
IF fileyn EQ 0L THEN BEGIN
IF resnum EQ ' ' THEN datafile = name_of_run+'_'+kind_data+'.nc'
IF resnum NE ' ' THEN datafile = name_of_run+'_'+kind_data+'.'+resnum+'.nc'
input = netcdf_path+datafile
fileyn = FILE_TEST(input)
ENDIF

IF fileyn EQ 0L THEN BEGIN
PRINT, 'netCDF-file does not exist!'
PRINT, 'Program aborted'
PRINT, ' '
GOTO, abort_flag
ENDIF

;=======================================================================
; Checking the netCDF-file:
; -------------------------

nid = NCDF_OPEN(input)

PRINT, 'Opened netCDF-file ', input

info_n = NCDF_INQUIRE(nid)

PRINT, ' '
PRINT, info_n.Nvars, ' variables existing:', FORMAT = '(I2,A20)'
PRINT, ' '
PRINT, 'No.         Variable              Dimensions        Type          Unit'
PRINT, '---         --------              ----------        ----          ----'

FOR n1 = 0, info_n.Nvars - 1 DO BEGIN
vars = NCDF_VARINQ(nid,n1)

dimens = vars.Ndims

IF dimens EQ 0 THEN str_dims = 'scalar'

IF dimens GE 1 THEN BEGIN

dimarr = LONARR(dimens)

FOR cc = 0, dimens - 1 DO BEGIN
NCDF_DIMINQ, nid, vars.Dim(cc), dimename, dim_size

dimarr(cc) = dim_size

ENDFOR

IF dimens EQ 1 THEN str_dims = '('+STRING(dimarr(0), FORMAT = '(I4)')+')'
IF dimens EQ 1 AND kind_data EQ 'ts' THEN str_dims = '('+STRING(dimarr(0), FORMAT = '(I6)')+')'
IF dimens EQ 2 THEN str_dims = '('+STRING(dimarr(0), FORMAT = '(I4)')+','+STRING(dimarr(1), FORMAT = '(I4)')+')'
IF dimens EQ 3 THEN str_dims = '('+STRING(dimarr(0), FORMAT = '(I4)')+','+STRING(dimarr(1), $
                               FORMAT = '(I4)')+','+STRING(dimarr(2), FORMAT = '(I4)')+')'
IF dimens EQ 4 THEN str_dims = '('+STRING(dimarr(0), FORMAT = '(I4)')+','+STRING(dimarr(1), $
                               FORMAT = '(I4)')+','+STRING(dimarr(2), FORMAT = '(I4)')+','+STRING(dimarr(3), FORMAT = '(I4)')+')'
IF dimens GT 4 THEN str_dims = '> 4-dimensional'

ENDIF

attdims = vars.Natts

IF attdims GE 1 THEN BEGIN
FOR aa = 0, attdims - 1 DO BEGIN

attr_name = NCDF_ATTNAME(nid,n1,aa)

IF attr_name EQ 'units' THEN BEGIN
NCDF_ATTGET, nid, n1, 'units', unit_byte

res = SIZE(unit_byte, /DIMENSION)
num_letters = res(0)

unit = ''
IF num_letters GT 0 THEN BEGIN
FOR ll = 0, num_letters - 1 DO BEGIN
unit = unit+STRING(unit_byte(ll))
ENDFOR
ENDIF
IF num_letters EQ 0 THEN unit = STRING(unit_byte)

;HELP, unit
ENDIF

ENDFOR
ENDIF

PRINT, n1+1, vars.Name, str_dims, vars.DataType, unit, FORMAT = '(I2,4X,A14,3X,A21,5X,A7,7X,A7)'

IF vars.Name EQ 'time' THEN BEGIN
NCDF_VARGET, nid, vars.Name, time
ENDIF

ENDFOR

IF kind_data EQ 'ts' THEN BEGIN

; Determining the mean time step of the run:
PRINT, ' '
dim_time = N_ELEMENTS(time)
time_diff = FLTARR(dim_time-2L)
time_diff(*) = time(2L:dim_time-1L) - time(1L:dim_time-2L)

mean_time_step = MEAN(time_diff)
sigma_time_step = SQRT(VARIANCE(time_diff))

PRINT, ' '
PRINT, 'Mean time step of the run: ', mean_time_step, ' s + - ', $
sigma_time_step, ' s', FORMAT = '(A27,F4.2,A7,F4.2,A2)'
PRINT, ' '

IF dim_time GT 30 THEN BEGIN

time_diff = time_diff(19L:dim_time-3L)

mean_time_step = MEAN(time_diff)
sigma_time_step = SQRT(VARIANCE(time_diff))

PRINT, ' '
PRINT, 'Mean time step of the run (but from the 20th time step): ', mean_time_step, ' s + - ', $
sigma_time_step, ' s', FORMAT = '(A57,F4.2,A7,F4.2,A2)'
PRINT, ' '

ENDIF

ENDIF


PRINT, ' '

NCDF_CLOSE, nid

PRINT, 'Program finished'
abort_flag:
PRINT, ' '


END