source: palm/trunk/SOURCE/time_integration.f90 @ 2118

Last change on this file since 2118 was 2118, checked in by raasch, 5 years ago

all OpenACC directives and related parts removed from the code

  • Property svn:keywords set to Id
File size: 39.9 KB
Line 
1!> @file time_integration.f90
2!------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2017 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! ------------------
22! OpenACC directives and related code removed
23!
24! Former revisions:
25! -----------------
26! $Id: time_integration.f90 2118 2017-01-17 16:38:49Z raasch $
27!
28! 2050 2016-11-08 15:00:55Z gronemeier
29! Implement turbulent outflow condition
30!
31! 2031 2016-10-21 15:11:58Z knoop
32! renamed variable rho to rho_ocean
33!
34! 2011 2016-09-19 17:29:57Z kanani
35! Flag urban_surface is now defined in module control_parameters,
36! removed commented CALLs of global_min_max.
37!
38! 2007 2016-08-24 15:47:17Z kanani
39! Added CALLs for new urban surface model
40!
41! 2000 2016-08-20 18:09:15Z knoop
42! Forced header and separation lines into 80 columns
43!
44! 1976 2016-07-27 13:28:04Z maronga
45! Simplified calls to radiation model
46!
47! 1960 2016-07-12 16:34:24Z suehring
48! Separate humidity and passive scalar
49!
50! 1957 2016-07-07 10:43:48Z suehring
51! flight module added
52!
53! 1919 2016-05-27 14:51:23Z raasch
54! Initial version of purely vertical nesting introduced.
55!
56! 1918 2016-05-27 14:35:57Z raasch
57! determination of time step moved to the end of the time step loop,
58! the first time step is now always calculated before the time step loop (i.e.
59! also in case of restart runs)
60!
61! 1914 2016-05-26 14:44:07Z witha
62! Added call for wind turbine model
63!
64! 1878 2016-04-19 12:30:36Z hellstea
65! Synchronization for nested runs rewritten
66!
67! 1853 2016-04-11 09:00:35Z maronga
68! Adjusted for use with radiation_scheme = constant
69!
70! 1849 2016-04-08 11:33:18Z hoffmann
71! Adapted for modularization of microphysics
72!
73! 1833 2016-04-07 14:23:03Z raasch
74! spectrum renamed spectra_mod, spectra related variables moved to spectra_mod
75!
76! 1831 2016-04-07 13:15:51Z hoffmann
77! turbulence renamed collision_turbulence
78!
79! 1822 2016-04-07 07:49:42Z hoffmann
80! icloud_scheme replaced by microphysics_*
81!
82! 1808 2016-04-05 19:44:00Z raasch
83! output message in case unscheduled radiation calls removed
84!
85! 1797 2016-03-21 16:50:28Z raasch
86! introduction of different datatransfer modes
87!
88! 1791 2016-03-11 10:41:25Z raasch
89! call of pmci_update_new removed
90!
91! 1786 2016-03-08 05:49:27Z raasch
92! +module spectrum
93!
94! 1783 2016-03-06 18:36:17Z raasch
95! switch back of netcdf data format for mask output moved to the mask output
96! routine
97!
98! 1781 2016-03-03 15:12:23Z raasch
99! some pmc calls removed at the beginning (before timeloop),
100! pmc initialization moved to the main program
101!
102! 1764 2016-02-28 12:45:19Z raasch
103! PMC_ACTIVE flags removed,
104! bugfix: nest synchronization after first call of timestep
105!
106! 1762 2016-02-25 12:31:13Z hellstea
107! Introduction of nested domain feature
108!
109! 1736 2015-12-04 08:56:33Z raasch
110! no perturbations added to total domain if energy limit has been set zero
111!
112! 1691 2015-10-26 16:17:44Z maronga
113! Added option for spin-ups without land surface and radiation models. Moved calls
114! for radiation and lan surface schemes.
115!
116! 1682 2015-10-07 23:56:08Z knoop
117! Code annotations made doxygen readable
118!
119! 1671 2015-09-25 03:29:37Z raasch
120! bugfix: ghostpoint exchange for array diss in case that sgs velocities are used
121! for particles
122!
123! 1585 2015-04-30 07:05:52Z maronga
124! Moved call of radiation scheme. Added support for RRTM
125!
126! 1551 2015-03-03 14:18:16Z maronga
127! Added interface for different radiation schemes.
128!
129! 1496 2014-12-02 17:25:50Z maronga
130! Added calls for the land surface model and radiation scheme
131!
132! 1402 2014-05-09 14:25:13Z raasch
133! location messages modified
134!
135! 1384 2014-05-02 14:31:06Z raasch
136! location messages added
137!
138! 1380 2014-04-28 12:40:45Z heinze
139! CALL of nudge_ref added
140! bc_pt_t_val and bc_q_t_val are updated in case nudging is used
141!
142! 1365 2014-04-22 15:03:56Z boeske
143! Reset sums_ls_l to zero at each timestep
144! +sums_ls_l
145! Calculation of reference state (previously in subroutine calc_mean_profile)
146
147! 1342 2014-03-26 17:04:47Z kanani
148! REAL constants defined as wp-kind
149!
150! 1320 2014-03-20 08:40:49Z raasch
151! ONLY-attribute added to USE-statements,
152! kind-parameters added to all INTEGER and REAL declaration statements,
153! kinds are defined in new module kinds,
154! old module precision_kind is removed,
155! revision history before 2012 removed,
156! comment fields (!:) to be used for variable explanations added to
157! all variable declaration statements
158! 1318 2014-03-17 13:35:16Z raasch
159! module interfaces removed
160!
161! 1308 2014-03-13 14:58:42Z fricke
162! +netcdf_data_format_save
163! For masked data, parallel netcdf output is not tested so far, hence
164! netcdf_data_format is switched back to non-paralell output.
165!
166! 1276 2014-01-15 13:40:41Z heinze
167! Use LSF_DATA also in case of Dirichlet bottom boundary condition for scalars
168!
169! 1257 2013-11-08 15:18:40Z raasch
170! acc-update-host directive for timestep removed
171!
172! 1241 2013-10-30 11:36:58Z heinze
173! Generalize calc_mean_profile for wider use
174! Determine shf and qsws in dependence on data from LSF_DATA
175! Determine ug and vg in dependence on data from LSF_DATA
176! 1221 2013-09-10 08:59:13Z raasch
177! host update of arrays before timestep is called
178!
179! 1179 2013-06-14 05:57:58Z raasch
180! mean profiles for reference state are only calculated if required,
181! small bugfix for background communication
182!
183! 1171 2013-05-30 11:27:45Z raasch
184! split of prognostic_equations deactivated (comment lines), for the time being
185!
186! 1128 2013-04-12 06:19:32Z raasch
187! asynchronous transfer of ghost point data realized for acc-optimized version:
188! prognostic_equations are first called two times for those points required for
189! the left-right and north-south exchange, respectively, and then for the
190! remaining points,
191! those parts requiring global communication moved from prognostic_equations to
192! here
193!
194! 1115 2013-03-26 18:16:16Z hoffmann
195! calculation of qr and nr is restricted to precipitation
196!
197! 1113 2013-03-10 02:48:14Z raasch
198! GPU-porting of boundary conditions,
199! openACC directives updated
200! formal parameter removed from routine boundary_conds
201!
202! 1111 2013-03-08 23:54:10Z raasch
203! +internal timestep counter for cpu statistics added,
204! openACC directives updated
205!
206! 1092 2013-02-02 11:24:22Z raasch
207! unused variables removed
208!
209! 1065 2012-11-22 17:42:36Z hoffmann
210! exchange of diss (dissipation rate) in case of turbulence = .TRUE. added
211!
212! 1053 2012-11-13 17:11:03Z hoffmann
213! exchange of ghost points for nr, qr added
214!
215! 1036 2012-10-22 13:43:42Z raasch
216! code put under GPL (PALM 3.9)
217!
218! 1019 2012-09-28 06:46:45Z raasch
219! non-optimized version of prognostic_equations removed
220!
221! 1015 2012-09-27 09:23:24Z raasch
222! +call of prognostic_equations_acc
223!
224! 1001 2012-09-13 14:08:46Z raasch
225! all actions concerning leapfrog- and upstream-spline-scheme removed
226!
227! 849 2012-03-15 10:35:09Z raasch
228! advec_particles renamed lpm, first_call_advec_particles renamed first_call_lpm
229!
230! 825 2012-02-19 03:03:44Z raasch
231! wang_collision_kernel renamed wang_kernel
232!
233! Revision 1.1  1997/08/11 06:19:04  raasch
234! Initial revision
235!
236!
237! Description:
238! ------------
239!> Integration in time of the model equations, statistical analysis and graphic
240!> output
241!------------------------------------------------------------------------------!
242 SUBROUTINE time_integration
243 
244
245    USE advec_ws,                                                              &
246        ONLY:  ws_statistics
247
248    USE arrays_3d,                                                             &
249        ONLY:  diss, dzu, e, e_p, nr_p, prho, pt, pt_p, pt_init, q_init, q,    &
250               ql, ql_c, ql_v, ql_vp, qr_p, q_p, ref_state, rho_ocean, s, s_p, sa_p, &
251               tend, u, u_p, v, vpt, v_p, w, w_p
252
253    USE calc_mean_profile_mod,                                                 &
254        ONLY:  calc_mean_profile
255
256    USE control_parameters,                                                    &
257        ONLY:  advected_distance_x, advected_distance_y, average_count_3d,     &
258               averaging_interval, averaging_interval_pr,                      &
259               bc_lr_cyc, bc_ns_cyc, bc_pt_t_val,                              &
260               bc_q_t_val, call_psolver_at_all_substeps, cloud_droplets,       &
261               cloud_physics, constant_flux_layer, constant_heatflux,          &
262               create_disturbances, dopr_n, constant_diffusion, coupling_mode, &
263               coupling_start_time, current_timestep_number,                   &
264               disturbance_created, disturbance_energy_limit, dist_range,      &
265               do_sum, dt_3d, dt_averaging_input, dt_averaging_input_pr,       &
266               dt_coupling, dt_data_output_av, dt_disturb, dt_do2d_xy,         &
267               dt_do2d_xz, dt_do2d_yz, dt_do3d, dt_domask,dt_dopts, dt_dopr,   &
268               dt_dopr_listing, dt_dots, dt_dvrp, dt_run_control,              &
269               end_time, first_call_lpm, galilei_transformation, humidity,     &
270               intermediate_timestep_count,                                    &
271               intermediate_timestep_count_max, large_scale_forcing,           &
272               loop_optimization, lsf_surf, lsf_vert, masks,                   &
273               microphysics_seifert, mid, nest_domain,                         &
274               neutral, nr_timesteps_this_run, nudging,                        &
275               ocean, passive_scalar,                                          &
276               prho_reference, pt_reference, pt_slope_offset, random_heatflux, &
277               run_coupled, simulated_time, simulated_time_chr,                &
278               skip_time_do2d_xy, skip_time_do2d_xz, skip_time_do2d_yz,        &
279               skip_time_do3d, skip_time_domask, skip_time_dopr,               &
280               skip_time_data_output_av, sloping_surface,                      &
281               stop_dt, terminate_coupled, terminate_run, timestep_scheme,     &
282               time_coupling, time_do2d_xy, time_do2d_xz, time_do2d_yz,        &
283               time_do3d, time_domask, time_dopr, time_dopr_av,                &
284               time_dopr_listing, time_dopts, time_dosp, time_dosp_av,         &
285               time_dots, time_do_av, time_do_sla, time_disturb, time_dvrp,    &
286               time_run_control, time_since_reference_point,                   &
287               turbulent_inflow, turbulent_outflow, urban_surface,             &
288               use_initial_profile_as_reference,                               &
289               use_single_reference_value, u_gtrans, v_gtrans, virtual_flight, &
290               ws_scheme_mom, ws_scheme_sca
291
292    USE cpulog,                                                                &
293        ONLY:  cpu_log, log_point, log_point_s
294
295    USE flight_mod,                                                            &
296        ONLY:  flight_measurement
297
298
299    USE indices,                                                               &
300        ONLY:  nbgp, nx, nxl, nxlg, nxr, nxrg, nyn, nyng, nys, nysg, nzb, nzt, &
301               nzb_u_inner, nzb_v_inner
302
303    USE interaction_droplets_ptq_mod,                                          &
304        ONLY:  interaction_droplets_ptq
305
306    USE interfaces
307
308    USE kinds
309
310    USE land_surface_model_mod,                                                &
311        ONLY:  land_surface, lsm_energy_balance, lsm_soil_model,               &
312               skip_time_do_lsm
313
314    USE ls_forcing_mod,                                                        &
315        ONLY:  ls_forcing_surf, ls_forcing_vert
316
317    USE microphysics_mod,                                                      &
318        ONLY: collision_turbulence
319
320    USE nudge_mod,                                                             &
321        ONLY:  calc_tnudge, nudge_ref
322
323    USE particle_attributes,                                                   &
324        ONLY:  particle_advection, particle_advection_start,                   &
325               use_sgs_for_particles, wang_kernel
326
327    USE pegrid
328
329    USE pmc_interface,                                                         &
330        ONLY:  nested_run, nesting_mode, pmci_datatrans,                       &
331               pmci_ensure_nest_mass_conservation, pmci_synchronize
332
333    USE production_e_mod,                                                      &
334        ONLY:  production_e_init
335
336    USE progress_bar,                                                          &
337        ONLY:  finish_progress_bar, output_progress_bar
338
339    USE prognostic_equations_mod,                                              &
340        ONLY:  prognostic_equations_cache, prognostic_equations_vector
341
342    USE radiation_model_mod,                                                   &
343        ONLY: dt_radiation, force_radiation_call, radiation, radiation_control,&
344              skip_time_do_radiation, time_radiation
345
346    USE spectra_mod,                                                           &
347        ONLY: average_count_sp, averaging_interval_sp, calc_spectra, dt_dosp,  &
348              skip_time_dosp
349
350    USE statistics,                                                            &
351        ONLY:  flow_statistics_called, hom, pr_palm, sums_ls_l, u_max,         &
352               u_max_ijk, v_max, v_max_ijk, w_max, w_max_ijk
353
354    USE surface_layer_fluxes_mod,                                              &
355        ONLY:  surface_layer_fluxes
356
357    USE urban_surface_mod,                                                     &
358        ONLY:  usm_material_heat_model, usm_material_model,     &
359               usm_radiation, usm_surface_energy_balance             
360
361    USE user_actions_mod,                                                      &
362        ONLY:  user_actions
363
364    USE wind_turbine_model_mod,                                                &
365        ONLY:  wind_turbine, wtm_forces
366
367    IMPLICIT NONE
368
369    CHARACTER (LEN=9) ::  time_to_string          !<
370
371    REAL(wp) ::  dt_3d_old  !< temporary storage of timestep to be used for
372                            !< steering of run control output interval
373
374!
375!-- At beginning determine the first time step
376    CALL timestep
377
378!
379!-- Synchronize the timestep in case of nested run.
380    IF ( nested_run )  THEN
381!
382!--    Synchronization by unifying the time step.
383!--    Global minimum of all time-steps is used for all.
384       CALL pmci_synchronize
385    ENDIF
386
387!
388!-- Determine and print out the run control quantities before the first time
389!-- step of this run. For the initial run, some statistics (e.g. divergence)
390!-- need to be determined first.
391    IF ( simulated_time == 0.0_wp )  CALL flow_statistics
392    CALL run_control
393
394!
395!-- Data exchange between coupled models in case that a call has been omitted
396!-- at the end of the previous run of a job chain.
397    IF ( coupling_mode /= 'uncoupled'  .AND.  run_coupled )  THEN
398!
399!--    In case of model termination initiated by the local model the coupler
400!--    must not be called because this would again cause an MPI hang.
401       DO WHILE ( time_coupling >= dt_coupling  .AND.  terminate_coupled == 0 )
402          CALL surface_coupler
403          time_coupling = time_coupling - dt_coupling
404       ENDDO
405       IF (time_coupling == 0.0_wp  .AND.                                      &
406           time_since_reference_point < dt_coupling )                          &
407       THEN
408          time_coupling = time_since_reference_point
409       ENDIF
410    ENDIF
411
412#if defined( __dvrp_graphics )
413!
414!-- Time measurement with dvrp software 
415    CALL DVRP_LOG_EVENT( 2, current_timestep_number )
416#endif
417
418    CALL location_message( 'start with time-stepping', .TRUE. )
419!
420!-- Start of the time loop
421    DO  WHILE ( simulated_time < end_time  .AND.  .NOT. stop_dt  .AND. &
422                .NOT. terminate_run )
423
424       CALL cpu_log( log_point_s(10), 'timesteps', 'start' )
425
426!
427!--    Determine ug, vg and w_subs in dependence on data from external file
428!--    LSF_DATA
429       IF ( large_scale_forcing .AND. lsf_vert )  THEN
430           CALL ls_forcing_vert ( simulated_time )
431           sums_ls_l = 0.0_wp
432       ENDIF
433
434!
435!--    Set pt_init and q_init to the current profiles taken from
436!--    NUDGING_DATA
437       IF ( nudging )  THEN
438           CALL nudge_ref ( simulated_time )
439!
440!--        Store temperature gradient at the top boundary for possible Neumann
441!--        boundary condition
442           bc_pt_t_val = ( pt_init(nzt+1) - pt_init(nzt) ) / dzu(nzt+1)
443           bc_q_t_val  = ( q_init(nzt+1) - q_init(nzt) ) / dzu(nzt+1)
444       ENDIF
445
446!
447!--    Execute the user-defined actions
448       CALL user_actions( 'before_timestep' )
449
450!
451!--    Calculate forces by wind turbines
452       IF ( wind_turbine )  THEN
453
454          CALL cpu_log( log_point(55), 'wind_turbine', 'start' )
455
456          CALL wtm_forces
457
458          CALL cpu_log( log_point(55), 'wind_turbine', 'stop' )
459
460       ENDIF       
461       
462!
463!--    Start of intermediate step loop
464       intermediate_timestep_count = 0
465       DO  WHILE ( intermediate_timestep_count < &
466                   intermediate_timestep_count_max )
467
468          intermediate_timestep_count = intermediate_timestep_count + 1
469
470!
471!--       Set the steering factors for the prognostic equations which depend
472!--       on the timestep scheme
473          CALL timestep_scheme_steering
474
475!
476!--       Calculate those variables needed in the tendency terms which need
477!--       global communication
478          IF ( .NOT. use_single_reference_value  .AND. &
479               .NOT. use_initial_profile_as_reference )  THEN
480!
481!--          Horizontally averaged profiles to be used as reference state in
482!--          buoyancy terms (WARNING: only the respective last call of
483!--          calc_mean_profile defines the reference state!)
484             IF ( .NOT. neutral )  THEN
485                CALL calc_mean_profile( pt, 4 )
486                ref_state(:)  = hom(:,1,4,0) ! this is used in the buoyancy term
487             ENDIF
488             IF ( ocean )  THEN
489                CALL calc_mean_profile( rho_ocean, 64 )
490                ref_state(:)  = hom(:,1,64,0)
491             ENDIF
492             IF ( humidity )  THEN
493                CALL calc_mean_profile( vpt, 44 )
494                ref_state(:)  = hom(:,1,44,0)
495             ENDIF
496
497          ENDIF
498
499          IF ( .NOT. constant_diffusion )  CALL production_e_init
500          IF ( ( ws_scheme_mom .OR. ws_scheme_sca )  .AND.  &
501               intermediate_timestep_count == 1 )  CALL ws_statistics
502!
503!--       In case of nudging calculate current nudging time scale and horizontal
504!--       means of u, v, pt and q
505          IF ( nudging )  THEN
506             CALL calc_tnudge( simulated_time )
507             CALL calc_mean_profile( u, 1 )
508             CALL calc_mean_profile( v, 2 )
509             CALL calc_mean_profile( pt, 4 )
510             CALL calc_mean_profile( q, 41 )
511          ENDIF
512
513!
514!--       Solve the prognostic equations. A fast cache optimized version with
515!--       only one single loop is used in case of Piascek-Williams advection
516!--       scheme. NEC vector machines use a different version, because
517!--       in the other versions a good vectorization is prohibited due to
518!--       inlining problems.
519          IF ( loop_optimization == 'cache' )  THEN
520             CALL prognostic_equations_cache
521          ELSEIF ( loop_optimization == 'vector' )  THEN
522             CALL prognostic_equations_vector
523          ENDIF
524
525!
526!--       Particle transport/physics with the Lagrangian particle model
527!--       (only once during intermediate steps, because it uses an Euler-step)
528!--       ### particle model should be moved before prognostic_equations, in order
529!--       to regard droplet interactions directly
530          IF ( particle_advection  .AND.                         &
531               simulated_time >= particle_advection_start  .AND. &
532               intermediate_timestep_count == 1 )  THEN
533             CALL lpm
534             first_call_lpm = .FALSE.
535          ENDIF
536
537!
538!--       Interaction of droplets with temperature and specific humidity.
539!--       Droplet condensation and evaporation is calculated within
540!--       advec_particles.
541          IF ( cloud_droplets  .AND.  &
542               intermediate_timestep_count == intermediate_timestep_count_max )&
543          THEN
544             CALL interaction_droplets_ptq
545          ENDIF
546
547!
548!--       Exchange of ghost points (lateral boundary conditions)
549          CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'start' )
550
551          CALL exchange_horiz( u_p, nbgp )
552          CALL exchange_horiz( v_p, nbgp )
553          CALL exchange_horiz( w_p, nbgp )
554          CALL exchange_horiz( pt_p, nbgp )
555          IF ( .NOT. constant_diffusion )  CALL exchange_horiz( e_p, nbgp )
556          IF ( ocean )  THEN
557             CALL exchange_horiz( sa_p, nbgp )
558             CALL exchange_horiz( rho_ocean, nbgp )
559             CALL exchange_horiz( prho, nbgp )
560          ENDIF
561          IF ( humidity )  THEN
562             CALL exchange_horiz( q_p, nbgp )
563             IF ( cloud_physics .AND. microphysics_seifert )  THEN
564                CALL exchange_horiz( qr_p, nbgp )
565                CALL exchange_horiz( nr_p, nbgp )
566             ENDIF
567          ENDIF
568          IF ( cloud_droplets )  THEN
569             CALL exchange_horiz( ql, nbgp )
570             CALL exchange_horiz( ql_c, nbgp )
571             CALL exchange_horiz( ql_v, nbgp )
572             CALL exchange_horiz( ql_vp, nbgp )
573          ENDIF
574          IF ( wang_kernel  .OR.  collision_turbulence  .OR.                &
575               use_sgs_for_particles )  THEN
576             CALL exchange_horiz( diss, nbgp )
577          ENDIF
578          IF ( passive_scalar )  CALL exchange_horiz( s_p, nbgp )
579
580          CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'stop' )
581
582!
583!--       Boundary conditions for the prognostic quantities (except of the
584!--       velocities at the outflow in case of a non-cyclic lateral wall)
585          CALL boundary_conds
586
587!
588!--       Swap the time levels in preparation for the next time step.
589          CALL swap_timelevel
590
591          IF ( nested_run )  THEN
592
593             CALL cpu_log( log_point(60), 'nesting', 'start' )
594!
595!--          Domain nesting. The data transfer subroutines pmci_parent_datatrans
596!--          and pmci_child_datatrans are called inside the wrapper
597!--          subroutine pmci_datatrans according to the control parameters
598!--          nesting_mode and nesting_datatransfer_mode.
599!--          TO_DO: why is nesting_mode given as a parameter here?
600             CALL pmci_datatrans( nesting_mode )
601
602             IF ( TRIM( nesting_mode ) == 'two-way' .OR.                               &
603                  nesting_mode == 'vertical' )  THEN
604!
605!--             Exchange_horiz is needed for all parent-domains after the
606!--             anterpolation
607                CALL exchange_horiz( u, nbgp )
608                CALL exchange_horiz( v, nbgp )
609                CALL exchange_horiz( w, nbgp )
610                IF ( .NOT. neutral            )  CALL exchange_horiz( pt, nbgp )
611                IF ( humidity                 )  CALL exchange_horiz( q, nbgp  )
612                IF ( passive_scalar           )  CALL exchange_horiz( s, nbgp  )
613                IF ( .NOT. constant_diffusion )  CALL exchange_horiz( e, nbgp  )
614             ENDIF
615!
616!--          Correct the w top-BC in nest domains to ensure mass conservation.
617!--          This action must never be done for the root domain. Vertical
618!--          nesting implies mass conservation.
619             IF ( nest_domain )  THEN
620                CALL pmci_ensure_nest_mass_conservation
621             ENDIF
622
623             CALL cpu_log( log_point(60), 'nesting', 'stop' )
624
625          ENDIF
626
627!
628!--       Temperature offset must be imposed at cyclic boundaries in x-direction
629!--       when a sloping surface is used
630          IF ( sloping_surface )  THEN
631             IF ( nxl ==  0 )  pt(:,:,nxlg:nxl-1) = pt(:,:,nxlg:nxl-1) - &
632                                                    pt_slope_offset
633             IF ( nxr == nx )  pt(:,:,nxr+1:nxrg) = pt(:,:,nxr+1:nxrg) + &
634                                                    pt_slope_offset
635          ENDIF
636
637!
638!--       Impose a turbulent inflow using the recycling method
639          IF ( turbulent_inflow )  CALL  inflow_turbulence
640
641!
642!--       Set values at outflow boundary using the special outflow condition
643          IF ( turbulent_outflow )  CALL  outflow_turbulence
644
645!
646!--       Impose a random perturbation on the horizontal velocity field
647          IF ( create_disturbances  .AND.                                      &
648               ( call_psolver_at_all_substeps  .AND.                           &
649               intermediate_timestep_count == intermediate_timestep_count_max )&
650          .OR. ( .NOT. call_psolver_at_all_substeps  .AND.                     &
651               intermediate_timestep_count == 1 ) )                            &
652          THEN
653             time_disturb = time_disturb + dt_3d
654             IF ( time_disturb >= dt_disturb )  THEN
655                IF ( disturbance_energy_limit /= 0.0_wp  .AND.                 &
656                     hom(nzb+5,1,pr_palm,0) < disturbance_energy_limit )  THEN
657                   CALL disturb_field( nzb_u_inner, tend, u )
658                   CALL disturb_field( nzb_v_inner, tend, v )
659                ELSEIF ( .NOT. bc_lr_cyc  .OR.  .NOT. bc_ns_cyc )  THEN
660!
661!--                Runs with a non-cyclic lateral wall need perturbations
662!--                near the inflow throughout the whole simulation
663                   dist_range = 1
664                   CALL disturb_field( nzb_u_inner, tend, u )
665                   CALL disturb_field( nzb_v_inner, tend, v )
666                   dist_range = 0
667                ENDIF
668                time_disturb = time_disturb - dt_disturb
669             ENDIF
670          ENDIF
671
672!
673!--       Reduce the velocity divergence via the equation for perturbation
674!--       pressure.
675          IF ( intermediate_timestep_count == 1  .OR. &
676                call_psolver_at_all_substeps )  THEN
677             CALL pres
678          ENDIF
679
680!
681!--       If required, compute liquid water content
682          IF ( cloud_physics )  THEN
683             CALL calc_liquid_water_content
684          ENDIF
685!
686!--       If required, compute virtual potential temperature
687          IF ( humidity )  THEN
688             CALL compute_vpt
689          ENDIF
690
691!
692!--       Compute the diffusion quantities
693          IF ( .NOT. constant_diffusion )  THEN
694
695!
696!--          Determine surface fluxes shf and qsws and surface values
697!--          pt_surface and q_surface in dependence on data from external
698!--          file LSF_DATA respectively
699             IF ( ( large_scale_forcing .AND. lsf_surf ) .AND. &
700                 intermediate_timestep_count == intermediate_timestep_count_max )&
701             THEN
702                CALL ls_forcing_surf ( simulated_time )
703             ENDIF
704
705!
706!--          First the vertical fluxes in the surface (constant flux) layer are computed
707             IF ( constant_flux_layer )  THEN
708                CALL cpu_log( log_point(19), 'surface_layer_fluxes', 'start' )
709                CALL surface_layer_fluxes
710                CALL cpu_log( log_point(19), 'surface_layer_fluxes', 'stop' )
711             ENDIF
712
713!
714!--          If required, solve the energy balance for the surface and run soil
715!--          model
716             IF ( land_surface .AND. simulated_time > skip_time_do_lsm)  THEN
717
718                CALL cpu_log( log_point(54), 'land_surface', 'start' )
719                CALL lsm_energy_balance
720                CALL lsm_soil_model
721                CALL cpu_log( log_point(54), 'land_surface', 'stop' )
722             ENDIF
723
724!
725!--          If required, solve the energy balance for urban surfaces and run
726!--          the material heat model
727             IF (urban_surface) THEN
728                CALL cpu_log( log_point(74), 'urban_surface', 'start' )
729                CALL usm_surface_energy_balance
730                IF ( usm_material_model )  THEN
731                   CALL usm_material_heat_model
732                ENDIF
733                CALL cpu_log( log_point(74), 'urban_surface', 'stop' )
734             ENDIF
735
736!
737!--          Compute the diffusion coefficients
738             CALL cpu_log( log_point(17), 'diffusivities', 'start' )
739             IF ( .NOT. humidity ) THEN
740                IF ( ocean )  THEN
741                   CALL diffusivities( prho, prho_reference )
742                ELSE
743                   CALL diffusivities( pt, pt_reference )
744                ENDIF
745             ELSE
746                CALL diffusivities( vpt, pt_reference )
747             ENDIF
748             CALL cpu_log( log_point(17), 'diffusivities', 'stop' )
749
750          ENDIF
751
752!
753!--       If required, calculate radiative fluxes and heating rates
754          IF ( radiation .AND. intermediate_timestep_count                     &
755               == intermediate_timestep_count_max .AND. simulated_time >    &
756               skip_time_do_radiation )  THEN
757
758               time_radiation = time_radiation + dt_3d
759
760             IF ( time_radiation >= dt_radiation .OR. force_radiation_call )   &
761             THEN
762
763                CALL cpu_log( log_point(50), 'radiation', 'start' )
764
765                IF ( .NOT. force_radiation_call )  THEN
766                   time_radiation = time_radiation - dt_radiation
767                ENDIF
768
769                CALL radiation_control
770
771                CALL cpu_log( log_point(50), 'radiation', 'stop' )
772
773                IF (urban_surface)  THEN
774                   CALL cpu_log( log_point(75), 'usm_radiation', 'start' )
775                   CALL usm_radiation
776                   CALL cpu_log( log_point(75), 'usm_radiation', 'stop' )
777                ENDIF
778
779             ENDIF
780          ENDIF
781
782       ENDDO   ! Intermediate step loop
783
784!
785!--    Increase simulation time and output times
786       nr_timesteps_this_run      = nr_timesteps_this_run + 1
787       current_timestep_number    = current_timestep_number + 1
788       simulated_time             = simulated_time   + dt_3d
789       simulated_time_chr         = time_to_string( simulated_time )
790       time_since_reference_point = simulated_time - coupling_start_time
791
792
793
794       IF ( simulated_time >= skip_time_data_output_av )  THEN
795          time_do_av         = time_do_av       + dt_3d
796       ENDIF
797       IF ( simulated_time >= skip_time_do2d_xy )  THEN
798          time_do2d_xy       = time_do2d_xy     + dt_3d
799       ENDIF
800       IF ( simulated_time >= skip_time_do2d_xz )  THEN
801          time_do2d_xz       = time_do2d_xz     + dt_3d
802       ENDIF
803       IF ( simulated_time >= skip_time_do2d_yz )  THEN
804          time_do2d_yz       = time_do2d_yz     + dt_3d
805       ENDIF
806       IF ( simulated_time >= skip_time_do3d    )  THEN
807          time_do3d          = time_do3d        + dt_3d
808       ENDIF
809       DO  mid = 1, masks
810          IF ( simulated_time >= skip_time_domask(mid) )  THEN
811             time_domask(mid)= time_domask(mid) + dt_3d
812          ENDIF
813       ENDDO
814       time_dvrp          = time_dvrp        + dt_3d
815       IF ( simulated_time >= skip_time_dosp )  THEN
816          time_dosp       = time_dosp        + dt_3d
817       ENDIF
818       time_dots          = time_dots        + dt_3d
819       IF ( .NOT. first_call_lpm )  THEN
820          time_dopts      = time_dopts       + dt_3d
821       ENDIF
822       IF ( simulated_time >= skip_time_dopr )  THEN
823          time_dopr       = time_dopr        + dt_3d
824       ENDIF
825       time_dopr_listing          = time_dopr_listing        + dt_3d
826       time_run_control   = time_run_control + dt_3d
827
828!
829!--    Data exchange between coupled models
830       IF ( coupling_mode /= 'uncoupled'  .AND.  run_coupled )  THEN
831          time_coupling = time_coupling + dt_3d
832
833!
834!--       In case of model termination initiated by the local model
835!--       (terminate_coupled > 0), the coupler must be skipped because it would
836!--       cause an MPI intercomminucation hang.
837!--       If necessary, the coupler will be called at the beginning of the
838!--       next restart run.
839          DO WHILE ( time_coupling >= dt_coupling .AND. terminate_coupled == 0 )
840             CALL surface_coupler
841             time_coupling = time_coupling - dt_coupling
842          ENDDO
843       ENDIF
844
845!
846!--    Execute user-defined actions
847       CALL user_actions( 'after_integration' )
848
849!
850!--    If Galilei transformation is used, determine the distance that the
851!--    model has moved so far
852       IF ( galilei_transformation )  THEN
853          advected_distance_x = advected_distance_x + u_gtrans * dt_3d
854          advected_distance_y = advected_distance_y + v_gtrans * dt_3d
855       ENDIF
856
857!
858!--    Check, if restart is necessary (because cpu-time is expiring or
859!--    because it is forced by user) and set stop flag
860!--    This call is skipped if the remote model has already initiated a restart.
861       IF ( .NOT. terminate_run )  CALL check_for_restart
862
863!
864!--    Carry out statistical analysis and output at the requested output times.
865!--    The MOD function is used for calculating the output time counters (like
866!--    time_dopr) in order to regard a possible decrease of the output time
867!--    interval in case of restart runs
868
869!
870!--    Set a flag indicating that so far no statistics have been created
871!--    for this time step
872       flow_statistics_called = .FALSE.
873
874!
875!--    If required, call flow_statistics for averaging in time
876       IF ( averaging_interval_pr /= 0.0_wp  .AND.  &
877            ( dt_dopr - time_dopr ) <= averaging_interval_pr  .AND.  &
878            simulated_time >= skip_time_dopr )  THEN
879          time_dopr_av = time_dopr_av + dt_3d
880          IF ( time_dopr_av >= dt_averaging_input_pr )  THEN
881             do_sum = .TRUE.
882             time_dopr_av = MOD( time_dopr_av, &
883                                    MAX( dt_averaging_input_pr, dt_3d ) )
884          ENDIF
885       ENDIF
886       IF ( do_sum )  CALL flow_statistics
887
888!
889!--    Sum-up 3d-arrays for later output of time-averaged 2d/3d/masked data
890       IF ( averaging_interval /= 0.0_wp  .AND.                                &
891            ( dt_data_output_av - time_do_av ) <= averaging_interval  .AND. &
892            simulated_time >= skip_time_data_output_av )                    &
893       THEN
894          time_do_sla = time_do_sla + dt_3d
895          IF ( time_do_sla >= dt_averaging_input )  THEN
896             CALL sum_up_3d_data
897             average_count_3d = average_count_3d + 1
898             time_do_sla = MOD( time_do_sla, MAX( dt_averaging_input, dt_3d ) )
899          ENDIF
900       ENDIF
901
902!
903!--    Calculate spectra for time averaging
904       IF ( averaging_interval_sp /= 0.0_wp  .AND.  &
905            ( dt_dosp - time_dosp ) <= averaging_interval_sp  .AND.  &
906            simulated_time >= skip_time_dosp )  THEN
907          time_dosp_av = time_dosp_av + dt_3d
908          IF ( time_dosp_av >= dt_averaging_input_pr )  THEN
909             CALL calc_spectra
910             time_dosp_av = MOD( time_dosp_av, &
911                                 MAX( dt_averaging_input_pr, dt_3d ) )
912          ENDIF
913       ENDIF
914
915!
916!--    Call flight module and output data
917       IF ( virtual_flight )  THEN
918          CALL flight_measurement
919          CALL data_output_flight
920       ENDIF
921
922!
923!--    Profile output (ASCII) on file
924       IF ( time_dopr_listing >= dt_dopr_listing )  THEN
925          CALL print_1d
926          time_dopr_listing = MOD( time_dopr_listing, MAX( dt_dopr_listing, &
927                                                           dt_3d ) )
928       ENDIF
929
930!
931!--    Graphic output for PROFIL
932       IF ( time_dopr >= dt_dopr )  THEN
933          IF ( dopr_n /= 0 )  CALL data_output_profiles
934          time_dopr = MOD( time_dopr, MAX( dt_dopr, dt_3d ) )
935          time_dopr_av = 0.0_wp    ! due to averaging (see above)
936       ENDIF
937
938!
939!--    Graphic output for time series
940       IF ( time_dots >= dt_dots )  THEN
941          CALL data_output_tseries
942          time_dots = MOD( time_dots, MAX( dt_dots, dt_3d ) )
943       ENDIF
944
945!
946!--    Output of spectra (formatted for use with PROFIL), in case of no
947!--    time averaging, spectra has to be calculated before
948       IF ( time_dosp >= dt_dosp )  THEN
949          IF ( average_count_sp == 0 )  CALL calc_spectra
950          CALL data_output_spectra
951          time_dosp = MOD( time_dosp, MAX( dt_dosp, dt_3d ) )
952       ENDIF
953
954!
955!--    2d-data output (cross-sections)
956       IF ( time_do2d_xy >= dt_do2d_xy )  THEN
957          CALL data_output_2d( 'xy', 0 )
958          time_do2d_xy = MOD( time_do2d_xy, MAX( dt_do2d_xy, dt_3d ) )
959       ENDIF
960       IF ( time_do2d_xz >= dt_do2d_xz )  THEN
961          CALL data_output_2d( 'xz', 0 )
962          time_do2d_xz = MOD( time_do2d_xz, MAX( dt_do2d_xz, dt_3d ) )
963       ENDIF
964       IF ( time_do2d_yz >= dt_do2d_yz )  THEN
965          CALL data_output_2d( 'yz', 0 )
966          time_do2d_yz = MOD( time_do2d_yz, MAX( dt_do2d_yz, dt_3d ) )
967       ENDIF
968
969!
970!--    3d-data output (volume data)
971       IF ( time_do3d >= dt_do3d )  THEN
972          CALL data_output_3d( 0 )
973          time_do3d = MOD( time_do3d, MAX( dt_do3d, dt_3d ) )
974       ENDIF
975
976!
977!--    Masked data output
978       DO  mid = 1, masks
979          IF ( time_domask(mid) >= dt_domask(mid) )  THEN
980             CALL data_output_mask( 0 )
981             time_domask(mid) = MOD( time_domask(mid),  &
982                                     MAX( dt_domask(mid), dt_3d ) )
983          ENDIF
984       ENDDO
985
986!
987!--    Output of time-averaged 2d/3d/masked data
988       IF ( time_do_av >= dt_data_output_av )  THEN
989          CALL average_3d_data
990          CALL data_output_2d( 'xy', 1 )
991          CALL data_output_2d( 'xz', 1 )
992          CALL data_output_2d( 'yz', 1 )
993          CALL data_output_3d( 1 )
994          DO  mid = 1, masks
995             CALL data_output_mask( 1 )
996          ENDDO
997          time_do_av = MOD( time_do_av, MAX( dt_data_output_av, dt_3d ) )
998       ENDIF
999
1000!
1001!--    Output of particle time series
1002       IF ( particle_advection )  THEN
1003          IF ( time_dopts >= dt_dopts  .OR. &
1004               ( simulated_time >= particle_advection_start  .AND. &
1005                 first_call_lpm ) )  THEN
1006             CALL data_output_ptseries
1007             time_dopts = MOD( time_dopts, MAX( dt_dopts, dt_3d ) )
1008          ENDIF
1009       ENDIF
1010
1011!
1012!--    Output of dvrp-graphics (isosurface, particles, slicer)
1013#if defined( __dvrp_graphics )
1014       CALL DVRP_LOG_EVENT( -2, current_timestep_number-1 )
1015#endif
1016       IF ( time_dvrp >= dt_dvrp )  THEN
1017          CALL data_output_dvrp
1018          time_dvrp = MOD( time_dvrp, MAX( dt_dvrp, dt_3d ) )
1019       ENDIF
1020#if defined( __dvrp_graphics )
1021       CALL DVRP_LOG_EVENT( 2, current_timestep_number )
1022#endif
1023
1024!
1025!--    If required, set the heat flux for the next time step at a random value
1026       IF ( constant_heatflux  .AND.  random_heatflux )  CALL disturb_heatflux
1027
1028!
1029!--    Execute user-defined actions
1030       CALL user_actions( 'after_timestep' )
1031
1032!
1033!--    Determine size of next time step. Save timestep dt_3d because it is
1034!--    newly calculated in routine timestep, but required further below for
1035!--    steering the run control output interval
1036       dt_3d_old = dt_3d
1037       CALL timestep
1038
1039!
1040!--    Synchronize the timestep in case of nested run.
1041       IF ( nested_run )  THEN
1042!
1043!--       Synchronize by unifying the time step.
1044!--       Global minimum of all time-steps is used for all.
1045          CALL pmci_synchronize
1046       ENDIF
1047
1048!
1049!--    Computation and output of run control parameters.
1050!--    This is also done whenever perturbations have been imposed
1051       IF ( time_run_control >= dt_run_control  .OR.                     &
1052            timestep_scheme(1:5) /= 'runge'  .OR.  disturbance_created ) &
1053       THEN
1054          CALL run_control
1055          IF ( time_run_control >= dt_run_control )  THEN
1056             time_run_control = MOD( time_run_control, &
1057                                     MAX( dt_run_control, dt_3d_old ) )
1058          ENDIF
1059       ENDIF
1060
1061!
1062!--    Output elapsed simulated time in form of a progress bar on stdout
1063       IF ( myid == 0 )  CALL output_progress_bar
1064
1065       CALL cpu_log( log_point_s(10), 'timesteps', 'stop' )
1066
1067
1068    ENDDO   ! time loop
1069
1070    IF ( myid == 0 )  CALL finish_progress_bar
1071
1072#if defined( __dvrp_graphics )
1073    CALL DVRP_LOG_EVENT( -2, current_timestep_number )
1074#endif
1075
1076    CALL location_message( 'finished time-stepping', .TRUE. )
1077
1078 END SUBROUTINE time_integration
Note: See TracBrowser for help on using the repository browser.