SUBROUTINE swap_timelevel

!------------------------------------------------------------------------------!
! Current revisions:
! -----------------
!
!
! Former revisions:
! -----------------
! $Id: swap_timelevel.f90 1002 2012-09-13 15:12:24Z franke $
!
! 1001 2012-09-13 14:08:46Z raasch
! all actions concerning leapfrog scheme removed
!
! 102 2007-07-27 09:09:17Z raasch
! swaping of uswst, vswst included
!
! 95 2007-06-02 16:48:38Z raasch
! Swaping of salinity
!
! 75 2007-03-22 09:54:05Z raasch
! moisture renamed humidity
!
! 19 2007-02-23 04:53:48Z raasch
! Swaping of top fluxes
!
! RCS Log replace by Id keyword, revision history cleaned up
!
! Revision 1.8  2004/01/28 15:28:18  raasch
! Swaping for Runge-Kutta schemes implemented
!
! Revision 1.1  2000/01/10  10:08:58  10:08:58  raasch (Siegfried Raasch)
! Initial revision
! 
!
! Description:
! ------------
! Swap of timelevels of variables after each timestep
!------------------------------------------------------------------------------!

    USE arrays_3d
    USE cpulog
    USE interfaces
    USE control_parameters

    IMPLICIT NONE


    CALL cpu_log( log_point(28), 'swap_timelevel', 'start' )

!
!-- Incrementing timestep counter
    timestep_count = timestep_count + 1

!
!-- Swap of variables
    SELECT CASE ( MOD( timestep_count, 2 ) )

       CASE ( 0 )

          u  => u_1;   u_p  => u_2
          v  => v_1;   v_p  => v_2
          w  => w_1;   w_p  => w_2
          pt => pt_1;  pt_p => pt_2
          IF ( .NOT. constant_diffusion )  THEN
             e => e_1;    e_p => e_2
          ENDIF
          IF ( ocean )  THEN
             sa => sa_1;  sa_p => sa_2
          ENDIF
          IF ( humidity  .OR.  passive_scalar )  THEN
             q => q_1;    q_p => q_2
          ENDIF


       CASE ( 1 )

          u  => u_2;   u_p  => u_1
          v  => v_2;   v_p  => v_1
          w  => w_2;   w_p  => w_1
          pt => pt_2;  pt_p => pt_1
          IF ( .NOT. constant_diffusion )  THEN
             e => e_2;    e_p => e_1
          ENDIF
          IF ( ocean )  THEN
             sa => sa_2;  sa_p => sa_1
          ENDIF
          IF ( humidity  .OR.  passive_scalar )  THEN
             q => q_2;    q_p => q_1
          ENDIF


    END SELECT

    CALL cpu_log( log_point(28), 'swap_timelevel', 'stop' )

 END SUBROUTINE swap_timelevel