source: palm/trunk/SOURCE/time_integration_spinup.f90 @ 3921

Last change on this file since 3921 was 3885, checked in by kanani, 5 years ago

restructure/add location/debug messages

  • Property svn:keywords set to Id
File size: 21.9 KB
Line 
1!> @file time_integration_spinup.f90
2!------------------------------------------------------------------------------!
3! This file is part of the PALM model system.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2019 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! ------------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: time_integration_spinup.f90 3885 2019-04-11 11:29:34Z suehring $
27! Changes related to global restructuring of location messages and introduction
28! of additional debug messages
29!
30! 3766 2019-02-26 16:23:41Z raasch
31! unused variable removed
32!
33! 3719 2019-02-06 13:10:18Z kanani
34! Removed log_point(19,54,74,50,75), since they count together with same log
35! points in time_integration, impossible to separate the contributions.
36! Instead, the entire spinup gets an individual log_point in palm.f90
37!
38! 3655 2019-01-07 16:51:22Z knoop
39! Removed call to calculation of near air (10 cm) potential temperature (now in
40! surface layer fluxes)
41!
42! 3467 2018-10-30 19:05:21Z suehring
43! call to material_heat_model now with check if spinup runs (rvtils)
44!
45! 3337 2018-10-12 15:17:09Z kanani
46! (from branch resler)
47! Add pt1 initialization
48!
49! 3274 2018-09-24 15:42:55Z knoop
50! Modularization of all bulk cloud physics code components
51!
52! 3241 2018-09-12 15:02:00Z raasch
53! unused variables removed
54!
55! 2983 2018-04-18 10:43:40Z suehring
56! Revise limitation of wall-adjacent velocity.
57!
58! 2934 2018-03-26 19:13:22Z suehring
59! Synchronize parent and child models after spinup.
60!
61! 2881 2018-03-13 16:24:40Z maronga
62! Added flag for switching on/off calculation of soil moisture
63!
64! 2818 2018-02-19 16:42:36Z maronga
65! Velocity components near walls/ground are now set to the profiles stored in
66! u_init and v_init. Activated soil moisture calculation during spinup.
67!
68! 2782 2018-02-02 11:51:10Z maronga
69! Bugfix and re-activation of homogeneous setting of velocity components
70! during spinup
71!
72! 2758 2018-01-17 12:55:21Z suehring
73! Comment out homogeneous setting of wind velocity as this will lead to zero
74! friction velocity and cause problems in MOST relationships.
75!
76! 2728 2018-01-09 07:03:53Z maronga
77! Set velocity componenets to homogeneous values during spinup
78!
79! 2724 2018-01-05 12:12:38Z maronga
80! Use dt_spinup for all active components during spinup
81!
82! 2723 2018-01-05 09:27:03Z maronga
83! Bugfix: array rad_sw_in no longer exists and is thus removed from RUN_CONTROL
84! output.
85! Added output of XY and 3D data during spinup.
86! Bugfix: time step in LSM and USM was set to dt_3d instead of dt_spinup
87!
88! 2718 2018-01-02 08:49:38Z maronga
89! Corrected "Former revisions" section
90!
91! 2696 2017-12-14 17:12:51Z kanani
92! Change in file header (GPL part)
93! Added radiation interactions (moved from USM) (MS)
94!
95! 2544 2017-10-13 18:09:32Z maronga
96! Date and time quantities are now read from date_and_time_mod
97!
98! 2299 2017-06-29 10:14:38Z maronga
99! Call of soil model adjusted to avoid prognostic equation for soil moisture
100! during spinup.
101! Better representation of diurnal cycle of near-surface temperature.
102! Excluded prognostic equation for soil moisture during spinup.
103! Added output of run control data for spinup.
104!
105! 2297 2017-06-28 14:35:57Z scharf
106! bugfixes
107!
108! 2296 2017-06-28 07:53:56Z maronga
109! Initial revision
110!
111!
112! Description:
113! ------------
114!> Integration in time of the non-atmospheric model components such as land
115!> surface model and urban surface model
116!------------------------------------------------------------------------------!
117 SUBROUTINE time_integration_spinup
118 
119    USE arrays_3d,                                                             &
120        ONLY:  pt, pt_p, u, u_init, v, v_init
121
122    USE control_parameters,                                                    &
123        ONLY:  averaging_interval_pr, calc_soil_moisture_during_spinup,        &
124               constant_diffusion, constant_flux_layer, coupling_start_time,   &
125               data_output_during_spinup, dopr_n, do_sum,                      &
126               dt_averaging_input_pr, dt_dopr, dt_dots, dt_do2d_xy, dt_do3d,   &
127               dt_spinup, dt_3d, humidity, intermediate_timestep_count,        &
128               intermediate_timestep_count_max, land_surface,                  &
129               simulated_time, simulated_time_chr, skip_time_dopr,             &
130               skip_time_do2d_xy, skip_time_do3d, spinup_pt_amplitude,         &
131               spinup_pt_mean, spinup_time, timestep_count, time_dopr,         &
132               time_dopr_av, time_dots, time_do2d_xy, time_do3d,               &
133               time_run_control, time_since_reference_point, urban_surface
134
135    USE cpulog,                                                                &
136        ONLY:  cpu_log, log_point_s
137
138    USE date_and_time_mod,                                                     &
139        ONLY: day_of_year_init, time_utc_init
140
141    USE indices,                                                               &
142        ONLY:  nbgp, nzb, nzt, nysg, nyng, nxlg, nxrg
143
144
145    USE land_surface_model_mod,                                                &
146        ONLY:  lsm_energy_balance, lsm_soil_model, lsm_swap_timelevel
147    USE pegrid
148
149    USE pmc_interface,                                                         &
150        ONLY:  nested_run
151
152    USE kinds
153
154    USE radiation_model_mod,                                                   &
155        ONLY:  force_radiation_call, radiation, radiation_control,             &
156               radiation_interaction, radiation_interactions, time_radiation
157
158    USE statistics,                                                            &
159        ONLY:  flow_statistics_called
160
161    USE surface_layer_fluxes_mod,                                              &
162        ONLY:  surface_layer_fluxes
163
164    USE surface_mod,                                                           &
165        ONLY :  surf_lsm_h, surf_lsm_v, surf_usm_h,    &
166                surf_usm_v
167
168    USE urban_surface_mod,                                                     &
169        ONLY:  usm_material_heat_model, usm_material_model,                    &
170               usm_surface_energy_balance, usm_swap_timelevel,                 &
171               usm_green_heat_model
172
173
174
175
176    IMPLICIT NONE
177
178    CHARACTER (LEN=9) ::  time_to_string          !<
179 
180    INTEGER(iwp) ::  i !< running index
181    INTEGER(iwp) ::  j !< running index
182    INTEGER(iwp) ::  k !< running index
183    INTEGER(iwp) ::  l !< running index
184    INTEGER(iwp) ::  m !< running index
185
186    INTEGER(iwp) :: current_timestep_number_spinup = 0  !< number if timestep during spinup
187 
188    LOGICAL :: run_control_header_spinup = .FALSE.  !< flag parameter for steering whether the header information must be output
189
190    REAL(wp) ::  pt_spinup   !< temporary storage of temperature
191    REAL(wp) ::  dt_save     !< temporary storage for time step
192                 
193    REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::  pt_save  !< temporary storage of temperature
194    REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::  u_save   !< temporary storage of u wind component
195    REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::  v_save   !< temporary storage of v wind component
196
197
198!
199!-- Save 3D arrays because they are to be changed for spinup purpose
200    ALLOCATE( pt_save(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
201    ALLOCATE( u_save(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
202    ALLOCATE( v_save(nzb:nzt+1,nysg:nyng,nxlg:nxrg) )
203
204    CALL exchange_horiz( pt, nbgp )   
205    CALL exchange_horiz( u,  nbgp ) 
206    CALL exchange_horiz( v,  nbgp ) 
207 
208    pt_save = pt
209    u_save  = u
210    v_save  = v
211
212!
213!-- Set the same wall-adjacent velocity to all grid points. The sign of the
214!-- original velocity field must be preserved because the surface schemes crash
215!-- otherwise. The precise reason is still unknown. A minimum velocity of 0.1
216!-- m/s is used to maintain turbulent transfer at the surface.
217    IF ( land_surface )  THEN
218       DO  m = 1, surf_lsm_h%ns
219          i   = surf_lsm_h%i(m)           
220          j   = surf_lsm_h%j(m)
221          k   = surf_lsm_h%k(m)
222          u(k,j,i) = SIGN(1.0_wp,u_init(k)) * MAX( ABS( u_init(k) ),0.1_wp)
223          v(k,j,i) = SIGN(1.0_wp,v_init(k)) * MAX( ABS( v_init(k) ),0.1_wp)
224       ENDDO
225
226       DO  l = 0, 3
227          DO  m = 1, surf_lsm_v(l)%ns
228             i   = surf_lsm_v(l)%i(m)           
229             j   = surf_lsm_v(l)%j(m)
230             k   = surf_lsm_v(l)%k(m)
231             u(k,j,i) = SIGN(1.0_wp,u_init(k)) * MAX( ABS( u_init(k) ),0.1_wp)
232             v(k,j,i) = SIGN(1.0_wp,v_init(k)) * MAX( ABS( v_init(k) ),0.1_wp)
233          ENDDO
234       ENDDO
235    ENDIF
236
237    IF ( urban_surface )  THEN
238       DO  m = 1, surf_usm_h%ns
239          i   = surf_usm_h%i(m)           
240          j   = surf_usm_h%j(m)
241          k   = surf_usm_h%k(m)
242          u(k,j,i) = SIGN(1.0_wp,u_init(k)) * MAX( ABS( u_init(k) ),0.1_wp)
243          v(k,j,i) = SIGN(1.0_wp,v_init(k)) * MAX( ABS( v_init(k) ),0.1_wp)
244       ENDDO
245
246       DO  l = 0, 3
247          DO  m = 1, surf_usm_v(l)%ns
248             i   = surf_usm_v(l)%i(m)           
249             j   = surf_usm_v(l)%j(m)
250             k   = surf_usm_v(l)%k(m)
251             u(k,j,i) = SIGN(1.0_wp,u_init(k)) * MAX( ABS( u_init(k) ),0.1_wp)
252             v(k,j,i) = SIGN(1.0_wp,v_init(k)) * MAX( ABS( v_init(k) ),0.1_wp)
253          ENDDO
254       ENDDO
255    ENDIF
256
257    CALL exchange_horiz( u,  nbgp )
258    CALL exchange_horiz( v,  nbgp )
259
260    dt_save = dt_3d
261    dt_3d   = dt_spinup
262
263    CALL location_message( 'wall/soil spinup time-stepping', 'start' )
264!
265!-- Start of the time loop
266    DO  WHILE ( simulated_time < spinup_time )
267
268       CALL cpu_log( log_point_s(15), 'timesteps spinup', 'start' )
269   
270!
271!--    Start of intermediate step loop
272       intermediate_timestep_count = 0
273       DO  WHILE ( intermediate_timestep_count < &
274                   intermediate_timestep_count_max )
275
276          intermediate_timestep_count = intermediate_timestep_count + 1
277
278!
279!--       Set the steering factors for the prognostic equations which depend
280!--       on the timestep scheme
281          CALL timestep_scheme_steering
282
283
284!
285!--       Estimate a near-surface air temperature based on the position of the
286!--       sun and user input about mean temperature and amplitude. The time is
287!--       shifted by one hour to simulate a lag between air temperature and
288!--       incoming radiation
289          pt_spinup = spinup_pt_mean + spinup_pt_amplitude                     &
290             * solar_angle (time_utc_init + time_since_reference_point - 3600.0)
291
292!
293!--       Map air temperature to all grid points in the vicinity of a surface
294!--       element
295          IF ( land_surface )  THEN
296             DO  m = 1, surf_lsm_h%ns
297                i   = surf_lsm_h%i(m)           
298                j   = surf_lsm_h%j(m)
299                k   = surf_lsm_h%k(m)
300                pt(k,j,i) = pt_spinup
301             ENDDO
302
303             DO  l = 0, 3
304                DO  m = 1, surf_lsm_v(l)%ns
305                   i   = surf_lsm_v(l)%i(m)           
306                   j   = surf_lsm_v(l)%j(m)
307                   k   = surf_lsm_v(l)%k(m)
308                   pt(k,j,i) = pt_spinup
309                ENDDO
310             ENDDO
311          ENDIF
312
313          IF ( urban_surface )  THEN
314             DO  m = 1, surf_usm_h%ns
315                i   = surf_usm_h%i(m)           
316                j   = surf_usm_h%j(m)
317                k   = surf_usm_h%k(m)
318                pt(k,j,i) = pt_spinup
319                !!!!!!!!!!!!!!!!HACK!!!!!!!!!!!!!
320                surf_usm_h%pt1 = pt_spinup
321                !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
322             ENDDO
323
324             DO  l = 0, 3
325                DO  m = 1, surf_usm_v(l)%ns
326                   i   = surf_usm_v(l)%i(m)           
327                   j   = surf_usm_v(l)%j(m)
328                   k   = surf_usm_v(l)%k(m)
329                   pt(k,j,i) = pt_spinup
330                   !!!!!!!!!!!!!!!!HACK!!!!!!!!!!!!!
331                   surf_usm_v(l)%pt1 = pt_spinup
332                   !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
333                ENDDO
334             ENDDO
335          ENDIF
336
337          CALL exchange_horiz( pt,  nbgp )   
338
339
340!
341!--       Swap the time levels in preparation for the next time step.
342          timestep_count = timestep_count + 1
343     
344          IF ( land_surface )  THEN
345              CALL lsm_swap_timelevel ( 0 )
346          ENDIF
347
348          IF ( urban_surface )  THEN
349             CALL usm_swap_timelevel ( 0 )
350          ENDIF
351
352          IF ( land_surface )  THEN
353             CALL lsm_swap_timelevel ( MOD( timestep_count, 2) )
354          ENDIF
355
356          IF ( urban_surface )  THEN
357             CALL usm_swap_timelevel ( MOD( timestep_count, 2) )
358          ENDIF
359         
360!
361!--       If required, compute virtual potential temperature
362          IF ( humidity )  THEN
363             CALL compute_vpt 
364          ENDIF 
365
366!
367!--       Compute the diffusion quantities
368          IF ( .NOT. constant_diffusion )  THEN
369
370!
371!--          First the vertical (and horizontal) fluxes in the surface
372!--          (constant flux) layer are computed
373             IF ( constant_flux_layer )  THEN
374                CALL surface_layer_fluxes
375             ENDIF
376
377!
378!--          If required, solve the energy balance for the surface and run soil
379!--          model. Call for horizontal as well as vertical surfaces.
380!--          The prognostic equation for soil moisure is switched off
381             IF ( land_surface )  THEN
382
383!
384!--             Call for horizontal upward-facing surfaces
385                CALL lsm_energy_balance( .TRUE., -1 )
386                CALL lsm_soil_model( .TRUE., -1, calc_soil_moisture_during_spinup )
387!
388!--             Call for northward-facing surfaces
389                CALL lsm_energy_balance( .FALSE., 0 )
390                CALL lsm_soil_model( .FALSE., 0, calc_soil_moisture_during_spinup )
391!
392!--             Call for southward-facing surfaces
393                CALL lsm_energy_balance( .FALSE., 1 )
394                CALL lsm_soil_model( .FALSE., 1, calc_soil_moisture_during_spinup )
395!
396!--             Call for eastward-facing surfaces
397                CALL lsm_energy_balance( .FALSE., 2 )
398                CALL lsm_soil_model( .FALSE., 2, calc_soil_moisture_during_spinup )
399!
400!--             Call for westward-facing surfaces
401                CALL lsm_energy_balance( .FALSE., 3 )
402                CALL lsm_soil_model( .FALSE., 3, calc_soil_moisture_during_spinup )
403
404             ENDIF
405
406!
407!--          If required, solve the energy balance for urban surfaces and run
408!--          the material heat model
409             IF (urban_surface) THEN
410
411                CALL usm_surface_energy_balance( .TRUE. )
412                IF ( usm_material_model )  THEN
413                   CALL usm_green_heat_model
414                   CALL usm_material_heat_model( .TRUE. )
415                ENDIF
416
417             ENDIF
418
419          ENDIF
420
421!
422!--       If required, calculate radiative fluxes and heating rates
423          IF ( radiation .AND. intermediate_timestep_count                     &
424               == intermediate_timestep_count_max )  THEN
425
426               time_radiation = time_radiation + dt_3d
427
428             IF ( time_radiation >= dt_3d .OR. force_radiation_call )          &
429             THEN
430
431                IF ( .NOT. force_radiation_call )  THEN
432                   time_radiation = time_radiation - dt_3d
433                ENDIF
434
435                CALL radiation_control
436
437                IF ( radiation_interactions )  THEN
438                   CALL radiation_interaction
439                ENDIF
440             ENDIF
441          ENDIF
442
443       ENDDO   ! Intermediate step loop
444
445!
446!--    Increase simulation time and output times
447       current_timestep_number_spinup = current_timestep_number_spinup + 1
448       simulated_time             = simulated_time   + dt_3d
449       simulated_time_chr         = time_to_string( simulated_time )
450       time_since_reference_point = simulated_time - coupling_start_time
451
452       IF ( data_output_during_spinup )  THEN
453          IF ( simulated_time >= skip_time_do2d_xy )  THEN
454             time_do2d_xy       = time_do2d_xy     + dt_3d
455          ENDIF
456          IF ( simulated_time >= skip_time_do3d    )  THEN
457             time_do3d          = time_do3d        + dt_3d
458          ENDIF
459          time_dots          = time_dots        + dt_3d
460          IF ( simulated_time >= skip_time_dopr )  THEN
461             time_dopr       = time_dopr        + dt_3d
462          ENDIF
463          time_run_control   = time_run_control + dt_3d
464
465!
466!--       Carry out statistical analysis and output at the requested output times.
467!--       The MOD function is used for calculating the output time counters (like
468!--       time_dopr) in order to regard a possible decrease of the output time
469!--       interval in case of restart runs
470
471!
472!--       Set a flag indicating that so far no statistics have been created
473!--       for this time step
474          flow_statistics_called = .FALSE.
475
476!
477!--       If required, call flow_statistics for averaging in time
478          IF ( averaging_interval_pr /= 0.0_wp  .AND.                          &
479             ( dt_dopr - time_dopr ) <= averaging_interval_pr  .AND.           &
480             simulated_time >= skip_time_dopr )  THEN
481             time_dopr_av = time_dopr_av + dt_3d
482             IF ( time_dopr_av >= dt_averaging_input_pr )  THEN
483                do_sum = .TRUE.
484                time_dopr_av = MOD( time_dopr_av,                              &
485                               MAX( dt_averaging_input_pr, dt_3d ) )
486             ENDIF
487          ENDIF
488          IF ( do_sum )  CALL flow_statistics
489
490!
491!--       Output of profiles
492          IF ( time_dopr >= dt_dopr )  THEN
493             IF ( dopr_n /= 0 )  CALL data_output_profiles
494             time_dopr = MOD( time_dopr, MAX( dt_dopr, dt_3d ) )
495             time_dopr_av = 0.0_wp    ! due to averaging (see above)
496          ENDIF
497
498!
499!--       Output of time series
500          IF ( time_dots >= dt_dots )  THEN
501             CALL data_output_tseries
502             time_dots = MOD( time_dots, MAX( dt_dots, dt_3d ) )
503          ENDIF
504
505!
506!--       2d-data output (cross-sections)
507          IF ( time_do2d_xy >= dt_do2d_xy )  THEN
508             CALL data_output_2d( 'xy', 0 )
509             time_do2d_xy = MOD( time_do2d_xy, MAX( dt_do2d_xy, dt_3d ) )
510          ENDIF
511
512!
513!--       3d-data output (volume data)
514          IF ( time_do3d >= dt_do3d )  THEN
515             CALL data_output_3d( 0 )
516             time_do3d = MOD( time_do3d, MAX( dt_do3d, dt_3d ) )
517          ENDIF
518
519
520       ENDIF
521
522!
523!--    Computation and output of run control parameters.
524!--    This is also done whenever perturbations have been imposed
525!        IF ( time_run_control >= dt_run_control  .OR.                           &
526!             timestep_scheme(1:5) /= 'runge'  .OR.  disturbance_created )       &
527!        THEN
528!           CALL run_control
529!           IF ( time_run_control >= dt_run_control )  THEN
530!              time_run_control = MOD( time_run_control,                         &
531!                                      MAX( dt_run_control, dt_3d ) )
532!           ENDIF
533!        ENDIF
534
535       CALL cpu_log( log_point_s(15), 'timesteps spinup', 'stop' )
536
537
538!
539!--    Run control output
540       IF ( myid == 0 )  THEN
541!
542!--       If necessary, write header
543          IF ( .NOT. run_control_header_spinup )  THEN
544             CALL check_open( 15 )
545             WRITE ( 15, 100 )
546             run_control_header_spinup = .TRUE.
547          ENDIF
548!
549!--       Write some general information about the spinup in run control file
550          WRITE ( 15, 101 )  current_timestep_number_spinup, simulated_time_chr, dt_3d, pt_spinup
551!
552!--       Write buffer contents to disc immediately
553          FLUSH( 15 )
554       ENDIF
555
556
557
558    ENDDO   ! time loop
559
560!
561!-- Write back saved arrays to the 3D arrays
562    pt   = pt_save
563    pt_p = pt_save
564    u    = u_save
565    v    = v_save
566
567!
568!-- Reset time step
569    dt_3d = dt_save
570
571    DEALLOCATE(pt_save)
572    DEALLOCATE(u_save)
573    DEALLOCATE(v_save)
574
575#if defined( __parallel )
576    IF ( nested_run )  CALL MPI_BARRIER( MPI_COMM_WORLD, ierr )
577#endif
578
579    CALL location_message( 'wall/soil spinup time-stepping', 'finished' )
580
581
582!
583!-- Formats
584100 FORMAT (///'Spinup control output:'/  &
585            '--------------------------------'// &
586            'ITER.  HH:MM:SS    DT   PT(z_MO)'/   &
587            '--------------------------------')
588101 FORMAT (I5,2X,A9,1X,F6.2,3X,F6.2,2X,F6.2)
589
590 CONTAINS
591
592!
593!-- Returns the cosine of the solar zenith angle at a given time. This routine
594!-- is similar to that for calculation zenith (see radiation_model_mod.f90)
595    FUNCTION solar_angle( local_time ) 
596
597       USE basic_constants_and_equations_mod,                                  &
598       ONLY:  pi
599     
600       USE kinds
601
602       USE radiation_model_mod,                                                &
603           ONLY:  decl_1, decl_2, decl_3, lat, lon
604
605       IMPLICIT NONE
606
607
608       REAL(wp) ::  solar_angle     !< cosine of the solar zenith angle
609
610       REAL(wp) ::  day             !< day of the year
611       REAL(wp) ::  declination     !< solar declination angle
612       REAL(wp) ::  hour_angle      !< solar hour angle
613       REAL(wp) ::  time_utc        !< current time in UTC
614       REAL(wp), INTENT(IN) :: local_time
615!
616!--    Calculate current day and time based on the initial values and simulation
617!--    time
618
619       day = day_of_year_init + INT(FLOOR( local_time / 86400.0_wp ), KIND=iwp)
620       time_utc = MOD(local_time, 86400.0_wp)
621
622
623!
624!--    Calculate solar declination and hour angle   
625       declination = ASIN( decl_1 * SIN(decl_2 * REAL(day, KIND=wp) - decl_3) )
626       hour_angle  = 2.0_wp * pi * (time_utc / 86400.0_wp) + lon - pi
627
628!
629!--    Calculate cosine of solar zenith angle
630       solar_angle = SIN(lat) * SIN(declination) + COS(lat) * COS(declination) &
631                     * COS(hour_angle)
632
633
634    END FUNCTION solar_angle
635
636
637 END SUBROUTINE time_integration_spinup
Note: See TracBrowser for help on using the repository browser.