SUBROUTINE user_header( io )

!------------------------------------------------------------------------------!
! Actual revisions:
! -----------------
! new topography case 'single_street_canyon'
!
! Former revisions:
! -----------------
! $Id: user_header.f90 240 2009-02-18 17:50:38Z heinze $
!
! 2008-12-09 18:00:48Z letzel
! +topography_grid_convention
! Former file user_interface.f90 split into one file per subroutine
!
! Description:
! ------------
! Print a header with user-defined informations.
!------------------------------------------------------------------------------!

    USE control_parameters
    USE statistics
    USE user

    IMPLICIT NONE

    INTEGER ::  i, io

!
!-- If no user-defined variables are read from the namelist-file, no
!-- informations will be printed.
    IF ( .NOT. user_defined_namelist_found )  THEN
       WRITE ( io, 100 )
       RETURN
    ENDIF

!
!-- Printing the informations.
    WRITE ( io, 110 )

    IF ( statistic_regions /= 0 )  THEN
       WRITE ( io, 200 )
       DO  i = 0, statistic_regions
          WRITE ( io, 201 )  i, region(i)
       ENDDO
    ENDIF

    IF ( TRIM( topography ) /= 'flat' )  THEN
       WRITE ( io, 300 )
       IF ( TRIM( topography_grid_convention ) == ' ' )  THEN
          IF ( TRIM( topography ) == 'single_building' .OR.  &
               TRIM( topography ) == 'single_street_canyon' )  THEN
             WRITE ( io, 301 )
          ELSEIF ( TRIM( topography ) == 'read_from_file' )  THEN
             WRITE ( io, 302 )
          ENDIF
       ELSEIF ( TRIM( topography_grid_convention ) == 'cell_edge' )  THEN
          WRITE ( io, 301 )
       ELSEIF ( TRIM( topography_grid_convention ) == 'cell_center' )  THEN
          WRITE ( io, 302 )
       ENDIF
    ENDIF

!
!-- Format-descriptors
100 FORMAT (//' *** no user-defined variables found'/)
110 FORMAT (//1X,78('#')                                      &
            //' User-defined variables and actions:'/  &
              ' -----------------------------------'//)
200 FORMAT (' Output of profiles and time series for following regions:' /)
201 FORMAT (4X,'Region ',I1,':   ',A)
300 FORMAT (' Topography grid definition convention:'/)
301 FORMAT (' cell edge (staggered grid points'/  &
            ' (u in x-direction, v in y-direction))' /)
302 FORMAT (' cell center (scalar grid points)' /)


 END SUBROUTINE user_header