source: palm/trunk/SOURCE/sor.f90 @ 1320

Last change on this file since 1320 was 1320, checked in by raasch, 7 years ago

ONLY-attribute added to USE-statements,
kind-parameters added to all INTEGER and REAL declaration statements,
kinds are defined in new module kinds,
old module precision_kind is removed,
revision history before 2012 removed,
comment fields (!:) to be used for variable explanations added to all variable declaration statements

  • Property svn:keywords set to Id
File size: 7.5 KB
Line 
1 SUBROUTINE sor( d, ddzu, ddzw, p )
2
3!--------------------------------------------------------------------------------!
4! This file is part of PALM.
5!
6! PALM is free software: you can redistribute it and/or modify it under the terms
7! of the GNU General Public License as published by the Free Software Foundation,
8! either version 3 of the License, or (at your option) any later version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2014 Leibniz Universitaet Hannover
18!--------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22! ONLY-attribute added to USE-statements,
23! kind-parameters added to all INTEGER and REAL declaration statements,
24! kinds are defined in new module kinds,
25! old module precision_kind is removed,
26! revision history before 2012 removed,
27! comment fields (!:) to be used for variable explanations added to
28! all variable declaration statements
29!
30! Former revisions:
31! -----------------
32! $Id: sor.f90 1320 2014-03-20 08:40:49Z raasch $
33!
34! 1036 2012-10-22 13:43:42Z raasch
35! code put under GPL (PALM 3.9)
36!
37! Revision 1.1  1997/08/11 06:25:56  raasch
38! Initial revision
39!
40!
41! Description:
42! ------------
43! Solve the Poisson-equation with the SOR-Red/Black-scheme.
44!------------------------------------------------------------------------------!
45
46    USE grid_variables,                                                        &
47        ONLY:  ddx2, ddy2
48
49    USE indices,                                                               &
50        ONLY:  nbgp, nxl, nxlg, nxr, nxrg, nyn, nyng, nys, nysg, nz, nzb, nzt
51
52    USE kinds
53
54    USE control_parameters,                                                    &
55        ONLY:  bc_lr_cyc, bc_ns_cyc, ibc_p_b, ibc_p_t, inflow_l, inflow_n,     &
56               inflow_r, inflow_s, n_sor, omega_sor, outflow_l, outflow_n,     &
57               outflow_r, outflow_s
58
59    IMPLICIT NONE
60
61    INTEGER(iwp) ::  i              !:
62    INTEGER(iwp) ::  j              !:
63    INTEGER(iwp) ::  k              !:
64    INTEGER(iwp) ::  n              !:
65    INTEGER(iwp) ::  nxl1           !:
66    INTEGER(iwp) ::  nxl2           !:
67    INTEGER(iwp) ::  nys1           !:
68    INTEGER(iwp) ::  nys2           !:
69
70    REAL(wp)     ::  ddzu(1:nz+1)   !:
71    REAL(wp)     ::  ddzw(1:nzt+1)  !:
72
73    REAL(wp)     ::  d(nzb+1:nzt,nys:nyn,nxl:nxr)      !:
74    REAL(wp)     ::  p(nzb:nzt+1,nysg:nyng,nxlg:nxrg)  !:
75
76    REAL(wp), DIMENSION(:), ALLOCATABLE ::  f1         !:
77    REAL(wp), DIMENSION(:), ALLOCATABLE ::  f2         !:
78    REAL(wp), DIMENSION(:), ALLOCATABLE ::  f3         !:
79
80    ALLOCATE( f1(1:nz), f2(1:nz), f3(1:nz) )
81
82!
83!-- Compute pre-factors.
84    DO  k = 1, nz
85         f2(k) = ddzu(k+1) * ddzw(k)
86         f3(k) = ddzu(k)   * ddzw(k)
87         f1(k) = 2.0 * ( ddx2 + ddy2 ) + f2(k) + f3(k)
88    ENDDO
89
90!
91!-- Limits for RED- and BLACK-part.
92    IF ( MOD( nxl , 2 ) == 0 )  THEN
93       nxl1 = nxl
94       nxl2 = nxl + 1
95    ELSE
96       nxl1 = nxl + 1
97       nxl2 = nxl
98    ENDIF
99    IF ( MOD( nys , 2 ) == 0 )  THEN
100       nys1 = nys
101       nys2 = nys + 1
102    ELSE
103       nys1 = nys + 1
104       nys2 = nys
105    ENDIF
106
107    DO  n = 1, n_sor
108
109!
110!--    RED-part
111       DO  i = nxl1, nxr, 2
112          DO  j = nys2, nyn, 2
113             DO  k = nzb+1, nzt
114                p(k,j,i) = p(k,j,i) + omega_sor / f1(k) * (            &
115                               ddx2 * ( p(k,j,i+1) + p(k,j,i-1) ) +    &
116                               ddy2 * ( p(k,j+1,i) + p(k,j-1,i) ) +    &
117                               f2(k) * p(k+1,j,i)                 +    &
118                               f3(k) * p(k-1,j,i)                 -    &
119                               d(k,j,i)                           -    &
120                               f1(k) * p(k,j,i)           )
121             ENDDO
122          ENDDO
123       ENDDO
124
125       DO  i = nxl2, nxr, 2
126          DO  j = nys1, nyn, 2
127             DO  k = nzb+1, nzt
128                p(k,j,i) = p(k,j,i) + omega_sor / f1(k) * (            &
129                               ddx2 * ( p(k,j,i+1) + p(k,j,i-1) ) +    &
130                               ddy2 * ( p(k,j+1,i) + p(k,j-1,i) ) +    &
131                               f2(k) * p(k+1,j,i)                 +    &
132                               f3(k) * p(k-1,j,i)                 -    &
133                               d(k,j,i)                           -    &
134                               f1(k) * p(k,j,i)           )
135             ENDDO
136          ENDDO
137       ENDDO
138
139!
140!--    Exchange of boundary values for p.
141       CALL exchange_horiz( p, nbgp )
142
143!
144!--    Horizontal (Neumann) boundary conditions in case of non-cyclic boundaries
145       IF ( .NOT. bc_lr_cyc )  THEN
146          IF ( inflow_l .OR. outflow_l )  p(:,:,nxl-1) = p(:,:,nxl)
147          IF ( inflow_r .OR. outflow_r )  p(:,:,nxr+1) = p(:,:,nxr)
148       ENDIF
149       IF ( .NOT. bc_ns_cyc )  THEN
150          IF ( inflow_n .OR. outflow_n )  p(:,nyn+1,:) = p(:,nyn,:)
151          IF ( inflow_s .OR. outflow_s )  p(:,nys-1,:) = p(:,nys,:)
152       ENDIF
153
154!
155!--    BLACK-part
156       DO  i = nxl1, nxr, 2
157          DO  j = nys1, nyn, 2
158             DO  k = nzb+1, nzt
159                p(k,j,i) = p(k,j,i) + omega_sor / f1(k) * (            &
160                               ddx2 * ( p(k,j,i+1) + p(k,j,i-1) ) +    &
161                               ddy2 * ( p(k,j+1,i) + p(k,j-1,i) ) +    &
162                               f2(k) * p(k+1,j,i)                 +    &
163                               f3(k) * p(k-1,j,i)                 -    &
164                               d(k,j,i)                           -    &
165                               f1(k) * p(k,j,i)           )
166             ENDDO
167          ENDDO
168       ENDDO
169
170       DO  i = nxl2, nxr, 2
171          DO  j = nys2, nyn, 2
172             DO  k = nzb+1, nzt
173                p(k,j,i) = p(k,j,i) + omega_sor / f1(k) * (            &
174                               ddx2 * ( p(k,j,i+1) + p(k,j,i-1) ) +    &
175                               ddy2 * ( p(k,j+1,i) + p(k,j-1,i) ) +    &
176                               f2(k) * p(k+1,j,i)                 +    &
177                               f3(k) * p(k-1,j,i)                 -    &
178                               d(k,j,i)                           -    &
179                               f1(k) * p(k,j,i)           )
180             ENDDO
181          ENDDO
182       ENDDO
183
184!
185!--    Exchange of boundary values for p.
186       CALL exchange_horiz( p, nbgp )
187
188!
189!--    Boundary conditions top/bottom.
190!--    Bottom boundary
191       IF ( ibc_p_b == 1 )  THEN       !       Neumann
192          p(nzb,:,:) = p(nzb+1,:,:)
193       ELSE                            !       Dirichlet
194          p(nzb,:,:) = 0.0
195       ENDIF
196
197!
198!--    Top boundary
199       IF ( ibc_p_t == 1 )  THEN                 !  Neumann
200          p(nzt+1,:,:) = p(nzt,:,:)
201       ELSE                      !  Dirichlet
202          p(nzt+1,:,:) = 0.0
203       ENDIF
204
205!
206!--    Horizontal (Neumann) boundary conditions in case of non-cyclic boundaries
207       IF ( .NOT. bc_lr_cyc )  THEN
208          IF ( inflow_l .OR. outflow_l )  p(:,:,nxl-1) = p(:,:,nxl)
209          IF ( inflow_r .OR. outflow_r )  p(:,:,nxr+1) = p(:,:,nxr)
210       ENDIF
211       IF ( .NOT. bc_ns_cyc )  THEN
212          IF ( inflow_n .OR. outflow_n )  p(:,nyn+1,:) = p(:,nyn,:)
213          IF ( inflow_s .OR. outflow_s )  p(:,nys-1,:) = p(:,nys,:)
214       ENDIF
215
216
217    ENDDO
218
219    DEALLOCATE( f1, f2, f3 )
220
221 END SUBROUTINE sor
Note: See TracBrowser for help on using the repository browser.