source: palm/trunk/SOURCE/time_integration.f90 @ 1792

Last change on this file since 1792 was 1792, checked in by raasch, 6 years ago

last commit documented

  • Property svn:keywords set to Id
File size: 43.5 KB
Line 
1!> @file time_integration.f90
2!--------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the terms
6! of the GNU General Public License as published by the Free Software Foundation,
7! either version 3 of the License, or (at your option) any later version.
8!
9! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
10! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
11! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
12!
13! You should have received a copy of the GNU General Public License along with
14! PALM. If not, see <http://www.gnu.org/licenses/>.
15!
16! Copyright 1997-2015 Leibniz Universitaet Hannover
17!--------------------------------------------------------------------------------!
18!
19! Current revisions:
20! ------------------
21!
22!
23! Former revisions:
24! -----------------
25! $Id: time_integration.f90 1792 2016-03-11 10:48:08Z raasch $
26!
27! 1791 2016-03-11 10:41:25Z raasch
28! call of pmci_update_new removed
29!
30! 1786 2016-03-08 05:49:27Z raasch
31! +module spectrum
32!
33! 1783 2016-03-06 18:36:17Z raasch
34! switch back of netcdf data format for mask output moved to the mask output
35! routine
36!
37! 1781 2016-03-03 15:12:23Z raasch
38! some pmc calls removed at the beginning (before timeloop),
39! pmc initialization moved to the main program
40!
41! 1764 2016-02-28 12:45:19Z raasch
42! PMC_ACTIVE flags removed,
43! bugfix: nest synchronization after first call of timestep
44!
45! 1762 2016-02-25 12:31:13Z hellstea
46! Introduction of nested domain feature
47!
48! 1736 2015-12-04 08:56:33Z raasch
49! no perturbations added to total domain if energy limit has been set zero
50!
51! 1691 2015-10-26 16:17:44Z maronga
52! Added option for spin-ups without land surface and radiation models. Moved calls
53! for radiation and lan surface schemes.
54!
55! 1682 2015-10-07 23:56:08Z knoop
56! Code annotations made doxygen readable
57!
58! 1671 2015-09-25 03:29:37Z raasch
59! bugfix: ghostpoint exchange for array diss in case that sgs velocities are used
60! for particles
61!
62! 1585 2015-04-30 07:05:52Z maronga
63! Moved call of radiation scheme. Added support for RRTM
64!
65! 1551 2015-03-03 14:18:16Z maronga
66! Added interface for different radiation schemes.
67!
68! 1496 2014-12-02 17:25:50Z maronga
69! Added calls for the land surface model and radiation scheme
70!
71! 1402 2014-05-09 14:25:13Z raasch
72! location messages modified
73!
74! 1384 2014-05-02 14:31:06Z raasch
75! location messages added
76!
77! 1380 2014-04-28 12:40:45Z heinze
78! CALL of nudge_ref added
79! bc_pt_t_val and bc_q_t_val are updated in case nudging is used
80!
81! 1365 2014-04-22 15:03:56Z boeske
82! Reset sums_ls_l to zero at each timestep
83! +sums_ls_l
84! Calculation of reference state (previously in subroutine calc_mean_profile)
85
86! 1342 2014-03-26 17:04:47Z kanani
87! REAL constants defined as wp-kind
88!
89! 1320 2014-03-20 08:40:49Z raasch
90! ONLY-attribute added to USE-statements,
91! kind-parameters added to all INTEGER and REAL declaration statements,
92! kinds are defined in new module kinds,
93! old module precision_kind is removed,
94! revision history before 2012 removed,
95! comment fields (!:) to be used for variable explanations added to
96! all variable declaration statements
97! 1318 2014-03-17 13:35:16Z raasch
98! module interfaces removed
99!
100! 1308 2014-03-13 14:58:42Z fricke
101! +netcdf_data_format_save
102! For masked data, parallel netcdf output is not tested so far, hence
103! netcdf_data_format is switched back to non-paralell output.
104!
105! 1276 2014-01-15 13:40:41Z heinze
106! Use LSF_DATA also in case of Dirichlet bottom boundary condition for scalars
107!
108! 1257 2013-11-08 15:18:40Z raasch
109! acc-update-host directive for timestep removed
110!
111! 1241 2013-10-30 11:36:58Z heinze
112! Generalize calc_mean_profile for wider use
113! Determine shf and qsws in dependence on data from LSF_DATA
114! Determine ug and vg in dependence on data from LSF_DATA
115! 1221 2013-09-10 08:59:13Z raasch
116! host update of arrays before timestep is called
117!
118! 1179 2013-06-14 05:57:58Z raasch
119! mean profiles for reference state are only calculated if required,
120! small bugfix for background communication
121!
122! 1171 2013-05-30 11:27:45Z raasch
123! split of prognostic_equations deactivated (comment lines), for the time being
124!
125! 1128 2013-04-12 06:19:32Z raasch
126! asynchronous transfer of ghost point data realized for acc-optimized version:
127! prognostic_equations are first called two times for those points required for
128! the left-right and north-south exchange, respectively, and then for the
129! remaining points,
130! those parts requiring global communication moved from prognostic_equations to
131! here
132!
133! 1115 2013-03-26 18:16:16Z hoffmann
134! calculation of qr and nr is restricted to precipitation
135!
136! 1113 2013-03-10 02:48:14Z raasch
137! GPU-porting of boundary conditions,
138! openACC directives updated
139! formal parameter removed from routine boundary_conds
140!
141! 1111 2013-03-08 23:54:10Z raasch
142! +internal timestep counter for cpu statistics added,
143! openACC directives updated
144!
145! 1092 2013-02-02 11:24:22Z raasch
146! unused variables removed
147!
148! 1065 2012-11-22 17:42:36Z hoffmann
149! exchange of diss (dissipation rate) in case of turbulence = .TRUE. added
150!
151! 1053 2012-11-13 17:11:03Z hoffmann
152! exchange of ghost points for nr, qr added
153!
154! 1036 2012-10-22 13:43:42Z raasch
155! code put under GPL (PALM 3.9)
156!
157! 1019 2012-09-28 06:46:45Z raasch
158! non-optimized version of prognostic_equations removed
159!
160! 1015 2012-09-27 09:23:24Z raasch
161! +call of prognostic_equations_acc
162!
163! 1001 2012-09-13 14:08:46Z raasch
164! all actions concerning leapfrog- and upstream-spline-scheme removed
165!
166! 849 2012-03-15 10:35:09Z raasch
167! advec_particles renamed lpm, first_call_advec_particles renamed first_call_lpm
168!
169! 825 2012-02-19 03:03:44Z raasch
170! wang_collision_kernel renamed wang_kernel
171!
172! Revision 1.1  1997/08/11 06:19:04  raasch
173! Initial revision
174!
175!
176! Description:
177! ------------
178!> Integration in time of the model equations, statistical analysis and graphic
179!> output
180!------------------------------------------------------------------------------!
181 SUBROUTINE time_integration
182 
183
184    USE advec_ws,                                                              &
185        ONLY:  ws_statistics
186
187    USE arrays_3d,                                                             &
188        ONLY:  diss, dzu, e, e_p, nr_p, prho, pt, pt_p, pt_init, q_init, q,    &
189               ql, ql_c, ql_v, ql_vp, qr_p, q_p, ref_state, rho, sa_p, tend,   &
190               u, u_p, v, vpt, v_p, w, w_p
191
192    USE calc_mean_profile_mod,                                                 &
193        ONLY:  calc_mean_profile
194
195    USE control_parameters,                                                    &
196        ONLY:  advected_distance_x, advected_distance_y, average_count_3d,     &
197               average_count_sp, averaging_interval, averaging_interval_pr,    &
198               averaging_interval_sp, bc_lr_cyc, bc_ns_cyc, bc_pt_t_val,       &
199               bc_q_t_val, call_psolver_at_all_substeps, cloud_droplets,       &
200               cloud_physics, constant_flux_layer, constant_heatflux,          &
201               create_disturbances, dopr_n, constant_diffusion, coupling_mode, &
202               coupling_start_time, current_timestep_number,                   &
203               disturbance_created, disturbance_energy_limit, dist_range,      &
204               do_sum, dt_3d, dt_averaging_input, dt_averaging_input_pr,       &
205               dt_coupling, dt_data_output_av, dt_disturb, dt_do2d_xy,         &
206               dt_do2d_xz, dt_do2d_yz, dt_do3d, dt_domask,dt_dopts, dt_dopr,   &
207               dt_dopr_listing, dt_dosp, dt_dots, dt_dvrp, dt_run_control,     &
208               end_time, first_call_lpm, galilei_transformation, humidity,     &
209               icloud_scheme, intermediate_timestep_count,                     &
210               intermediate_timestep_count_max, large_scale_forcing,           &
211               loop_optimization, lsf_surf, lsf_vert, masks, mid, nest_domain, &
212               neutral, nr_timesteps_this_run, nudging,                        &
213               ocean, on_device, passive_scalar, precipitation,                &
214               prho_reference, pt_reference, pt_slope_offset, random_heatflux, &
215               run_coupled, simulated_time, simulated_time_chr,                &
216               skip_time_do2d_xy, skip_time_do2d_xz, skip_time_do2d_yz,        &
217               skip_time_do3d, skip_time_domask, skip_time_dopr,               &
218               skip_time_dosp, skip_time_data_output_av, sloping_surface,      &
219               stop_dt, terminate_coupled, terminate_run, timestep_scheme,     &
220               time_coupling, time_do2d_xy, time_do2d_xz, time_do2d_yz,        &
221               time_do3d, time_domask, time_dopr, time_dopr_av,                &
222               time_dopr_listing, time_dopts, time_dosp, time_dosp_av,         &
223               time_dots, time_do_av, time_do_sla, time_disturb, time_dvrp,    &
224               time_run_control, time_since_reference_point,                   &
225               turbulence,                                                     &
226               turbulent_inflow, use_initial_profile_as_reference,             &
227               use_single_reference_value, u_gtrans, v_gtrans, ws_scheme_mom,  &
228               ws_scheme_sca
229
230    USE cpulog,                                                                &
231        ONLY:  cpu_log, log_point, log_point_s
232
233    USE indices,                                                               &
234        ONLY:  i_left, i_right, j_north, j_south, nbgp, nx, nxl, nxlg, nxr,    &
235               nxrg, nyn, nys, nzb, nzt, nzb_u_inner, nzb_v_inner
236
237    USE interaction_droplets_ptq_mod,                                          &
238        ONLY:  interaction_droplets_ptq
239
240    USE kinds
241
242    USE land_surface_model_mod,                                                &
243        ONLY:  land_surface, lsm_energy_balance, lsm_soil_model,               &
244               skip_time_do_lsm
245
246    USE ls_forcing_mod,                                                        &
247        ONLY:  ls_forcing_surf, ls_forcing_vert
248
249    USE nudge_mod,                                                             &
250        ONLY:  calc_tnudge, nudge_ref
251
252    USE particle_attributes,                                                   &
253        ONLY:  particle_advection, particle_advection_start,                   &
254               use_sgs_for_particles, wang_kernel
255
256    USE pegrid
257
258    USE pmc_interface,                                                         &
259        ONLY:  client_to_server, nested_run, nesting_mode,                     &
260               pmci_ensure_nest_mass_conservation, pmci_client_datatrans,      &
261               pmci_client_synchronize, pmci_server_datatrans,                 &
262               pmci_server_synchronize, server_to_client
263
264    USE production_e_mod,                                                      &
265        ONLY:  production_e_init
266
267    USE progress_bar,                                                          &
268        ONLY:  finish_progress_bar, output_progress_bar
269
270    USE prognostic_equations_mod,                                              &
271        ONLY:  prognostic_equations_acc, prognostic_equations_cache,           &
272               prognostic_equations_vector
273
274    USE radiation_model_mod,                                                   &
275        ONLY: dt_radiation, force_radiation_call, radiation,                   &
276              radiation_clearsky, radiation_rrtmg, radiation_scheme,           &
277              skip_time_do_radiation, time_radiation
278
279    USE spectrum,                                                              &
280        ONLY: calc_spectra
281
282    USE statistics,                                                            &
283        ONLY:  flow_statistics_called, hom, pr_palm, sums_ls_l
284
285    USE surface_layer_fluxes_mod,                                              &
286        ONLY:  surface_layer_fluxes
287
288    USE user_actions_mod,                                                      &
289        ONLY:  user_actions
290
291    IMPLICIT NONE
292
293    CHARACTER (LEN=9) ::  time_to_string          !<
294
295!
296!-- At the beginning of a simulation determine the time step as well as
297!-- determine and print out the run control parameters
298    IF ( simulated_time == 0.0_wp )  CALL timestep
299
300!
301!-- Synchronize the timestep in case of nested run.
302!-- The server side must be called first
303    IF ( nested_run )  THEN
304       CALL pmci_server_synchronize
305       CALL pmci_client_synchronize
306    ENDIF
307
308    CALL run_control
309
310!
311!-- Data exchange between coupled models in case that a call has been omitted
312!-- at the end of the previous run of a job chain.
313    IF ( coupling_mode /= 'uncoupled'  .AND.  run_coupled )  THEN
314!
315!--    In case of model termination initiated by the local model the coupler
316!--    must not be called because this would again cause an MPI hang.
317       DO WHILE ( time_coupling >= dt_coupling .AND. terminate_coupled == 0 )
318          CALL surface_coupler
319          time_coupling = time_coupling - dt_coupling
320       ENDDO
321       IF (time_coupling == 0.0_wp .AND. time_since_reference_point < dt_coupling)&
322       THEN
323          time_coupling = time_since_reference_point
324       ENDIF
325    ENDIF
326
327#if defined( __dvrp_graphics )
328!
329!-- Time measurement with dvrp software 
330    CALL DVRP_LOG_EVENT( 2, current_timestep_number )
331#endif
332
333    CALL location_message( 'start with time-stepping', .TRUE. )
334!
335!-- Start of the time loop
336    DO  WHILE ( simulated_time < end_time  .AND.  .NOT. stop_dt  .AND. &
337                .NOT. terminate_run )
338
339       CALL cpu_log( log_point_s(10), 'timesteps', 'start' )
340
341!
342!--    Determine size of next time step
343       IF ( simulated_time /= 0.0_wp )  THEN
344          CALL timestep
345
346          IF ( nested_run )  THEN
347!
348!--          TO_DO: try to give more detailed and meaningful comments here
349!--          Server side must be called first
350             CALL pmci_server_synchronize
351             CALL pmci_client_synchronize
352          ENDIF
353       ENDIF
354
355
356!
357!--    Determine ug, vg and w_subs in dependence on data from external file
358!--    LSF_DATA
359       IF ( large_scale_forcing .AND. lsf_vert )  THEN
360           CALL ls_forcing_vert ( simulated_time )
361           sums_ls_l = 0.0_wp
362       ENDIF
363
364!
365!--    Set pt_init and q_init to the current profiles taken from
366!--    NUDGING_DATA
367       IF ( nudging )  THEN
368           CALL nudge_ref ( simulated_time )
369!
370!--        Store temperature gradient at the top boundary for possible Neumann
371!--        boundary condition
372           bc_pt_t_val = ( pt_init(nzt+1) - pt_init(nzt) ) / dzu(nzt+1)
373           bc_q_t_val  = ( q_init(nzt+1) - q_init(nzt) ) / dzu(nzt+1)
374       ENDIF
375
376!
377!--    Execute the user-defined actions
378       CALL user_actions( 'before_timestep' )
379
380!
381!--    Start of intermediate step loop
382       intermediate_timestep_count = 0
383       DO  WHILE ( intermediate_timestep_count < &
384                   intermediate_timestep_count_max )
385
386          intermediate_timestep_count = intermediate_timestep_count + 1
387
388!
389!--       Set the steering factors for the prognostic equations which depend
390!--       on the timestep scheme
391          CALL timestep_scheme_steering
392
393!
394!--       Calculate those variables needed in the tendency terms which need
395!--       global communication
396          IF ( .NOT. use_single_reference_value  .AND. &
397               .NOT. use_initial_profile_as_reference )  THEN
398!
399!--          Horizontally averaged profiles to be used as reference state in
400!--          buoyancy terms (WARNING: only the respective last call of
401!--          calc_mean_profile defines the reference state!)
402             IF ( .NOT. neutral )  THEN
403                CALL calc_mean_profile( pt, 4 )
404                ref_state(:)  = hom(:,1,4,0) ! this is used in the buoyancy term
405             ENDIF
406             IF ( ocean )  THEN
407                CALL calc_mean_profile( rho, 64 )
408                ref_state(:)  = hom(:,1,64,0)
409             ENDIF
410             IF ( humidity )  THEN
411                CALL calc_mean_profile( vpt, 44 )
412                ref_state(:)  = hom(:,1,44,0)
413             ENDIF
414
415          ENDIF
416
417          IF ( .NOT. constant_diffusion )  CALL production_e_init
418          IF ( ( ws_scheme_mom .OR. ws_scheme_sca )  .AND.  &
419               intermediate_timestep_count == 1 )  CALL ws_statistics
420!
421!--       In case of nudging calculate current nudging time scale and horizontal
422!--       means of u, v, pt and q
423          IF ( nudging )  THEN
424             CALL calc_tnudge( simulated_time )
425             CALL calc_mean_profile( u, 1 )
426             CALL calc_mean_profile( v, 2 )
427             CALL calc_mean_profile( pt, 4 )
428             CALL calc_mean_profile( q, 41 )
429          ENDIF
430
431!
432!--       Solve the prognostic equations. A fast cache optimized version with
433!--       only one single loop is used in case of Piascek-Williams advection
434!--       scheme. NEC vector machines use a different version, because
435!--       in the other versions a good vectorization is prohibited due to
436!--       inlining problems.
437          IF ( loop_optimization == 'cache' )  THEN
438             CALL prognostic_equations_cache
439          ELSEIF ( loop_optimization == 'vector' )  THEN
440             CALL prognostic_equations_vector
441          ELSEIF ( loop_optimization == 'acc' )  THEN
442             i_left  = nxl;         i_right = nxr
443             j_south = nys;         j_north = nyn
444             CALL prognostic_equations_acc
445
446!             i_left  = nxl;         i_right = nxl+nbgp-1
447!             j_south = nys;         j_north = nyn
448!             CALL prognostic_equations_acc
449!             i_left  = nxr-nbgp+1;  i_right = nxr
450!             j_south = nys;         j_north = nyn
451!             CALL prognostic_equations_acc
452
453!
454!--          Exchange of ghost points (lateral boundary conditions)
455             IF ( background_communication )  THEN
456
457                CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'start' )
458               
459                send_receive = 'lr'
460                sendrecv_in_background = .TRUE.
461                req          = 0
462                req_count    = 0
463
464                IF ( numprocs == 1 )  THEN    ! workaround for single-core GPU runs
465                   on_device = .TRUE.         ! to be removed after complete porting
466                ELSE                          ! of ghost point exchange
467                   !$acc update host( e_p, pt_p, u_p, v_p, w_p )
468                ENDIF
469
470                CALL exchange_horiz( u_p, nbgp )
471                CALL exchange_horiz( v_p, nbgp )
472                CALL exchange_horiz( w_p, nbgp )
473                CALL exchange_horiz( pt_p, nbgp )
474                IF ( .NOT. constant_diffusion )  CALL exchange_horiz( e_p, nbgp )
475                IF ( ocean )  THEN
476                   CALL exchange_horiz( sa_p, nbgp )
477                   CALL exchange_horiz( rho, nbgp )
478                  CALL exchange_horiz( prho, nbgp )
479                ENDIF
480                IF (humidity  .OR.  passive_scalar)  THEN
481                   CALL exchange_horiz( q_p, nbgp )
482                   IF ( cloud_physics .AND. icloud_scheme == 0 )  THEN
483                      CALL exchange_horiz( qr_p, nbgp )
484                      CALL exchange_horiz( nr_p, nbgp )
485                   ENDIF
486                ENDIF
487                IF ( cloud_droplets )  THEN
488                   CALL exchange_horiz( ql, nbgp )
489                   CALL exchange_horiz( ql_c, nbgp )
490                   CALL exchange_horiz( ql_v, nbgp )
491                   CALL exchange_horiz( ql_vp, nbgp )
492                ENDIF
493                IF ( wang_kernel  .OR.  turbulence  .OR.  use_sgs_for_particles ) &
494                THEN
495                   CALL exchange_horiz( diss, nbgp )
496                ENDIF
497
498                IF ( numprocs == 1 )  THEN    ! workaround for single-core GPU runs
499                   on_device = .FALSE.        ! to be removed after complete porting
500                ELSE                          ! of ghost point exchange
501                   !$acc update device( e_p, pt_p, u_p, v_p, w_p )
502                ENDIF
503
504                sendrecv_in_background = .FALSE.
505
506                CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'pause' )
507
508             ENDIF
509
510!             i_left  = nxl+nbgp;    i_right = nxr-nbgp
511!             j_south = nys;         j_north = nys+nbgp-1
512!             CALL prognostic_equations_acc
513!             i_left  = nxl+nbgp;    i_right = nxr-nbgp
514!             j_south = nyn-nbgp+1;  j_north = nyn
515!             CALL prognostic_equations_acc
516
517             IF ( background_communication )  THEN
518                CALL cpu_log( log_point(41), 'exchange-horiz-wait', 'start' )
519#if defined( __parallel )
520                CALL MPI_WAITALL( req_count, req, wait_stat, ierr )
521#endif
522                CALL cpu_log( log_point(41), 'exchange-horiz-wait', 'pause' )
523
524                CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'continue' )
525
526                send_receive = 'ns'
527                sendrecv_in_background = .TRUE.
528                req          = 0
529                req_count    = 0
530
531                IF ( numprocs == 1 )  THEN    ! workaround for single-core GPU runs
532                   on_device = .TRUE.         ! to be removed after complete porting
533                ELSE                          ! of ghost point exchange
534                   !$acc update host( e_p, pt_p, u_p, v_p, w_p )
535                ENDIF
536
537                CALL exchange_horiz( u_p, nbgp )
538                CALL exchange_horiz( v_p, nbgp )
539                CALL exchange_horiz( w_p, nbgp )
540                CALL exchange_horiz( pt_p, nbgp )
541                IF ( .NOT. constant_diffusion )  CALL exchange_horiz( e_p, nbgp )
542                IF ( ocean )  THEN
543                   CALL exchange_horiz( sa_p, nbgp )
544                   CALL exchange_horiz( rho, nbgp )
545                  CALL exchange_horiz( prho, nbgp )
546                ENDIF
547                IF (humidity  .OR.  passive_scalar)  THEN
548                   CALL exchange_horiz( q_p, nbgp )
549                   IF ( cloud_physics .AND. icloud_scheme == 0 )  THEN
550                      CALL exchange_horiz( qr_p, nbgp )
551                      CALL exchange_horiz( nr_p, nbgp )
552                   ENDIF
553                ENDIF
554                IF ( cloud_droplets )  THEN
555                   CALL exchange_horiz( ql, nbgp )
556                   CALL exchange_horiz( ql_c, nbgp )
557                   CALL exchange_horiz( ql_v, nbgp )
558                   CALL exchange_horiz( ql_vp, nbgp )
559                ENDIF
560                IF ( wang_kernel  .OR.  turbulence  .OR.  use_sgs_for_particles ) &
561                THEN
562                   CALL exchange_horiz( diss, nbgp )
563                ENDIF
564
565                IF ( numprocs == 1 )  THEN    ! workaround for single-core GPU runs
566                   on_device = .FALSE.        ! to be removed after complete porting
567                ELSE                          ! of ghost point exchange
568                   !$acc update device( e_p, pt_p, u_p, v_p, w_p )
569                ENDIF
570
571                sendrecv_in_background = .FALSE.
572
573                CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'stop' )
574
575             ENDIF
576
577!             i_left  = nxl+nbgp;    i_right = nxr-nbgp
578!             j_south = nys+nbgp;    j_north = nyn-nbgp
579!             CALL prognostic_equations_acc
580
581             IF ( background_communication )  THEN
582                CALL cpu_log( log_point(41), 'exchange-horiz-wait', 'continue' )
583#if defined( __parallel )
584                CALL MPI_WAITALL( req_count, req, wait_stat, ierr )
585#endif
586                send_receive = 'al'
587                CALL cpu_log( log_point(41), 'exchange-horiz-wait', 'stop' )
588             ENDIF
589
590          ENDIF
591
592!
593!--       Particle transport/physics with the Lagrangian particle model
594!--       (only once during intermediate steps, because it uses an Euler-step)
595!--       ### particle model should be moved before prognostic_equations, in order
596!--       to regard droplet interactions directly
597          IF ( particle_advection  .AND.                         &
598               simulated_time >= particle_advection_start  .AND. &
599               intermediate_timestep_count == 1 )  THEN
600             CALL lpm
601             first_call_lpm = .FALSE.
602          ENDIF
603
604!
605!--       Interaction of droplets with temperature and specific humidity.
606!--       Droplet condensation and evaporation is calculated within
607!--       advec_particles.
608          IF ( cloud_droplets  .AND.  &
609               intermediate_timestep_count == intermediate_timestep_count_max )&
610          THEN
611             CALL interaction_droplets_ptq
612          ENDIF
613
614!
615!--       Exchange of ghost points (lateral boundary conditions)
616          IF ( .NOT. background_communication )  THEN
617
618             CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'start' )
619
620             IF ( numprocs == 1 )  THEN    ! workaround for single-core GPU runs
621                on_device = .TRUE.         ! to be removed after complete porting
622             ELSE                          ! of ghost point exchange
623                !$acc update host( e_p, pt_p, u_p, v_p, w_p )
624             ENDIF
625
626             CALL exchange_horiz( u_p, nbgp )
627             CALL exchange_horiz( v_p, nbgp )
628             CALL exchange_horiz( w_p, nbgp )
629             CALL exchange_horiz( pt_p, nbgp )
630             IF ( .NOT. constant_diffusion )  CALL exchange_horiz( e_p, nbgp )
631             IF ( ocean )  THEN
632                CALL exchange_horiz( sa_p, nbgp )
633                CALL exchange_horiz( rho, nbgp )
634                CALL exchange_horiz( prho, nbgp )
635             ENDIF
636             IF (humidity  .OR.  passive_scalar)  THEN
637                CALL exchange_horiz( q_p, nbgp )
638                IF ( cloud_physics .AND. icloud_scheme == 0  .AND.  &
639                     precipitation )  THEN
640                   CALL exchange_horiz( qr_p, nbgp )
641                   CALL exchange_horiz( nr_p, nbgp )
642                ENDIF
643             ENDIF
644             IF ( cloud_droplets )  THEN
645                CALL exchange_horiz( ql, nbgp )
646                CALL exchange_horiz( ql_c, nbgp )
647                CALL exchange_horiz( ql_v, nbgp )
648                CALL exchange_horiz( ql_vp, nbgp )
649             ENDIF
650             IF ( wang_kernel  .OR.  turbulence  .OR.  use_sgs_for_particles ) &
651             THEN
652                CALL exchange_horiz( diss, nbgp )
653             ENDIF
654
655             IF ( numprocs == 1 )  THEN    ! workaround for single-core GPU runs
656                on_device = .FALSE.        ! to be removed after complete porting
657             ELSE                          ! of ghost point exchange
658                !$acc update device( e_p, pt_p, u_p, v_p, w_p )
659             ENDIF
660
661             CALL cpu_log( log_point(26), 'exchange-horiz-progn', 'stop' )
662
663          ENDIF
664
665!
666!--       Boundary conditions for the prognostic quantities (except of the
667!--       velocities at the outflow in case of a non-cyclic lateral wall)
668          CALL boundary_conds
669
670!
671!--       Swap the time levels in preparation for the next time step.
672          CALL swap_timelevel
673
674          IF ( nested_run )  THEN
675!
676!--          TO_DO: try to give more meaningful comments here
677!--          Domain nesting
678!--          Note that the nesting operations are omitted intentionally on the
679!--          first two RK-substeps.
680             CALL cpu_log( log_point(60), 'nesting', 'start' )
681!
682!--          From server to client commmunication ( direction=SERVER_TO_CLIENT )
683             CALL pmci_server_datatrans( server_to_client )
684             CALL pmci_client_datatrans( server_to_client )
685
686             IF ( nesting_mode == 'two-way' )  THEN
687!
688!--             From client to server commmunication ( direction=CLIENT_TO_SERVER )
689                CALL pmci_server_datatrans( client_to_server )
690                CALL pmci_client_datatrans( client_to_server )
691!
692!--             Exchange_horiz is needed for all server-domains after the
693!--             anterpolation
694                CALL exchange_horiz( u, nbgp )
695                CALL exchange_horiz( v, nbgp )
696                CALL exchange_horiz( w, nbgp )
697                CALL exchange_horiz( pt, nbgp )
698                IF ( humidity  .OR.  passive_scalar )  THEN
699                   CALL exchange_horiz( q, nbgp )
700                ENDIF
701                IF ( .NOT. constant_diffusion )  CALL exchange_horiz( e, nbgp )
702             ENDIF
703!
704!--          Correct the w top-BC in nest domains to ensure mass conservation.
705!--          This action must never be done for the root domain.
706             IF ( nest_domain )  THEN
707                CALL pmci_ensure_nest_mass_conservation
708             ENDIF
709
710             CALL cpu_log( log_point(60), 'nesting', 'stop' )
711
712          ENDIF
713
714!
715!--       Temperature offset must be imposed at cyclic boundaries in x-direction
716!--       when a sloping surface is used
717          IF ( sloping_surface )  THEN
718             IF ( nxl ==  0 )  pt(:,:,nxlg:nxl-1) = pt(:,:,nxlg:nxl-1) - &
719                                                    pt_slope_offset
720             IF ( nxr == nx )  pt(:,:,nxr+1:nxrg) = pt(:,:,nxr+1:nxrg) + &
721                                                    pt_slope_offset
722          ENDIF
723
724!
725!--       Impose a turbulent inflow using the recycling method
726          IF ( turbulent_inflow )  CALL  inflow_turbulence
727
728!
729!--       Impose a random perturbation on the horizontal velocity field
730          IF ( create_disturbances  .AND.                                      &
731               ( call_psolver_at_all_substeps  .AND.                           &
732               intermediate_timestep_count == intermediate_timestep_count_max )&
733          .OR. ( .NOT. call_psolver_at_all_substeps  .AND.                     &
734               intermediate_timestep_count == 1 ) )                            &
735          THEN
736             time_disturb = time_disturb + dt_3d
737             IF ( time_disturb >= dt_disturb )  THEN
738                !$acc update host( u, v )
739                IF ( numprocs == 1 )  on_device = .FALSE.  ! workaround, remove later
740                IF ( disturbance_energy_limit /= 0.0_wp  .AND.                 &
741                     hom(nzb+5,1,pr_palm,0) < disturbance_energy_limit )  THEN
742                   CALL disturb_field( nzb_u_inner, tend, u )
743                   CALL disturb_field( nzb_v_inner, tend, v )
744                ELSEIF ( .NOT. bc_lr_cyc  .OR.  .NOT. bc_ns_cyc )  THEN
745!
746!--                Runs with a non-cyclic lateral wall need perturbations
747!--                near the inflow throughout the whole simulation
748                   dist_range = 1
749                   CALL disturb_field( nzb_u_inner, tend, u )
750                   CALL disturb_field( nzb_v_inner, tend, v )
751                   dist_range = 0
752                ENDIF
753                IF ( numprocs == 1 )  on_device = .TRUE.  ! workaround, remove later
754                !$acc update device( u, v )
755                time_disturb = time_disturb - dt_disturb
756             ENDIF
757          ENDIF
758
759!
760!--       Reduce the velocity divergence via the equation for perturbation
761!--       pressure.
762          IF ( intermediate_timestep_count == 1  .OR. &
763                call_psolver_at_all_substeps )  THEN
764             CALL pres
765          ENDIF
766
767!
768!--       If required, compute liquid water content
769          IF ( cloud_physics )  THEN
770             CALL calc_liquid_water_content
771             !$acc update device( ql )
772          ENDIF
773!
774!--       If required, compute virtual potential temperature
775          IF ( humidity )  THEN
776             CALL compute_vpt
777             !$acc update device( vpt )
778          ENDIF
779
780!
781!--       Compute the diffusion quantities
782          IF ( .NOT. constant_diffusion )  THEN
783
784!
785!--          Determine surface fluxes shf and qsws and surface values
786!--          pt_surface and q_surface in dependence on data from external
787!--          file LSF_DATA respectively
788             IF ( ( large_scale_forcing .AND. lsf_surf ) .AND. &
789                 intermediate_timestep_count == intermediate_timestep_count_max )&
790             THEN
791                CALL ls_forcing_surf ( simulated_time )
792             ENDIF
793
794!
795!--          First the vertical fluxes in the surface (constant flux) layer are computed
796             IF ( constant_flux_layer )  THEN
797                CALL cpu_log( log_point(19), 'surface_layer_fluxes', 'start' )
798                CALL surface_layer_fluxes
799                CALL cpu_log( log_point(19), 'surface_layer_fluxes', 'stop' )
800             ENDIF
801
802!
803!--          If required, solve the energy balance for the surface and run soil
804!--          model
805             IF ( land_surface .AND. simulated_time > skip_time_do_lsm)  THEN
806
807                CALL cpu_log( log_point(54), 'land_surface', 'start' )
808                CALL lsm_energy_balance
809                CALL lsm_soil_model
810                CALL cpu_log( log_point(54), 'land_surface', 'stop' )
811             ENDIF
812!
813!--          Compute the diffusion coefficients
814             CALL cpu_log( log_point(17), 'diffusivities', 'start' )
815             IF ( .NOT. humidity ) THEN
816                IF ( ocean )  THEN
817                   CALL diffusivities( prho, prho_reference )
818                ELSE
819                   CALL diffusivities( pt, pt_reference )
820                ENDIF
821             ELSE
822                CALL diffusivities( vpt, pt_reference )
823             ENDIF
824             CALL cpu_log( log_point(17), 'diffusivities', 'stop' )
825
826          ENDIF
827
828!
829!--       If required, calculate radiative fluxes and heating rates
830          IF ( radiation .AND. intermediate_timestep_count                     &
831               == intermediate_timestep_count_max .AND. simulated_time >    &
832               skip_time_do_radiation )  THEN
833
834               time_radiation = time_radiation + dt_3d
835
836             IF ( time_radiation >= dt_radiation .OR. force_radiation_call )   &
837             THEN
838
839                CALL cpu_log( log_point(50), 'radiation', 'start' )
840
841                IF ( .NOT. force_radiation_call )  THEN
842                   time_radiation = time_radiation - dt_radiation
843                ELSE
844                   WRITE(9,*) "Unscheduled radiation call at ", simulated_time
845                   CALL LOCAL_FLUSH ( 9 )
846                ENDIF
847
848                IF ( radiation_scheme == 'clear-sky' )  THEN
849                   CALL radiation_clearsky
850                ELSEIF ( radiation_scheme == 'rrtmg' )  THEN
851                   CALL radiation_rrtmg
852                ENDIF
853
854                CALL cpu_log( log_point(50), 'radiation', 'stop' )
855             ENDIF
856          ENDIF
857
858       ENDDO   ! Intermediate step loop
859
860!
861!--    Increase simulation time and output times
862       nr_timesteps_this_run      = nr_timesteps_this_run + 1
863       current_timestep_number    = current_timestep_number + 1
864       simulated_time             = simulated_time   + dt_3d
865       simulated_time_chr         = time_to_string( simulated_time )
866       time_since_reference_point = simulated_time - coupling_start_time
867
868       IF ( simulated_time >= skip_time_data_output_av )  THEN
869          time_do_av         = time_do_av       + dt_3d
870       ENDIF
871       IF ( simulated_time >= skip_time_do2d_xy )  THEN
872          time_do2d_xy       = time_do2d_xy     + dt_3d
873       ENDIF
874       IF ( simulated_time >= skip_time_do2d_xz )  THEN
875          time_do2d_xz       = time_do2d_xz     + dt_3d
876       ENDIF
877       IF ( simulated_time >= skip_time_do2d_yz )  THEN
878          time_do2d_yz       = time_do2d_yz     + dt_3d
879       ENDIF
880       IF ( simulated_time >= skip_time_do3d    )  THEN
881          time_do3d          = time_do3d        + dt_3d
882       ENDIF
883       DO  mid = 1, masks
884          IF ( simulated_time >= skip_time_domask(mid) )  THEN
885             time_domask(mid)= time_domask(mid) + dt_3d
886          ENDIF
887       ENDDO
888       time_dvrp          = time_dvrp        + dt_3d
889       IF ( simulated_time >= skip_time_dosp )  THEN
890          time_dosp       = time_dosp        + dt_3d
891       ENDIF
892       time_dots          = time_dots        + dt_3d
893       IF ( .NOT. first_call_lpm )  THEN
894          time_dopts      = time_dopts       + dt_3d
895       ENDIF
896       IF ( simulated_time >= skip_time_dopr )  THEN
897          time_dopr       = time_dopr        + dt_3d
898       ENDIF
899       time_dopr_listing          = time_dopr_listing        + dt_3d
900       time_run_control   = time_run_control + dt_3d
901
902!
903!--    Data exchange between coupled models
904       IF ( coupling_mode /= 'uncoupled'  .AND.  run_coupled )  THEN
905          time_coupling = time_coupling + dt_3d
906
907!
908!--       In case of model termination initiated by the local model
909!--       (terminate_coupled > 0), the coupler must be skipped because it would
910!--       cause an MPI intercomminucation hang.
911!--       If necessary, the coupler will be called at the beginning of the
912!--       next restart run.
913          DO WHILE ( time_coupling >= dt_coupling .AND. terminate_coupled == 0 )
914             CALL surface_coupler
915             time_coupling = time_coupling - dt_coupling
916          ENDDO
917       ENDIF
918
919!
920!--    Execute user-defined actions
921       CALL user_actions( 'after_integration' )
922
923!
924!--    If Galilei transformation is used, determine the distance that the
925!--    model has moved so far
926       IF ( galilei_transformation )  THEN
927          advected_distance_x = advected_distance_x + u_gtrans * dt_3d
928          advected_distance_y = advected_distance_y + v_gtrans * dt_3d
929       ENDIF
930
931!
932!--    Check, if restart is necessary (because cpu-time is expiring or
933!--    because it is forced by user) and set stop flag
934!--    This call is skipped if the remote model has already initiated a restart.
935       IF ( .NOT. terminate_run )  CALL check_for_restart
936
937!
938!--    Carry out statistical analysis and output at the requested output times.
939!--    The MOD function is used for calculating the output time counters (like
940!--    time_dopr) in order to regard a possible decrease of the output time
941!--    interval in case of restart runs
942
943!
944!--    Set a flag indicating that so far no statistics have been created
945!--    for this time step
946       flow_statistics_called = .FALSE.
947
948!
949!--    If required, call flow_statistics for averaging in time
950       IF ( averaging_interval_pr /= 0.0_wp  .AND.  &
951            ( dt_dopr - time_dopr ) <= averaging_interval_pr  .AND.  &
952            simulated_time >= skip_time_dopr )  THEN
953          time_dopr_av = time_dopr_av + dt_3d
954          IF ( time_dopr_av >= dt_averaging_input_pr )  THEN
955             do_sum = .TRUE.
956             time_dopr_av = MOD( time_dopr_av, &
957                                    MAX( dt_averaging_input_pr, dt_3d ) )
958          ENDIF
959       ENDIF
960       IF ( do_sum )  CALL flow_statistics
961
962!
963!--    Sum-up 3d-arrays for later output of time-averaged 2d/3d/masked data
964       IF ( averaging_interval /= 0.0_wp  .AND.                                &
965            ( dt_data_output_av - time_do_av ) <= averaging_interval  .AND. &
966            simulated_time >= skip_time_data_output_av )                    &
967       THEN
968          time_do_sla = time_do_sla + dt_3d
969          IF ( time_do_sla >= dt_averaging_input )  THEN
970             CALL sum_up_3d_data
971             average_count_3d = average_count_3d + 1
972             time_do_sla = MOD( time_do_sla, MAX( dt_averaging_input, dt_3d ) )
973          ENDIF
974       ENDIF
975
976!
977!--    Calculate spectra for time averaging
978       IF ( averaging_interval_sp /= 0.0_wp  .AND.  &
979            ( dt_dosp - time_dosp ) <= averaging_interval_sp  .AND.  &
980            simulated_time >= skip_time_dosp )  THEN
981          time_dosp_av = time_dosp_av + dt_3d
982          IF ( time_dosp_av >= dt_averaging_input_pr )  THEN
983             CALL calc_spectra
984             time_dosp_av = MOD( time_dosp_av, &
985                                 MAX( dt_averaging_input_pr, dt_3d ) )
986          ENDIF
987       ENDIF
988
989!
990!--    Computation and output of run control parameters.
991!--    This is also done whenever perturbations have been imposed
992       IF ( time_run_control >= dt_run_control  .OR.                     &
993            timestep_scheme(1:5) /= 'runge'  .OR.  disturbance_created ) &
994       THEN
995          CALL run_control
996          IF ( time_run_control >= dt_run_control )  THEN
997             time_run_control = MOD( time_run_control, &
998                                     MAX( dt_run_control, dt_3d ) )
999          ENDIF
1000       ENDIF
1001
1002!
1003!--    Profile output (ASCII) on file
1004       IF ( time_dopr_listing >= dt_dopr_listing )  THEN
1005          CALL print_1d
1006          time_dopr_listing = MOD( time_dopr_listing, MAX( dt_dopr_listing, &
1007                                                           dt_3d ) )
1008       ENDIF
1009
1010!
1011!--    Graphic output for PROFIL
1012       IF ( time_dopr >= dt_dopr )  THEN
1013          IF ( dopr_n /= 0 )  CALL data_output_profiles
1014          time_dopr = MOD( time_dopr, MAX( dt_dopr, dt_3d ) )
1015          time_dopr_av = 0.0_wp    ! due to averaging (see above)
1016       ENDIF
1017
1018!
1019!--    Graphic output for time series
1020       IF ( time_dots >= dt_dots )  THEN
1021          CALL data_output_tseries
1022          time_dots = MOD( time_dots, MAX( dt_dots, dt_3d ) )
1023       ENDIF
1024
1025!
1026!--    Output of spectra (formatted for use with PROFIL), in case of no
1027!--    time averaging, spectra has to be calculated before
1028       IF ( time_dosp >= dt_dosp )  THEN
1029          IF ( average_count_sp == 0 )  CALL calc_spectra
1030          CALL data_output_spectra
1031          time_dosp = MOD( time_dosp, MAX( dt_dosp, dt_3d ) )
1032       ENDIF
1033
1034!
1035!--    2d-data output (cross-sections)
1036       IF ( time_do2d_xy >= dt_do2d_xy )  THEN
1037          CALL data_output_2d( 'xy', 0 )
1038          time_do2d_xy = MOD( time_do2d_xy, MAX( dt_do2d_xy, dt_3d ) )
1039       ENDIF
1040       IF ( time_do2d_xz >= dt_do2d_xz )  THEN
1041          CALL data_output_2d( 'xz', 0 )
1042          time_do2d_xz = MOD( time_do2d_xz, MAX( dt_do2d_xz, dt_3d ) )
1043       ENDIF
1044       IF ( time_do2d_yz >= dt_do2d_yz )  THEN
1045          CALL data_output_2d( 'yz', 0 )
1046          time_do2d_yz = MOD( time_do2d_yz, MAX( dt_do2d_yz, dt_3d ) )
1047       ENDIF
1048
1049!
1050!--    3d-data output (volume data)
1051       IF ( time_do3d >= dt_do3d )  THEN
1052          CALL data_output_3d( 0 )
1053          time_do3d = MOD( time_do3d, MAX( dt_do3d, dt_3d ) )
1054       ENDIF
1055
1056!
1057!--    Masked data output
1058       DO  mid = 1, masks
1059          IF ( time_domask(mid) >= dt_domask(mid) )  THEN
1060             CALL data_output_mask( 0 )
1061             time_domask(mid) = MOD( time_domask(mid),  &
1062                                     MAX( dt_domask(mid), dt_3d ) )
1063          ENDIF
1064       ENDDO
1065
1066!
1067!--    Output of time-averaged 2d/3d/masked data
1068       IF ( time_do_av >= dt_data_output_av )  THEN
1069          CALL average_3d_data
1070          CALL data_output_2d( 'xy', 1 )
1071          CALL data_output_2d( 'xz', 1 )
1072          CALL data_output_2d( 'yz', 1 )
1073          CALL data_output_3d( 1 )
1074          DO  mid = 1, masks
1075             CALL data_output_mask( 1 )
1076          ENDDO
1077          time_do_av = MOD( time_do_av, MAX( dt_data_output_av, dt_3d ) )
1078       ENDIF
1079
1080!
1081!--    Output of particle time series
1082       IF ( particle_advection )  THEN
1083          IF ( time_dopts >= dt_dopts  .OR. &
1084               ( simulated_time >= particle_advection_start  .AND. &
1085                 first_call_lpm ) )  THEN
1086             CALL data_output_ptseries
1087             time_dopts = MOD( time_dopts, MAX( dt_dopts, dt_3d ) )
1088          ENDIF
1089       ENDIF
1090
1091!
1092!--    Output of dvrp-graphics (isosurface, particles, slicer)
1093#if defined( __dvrp_graphics )
1094       CALL DVRP_LOG_EVENT( -2, current_timestep_number-1 )
1095#endif
1096       IF ( time_dvrp >= dt_dvrp )  THEN
1097          CALL data_output_dvrp
1098          time_dvrp = MOD( time_dvrp, MAX( dt_dvrp, dt_3d ) )
1099       ENDIF
1100#if defined( __dvrp_graphics )
1101       CALL DVRP_LOG_EVENT( 2, current_timestep_number )
1102#endif
1103
1104!
1105!--    If required, set the heat flux for the next time step at a random value
1106       IF ( constant_heatflux  .AND.  random_heatflux )  CALL disturb_heatflux
1107
1108!
1109!--    Execute user-defined actions
1110       CALL user_actions( 'after_timestep' )
1111
1112!
1113!--    Output elapsed simulated time in form of a progress bar on stdout
1114       IF ( myid == 0 )  CALL output_progress_bar
1115
1116       CALL cpu_log( log_point_s(10), 'timesteps', 'stop' )
1117
1118
1119    ENDDO   ! time loop
1120
1121    IF ( myid == 0 )  CALL finish_progress_bar
1122
1123#if defined( __dvrp_graphics )
1124    CALL DVRP_LOG_EVENT( -2, current_timestep_number )
1125#endif
1126
1127    CALL location_message( 'finished time-stepping', .TRUE. )
1128
1129 END SUBROUTINE time_integration
Note: See TracBrowser for help on using the repository browser.