source: palm/trunk/SOURCE/time_integration.f90 @ 1808

Last change on this file since 1808 was 1808, checked in by raasch, 5 years ago

preprocessor directives using machine dependent flags (lc, ibm, etc.) mostly removed from the code

  • Property svn:keywords set to Id
File size: 43.3 KB
Line 
1!> @file time_integration.f90
2!--------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the terms
6! of the GNU General Public License as published by the Free Software Foundation,
7! either version 3 of the License, or (at your option) any later version.
8!
9! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
10! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
11! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
12!
13! You should have received a copy of the GNU General Public License along with
14! PALM. If not, see <http://www.gnu.org/licenses/>.
15!
16! Copyright 1997-2015 Leibniz Universitaet Hannover
17!--------------------------------------------------------------------------------!
18!
19! Current revisions:
20! ------------------
21! output message in case unscheduled radiation calls removed
22!
23! Former revisions:
24! -----------------
25! $Id: time_integration.f90 1808 2016-04-05 19:44:00Z raasch $
26!
27! 1797 2016-03-21 16:50:28Z raasch
28! introduction of different datatransfer modes
29!
30! 1791 2016-03-11 10:41:25Z raasch
31! call of pmci_update_new removed
32!
33! 1786 2016-03-08 05:49:27Z raasch
34! +module spectrum
35!
36! 1783 2016-03-06 18:36:17Z raasch
37! switch back of netcdf data format for mask output moved to the mask output
38! routine
39!
40! 1781 2016-03-03 15:12:23Z raasch
41! some pmc calls removed at the beginning (before timeloop),
42! pmc initialization moved to the main program
43!
44! 1764 2016-02-28 12:45:19Z raasch
45! PMC_ACTIVE flags removed,
46! bugfix: nest synchronization after first call of timestep
47!
48! 1762 2016-02-25 12:31:13Z hellstea
49! Introduction of nested domain feature
50!
51! 1736 2015-12-04 08:56:33Z raasch
52! no perturbations added to total domain if energy limit has been set zero
53!
54! 1691 2015-10-26 16:17:44Z maronga
55! Added option for spin-ups without land surface and radiation models. Moved calls
56! for radiation and lan surface schemes.
57!
58! 1682 2015-10-07 23:56:08Z knoop
59! Code annotations made doxygen readable
60!
61! 1671 2015-09-25 03:29:37Z raasch
62! bugfix: ghostpoint exchange for array diss in case that sgs velocities are used
63! for particles
64!
65! 1585 2015-04-30 07:05:52Z maronga
66! Moved call of radiation scheme. Added support for RRTM
67!
68! 1551 2015-03-03 14:18:16Z maronga
69! Added interface for different radiation schemes.
70!
71! 1496 2014-12-02 17:25:50Z maronga
72! Added calls for the land surface model and radiation scheme
73!
74! 1402 2014-05-09 14:25:13Z raasch
75! location messages modified
76!
77! 1384 2014-05-02 14:31:06Z raasch
78! location messages added
79!
80! 1380 2014-04-28 12:40:45Z heinze
81! CALL of nudge_ref added
82! bc_pt_t_val and bc_q_t_val are updated in case nudging is used
83!
84! 1365 2014-04-22 15:03:56Z boeske
85! Reset sums_ls_l to zero at each timestep
86! +sums_ls_l
87! Calculation of reference state (previously in subroutine calc_mean_profile)
88
89! 1342 2014-03-26 17:04:47Z kanani
90! REAL constants defined as wp-kind
91!
92! 1320 2014-03-20 08:40:49Z raasch
93! ONLY-attribute added to USE-statements,
94! kind-parameters added to all INTEGER and REAL declaration statements,
95! kinds are defined in new module kinds,
96! old module precision_kind is removed,
97! revision history before 2012 removed,
98! comment fields (!:) to be used for variable explanations added to
99! all variable declaration statements
100! 1318 2014-03-17 13:35:16Z raasch
101! module interfaces removed
102!
103! 1308 2014-03-13 14:58:42Z fricke
104! +netcdf_data_format_save
105! For masked data, parallel netcdf output is not tested so far, hence
106! netcdf_data_format is switched back to non-paralell output.
107!
108! 1276 2014-01-15 13:40:41Z heinze
109! Use LSF_DATA also in case of Dirichlet bottom boundary condition for scalars
110!
111! 1257 2013-11-08 15:18:40Z raasch
112! acc-update-host directive for timestep removed
113!
114! 1241 2013-10-30 11:36:58Z heinze
115! Generalize calc_mean_profile for wider use
116! Determine shf and qsws in dependence on data from LSF_DATA
117! Determine ug and vg in dependence on data from LSF_DATA
118! 1221 2013-09-10 08:59:13Z raasch
119! host update of arrays before timestep is called
120!
121! 1179 2013-06-14 05:57:58Z raasch
122! mean profiles for reference state are only calculated if required,
123! small bugfix for background communication
124!
125! 1171 2013-05-30 11:27:45Z raasch
126! split of prognostic_equations deactivated (comment lines), for the time being
127!
128! 1128 2013-04-12 06:19:32Z raasch
129! asynchronous transfer of ghost point data realized for acc-optimized version:
130! prognostic_equations are first called two times for those points required for
131! the left-right and north-south exchange, respectively, and then for the
132! remaining points,
133! those parts requiring global communication moved from prognostic_equations to
134! here
135!
136! 1115 2013-03-26 18:16:16Z hoffmann
137! calculation of qr and nr is restricted to precipitation
138!
139! 1113 2013-03-10 02:48:14Z raasch
140! GPU-porting of boundary conditions,
141! openACC directives updated
142! formal parameter removed from routine boundary_conds
143!
144! 1111 2013-03-08 23:54:10Z raasch
145! +internal timestep counter for cpu statistics added,
146! openACC directives updated
147!
148! 1092 2013-02-02 11:24:22Z raasch
149! unused variables removed
150!
151! 1065 2012-11-22 17:42:36Z hoffmann
152! exchange of diss (dissipation rate) in case of turbulence = .TRUE. added
153!
154! 1053 2012-11-13 17:11:03Z hoffmann
155! exchange of ghost points for nr, qr added
156!
157! 1036 2012-10-22 13:43:42Z raasch
158! code put under GPL (PALM 3.9)
159!
160! 1019 2012-09-28 06:46:45Z raasch
161! non-optimized version of prognostic_equations removed
162!
163! 1015 2012-09-27 09:23:24Z raasch
164! +call of prognostic_equations_acc
165!
166! 1001 2012-09-13 14:08:46Z raasch
167! all actions concerning leapfrog- and upstream-spline-scheme removed
168!
169! 849 2012-03-15 10:35:09Z raasch
170! advec_particles renamed lpm, first_call_advec_particles renamed first_call_lpm
171!
172! 825 2012-02-19 03:03:44Z raasch
173! wang_collision_kernel renamed wang_kernel
174!
175! Revision 1.1  1997/08/11 06:19:04  raasch
176! Initial revision
177!
178!
179! Description:
180! ------------
181!> Integration in time of the model equations, statistical analysis and graphic
182!> output
183!------------------------------------------------------------------------------!
184 SUBROUTINE time_integration
185 
186
187    USE advec_ws,                                                              &
188        ONLY:  ws_statistics
189
190    USE arrays_3d,                                                             &
191        ONLY:  diss, dzu, e, e_p, nr_p, prho, pt, pt_p, pt_init, q_init, q,    &
192               ql, ql_c, ql_v, ql_vp, qr_p, q_p, ref_state, rho, sa_p, tend,   &
193               u, u_p, v, vpt, v_p, w, w_p
194
195    USE calc_mean_profile_mod,                                                 &
196        ONLY:  calc_mean_profile
197
198    USE control_parameters,                                                    &
199        ONLY:  advected_distance_x, advected_distance_y, average_count_3d,     &
200               average_count_sp, averaging_interval, averaging_interval_pr,    &
201               averaging_interval_sp, bc_lr_cyc, bc_ns_cyc, bc_pt_t_val,       &
202               bc_q_t_val, call_psolver_at_all_substeps, cloud_droplets,       &
203               cloud_physics, constant_flux_layer, constant_heatflux,          &
204               create_disturbances, dopr_n, constant_diffusion, coupling_mode, &
205               coupling_start_time, current_timestep_number,                   &
206               disturbance_created, disturbance_energy_limit, dist_range,      &
207               do_sum, dt_3d, dt_averaging_input, dt_averaging_input_pr,       &
208               dt_coupling, dt_data_output_av, dt_disturb, dt_do2d_xy,         &
209               dt_do2d_xz, dt_do2d_yz, dt_do3d, dt_domask,dt_dopts, dt_dopr,   &
210               dt_dopr_listing, dt_dosp, dt_dots, dt_dvrp, dt_run_control,     &
211               end_time, first_call_lpm, galilei_transformation, humidity,     &
212               icloud_scheme, intermediate_timestep_count,                     &
213               intermediate_timestep_count_max, large_scale_forcing,           &
214               loop_optimization, lsf_surf, lsf_vert, masks, mid, nest_domain, &
215               neutral, nr_timesteps_this_run, nudging,                        &
216               ocean, on_device, passive_scalar, precipitation,                &
217               prho_reference, pt_reference, pt_slope_offset, random_heatflux, &
218               run_coupled, simulated_time, simulated_time_chr,                &
219               skip_time_do2d_xy, skip_time_do2d_xz, skip_time_do2d_yz,        &
220               skip_time_do3d, skip_time_domask, skip_time_dopr,               &
221               skip_time_dosp, skip_time_data_output_av, sloping_surface,      &
222               stop_dt, terminate_coupled, terminate_run, timestep_scheme,     &
223               time_coupling, time_do2d_xy, time_do2d_xz, time_do2d_yz,        &
224               time_do3d, time_domask, time_dopr, time_dopr_av,                &
225               time_dopr_listing, time_dopts, time_dosp, time_dosp_av,         &
226               time_dots, time_do_av, time_do_sla, time_disturb, time_dvrp,    &
227               time_run_control, time_since_reference_point,                   &
228               turbulence,                                                     &
229               turbulent_inflow, use_initial_profile_as_reference,             &
230               use_single_reference_value, u_gtrans, v_gtrans, ws_scheme_mom,  &
231               ws_scheme_sca
232
233    USE cpulog,                                                                &
234        ONLY:  cpu_log, log_point, log_point_s
235
236    USE indices,                                                               &
237        ONLY:  i_left, i_right, j_north, j_south, nbgp, nx, nxl, nxlg, nxr,    &
238               nxrg, nyn, nys, nzb, nzt, nzb_u_inner, nzb_v_inner
239
240    USE interaction_droplets_ptq_mod,                                          &
241        ONLY:  interaction_droplets_ptq
242
243    USE kinds
244
245    USE land_surface_model_mod,                                                &
246        ONLY:  land_surface, lsm_energy_balance, lsm_soil_model,               &
247               skip_time_do_lsm
248
249    USE ls_forcing_mod,                                                        &
250        ONLY:  ls_forcing_surf, ls_forcing_vert
251
252    USE nudge_mod,                                                             &
253        ONLY:  calc_tnudge, nudge_ref
254
255    USE particle_attributes,                                                   &
256        ONLY:  particle_advection, particle_advection_start,                   &
257               use_sgs_for_particles, wang_kernel
258
259    USE pegrid
260
261    USE pmc_interface,                                                         &
262        ONLY:  client_to_server, nested_run, nesting_mode,                     &
263               pmci_client_synchronize, pmci_datatrans,                        &
264               pmci_ensure_nest_mass_conservation,                             &
265               pmci_server_synchronize, server_to_client
266
267    USE production_e_mod,                                                      &
268        ONLY:  production_e_init
269
270    USE progress_bar,                                                          &
271        ONLY:  finish_progress_bar, output_progress_bar
272
273    USE prognostic_equations_mod,                                              &
274        ONLY:  prognostic_equations_acc, prognostic_equations_cache,           &
275               prognostic_equations_vector
276
277    USE radiation_model_mod,                                                   &
278        ONLY: dt_radiation, force_radiation_call, radiation,                   &
279              radiation_clearsky, radiation_rrtmg, radiation_scheme,           &
280              skip_time_do_radiation, time_radiation
281
282    USE spectrum,                                                              &
283        ONLY: calc_spectra
284
285    USE statistics,                                                            &
286        ONLY:  flow_statistics_called, hom, pr_palm, sums_ls_l
287
288    USE surface_layer_fluxes_mod,                                              &
289        ONLY:  surface_layer_fluxes
290
291    USE user_actions_mod,                                                      &
292        ONLY:  user_actions
293
294    IMPLICIT NONE
295
296    CHARACTER (LEN=9) ::  time_to_string          !<
297
298!
299!-- At the beginning of a simulation determine the time step as well as
300!-- determine and print out the run control parameters
301    IF ( simulated_time == 0.0_wp )  CALL timestep
302
303!
304!-- Synchronize the timestep in case of nested run.
305!-- The server side must be called first
306    IF ( nested_run )  THEN
307       CALL pmci_server_synchronize
308       CALL pmci_client_synchronize
309    ENDIF
310
311    CALL run_control
312
313!
314!-- Data exchange between coupled models in case that a call has been omitted
315!-- at the end of the previous run of a job chain.
316    IF ( coupling_mode /= 'uncoupled'  .AND.  run_coupled )  THEN
317!
318!--    In case of model termination initiated by the local model the coupler
319!--    must not be called because this would again cause an MPI hang.
320       DO WHILE ( time_coupling >= dt_coupling .AND. terminate_coupled == 0 )
321          CALL surface_coupler
322          time_coupling = time_coupling - dt_coupling
323       ENDDO
324       IF (time_coupling == 0.0_wp .AND. time_since_reference_point < dt_coupling)&
325       THEN
326          time_coupling = time_since_reference_point
327       ENDIF
328    ENDIF
329
330#if defined( __dvrp_graphics )
331!
332!-- Time measurement with dvrp software 
333    CALL DVRP_LOG_EVENT( 2, current_timestep_number )
334#endif
335
336    CALL location_message( 'start with time-stepping', .TRUE. )
337!
338!-- Start of the time loop
339    DO  WHILE ( simulated_time < end_time  .AND.  .NOT. stop_dt  .AND. &
340                .NOT. terminate_run )
341
342       CALL cpu_log( log_point_s(10), 'timesteps', 'start' )
343
344!
345!--    Determine size of next time step
346       IF ( simulated_time /= 0.0_wp )  THEN
347          CALL timestep
348
349          IF ( nested_run )  THEN
350!
351!--          TO_DO: try to give more detailed and meaningful comments here
352!--          Server side must be called first
353             CALL pmci_server_synchronize
354             CALL pmci_client_synchronize
355          ENDIF
356       ENDIF
357
358
359!
360!--    Determine ug, vg and w_subs in dependence on data from external file
361!--    LSF_DATA
362       IF ( large_scale_forcing .AND. lsf_vert )  THEN
363           CALL ls_forcing_vert ( simulated_time )
364           sums_ls_l = 0.0_wp
365       ENDIF
366
367!
368!--    Set pt_init and q_init to the current profiles taken from
369!--    NUDGING_DATA
370       IF ( nudging )  THEN
371           CALL nudge_ref ( simulated_time )
372!
373!--        Store temperature gradient at the top boundary for possible Neumann
374!--        boundary condition
375           bc_pt_t_val = ( pt_init(nzt+1) - pt_init(nzt) ) / dzu(nzt+1)
376           bc_q_t_val  = ( q_init(nzt+1) - q_init(nzt) ) / dzu(nzt+1)
377       ENDIF
378
379!
380!--    Execute the user-defined actions
381       CALL user_actions( 'before_timestep' )
382
383!
384!--    Start of intermediate step loop
385       intermediate_timestep_count = 0
386       DO  WHILE ( intermediate_timestep_count < &
387                   intermediate_timestep_count_max )
388
389          intermediate_timestep_count = intermediate_timestep_count + 1
390
391!
392!--       Set the steering factors for the prognostic equations which depend
393!--       on the timestep scheme
394          CALL timestep_scheme_steering
395
396!
397!--       Calculate those variables needed in the tendency terms which need
398!--       global communication
399          IF ( .NOT. use_single_reference_value  .AND. &
400               .NOT. use_initial_profile_as_reference )  THEN
401!
402!--          Horizontally averaged profiles to be used as reference state in
403!--          buoyancy terms (WARNING: only the respective last call of
404!--          calc_mean_profile defines the reference state!)
405             IF ( .NOT. neutral )  THEN
406                CALL calc_mean_profile( pt, 4 )
407                ref_state(:)  = hom(:,1,4,0) ! this is used in the buoyancy term
408             ENDIF
409             IF ( ocean )  THEN
410                CALL calc_mean_profile( rho, 64 )
411                ref_state(:)  = hom(:,1,64,0)
412             ENDIF
413             IF ( humidity )  THEN
414                CALL calc_mean_profile( vpt, 44 )
415                ref_state(:)  = hom(:,1,44,0)
416             ENDIF
417
418          ENDIF
419
420          IF ( .NOT. constant_diffusion )  CALL production_e_init
421          IF ( ( ws_scheme_mom .OR. ws_scheme_sca )  .AND.  &
422               intermediate_timestep_count == 1 )  CALL ws_statistics
423!
424!--       In case of nudging calculate current nudging time scale and horizontal
425!--       means of u, v, pt and q
426          IF ( nudging )  THEN
427             CALL calc_tnudge( simulated_time )
428             CALL calc_mean_profile( u, 1 )
429             CALL calc_mean_profile( v, 2 )
430             CALL calc_mean_profile( pt, 4 )
431             CALL calc_mean_profile( q, 41 )
432          ENDIF
433
434!
435!--       Solve the prognostic equations. A fast cache optimized version with
436!--       only one single loop is used in case of Piascek-Williams advection
437!--       scheme. NEC vector machines use a different version, because
438!--       in the other versions a good vectorization is prohibited due to
439!--       inlining problems.
440          IF ( loop_optimization == 'cache' )  THEN
441             CALL prognostic_equations_cache
442          ELSEIF ( loop_optimization == 'vector' )  THEN
443             CALL prognostic_equations_vector
444          ELSEIF ( loop_optimization == 'acc' )  THEN
445             i_left  = nxl;         i_right = nxr
446             j_south = nys;         j_north = nyn
447             CALL prognostic_equations_acc
448
449!             i_left  = nxl;         i_right = nxl+nbgp-1
450!             j_south = nys;         j_north = nyn
451!             CALL prognostic_equations_acc
452!             i_left  = nxr-nbgp+1;  i_right = nxr
453!             j_south = nys;         j_north = nyn
454!             CALL prognostic_equations_acc
455
456!
457!--          Exchange of ghost points (lateral boundary conditions)
458             IF ( background_communication )  THEN
459
460                CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'start' )
461               
462                send_receive = 'lr'
463                sendrecv_in_background = .TRUE.
464                req          = 0
465                req_count    = 0
466
467                IF ( numprocs == 1 )  THEN    ! workaround for single-core GPU runs
468                   on_device = .TRUE.         ! to be removed after complete porting
469                ELSE                          ! of ghost point exchange
470                   !$acc update host( e_p, pt_p, u_p, v_p, w_p )
471                ENDIF
472
473                CALL exchange_horiz( u_p, nbgp )
474                CALL exchange_horiz( v_p, nbgp )
475                CALL exchange_horiz( w_p, nbgp )
476                CALL exchange_horiz( pt_p, nbgp )
477                IF ( .NOT. constant_diffusion )  CALL exchange_horiz( e_p, nbgp )
478                IF ( ocean )  THEN
479                   CALL exchange_horiz( sa_p, nbgp )
480                   CALL exchange_horiz( rho, nbgp )
481                  CALL exchange_horiz( prho, nbgp )
482                ENDIF
483                IF (humidity  .OR.  passive_scalar)  THEN
484                   CALL exchange_horiz( q_p, nbgp )
485                   IF ( cloud_physics .AND. icloud_scheme == 0 )  THEN
486                      CALL exchange_horiz( qr_p, nbgp )
487                      CALL exchange_horiz( nr_p, nbgp )
488                   ENDIF
489                ENDIF
490                IF ( cloud_droplets )  THEN
491                   CALL exchange_horiz( ql, nbgp )
492                   CALL exchange_horiz( ql_c, nbgp )
493                   CALL exchange_horiz( ql_v, nbgp )
494                   CALL exchange_horiz( ql_vp, nbgp )
495                ENDIF
496                IF ( wang_kernel  .OR.  turbulence  .OR.  use_sgs_for_particles ) &
497                THEN
498                   CALL exchange_horiz( diss, nbgp )
499                ENDIF
500
501                IF ( numprocs == 1 )  THEN    ! workaround for single-core GPU runs
502                   on_device = .FALSE.        ! to be removed after complete porting
503                ELSE                          ! of ghost point exchange
504                   !$acc update device( e_p, pt_p, u_p, v_p, w_p )
505                ENDIF
506
507                sendrecv_in_background = .FALSE.
508
509                CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'pause' )
510
511             ENDIF
512
513!             i_left  = nxl+nbgp;    i_right = nxr-nbgp
514!             j_south = nys;         j_north = nys+nbgp-1
515!             CALL prognostic_equations_acc
516!             i_left  = nxl+nbgp;    i_right = nxr-nbgp
517!             j_south = nyn-nbgp+1;  j_north = nyn
518!             CALL prognostic_equations_acc
519
520             IF ( background_communication )  THEN
521                CALL cpu_log( log_point(41), 'exchange-horiz-wait', 'start' )
522#if defined( __parallel )
523                CALL MPI_WAITALL( req_count, req, wait_stat, ierr )
524#endif
525                CALL cpu_log( log_point(41), 'exchange-horiz-wait', 'pause' )
526
527                CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'continue' )
528
529                send_receive = 'ns'
530                sendrecv_in_background = .TRUE.
531                req          = 0
532                req_count    = 0
533
534                IF ( numprocs == 1 )  THEN    ! workaround for single-core GPU runs
535                   on_device = .TRUE.         ! to be removed after complete porting
536                ELSE                          ! of ghost point exchange
537                   !$acc update host( e_p, pt_p, u_p, v_p, w_p )
538                ENDIF
539
540                CALL exchange_horiz( u_p, nbgp )
541                CALL exchange_horiz( v_p, nbgp )
542                CALL exchange_horiz( w_p, nbgp )
543                CALL exchange_horiz( pt_p, nbgp )
544                IF ( .NOT. constant_diffusion )  CALL exchange_horiz( e_p, nbgp )
545                IF ( ocean )  THEN
546                   CALL exchange_horiz( sa_p, nbgp )
547                   CALL exchange_horiz( rho, nbgp )
548                  CALL exchange_horiz( prho, nbgp )
549                ENDIF
550                IF (humidity  .OR.  passive_scalar)  THEN
551                   CALL exchange_horiz( q_p, nbgp )
552                   IF ( cloud_physics .AND. icloud_scheme == 0 )  THEN
553                      CALL exchange_horiz( qr_p, nbgp )
554                      CALL exchange_horiz( nr_p, nbgp )
555                   ENDIF
556                ENDIF
557                IF ( cloud_droplets )  THEN
558                   CALL exchange_horiz( ql, nbgp )
559                   CALL exchange_horiz( ql_c, nbgp )
560                   CALL exchange_horiz( ql_v, nbgp )
561                   CALL exchange_horiz( ql_vp, nbgp )
562                ENDIF
563                IF ( wang_kernel  .OR.  turbulence  .OR.  use_sgs_for_particles ) &
564                THEN
565                   CALL exchange_horiz( diss, nbgp )
566                ENDIF
567
568                IF ( numprocs == 1 )  THEN    ! workaround for single-core GPU runs
569                   on_device = .FALSE.        ! to be removed after complete porting
570                ELSE                          ! of ghost point exchange
571                   !$acc update device( e_p, pt_p, u_p, v_p, w_p )
572                ENDIF
573
574                sendrecv_in_background = .FALSE.
575
576                CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'stop' )
577
578             ENDIF
579
580!             i_left  = nxl+nbgp;    i_right = nxr-nbgp
581!             j_south = nys+nbgp;    j_north = nyn-nbgp
582!             CALL prognostic_equations_acc
583
584             IF ( background_communication )  THEN
585                CALL cpu_log( log_point(41), 'exchange-horiz-wait', 'continue' )
586#if defined( __parallel )
587                CALL MPI_WAITALL( req_count, req, wait_stat, ierr )
588#endif
589                send_receive = 'al'
590                CALL cpu_log( log_point(41), 'exchange-horiz-wait', 'stop' )
591             ENDIF
592
593          ENDIF
594
595!
596!--       Particle transport/physics with the Lagrangian particle model
597!--       (only once during intermediate steps, because it uses an Euler-step)
598!--       ### particle model should be moved before prognostic_equations, in order
599!--       to regard droplet interactions directly
600          IF ( particle_advection  .AND.                         &
601               simulated_time >= particle_advection_start  .AND. &
602               intermediate_timestep_count == 1 )  THEN
603             CALL lpm
604             first_call_lpm = .FALSE.
605          ENDIF
606
607!
608!--       Interaction of droplets with temperature and specific humidity.
609!--       Droplet condensation and evaporation is calculated within
610!--       advec_particles.
611          IF ( cloud_droplets  .AND.  &
612               intermediate_timestep_count == intermediate_timestep_count_max )&
613          THEN
614             CALL interaction_droplets_ptq
615          ENDIF
616
617!
618!--       Exchange of ghost points (lateral boundary conditions)
619          IF ( .NOT. background_communication )  THEN
620
621             CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'start' )
622
623             IF ( numprocs == 1 )  THEN    ! workaround for single-core GPU runs
624                on_device = .TRUE.         ! to be removed after complete porting
625             ELSE                          ! of ghost point exchange
626                !$acc update host( e_p, pt_p, u_p, v_p, w_p )
627             ENDIF
628
629             CALL exchange_horiz( u_p, nbgp )
630             CALL exchange_horiz( v_p, nbgp )
631             CALL exchange_horiz( w_p, nbgp )
632             CALL exchange_horiz( pt_p, nbgp )
633             IF ( .NOT. constant_diffusion )  CALL exchange_horiz( e_p, nbgp )
634             IF ( ocean )  THEN
635                CALL exchange_horiz( sa_p, nbgp )
636                CALL exchange_horiz( rho, nbgp )
637                CALL exchange_horiz( prho, nbgp )
638             ENDIF
639             IF (humidity  .OR.  passive_scalar)  THEN
640                CALL exchange_horiz( q_p, nbgp )
641                IF ( cloud_physics .AND. icloud_scheme == 0  .AND.  &
642                     precipitation )  THEN
643                   CALL exchange_horiz( qr_p, nbgp )
644                   CALL exchange_horiz( nr_p, nbgp )
645                ENDIF
646             ENDIF
647             IF ( cloud_droplets )  THEN
648                CALL exchange_horiz( ql, nbgp )
649                CALL exchange_horiz( ql_c, nbgp )
650                CALL exchange_horiz( ql_v, nbgp )
651                CALL exchange_horiz( ql_vp, nbgp )
652             ENDIF
653             IF ( wang_kernel  .OR.  turbulence  .OR.  use_sgs_for_particles ) &
654             THEN
655                CALL exchange_horiz( diss, nbgp )
656             ENDIF
657
658             IF ( numprocs == 1 )  THEN    ! workaround for single-core GPU runs
659                on_device = .FALSE.        ! to be removed after complete porting
660             ELSE                          ! of ghost point exchange
661                !$acc update device( e_p, pt_p, u_p, v_p, w_p )
662             ENDIF
663
664             CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'stop' )
665
666          ENDIF
667
668!
669!--       Boundary conditions for the prognostic quantities (except of the
670!--       velocities at the outflow in case of a non-cyclic lateral wall)
671          CALL boundary_conds
672
673!
674!--       Swap the time levels in preparation for the next time step.
675          CALL swap_timelevel
676
677          IF ( nested_run )  THEN
678
679             CALL cpu_log( log_point(60), 'nesting', 'start' )
680!
681!--          Domain nesting. The data transfer subroutines pmci_server_datatrans
682!--          and pmci_client_datatatrans are called inside the wrapper
683!--          subroutine pmci_datatrans according to the control parameters
684!--          nesting_mode and nesting_datatransfer_mode.
685!--          TO_DO: why is nesting_mode given as a parameter here?
686             CALL pmci_datatrans( nesting_mode )
687
688             IF ( nesting_mode == 'two-way' )  THEN
689!
690!--             Exchange_horiz is needed for all server-domains after the
691!--             anterpolation
692                CALL exchange_horiz( u, nbgp )
693                CALL exchange_horiz( v, nbgp )
694                CALL exchange_horiz( w, nbgp )
695                CALL exchange_horiz( pt, nbgp )
696                IF ( humidity  .OR.  passive_scalar )  THEN
697                   CALL exchange_horiz( q, nbgp )
698                ENDIF
699                IF ( .NOT. constant_diffusion )  CALL exchange_horiz( e, nbgp )
700             ENDIF
701!
702!--          Correct the w top-BC in nest domains to ensure mass conservation.
703!--          This action must never be done for the root domain.
704             IF ( nest_domain )  THEN
705                CALL pmci_ensure_nest_mass_conservation
706             ENDIF
707
708             CALL cpu_log( log_point(60), 'nesting', 'stop' )
709
710          ENDIF
711
712!
713!--       Temperature offset must be imposed at cyclic boundaries in x-direction
714!--       when a sloping surface is used
715          IF ( sloping_surface )  THEN
716             IF ( nxl ==  0 )  pt(:,:,nxlg:nxl-1) = pt(:,:,nxlg:nxl-1) - &
717                                                    pt_slope_offset
718             IF ( nxr == nx )  pt(:,:,nxr+1:nxrg) = pt(:,:,nxr+1:nxrg) + &
719                                                    pt_slope_offset
720          ENDIF
721
722!
723!--       Impose a turbulent inflow using the recycling method
724          IF ( turbulent_inflow )  CALL  inflow_turbulence
725
726!
727!--       Impose a random perturbation on the horizontal velocity field
728          IF ( create_disturbances  .AND.                                      &
729               ( call_psolver_at_all_substeps  .AND.                           &
730               intermediate_timestep_count == intermediate_timestep_count_max )&
731          .OR. ( .NOT. call_psolver_at_all_substeps  .AND.                     &
732               intermediate_timestep_count == 1 ) )                            &
733          THEN
734             time_disturb = time_disturb + dt_3d
735             IF ( time_disturb >= dt_disturb )  THEN
736                !$acc update host( u, v )
737                IF ( numprocs == 1 )  on_device = .FALSE.  ! workaround, remove later
738                IF ( disturbance_energy_limit /= 0.0_wp  .AND.                 &
739                     hom(nzb+5,1,pr_palm,0) < disturbance_energy_limit )  THEN
740                   CALL disturb_field( nzb_u_inner, tend, u )
741                   CALL disturb_field( nzb_v_inner, tend, v )
742                ELSEIF ( .NOT. bc_lr_cyc  .OR.  .NOT. bc_ns_cyc )  THEN
743!
744!--                Runs with a non-cyclic lateral wall need perturbations
745!--                near the inflow throughout the whole simulation
746                   dist_range = 1
747                   CALL disturb_field( nzb_u_inner, tend, u )
748                   CALL disturb_field( nzb_v_inner, tend, v )
749                   dist_range = 0
750                ENDIF
751                IF ( numprocs == 1 )  on_device = .TRUE.  ! workaround, remove later
752                !$acc update device( u, v )
753                time_disturb = time_disturb - dt_disturb
754             ENDIF
755          ENDIF
756
757!
758!--       Reduce the velocity divergence via the equation for perturbation
759!--       pressure.
760          IF ( intermediate_timestep_count == 1  .OR. &
761                call_psolver_at_all_substeps )  THEN
762             CALL pres
763          ENDIF
764
765!
766!--       If required, compute liquid water content
767          IF ( cloud_physics )  THEN
768             CALL calc_liquid_water_content
769             !$acc update device( ql )
770          ENDIF
771!
772!--       If required, compute virtual potential temperature
773          IF ( humidity )  THEN
774             CALL compute_vpt
775             !$acc update device( vpt )
776          ENDIF
777
778!
779!--       Compute the diffusion quantities
780          IF ( .NOT. constant_diffusion )  THEN
781
782!
783!--          Determine surface fluxes shf and qsws and surface values
784!--          pt_surface and q_surface in dependence on data from external
785!--          file LSF_DATA respectively
786             IF ( ( large_scale_forcing .AND. lsf_surf ) .AND. &
787                 intermediate_timestep_count == intermediate_timestep_count_max )&
788             THEN
789                CALL ls_forcing_surf ( simulated_time )
790             ENDIF
791
792!
793!--          First the vertical fluxes in the surface (constant flux) layer are computed
794             IF ( constant_flux_layer )  THEN
795                CALL cpu_log( log_point(19), 'surface_layer_fluxes', 'start' )
796                CALL surface_layer_fluxes
797                CALL cpu_log( log_point(19), 'surface_layer_fluxes', 'stop' )
798             ENDIF
799
800!
801!--          If required, solve the energy balance for the surface and run soil
802!--          model
803             IF ( land_surface .AND. simulated_time > skip_time_do_lsm)  THEN
804
805                CALL cpu_log( log_point(54), 'land_surface', 'start' )
806                CALL lsm_energy_balance
807                CALL lsm_soil_model
808                CALL cpu_log( log_point(54), 'land_surface', 'stop' )
809             ENDIF
810!
811!--          Compute the diffusion coefficients
812             CALL cpu_log( log_point(17), 'diffusivities', 'start' )
813             IF ( .NOT. humidity ) THEN
814                IF ( ocean )  THEN
815                   CALL diffusivities( prho, prho_reference )
816                ELSE
817                   CALL diffusivities( pt, pt_reference )
818                ENDIF
819             ELSE
820                CALL diffusivities( vpt, pt_reference )
821             ENDIF
822             CALL cpu_log( log_point(17), 'diffusivities', 'stop' )
823
824          ENDIF
825
826!
827!--       If required, calculate radiative fluxes and heating rates
828          IF ( radiation .AND. intermediate_timestep_count                     &
829               == intermediate_timestep_count_max .AND. simulated_time >    &
830               skip_time_do_radiation )  THEN
831
832               time_radiation = time_radiation + dt_3d
833
834             IF ( time_radiation >= dt_radiation .OR. force_radiation_call )   &
835             THEN
836
837                CALL cpu_log( log_point(50), 'radiation', 'start' )
838
839                IF ( .NOT. force_radiation_call )  THEN
840                   time_radiation = time_radiation - dt_radiation
841                ENDIF
842
843                IF ( radiation_scheme == 'clear-sky' )  THEN
844                   CALL radiation_clearsky
845                ELSEIF ( radiation_scheme == 'rrtmg' )  THEN
846                   CALL radiation_rrtmg
847                ENDIF
848
849                CALL cpu_log( log_point(50), 'radiation', 'stop' )
850             ENDIF
851          ENDIF
852
853       ENDDO   ! Intermediate step loop
854
855!
856!--    Increase simulation time and output times
857       nr_timesteps_this_run      = nr_timesteps_this_run + 1
858       current_timestep_number    = current_timestep_number + 1
859       simulated_time             = simulated_time   + dt_3d
860       simulated_time_chr         = time_to_string( simulated_time )
861       time_since_reference_point = simulated_time - coupling_start_time
862
863       IF ( simulated_time >= skip_time_data_output_av )  THEN
864          time_do_av         = time_do_av       + dt_3d
865       ENDIF
866       IF ( simulated_time >= skip_time_do2d_xy )  THEN
867          time_do2d_xy       = time_do2d_xy     + dt_3d
868       ENDIF
869       IF ( simulated_time >= skip_time_do2d_xz )  THEN
870          time_do2d_xz       = time_do2d_xz     + dt_3d
871       ENDIF
872       IF ( simulated_time >= skip_time_do2d_yz )  THEN
873          time_do2d_yz       = time_do2d_yz     + dt_3d
874       ENDIF
875       IF ( simulated_time >= skip_time_do3d    )  THEN
876          time_do3d          = time_do3d        + dt_3d
877       ENDIF
878       DO  mid = 1, masks
879          IF ( simulated_time >= skip_time_domask(mid) )  THEN
880             time_domask(mid)= time_domask(mid) + dt_3d
881          ENDIF
882       ENDDO
883       time_dvrp          = time_dvrp        + dt_3d
884       IF ( simulated_time >= skip_time_dosp )  THEN
885          time_dosp       = time_dosp        + dt_3d
886       ENDIF
887       time_dots          = time_dots        + dt_3d
888       IF ( .NOT. first_call_lpm )  THEN
889          time_dopts      = time_dopts       + dt_3d
890       ENDIF
891       IF ( simulated_time >= skip_time_dopr )  THEN
892          time_dopr       = time_dopr        + dt_3d
893       ENDIF
894       time_dopr_listing          = time_dopr_listing        + dt_3d
895       time_run_control   = time_run_control + dt_3d
896
897!
898!--    Data exchange between coupled models
899       IF ( coupling_mode /= 'uncoupled'  .AND.  run_coupled )  THEN
900          time_coupling = time_coupling + dt_3d
901
902!
903!--       In case of model termination initiated by the local model
904!--       (terminate_coupled > 0), the coupler must be skipped because it would
905!--       cause an MPI intercomminucation hang.
906!--       If necessary, the coupler will be called at the beginning of the
907!--       next restart run.
908          DO WHILE ( time_coupling >= dt_coupling .AND. terminate_coupled == 0 )
909             CALL surface_coupler
910             time_coupling = time_coupling - dt_coupling
911          ENDDO
912       ENDIF
913
914!
915!--    Execute user-defined actions
916       CALL user_actions( 'after_integration' )
917
918!
919!--    If Galilei transformation is used, determine the distance that the
920!--    model has moved so far
921       IF ( galilei_transformation )  THEN
922          advected_distance_x = advected_distance_x + u_gtrans * dt_3d
923          advected_distance_y = advected_distance_y + v_gtrans * dt_3d
924       ENDIF
925
926!
927!--    Check, if restart is necessary (because cpu-time is expiring or
928!--    because it is forced by user) and set stop flag
929!--    This call is skipped if the remote model has already initiated a restart.
930       IF ( .NOT. terminate_run )  CALL check_for_restart
931
932!
933!--    Carry out statistical analysis and output at the requested output times.
934!--    The MOD function is used for calculating the output time counters (like
935!--    time_dopr) in order to regard a possible decrease of the output time
936!--    interval in case of restart runs
937
938!
939!--    Set a flag indicating that so far no statistics have been created
940!--    for this time step
941       flow_statistics_called = .FALSE.
942
943!
944!--    If required, call flow_statistics for averaging in time
945       IF ( averaging_interval_pr /= 0.0_wp  .AND.  &
946            ( dt_dopr - time_dopr ) <= averaging_interval_pr  .AND.  &
947            simulated_time >= skip_time_dopr )  THEN
948          time_dopr_av = time_dopr_av + dt_3d
949          IF ( time_dopr_av >= dt_averaging_input_pr )  THEN
950             do_sum = .TRUE.
951             time_dopr_av = MOD( time_dopr_av, &
952                                    MAX( dt_averaging_input_pr, dt_3d ) )
953          ENDIF
954       ENDIF
955       IF ( do_sum )  CALL flow_statistics
956
957!
958!--    Sum-up 3d-arrays for later output of time-averaged 2d/3d/masked data
959       IF ( averaging_interval /= 0.0_wp  .AND.                                &
960            ( dt_data_output_av - time_do_av ) <= averaging_interval  .AND. &
961            simulated_time >= skip_time_data_output_av )                    &
962       THEN
963          time_do_sla = time_do_sla + dt_3d
964          IF ( time_do_sla >= dt_averaging_input )  THEN
965             CALL sum_up_3d_data
966             average_count_3d = average_count_3d + 1
967             time_do_sla = MOD( time_do_sla, MAX( dt_averaging_input, dt_3d ) )
968          ENDIF
969       ENDIF
970
971!
972!--    Calculate spectra for time averaging
973       IF ( averaging_interval_sp /= 0.0_wp  .AND.  &
974            ( dt_dosp - time_dosp ) <= averaging_interval_sp  .AND.  &
975            simulated_time >= skip_time_dosp )  THEN
976          time_dosp_av = time_dosp_av + dt_3d
977          IF ( time_dosp_av >= dt_averaging_input_pr )  THEN
978             CALL calc_spectra
979             time_dosp_av = MOD( time_dosp_av, &
980                                 MAX( dt_averaging_input_pr, dt_3d ) )
981          ENDIF
982       ENDIF
983
984!
985!--    Computation and output of run control parameters.
986!--    This is also done whenever perturbations have been imposed
987       IF ( time_run_control >= dt_run_control  .OR.                     &
988            timestep_scheme(1:5) /= 'runge'  .OR.  disturbance_created ) &
989       THEN
990          CALL run_control
991          IF ( time_run_control >= dt_run_control )  THEN
992             time_run_control = MOD( time_run_control, &
993                                     MAX( dt_run_control, dt_3d ) )
994          ENDIF
995       ENDIF
996
997!
998!--    Profile output (ASCII) on file
999       IF ( time_dopr_listing >= dt_dopr_listing )  THEN
1000          CALL print_1d
1001          time_dopr_listing = MOD( time_dopr_listing, MAX( dt_dopr_listing, &
1002                                                           dt_3d ) )
1003       ENDIF
1004
1005!
1006!--    Graphic output for PROFIL
1007       IF ( time_dopr >= dt_dopr )  THEN
1008          IF ( dopr_n /= 0 )  CALL data_output_profiles
1009          time_dopr = MOD( time_dopr, MAX( dt_dopr, dt_3d ) )
1010          time_dopr_av = 0.0_wp    ! due to averaging (see above)
1011       ENDIF
1012
1013!
1014!--    Graphic output for time series
1015       IF ( time_dots >= dt_dots )  THEN
1016          CALL data_output_tseries
1017          time_dots = MOD( time_dots, MAX( dt_dots, dt_3d ) )
1018       ENDIF
1019
1020!
1021!--    Output of spectra (formatted for use with PROFIL), in case of no
1022!--    time averaging, spectra has to be calculated before
1023       IF ( time_dosp >= dt_dosp )  THEN
1024          IF ( average_count_sp == 0 )  CALL calc_spectra
1025          CALL data_output_spectra
1026          time_dosp = MOD( time_dosp, MAX( dt_dosp, dt_3d ) )
1027       ENDIF
1028
1029!
1030!--    2d-data output (cross-sections)
1031       IF ( time_do2d_xy >= dt_do2d_xy )  THEN
1032          CALL data_output_2d( 'xy', 0 )
1033          time_do2d_xy = MOD( time_do2d_xy, MAX( dt_do2d_xy, dt_3d ) )
1034       ENDIF
1035       IF ( time_do2d_xz >= dt_do2d_xz )  THEN
1036          CALL data_output_2d( 'xz', 0 )
1037          time_do2d_xz = MOD( time_do2d_xz, MAX( dt_do2d_xz, dt_3d ) )
1038       ENDIF
1039       IF ( time_do2d_yz >= dt_do2d_yz )  THEN
1040          CALL data_output_2d( 'yz', 0 )
1041          time_do2d_yz = MOD( time_do2d_yz, MAX( dt_do2d_yz, dt_3d ) )
1042       ENDIF
1043
1044!
1045!--    3d-data output (volume data)
1046       IF ( time_do3d >= dt_do3d )  THEN
1047          CALL data_output_3d( 0 )
1048          time_do3d = MOD( time_do3d, MAX( dt_do3d, dt_3d ) )
1049       ENDIF
1050
1051!
1052!--    Masked data output
1053       DO  mid = 1, masks
1054          IF ( time_domask(mid) >= dt_domask(mid) )  THEN
1055             CALL data_output_mask( 0 )
1056             time_domask(mid) = MOD( time_domask(mid),  &
1057                                     MAX( dt_domask(mid), dt_3d ) )
1058          ENDIF
1059       ENDDO
1060
1061!
1062!--    Output of time-averaged 2d/3d/masked data
1063       IF ( time_do_av >= dt_data_output_av )  THEN
1064          CALL average_3d_data
1065          CALL data_output_2d( 'xy', 1 )
1066          CALL data_output_2d( 'xz', 1 )
1067          CALL data_output_2d( 'yz', 1 )
1068          CALL data_output_3d( 1 )
1069          DO  mid = 1, masks
1070             CALL data_output_mask( 1 )
1071          ENDDO
1072          time_do_av = MOD( time_do_av, MAX( dt_data_output_av, dt_3d ) )
1073       ENDIF
1074
1075!
1076!--    Output of particle time series
1077       IF ( particle_advection )  THEN
1078          IF ( time_dopts >= dt_dopts  .OR. &
1079               ( simulated_time >= particle_advection_start  .AND. &
1080                 first_call_lpm ) )  THEN
1081             CALL data_output_ptseries
1082             time_dopts = MOD( time_dopts, MAX( dt_dopts, dt_3d ) )
1083          ENDIF
1084       ENDIF
1085
1086!
1087!--    Output of dvrp-graphics (isosurface, particles, slicer)
1088#if defined( __dvrp_graphics )
1089       CALL DVRP_LOG_EVENT( -2, current_timestep_number-1 )
1090#endif
1091       IF ( time_dvrp >= dt_dvrp )  THEN
1092          CALL data_output_dvrp
1093          time_dvrp = MOD( time_dvrp, MAX( dt_dvrp, dt_3d ) )
1094       ENDIF
1095#if defined( __dvrp_graphics )
1096       CALL DVRP_LOG_EVENT( 2, current_timestep_number )
1097#endif
1098
1099!
1100!--    If required, set the heat flux for the next time step at a random value
1101       IF ( constant_heatflux  .AND.  random_heatflux )  CALL disturb_heatflux
1102
1103!
1104!--    Execute user-defined actions
1105       CALL user_actions( 'after_timestep' )
1106
1107!
1108!--    Output elapsed simulated time in form of a progress bar on stdout
1109       IF ( myid == 0 )  CALL output_progress_bar
1110
1111       CALL cpu_log( log_point_s(10), 'timesteps', 'stop' )
1112
1113
1114    ENDDO   ! time loop
1115
1116    IF ( myid == 0 )  CALL finish_progress_bar
1117
1118#if defined( __dvrp_graphics )
1119    CALL DVRP_LOG_EVENT( -2, current_timestep_number )
1120#endif
1121
1122    CALL location_message( 'finished time-stepping', .TRUE. )
1123
1124 END SUBROUTINE time_integration
Note: See TracBrowser for help on using the repository browser.