source: palm/trunk/SOURCE/salsa_mod.f90 @ 3685

Last change on this file since 3685 was 3685, checked in by knoop, 2 years ago

Some interface calls moved to module_interface + cleanup

  • Property svn:keywords set to Id
File size: 459.5 KB
Line 
1!> @file salsa_mod.f90
2!--------------------------------------------------------------------------------!
3! This file is part of PALM-4U.
4!
5! PALM-4U is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM-4U is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 2018-2018 University of Helsinki
18! Copyright 1997-2019 Leibniz Universitaet Hannover
19!--------------------------------------------------------------------------------!
20!
21! Current revisions:
22! -----------------
23!
24!
25! Former revisions:
26! -----------------
27! $Id: salsa_mod.f90 3685 2019-01-21 01:02:11Z knoop $
28! Some interface calls moved to module_interface + cleanup
29!
30! 3655 2019-01-07 16:51:22Z knoop
31! Implementation of the PALM module interface
32!
33! 3636 2018-12-19 13:48:34Z raasch
34! nopointer option removed
35!
36! 3630 2018-12-17 11:04:17Z knoop
37! - Moved the control parameter "salsa" from salsa_mod.f90 to control_parameters
38! - Updated salsa_rrd_local and salsa_wrd_local
39! - Add target attribute
40! - Revise initialization in case of restarts
41! - Revise masked data output
42!
43! 3582 2018-11-29 19:16:36Z suehring
44! missing comma separator inserted
45!
46! 3483 2018-11-02 14:19:26Z raasch
47! bugfix: directives added to allow compilation without netCDF
48!
49! 3481 2018-11-02 09:14:13Z raasch
50! temporary variable cc introduced to circumvent a possible Intel18 compiler bug
51! related to contiguous/non-contguous pointer/target attributes
52!
53! 3473 2018-10-30 20:50:15Z suehring
54! NetCDF input routine renamed
55!
56! 3467 2018-10-30 19:05:21Z suehring
57! Initial revision
58!
59! 3412 2018-10-24 07:25:57Z monakurppa
60!
61! Authors:
62! --------
63! @author Mona Kurppa (University of Helsinki)
64!
65!
66! Description:
67! ------------
68!> Sectional aerosol module for large scale applications SALSA
69!> (Kokkola et al., 2008, ACP 8, 2469-2483). Solves the aerosol number and mass
70!> concentration as well as chemical composition. Includes aerosol dynamic
71!> processes: nucleation, condensation/evaporation of vapours, coagulation and
72!> deposition on tree leaves, ground and roofs.
73!> Implementation is based on formulations implemented in UCLALES-SALSA except
74!> for deposition which is based on parametrisations by Zhang et al. (2001,
75!> Atmos. Environ. 35, 549-560) or Petroff&Zhang (2010, Geosci. Model Dev. 3,
76!> 753-769)
77!>
78!> @todo Implement turbulent inflow of aerosols in inflow_turbulence.
79!> @todo Deposition on subgrid scale vegetation
80!> @todo Deposition on vegetation calculated by default for deciduous broadleaf
81!>       trees
82!> @todo Revise masked data output. There is a potential bug in case of
83!>       terrain-following masked output, according to data_output_mask.
84!> @todo There are now improved interfaces for NetCDF data input which can be
85!>       used instead of get variable etc.
86!------------------------------------------------------------------------------!
87 MODULE salsa_mod
88
89    USE basic_constants_and_equations_mod,                                     &
90        ONLY:  c_p, g, p_0, pi, r_d
91 
92    USE chemistry_model_mod,                                                   &
93        ONLY:  chem_species, nspec, nvar, spc_names
94
95    USE chem_modules,                                                          &
96        ONLY:  call_chem_at_all_substeps, chem_gasphase_on
97
98    USE control_parameters
99
100    USE indices,                                                               &
101        ONLY:  nbgp, nx, nxl, nxlg, nxr, nxrg, ny, nyn, nyng, nys, nysg, nzb,  &
102               nzb_s_inner, nz, nzt, wall_flags_0
103     
104    USE kinds
105   
106    USE pegrid
107   
108    USE salsa_util_mod
109
110    IMPLICIT NONE
111!
112!-- SALSA constants:
113!
114!-- Local constants:
115    INTEGER(iwp), PARAMETER ::  ngast   = 5 !< total number of gaseous tracers:
116                                            !< 1 = H2SO4, 2 = HNO3, 3 = NH3,
117                                            !< 4 = OCNV (non-volatile OC),
118                                            !< 5 = OCSV (semi-volatile) 
119    INTEGER(iwp), PARAMETER ::  nmod    = 7 !< number of modes for initialising
120                                            !< the aerosol size distribution                                             
121    INTEGER(iwp), PARAMETER ::  nreg    = 2 !< Number of main size subranges
122    INTEGER(iwp), PARAMETER ::  maxspec = 7 !< Max. number of aerosol species
123!   
124!-- Universal constants
125    REAL(wp), PARAMETER ::  abo    = 1.380662E-23_wp  !< Boltzmann constant (J/K)
126    REAL(wp), PARAMETER ::  alv    = 2.260E+6_wp      !< latent heat for H2O
127                                                      !< vaporisation (J/kg)
128    REAL(wp), PARAMETER ::  alv_d_rv  = 4896.96865_wp !< alv / rv
129    REAL(wp), PARAMETER ::  am_airmol = 4.8096E-26_wp !< Average mass of one air
130                                                      !< molecule (Jacobson,
131                                                      !< 2005, Eq. 2.3)                                                   
132    REAL(wp), PARAMETER ::  api6   = 0.5235988_wp     !< pi / 6   
133    REAL(wp), PARAMETER ::  argas  = 8.314409_wp      !< Gas constant (J/(mol K))
134    REAL(wp), PARAMETER ::  argas_d_cpd = 8.281283865E-3_wp !< argas per cpd
135    REAL(wp), PARAMETER ::  avo    = 6.02214E+23_wp   !< Avogadro constant (1/mol)
136    REAL(wp), PARAMETER ::  d_sa   = 5.539376964394570E-10_wp !< diameter of
137                                                      !< condensing sulphuric
138                                                      !< acid molecule (m) 
139    REAL(wp), PARAMETER ::  for_ppm_to_nconc =  7.243016311E+16_wp !<
140                                                 !< ppm * avo / R (K/(Pa*m3))
141    REAL(wp), PARAMETER ::  epsoc  = 0.15_wp          !< water uptake of organic
142                                                      !< material     
143    REAL(wp), PARAMETER ::  mclim  = 1.0E-23_wp    !< mass concentration min
144                                                   !< limit for aerosols (kg/m3)                                                   
145    REAL(wp), PARAMETER ::  n3     = 158.79_wp !< Number of H2SO4 molecules in
146                                               !< 3 nm cluster if d_sa=5.54e-10m
147    REAL(wp), PARAMETER ::  nclim  = 1.0_wp    !< number concentration min limit
148                                               !< for aerosols and gases (#/m3)
149    REAL(wp), PARAMETER ::  surfw0 = 0.073_wp  !< surface tension of pure water
150                                               !< at ~ 293 K (J/m2)   
151    REAL(wp), PARAMETER ::  vclim  = 1.0E-24_wp    !< volume concentration min
152                                                   !< limit for aerosols (m3/m3)                                           
153!-- Molar masses in kg/mol
154    REAL(wp), PARAMETER ::  ambc   = 12.0E-3_wp     !< black carbon (BC)
155    REAL(wp), PARAMETER ::  amdair = 28.970E-3_wp   !< dry air
156    REAL(wp), PARAMETER ::  amdu   = 100.E-3_wp     !< mineral dust
157    REAL(wp), PARAMETER ::  amh2o  = 18.0154E-3_wp  !< H2O
158    REAL(wp), PARAMETER ::  amh2so4  = 98.06E-3_wp  !< H2SO4
159    REAL(wp), PARAMETER ::  amhno3 = 63.01E-3_wp    !< HNO3
160    REAL(wp), PARAMETER ::  amn2o  = 44.013E-3_wp   !< N2O
161    REAL(wp), PARAMETER ::  amnh3  = 17.031E-3_wp   !< NH3
162    REAL(wp), PARAMETER ::  amo2   = 31.9988E-3_wp  !< O2
163    REAL(wp), PARAMETER ::  amo3   = 47.998E-3_wp   !< O3
164    REAL(wp), PARAMETER ::  amoc   = 150.E-3_wp     !< organic carbon (OC)
165    REAL(wp), PARAMETER ::  amss   = 58.44E-3_wp    !< sea salt (NaCl)
166!-- Densities in kg/m3
167    REAL(wp), PARAMETER ::  arhobc     = 2000.0_wp !< black carbon
168    REAL(wp), PARAMETER ::  arhodu     = 2650.0_wp !< mineral dust
169    REAL(wp), PARAMETER ::  arhoh2o    = 1000.0_wp !< H2O
170    REAL(wp), PARAMETER ::  arhoh2so4  = 1830.0_wp !< SO4
171    REAL(wp), PARAMETER ::  arhohno3   = 1479.0_wp !< HNO3
172    REAL(wp), PARAMETER ::  arhonh3    = 1530.0_wp !< NH3
173    REAL(wp), PARAMETER ::  arhooc     = 2000.0_wp !< organic carbon
174    REAL(wp), PARAMETER ::  arhoss     = 2165.0_wp !< sea salt (NaCl)
175!-- Volume of molecule in m3/#
176    REAL(wp), PARAMETER ::  amvh2o   = amh2o /avo / arhoh2o      !< H2O
177    REAL(wp), PARAMETER ::  amvh2so4 = amh2so4 / avo / arhoh2so4 !< SO4
178    REAL(wp), PARAMETER ::  amvhno3  = amhno3 / avo / arhohno3   !< HNO3
179    REAL(wp), PARAMETER ::  amvnh3   = amnh3 / avo / arhonh3     !< NH3 
180    REAL(wp), PARAMETER ::  amvoc    = amoc / avo / arhooc       !< OC
181    REAL(wp), PARAMETER ::  amvss    = amss / avo / arhoss       !< sea salt
182   
183!
184!-- SALSA switches:
185    INTEGER(iwp) ::  nj3 = 1 !< J3 parametrization (nucleation)
186                             !< 1 = condensational sink (Kerminen&Kulmala, 2002)
187                             !< 2 = coagulational sink (Lehtinen et al. 2007)
188                             !< 3 = coagS+self-coagulation (Anttila et al. 2010)                                       
189    INTEGER(iwp) ::  nsnucl = 0 !< Choice of the nucleation scheme:
190                                !< 0 = off   
191                                !< 1 = binary nucleation
192                                !< 2 = activation type nucleation
193                                !< 3 = kinetic nucleation
194                                !< 4 = ternary nucleation
195                                !< 5 = nucleation with ORGANICs
196                                !< 6 = activation type of nucleation with
197                                !<     H2SO4+ORG
198                                !< 7 = heteromolecular nucleation with H2SO4*ORG
199                                !< 8 = homomolecular nucleation of  H2SO4 +
200                                !<     heteromolecular nucleation with H2SO4*ORG
201                                !< 9 = homomolecular nucleation of  H2SO4 and ORG
202                                !<     +heteromolecular nucleation with H2SO4*ORG
203    LOGICAL ::  advect_particle_water = .TRUE.  !< advect water concentration of
204                                                !< particles                               
205    LOGICAL ::  decycle_lr            = .FALSE. !< Undo cyclic boundary
206                                                !< conditions: left and right
207    LOGICAL ::  decycle_ns            = .FALSE. !< north and south boundaries
208    LOGICAL ::  feedback_to_palm      = .FALSE. !< allow feedback due to
209                                                !< hydration and/or condensation
210                                                !< of H20
211    LOGICAL ::  no_insoluble          = .FALSE. !< Switch to exclude insoluble 
212                                                !< chemical components
213    LOGICAL ::  read_restart_data_salsa = .FALSE. !< read restart data for salsa
214    LOGICAL ::  salsa_gases_from_chem = .FALSE.   !< Transfer the gaseous
215                                                  !< components to SALSA from 
216                                                  !< from chemistry model
217    LOGICAL ::  van_der_waals_coagc   = .FALSE.   !< Enhancement of coagulation
218                                                  !< kernel by van der Waals and
219                                                  !< viscous forces
220    LOGICAL ::  write_binary_salsa    = .FALSE.   !< read binary for salsa
221!-- Process switches: nl* is read from the NAMELIST and is NOT changed.
222!--                   ls* is the switch used and will get the value of nl*
223!--                       except for special circumstances (spinup period etc.)
224    LOGICAL ::  nlcoag       = .FALSE. !< Coagulation master switch
225    LOGICAL ::  lscoag       = .FALSE. !<
226    LOGICAL ::  nlcnd        = .FALSE. !< Condensation master switch
227    LOGICAL ::  lscnd        = .FALSE. !<
228    LOGICAL ::  nlcndgas     = .FALSE. !< Condensation of precursor gases
229    LOGICAL ::  lscndgas     = .FALSE. !<
230    LOGICAL ::  nlcndh2oae   = .FALSE. !< Condensation of H2O on aerosol
231    LOGICAL ::  lscndh2oae   = .FALSE. !< particles (FALSE -> equilibrium calc.)
232    LOGICAL ::  nldepo       = .FALSE. !< Deposition master switch
233    LOGICAL ::  lsdepo       = .FALSE. !<
234    LOGICAL ::  nldepo_topo  = .FALSE. !< Deposition on vegetation master switch
235    LOGICAL ::  lsdepo_topo  = .FALSE. !<
236    LOGICAL ::  nldepo_vege  = .FALSE. !< Deposition on walls master switch
237    LOGICAL ::  lsdepo_vege  = .FALSE. !<
238    LOGICAL ::  nldistupdate = .TRUE.  !< Size distribution update master switch                                     
239    LOGICAL ::  lsdistupdate = .FALSE. !<                                     
240!
241!-- SALSA variables:
242    CHARACTER (LEN=20) ::  bc_salsa_b = 'neumann'   !< bottom boundary condition                                     
243    CHARACTER (LEN=20) ::  bc_salsa_t = 'neumann'   !< top boundary condition
244    CHARACTER (LEN=20) ::  depo_vege_type = 'zhang2001' !< or 'petroff2010'
245    CHARACTER (LEN=20) ::  depo_topo_type = 'zhang2001' !< or 'petroff2010'
246    CHARACTER (LEN=20), DIMENSION(4) ::  decycle_method = & 
247                             (/'dirichlet','dirichlet','dirichlet','dirichlet'/)
248                                 !< Decycling method at horizontal boundaries,
249                                 !< 1=left, 2=right, 3=south, 4=north
250                                 !< dirichlet = initial size distribution and
251                                 !< chemical composition set for the ghost and
252                                 !< first three layers
253                                 !< neumann = zero gradient
254    CHARACTER (LEN=3), DIMENSION(maxspec) ::  listspec = &  !< Active aerosols
255                                   (/'SO4','   ','   ','   ','   ','   ','   '/)
256    CHARACTER (LEN=20) ::  salsa_source_mode = 'no_source' 
257                                                    !< 'read_from_file',
258                                                    !< 'constant' or 'no_source'                                   
259    INTEGER(iwp) ::  dots_salsa = 0  !< starting index for salsa-timeseries
260    INTEGER(iwp) ::  fn1a = 1    !< last index for bin subranges:  subrange 1a
261    INTEGER(iwp) ::  fn2a = 1    !<                              subrange 2a
262    INTEGER(iwp) ::  fn2b = 1    !<                              subrange 2b
263    INTEGER(iwp), DIMENSION(ngast) ::  gas_index_chem = (/ 1, 1, 1, 1, 1/) !<
264                                 !< Index of gaseous compounds in the chemistry
265                                 !< model. In SALSA, 1 = H2SO4, 2 = HNO3,
266                                 !< 3 = NH3, 4 = OCNV, 5 = OCSV
267    INTEGER(iwp) ::  ibc_salsa_b !<
268    INTEGER(iwp) ::  ibc_salsa_t !<
269    INTEGER(iwp) ::  igctyp = 0  !< Initial gas concentration type
270                                 !< 0 = uniform (use H2SO4_init, HNO3_init,
271                                 !<     NH3_init, OCNV_init and OCSV_init)
272                                 !< 1 = read vertical profile from an input file 
273    INTEGER(iwp) ::  in1a = 1    !< start index for bin subranges: subrange 1a
274    INTEGER(iwp) ::  in2a = 1    !<                              subrange 2a
275    INTEGER(iwp) ::  in2b = 1    !<                              subrange 2b
276    INTEGER(iwp) ::  isdtyp = 0  !< Initial size distribution type
277                                 !< 0 = uniform
278                                 !< 1 = read vertical profile of the mode number
279                                 !<     concentration from an input file 
280    INTEGER(iwp) ::  ibc  = -1 !< Indice for: black carbon (BC)
281    INTEGER(iwp) ::  idu  = -1 !< dust
282    INTEGER(iwp) ::  inh  = -1 !< NH3
283    INTEGER(iwp) ::  ino  = -1 !< HNO3   
284    INTEGER(iwp) ::  ioc  = -1 !< organic carbon (OC)
285    INTEGER(iwp) ::  iso4 = -1 !< SO4 or H2SO4   
286    INTEGER(iwp) ::  iss  = -1 !< sea salt
287    INTEGER(iwp) ::  lod_aero = 0   !< level of detail for aerosol emissions
288    INTEGER(iwp) ::  lod_gases = 0  !< level of detail for gaseous emissions   
289    INTEGER(iwp), DIMENSION(nreg) ::  nbin = (/ 3, 7/)    !< Number of size bins
290                                               !< for each aerosol size subrange
291    INTEGER(iwp) ::  nbins = 1  !< total number of size bins
292    INTEGER(iwp) ::  ncc   = 1  !< number of chemical components used     
293    INTEGER(iwp) ::  ncc_tot = 1!< total number of chemical compounds (ncc+1
294                                !< if particle water is advected)
295    REAL(wp) ::  act_coeff = 1.0E-7_wp     !< Activation coefficient
296    REAL(wp) ::  aerosol_source = 0.0_wp   !< Constant aerosol flux (#/(m3*s))
297    REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::  emission_mass_fracs  !< array for
298                                    !< aerosol composition per emission category
299                                    !< 1:SO4 2:OC 3:BC 4:DU 5:SS 6:NO 7:NH 
300    REAL(wp) ::  dt_salsa  = 0.00001_wp    !< Time step of SALSA
301    REAL(wp) ::  H2SO4_init = nclim        !< Init value for sulphuric acid gas
302    REAL(wp) ::  HNO3_init  = nclim        !< Init value for nitric acid gas
303    REAL(wp) ::  last_salsa_time = 0.0_wp  !< time of the previous salsa
304                                           !< timestep
305    REAL(wp) ::  nf2a = 1.0_wp             !< Number fraction allocated to a-
306                                           !< bins in subrange 2
307                                           !< (b-bins will get 1-nf2a)   
308    REAL(wp) ::  NH3_init  = nclim         !< Init value for ammonia gas
309    REAL(wp) ::  OCNV_init = nclim         !< Init value for non-volatile
310                                           !< organic gases
311    REAL(wp) ::  OCSV_init = nclim         !< Init value for semi-volatile
312                                           !< organic gases
313    REAL(wp), DIMENSION(nreg+1) ::  reglim = & !< Min&max diameters of size subranges
314                                 (/ 3.0E-9_wp, 5.0E-8_wp, 1.0E-5_wp/)
315    REAL(wp) ::  rhlim = 1.20_wp    !< RH limit in %/100. Prevents
316                                    !< unrealistically high RH in condensation                           
317    REAL(wp) ::  skip_time_do_salsa = 0.0_wp !< Starting time of SALSA (s)
318!-- Initial log-normal size distribution: mode diameter (dpg, micrometres),
319!-- standard deviation (sigmag) and concentration (n_lognorm, #/cm3)
320    REAL(wp), DIMENSION(nmod) ::  dpg   = (/0.013_wp, 0.054_wp, 0.86_wp,       &
321                                            0.2_wp, 0.2_wp, 0.2_wp, 0.2_wp/) 
322    REAL(wp), DIMENSION(nmod) ::  sigmag  = (/1.8_wp, 2.16_wp, 2.21_wp,        &
323                                              2.0_wp, 2.0_wp, 2.0_wp, 2.0_wp/) 
324    REAL(wp), DIMENSION(nmod) ::  n_lognorm = (/1.04e+5_wp, 3.23E+4_wp, 5.4_wp,&
325                                                0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp/)
326!-- Initial mass fractions / chemical composition of the size distribution   
327    REAL(wp), DIMENSION(maxspec) ::  mass_fracs_a = & !< mass fractions between
328             (/1.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0/) !< aerosol species for A bins
329    REAL(wp), DIMENSION(maxspec) ::  mass_fracs_b = & !< mass fractions between
330             (/0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0/) !< aerosol species for B bins
331             
332    REAL(wp), ALLOCATABLE, DIMENSION(:) ::  bin_low_limits  !< to deliver
333                                                            !< information about
334                                                            !< the lower
335                                                            !< diameters per bin                                       
336    REAL(wp), ALLOCATABLE, DIMENSION(:) ::  nsect     !< Background number
337                                                      !< concentration per bin
338    REAL(wp), ALLOCATABLE, DIMENSION(:) ::  massacc   !< Mass accomodation
339                                                      !< coefficients per bin                                             
340!
341!-- SALSA derived datatypes:
342!
343!-- Prognostic variable: Aerosol size bin information (number (#/m3) and
344!-- mass (kg/m3) concentration) and the concentration of gaseous tracers (#/m3).
345!-- Gas tracers are contained sequentially in dimension 4 as:
346!-- 1. H2SO4, 2. HNO3, 3. NH3, 4. OCNV (non-volatile organics),
347!-- 5. OCSV (semi-volatile)
348    TYPE salsa_variable
349       REAL(wp), POINTER, DIMENSION(:,:,:), CONTIGUOUS     ::  conc
350       REAL(wp), POINTER, DIMENSION(:,:,:), CONTIGUOUS     ::  conc_p
351       REAL(wp), POINTER, DIMENSION(:,:,:), CONTIGUOUS     ::  tconc_m
352       REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  flux_s, diss_s
353       REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  flux_l, diss_l
354       REAL(wp), ALLOCATABLE, DIMENSION(:)     ::  init
355       REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  source
356       REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  sums_ws_l
357    END TYPE salsa_variable
358   
359!-- Map bin indices between parallel size distributions   
360    TYPE t_parallelbin
361       INTEGER(iwp) ::  cur  ! Index for current distribution
362       INTEGER(iwp) ::  par  ! Index for corresponding parallel distribution
363    END TYPE t_parallelbin
364   
365!-- Datatype used to store information about the binned size distributions of
366!-- aerosols
367    TYPE t_section
368       REAL(wp) ::  vhilim   !< bin volume at the high limit
369       REAL(wp) ::  vlolim   !< bin volume at the low limit
370       REAL(wp) ::  vratiohi !< volume ratio between the center and high limit
371       REAL(wp) ::  vratiolo !< volume ratio between the center and low limit
372       REAL(wp) ::  dmid     !< bin middle diameter (m)
373       !******************************************************
374       ! ^ Do NOT change the stuff above after initialization !
375       !******************************************************
376       REAL(wp) ::  dwet    !< Wet diameter or mean droplet diameter (m)
377       REAL(wp), DIMENSION(maxspec+1) ::  volc !< Volume concentrations
378                            !< (m^3/m^3) of aerosols + water. Since most of
379                            !< the stuff in SALSA is hard coded, these *have to
380                            !< be* in the order
381                            !< 1:SO4, 2:OC, 3:BC, 4:DU, 5:SS, 6:NO, 7:NH, 8:H2O
382       REAL(wp) ::  veqh2o  !< Equilibrium H2O concentration for each particle
383       REAL(wp) ::  numc    !< Number concentration of particles/droplets (#/m3)
384       REAL(wp) ::  core    !< Volume of dry particle
385    END TYPE t_section 
386!
387!-- Local aerosol properties in SALSA
388    TYPE(t_section), ALLOCATABLE ::  aero(:)
389!
390!-- SALSA tracers:
391!-- Tracers as x = x(k,j,i,bin). The 4th dimension contains all the size bins
392!-- sequentially for each aerosol species  + water.
393!
394!-- Prognostic tracers:
395!
396!-- Number concentration (#/m3)
397    TYPE(salsa_variable), ALLOCATABLE, DIMENSION(:), TARGET ::  aerosol_number
398    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  nconc_1
399    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  nconc_2
400    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  nconc_3
401!
402!-- Mass concentration (kg/m3)
403    TYPE(salsa_variable), ALLOCATABLE, DIMENSION(:), TARGET ::  aerosol_mass
404    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  mconc_1
405    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  mconc_2
406    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  mconc_3
407!
408!-- Gaseous tracers (#/m3)
409    TYPE(salsa_variable), ALLOCATABLE, DIMENSION(:), TARGET ::  salsa_gas
410    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  gconc_1
411    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  gconc_2
412    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  gconc_3
413!
414!-- Diagnostic tracers
415    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::  sedim_vd !< sedimentation
416                                                           !< velocity per size
417                                                           !< bin (m/s)
418    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::  Ra_dry !< dry radius (m)
419   
420!-- Particle component index tables
421    TYPE(component_index) :: prtcl !< Contains "getIndex" which gives the index
422                                   !< for a given aerosol component name, i.e.
423                                   !< 1:SO4, 2:OC, 3:BC, 4:DU,
424                                   !< 5:SS, 6:NO, 7:NH, 8:H2O 
425!                                   
426!-- Data output arrays:
427!-- Gases:
428    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  g_H2SO4_av  !< H2SO4
429    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  g_HNO3_av   !< HNO3
430    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  g_NH3_av    !< NH3
431    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  g_OCNV_av   !< non-vola-
432                                                                    !< tile OC
433    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  g_OCSV_av   !< semi-vol.
434                                                                    !< OC
435!-- Integrated:                                                                   
436    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  LDSA_av  !< lung-
437                                                                 !< deposited
438                                                                 !< surface area                                                   
439    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  Ntot_av  !< total number
440                                                                 !< conc.
441    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  PM25_av  !< PM2.5
442    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  PM10_av  !< PM10
443!-- In the particle phase:   
444    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  s_BC_av  !< black carbon
445    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  s_DU_av  !< dust
446    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  s_H2O_av !< liquid water
447    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  s_NH_av  !< ammonia
448    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  s_NO_av  !< nitrates
449    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  s_OC_av  !< org. carbon
450    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  s_SO4_av !< sulphates
451    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  s_SS_av  !< sea salt
452!-- Bins:   
453    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  mbins_av !< bin mass 
454    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  Nbins_av !< bin number
455
456   
457!
458!-- PALM interfaces:
459!
460!-- Boundary conditions:
461    INTERFACE salsa_boundary_conds
462       MODULE PROCEDURE salsa_boundary_conds
463       MODULE PROCEDURE salsa_boundary_conds_decycle
464    END INTERFACE salsa_boundary_conds
465!   
466!-- Data output checks for 2D/3D data to be done in check_parameters
467    INTERFACE salsa_check_data_output
468       MODULE PROCEDURE salsa_check_data_output
469    END INTERFACE salsa_check_data_output
470   
471!
472!-- Input parameter checks to be done in check_parameters
473    INTERFACE salsa_check_parameters
474       MODULE PROCEDURE salsa_check_parameters
475    END INTERFACE salsa_check_parameters
476
477!
478!-- Averaging of 3D data for output
479    INTERFACE salsa_3d_data_averaging
480       MODULE PROCEDURE salsa_3d_data_averaging
481    END INTERFACE salsa_3d_data_averaging
482
483!
484!-- Data output of 2D quantities
485    INTERFACE salsa_data_output_2d
486       MODULE PROCEDURE salsa_data_output_2d
487    END INTERFACE salsa_data_output_2d
488
489!
490!-- Data output of 3D data
491    INTERFACE salsa_data_output_3d
492       MODULE PROCEDURE salsa_data_output_3d
493    END INTERFACE salsa_data_output_3d
494   
495!
496!-- Data output of 3D data
497    INTERFACE salsa_data_output_mask
498       MODULE PROCEDURE salsa_data_output_mask
499    END INTERFACE salsa_data_output_mask
500
501!
502!-- Definition of data output quantities
503    INTERFACE salsa_define_netcdf_grid
504       MODULE PROCEDURE salsa_define_netcdf_grid
505    END INTERFACE salsa_define_netcdf_grid
506   
507!
508!-- Output of information to the header file
509    INTERFACE salsa_header
510       MODULE PROCEDURE salsa_header
511    END INTERFACE salsa_header
512 
513!
514!-- Initialization actions 
515    INTERFACE salsa_init
516       MODULE PROCEDURE salsa_init
517    END INTERFACE salsa_init
518 
519!
520!-- Initialization of arrays
521    INTERFACE salsa_init_arrays
522       MODULE PROCEDURE salsa_init_arrays
523    END INTERFACE salsa_init_arrays
524
525!
526!-- Writing of binary output for restart runs  !!! renaming?!
527    INTERFACE salsa_wrd_local
528       MODULE PROCEDURE salsa_wrd_local
529    END INTERFACE salsa_wrd_local
530   
531!
532!-- Reading of NAMELIST parameters
533    INTERFACE salsa_parin
534       MODULE PROCEDURE salsa_parin
535    END INTERFACE salsa_parin
536
537!
538!-- Reading of parameters for restart runs
539    INTERFACE salsa_rrd_local
540       MODULE PROCEDURE salsa_rrd_local
541    END INTERFACE salsa_rrd_local
542   
543!
544!-- Swapping of time levels (required for prognostic variables)
545    INTERFACE salsa_swap_timelevel
546       MODULE PROCEDURE salsa_swap_timelevel
547    END INTERFACE salsa_swap_timelevel
548
549    INTERFACE salsa_driver
550       MODULE PROCEDURE salsa_driver
551    END INTERFACE salsa_driver
552
553    INTERFACE salsa_tendency
554       MODULE PROCEDURE salsa_tendency
555       MODULE PROCEDURE salsa_tendency_ij
556    END INTERFACE salsa_tendency
557   
558   
559   
560    SAVE
561
562    PRIVATE
563!
564!-- Public functions:
565    PUBLIC salsa_boundary_conds, salsa_check_data_output,                      &
566           salsa_check_parameters, salsa_3d_data_averaging,                    &
567           salsa_data_output_2d, salsa_data_output_3d, salsa_data_output_mask, &
568           salsa_define_netcdf_grid, salsa_diagnostics, salsa_driver,          &
569           salsa_header, salsa_init, salsa_init_arrays, salsa_parin,           &
570           salsa_rrd_local, salsa_swap_timelevel, salsa_tendency,              &
571           salsa_wrd_local
572!
573!-- Public parameters, constants and initial values
574    PUBLIC dots_salsa, dt_salsa, last_salsa_time, lsdepo, salsa,               &
575           salsa_gases_from_chem, skip_time_do_salsa
576!
577!-- Public prognostic variables
578    PUBLIC aerosol_mass, aerosol_number, fn2a, fn2b, gconc_2, in1a, in2b,      &
579           mconc_2, nbins, ncc, ncc_tot, nclim, nconc_2, ngast, prtcl, Ra_dry, &
580           salsa_gas, sedim_vd
581           
582
583 CONTAINS
584
585!------------------------------------------------------------------------------!
586! Description:
587! ------------
588!> Parin for &salsa_par for new modules
589!------------------------------------------------------------------------------!
590 SUBROUTINE salsa_parin
591
592    IMPLICIT NONE
593
594    CHARACTER (LEN=80) ::  line   !< dummy string that contains the current line
595                                  !< of the parameter file
596                                 
597    NAMELIST /salsa_parameters/             &
598                          advect_particle_water, & ! Switch for advecting
599                                                ! particle water. If .FALSE.,
600                                                ! equilibration is called at
601                                                ! each time step.       
602                          bc_salsa_b,       &   ! bottom boundary condition
603                          bc_salsa_t,       &   ! top boundary condition
604                          decycle_lr,       &   ! decycle SALSA components
605                          decycle_method,   &   ! decycle method applied:
606                                                ! 1=left 2=right 3=south 4=north
607                          decycle_ns,       &   ! decycle SALSA components
608                          depo_vege_type,   &   ! Parametrisation type
609                          depo_topo_type,   &   ! Parametrisation type
610                          dpg,              &   ! Mean diameter for the initial
611                                                ! log-normal modes
612                          dt_salsa,         &   ! SALSA timestep in seconds
613                          feedback_to_palm, &   ! allow feedback due to
614                                                ! hydration / condensation
615                          H2SO4_init,       &   ! Init value for sulphuric acid
616                          HNO3_init,        &   ! Init value for nitric acid
617                          igctyp,           &   ! Initial gas concentration type
618                          isdtyp,           &   ! Initial size distribution type                                               
619                          listspec,         &   ! List of actived aerosols
620                                                ! (string list)
621                          mass_fracs_a,     &   ! Initial relative contribution 
622                                                ! of each species to particle 
623                                                ! volume in a-bins, 0 for unused
624                          mass_fracs_b,     &   ! Initial relative contribution 
625                                                ! of each species to particle
626                                                ! volume in b-bins, 0 for unused
627                          n_lognorm,        &   ! Number concentration for the
628                                                ! log-normal modes                                               
629                          nbin,             &   ! Number of size bins for
630                                                ! aerosol size subranges 1 & 2
631                          nf2a,             &   ! Number fraction of particles
632                                                ! allocated to a-bins in
633                                                ! subrange 2 b-bins will get
634                                                ! 1-nf2a                         
635                          NH3_init,         &   ! Init value for ammonia
636                          nj3,              &   ! J3 parametrization
637                                                ! 1 = condensational sink
638                                                !     (Kerminen&Kulmala, 2002)
639                                                ! 2 = coagulational sink
640                                                !     (Lehtinen et al. 2007)
641                                                ! 3 = coagS+self-coagulation
642                                                !     (Anttila et al. 2010)                                                   
643                          nlcnd,            &   ! Condensation master switch
644                          nlcndgas,         &   ! Condensation of gases
645                          nlcndh2oae,       &   ! Condensation of H2O                           
646                          nlcoag,           &   ! Coagulation master switch
647                          nldepo,           &   ! Deposition master switch
648                          nldepo_vege,      &   ! Deposition on vegetation
649                                                ! master switch
650                          nldepo_topo,      &   ! Deposition on topo master
651                                                ! switch                         
652                          nldistupdate,     &   ! Size distribution update
653                                                ! master switch
654                          nsnucl,           &   ! Nucleation scheme:
655                                                ! 0 = off,
656                                                ! 1 = binary nucleation
657                                                ! 2 = activation type nucleation
658                                                ! 3 = kinetic nucleation
659                                                ! 4 = ternary nucleation
660                                                ! 5 = nucleation with organics
661                                                ! 6 = activation type of
662                                                !     nucleation with H2SO4+ORG
663                                                ! 7 = heteromolecular nucleation
664                                                !     with H2SO4*ORG
665                                                ! 8 = homomolecular nucleation 
666                                                !     of H2SO4 + heteromolecular
667                                                !     nucleation with H2SO4*ORG
668                                                ! 9 = homomolecular nucleation
669                                                !     of H2SO4 and ORG + hetero-
670                                                !     molecular nucleation with
671                                                !     H2SO4*ORG
672                          OCNV_init,        &   ! Init value for non-volatile
673                                                ! organic gases
674                          OCSV_init,        &   ! Init value for semi-volatile
675                                                ! organic gases
676                          read_restart_data_salsa, & ! read restart data for
677                                                     ! salsa
678                          reglim,           &   ! Min&max diameter limits of
679                                                ! size subranges
680                          salsa,            &   ! Master switch for SALSA
681                          salsa_source_mode,&   ! 'read_from_file' or 'constant'
682                                                ! or 'no_source'
683                          sigmag,           &   ! stdev for the initial log-
684                                                ! normal modes                                               
685                          skip_time_do_salsa, & ! Starting time of SALSA (s)
686                          van_der_waals_coagc,& ! include van der Waals forces
687                          write_binary_salsa    ! Write binary for salsa
688                           
689       
690    line = ' '
691       
692!
693!-- Try to find salsa package
694    REWIND ( 11 )
695    line = ' '
696    DO WHILE ( INDEX( line, '&salsa_parameters' ) == 0 )
697       READ ( 11, '(A)', END=10 )  line
698    ENDDO
699    BACKSPACE ( 11 )
700
701!
702!-- Read user-defined namelist
703    READ ( 11, salsa_parameters )
704
705!
706!-- Enable salsa (salsa switch in modules.f90)
707    salsa = .TRUE.
708
709 10 CONTINUE
710       
711 END SUBROUTINE salsa_parin
712
713 
714!------------------------------------------------------------------------------!
715! Description:
716! ------------
717!> Check parameters routine for salsa.
718!------------------------------------------------------------------------------!
719 SUBROUTINE salsa_check_parameters
720
721    USE control_parameters,                                                    &
722        ONLY:  message_string
723       
724    IMPLICIT NONE
725   
726!
727!-- Checks go here (cf. check_parameters.f90).
728    IF ( salsa  .AND.  .NOT.  humidity )  THEN
729       WRITE( message_string, * ) 'salsa = ', salsa, ' is ',                   &
730              'not allowed with humidity = ', humidity
731       CALL message( 'check_parameters', 'SA0009', 1, 2, 0, 6, 0 )
732    ENDIF
733   
734    IF ( bc_salsa_b == 'dirichlet' )  THEN
735       ibc_salsa_b = 0
736    ELSEIF ( bc_salsa_b == 'neumann' )  THEN
737       ibc_salsa_b = 1
738    ELSE
739       message_string = 'unknown boundary condition: bc_salsa_b = "'           &
740                         // TRIM( bc_salsa_t ) // '"'
741       CALL message( 'check_parameters', 'SA0011', 1, 2, 0, 6, 0 )                 
742    ENDIF
743   
744    IF ( bc_salsa_t == 'dirichlet' )  THEN
745       ibc_salsa_t = 0
746    ELSEIF ( bc_salsa_t == 'neumann' )  THEN
747       ibc_salsa_t = 1
748    ELSE
749       message_string = 'unknown boundary condition: bc_salsa_t = "'           &
750                         // TRIM( bc_salsa_t ) // '"'
751       CALL message( 'check_parameters', 'SA0012', 1, 2, 0, 6, 0 )                 
752    ENDIF
753   
754    IF ( nj3 < 1  .OR.  nj3 > 3 )  THEN
755       message_string = 'unknown nj3 (must be 1-3)'
756       CALL message( 'check_parameters', 'SA0044', 1, 2, 0, 6, 0 )
757    ENDIF
758           
759 END SUBROUTINE salsa_check_parameters
760
761!------------------------------------------------------------------------------!
762!
763! Description:
764! ------------
765!> Subroutine defining appropriate grid for netcdf variables.
766!> It is called out from subroutine netcdf.
767!> Same grid as for other scalars (see netcdf_interface_mod.f90)
768!------------------------------------------------------------------------------!
769 SUBROUTINE salsa_define_netcdf_grid( var, found, grid_x, grid_y, grid_z )
770   
771    IMPLICIT NONE
772
773    CHARACTER (LEN=*), INTENT(OUT) ::  grid_x   !<
774    CHARACTER (LEN=*), INTENT(OUT) ::  grid_y   !<
775    CHARACTER (LEN=*), INTENT(OUT) ::  grid_z   !<
776    CHARACTER (LEN=*), INTENT(IN)  ::  var      !<
777   
778    LOGICAL, INTENT(OUT) ::  found   !<
779   
780    found  = .TRUE.
781!
782!-- Check for the grid
783
784    IF ( var(1:2) == 'g_' )  THEN
785       grid_x = 'x' 
786       grid_y = 'y' 
787       grid_z = 'zu'   
788    ELSEIF ( var(1:4) == 'LDSA' )  THEN
789       grid_x = 'x' 
790       grid_y = 'y' 
791       grid_z = 'zu'
792    ELSEIF ( var(1:5) == 'm_bin' )  THEN
793       grid_x = 'x' 
794       grid_y = 'y' 
795       grid_z = 'zu'
796    ELSEIF ( var(1:5) == 'N_bin' )  THEN
797       grid_x = 'x' 
798       grid_y = 'y' 
799       grid_z = 'zu'
800    ELSEIF ( var(1:4) == 'Ntot' ) THEN
801       grid_x = 'x' 
802       grid_y = 'y' 
803       grid_z = 'zu'
804    ELSEIF ( var(1:2) == 'PM' )  THEN
805       grid_x = 'x' 
806       grid_y = 'y' 
807       grid_z = 'zu'
808    ELSEIF ( var(1:2) == 's_' )  THEN
809       grid_x = 'x' 
810       grid_y = 'y' 
811       grid_z = 'zu'
812    ELSE
813       found  = .FALSE.
814       grid_x = 'none'
815       grid_y = 'none'
816       grid_z = 'none'
817    ENDIF
818
819 END SUBROUTINE salsa_define_netcdf_grid
820
821 
822!------------------------------------------------------------------------------!
823! Description:
824! ------------
825!> Header output for new module
826!------------------------------------------------------------------------------!
827 SUBROUTINE salsa_header( io )
828
829    IMPLICIT NONE
830 
831    INTEGER(iwp), INTENT(IN) ::  io   !< Unit of the output file
832!
833!-- Write SALSA header
834    WRITE( io, 1 )
835    WRITE( io, 2 ) skip_time_do_salsa
836    WRITE( io, 3 ) dt_salsa
837    WRITE( io, 12 )  SHAPE( aerosol_number(1)%conc ), nbins
838    IF ( advect_particle_water )  THEN
839       WRITE( io, 16 )  SHAPE( aerosol_mass(1)%conc ), ncc_tot*nbins,          &
840                        advect_particle_water
841    ELSE
842       WRITE( io, 16 )  SHAPE( aerosol_mass(1)%conc ), ncc*nbins,              &
843                        advect_particle_water
844    ENDIF
845    IF ( .NOT. salsa_gases_from_chem )  THEN
846       WRITE( io, 17 )  SHAPE( aerosol_mass(1)%conc ), ngast,                  &
847                        salsa_gases_from_chem
848    ENDIF
849    WRITE( io, 4 ) 
850    IF ( nsnucl > 0 )  THEN
851       WRITE( io, 5 ) nsnucl, nj3
852    ENDIF
853    IF ( nlcoag )  THEN
854       WRITE( io, 6 ) 
855    ENDIF
856    IF ( nlcnd )  THEN
857       WRITE( io, 7 ) nlcndgas, nlcndh2oae
858    ENDIF
859    IF ( nldepo )  THEN
860       WRITE( io, 14 ) nldepo_vege, nldepo_topo
861    ENDIF
862    WRITE( io, 8 )  reglim, nbin, bin_low_limits
863    WRITE( io, 15 ) nsect
864    WRITE( io, 13 ) ncc, listspec, mass_fracs_a, mass_fracs_b
865    IF ( .NOT. salsa_gases_from_chem )  THEN
866       WRITE( io, 18 ) ngast, H2SO4_init, HNO3_init, NH3_init, OCNV_init,      &
867                       OCSV_init
868    ENDIF
869    WRITE( io, 9 )  isdtyp, igctyp
870    IF ( isdtyp == 0 )  THEN
871       WRITE( io, 10 )  dpg, sigmag, n_lognorm
872    ELSE
873       WRITE( io, 11 )
874    ENDIF
875   
876
8771   FORMAT (//' SALSA information:'/                                           &
878              ' ------------------------------'/)
8792   FORMAT   ('    Starts at: skip_time_do_salsa = ', F10.2, '  s')
8803   FORMAT  (/'    Timestep: dt_salsa = ', F6.2, '  s')
88112  FORMAT  (/'    Array shape (z,y,x,bins):'/                                 &
882              '       aerosol_number:  ', 4(I3)) 
88316  FORMAT  (/'       aerosol_mass:    ', 4(I3),/                              &
884              '       (advect_particle_water = ', L1, ')')
88517  FORMAT   ('       salsa_gas: ', 4(I3),/                                    &
886              '       (salsa_gases_from_chem = ', L1, ')')
8874   FORMAT  (/'    Aerosol dynamic processes included: ')
8885   FORMAT  (/'       nucleation (scheme = ', I1, ' and J3 parametrization = ',&
889               I1, ')')
8906   FORMAT  (/'       coagulation')
8917   FORMAT  (/'       condensation (of precursor gases = ', L1,                &
892              '          and water vapour = ', L1, ')' )
89314  FORMAT  (/'       dry deposition (on vegetation = ', L1,                   &
894              '          and on topography = ', L1, ')')             
8958   FORMAT  (/'    Aerosol bin subrange limits (in metres): ',  3(ES10.2E3), / &
896              '    Number of size bins for each aerosol subrange: ', 2I3,/     &
897              '    Aerosol bin limits (in metres): ', *(ES10.2E3))
89815  FORMAT   ('    Initial number concentration in bins at the lowest level',  &
899              ' (#/m**3):', *(ES10.2E3))       
90013  FORMAT  (/'    Number of chemical components used: ', I1,/                 &
901              '       Species: ',7(A6),/                                       &
902              '    Initial relative contribution of each species to particle', & 
903              ' volume in:',/                                                  &
904              '       a-bins: ', 7(F6.3),/                                     &
905              '       b-bins: ', 7(F6.3))
90618  FORMAT  (/'    Number of gaseous tracers used: ', I1,/                     &
907              '    Initial gas concentrations:',/                              &
908              '       H2SO4: ',ES12.4E3, ' #/m**3',/                           &
909              '       HNO3:  ',ES12.4E3, ' #/m**3',/                           &
910              '       NH3:   ',ES12.4E3, ' #/m**3',/                           &
911              '       OCNV:  ',ES12.4E3, ' #/m**3',/                           &
912              '       OCSV:  ',ES12.4E3, ' #/m**3')
9139    FORMAT (/'   Initialising concentrations: ', /                            &
914              '      Aerosol size distribution: isdtyp = ', I1,/               &
915              '      Gas concentrations: igctyp = ', I1 )
91610   FORMAT ( '      Mode diametres: dpg(nmod) = ', 7(F7.3),/                  &
917              '      Standard deviation: sigmag(nmod) = ', 7(F7.2),/           &
918              '      Number concentration: n_lognorm(nmod) = ', 7(ES12.4E3) )
91911   FORMAT (/'      Size distribution read from a file.')
920
921 END SUBROUTINE salsa_header
922
923!------------------------------------------------------------------------------!
924! Description:
925! ------------
926!> Allocate SALSA arrays and define pointers if required
927!------------------------------------------------------------------------------!
928 SUBROUTINE salsa_init_arrays
929 
930    USE surface_mod,                                                           &
931        ONLY:  surf_def_h, surf_def_v, surf_lsm_h, surf_lsm_v, surf_usm_h,     &
932               surf_usm_v
933
934    IMPLICIT NONE
935   
936    INTEGER(iwp) ::  gases_available !< Number of available gas components in
937                                     !< the chemistry model
938    INTEGER(iwp) ::  i   !< loop index for allocating
939    INTEGER(iwp) ::  l   !< loop index for allocating: surfaces
940    INTEGER(iwp) ::  lsp !< loop index for chem species in the chemistry model
941   
942    gases_available = 0
943
944!
945!-- Allocate prognostic variables (see salsa_swap_timelevel)
946
947!
948!-- Set derived indices:
949!-- (This does the same as the subroutine salsa_initialize in SALSA/
950!-- UCLALES-SALSA)       
951    in1a = 1                ! 1st index of subrange 1a
952    in2a = in1a + nbin(1)   ! 1st index of subrange 2a
953    fn1a = in2a - 1         ! last index of subrange 1a
954    fn2a = fn1a + nbin(2)   ! last index of subrange 2a
955   
956!   
957!-- If the fraction of insoluble aerosols in subrange 2 is zero: do not allocate
958!-- arrays for them
959    IF ( nf2a > 0.999999_wp  .AND.  SUM( mass_fracs_b ) < 0.00001_wp )  THEN
960       no_insoluble = .TRUE.
961       in2b = fn2a+1    ! 1st index of subrange 2b
962       fn2b = fn2a      ! last index of subrange 2b
963    ELSE
964       in2b = in2a + nbin(2)   ! 1st index of subrange 2b
965       fn2b = fn2a + nbin(2)   ! last index of subrange 2b
966    ENDIF
967   
968   
969    nbins = fn2b   ! total number of aerosol size bins
970!   
971!-- Create index tables for different aerosol components
972    CALL component_index_constructor( prtcl, ncc, maxspec, listspec )
973   
974    ncc_tot = ncc
975    IF ( advect_particle_water )  ncc_tot = ncc + 1  ! Add water
976   
977!
978!-- Allocate:
979    ALLOCATE( aero(nbins), bin_low_limits(nbins), nsect(nbins), massacc(nbins) )
980    IF ( nldepo ) ALLOCATE( sedim_vd(nzb:nzt+1,nysg:nyng,nxlg:nxrg,nbins) )         
981    ALLOCATE( Ra_dry(nzb:nzt+1,nysg:nyng,nxlg:nxrg,nbins) )
982   
983!   
984!-- Aerosol number concentration
985    ALLOCATE( aerosol_number(nbins) )
986    ALLOCATE( nconc_1(nzb:nzt+1,nysg:nyng,nxlg:nxrg,nbins),                    &
987              nconc_2(nzb:nzt+1,nysg:nyng,nxlg:nxrg,nbins),                    &
988              nconc_3(nzb:nzt+1,nysg:nyng,nxlg:nxrg,nbins) )
989    nconc_1 = 0.0_wp
990    nconc_2 = 0.0_wp
991    nconc_3 = 0.0_wp
992   
993    DO i = 1, nbins
994       aerosol_number(i)%conc(nzb:nzt+1,nysg:nyng,nxlg:nxrg)    => nconc_1(:,:,:,i)
995       aerosol_number(i)%conc_p(nzb:nzt+1,nysg:nyng,nxlg:nxrg)  => nconc_2(:,:,:,i)
996       aerosol_number(i)%tconc_m(nzb:nzt+1,nysg:nyng,nxlg:nxrg) => nconc_3(:,:,:,i)
997       ALLOCATE( aerosol_number(i)%flux_s(nzb+1:nzt,0:threads_per_task-1),     &
998                 aerosol_number(i)%diss_s(nzb+1:nzt,0:threads_per_task-1),     &
999                 aerosol_number(i)%flux_l(nzb+1:nzt,nys:nyn,0:threads_per_task-1),&
1000                 aerosol_number(i)%diss_l(nzb+1:nzt,nys:nyn,0:threads_per_task-1),&
1001                 aerosol_number(i)%init(nzb:nzt+1),                            &
1002                 aerosol_number(i)%sums_ws_l(nzb:nzt+1,0:threads_per_task-1) )
1003    ENDDO     
1004   
1005!   
1006!-- Aerosol mass concentration   
1007    ALLOCATE( aerosol_mass(ncc_tot*nbins) ) 
1008    ALLOCATE( mconc_1(nzb:nzt+1,nysg:nyng,nxlg:nxrg,ncc_tot*nbins),            &
1009              mconc_2(nzb:nzt+1,nysg:nyng,nxlg:nxrg,ncc_tot*nbins),            &
1010              mconc_3(nzb:nzt+1,nysg:nyng,nxlg:nxrg,ncc_tot*nbins) )
1011    mconc_1 = 0.0_wp
1012    mconc_2 = 0.0_wp
1013    mconc_3 = 0.0_wp
1014   
1015    DO i = 1, ncc_tot*nbins
1016       aerosol_mass(i)%conc(nzb:nzt+1,nysg:nyng,nxlg:nxrg)    => mconc_1(:,:,:,i)
1017       aerosol_mass(i)%conc_p(nzb:nzt+1,nysg:nyng,nxlg:nxrg)  => mconc_2(:,:,:,i)
1018       aerosol_mass(i)%tconc_m(nzb:nzt+1,nysg:nyng,nxlg:nxrg) => mconc_3(:,:,:,i)       
1019       ALLOCATE( aerosol_mass(i)%flux_s(nzb+1:nzt,0:threads_per_task-1),       &
1020                 aerosol_mass(i)%diss_s(nzb+1:nzt,0:threads_per_task-1),       &
1021                 aerosol_mass(i)%flux_l(nzb+1:nzt,nys:nyn,0:threads_per_task-1),&
1022                 aerosol_mass(i)%diss_l(nzb+1:nzt,nys:nyn,0:threads_per_task-1),&
1023                 aerosol_mass(i)%init(nzb:nzt+1),                              &
1024                 aerosol_mass(i)%sums_ws_l(nzb:nzt+1,0:threads_per_task-1)  )
1025    ENDDO
1026   
1027!
1028!-- Surface fluxes: answs = aerosol number, amsws = aerosol mass
1029!
1030!-- Horizontal surfaces: default type
1031    DO  l = 0, 2   ! upward (l=0), downward (l=1) and model top (l=2)
1032       ALLOCATE( surf_def_h(l)%answs( 1:surf_def_h(l)%ns, nbins ) )
1033       ALLOCATE( surf_def_h(l)%amsws( 1:surf_def_h(l)%ns, nbins*ncc_tot ) )
1034       surf_def_h(l)%answs = 0.0_wp
1035       surf_def_h(l)%amsws = 0.0_wp
1036    ENDDO
1037!-- Horizontal surfaces: natural type   
1038    IF ( land_surface )  THEN
1039       ALLOCATE( surf_lsm_h%answs( 1:surf_lsm_h%ns, nbins ) )
1040       ALLOCATE( surf_lsm_h%amsws( 1:surf_lsm_h%ns, nbins*ncc_tot ) )
1041       surf_lsm_h%answs = 0.0_wp
1042       surf_lsm_h%amsws = 0.0_wp
1043    ENDIF
1044!-- Horizontal surfaces: urban type
1045    IF ( urban_surface )  THEN
1046       ALLOCATE( surf_usm_h%answs( 1:surf_usm_h%ns, nbins ) )
1047       ALLOCATE( surf_usm_h%amsws( 1:surf_usm_h%ns, nbins*ncc_tot ) )
1048       surf_usm_h%answs = 0.0_wp
1049       surf_usm_h%amsws = 0.0_wp
1050    ENDIF
1051!
1052!-- Vertical surfaces: northward (l=0), southward (l=1), eastward (l=2) and
1053!-- westward (l=3) facing
1054    DO  l = 0, 3   
1055       ALLOCATE( surf_def_v(l)%answs( 1:surf_def_v(l)%ns, nbins ) )
1056       surf_def_v(l)%answs = 0.0_wp
1057       ALLOCATE( surf_def_v(l)%amsws( 1:surf_def_v(l)%ns, nbins*ncc_tot ) )
1058       surf_def_v(l)%amsws = 0.0_wp
1059       
1060       IF ( land_surface)  THEN
1061          ALLOCATE( surf_lsm_v(l)%answs( 1:surf_lsm_v(l)%ns, nbins ) )
1062          surf_lsm_v(l)%answs = 0.0_wp
1063          ALLOCATE( surf_lsm_v(l)%amsws( 1:surf_lsm_v(l)%ns, nbins*ncc_tot ) )
1064          surf_lsm_v(l)%amsws = 0.0_wp
1065       ENDIF
1066       
1067       IF ( urban_surface )  THEN
1068          ALLOCATE( surf_usm_v(l)%answs( 1:surf_usm_v(l)%ns, nbins ) )
1069          surf_usm_v(l)%answs = 0.0_wp
1070          ALLOCATE( surf_usm_v(l)%amsws( 1:surf_usm_v(l)%ns, nbins*ncc_tot ) )
1071          surf_usm_v(l)%amsws = 0.0_wp
1072       ENDIF
1073    ENDDO   
1074   
1075!
1076!-- Concentration of gaseous tracers (1. SO4, 2. HNO3, 3. NH3, 4. OCNV, 5. OCSV)
1077!-- (number concentration (#/m3) )
1078!
1079!-- If chemistry is on, read gas phase concentrations from there. Otherwise,
1080!-- allocate salsa_gas array.
1081
1082    IF ( air_chemistry )  THEN   
1083       DO  lsp = 1, nvar
1084          IF ( TRIM( chem_species(lsp)%name ) == 'H2SO4' )  THEN
1085             gases_available = gases_available + 1
1086             gas_index_chem(1) = lsp
1087          ELSEIF ( TRIM( chem_species(lsp)%name ) == 'HNO3' )  THEN
1088             gases_available = gases_available + 1 
1089             gas_index_chem(2) = lsp
1090          ELSEIF ( TRIM( chem_species(lsp)%name ) == 'NH3' )  THEN
1091             gases_available = gases_available + 1
1092             gas_index_chem(3) = lsp
1093          ELSEIF ( TRIM( chem_species(lsp)%name ) == 'OCNV' )  THEN
1094             gases_available = gases_available + 1
1095             gas_index_chem(4) = lsp
1096          ELSEIF ( TRIM( chem_species(lsp)%name ) == 'OCSV' )  THEN
1097             gases_available = gases_available + 1
1098             gas_index_chem(5) = lsp
1099          ENDIF
1100       ENDDO
1101
1102       IF ( gases_available == ngast )  THEN
1103          salsa_gases_from_chem = .TRUE.
1104       ELSE
1105          WRITE( message_string, * ) 'SALSA is run together with chemistry '// &
1106                                     'but not all gaseous components are '//   &
1107                                     'provided by kpp (H2SO4, HNO3, NH3, '//   &
1108                                     'OCNV, OCSC)'
1109       CALL message( 'check_parameters', 'SA0024', 1, 2, 0, 6, 0 )
1110       ENDIF
1111
1112    ELSE
1113
1114       ALLOCATE( salsa_gas(ngast) ) 
1115       ALLOCATE( gconc_1(nzb:nzt+1,nysg:nyng,nxlg:nxrg,ngast),                 &
1116                 gconc_2(nzb:nzt+1,nysg:nyng,nxlg:nxrg,ngast),                 &
1117                 gconc_3(nzb:nzt+1,nysg:nyng,nxlg:nxrg,ngast) )
1118       gconc_1 = 0.0_wp
1119       gconc_2 = 0.0_wp
1120       gconc_3 = 0.0_wp
1121       
1122       DO i = 1, ngast
1123          salsa_gas(i)%conc(nzb:nzt+1,nysg:nyng,nxlg:nxrg)    => gconc_1(:,:,:,i)
1124          salsa_gas(i)%conc_p(nzb:nzt+1,nysg:nyng,nxlg:nxrg)  => gconc_2(:,:,:,i)
1125          salsa_gas(i)%tconc_m(nzb:nzt+1,nysg:nyng,nxlg:nxrg) => gconc_3(:,:,:,i)
1126          ALLOCATE( salsa_gas(i)%flux_s(nzb+1:nzt,0:threads_per_task-1),       &
1127                    salsa_gas(i)%diss_s(nzb+1:nzt,0:threads_per_task-1),       &
1128                    salsa_gas(i)%flux_l(nzb+1:nzt,nys:nyn,0:threads_per_task-1),&
1129                    salsa_gas(i)%diss_l(nzb+1:nzt,nys:nyn,0:threads_per_task-1),&
1130                    salsa_gas(i)%init(nzb:nzt+1),                              &
1131                    salsa_gas(i)%sums_ws_l(nzb:nzt+1,0:threads_per_task-1) )
1132       ENDDO       
1133!
1134!--    Surface fluxes: gtsws = gaseous tracer flux
1135!
1136!--    Horizontal surfaces: default type
1137       DO  l = 0, 2   ! upward (l=0), downward (l=1) and model top (l=2)
1138          ALLOCATE( surf_def_h(l)%gtsws( 1:surf_def_h(l)%ns, ngast ) )
1139          surf_def_h(l)%gtsws = 0.0_wp
1140       ENDDO
1141!--    Horizontal surfaces: natural type   
1142       IF ( land_surface )  THEN
1143          ALLOCATE( surf_lsm_h%gtsws( 1:surf_lsm_h%ns, ngast ) )
1144          surf_lsm_h%gtsws = 0.0_wp
1145       ENDIF
1146!--    Horizontal surfaces: urban type         
1147       IF ( urban_surface )  THEN
1148          ALLOCATE( surf_usm_h%gtsws( 1:surf_usm_h%ns, ngast ) )
1149          surf_usm_h%gtsws = 0.0_wp
1150       ENDIF
1151!
1152!--    Vertical surfaces: northward (l=0), southward (l=1), eastward (l=2) and
1153!--    westward (l=3) facing
1154       DO  l = 0, 3     
1155          ALLOCATE( surf_def_v(l)%gtsws( 1:surf_def_v(l)%ns, ngast ) )
1156          surf_def_v(l)%gtsws = 0.0_wp
1157          IF ( land_surface )  THEN
1158             ALLOCATE( surf_lsm_v(l)%gtsws( 1:surf_lsm_v(l)%ns, ngast ) )
1159             surf_lsm_v(l)%gtsws = 0.0_wp
1160          ENDIF
1161          IF ( urban_surface )  THEN
1162             ALLOCATE( surf_usm_v(l)%gtsws( 1:surf_usm_v(l)%ns, ngast ) )
1163             surf_usm_v(l)%gtsws = 0.0_wp
1164          ENDIF
1165       ENDDO
1166    ENDIF
1167   
1168 END SUBROUTINE salsa_init_arrays
1169
1170!------------------------------------------------------------------------------!
1171! Description:
1172! ------------
1173!> Initialization of SALSA. Based on salsa_initialize in UCLALES-SALSA.
1174!> Subroutines salsa_initialize, SALSAinit and DiagInitAero in UCLALES-SALSA are
1175!> also merged here.
1176!------------------------------------------------------------------------------!
1177 SUBROUTINE salsa_init
1178
1179    IMPLICIT NONE
1180   
1181    INTEGER(iwp) :: b
1182    INTEGER(iwp) :: c
1183    INTEGER(iwp) :: g
1184    INTEGER(iwp) :: i
1185    INTEGER(iwp) :: j
1186   
1187    CALL location_message( 'initializing SALSA model', .TRUE. )
1188   
1189    bin_low_limits = 0.0_wp
1190    nsect          = 0.0_wp
1191    massacc        = 1.0_wp 
1192   
1193!
1194!-- Indices for chemical components used (-1 = not used)
1195    i = 0
1196    IF ( is_used( prtcl, 'SO4' ) )  THEN
1197       iso4 = get_index( prtcl,'SO4' )
1198       i = i + 1
1199    ENDIF
1200    IF ( is_used( prtcl,'OC' ) )  THEN
1201       ioc = get_index(prtcl, 'OC')
1202       i = i + 1
1203    ENDIF
1204    IF ( is_used( prtcl, 'BC' ) )  THEN
1205       ibc = get_index( prtcl, 'BC' )
1206       i = i + 1
1207    ENDIF
1208    IF ( is_used( prtcl, 'DU' ) )  THEN
1209       idu = get_index( prtcl, 'DU' )
1210       i = i + 1
1211    ENDIF
1212    IF ( is_used( prtcl, 'SS' ) )  THEN
1213       iss = get_index( prtcl, 'SS' )
1214       i = i + 1
1215    ENDIF
1216    IF ( is_used( prtcl, 'NO' ) )  THEN
1217       ino = get_index( prtcl, 'NO' )
1218       i = i + 1
1219    ENDIF
1220    IF ( is_used( prtcl, 'NH' ) )  THEN
1221       inh = get_index( prtcl, 'NH' )
1222       i = i + 1
1223    ENDIF
1224!   
1225!-- All species must be known
1226    IF ( i /= ncc )  THEN
1227       message_string = 'Unknown aerosol species/component(s) given in the' // &
1228                        ' initialization'
1229       CALL message( 'salsa_mod: salsa_init', 'SA0020', 1, 2, 0, 6, 0 )
1230    ENDIF
1231   
1232!
1233!-- Initialise
1234!
1235!-- Aerosol size distribution (TYPE t_section)
1236    aero(:)%dwet     = 1.0E-10_wp
1237    aero(:)%veqh2o   = 1.0E-10_wp
1238    aero(:)%numc     = nclim
1239    aero(:)%core     = 1.0E-10_wp
1240    DO c = 1, maxspec+1    ! 1:SO4, 2:OC, 3:BC, 4:DU, 5:SS, 6:NO, 7:NH, 8:H2O
1241       aero(:)%volc(c) = 0.0_wp
1242    ENDDO
1243   
1244    IF ( nldepo )  sedim_vd = 0.0_wp 
1245   
1246    DO  b = 1, nbins
1247       IF ( .NOT. read_restart_data_salsa )  aerosol_number(b)%conc = nclim
1248       aerosol_number(b)%conc_p    = 0.0_wp
1249       aerosol_number(b)%tconc_m   = 0.0_wp
1250       aerosol_number(b)%flux_s    = 0.0_wp
1251       aerosol_number(b)%diss_s    = 0.0_wp
1252       aerosol_number(b)%flux_l    = 0.0_wp
1253       aerosol_number(b)%diss_l    = 0.0_wp
1254       aerosol_number(b)%init      = nclim
1255       aerosol_number(b)%sums_ws_l = 0.0_wp
1256    ENDDO
1257    DO  c = 1, ncc_tot*nbins
1258       IF ( .NOT. read_restart_data_salsa )  aerosol_mass(c)%conc = mclim
1259       aerosol_mass(c)%conc_p    = 0.0_wp
1260       aerosol_mass(c)%tconc_m   = 0.0_wp
1261       aerosol_mass(c)%flux_s    = 0.0_wp
1262       aerosol_mass(c)%diss_s    = 0.0_wp
1263       aerosol_mass(c)%flux_l    = 0.0_wp
1264       aerosol_mass(c)%diss_l    = 0.0_wp
1265       aerosol_mass(c)%init      = mclim
1266       aerosol_mass(c)%sums_ws_l = 0.0_wp
1267    ENDDO
1268   
1269    IF ( .NOT. salsa_gases_from_chem )  THEN
1270       DO  g = 1, ngast
1271          salsa_gas(g)%conc_p    = 0.0_wp
1272          salsa_gas(g)%tconc_m   = 0.0_wp
1273          salsa_gas(g)%flux_s    = 0.0_wp
1274          salsa_gas(g)%diss_s    = 0.0_wp
1275          salsa_gas(g)%flux_l    = 0.0_wp
1276          salsa_gas(g)%diss_l    = 0.0_wp
1277          salsa_gas(g)%sums_ws_l = 0.0_wp
1278       ENDDO
1279       IF ( .NOT. read_restart_data_salsa )  THEN
1280          salsa_gas(1)%conc = H2SO4_init
1281          salsa_gas(2)%conc = HNO3_init
1282          salsa_gas(3)%conc = NH3_init
1283          salsa_gas(4)%conc = OCNV_init
1284          salsa_gas(5)%conc = OCSV_init
1285       ENDIF
1286!
1287!--    Set initial value for gas compound tracers and initial values
1288       salsa_gas(1)%init = H2SO4_init
1289       salsa_gas(2)%init = HNO3_init
1290       salsa_gas(3)%init = NH3_init
1291       salsa_gas(4)%init = OCNV_init
1292       salsa_gas(5)%init = OCSV_init     
1293    ENDIF
1294!
1295!-- Aerosol radius in each bin: dry and wet (m)
1296    Ra_dry = 1.0E-10_wp
1297!   
1298!-- Initialise aerosol tracers   
1299    aero(:)%vhilim   = 0.0_wp
1300    aero(:)%vlolim   = 0.0_wp
1301    aero(:)%vratiohi = 0.0_wp
1302    aero(:)%vratiolo = 0.0_wp
1303    aero(:)%dmid     = 0.0_wp
1304!
1305!-- Initialise the sectional particle size distribution
1306    CALL set_sizebins()
1307!
1308!-- Initialise location-dependent aerosol size distributions and
1309!-- chemical compositions:
1310    CALL aerosol_init
1311!
1312!-- Initalisation run of SALSA
1313    DO  i = nxl, nxr
1314       DO  j = nys, nyn
1315          CALL salsa_driver( i, j, 1 )
1316          CALL salsa_diagnostics( i, j )
1317       ENDDO
1318    ENDDO
1319!
1320!-- Set the aerosol and gas sources
1321    IF ( salsa_source_mode == 'read_from_file' )  THEN
1322       CALL salsa_set_source
1323    ENDIF
1324   
1325    CALL location_message( 'finished', .TRUE. )
1326   
1327 END SUBROUTINE salsa_init
1328
1329!------------------------------------------------------------------------------!
1330! Description:
1331! ------------
1332!> Initializes particle size distribution grid by calculating size bin limits
1333!> and mid-size for *dry* particles in each bin. Called from salsa_initialize
1334!> (only at the beginning of simulation).
1335!> Size distribution described using:
1336!>   1) moving center method (subranges 1 and 2)
1337!>      (Jacobson, Atmos. Env., 31, 131-144, 1997)
1338!>   2) fixed sectional method (subrange 3)
1339!> Size bins in each subrange are spaced logarithmically
1340!> based on given subrange size limits and bin number.
1341!
1342!> Mona changed 06/2017: Use geometric mean diameter to describe the mean
1343!> particle diameter in a size bin, not the arithmeric mean which clearly
1344!> overestimates the total particle volume concentration.
1345!
1346!> Coded by:
1347!> Hannele Korhonen (FMI) 2005
1348!> Harri Kokkola (FMI) 2006
1349!
1350!> Bug fixes for box model + updated for the new aerosol datatype:
1351!> Juha Tonttila (FMI) 2014
1352!------------------------------------------------------------------------------!
1353 SUBROUTINE set_sizebins
1354               
1355    IMPLICIT NONE
1356!   
1357!-- Local variables
1358    INTEGER(iwp) ::  cc
1359    INTEGER(iwp) ::  dd
1360    REAL(wp) ::  ratio_d !< ratio of the upper and lower diameter of subranges
1361!
1362!-- vlolim&vhilim: min & max *dry* volumes [fxm]
1363!-- dmid: bin mid *dry* diameter (m)
1364!-- vratiolo&vratiohi: volume ratio between the center and low/high limit
1365!
1366!-- 1) Size subrange 1:
1367    ratio_d = reglim(2) / reglim(1)   ! section spacing (m)
1368    DO  cc = in1a,fn1a
1369       aero(cc)%vlolim = api6 * ( reglim(1) * ratio_d **                       &
1370                                ( REAL( cc-1 ) / nbin(1) ) ) ** 3.0_wp
1371       aero(cc)%vhilim = api6 * ( reglim(1) * ratio_d **                       &
1372                                ( REAL( cc ) / nbin(1) ) ) ** 3.0_wp
1373       aero(cc)%dmid = SQRT( ( aero(cc)%vhilim / api6 ) ** ( 1.0_wp / 3.0_wp ) &
1374                           * ( aero(cc)%vlolim / api6 ) ** ( 1.0_wp / 3.0_wp ) )
1375       aero(cc)%vratiohi = aero(cc)%vhilim / ( api6 * aero(cc)%dmid ** 3.0_wp )
1376       aero(cc)%vratiolo = aero(cc)%vlolim / ( api6 * aero(cc)%dmid ** 3.0_wp )
1377    ENDDO
1378!
1379!-- 2) Size subrange 2:
1380!-- 2.1) Sub-subrange 2a: high hygroscopicity
1381    ratio_d = reglim(3) / reglim(2)   ! section spacing
1382    DO  dd = in2a, fn2a
1383       cc = dd - in2a
1384       aero(dd)%vlolim = api6 * ( reglim(2) * ratio_d **                       &
1385                                  ( REAL( cc ) / nbin(2) ) ) ** 3.0_wp
1386       aero(dd)%vhilim = api6 * ( reglim(2) * ratio_d **                       &
1387                                  ( REAL( cc+1 ) / nbin(2) ) ) ** 3.0_wp
1388       aero(dd)%dmid = SQRT( ( aero(dd)%vhilim / api6 ) ** ( 1.0_wp / 3.0_wp ) &
1389                           * ( aero(dd)%vlolim / api6 ) ** ( 1.0_wp / 3.0_wp ) )
1390       aero(dd)%vratiohi = aero(dd)%vhilim / ( api6 * aero(dd)%dmid ** 3.0_wp )
1391       aero(dd)%vratiolo = aero(dd)%vlolim / ( api6 * aero(dd)%dmid ** 3.0_wp )
1392    ENDDO
1393!         
1394!-- 2.2) Sub-subrange 2b: low hygroscopicity
1395    IF ( .NOT. no_insoluble )  THEN
1396       aero(in2b:fn2b)%vlolim   = aero(in2a:fn2a)%vlolim
1397       aero(in2b:fn2b)%vhilim   = aero(in2a:fn2a)%vhilim
1398       aero(in2b:fn2b)%dmid     = aero(in2a:fn2a)%dmid
1399       aero(in2b:fn2b)%vratiohi = aero(in2a:fn2a)%vratiohi
1400       aero(in2b:fn2b)%vratiolo = aero(in2a:fn2a)%vratiolo
1401    ENDIF
1402!         
1403!-- Initialize the wet diameter with the bin dry diameter to avoid numerical
1404!-- problems later
1405    aero(:)%dwet = aero(:)%dmid
1406!
1407!-- Save bin limits (lower diameter) to be delivered to the host model if needed
1408    DO cc = 1, nbins
1409       bin_low_limits(cc) = ( aero(cc)%vlolim / api6 )**( 1.0_wp / 3.0_wp )
1410    ENDDO   
1411   
1412 END SUBROUTINE set_sizebins
1413 
1414!------------------------------------------------------------------------------!
1415! Description:
1416! ------------
1417!> Initilize altitude-dependent aerosol size distributions and compositions.
1418!>
1419!> Mona added 06/2017: Correct the number and mass concentrations by normalizing
1420!< by the given total number and mass concentration.
1421!>
1422!> Tomi Raatikainen, FMI, 29.2.2016
1423!------------------------------------------------------------------------------!
1424 SUBROUTINE aerosol_init
1425 
1426    USE arrays_3d,                                                             &
1427        ONLY:  zu
1428 
1429!    USE NETCDF
1430   
1431    USE netcdf_data_input_mod,                                                 &
1432        ONLY:  get_attribute, get_variable,                                    &
1433               netcdf_data_input_get_dimension_length, open_read_file
1434   
1435    IMPLICIT NONE
1436   
1437    INTEGER(iwp) ::  b          !< loop index: size bins
1438    INTEGER(iwp) ::  c          !< loop index: chemical components
1439    INTEGER(iwp) ::  ee         !< index: end
1440    INTEGER(iwp) ::  g          !< loop index: gases
1441    INTEGER(iwp) ::  i          !< loop index: x-direction
1442    INTEGER(iwp) ::  id_faero   !< NetCDF id of PIDS_SALSA
1443    INTEGER(iwp) ::  id_fchem   !< NetCDF id of PIDS_CHEM
1444    INTEGER(iwp) ::  j          !< loop index: y-direction
1445    INTEGER(iwp) ::  k          !< loop index: z-direction
1446    INTEGER(iwp) ::  kk         !< loop index: z-direction
1447    INTEGER(iwp) ::  nz_file    !< Number of grid-points in file (heights)                           
1448    INTEGER(iwp) ::  prunmode
1449    INTEGER(iwp) ::  ss !< index: start
1450    LOGICAL  ::  netcdf_extend = .FALSE. !< Flag indicating wether netcdf
1451                                         !< topography input file or not
1452    REAL(wp), DIMENSION(nbins) ::  core  !< size of the bin mid aerosol particle,
1453    REAL(wp) ::  flag           !< flag to mask topography grid points
1454    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  pr_gas !< gas profiles
1455    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  pr_mass_fracs_a !< mass fraction
1456                                                              !< profiles: a
1457    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  pr_mass_fracs_b !< and b
1458    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  pr_nsect !< sectional size
1459                                                       !< distribution profile
1460    REAL(wp), DIMENSION(nbins)            ::  nsect  !< size distribution (#/m3)
1461    REAL(wp), DIMENSION(0:nz+1,nbins)     ::  pndist !< size dist as a function
1462                                                     !< of height (#/m3)
1463    REAL(wp), DIMENSION(0:nz+1)           ::  pnf2a  !< number fraction: bins 2a
1464    REAL(wp), DIMENSION(0:nz+1,maxspec)   ::  pvf2a  !< mass distributions of 
1465                                                     !< aerosol species for a 
1466    REAL(wp), DIMENSION(0:nz+1,maxspec)   ::  pvf2b  !< and b-bins     
1467    REAL(wp), DIMENSION(0:nz+1)           ::  pvfOC1a !< mass fraction between
1468                                                     !< SO4 and OC in 1a
1469    REAL(wp), DIMENSION(:), ALLOCATABLE   ::  pr_z
1470
1471    prunmode = 1
1472!
1473!-- Bin mean aerosol particle volume (m3)
1474    core(:) = 0.0_wp
1475    core(1:nbins) = api6 * aero(1:nbins)%dmid ** 3.0_wp
1476!   
1477!-- Set concentrations to zero
1478    nsect(:)     = 0.0_wp
1479    pndist(:,:)  = 0.0_wp
1480    pnf2a(:)     = nf2a   
1481    pvf2a(:,:)   = 0.0_wp
1482    pvf2b(:,:)   = 0.0_wp
1483    pvfOC1a(:)   = 0.0_wp
1484
1485    IF ( isdtyp == 1 )  THEN
1486!
1487!--    Read input profiles from PIDS_SALSA   
1488#if defined( __netcdf )
1489!   
1490!--    Location-dependent size distributions and compositions.     
1491       INQUIRE( FILE='PIDS_SALSA'// TRIM( coupling_char ), EXIST=netcdf_extend )
1492       IF ( netcdf_extend )  THEN
1493!
1494!--       Open file in read-only mode 
1495          CALL open_read_file( 'PIDS_SALSA' // TRIM( coupling_char ), id_faero )
1496!
1497!--       Input heights   
1498          CALL netcdf_data_input_get_dimension_length( id_faero, nz_file,      &
1499                                                       "profile_z" ) 
1500         
1501          ALLOCATE( pr_z(nz_file), pr_mass_fracs_a(maxspec,nz_file),           &
1502                    pr_mass_fracs_b(maxspec,nz_file), pr_nsect(nbins,nz_file) ) 
1503          CALL get_variable( id_faero, 'profile_z', pr_z ) 
1504!       
1505!--       Mass fracs profile: 1: H2SO4 (sulphuric acid), 2: OC (organic carbon),
1506!--                           3: BC (black carbon),      4: DU (dust), 
1507!--                           5: SS (sea salt),          6: HNO3 (nitric acid),
1508!--                           7: NH3 (ammonia)         
1509          CALL get_variable( id_faero, "profile_mass_fracs_a", pr_mass_fracs_a,&
1510                             0, nz_file-1, 0, maxspec-1 )
1511          CALL get_variable( id_faero, "profile_mass_fracs_b", pr_mass_fracs_b,&
1512                             0, nz_file-1, 0, maxspec-1 )
1513          CALL get_variable( id_faero, "profile_nsect", pr_nsect, 0, nz_file-1,&
1514                             0, nbins-1 )                   
1515         
1516          kk = 1
1517          DO  k = nzb, nz+1
1518             IF ( kk < nz_file )  THEN
1519                DO  WHILE ( pr_z(kk+1) <= zu(k) )
1520                   kk = kk + 1
1521                   IF ( kk == nz_file )  EXIT
1522                ENDDO
1523             ENDIF
1524             IF ( kk < nz_file )  THEN
1525!             
1526!--             Set initial value for gas compound tracers and initial values
1527                pvf2a(k,:) = pr_mass_fracs_a(:,kk) + ( zu(k) - pr_z(kk) ) / (  &
1528                            pr_z(kk+1) - pr_z(kk) ) * ( pr_mass_fracs_a(:,kk+1)&
1529                            - pr_mass_fracs_a(:,kk) )   
1530                pvf2b(k,:) = pr_mass_fracs_b(:,kk) + ( zu(k) - pr_z(kk) ) / (  &
1531                            pr_z(kk+1) - pr_z(kk) ) * ( pr_mass_fracs_b(:,kk+1)&
1532                            - pr_mass_fracs_b(:,kk) )             
1533                pndist(k,:) = pr_nsect(:,kk) + ( zu(k) - pr_z(kk) ) / (        &
1534                              pr_z(kk+1) - pr_z(kk) ) * ( pr_nsect(:,kk+1) -   &
1535                              pr_nsect(:,kk) )
1536             ELSE
1537                pvf2a(k,:) = pr_mass_fracs_a(:,kk)       
1538                pvf2b(k,:) = pr_mass_fracs_b(:,kk)
1539                pndist(k,:) = pr_nsect(:,kk)
1540             ENDIF
1541             IF ( iso4 < 0 )  THEN
1542                pvf2a(k,1) = 0.0_wp
1543                pvf2b(k,1) = 0.0_wp
1544             ENDIF
1545             IF ( ioc < 0 )  THEN
1546                pvf2a(k,2) = 0.0_wp
1547                pvf2b(k,2) = 0.0_wp
1548             ENDIF
1549             IF ( ibc < 0 )  THEN
1550                pvf2a(k,3) = 0.0_wp
1551                pvf2b(k,3) = 0.0_wp
1552             ENDIF
1553             IF ( idu < 0 )  THEN
1554                pvf2a(k,4) = 0.0_wp
1555                pvf2b(k,4) = 0.0_wp
1556             ENDIF
1557             IF ( iss < 0 )  THEN
1558                pvf2a(k,5) = 0.0_wp
1559                pvf2b(k,5) = 0.0_wp
1560             ENDIF
1561             IF ( ino < 0 )  THEN
1562                pvf2a(k,6) = 0.0_wp
1563                pvf2b(k,6) = 0.0_wp
1564             ENDIF
1565             IF ( inh < 0 )  THEN
1566                pvf2a(k,7) = 0.0_wp
1567                pvf2b(k,7) = 0.0_wp
1568             ENDIF
1569!
1570!--          Then normalise the mass fraction so that SUM = 1
1571             pvf2a(k,:) = pvf2a(k,:) / SUM( pvf2a(k,:) )
1572             IF ( SUM( pvf2b(k,:) ) > 0.0_wp ) pvf2b(k,:) = pvf2b(k,:) /       &
1573                                                            SUM( pvf2b(k,:) )
1574          ENDDO         
1575          DEALLOCATE( pr_z, pr_mass_fracs_a, pr_mass_fracs_b, pr_nsect )
1576       ELSE
1577          message_string = 'Input file '// TRIM( 'PIDS_SALSA' ) //             &
1578                           TRIM( coupling_char ) // ' for SALSA missing!'
1579          CALL message( 'salsa_mod: aerosol_init', 'SA0032', 1, 2, 0, 6, 0 )               
1580       ENDIF   ! netcdf_extend   
1581#endif
1582 
1583    ELSEIF ( isdtyp == 0 )  THEN
1584!
1585!--    Mass fractions for species in a and b-bins
1586       IF ( iso4 > 0 )  THEN
1587          pvf2a(:,1) = mass_fracs_a(iso4) 
1588          pvf2b(:,1) = mass_fracs_b(iso4)
1589       ENDIF
1590       IF ( ioc > 0 )  THEN
1591          pvf2a(:,2) = mass_fracs_a(ioc)
1592          pvf2b(:,2) = mass_fracs_b(ioc) 
1593       ENDIF
1594       IF ( ibc > 0 )  THEN
1595          pvf2a(:,3) = mass_fracs_a(ibc) 
1596          pvf2b(:,3) = mass_fracs_b(ibc)
1597       ENDIF
1598       IF ( idu > 0 )  THEN
1599          pvf2a(:,4) = mass_fracs_a(idu)
1600          pvf2b(:,4) = mass_fracs_b(idu) 
1601       ENDIF
1602       IF ( iss > 0 )  THEN
1603          pvf2a(:,5) = mass_fracs_a(iss)
1604          pvf2b(:,5) = mass_fracs_b(iss) 
1605       ENDIF
1606       IF ( ino > 0 )  THEN
1607          pvf2a(:,6) = mass_fracs_a(ino)
1608          pvf2b(:,6) = mass_fracs_b(ino)
1609       ENDIF
1610       IF ( inh > 0 )  THEN
1611          pvf2a(:,7) = mass_fracs_a(inh)
1612          pvf2b(:,7) = mass_fracs_b(inh)
1613       ENDIF
1614       DO  k = nzb, nz+1
1615          pvf2a(k,:) = pvf2a(k,:) / SUM( pvf2a(k,:) )
1616          IF ( SUM( pvf2b(k,:) ) > 0.0_wp ) pvf2b(k,:) = pvf2b(k,:) /          &
1617                                                         SUM( pvf2b(k,:) )
1618       ENDDO
1619       
1620       CALL size_distribution( n_lognorm, dpg, sigmag, nsect )
1621!
1622!--    Normalize by the given total number concentration
1623       nsect = nsect * SUM( n_lognorm ) * 1.0E+6_wp / SUM( nsect )     
1624       DO  b = in1a, fn2b
1625          pndist(:,b) = nsect(b)
1626       ENDDO
1627    ENDIF
1628   
1629    IF ( igctyp == 1 )  THEN
1630!
1631!--    Read input profiles from PIDS_CHEM   
1632#if defined( __netcdf )
1633!   
1634!--    Location-dependent size distributions and compositions.     
1635       INQUIRE( FILE='PIDS_CHEM' // TRIM( coupling_char ), EXIST=netcdf_extend )
1636       IF ( netcdf_extend  .AND.  .NOT. salsa_gases_from_chem )  THEN
1637!
1638!--       Open file in read-only mode     
1639          CALL open_read_file( 'PIDS_CHEM' // TRIM( coupling_char ), id_fchem )
1640!
1641!--       Input heights   
1642          CALL netcdf_data_input_get_dimension_length( id_fchem, nz_file,      &
1643                                                       "profile_z" ) 
1644          ALLOCATE( pr_z(nz_file), pr_gas(ngast,nz_file) ) 
1645          CALL get_variable( id_fchem, 'profile_z', pr_z ) 
1646!       
1647!--       Gases:
1648          CALL get_variable( id_fchem, "profile_H2SO4", pr_gas(1,:) )
1649          CALL get_variable( id_fchem, "profile_HNO3", pr_gas(2,:) )
1650          CALL get_variable( id_fchem, "profile_NH3", pr_gas(3,:) )
1651          CALL get_variable( id_fchem, "profile_OCNV", pr_gas(4,:) )
1652          CALL get_variable( id_fchem, "profile_OCSV", pr_gas(5,:) )
1653         
1654          kk = 1
1655          DO  k = nzb, nz+1
1656             IF ( kk < nz_file )  THEN
1657                DO  WHILE ( pr_z(kk+1) <= zu(k) )
1658                   kk = kk + 1
1659                   IF ( kk == nz_file )  EXIT
1660                ENDDO
1661             ENDIF
1662             IF ( kk < nz_file )  THEN
1663!             
1664!--             Set initial value for gas compound tracers and initial values
1665                DO  g = 1, ngast
1666                   salsa_gas(g)%init(k) =  pr_gas(g,kk) + ( zu(k) - pr_z(kk) ) &
1667                                           / ( pr_z(kk+1) - pr_z(kk) ) *       &
1668                                           ( pr_gas(g,kk+1) - pr_gas(g,kk) )
1669                   salsa_gas(g)%conc(k,:,:) = salsa_gas(g)%init(k)
1670                ENDDO
1671             ELSE
1672                DO  g = 1, ngast
1673                   salsa_gas(g)%init(k) =  pr_gas(g,kk) 
1674                   salsa_gas(g)%conc(k,:,:) = salsa_gas(g)%init(k)
1675                ENDDO
1676             ENDIF
1677          ENDDO
1678         
1679          DEALLOCATE( pr_z, pr_gas )
1680       ELSEIF ( .NOT. netcdf_extend  .AND.  .NOT.  salsa_gases_from_chem )  THEN
1681          message_string = 'Input file '// TRIM( 'PIDS_CHEM' ) //              &
1682                           TRIM( coupling_char ) // ' for SALSA missing!'
1683          CALL message( 'salsa_mod: aerosol_init', 'SA0033', 1, 2, 0, 6, 0 )               
1684       ENDIF   ! netcdf_extend     
1685#endif
1686
1687    ENDIF
1688
1689    IF ( ioc > 0  .AND.  iso4 > 0 )  THEN     
1690!--    Both are there, so use the given "massDistrA"
1691       pvfOC1a(:) = pvf2a(:,2) / ( pvf2a(:,2) + pvf2a(:,1) )  ! Normalize
1692    ELSEIF ( ioc > 0 )  THEN
1693!--    Pure organic carbon
1694       pvfOC1a(:) = 1.0_wp
1695    ELSEIF ( iso4 > 0 )  THEN
1696!--    Pure SO4
1697       pvfOC1a(:) = 0.0_wp   
1698    ELSE
1699       message_string = 'Either OC or SO4 must be active for aerosol region 1a!'
1700       CALL message( 'salsa_mod: aerosol_init', 'SA0021', 1, 2, 0, 6, 0 )
1701    ENDIF   
1702   
1703!
1704!-- Initialize concentrations
1705    DO  i = nxlg, nxrg
1706       DO  j = nysg, nyng
1707          DO  k = nzb, nzt+1
1708!
1709!--          Predetermine flag to mask topography         
1710             flag = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_0(k,j,i), 0 ) )
1711!         
1712!--          a) Number concentrations
1713!--           Region 1:
1714             DO  b = in1a, fn1a
1715                aerosol_number(b)%conc(k,j,i) = pndist(k,b) * flag
1716                IF ( prunmode == 1 )  THEN
1717                   aerosol_number(b)%init = pndist(:,b)
1718                ENDIF
1719             ENDDO
1720!             
1721!--           Region 2:
1722             IF ( nreg > 1 )  THEN
1723                DO  b = in2a, fn2a
1724                   aerosol_number(b)%conc(k,j,i) = MAX( 0.0_wp, pnf2a(k) ) *   &
1725                                                    pndist(k,b) * flag
1726                   IF ( prunmode == 1 )  THEN
1727                      aerosol_number(b)%init = MAX( 0.0_wp, nf2a ) * pndist(:,b)
1728                   ENDIF
1729                ENDDO
1730                IF ( .NOT. no_insoluble )  THEN
1731                   DO  b = in2b, fn2b
1732                      IF ( pnf2a(k) < 1.0_wp )  THEN             
1733                         aerosol_number(b)%conc(k,j,i) = MAX( 0.0_wp, 1.0_wp   &
1734                                               - pnf2a(k) ) * pndist(k,b) * flag
1735                         IF ( prunmode == 1 )  THEN
1736                            aerosol_number(b)%init = MAX( 0.0_wp, 1.0_wp -     &
1737                                                          nf2a ) * pndist(:,b)
1738                         ENDIF
1739                      ENDIF
1740                   ENDDO
1741                ENDIF
1742             ENDIF
1743!
1744!--          b) Aerosol mass concentrations
1745!--             bin subrange 1: done here separately due to the SO4/OC convention
1746!--          SO4:
1747             IF ( iso4 > 0 )  THEN
1748                ss = ( iso4 - 1 ) * nbins + in1a !< start
1749                ee = ( iso4 - 1 ) * nbins + fn1a !< end
1750                b = in1a
1751                DO  c = ss, ee
1752                   aerosol_mass(c)%conc(k,j,i) = MAX( 0.0_wp, 1.0_wp -         &
1753                                                  pvfOC1a(k) ) * pndist(k,b) * &
1754                                                  core(b) * arhoh2so4 * flag
1755                   IF ( prunmode == 1 )  THEN
1756                      aerosol_mass(c)%init = MAX( 0.0_wp, 1.0_wp - MAXVAL(     &
1757                                             pvfOC1a ) ) * pndist(:,b) *       &
1758                                             core(b) * arhoh2so4
1759                   ENDIF
1760                   b = b+1
1761                ENDDO
1762             ENDIF
1763!--          OC:
1764             IF ( ioc > 0 ) THEN
1765                ss = ( ioc - 1 ) * nbins + in1a !< start
1766                ee = ( ioc - 1 ) * nbins + fn1a !< end
1767                b = in1a
1768                DO  c = ss, ee
1769                   aerosol_mass(c)%conc(k,j,i) = MAX( 0.0_wp, pvfOC1a(k) ) *   &
1770                                           pndist(k,b) * core(b) * arhooc * flag
1771                   IF ( prunmode == 1 )  THEN
1772                      aerosol_mass(c)%init = MAX( 0.0_wp, MAXVAL( pvfOC1a ) )  &
1773                                             * pndist(:,b) *  core(b) * arhooc
1774                   ENDIF
1775                   b = b+1
1776                ENDDO
1777             ENDIF
1778             
1779             prunmode = 3  ! Init only once
1780 
1781          ENDDO !< k
1782       ENDDO !< j
1783    ENDDO !< i
1784   
1785!
1786!-- c) Aerosol mass concentrations
1787!--    bin subrange 2:
1788    IF ( nreg > 1 ) THEN
1789   
1790       IF ( iso4 > 0 ) THEN
1791          CALL set_aero_mass( iso4, pvf2a(:,1), pvf2b(:,1), pnf2a, pndist,     &
1792                              core, arhoh2so4 )
1793       ENDIF
1794       IF ( ioc > 0 ) THEN
1795          CALL set_aero_mass( ioc, pvf2a(:,2), pvf2b(:,2), pnf2a, pndist, core,&
1796                              arhooc )
1797       ENDIF
1798       IF ( ibc > 0 ) THEN
1799          CALL set_aero_mass( ibc, pvf2a(:,3), pvf2b(:,3), pnf2a, pndist, core,&
1800                              arhobc )
1801       ENDIF
1802       IF ( idu > 0 ) THEN
1803          CALL set_aero_mass( idu, pvf2a(:,4), pvf2b(:,4), pnf2a, pndist, core,&
1804                              arhodu )
1805       ENDIF
1806       IF ( iss > 0 ) THEN
1807          CALL set_aero_mass( iss, pvf2a(:,5), pvf2b(:,5), pnf2a, pndist, core,&
1808                              arhoss )
1809       ENDIF
1810       IF ( ino > 0 ) THEN
1811          CALL set_aero_mass( ino, pvf2a(:,6), pvf2b(:,6), pnf2a, pndist, core,&
1812                              arhohno3 )
1813       ENDIF
1814       IF ( inh > 0 ) THEN
1815          CALL set_aero_mass( inh, pvf2a(:,7), pvf2b(:,7), pnf2a, pndist, core,&
1816                              arhonh3 )
1817       ENDIF
1818
1819    ENDIF
1820   
1821 END SUBROUTINE aerosol_init
1822 
1823!------------------------------------------------------------------------------!
1824! Description:
1825! ------------
1826!> Create a lognormal size distribution and discretise to a sectional
1827!> representation.
1828!------------------------------------------------------------------------------!
1829 SUBROUTINE size_distribution( in_ntot, in_dpg, in_sigma, psd_sect )
1830   
1831    IMPLICIT NONE
1832   
1833!-- Log-normal size distribution: modes   
1834    REAL(wp), DIMENSION(:), INTENT(in) ::  in_dpg    !< geometric mean diameter
1835                                                     !< (micrometres)
1836    REAL(wp), DIMENSION(:), INTENT(in) ::  in_ntot   !< number conc. (#/cm3)
1837    REAL(wp), DIMENSION(:), INTENT(in) ::  in_sigma  !< standard deviation
1838    REAL(wp), DIMENSION(:), INTENT(inout) ::  psd_sect !< sectional size
1839                                                       !< distribution
1840    INTEGER(iwp) ::  b          !< running index: bin
1841    INTEGER(iwp) ::  ib         !< running index: iteration
1842    REAL(wp) ::  d1             !< particle diameter (m, dummy)
1843    REAL(wp) ::  d2             !< particle diameter (m, dummy)
1844    REAL(wp) ::  delta_d        !< (d2-d1)/10                                                     
1845    REAL(wp) ::  deltadp        !< bin width
1846    REAL(wp) ::  dmidi          !< ( d1 + d2 ) / 2
1847   
1848    DO  b = in1a, fn2b !< aerosol size bins
1849       psd_sect(b) = 0.0_wp
1850!--    Particle diameter at the low limit (largest in the bin) (m)
1851       d1 = ( aero(b)%vlolim / api6 ) ** ( 1.0_wp / 3.0_wp )
1852!--    Particle diameter at the high limit (smallest in the bin) (m)
1853       d2 = ( aero(b)%vhilim / api6 ) ** ( 1.0_wp / 3.0_wp )
1854!--    Span of particle diameter in a bin (m)
1855       delta_d = ( d2 - d1 ) / 10.0_wp
1856!--    Iterate:             
1857       DO  ib = 1, 10
1858          d1 = ( aero(b)%vlolim / api6 ) ** ( 1.0_wp / 3.0_wp ) + ( ib - 1)    &
1859               * delta_d
1860          d2 = d1 + delta_d
1861          dmidi = ( d1 + d2 ) / 2.0_wp
1862          deltadp = LOG10( d2 / d1 )
1863         
1864!--       Size distribution
1865!--       in_ntot = total number, total area, or total volume concentration
1866!--       in_dpg = geometric-mean number, area, or volume diameter
1867!--       n(k) = number, area, or volume concentration in a bin
1868!--       n_lognorm and dpg converted to units of #/m3 and m
1869          psd_sect(b) = psd_sect(b) + SUM( in_ntot * 1.0E+6_wp * deltadp /     &
1870                     ( SQRT( 2.0_wp * pi ) * LOG10( in_sigma ) ) *             &
1871                     EXP( -LOG10( dmidi / ( 1.0E-6_wp * in_dpg ) )**2.0_wp /   &
1872                     ( 2.0_wp * LOG10( in_sigma ) ** 2.0_wp ) ) )
1873 
1874       ENDDO
1875    ENDDO
1876   
1877 END SUBROUTINE size_distribution
1878
1879!------------------------------------------------------------------------------!
1880! Description:
1881! ------------
1882!> Sets the mass concentrations to aerosol arrays in 2a and 2b.
1883!>
1884!> Tomi Raatikainen, FMI, 29.2.2016
1885!------------------------------------------------------------------------------!
1886 SUBROUTINE set_aero_mass( ispec, ppvf2a, ppvf2b, ppnf2a, ppndist, pcore, prho )
1887   
1888    IMPLICIT NONE
1889
1890    INTEGER(iwp), INTENT(in) :: ispec  !< Aerosol species index
1891    REAL(wp), INTENT(in) ::  pcore(nbins) !< Aerosol bin mid core volume   
1892    REAL(wp), INTENT(in) ::  ppndist(0:nz+1,nbins) !< Aerosol size distribution
1893    REAL(wp), INTENT(in) ::  ppnf2a(0:nz+1) !< Number fraction for 2a   
1894    REAL(wp), INTENT(in) ::  ppvf2a(0:nz+1) !< Mass distributions for a
1895    REAL(wp), INTENT(in) ::  ppvf2b(0:nz+1) !< and b bins   
1896    REAL(wp), INTENT(in) ::  prho !< Aerosol density
1897    INTEGER(iwp) ::  b  !< loop index
1898    INTEGER(iwp) ::  c  !< loop index       
1899    INTEGER(iwp) ::  ee !< index: end
1900    INTEGER(iwp) ::  i  !< loop index
1901    INTEGER(iwp) ::  j  !< loop index
1902    INTEGER(iwp) ::  k  !< loop index
1903    INTEGER(iwp) ::  prunmode  !< 1 = initialise
1904    INTEGER(iwp) ::  ss !< index: start
1905    REAL(wp) ::  flag   !< flag to mask topography grid points
1906   
1907    prunmode = 1
1908   
1909    DO i = nxlg, nxrg
1910       DO j = nysg, nyng
1911          DO k = nzb, nzt+1 
1912!
1913!--          Predetermine flag to mask topography
1914             flag = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_0(k,j,i), 0 ) ) 
1915!             
1916!--          Regime 2a:
1917             ss = ( ispec - 1 ) * nbins + in2a
1918             ee = ( ispec - 1 ) * nbins + fn2a
1919             b = in2a
1920             DO c = ss, ee
1921                aerosol_mass(c)%conc(k,j,i) = MAX( 0.0_wp, ppvf2a(k) ) *       &
1922                               ppnf2a(k) * ppndist(k,b) * pcore(b) * prho * flag
1923                IF ( prunmode == 1 )  THEN
1924                   aerosol_mass(c)%init = MAX( 0.0_wp, MAXVAL( ppvf2a(:) ) ) * &
1925                                          MAXVAL( ppnf2a ) * pcore(b) * prho * &
1926                                          MAXVAL( ppndist(:,b) ) 
1927                ENDIF
1928                b = b+1
1929             ENDDO
1930!--          Regime 2b:
1931             IF ( .NOT. no_insoluble )  THEN
1932                ss = ( ispec - 1 ) * nbins + in2b
1933                ee = ( ispec - 1 ) * nbins + fn2b
1934                b = in2a
1935                DO c = ss, ee
1936                   aerosol_mass(c)%conc(k,j,i) = MAX( 0.0_wp, ppvf2b(k) ) * (  &
1937                                         1.0_wp - ppnf2a(k) ) * ppndist(k,b) * &
1938                                         pcore(b) * prho * flag
1939                   IF ( prunmode == 1 )  THEN
1940                      aerosol_mass(c)%init = MAX( 0.0_wp, MAXVAL( ppvf2b(:) ) )&
1941                                        * ( 1.0_wp - MAXVAL( ppnf2a ) ) *      &
1942                                        MAXVAL( ppndist(:,b) ) * pcore(b) * prho
1943                   ENDIF
1944                   b = b+1
1945                ENDDO
1946             ENDIF
1947             prunmode = 3  ! Init only once
1948          ENDDO
1949       ENDDO
1950    ENDDO
1951 END SUBROUTINE set_aero_mass
1952
1953!------------------------------------------------------------------------------!
1954! Description:
1955! ------------
1956!> Swapping of timelevels
1957!------------------------------------------------------------------------------!
1958 SUBROUTINE salsa_swap_timelevel( mod_count )
1959
1960    IMPLICIT NONE
1961
1962    INTEGER(iwp), INTENT(IN) ::  mod_count  !<
1963    INTEGER(iwp) ::  b  !<   
1964    INTEGER(iwp) ::  c  !<   
1965    INTEGER(iwp) ::  cc !<
1966    INTEGER(iwp) ::  g  !<
1967
1968    IF ( simulated_time >= time_since_reference_point )  THEN
1969
1970    SELECT CASE ( mod_count )
1971
1972       CASE ( 0 )
1973
1974          DO  b = 1, nbins
1975             aerosol_number(b)%conc(nzb:nzt+1,nysg:nyng,nxlg:nxrg)   =>        &
1976                nconc_1(:,:,:,b)
1977             aerosol_number(b)%conc_p(nzb:nzt+1,nysg:nyng,nxlg:nxrg) =>        &
1978                nconc_2(:,:,:,b)
1979             DO  c = 1, ncc_tot
1980                cc = ( c-1 ) * nbins + b  ! required due to possible Intel18 bug
1981                aerosol_mass(cc)%conc(nzb:nzt+1,nysg:nyng,nxlg:nxrg)   =>      &
1982                   mconc_1(:,:,:,cc)
1983                aerosol_mass(cc)%conc_p(nzb:nzt+1,nysg:nyng,nxlg:nxrg) =>      &
1984                   mconc_2(:,:,:,cc)
1985             ENDDO
1986          ENDDO
1987         
1988          IF ( .NOT. salsa_gases_from_chem )  THEN
1989             DO  g = 1, ngast
1990                salsa_gas(g)%conc(nzb:nzt+1,nysg:nyng,nxlg:nxrg)   =>          &
1991                   gconc_1(:,:,:,g)
1992                salsa_gas(g)%conc_p(nzb:nzt+1,nysg:nyng,nxlg:nxrg) =>          &
1993                   gconc_2(:,:,:,g)
1994             ENDDO
1995          ENDIF
1996
1997       CASE ( 1 )
1998
1999          DO  b = 1, nbins
2000             aerosol_number(b)%conc(nzb:nzt+1,nysg:nyng,nxlg:nxrg)   =>        &
2001                nconc_2(:,:,:,b)
2002             aerosol_number(b)%conc_p(nzb:nzt+1,nysg:nyng,nxlg:nxrg) =>        &
2003                nconc_1(:,:,:,b)
2004             DO  c = 1, ncc_tot
2005                cc = ( c-1 ) * nbins + b  ! required due to possible Intel18 bug
2006                aerosol_mass(cc)%conc(nzb:nzt+1,nysg:nyng,nxlg:nxrg)   =>      &
2007                   mconc_2(:,:,:,cc)
2008                aerosol_mass(cc)%conc_p(nzb:nzt+1,nysg:nyng,nxlg:nxrg) =>      &
2009                   mconc_1(:,:,:,cc)
2010             ENDDO
2011          ENDDO
2012         
2013          IF ( .NOT. salsa_gases_from_chem )  THEN
2014             DO  g = 1, ngast
2015                salsa_gas(g)%conc(nzb:nzt+1,nysg:nyng,nxlg:nxrg)   =>          &
2016                   gconc_2(:,:,:,g)
2017                salsa_gas(g)%conc_p(nzb:nzt+1,nysg:nyng,nxlg:nxrg) =>          &
2018                   gconc_1(:,:,:,g)
2019             ENDDO
2020          ENDIF
2021
2022    END SELECT
2023
2024    ENDIF
2025
2026 END SUBROUTINE salsa_swap_timelevel
2027
2028
2029!------------------------------------------------------------------------------!
2030! Description:
2031! ------------
2032!> This routine reads the respective restart data.
2033!------------------------------------------------------------------------------!
2034 SUBROUTINE salsa_rrd_local( i, k, nxlf, nxlc, nxl_on_file, nxrf, nxrc,        &
2035                             nxr_on_file, nynf, nync, nyn_on_file, nysf,       &
2036                             nysc, nys_on_file, tmp_3d, found )
2037
2038   
2039    IMPLICIT NONE
2040   
2041    CHARACTER (LEN=20) :: field_char   !<
2042    INTEGER(iwp) ::  b  !<   
2043    INTEGER(iwp) ::  c  !<
2044    INTEGER(iwp) ::  g  !<
2045    INTEGER(iwp) ::  i  !<
2046    INTEGER(iwp) ::  k  !<
2047    INTEGER(iwp) ::  nxlc            !<
2048    INTEGER(iwp) ::  nxlf            !<
2049    INTEGER(iwp) ::  nxl_on_file     !<
2050    INTEGER(iwp) ::  nxrc            !<
2051    INTEGER(iwp) ::  nxrf            !<
2052    INTEGER(iwp) ::  nxr_on_file     !<
2053    INTEGER(iwp) ::  nync            !<
2054    INTEGER(iwp) ::  nynf            !<
2055    INTEGER(iwp) ::  nyn_on_file     !<
2056    INTEGER(iwp) ::  nysc            !<
2057    INTEGER(iwp) ::  nysf            !<
2058    INTEGER(iwp) ::  nys_on_file     !<
2059
2060    LOGICAL, INTENT(OUT)  ::  found
2061
2062    REAL(wp), &
2063       DIMENSION(nzb:nzt+1,nys_on_file-nbgp:nyn_on_file+nbgp,nxl_on_file-nbgp:nxr_on_file+nbgp) :: tmp_3d   !<
2064       
2065    found = .FALSE.
2066   
2067    IF ( read_restart_data_salsa )  THEN
2068   
2069       SELECT CASE ( restart_string(1:length) )
2070       
2071          CASE ( 'aerosol_number' )
2072             DO  b = 1, nbins
2073                IF ( k == 1 )  READ ( 13 ) tmp_3d
2074                aerosol_number(b)%conc(:,nysc-nbgp:nync+nbgp,nxlc-nbgp:nxrc+nbgp) = & 
2075                               tmp_3d(:,nysf-nbgp:nynf+nbgp,nxlf-nbgp:nxrf+nbgp)
2076                found = .TRUE.
2077             ENDDO
2078       
2079          CASE ( 'aerosol_mass' )
2080             DO  c = 1, ncc_tot * nbins
2081                IF ( k == 1 )  READ ( 13 ) tmp_3d
2082                aerosol_mass(c)%conc(:,nysc-nbgp:nync+nbgp,nxlc-nbgp:nxrc+nbgp) = & 
2083                               tmp_3d(:,nysf-nbgp:nynf+nbgp,nxlf-nbgp:nxrf+nbgp)
2084                found = .TRUE.
2085             ENDDO
2086         
2087          CASE ( 'salsa_gas' )
2088             DO  g = 1, ngast
2089                IF ( k == 1 )  READ ( 13 ) tmp_3d
2090                salsa_gas(g)%conc(:,nysc-nbgp:nync+nbgp,nxlc-nbgp:nxrc+nbgp) =  & 
2091                               tmp_3d(:,nysf-nbgp:nynf+nbgp,nxlf-nbgp:nxrf+nbgp)
2092                found = .TRUE.
2093             ENDDO
2094             
2095          CASE DEFAULT
2096             found = .FALSE.
2097             
2098       END SELECT
2099    ENDIF
2100
2101 END SUBROUTINE salsa_rrd_local
2102   
2103
2104!------------------------------------------------------------------------------!
2105! Description:
2106! ------------
2107!> This routine writes the respective restart data.
2108!> Note that the following input variables in PARIN have to be equal between
2109!> restart runs:
2110!>    listspec, nbin, nbin2, nf2a, ncc, mass_fracs_a, mass_fracs_b
2111!------------------------------------------------------------------------------!
2112 SUBROUTINE salsa_wrd_local
2113
2114    IMPLICIT NONE
2115   
2116    INTEGER(iwp) ::  b  !<   
2117    INTEGER(iwp) ::  c  !<
2118    INTEGER(iwp) ::  g  !<
2119   
2120    IF ( write_binary  .AND.  write_binary_salsa )  THEN
2121   
2122       CALL wrd_write_string( 'aerosol_number' )
2123       DO  b = 1, nbins
2124          WRITE ( 14 )  aerosol_number(b)%conc
2125       ENDDO
2126       
2127       CALL wrd_write_string( 'aerosol_mass' )
2128       DO  c = 1, nbins*ncc_tot
2129          WRITE ( 14 )  aerosol_mass(c)%conc
2130       ENDDO
2131       
2132       CALL wrd_write_string( 'salsa_gas' )
2133       DO  g = 1, ngast
2134          WRITE ( 14 )  salsa_gas(g)%conc
2135       ENDDO
2136         
2137    ENDIF
2138       
2139 END SUBROUTINE salsa_wrd_local   
2140
2141
2142!------------------------------------------------------------------------------!
2143! Description:
2144! ------------
2145!> Performs necessary unit and dimension conversion between the host model and
2146!> SALSA module, and calls the main SALSA routine.
2147!> Partially adobted form the original SALSA boxmodel version.
2148!> Now takes masses in as kg/kg from LES!! Converted to m3/m3 for SALSA
2149!> 05/2016 Juha: This routine is still pretty much in its original shape.
2150!>               It's dumb as a mule and twice as ugly, so implementation of
2151!>               an improved solution is necessary sooner or later.
2152!> Juha Tonttila, FMI, 2014
2153!> Jaakko Ahola, FMI, 2016
2154!> Only aerosol processes included, Mona Kurppa, UHel, 2017
2155!------------------------------------------------------------------------------!
2156 SUBROUTINE salsa_driver( i, j, prunmode )
2157
2158    USE arrays_3d,                                                             &
2159        ONLY: pt_p, q_p, rho_air_zw, u, v, w
2160       
2161    USE plant_canopy_model_mod,                                                &
2162        ONLY: lad_s
2163       
2164    USE surface_mod,                                                           &
2165        ONLY:  surf_def_h, surf_def_v, surf_lsm_h, surf_lsm_v, surf_usm_h,     &
2166               surf_usm_v
2167 
2168    IMPLICIT NONE
2169   
2170    INTEGER(iwp), INTENT(in) ::  i   !< loop index
2171    INTEGER(iwp), INTENT(in) ::  j   !< loop index
2172    INTEGER(iwp), INTENT(in) ::  prunmode !< 1: Initialization call
2173                                          !< 2: Spinup period call
2174                                          !< 3: Regular runtime call
2175!-- Local variables
2176    TYPE(t_section), DIMENSION(fn2b) ::  aero_old !< helper array
2177    INTEGER(iwp) ::  bb     !< loop index
2178    INTEGER(iwp) ::  cc     !< loop index
2179    INTEGER(iwp) ::  endi   !< end index
2180    INTEGER(iwp) ::  k_wall !< vertical index of topography top
2181    INTEGER(iwp) ::  k      !< loop index
2182    INTEGER(iwp) ::  l      !< loop index
2183    INTEGER(iwp) ::  nc_h2o !< index of H2O in the prtcl index table
2184    INTEGER(iwp) ::  ss     !< loop index
2185    INTEGER(iwp) ::  str    !< start index
2186    INTEGER(iwp) ::  vc     !< default index in prtcl
2187    REAL(wp) ::  cw_old     !< previous H2O mixing ratio
2188    REAL(wp) ::  flag       !< flag to mask topography grid points
2189    REAL(wp), DIMENSION(nzb:nzt+1) ::  in_adn !< air density (kg/m3)   
2190    REAL(wp), DIMENSION(nzb:nzt+1) ::  in_cs  !< H2O sat. vapour conc.
2191    REAL(wp), DIMENSION(nzb:nzt+1) ::  in_cw  !< H2O vapour concentration
2192    REAL(wp) ::  in_lad                       !< leaf area density (m2/m3)
2193    REAL(wp), DIMENSION(nzb:nzt+1) ::  in_p   !< pressure (Pa)     
2194    REAL(wp) ::  in_rh                        !< relative humidity                     
2195    REAL(wp), DIMENSION(nzb:nzt+1) ::  in_t   !< temperature (K)
2196    REAL(wp), DIMENSION(nzb:nzt+1) ::  in_u   !< wind magnitude (m/s)
2197    REAL(wp), DIMENSION(nzb:nzt+1) ::  kvis   !< kinematic viscosity of air(m2/s)                                           
2198    REAL(wp), DIMENSION(nzb:nzt+1,fn2b) ::  Sc      !< particle Schmidt number   
2199    REAL(wp), DIMENSION(nzb:nzt+1,fn2b) ::  vd      !< particle fall seed (m/s,
2200                                                    !< sedimentation velocity)
2201    REAL(wp), DIMENSION(nzb:nzt+1) ::  ppm_to_nconc !< Conversion factor
2202                                                    !< from ppm to #/m3                                                     
2203    REAL(wp) ::  zgso4  !< SO4
2204    REAL(wp) ::  zghno3 !< HNO3
2205    REAL(wp) ::  zgnh3  !< NH3
2206    REAL(wp) ::  zgocnv !< non-volatile OC
2207    REAL(wp) ::  zgocsv !< semi-volatile OC
2208   
2209    aero_old(:)%numc = 0.0_wp
2210    in_adn           = 0.0_wp   
2211    in_cs            = 0.0_wp
2212    in_cw            = 0.0_wp 
2213    in_lad           = 0.0_wp
2214    in_rh            = 0.0_wp
2215    in_p             = 0.0_wp 
2216    in_t             = 0.0_wp 
2217    in_u             = 0.0_wp
2218    kvis             = 0.0_wp
2219    Sc               = 0.0_wp
2220    vd               = 0.0_wp
2221    ppm_to_nconc     = 1.0_wp
2222    zgso4            = nclim
2223    zghno3           = nclim
2224    zgnh3            = nclim
2225    zgocnv           = nclim
2226    zgocsv           = nclim
2227   
2228!       
2229!-- Aerosol number is always set, but mass can be uninitialized
2230    DO cc = 1, nbins
2231       aero(cc)%volc     = 0.0_wp
2232       aero_old(cc)%volc = 0.0_wp
2233    ENDDO
2234!   
2235!-- Set the salsa runtime config (How to make this more efficient?)
2236    CALL set_salsa_runtime( prunmode )
2237!             
2238!-- Calculate thermodynamic quantities needed in SALSA
2239    CALL salsa_thrm_ij( i, j, p_ij=in_p, temp_ij=in_t, cw_ij=in_cw,            &
2240                        cs_ij=in_cs, adn_ij=in_adn )
2241!
2242!-- Magnitude of wind: needed for deposition
2243    IF ( lsdepo )  THEN
2244       in_u(nzb+1:nzt) = SQRT(                                                 &
2245                   ( 0.5_wp * ( u(nzb+1:nzt,j,i) + u(nzb+1:nzt,j,i+1) ) )**2 + & 
2246                   ( 0.5_wp * ( v(nzb+1:nzt,j,i) + v(nzb+1:nzt,j+1,i) ) )**2 + &
2247                   ( 0.5_wp * ( w(nzb:nzt-1,j,i) + w(nzb+1:nzt,j,  i) ) )**2 )
2248    ENDIF
2249!
2250!-- Calculate conversion factors for gas concentrations
2251    ppm_to_nconc = for_ppm_to_nconc * in_p / in_t
2252!
2253!-- Determine topography-top index on scalar grid
2254    k_wall = MAXLOC( MERGE( 1, 0, BTEST( wall_flags_0(:,j,i), 12 ) ),          &
2255                     DIM = 1 ) - 1     
2256               
2257    DO k = nzb+1, nzt
2258!
2259!--    Predetermine flag to mask topography
2260       flag = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_0(k,j,i), 0 ) )
2261!       
2262!--    Do not run inside buildings       
2263       IF ( flag == 0.0_wp )  CYCLE   
2264!
2265!--    Wind velocity for dry depositon on vegetation   
2266       IF ( lsdepo_vege  .AND.  plant_canopy  )  THEN
2267          in_lad = lad_s(k-k_wall,j,i)
2268       ENDIF       
2269!
2270!--    For initialization and spinup, limit the RH with the parameter rhlim
2271       IF ( prunmode < 3 ) THEN
2272          in_cw(k) = MIN( in_cw(k), in_cs(k) * rhlim )
2273       ELSE
2274          in_cw(k) = in_cw(k)
2275       ENDIF
2276       cw_old = in_cw(k) !* in_adn(k)
2277!               
2278!--    Set volume concentrations:
2279!--    Sulphate (SO4) or sulphuric acid H2SO4
2280       IF ( iso4 > 0 )  THEN
2281          vc = 1
2282          str = ( iso4-1 ) * nbins + 1    ! start index
2283          endi = iso4 * nbins             ! end index
2284          cc = 1
2285          DO ss = str, endi
2286             aero(cc)%volc(vc) = aerosol_mass(ss)%conc(k,j,i) / arhoh2so4
2287             cc = cc+1
2288          ENDDO
2289          aero_old(1:nbins)%volc(vc) = aero(1:nbins)%volc(vc)
2290       ENDIF
2291       
2292!--    Organic carbon (OC) compounds
2293       IF ( ioc > 0 )  THEN
2294          vc = 2
2295          str = ( ioc-1 ) * nbins + 1
2296          endi = ioc * nbins
2297          cc = 1
2298          DO ss = str, endi
2299             aero(cc)%volc(vc) = aerosol_mass(ss)%conc(k,j,i) / arhooc
2300             cc = cc+1
2301          ENDDO
2302          aero_old(1:nbins)%volc(vc) = aero(1:nbins)%volc(vc)
2303       ENDIF
2304       
2305!--    Black carbon (BC)
2306       IF ( ibc > 0 )  THEN
2307          vc = 3
2308          str = ( ibc-1 ) * nbins + 1 + fn1a
2309          endi = ibc * nbins
2310          cc = 1 + fn1a
2311          DO ss = str, endi
2312             aero(cc)%volc(vc) = aerosol_mass(ss)%conc(k,j,i) / arhobc
2313             cc = cc+1
2314          ENDDO                   
2315          aero_old(1:nbins)%volc(vc) = aero(1:nbins)%volc(vc)
2316       ENDIF
2317
2318!--    Dust (DU)
2319       IF ( idu > 0 )  THEN
2320          vc = 4
2321          str = ( idu-1 ) * nbins + 1 + fn1a
2322          endi = idu * nbins
2323          cc = 1 + fn1a
2324          DO ss = str, endi
2325             aero(cc)%volc(vc) = aerosol_mass(ss)%conc(k,j,i) / arhodu
2326             cc = cc+1
2327          ENDDO
2328          aero_old(1:nbins)%volc(vc) = aero(1:nbins)%volc(vc)
2329       ENDIF
2330
2331!--    Sea salt (SS)
2332       IF ( iss > 0 )  THEN
2333          vc = 5
2334          str = ( iss-1 ) * nbins + 1 + fn1a
2335          endi = iss * nbins
2336          cc = 1 + fn1a
2337          DO ss = str, endi
2338             aero(cc)%volc(vc) = aerosol_mass(ss)%conc(k,j,i) / arhoss 
2339             cc = cc+1
2340          ENDDO
2341          aero_old(1:nbins)%volc(vc) = aero(1:nbins)%volc(vc)
2342       ENDIF
2343
2344!--    Nitrate (NO(3-)) or nitric acid HNO3
2345       IF ( ino > 0 )  THEN
2346          vc = 6
2347          str = ( ino-1 ) * nbins + 1 
2348          endi = ino * nbins
2349          cc = 1
2350          DO ss = str, endi
2351             aero(cc)%volc(vc) = aerosol_mass(ss)%conc(k,j,i) / arhohno3
2352             cc = cc+1
2353          ENDDO
2354          aero_old(1:nbins)%volc(vc) = aero(1:nbins)%volc(vc)
2355       ENDIF
2356
2357!--    Ammonium (NH(4+)) or ammonia NH3
2358       IF ( inh > 0 )  THEN
2359          vc = 7
2360          str = ( inh-1 ) * nbins + 1
2361          endi = inh * nbins
2362          cc = 1
2363          DO ss = str, endi
2364             aero(cc)%volc(vc) = aerosol_mass(ss)%conc(k,j,i) / arhonh3 
2365             cc = cc+1
2366          ENDDO
2367          aero_old(1:nbins)%volc(vc) = aero(1:nbins)%volc(vc)
2368       ENDIF
2369
2370!--    Water (always used)
2371       nc_h2o = get_index( prtcl,'H2O' )
2372       vc = 8
2373       str = ( nc_h2o-1 ) * nbins + 1
2374       endi = nc_h2o * nbins
2375       cc = 1
2376       IF ( advect_particle_water )  THEN
2377          DO ss = str, endi
2378             aero(cc)%volc(vc) = aerosol_mass(ss)%conc(k,j,i) / arhoh2o
2379             cc = cc+1
2380          ENDDO
2381       ELSE
2382         aero(1:nbins)%volc(vc) = mclim
2383       ENDIF
2384       aero_old(1:nbins)%volc(vc) = aero(1:nbins)%volc(vc)
2385!
2386!--    Number concentrations (numc) and particle sizes
2387!--    (dwet = wet diameter, core = dry volume)
2388       DO  bb = 1, nbins
2389          aero(bb)%numc = aerosol_number(bb)%conc(k,j,i) 
2390          aero_old(bb)%numc = aero(bb)%numc
2391          IF ( aero(bb)%numc > nclim )  THEN
2392             aero(bb)%dwet = ( SUM( aero(bb)%volc(:) ) / aero(bb)%numc / api6 )&
2393                                **( 1.0_wp / 3.0_wp )
2394             aero(bb)%core = SUM( aero(bb)%volc(1:7) ) / aero(bb)%numc
2395          ELSE
2396             aero(bb)%dwet = aero(bb)%dmid
2397             aero(bb)%core = api6 * ( aero(bb)%dwet ) ** 3.0_wp
2398          ENDIF
2399       ENDDO
2400!       
2401!--    On EACH call of salsa_driver, calculate the ambient sizes of
2402!--    particles by equilibrating soluble fraction of particles with water
2403!--    using the ZSR method.
2404       in_rh = in_cw(k) / in_cs(k)
2405       IF ( prunmode==1  .OR.  .NOT. advect_particle_water )  THEN
2406          CALL equilibration( in_rh, in_t(k), aero, .TRUE. )
2407       ENDIF
2408!
2409!--    Gaseous tracer concentrations in #/m3
2410       IF ( salsa_gases_from_chem )  THEN       
2411!       
2412!--       Convert concentrations in ppm to #/m3
2413          zgso4  = chem_species(gas_index_chem(1))%conc(k,j,i) * ppm_to_nconc(k)
2414          zghno3 = chem_species(gas_index_chem(2))%conc(k,j,i) * ppm_to_nconc(k)
2415          zgnh3  = chem_species(gas_index_chem(3))%conc(k,j,i) * ppm_to_nconc(k)
2416          zgocnv = chem_species(gas_index_chem(4))%conc(k,j,i) * ppm_to_nconc(k)     
2417          zgocsv = chem_species(gas_index_chem(5))%conc(k,j,i) * ppm_to_nconc(k)                 
2418       ELSE
2419          zgso4  = salsa_gas(1)%conc(k,j,i) 
2420          zghno3 = salsa_gas(2)%conc(k,j,i) 
2421          zgnh3  = salsa_gas(3)%conc(k,j,i) 
2422          zgocnv = salsa_gas(4)%conc(k,j,i) 
2423          zgocsv = salsa_gas(5)%conc(k,j,i)
2424       ENDIF   
2425!
2426!--    ***************************************!
2427!--                   Run SALSA               !
2428!--    ***************************************!
2429       CALL run_salsa( in_p(k), in_cw(k), in_cs(k), in_t(k), in_u(k),          &
2430                       in_adn(k), in_lad, zgso4, zgocnv, zgocsv, zghno3, zgnh3,&
2431                       aero, prtcl, kvis(k), Sc(k,:), vd(k,:), dt_salsa )
2432!--    ***************************************!
2433       IF ( lsdepo ) sedim_vd(k,j,i,:) = vd(k,:)
2434!                           
2435!--    Calculate changes in concentrations
2436       DO bb = 1, nbins
2437          aerosol_number(bb)%conc(k,j,i) = aerosol_number(bb)%conc(k,j,i)      &
2438                                 +  ( aero(bb)%numc - aero_old(bb)%numc ) * flag
2439       ENDDO
2440       
2441       IF ( iso4 > 0 )  THEN
2442          vc = 1
2443          str = ( iso4-1 ) * nbins + 1
2444          endi = iso4 * nbins
2445          cc = 1
2446          DO ss = str, endi
2447             aerosol_mass(ss)%conc(k,j,i) = aerosol_mass(ss)%conc(k,j,i)       &
2448                               + ( aero(cc)%volc(vc) - aero_old(cc)%volc(vc) ) &
2449                               * arhoh2so4 * flag
2450             cc = cc+1
2451          ENDDO
2452       ENDIF
2453       
2454       IF ( ioc > 0 )  THEN
2455          vc = 2
2456          str = ( ioc-1 ) * nbins + 1
2457          endi = ioc * nbins
2458          cc = 1
2459          DO ss = str, endi
2460             aerosol_mass(ss)%conc(k,j,i) = aerosol_mass(ss)%conc(k,j,i)       &
2461                               + ( aero(cc)%volc(vc) - aero_old(cc)%volc(vc) ) &
2462                               * arhooc * flag
2463             cc = cc+1
2464          ENDDO
2465       ENDIF
2466       
2467       IF ( ibc > 0 )  THEN
2468          vc = 3
2469          str = ( ibc-1 ) * nbins + 1 + fn1a
2470          endi = ibc * nbins
2471          cc = 1 + fn1a
2472          DO ss = str, endi
2473             aerosol_mass(ss)%conc(k,j,i) = aerosol_mass(ss)%conc(k,j,i)       &
2474                               + ( aero(cc)%volc(vc) - aero_old(cc)%volc(vc) ) &
2475                               * arhobc * flag
2476             cc = cc+1
2477          ENDDO
2478       ENDIF
2479       
2480       IF ( idu > 0 )  THEN
2481          vc = 4
2482          str = ( idu-1 ) * nbins + 1 + fn1a
2483          endi = idu * nbins
2484          cc = 1 + fn1a
2485          DO ss = str, endi
2486             aerosol_mass(ss)%conc(k,j,i) = aerosol_mass(ss)%conc(k,j,i)       &
2487                               + ( aero(cc)%volc(vc) - aero_old(cc)%volc(vc) ) &
2488                               * arhodu * flag
2489             cc = cc+1
2490          ENDDO
2491       ENDIF
2492       
2493       IF ( iss > 0 )  THEN
2494          vc = 5
2495          str = ( iss-1 ) * nbins + 1 + fn1a
2496          endi = iss * nbins
2497          cc = 1 + fn1a
2498          DO ss = str, endi
2499             aerosol_mass(ss)%conc(k,j,i) = aerosol_mass(ss)%conc(k,j,i)       &
2500                               + ( aero(cc)%volc(vc) - aero_old(cc)%volc(vc) ) &
2501                               * arhoss * flag
2502             cc = cc+1
2503          ENDDO
2504       ENDIF
2505       
2506       IF ( ino > 0 )  THEN
2507          vc = 6
2508          str = ( ino-1 ) * nbins + 1
2509          endi = ino * nbins
2510          cc = 1
2511          DO ss = str, endi
2512             aerosol_mass(ss)%conc(k,j,i) = aerosol_mass(ss)%conc(k,j,i)       &
2513                               + ( aero(cc)%volc(vc) - aero_old(cc)%volc(vc) ) &
2514                               * arhohno3 * flag
2515             cc = cc+1
2516          ENDDO
2517       ENDIF
2518       
2519       IF ( inh > 0 )  THEN
2520          vc = 7
2521          str = ( ino-1 ) * nbins + 1
2522          endi = ino * nbins
2523          cc = 1
2524          DO ss = str, endi
2525             aerosol_mass(ss)%conc(k,j,i) = aerosol_mass(ss)%conc(k,j,i)       &
2526                               + ( aero(cc)%volc(vc) - aero_old(cc)%volc(vc) ) &
2527                               * arhonh3 * flag
2528             cc = cc+1
2529          ENDDO
2530       ENDIF
2531       
2532       IF ( advect_particle_water )  THEN
2533          nc_h2o = get_index( prtcl,'H2O' )
2534          vc = 8
2535          str = ( nc_h2o-1 ) * nbins + 1
2536          endi = nc_h2o * nbins
2537          cc = 1
2538          DO ss = str, endi
2539             aerosol_mass(ss)%conc(k,j,i) = aerosol_mass(ss)%conc(k,j,i)       &
2540                               + ( aero(cc)%volc(vc) - aero_old(cc)%volc(vc) ) &
2541                               * arhoh2o * flag
2542             IF ( prunmode == 1 )  THEN
2543                aerosol_mass(ss)%init(k) = MAX( aerosol_mass(ss)%init(k),      &
2544                                               aerosol_mass(ss)%conc(k,j,i) )
2545             ENDIF
2546             cc = cc+1                             
2547          ENDDO
2548       ENDIF
2549
2550!--    Condensation of precursor gases
2551       IF ( lscndgas )  THEN
2552          IF ( salsa_gases_from_chem )  THEN         
2553!         
2554!--          SO4 (or H2SO4)
2555             chem_species( gas_index_chem(1) )%conc(k,j,i) =                &
2556                            chem_species( gas_index_chem(1) )%conc(k,j,i) + &
2557                                                  ( zgso4 / ppm_to_nconc(k) - &
2558                       chem_species( gas_index_chem(1) )%conc(k,j,i) ) * flag
2559!                           
2560!--          HNO3
2561             chem_species( gas_index_chem(2) )%conc(k,j,i) =                &
2562                            chem_species( gas_index_chem(2) )%conc(k,j,i) + &
2563                                                 ( zghno3 / ppm_to_nconc(k) - &
2564                       chem_species( gas_index_chem(2) )%conc(k,j,i) ) * flag
2565!                           
2566!--          NH3
2567             chem_species( gas_index_chem(3) )%conc(k,j,i) =                &
2568                            chem_species( gas_index_chem(3) )%conc(k,j,i) + &
2569                                                  ( zgnh3 / ppm_to_nconc(k) - &
2570                       chem_species( gas_index_chem(3) )%conc(k,j,i) ) * flag
2571!                           
2572!--          non-volatile OC
2573             chem_species( gas_index_chem(4) )%conc(k,j,i) =                &
2574                            chem_species( gas_index_chem(4) )%conc(k,j,i) + &
2575                                                 ( zgocnv / ppm_to_nconc(k) - &
2576                       chem_species( gas_index_chem(4) )%conc(k,j,i) ) * flag
2577!                           
2578!--          semi-volatile OC
2579             chem_species( gas_index_chem(5) )%conc(k,j,i) =                &
2580                            chem_species( gas_index_chem(5) )%conc(k,j,i) + &
2581                                                 ( zgocsv / ppm_to_nconc(k) - &
2582                       chem_species( gas_index_chem(5) )%conc(k,j,i) ) * flag                 
2583         
2584          ELSE
2585!         
2586!--          SO4 (or H2SO4)
2587             salsa_gas(1)%conc(k,j,i) = salsa_gas(1)%conc(k,j,i) + ( zgso4 -   &
2588                                          salsa_gas(1)%conc(k,j,i) ) * flag
2589!                           
2590!--          HNO3
2591             salsa_gas(2)%conc(k,j,i) = salsa_gas(2)%conc(k,j,i) + ( zghno3 -  &
2592                                          salsa_gas(2)%conc(k,j,i) ) * flag
2593!                           
2594!--          NH3
2595             salsa_gas(3)%conc(k,j,i) = salsa_gas(3)%conc(k,j,i) + ( zgnh3 -   &
2596                                          salsa_gas(3)%conc(k,j,i) ) * flag
2597!                           
2598!--          non-volatile OC
2599             salsa_gas(4)%conc(k,j,i) = salsa_gas(4)%conc(k,j,i) + ( zgocnv -  &
2600                                          salsa_gas(4)%conc(k,j,i) ) * flag
2601!                           
2602!--          semi-volatile OC
2603             salsa_gas(5)%conc(k,j,i) = salsa_gas(5)%conc(k,j,i) + ( zgocsv -  &
2604                                          salsa_gas(5)%conc(k,j,i) ) * flag
2605          ENDIF
2606       ENDIF
2607!               
2608!--    Tendency of water vapour mixing ratio is obtained from the
2609!--    change in RH during SALSA run. This releases heat and changes pt.
2610!--    Assumes no temperature change during SALSA run.
2611!--    q = r / (1+r), Euler method for integration
2612!
2613       IF ( feedback_to_palm )  THEN
2614          q_p(k,j,i) = q_p(k,j,i) + 1.0_wp / ( in_cw(k) * in_adn(k) + 1.0_wp ) &
2615                       ** 2.0_wp * ( in_cw(k) - cw_old ) * in_adn(k) 
2616          pt_p(k,j,i) = pt_p(k,j,i) + alv / c_p * ( in_cw(k) - cw_old ) *      &
2617                        in_adn(k) / ( in_cw(k) / in_adn(k) + 1.0_wp ) ** 2.0_wp&
2618                        * pt_p(k,j,i) / in_t(k)
2619       ENDIF
2620                         
2621    ENDDO   ! k
2622!   
2623!-- Set surfaces and wall fluxes due to deposition 
2624    IF ( lsdepo_topo  .AND.  prunmode == 3 )  THEN
2625       IF ( .NOT. land_surface  .AND.  .NOT. urban_surface )  THEN
2626          CALL depo_topo( i, j, surf_def_h(0), vd, Sc, kvis, in_u, rho_air_zw )
2627          DO  l = 0, 3
2628             CALL depo_topo( i, j, surf_def_v(l), vd, Sc, kvis, in_u,          &
2629                             rho_air_zw**0.0_wp )
2630          ENDDO
2631       ELSE
2632          CALL depo_topo( i, j, surf_usm_h, vd, Sc, kvis, in_u, rho_air_zw )
2633          DO  l = 0, 3
2634             CALL depo_topo( i, j, surf_usm_v(l), vd, Sc, kvis, in_u,          &
2635                             rho_air_zw**0.0_wp )
2636          ENDDO
2637          CALL depo_topo( i, j, surf_lsm_h, vd, Sc, kvis, in_u, rho_air_zw )
2638          DO  l = 0, 3
2639             CALL depo_topo( i, j, surf_lsm_v(l), vd, Sc, kvis, in_u,          &
2640                             rho_air_zw**0.0_wp )
2641          ENDDO
2642       ENDIF
2643    ENDIF
2644   
2645 END SUBROUTINE salsa_driver
2646
2647!------------------------------------------------------------------------------!
2648! Description:
2649! ------------
2650!> The SALSA subroutine
2651!> Modified for the new aerosol datatype,
2652!> Juha Tonttila, FMI, 2014.
2653!> Only aerosol processes included, Mona Kurppa, UHel, 2017
2654!------------------------------------------------------------------------------!   
2655 SUBROUTINE run_salsa( ppres, pcw, pcs, ptemp, mag_u, adn, lad, pc_h2so4,      &
2656                       pc_ocnv, pc_ocsv, pc_hno3, pc_nh3, paero, prtcl, kvis,  &
2657                       Sc, vc, ptstep )
2658
2659    IMPLICIT NONE
2660!
2661!-- Input parameters and variables
2662    REAL(wp), INTENT(in) ::  adn    !< air density (kg/m3)
2663    REAL(wp), INTENT(in) ::  lad    !< leaf area density (m2/m3)
2664    REAL(wp), INTENT(in) ::  mag_u  !< magnitude of wind (m/s)
2665    REAL(wp), INTENT(in) ::  ppres  !< atmospheric pressure at each grid
2666                                    !< point (Pa)
2667    REAL(wp), INTENT(in) ::  ptemp  !< temperature at each grid point (K)
2668    REAL(wp), INTENT(in) ::  ptstep !< time step of salsa processes (s)
2669    TYPE(component_index), INTENT(in) :: prtcl  !< part. component index table
2670!       
2671!-- Input variables that are changed within:
2672    REAL(wp), INTENT(inout) ::  kvis     !< kinematic viscosity of air (m2/s)
2673    REAL(wp), INTENT(inout) ::  Sc(:)    !< particle Schmidt number
2674    REAL(wp), INTENT(inout) ::  vc(:)    !< particle fall speed (m/s,
2675                                         !< sedimentation velocity)
2676!-- Gas phase concentrations at each grid point (#/m3)
2677    REAL(wp), INTENT(inout) ::  pc_h2so4 !< sulphuric acid
2678    REAL(wp), INTENT(inout) ::  pc_hno3  !< nitric acid
2679    REAL(wp), INTENT(inout) ::  pc_nh3   !< ammonia
2680    REAL(wp), INTENT(inout) ::  pc_ocnv  !< nonvolatile OC
2681    REAL(wp), INTENT(inout) ::  pc_ocsv  !< semivolatile OC
2682    REAL(wp), INTENT(inout) ::  pcs      !< Saturation concentration of water
2683                                         !< vapour (kg/m3)
2684    REAL(wp), INTENT(inout) ::  pcw      !< Water vapour concentration (kg/m3)                                                   
2685    TYPE(t_section), INTENT(inout) ::  paero(fn2b) 
2686!
2687!-- Coagulation
2688    IF ( lscoag )   THEN
2689       CALL coagulation( paero, ptstep, ptemp, ppres )
2690    ENDIF
2691!
2692!-- Condensation
2693    IF ( lscnd )   THEN
2694       CALL condensation( paero, pc_h2so4, pc_ocnv, pc_ocsv,  pc_hno3, pc_nh3, &
2695                          pcw, pcs, ptemp, ppres, ptstep, prtcl )
2696    ENDIF   
2697!   
2698!-- Deposition
2699    IF ( lsdepo )  THEN
2700       CALL deposition( paero, ptemp, adn, mag_u, lad, kvis, Sc, vc ) 
2701    ENDIF       
2702!
2703!-- Size distribution bin update
2704!-- Mona: why done 3 times in SALSA-standalone?
2705    IF ( lsdistupdate )   THEN
2706       CALL distr_update( paero )
2707    ENDIF
2708   
2709  END SUBROUTINE run_salsa
2710 
2711!------------------------------------------------------------------------------!
2712! Description:
2713! ------------
2714!> Set logical switches according to the host model state and user-specified
2715!> NAMELIST options.
2716!> Juha Tonttila, FMI, 2014
2717!> Only aerosol processes included, Mona Kurppa, UHel, 2017
2718!------------------------------------------------------------------------------!
2719 SUBROUTINE set_salsa_runtime( prunmode )
2720 
2721    IMPLICIT NONE
2722   
2723    INTEGER(iwp), INTENT(in) ::  prunmode
2724   
2725    SELECT CASE(prunmode)
2726
2727       CASE(1) !< Initialization
2728          lscoag       = .FALSE.
2729          lscnd        = .FALSE.
2730          lscndgas     = .FALSE.
2731          lscndh2oae   = .FALSE.
2732          lsdepo       = .FALSE.
2733          lsdepo_vege  = .FALSE.
2734          lsdepo_topo  = .FALSE.
2735          lsdistupdate = .TRUE.
2736
2737       CASE(2)  !< Spinup period
2738          lscoag      = ( .FALSE. .AND. nlcoag   )
2739          lscnd       = ( .TRUE.  .AND. nlcnd    )
2740          lscndgas    = ( .TRUE.  .AND. nlcndgas )
2741          lscndh2oae  = ( .TRUE.  .AND. nlcndh2oae )
2742
2743       CASE(3)  !< Run
2744          lscoag       = nlcoag
2745          lscnd        = nlcnd
2746          lscndgas     = nlcndgas
2747          lscndh2oae   = nlcndh2oae
2748          lsdepo       = nldepo
2749          lsdepo_vege  = nldepo_vege
2750          lsdepo_topo  = nldepo_topo
2751          lsdistupdate = nldistupdate
2752
2753    END SELECT
2754
2755
2756 END SUBROUTINE set_salsa_runtime
2757 
2758!------------------------------------------------------------------------------!
2759! Description:
2760! ------------
2761!> Calculates the absolute temperature (using hydrostatic pressure), saturation
2762!> vapour pressure and mixing ratio over water, relative humidity and air
2763!> density needed in the SALSA model.
2764!> NOTE, no saturation adjustment takes place -> the resulting water vapour
2765!> mixing ratio can be supersaturated, allowing the microphysical calculations
2766!> in SALSA.
2767!
2768!> Juha Tonttila, FMI, 2014 (original SALSAthrm)
2769!> Mona Kurppa, UHel, 2017 (adjustment for PALM and only aerosol processes)
2770!------------------------------------------------------------------------------!
2771 SUBROUTINE salsa_thrm_ij( i, j, p_ij, temp_ij, cw_ij, cs_ij, adn_ij )
2772 
2773    USE arrays_3d,                                                             &
2774        ONLY: p, pt, q, zu
2775       
2776    USE basic_constants_and_equations_mod,                                     &
2777        ONLY:  barometric_formula, exner_function, ideal_gas_law_rho, magnus
2778       
2779    USE control_parameters,                                                    &
2780        ONLY: pt_surface, surface_pressure
2781       
2782    IMPLICIT NONE
2783   
2784    INTEGER(iwp), INTENT(in) ::  i
2785    INTEGER(iwp), INTENT(in) ::  j
2786    REAL(wp), DIMENSION(:), INTENT(inout) ::  adn_ij
2787    REAL(wp), DIMENSION(:), INTENT(inout) ::  p_ij       
2788    REAL(wp), DIMENSION(:), INTENT(inout) ::  temp_ij
2789    REAL(wp), DIMENSION(:), INTENT(inout), OPTIONAL ::  cw_ij
2790    REAL(wp), DIMENSION(:), INTENT(inout), OPTIONAL ::  cs_ij
2791    REAL(wp), DIMENSION(nzb:nzt+1) ::  e_s !< saturation vapour pressure
2792                                           !< over water (Pa)
2793    REAL(wp) ::  t_surface !< absolute surface temperature (K)
2794!
2795!-- Pressure p_ijk (Pa) = hydrostatic pressure + perturbation pressure (p)
2796    t_surface = pt_surface * exner_function( surface_pressure * 100.0_wp )
2797    p_ij(:) = barometric_formula( zu, t_surface, surface_pressure * 100.0_wp ) &
2798              + p(:,j,i)
2799!             
2800!-- Absolute ambient temperature (K)
2801    temp_ij(:) = pt(:,j,i) * exner_function( p_ij(:) )       
2802!
2803!-- Air density
2804    adn_ij(:) = ideal_gas_law_rho( p_ij(:), temp_ij(:) )
2805!
2806!-- Water vapour concentration r_v (kg/m3)
2807    IF ( PRESENT( cw_ij ) )  THEN
2808       cw_ij(:) = ( q(:,j,i) / ( 1.0_wp - q(:,j,i) ) ) * adn_ij(:) 
2809    ENDIF
2810!
2811!-- Saturation mixing ratio r_s (kg/kg) from vapour pressure at temp (Pa)
2812    IF ( PRESENT( cs_ij ) )  THEN
2813       e_s(:) = 611.0_wp * EXP( alv_d_rv * ( 3.6609E-3_wp - 1.0_wp /           &
2814                temp_ij(:) ) )! magnus( temp_ij(:) )
2815       cs_ij(:) = ( 0.622_wp * e_s / ( p_ij(:) - e_s(:) ) ) * adn_ij(:) 
2816    ENDIF
2817
2818 END SUBROUTINE salsa_thrm_ij
2819
2820!------------------------------------------------------------------------------!
2821! Description:
2822! ------------
2823!> Calculates ambient sizes of particles by equilibrating soluble fraction of
2824!> particles with water using the ZSR method (Stokes and Robinson, 1966).
2825!> Method:
2826!> Following chemical components are assumed water-soluble
2827!> - (ammonium) sulphate (100%)
2828!> - sea salt (100 %)
2829!> - organic carbon (epsoc * 100%)
2830!> Exact thermodynamic considerations neglected.
2831!> - If particles contain no sea salt, calculation according to sulphate
2832!>   properties
2833!> - If contain sea salt but no sulphate, calculation according to sea salt
2834!>   properties
2835!> - If contain both sulphate and sea salt -> the molar fraction of these
2836!>   compounds determines which one of them is used as the basis of calculation.
2837!> If sulphate and sea salt coexist in a particle, it is assumed that the Cl is
2838!> replaced by sulphate; thus only either sulphate + organics or sea salt +
2839!> organics is included in the calculation of soluble fraction.
2840!> Molality parameterizations taken from Table 1 of Tang: Thermodynamic and
2841!> optical properties of mixed-salt aerosols of atmospheric importance,
2842!> J. Geophys. Res., 102 (D2), 1883-1893 (1997)
2843!
2844!> Coded by:
2845!> Hannele Korhonen (FMI) 2005
2846!> Harri Kokkola (FMI) 2006
2847!> Matti Niskanen(FMI) 2012
2848!> Anton Laakso  (FMI) 2013
2849!> Modified for the new aerosol datatype, Juha Tonttila (FMI) 2014
2850!
2851!> fxm: should sea salt form a solid particle when prh is very low (even though
2852!> it could be mixed with e.g. sulphate)?
2853!> fxm: crashes if no sulphate or sea salt
2854!> fxm: do we really need to consider Kelvin effect for subrange 2
2855!------------------------------------------------------------------------------!     
2856 SUBROUTINE equilibration( prh, ptemp, paero, init )
2857     
2858    IMPLICIT NONE
2859!
2860!-- Input variables
2861    LOGICAL, INTENT(in) ::  init   !< TRUE: Initialization call
2862                                   !< FALSE: Normal runtime: update water
2863                                   !<        content only for 1a
2864    REAL(wp), INTENT(in) ::  prh   !< relative humidity [0-1]
2865    REAL(wp), INTENT(in) ::  ptemp !< temperature (K)
2866!
2867!-- Output variables
2868    TYPE(t_section), INTENT(inout) ::  paero(fn2b)     
2869!
2870!-- Local
2871    INTEGER(iwp) :: b      !< loop index
2872    INTEGER(iwp) :: counti  !< loop index
2873    REAL(wp) ::  zaw        !< water activity [0-1]       
2874    REAL(wp) ::  zbinmol(7) !< binary molality of each components (mol/kg)
2875    REAL(wp) ::  zcore      !< Volume of dry particle   
2876    REAL(wp) ::  zdold      !< Old diameter
2877    REAL(wp) ::  zdwet      !< Wet diameter or mean droplet diameter
2878    REAL(wp) ::  zke        !< Kelvin term in the Köhler equation
2879    REAL(wp) ::  zlwc       !< liquid water content [kg/m3-air]
2880    REAL(wp) ::  zrh        !< Relative humidity
2881    REAL(wp) ::  zvpart(7)  !< volume of chem. compounds in one particle
2882   
2883    zaw       = 0.0_wp
2884    zbinmol   = 0.0_wp
2885    zcore     = 0.0_wp
2886    zdold     = 0.0_wp
2887    zdwet     = 0.0_wp
2888    zlwc      = 0.0_wp
2889    zrh       = 0.0_wp
2890   
2891!               
2892!-- Relative humidity:
2893    zrh = prh
2894    zrh = MAX( zrh, 0.05_wp )
2895    zrh = MIN( zrh, 0.98_wp)   
2896!
2897!-- 1) Regime 1: sulphate and partly water-soluble OC. Done for every CALL
2898    DO  b = in1a, fn1a   ! size bin
2899         
2900       zbinmol = 0.0_wp
2901       zdold   = 1.0_wp 
2902       zke     = 1.02_wp
2903       
2904       IF ( paero(b)%numc > nclim )  THEN
2905!
2906!--       Volume in one particle
2907          zvpart = 0.0_wp
2908          zvpart(1:2) = paero(b)%volc(1:2) / paero(b)%numc
2909          zvpart(6:7) = paero(b)%volc(6:7) / paero(b)%numc
2910!               
2911!--       Total volume and wet diameter of one dry particle
2912          zcore = SUM( zvpart(1:2) )
2913          zdwet = paero(b)%dwet
2914         
2915          counti = 0
2916          DO  WHILE ( ABS( zdwet / zdold - 1.0_wp ) > 1.0E-2_wp ) 
2917         
2918             zdold = MAX( zdwet, 1.0E-20_wp )
2919             zaw = MAX( 1.0E-3_wp, zrh / zke ) ! To avoid underflow
2920!                   
2921!--          Binary molalities (mol/kg):
2922!--          Sulphate
2923             zbinmol(1) = 1.1065495E+2_wp - 3.6759197E+2_wp * zaw              &
2924                                          + 5.0462934E+2_wp * zaw**2.0_wp      &
2925                                          - 3.1543839E+2_wp * zaw**3.0_wp      &
2926                                          + 6.770824E+1_wp  * zaw**4.0_wp 
2927!--          Organic carbon                     
2928             zbinmol(2) = 1.0_wp / ( zaw * amh2o ) - 1.0_wp / amh2o
2929!--          Nitric acid                             
2930             zbinmol(6) = 2.306844303E+1_wp - 3.563608869E+1_wp * zaw          &
2931                                            - 6.210577919E+1_wp * zaw**2.0_wp  &
2932                                            + 5.510176187E+2_wp * zaw**3.0_wp  &
2933                                            - 1.460055286E+3_wp * zaw**4.0_wp  &
2934                                            + 1.894467542E+3_wp * zaw**5.0_wp  &
2935                                            - 1.220611402E+3_wp * zaw**6.0_wp  &
2936                                            + 3.098597737E+2_wp * zaw**7.0_wp 
2937!
2938!--          Calculate the liquid water content (kg/m3-air) using ZSR (see e.g.
2939!--          Eq. 10.98 in Seinfeld and Pandis (2006))
2940             zlwc = ( paero(b)%volc(1) * ( arhoh2so4 / amh2so4 ) ) /           &
2941                    zbinmol(1) + epsoc * paero(b)%volc(2) * ( arhooc / amoc )  &
2942                    / zbinmol(2) + ( paero(b)%volc(6) * ( arhohno3/amhno3 ) )  &
2943                    / zbinmol(6)
2944!                           
2945!--          Particle wet diameter (m)
2946             zdwet = ( zlwc / paero(b)%numc / arhoh2o / api6 +                 &
2947                     ( SUM( zvpart(6:7) ) / api6 ) +      &
2948                       zcore / api6 )**( 1.0_wp / 3.0_wp )
2949!                             
2950!--          Kelvin effect (Eq. 10.85 in in Seinfeld and Pandis (2006)). Avoid
2951!--          overflow.
2952             zke = EXP( MIN( 50.0_wp,                                          &
2953                       4.0_wp * surfw0 * amvh2so4 / ( abo * ptemp *  zdwet ) ) )
2954             
2955             counti = counti + 1
2956             IF ( counti > 1000 )  THEN
2957                message_string = 'Subrange 1: no convergence!'
2958                CALL message( 'salsa_mod: equilibration', 'SA0042',            &
2959                              1, 2, 0, 6, 0 )
2960             ENDIF
2961          ENDDO
2962!               
2963!--       Instead of lwc, use the volume concentration of water from now on
2964!--       (easy to convert...)
2965          paero(b)%volc(8) = zlwc / arhoh2o
2966!               
2967!--       If this is initialization, update the core and wet diameter
2968          IF ( init )  THEN
2969             paero(b)%dwet = zdwet
2970             paero(b)%core = zcore
2971          ENDIF
2972         
2973       ELSE
2974!--       If initialization
2975!--       1.2) empty bins given bin average values 
2976          IF ( init )  THEN
2977             paero(b)%dwet = paero(b)%dmid
2978             paero(b)%core = api6 * paero(b)%dmid ** 3.0_wp
2979          ENDIF
2980         
2981       ENDIF
2982             
2983    ENDDO !< b
2984!
2985!-- 2) Regime 2a: sulphate, OC, BC and sea salt
2986!--    This is done only for initialization call, otherwise the water contents
2987!--    are computed via condensation
2988    IF ( init )  THEN
2989       DO  b = in2a, fn2b
2990             
2991!--       Initialize
2992          zke     = 1.02_wp
2993          zbinmol = 0.0_wp
2994          zdold   = 1.0_wp
2995!               
2996!--       1) Particle properties calculated for non-empty bins
2997          IF ( paero(b)%numc > nclim )  THEN
2998!               
2999!--          Volume in one particle [fxm]
3000             zvpart = 0.0_wp
3001             zvpart(1:7) = paero(b)%volc(1:7) / paero(b)%numc
3002!
3003!--          Total volume and wet diameter of one dry particle [fxm]
3004             zcore = SUM( zvpart(1:5) )
3005             zdwet = paero(b)%dwet
3006
3007             counti = 0
3008             DO  WHILE ( ABS( zdwet / zdold - 1.0_wp ) > 1.0E-12_wp )
3009             
3010                zdold = MAX( zdwet, 1.0E-20_wp )
3011                zaw = zrh / zke
3012!                     
3013!--             Binary molalities (mol/kg):
3014!--             Sulphate
3015                zbinmol(1) = 1.1065495E+2_wp - 3.6759197E+2_wp * zaw           & 
3016                        + 5.0462934E+2_wp * zaw**2 - 3.1543839E+2_wp * zaw**3  &
3017                        + 6.770824E+1_wp  * zaw**4 
3018!--             Organic carbon                       
3019                zbinmol(2) = 1.0_wp / ( zaw * amh2o ) - 1.0_wp / amh2o
3020!--             Nitric acid
3021                zbinmol(6) = 2.306844303E+1_wp - 3.563608869E+1_wp * zaw       &
3022                     - 6.210577919E+1_wp * zaw**2 + 5.510176187E+2_wp * zaw**3 &
3023                     - 1.460055286E+3_wp * zaw**4 + 1.894467542E+3_wp * zaw**5 &
3024                     - 1.220611402E+3_wp * zaw**6 + 3.098597737E+2_wp * zaw**7 
3025!--             Sea salt (natrium chloride)                                 
3026                zbinmol(5) = 5.875248E+1_wp - 1.8781997E+2_wp * zaw            &
3027                         + 2.7211377E+2_wp * zaw**2 - 1.8458287E+2_wp * zaw**3 &
3028                         + 4.153689E+1_wp  * zaw**4 
3029!                                 
3030!--             Calculate the liquid water content (kg/m3-air)
3031                zlwc = ( paero(b)%volc(1) * ( arhoh2so4 / amh2so4 ) ) /        &
3032                       zbinmol(1) + epsoc * ( paero(b)%volc(2) * ( arhooc /    &
3033                       amoc ) ) / zbinmol(2) + ( paero(b)%volc(6) * ( arhohno3 &
3034                       / amhno3 ) ) / zbinmol(6) + ( paero(b)%volc(5) *        &
3035                       ( arhoss / amss ) ) / zbinmol(5)
3036                       
3037!--             Particle wet radius (m)
3038                zdwet = ( zlwc / paero(b)%numc / arhoh2o / api6 +              &
3039                          ( SUM( zvpart(6:7) ) / api6 )  + &
3040                           zcore / api6 ) ** ( 1.0_wp / 3.0_wp )
3041!                               
3042!--             Kelvin effect (Eq. 10.85 in Seinfeld and Pandis (2006))
3043                zke = EXP( MIN( 50.0_wp,                                       &
3044                        4.0_wp * surfw0 * amvh2so4 / ( abo * zdwet * ptemp ) ) )
3045                         
3046                counti = counti + 1
3047                IF ( counti > 1000 )  THEN
3048                   message_string = 'Subrange 2: no convergence!'
3049                CALL message( 'salsa_mod: equilibration', 'SA0043',            &
3050                              1, 2, 0, 6, 0 )
3051                ENDIF
3052             ENDDO
3053!                   
3054!--          Liquid water content; instead of LWC use the volume concentration
3055             paero(b)%volc(8) = zlwc / arhoh2o
3056             paero(b)%dwet    = zdwet
3057             paero(b)%core    = zcore
3058             
3059          ELSE
3060!--          2.2) empty bins given bin average values
3061             paero(b)%dwet = paero(b)%dmid
3062             paero(b)%core = api6 * paero(b)%dmid ** 3.0_wp
3063          ENDIF
3064               
3065       ENDDO   ! b
3066    ENDIF
3067
3068 END SUBROUTINE equilibration
3069 
3070!------------------------------------------------------------------------------!
3071!> Description:
3072!> ------------
3073!> Calculation of the settling velocity vc (m/s) per aerosol size bin and
3074!> deposition on plant canopy (lsdepo_vege).
3075!
3076!> Deposition is based on either the scheme presented in:
3077!> Zhang et al. (2001), Atmos. Environ. 35, 549-560 (includes collection due to
3078!> Brownian diffusion, impaction, interception and sedimentation)
3079!> OR
3080!> Petroff & Zhang (2010), Geosci. Model Dev. 3, 753-769 (includes also
3081!> collection due to turbulent impaction)
3082!
3083!> Equation numbers refer to equation in Jacobson (2005): Fundamentals of
3084!> Atmospheric Modeling, 2nd Edition.
3085!
3086!> Subroutine follows closely sedim_SALSA in UCLALES-SALSA written by Juha
3087!> Tonttila (KIT/FMI) and Zubair Maalick (UEF).
3088!> Rewritten to PALM by Mona Kurppa (UH), 2017.
3089!
3090!> Call for grid point i,j,k
3091!------------------------------------------------------------------------------!
3092
3093 SUBROUTINE deposition( paero, tk, adn, mag_u, lad, kvis, Sc, vc )
3094 
3095    USE plant_canopy_model_mod,                                                &
3096        ONLY: cdc
3097 
3098    IMPLICIT NONE
3099   
3100    REAL(wp), INTENT(in)    ::  adn    !< air density (kg/m3) 
3101    REAL(wp), INTENT(out)   ::  kvis   !< kinematic viscosity of air (m2/s)
3102    REAL(wp), INTENT(in) ::     lad    !< leaf area density (m2/m3)
3103    REAL(wp), INTENT(in)    ::  mag_u  !< wind velocity (m/s)
3104    REAL(wp), INTENT(out)   ::  Sc(:)  !< particle Schmidt number 
3105    REAL(wp), INTENT(in)    ::  tk     !< abs.temperature (K)   
3106    REAL(wp), INTENT(out)   ::  vc(:)  !< critical fall speed i.e. settling
3107                                       !< velocity of an aerosol particle (m/s)
3108    TYPE(t_section), INTENT(inout) ::  paero(fn2b)       
3109   
3110    INTEGER(iwp) ::  b      !< loop index
3111    INTEGER(iwp) ::  c      !< loop index
3112    REAL(wp) ::  avis       !< molecular viscocity of air (kg/(m*s))
3113    REAL(wp), PARAMETER ::  c_A = 1.249_wp !< Constants A, B and C for
3114    REAL(wp), PARAMETER ::  c_B = 0.42_wp  !< calculating  the Cunningham 
3115    REAL(wp), PARAMETER ::  c_C = 0.87_wp  !< slip-flow correction (Cc) 
3116                                           !< according to Jacobson (2005),
3117                                           !< Eq. 15.30
3118    REAL(wp) ::  Cc         !< Cunningham slip-flow correction factor     
3119    REAL(wp) ::  Kn         !< Knudsen number   
3120    REAL(wp) ::  lambda     !< molecular mean free path (m)
3121    REAL(wp) ::  mdiff      !< particle diffusivity coefficient   
3122    REAL(wp) ::  pdn        !< particle density (kg/m3)     
3123    REAL(wp) ::  ustar      !< friction velocity (m/s)   
3124    REAL(wp) ::  va         !< thermal speed of an air molecule (m/s)
3125    REAL(wp) ::  zdwet      !< wet diameter (m)                             
3126!
3127!-- Initialise
3128    Cc            = 0.0_wp
3129    Kn            = 0.0_wp
3130    mdiff         = 0.0_wp
3131    pdn           = 1500.0_wp    ! default value
3132    ustar         = 0.0_wp 
3133!
3134!-- Molecular viscosity of air (Eq. 4.54)
3135    avis = 1.8325E-5_wp * ( 416.16_wp / ( tk + 120.0_wp ) ) * ( tk /           &
3136           296.16_wp )**1.5_wp
3137!             
3138!-- Kinematic viscosity (Eq. 4.55)
3139    kvis =  avis / adn
3140!       
3141!-- Thermal velocity of an air molecule (Eq. 15.32)
3142    va = SQRT( 8.0_wp * abo * tk / ( pi * am_airmol ) ) 
3143!
3144!-- Mean free path (m) (Eq. 15.24)
3145    lambda = 2.0_wp * avis / ( adn * va )
3146   
3147    DO  b = 1, nbins
3148   
3149       IF ( paero(b)%numc < nclim )  CYCLE
3150       zdwet = paero(b)%dwet
3151!
3152!--    Knudsen number (Eq. 15.23)
3153       Kn = MAX( 1.0E-2_wp, lambda / ( zdwet * 0.5_wp ) ) ! To avoid underflow
3154!
3155!--    Cunningham slip-flow correction (Eq. 15.30)
3156       Cc = 1.0_wp + Kn * ( c_A + c_B * EXP( -c_C / Kn ) )
3157
3158!--    Particle diffusivity coefficient (Eq. 15.29)
3159       mdiff = ( abo * tk * Cc ) / ( 3.0_wp * pi * avis * zdwet )
3160!       
3161!--    Particle Schmidt number (Eq. 15.36)
3162       Sc(b) = kvis / mdiff       
3163!       
3164!--    Critical fall speed i.e. settling velocity  (Eq. 20.4)                 
3165       vc(b) = MIN( 1.0_wp, terminal_vel( 0.5_wp * zdwet, pdn, adn, avis, Cc) )
3166       
3167       IF ( lsdepo_vege  .AND.  plant_canopy  .AND.  lad > 0.0_wp )  THEN
3168!       
3169!--       Friction velocity calculated following Prandtl (1925):
3170          ustar = SQRT( cdc ) * mag_u
3171          CALL depo_vege( paero, b, vc(b), mag_u, ustar, kvis, Sc(b), lad )
3172       ENDIF
3173    ENDDO
3174 
3175 END SUBROUTINE deposition
3176 
3177!------------------------------------------------------------------------------!
3178! Description:
3179! ------------
3180!> Calculate change in number and volume concentrations due to deposition on
3181!> plant canopy.
3182!------------------------------------------------------------------------------!
3183 SUBROUTINE depo_vege( paero, b, vc, mag_u, ustar, kvis_a, Sc, lad )
3184 
3185    IMPLICIT NONE
3186   
3187    INTEGER(iwp), INTENT(in) ::  b  !< loop index
3188    REAL(wp), INTENT(in) ::  kvis_a !< kinematic viscosity of air (m2/s)
3189    REAL(wp), INTENT(in) ::  lad    !< leaf area density (m2/m3)
3190    REAL(wp), INTENT(in) ::  mag_u  !< wind velocity (m/s)   
3191    REAL(wp), INTENT(in) ::  Sc     !< particle Schmidt number
3192    REAL(wp), INTENT(in) ::  ustar  !< friction velocity (m/s)                                   
3193    REAL(wp), INTENT(in) ::  vc     !< terminal velocity (m/s) 
3194    TYPE(t_section), INTENT(inout) ::  paero(fn2b) 
3195   
3196    INTEGER(iwp) ::  c      !< loop index
3197    REAL(wp), PARAMETER ::  c_A = 1.249_wp !< Constants A, B and C for
3198    REAL(wp), PARAMETER ::  c_B = 0.42_wp  !< calculating  the Cunningham 
3199    REAL(wp), PARAMETER ::  c_C = 0.87_wp  !< slip-flow correction (Cc) 
3200                                           !< according to Jacobson (2005),
3201                                           !< Eq. 15.30
3202    REAL(wp) ::  alpha       !< parameter, Table 3 in Zhang et al. (2001) 
3203    REAL(wp) ::  depo        !< deposition efficiency
3204    REAL(wp) ::  C_Br        !< coefficient for Brownian diffusion
3205    REAL(wp) ::  C_IM        !< coefficient for inertial impaction
3206    REAL(wp) ::  C_IN        !< coefficient for interception
3207    REAL(wp) ::  C_IT        !< coefficient for turbulent impaction   
3208    REAL(wp) ::  gamma       !< parameter, Table 3 in Zhang et al. (2001)   
3209    REAL(wp) ::  par_A       !< parameter A for the characteristic radius of
3210                             !< collectors, Table 3 in Zhang et al. (2001)   
3211    REAL(wp) ::  rt          !< the overall quasi-laminar resistance for
3212                             !< particles
3213    REAL(wp) ::  St          !< Stokes number for smooth surfaces or bluff
3214                             !< surface elements                                 
3215    REAL(wp) ::  tau_plus    !< dimensionless particle relaxation time   
3216    REAL(wp) ::  v_bd        !< deposition velocity due to Brownian diffusion
3217    REAL(wp) ::  v_im        !< deposition velocity due to impaction
3218    REAL(wp) ::  v_in        !< deposition velocity due to interception
3219    REAL(wp) ::  v_it        !< deposition velocity due to turbulent impaction                               
3220!
3221!-- Initialise
3222    depo     = 0.0_wp 
3223    rt       = 0.0_wp
3224    St       = 0.0_wp
3225    tau_plus = 0.0_wp
3226    v_bd     = 0.0_wp     
3227    v_im     = 0.0_wp       
3228    v_in     = 0.0_wp       
3229    v_it     = 0.0_wp         
3230       
3231    IF ( depo_vege_type == 'zhang2001' )  THEN
3232!       
3233!--    Parameters for the land use category 'deciduous broadleaf trees'(Table 3)     
3234       par_A = 5.0E-3_wp
3235       alpha = 0.8_wp
3236       gamma = 0.56_wp 
3237!       
3238!--    Stokes number for vegetated surfaces (Seinfeld & Pandis (2006): Eq.19.24) 
3239       St = vc * ustar / ( g * par_A )         
3240!         
3241!--    The overall quasi-laminar resistance for particles (Zhang et al., Eq. 5)       
3242       rt = MAX( EPSILON( 1.0_wp ), ( 3.0_wp * ustar * EXP( -St**0.5_wp ) *    &
3243                         ( Sc**( -gamma ) + ( St / ( alpha + St ) )**2.0_wp +  &
3244                           0.5_wp * ( paero(b)%dwet / par_A )**2.0_wp ) ) )
3245       depo = ( rt + vc ) * lad
3246       paero(b)%numc = paero(b)%numc - depo * paero(b)%numc * dt_salsa
3247       DO  c = 1, maxspec+1
3248          paero(b)%volc(c) = paero(b)%volc(c) - depo * paero(b)%volc(c) *      &
3249                             dt_salsa
3250       ENDDO
3251       
3252    ELSEIF ( depo_vege_type == 'petroff2010' )  THEN
3253!
3254!--    vd = v_BD + v_IN + v_IM + v_IT + vc
3255!--    Deposition efficiencies from Table 1. Constants from Table 2.
3256       C_Br  = 1.262_wp
3257       C_IM  = 0.130_wp
3258       C_IN  = 0.216_wp
3259       C_IT  = 0.056_wp
3260       par_A = 0.03_wp   ! Here: leaf width (m)     
3261!       
3262!--    Stokes number for vegetated surfaces (Seinfeld & Pandis (2006): Eq.19.24) 
3263       St = vc * ustar / ( g * par_A )         
3264!
3265!--    Non-dimensional relexation time of the particle on top of canopy
3266       tau_plus = vc * ustar**2.0_wp / ( kvis_a * g ) 
3267!
3268!--    Brownian diffusion
3269       v_bd = mag_u * C_Br * Sc**( -2.0_wp / 3.0_wp ) *                        &
3270              ( mag_u * par_A / kvis_a )**( -0.5_wp )
3271!
3272!--    Interception
3273       v_in = mag_u * C_IN * paero(b)%dwet / par_A * ( 2.0_wp + LOG( 2.0_wp *  &
3274              par_A / paero(b)%dwet ) )                     
3275!
3276!--    Impaction: Petroff (2009) Eq. 18
3277       v_im = mag_u * C_IM * ( St / ( St + 0.47_wp ) )**2.0_wp
3278       
3279       IF ( tau_plus < 20.0_wp )  THEN
3280          v_it = 2.5E-3_wp * C_IT * tau_plus**2.0_wp
3281       ELSE
3282          v_it = C_IT
3283       ENDIF
3284       depo = ( v_bd + v_in + v_im + v_it + vc ) * lad     
3285       paero(b)%numc = paero(b)%numc - depo * paero(b)%numc * dt_salsa     
3286       DO  c = 1, maxspec+1
3287          paero(b)%volc(c) = paero(b)%volc(c) - depo * paero(b)%volc(c) *      &
3288                             dt_salsa
3289       ENDDO
3290    ENDIF 
3291 
3292 END SUBROUTINE depo_vege
3293 
3294!------------------------------------------------------------------------------!
3295! Description:
3296! ------------ 
3297!> Calculate deposition on horizontal and vertical surfaces. Implement as
3298!> surface flux.
3299!------------------------------------------------------------------------------!
3300
3301 SUBROUTINE depo_topo( i, j, surf, vc, Sc, kvis, mag_u, norm )
3302 
3303    USE surface_mod,                                                           &
3304        ONLY:  surf_type
3305 
3306    IMPLICIT NONE
3307   
3308    INTEGER(iwp), INTENT(in) ::  i     !< loop index
3309    INTEGER(iwp), INTENT(in) ::  j     !< loop index
3310    REAL(wp), INTENT(in) ::  kvis(:)   !< kinematic viscosity of air (m2/s)
3311    REAL(wp), INTENT(in) ::  mag_u(:)  !< wind velocity (m/s)                                                 
3312    REAL(wp), INTENT(in) ::  norm(:)   !< normalisation (usually air density)
3313    REAL(wp), INTENT(in) ::  Sc(:,:)  !< particle Schmidt number
3314    REAL(wp), INTENT(in) ::  vc(:,:)  !< terminal velocity (m/s)   
3315    TYPE(surf_type), INTENT(inout) :: surf  !< respective surface type
3316    INTEGER(iwp) ::  b      !< loop index
3317    INTEGER(iwp) ::  c      !< loop index
3318    INTEGER(iwp) ::  k      !< loop index
3319    INTEGER(iwp) ::  m      !< loop index
3320    INTEGER(iwp) ::  surf_e !< End index of surface elements at (j,i)-gridpoint
3321    INTEGER(iwp) ::  surf_s !< Start index of surface elements at (j,i)-gridpoint
3322    REAL(wp) ::  alpha      !< parameter, Table 3 in Zhang et al. (2001)
3323    REAL(wp) ::  C_Br       !< coefficient for Brownian diffusion
3324    REAL(wp) ::  C_IM       !< coefficient for inertial impaction
3325    REAL(wp) ::  C_IN       !< coefficient for interception
3326    REAL(wp) ::  C_IT       !< coefficient for turbulent impaction
3327    REAL(wp) ::  depo       !< deposition efficiency
3328    REAL(wp) ::  gamma      !< parameter, Table 3 in Zhang et al. (2001)
3329    REAL(wp) ::  par_A      !< parameter A for the characteristic radius of
3330                            !< collectors, Table 3 in Zhang et al. (2001)
3331    REAL(wp) ::  rt         !< the overall quasi-laminar resistance for
3332                            !< particles
3333    REAL(wp) ::  St         !< Stokes number for bluff surface elements 
3334    REAL(wp) ::  tau_plus   !< dimensionless particle relaxation time   
3335    REAL(wp) ::  v_bd       !< deposition velocity due to Brownian diffusion
3336    REAL(wp) ::  v_im       !< deposition velocity due to impaction
3337    REAL(wp) ::  v_in       !< deposition velocity due to interception
3338    REAL(wp) ::  v_it       !< deposition velocity due to turbulent impaction 
3339!
3340!-- Initialise
3341    rt       = 0.0_wp
3342    St       = 0.0_wp
3343    tau_plus = 0.0_wp
3344    v_bd     = 0.0_wp     
3345    v_im     = 0.0_wp       
3346    v_in     = 0.0_wp       
3347    v_it     = 0.0_wp                                 
3348    surf_s   = surf%start_index(j,i)
3349    surf_e   = surf%end_index(j,i) 
3350   
3351    DO  m = surf_s, surf_e
3352       k = surf%k(m)       
3353       DO  b = 1, nbins
3354          IF ( aerosol_number(b)%conc(k,j,i) <= nclim  .OR.                    &
3355               Sc(k+1,b) < 1.0_wp )  CYCLE   
3356                   
3357          IF ( depo_topo_type == 'zhang2001' )  THEN
3358!       
3359!--          Parameters for the land use category 'urban' in Table 3
3360             alpha = 1.5_wp
3361             gamma = 0.56_wp 
3362             par_A = 10.0E-3_wp
3363!       
3364!--          Stokes number for smooth surfaces or surfaces with bluff roughness
3365!--          elements (Seinfeld and Pandis, 2nd edition (2006): Eq. 19.23)       
3366             St = MAX( 0.01_wp, vc(k+1,b) * surf%us(m) ** 2.0_wp /             &
3367                       ( g * kvis(k+1)  ) ) 
3368!         
3369!--          The overall quasi-laminar resistance for particles (Eq. 5)       
3370             rt = MAX( EPSILON( 1.0_wp ), ( 3.0_wp * surf%us(m) * (            &
3371                       Sc(k+1,b)**( -gamma ) + ( St / ( alpha + St ) )**2.0_wp &
3372                        + 0.5_wp * ( Ra_dry(k,j,i,b) / par_A )**2.0_wp ) *     &
3373                       EXP( -St**0.5_wp ) ) ) 
3374             depo = vc(k+1,b) + rt
3375             
3376          ELSEIF ( depo_topo_type == 'petroff2010' )  THEN 
3377!
3378!--          vd = v_BD + v_IN + v_IM + v_IT + vc
3379!--          Deposition efficiencies from Table 1. Constants from Table 2.
3380             C_Br  = 1.262_wp
3381             C_IM  = 0.130_wp
3382             C_IN  = 0.216_wp
3383             C_IT  = 0.056_wp
3384             par_A = 0.03_wp   ! Here: leaf width (m) 
3385!       
3386!--          Stokes number for smooth surfaces or surfaces with bluff roughness
3387!--          elements (Seinfeld and Pandis, 2nd edition (2006): Eq. 19.23)       
3388             St = MAX( 0.01_wp, vc(k+1,b) * surf%us(m) ** 2.0_wp /             &
3389                       ( g *  kvis(k+1) ) )             
3390!
3391!--          Non-dimensional relexation time of the particle on top of canopy
3392             tau_plus = vc(k+1,b) * surf%us(m)**2.0_wp / ( kvis(k+1) * g ) 
3393!
3394!--          Brownian diffusion
3395             v_bd = mag_u(k+1) * C_Br * Sc(k+1,b)**( -2.0_wp / 3.0_wp ) *      &
3396                    ( mag_u(k+1) * par_A / kvis(k+1) )**( -0.5_wp )
3397!
3398!--          Interception
3399             v_in = mag_u(k+1) * C_IN * Ra_dry(k,j,i,b)/ par_A * ( 2.0_wp +    &
3400                    LOG( 2.0_wp * par_A / Ra_dry(k,j,i,b) ) )                     
3401!
3402!--          Impaction: Petroff (2009) Eq. 18
3403             v_im = mag_u(k+1) * C_IM * ( St / ( St + 0.47_wp ) )**2.0_wp
3404             
3405             IF ( tau_plus < 20.0_wp )  THEN
3406                v_it = 2.5E-3_wp * C_IT * tau_plus**2.0_wp
3407             ELSE
3408                v_it = C_IT
3409             ENDIF
3410             depo =  v_bd + v_in + v_im + v_it + vc(k+1,b)       
3411         
3412          ENDIF
3413          IF ( lod_aero == 3  .OR.  salsa_source_mode ==  'no_source' )  THEN
3414             surf%answs(m,b) = -depo * norm(k) * aerosol_number(b)%conc(k,j,i) 
3415             DO  c = 1, ncc_tot   
3416                surf%amsws(m,(c-1)*nbins+b) = -depo *  norm(k) *               &
3417                                         aerosol_mass((c-1)*nbins+b)%conc(k,j,i)
3418             ENDDO    ! c
3419          ELSE
3420             surf%answs(m,b) = SUM( aerosol_number(b)%source(:,j,i) ) -        &
3421                               MAX( 0.0_wp, depo * norm(k) *                   &
3422                               aerosol_number(b)%conc(k,j,i) )
3423             DO  c = 1, ncc_tot   
3424                surf%amsws(m,(c-1)*nbins+b) = SUM(                             &
3425                               aerosol_mass((c-1)*nbins+b)%source(:,j,i) ) -   &
3426                               MAX(  0.0_wp, depo *  norm(k) *                 &
3427                               aerosol_mass((c-1)*nbins+b)%conc(k,j,i) )
3428             ENDDO
3429          ENDIF
3430       ENDDO    ! b
3431    ENDDO    ! m     
3432     
3433 END SUBROUTINE depo_topo
3434 
3435!------------------------------------------------------------------------------!
3436! Description:
3437! ------------
3438! Function for calculating terminal velocities for different particles sizes.
3439!------------------------------------------------------------------------------!
3440 REAL(wp) FUNCTION terminal_vel( radius, rhop, rhoa, visc, beta )
3441 
3442    IMPLICIT NONE
3443   
3444    REAL(wp), INTENT(in) ::  beta    !< Cunningham correction factor
3445    REAL(wp), INTENT(in) ::  radius  !< particle radius (m)
3446    REAL(wp), INTENT(in) ::  rhop    !< particle density (kg/m3)
3447    REAL(wp), INTENT(in) ::  rhoa    !< air density (kg/m3)
3448    REAL(wp), INTENT(in) ::  visc    !< molecular viscosity of air (kg/(m*s))
3449   
3450    REAL(wp), PARAMETER ::  rhoa_ref = 1.225_wp ! reference air density (kg/m3)
3451!
3452!-- Stokes law with Cunningham slip correction factor
3453    terminal_vel = ( 4.0_wp * radius**2.0_wp ) * ( rhop - rhoa ) * g * beta /  &
3454                   ( 18.0_wp * visc ) ! (m/s)
3455       
3456 END FUNCTION terminal_vel
3457 
3458!------------------------------------------------------------------------------!
3459! Description:
3460! ------------
3461!> Calculates particle loss and change in size distribution due to (Brownian)
3462!> coagulation. Only for particles with dwet < 30 micrometres.
3463!
3464!> Method:
3465!> Semi-implicit, non-iterative method: (Jacobson, 1994)
3466!> Volume concentrations of the smaller colliding particles added to the bin of
3467!> the larger colliding particles. Start from first bin and use the updated
3468!> number and volume for calculation of following bins. NB! Our bin numbering
3469!> does not follow particle size in subrange 2.
3470!
3471!> Schematic for bin numbers in different subranges:
3472!>             1                            2
3473!>    +-------------------------------------------+
3474!>  a | 1 | 2 | 3 || 4 | 5 | 6 | 7 |  8 |  9 | 10||
3475!>  b |           ||11 |12 |13 |14 | 15 | 16 | 17||
3476!>    +-------------------------------------------+
3477!
3478!> Exact coagulation coefficients for each pressure level are scaled according
3479!> to current particle wet size (linear scaling).
3480!> Bins are organized in terms of the dry size of the condensation nucleus,
3481!> while coagulation kernell is calculated with the actual hydrometeor
3482!> size.
3483!
3484!> Called from salsa_driver
3485!> fxm: Process selection should be made smarter - now just lots of IFs inside
3486!>      loops
3487!
3488!> Coded by:
3489!> Hannele Korhonen (FMI) 2005
3490!> Harri Kokkola (FMI) 2006
3491!> Tommi Bergman (FMI) 2012
3492!> Matti Niskanen(FMI) 2012
3493!> Anton Laakso  (FMI) 2013
3494!> Juha Tonttila (FMI) 2014
3495!------------------------------------------------------------------------------!
3496 SUBROUTINE coagulation( paero, ptstep, ptemp, ppres )
3497               
3498    IMPLICIT NONE
3499   
3500!-- Input and output variables
3501    TYPE(t_section), INTENT(inout) ::  paero(fn2b) !< Aerosol properties
3502    REAL(wp), INTENT(in) ::  ppres  !< ambient pressure (Pa)
3503    REAL(wp), INTENT(in) ::  ptemp  !< ambient temperature (K)
3504    REAL(wp), INTENT(in) ::  ptstep !< time step (s)
3505!-- Local variables
3506    INTEGER(iwp) ::  index_2a !< corresponding bin in subrange 2a
3507    INTEGER(iwp) ::  index_2b !< corresponding bin in subrange 2b
3508    INTEGER(iwp) ::  b !< loop index
3509    INTEGER(iwp) ::  ll !< loop index
3510    INTEGER(iwp) ::  mm !< loop index
3511    INTEGER(iwp) ::  nn !< loop index
3512    REAL(wp) ::  pressi !< pressure
3513    REAL(wp) ::  temppi !< temperature
3514    REAL(wp) ::  zcc(fn2b,fn2b)   !< updated coagulation coefficients (m3/s) 
3515    REAL(wp) ::  zdpart_mm        !< diameter of particle (m)
3516    REAL(wp) ::  zdpart_nn        !< diameter of particle (m)   
3517    REAL(wp) ::  zminusterm       !< coagulation loss in a bin (1/s)
3518    REAL(wp) ::  zplusterm(8)     !< coagulation gain in a bin (fxm/s)
3519                                  !< (for each chemical compound)
3520    REAL(wp) ::  zmpart(fn2b)     !< approximate mass of particles (kg)
3521   
3522    zcc       = 0.0_wp
3523    zmpart    = 0.0_wp
3524    zdpart_mm = 0.0_wp
3525    zdpart_nn = 0.0_wp
3526!
3527!-- 1) Coagulation to coarse mode calculated in a simplified way:
3528!--    CoagSink ~ Dp in continuum subrange, thus we calculate 'effective'
3529!--    number concentration of coarse particles
3530
3531!-- 2) Updating coagulation coefficients
3532!   
3533!-- Aerosol mass (kg). Density of 1500 kg/m3 assumed
3534    zmpart(1:fn2b) = api6 * ( MIN( paero(1:fn2b)%dwet, 30.0E-6_wp )**3.0_wp  ) &
3535                     * 1500.0_wp 
3536    temppi = ptemp
3537    pressi = ppres
3538    zcc    = 0.0_wp
3539!
3540!-- Aero-aero coagulation
3541    DO  mm = 1, fn2b   ! smaller colliding particle
3542       IF ( paero(mm)%numc < nclim )  CYCLE
3543       DO  nn = mm, fn2b   ! larger colliding particle
3544          IF ( paero(nn)%numc < nclim )  CYCLE
3545         
3546          zdpart_mm = MIN( paero(mm)%dwet, 30.0E-6_wp )     ! Limit to 30 um
3547          zdpart_nn = MIN( paero(nn)%dwet, 30.0E-6_wp )     ! Limit to 30 um
3548!             
3549!--       Coagulation coefficient of particles (m3/s)
3550          zcc(mm,nn) = coagc( zdpart_mm, zdpart_nn, zmpart(mm), zmpart(nn),    &
3551                              temppi, pressi )
3552          zcc(nn,mm) = zcc(mm,nn)
3553       ENDDO
3554    ENDDO
3555       
3556!   
3557!-- 3) New particle and volume concentrations after coagulation:
3558!--    Calculated according to Jacobson (2005) eq. 15.9
3559!
3560!-- Aerosols in subrange 1a:
3561    DO  b = in1a, fn1a
3562       IF ( paero(b)%numc < nclim )  CYCLE
3563       zminusterm   = 0.0_wp
3564       zplusterm(:) = 0.0_wp
3565!       
3566!--    Particles lost by coagulation with larger aerosols
3567       DO  ll = b+1, fn2b
3568          zminusterm = zminusterm + zcc(b,ll) * paero(ll)%numc
3569       ENDDO
3570!       
3571!--    Coagulation gain in a bin: change in volume conc. (cm3/cm3):
3572       DO ll = in1a, b-1
3573          zplusterm(1:2) = zplusterm(1:2) + zcc(ll,b) * paero(ll)%volc(1:2)
3574          zplusterm(6:7) = zplusterm(6:7) + zcc(ll,b) * paero(ll)%volc(6:7)
3575          zplusterm(8)   = zplusterm(8)   + zcc(ll,b) * paero(ll)%volc(8)
3576       ENDDO
3577!       
3578!--    Volume and number concentrations after coagulation update [fxm]
3579       paero(b)%volc(1:2) = ( paero(b)%volc(1:2) + ptstep * zplusterm(1:2) * &
3580                             paero(b)%numc ) / ( 1.0_wp + ptstep * zminusterm )
3581       paero(b)%volc(6:7) = ( paero(b)%volc(6:7) + ptstep * zplusterm(6:7) * &
3582                             paero(b)%numc ) / ( 1.0_wp + ptstep * zminusterm )
3583       paero(b)%volc(8)   = ( paero(b)%volc(8)   + ptstep * zplusterm(8) *   &
3584                             paero(b)%numc ) / ( 1.0_wp + ptstep * zminusterm )
3585       paero(b)%numc = paero(b)%numc / ( 1.0_wp + ptstep * zminusterm  +     &
3586                        0.5_wp * ptstep * zcc(b,b) * paero(b)%numc )               
3587    ENDDO
3588!             
3589!-- Aerosols in subrange 2a:
3590    DO  b = in2a, fn2a
3591       IF ( paero(b)%numc < nclim )  CYCLE
3592       zminusterm   = 0.0_wp
3593       zplusterm(:) = 0.0_wp
3594!       
3595!--    Find corresponding size bin in subrange 2b
3596       index_2b = b - in2a + in2b
3597!       
3598!--    Particles lost by larger particles in 2a
3599       DO  ll = b+1, fn2a
3600          zminusterm = zminusterm + zcc(b,ll) * paero(ll)%numc
3601       ENDDO
3602!       
3603!--    Particles lost by larger particles in 2b
3604       IF ( .NOT. no_insoluble )  THEN
3605          DO  ll = index_2b+1, fn2b
3606             zminusterm = zminusterm + zcc(b,ll) * paero(ll)%numc
3607          ENDDO
3608       ENDIF
3609!       
3610!--    Particle volume gained from smaller particles in subranges 1, 2a and 2b
3611       DO  ll = in1a, b-1
3612          zplusterm(1:2) = zplusterm(1:2) + zcc(ll,b) * paero(ll)%volc(1:2)
3613          zplusterm(6:7) = zplusterm(6:7) + zcc(ll,b) * paero(ll)%volc(6:7)
3614          zplusterm(8)   = zplusterm(8)   + zcc(ll,b) * paero(ll)%volc(8)
3615       ENDDO 
3616!       
3617!--    Particle volume gained from smaller particles in 2a
3618!--    (Note, for components not included in the previous loop!)
3619       DO  ll = in2a, b-1
3620          zplusterm(3:5) = zplusterm(3:5) + zcc(ll,b)*paero(ll)%volc(3:5)             
3621       ENDDO
3622       
3623!       
3624!--    Particle volume gained from smaller (and equal) particles in 2b
3625       IF ( .NOT. no_insoluble )  THEN
3626          DO  ll = in2b, index_2b
3627             zplusterm(1:8) = zplusterm(1:8) + zcc(ll,b) * paero(ll)%volc(1:8)
3628          ENDDO
3629       ENDIF
3630!       
3631!--    Volume and number concentrations after coagulation update [fxm]
3632       paero(b)%volc(1:8) = ( paero(b)%volc(1:8) + ptstep * zplusterm(1:8) * &
3633                             paero(b)%numc ) / ( 1.0_wp + ptstep * zminusterm )
3634       paero(b)%numc = paero(b)%numc / ( 1.0_wp + ptstep * zminusterm +      &
3635                        0.5_wp * ptstep * zcc(b,b) * paero(b)%numc )
3636    ENDDO
3637!             
3638!-- Aerosols in subrange 2b:
3639    IF ( .NOT. no_insoluble )  THEN
3640       DO  b = in2b, fn2b
3641          IF ( paero(b)%numc < nclim )  CYCLE
3642          zminusterm   = 0.0_wp
3643          zplusterm(:) = 0.0_wp
3644!       
3645!--       Find corresponding size bin in subsubrange 2a
3646          index_2a = b - in2b + in2a
3647!       
3648!--       Particles lost to larger particles in subranges 2b
3649          DO  ll = b+1, fn2b
3650             zminusterm = zminusterm + zcc(b,ll) * paero(ll)%numc
3651          ENDDO
3652!       
3653!--       Particles lost to larger and equal particles in 2a
3654          DO  ll = index_2a, fn2a
3655             zminusterm = zminusterm + zcc(b,ll) * paero(ll)%numc
3656          ENDDO
3657!       
3658!--       Particle volume gained from smaller particles in subranges 1 & 2a
3659          DO  ll = in1a, index_2a-1
3660             zplusterm(1:8) = zplusterm(1:8) + zcc(ll,b) * paero(ll)%volc(1:8)
3661          ENDDO
3662!       
3663!--       Particle volume gained from smaller particles in 2b
3664          DO  ll = in2b, b-1
3665             zplusterm(1:8) = zplusterm(1:8) + zcc(ll,b) * paero(ll)%volc(1:8)
3666          ENDDO
3667!       
3668!--       Volume and number concentrations after coagulation update [fxm]
3669          paero(b)%volc(1:8) = ( paero(b)%volc(1:8) + ptstep * zplusterm(1:8)&
3670                           * paero(b)%numc ) / ( 1.0_wp + ptstep * zminusterm )
3671          paero(b)%numc = paero(b)%numc / ( 1.0_wp + ptstep * zminusterm  +  &
3672                           0.5_wp * ptstep * zcc(b,b) * paero(b)%numc )
3673       ENDDO
3674    ENDIF
3675
3676 END SUBROUTINE coagulation
3677
3678!------------------------------------------------------------------------------!
3679! Description:
3680! ------------
3681!> Calculation of coagulation coefficients. Extended version of the function
3682!> originally found in mo_salsa_init.
3683!
3684!> J. Tonttila, FMI, 05/2014
3685!------------------------------------------------------------------------------!
3686 REAL(wp) FUNCTION coagc( diam1, diam2, mass1, mass2, temp, pres )
3687 
3688    IMPLICIT NONE
3689!       
3690!-- Input and output variables
3691    REAL(wp), INTENT(in) ::  diam1 !< diameter of colliding particle 1 (m)
3692    REAL(wp), INTENT(in) ::  diam2 !< diameter of colliding particle 2 (m)
3693    REAL(wp), INTENT(in) ::  mass1 !< mass of colliding particle 1 (kg)
3694    REAL(wp), INTENT(in) ::  mass2 !< mass of colliding particle 2 (kg)
3695    REAL(wp), INTENT(in) ::  pres  !< ambient pressure (Pa?) [fxm]
3696    REAL(wp), INTENT(in) ::  temp  !< ambient temperature (K)       
3697!
3698!-- Local variables
3699    REAL(wp) ::  fmdist !< distance of flux matching (m)   
3700    REAL(wp) ::  knud_p !< particle Knudsen number
3701    REAL(wp) ::  mdiam  !< mean diameter of colliding particles (m) 
3702    REAL(wp) ::  mfp    !< mean free path of air molecules (m)   
3703    REAL(wp) ::  visc   !< viscosity of air (kg/(m s))                   
3704    REAL(wp), DIMENSION (2) ::  beta   !< Cunningham correction factor
3705    REAL(wp), DIMENSION (2) ::  dfpart !< particle diffusion coefficient
3706                                       !< (m2/s)       
3707    REAL(wp), DIMENSION (2) ::  diam   !< diameters of particles (m)
3708    REAL(wp), DIMENSION (2) ::  flux   !< flux in continuum and free molec.
3709                                       !< regime (m/s)       
3710    REAL(wp), DIMENSION (2) ::  knud   !< particle Knudsen number       
3711    REAL(wp), DIMENSION (2) ::  mpart  !< masses of particles (kg)
3712    REAL(wp), DIMENSION (2) ::  mtvel  !< particle mean thermal velocity (m/s)
3713    REAL(wp), DIMENSION (2) ::  omega  !< particle mean free path             
3714    REAL(wp), DIMENSION (2) ::  tva    !< temporary variable (m)       
3715!
3716!-- Initialisation
3717    coagc   = 0.0_wp
3718!
3719!-- 1) Initializing particle and ambient air variables
3720    diam  = (/ diam1, diam2 /) !< particle diameters (m)
3721    mpart = (/ mass1, mass2 /) !< particle masses (kg)
3722!-- Viscosity of air (kg/(m s))       
3723    visc = ( 7.44523E-3_wp * temp ** 1.5_wp ) /                                &
3724           ( 5093.0_wp * ( temp + 110.4_wp ) ) 
3725!-- Mean free path of air (m)           
3726    mfp = ( 1.656E-10_wp * temp + 1.828E-8_wp ) * ( p_0 + 1325.0_wp ) / pres
3727!
3728!-- 2) Slip correction factor for small particles
3729    knud = 2.0_wp * EXP( LOG(mfp) - LOG(diam) )! Knudsen number for air (15.23)
3730!-- Cunningham correction factor (Allen and Raabe, Aerosol Sci. Tech. 4, 269)       
3731    beta = 1.0_wp + knud * ( 1.142_wp + 0.558_wp * EXP( -0.999_wp / knud ) )
3732!
3733!-- 3) Particle properties
3734!-- Diffusion coefficient (m2/s) (Jacobson (2005) eq. 15.29)
3735    dfpart = beta * abo * temp / ( 3.0_wp * pi * visc * diam ) 
3736!-- Mean thermal velocity (m/s) (Jacobson (2005) eq. 15.32)
3737    mtvel = SQRT( ( 8.0_wp * abo * temp ) / ( pi * mpart ) )
3738!-- Particle mean free path (m) (Jacobson (2005) eq. 15.34 )
3739    omega = 8.0_wp * dfpart / ( pi * mtvel ) 
3740!-- Mean diameter (m)
3741    mdiam = 0.5_wp * ( diam(1) + diam(2) )
3742!
3743!-- 4) Calculation of fluxes (Brownian collision kernels) and flux matching
3744!-- following Jacobson (2005):
3745!-- Flux in continuum regime (m3/s) (eq. 15.28)
3746    flux(1) = 4.0_wp * pi * mdiam * ( dfpart(1) + dfpart(2) )
3747!-- Flux in free molec. regime (m3/s) (eq. 15.31)
3748    flux(2) = pi * SQRT( ( mtvel(1)**2.0_wp ) + ( mtvel(2)**2.0_wp ) ) *      &
3749              ( mdiam**2.0_wp )
3750!-- temporary variables (m) to calculate flux matching distance (m)
3751    tva(1) = ( ( mdiam + omega(1) )**3.0_wp - ( mdiam**2.0_wp +                &
3752               omega(1)**2.0_wp ) * SQRT( ( mdiam**2.0_wp + omega(1)**2.0_wp ) &
3753               ) ) / ( 3.0_wp * mdiam * omega(1) ) - mdiam
3754    tva(2) = ( ( mdiam + omega(2) )**3.0_wp - ( mdiam**2.0_wp +                &
3755               omega(2)**2.0_wp ) * SQRT( ( mdiam**2 + omega(2)**2 ) ) ) /     &
3756             ( 3.0_wp * mdiam * omega(2) ) - mdiam
3757!-- Flux matching distance (m) i.e. the mean distance from the centre of a
3758!-- sphere reached by particles leaving sphere's surface and travelling a
3759!-- distance of particle mean free path mfp (eq. 15 34)                 
3760    fmdist = SQRT( tva(1)**2 + tva(2)**2.0_wp) 
3761!
3762!-- 5) Coagulation coefficient (m3/s) (eq. 15.33). Here assumed
3763!-- coalescence efficiency 1!!
3764    coagc = flux(1) / ( mdiam / ( mdiam + fmdist) + flux(1) / flux(2) ) 
3765!-- coagulation coefficient = coalescence efficiency * collision kernel
3766!
3767!-- Corrected collision kernel following Karl et al., 2016 (ACP):
3768!-- Inclusion of van der Waals and viscous forces
3769    IF ( van_der_waals_coagc )  THEN
3770       knud_p = SQRT( omega(1)**2 + omega(2)**2 ) / mdiam   
3771       IF ( knud_p >= 0.1_wp  .AND.  knud_p <= 10.0_wp )  THEN
3772          coagc = coagc * ( 2.0_wp + 0.4_wp * LOG( knud_p ) )
3773       ELSE
3774          coagc = coagc * 3.0_wp
3775       ENDIF
3776    ENDIF
3777   
3778 END FUNCTION coagc
3779 
3780!------------------------------------------------------------------------------!   
3781! Description:
3782! ------------
3783!> Calculates the change in particle volume and gas phase
3784!> concentrations due to nucleation, condensation and dissolutional growth.
3785!
3786!> Sulphuric acid and organic vapour: only condensation and no evaporation.
3787!
3788!> New gas and aerosol phase concentrations calculated according to Jacobson
3789!> (1997): Numerical techniques to solve condensational and dissolutional growth
3790!> equations when growth is coupled to reversible reactions, Aerosol Sci. Tech.,
3791!> 27, pp 491-498.
3792!
3793!> Following parameterization has been used:
3794!> Molecular diffusion coefficient of condensing vapour (m2/s)
3795!> (Reid et al. (1987): Properties of gases and liquids, McGraw-Hill, New York.)
3796!> D = {1.d-7*sqrt(1/M_air + 1/M_gas)*T^1.75} / &
3797!      {p_atm/p_stand * (d_air^(1/3) + d_gas^(1/3))^2 }
3798! M_air = 28.965 : molar mass of air (g/mol)
3799! d_air = 19.70  : diffusion volume of air
3800! M_h2so4 = 98.08 : molar mass of h2so4 (g/mol)
3801! d_h2so4 = 51.96  : diffusion volume of h2so4
3802!
3803!> Called from main aerosol model
3804!
3805!> fxm: calculated for empty bins too
3806!> fxm: same diffusion coefficients and mean free paths used for sulphuric acid
3807!>      and organic vapours (average values? 'real' values for each?)
3808!> fxm: one should really couple with vapour production and loss terms as well
3809!>      should nucleation be coupled here as well????
3810!
3811! Coded by:
3812! Hannele Korhonen (FMI) 2005
3813! Harri Kokkola (FMI) 2006
3814! Juha Tonttila (FMI) 2014
3815! Rewritten to PALM by Mona Kurppa (UHel) 2017
3816!------------------------------------------------------------------------------!
3817 SUBROUTINE condensation( paero, pcsa, pcocnv, pcocsv, pchno3, pcnh3, pcw, pcs,&
3818                          ptemp, ppres, ptstep, prtcl )
3819       
3820    IMPLICIT NONE
3821   
3822!-- Input and output variables
3823    REAL(wp), INTENT(IN) ::  ppres !< ambient pressure (Pa)
3824    REAL(wp), INTENT(IN) ::  pcs   !< Water vapour saturation concentration
3825                                   !< (kg/m3)     
3826    REAL(wp), INTENT(IN) ::  ptemp !< ambient temperature (K)
3827    REAL(wp), INTENT(IN) ::  ptstep            !< timestep (s) 
3828    TYPE(component_index), INTENT(in) :: prtcl !< Keeps track which substances
3829                                               !< are used                                               
3830    REAL(wp), INTENT(INOUT) ::  pchno3 !< Gas concentrations (#/m3):
3831                                       !< nitric acid HNO3
3832    REAL(wp), INTENT(INOUT) ::  pcnh3  !< ammonia NH3
3833    REAL(wp), INTENT(INOUT) ::  pcocnv !< non-volatile organics
3834    REAL(wp), INTENT(INOUT) ::  pcocsv !< semi-volatile organics
3835    REAL(wp), INTENT(INOUT) ::  pcsa   !< sulphuric acid H2SO4
3836    REAL(wp), INTENT(INOUT) ::  pcw    !< Water vapor concentration (kg/m3)
3837    TYPE(t_section), INTENT(inout) ::  paero(fn2b) !< Aerosol properties                                     
3838!-- Local variables
3839    REAL(wp) ::  zbeta(fn2b) !< transitional correction factor for aerosols
3840    REAL(wp) ::  zcolrate(fn2b) !< collision rate of molecules to particles
3841                                !< (1/s)
3842    REAL(wp) ::  zcolrate_ocnv(fn2b) !< collision rate of organic molecules
3843                                     !< to particles (1/s)
3844    REAL(wp) ::  zcs_ocnv !< condensation sink of nonvolatile organics (1/s)       
3845    REAL(wp) ::  zcs_ocsv !< condensation sink of semivolatile organics (1/s)
3846    REAL(wp) ::  zcs_su !< condensation sink of sulfate (1/s)
3847    REAL(wp) ::  zcs_tot!< total condensation sink (1/s) (gases)
3848!-- vapour concentration after time step (#/m3)
3849    REAL(wp) ::  zcvap_new1 !< sulphuric acid
3850    REAL(wp) ::  zcvap_new2 !< nonvolatile organics
3851    REAL(wp) ::  zcvap_new3 !< semivolatile organics
3852    REAL(wp) ::  zdfpart(in1a+1) !< particle diffusion coefficient (m2/s)     
3853    REAL(wp) ::  zdfvap !< air diffusion coefficient (m2/s)
3854!-- change in vapour concentration (#/m3)
3855    REAL(wp) ::  zdvap1 !< sulphuric acid
3856    REAL(wp) ::  zdvap2 !< nonvolatile organics
3857    REAL(wp) ::  zdvap3 !< semivolatile organics
3858    REAL(wp) ::  zdvoloc(fn2b) !< change of organics volume in each bin [fxm]   
3859    REAL(wp) ::  zdvolsa(fn2b) !< change of sulphate volume in each bin [fxm]
3860    REAL(wp) ::  zj3n3(2)      !< Formation massrate of molecules in
3861                               !< nucleation, (molec/m3s). 1: H2SO4
3862                               !< and 2: organic vapor       
3863    REAL(wp) ::  zknud(fn2b) !< particle Knudsen number       
3864    REAL(wp) ::  zmfp    !< mean free path of condensing vapour (m)
3865    REAL(wp) ::  zrh     !< Relative humidity [0-1]         
3866    REAL(wp) ::  zvisc   !< viscosity of air (kg/(m s))     
3867    REAL(wp) ::  zn_vs_c !< ratio of nucleation of all mass transfer in the
3868                         !< smallest bin
3869    REAL(wp) ::  zxocnv  !< ratio of organic vapour in 3nm particles
3870    REAL(wp) ::  zxsa    !< Ratio in 3nm particles: sulphuric acid
3871   
3872    zj3n3  = 0.0_wp
3873    zrh    = pcw / pcs   
3874    zxocnv = 0.0_wp
3875    zxsa   = 0.0_wp
3876!
3877!-- Nucleation
3878    IF ( nsnucl > 0 )  THEN
3879       CALL nucleation( paero, ptemp, zrh, ppres, pcsa, pcocnv, pcnh3, ptstep, &
3880                        zj3n3, zxsa, zxocnv )
3881    ENDIF
3882!
3883!-- Condensation on pre-existing particles
3884    IF ( lscndgas )  THEN
3885!
3886!--    Initialise:
3887       zdvolsa = 0.0_wp 
3888       zdvoloc = 0.0_wp
3889       zcolrate = 0.0_wp
3890!             
3891!--    1) Properties of air and condensing gases:
3892!--    Viscosity of air (kg/(m s)) (Eq. 4.54 in Jabonson (2005))
3893       zvisc = ( 7.44523E-3_wp * ptemp ** 1.5_wp ) / ( 5093.0_wp *             &
3894                 ( ptemp + 110.4_wp ) )
3895!--    Diffusion coefficient of air (m2/s)
3896       zdfvap = 5.1111E-10_wp * ptemp ** 1.75_wp * ( p_0 + 1325.0_wp ) / ppres
3897!--    Mean free path (m): same for H2SO4 and organic compounds
3898       zmfp = 3.0_wp * zdfvap * SQRT( pi * amh2so4 / ( 8.0_wp * argas * ptemp ) )
3899!                   
3900!--    2) Transition regime correction factor zbeta for particles:
3901!--       Fuchs and Sutugin (1971), In: Hidy et al. (ed.) Topics in current
3902!--       aerosol research, Pergamon. Size of condensing molecule considered 
3903!--       only for nucleation mode (3 - 20 nm)
3904!
3905!--    Particle Knudsen number: condensation of gases on aerosols
3906       zknud(in1a:in1a+1) = 2.0_wp * zmfp / ( paero(in1a:in1a+1)%dwet + d_sa )
3907       zknud(in1a+2:fn2b) = 2.0_wp * zmfp / paero(in1a+2:fn2b)%dwet
3908!   
3909!--    Transitional correction factor: aerosol + gas (the semi-empirical Fuchs-
3910!--    Sutugin interpolation function (Fuchs and Sutugin, 1971))
3911       zbeta = ( zknud + 1.0_wp ) / ( 0.377_wp * zknud + 1.0_wp + 4.0_wp /     &
3912               ( 3.0_wp * massacc ) * ( zknud + zknud ** 2.0_wp ) )
3913!                   
3914!--    3) Collision rate of molecules to particles
3915!--       Particle diffusion coefficient considered only for nucleation mode
3916!--       (3 - 20 nm)
3917!
3918!--    Particle diffusion coefficient (m2/s) (e.g. Eq. 15.29 in Jacobson (2005))
3919       zdfpart = abo * ptemp * zbeta(in1a:in1a+1) / ( 3.0_wp * pi * zvisc *    &
3920                 paero(in1a:in1a+1)%dwet )
3921!             
3922!--    Collision rate (mass-transfer coefficient): gases on aerosols (1/s)
3923!--    (Eq. 16.64 in Jacobson (2005))
3924       zcolrate(in1a:in1a+1) = MERGE( 2.0_wp * pi *                            &
3925                                      ( paero(in1a:in1a+1)%dwet + d_sa ) *     &
3926                                      ( zdfvap + zdfpart ) * zbeta(in1a:in1a+1)& 
3927                                        * paero(in1a:in1a+1)%numc, 0.0_wp,     &
3928                                      paero(in1a:in1a+1)%numc > nclim )
3929       zcolrate(in1a+2:fn2b) = MERGE( 2.0_wp * pi * paero(in1a+2:fn2b)%dwet *  &
3930                                      zdfvap * zbeta(in1a+2:fn2b) *            &
3931                                      paero(in1a+2:fn2b)%numc, 0.0_wp,         &
3932                                      paero(in1a+2:fn2b)%numc > nclim )
3933!                 
3934!-- 4) Condensation sink (1/s)
3935       zcs_tot = SUM( zcolrate )   ! total sink
3936!
3937!--    5) Changes in gas-phase concentrations and particle volume
3938!
3939!--    5.1) Organic vapours
3940!
3941!--    5.1.1) Non-volatile organic compound: condenses onto all bins
3942       IF ( pcocnv > 1.0E+10_wp  .AND.  zcs_tot > 1.0E-30_wp  .AND.            &
3943            is_used( prtcl,'OC' ) )                                            &
3944       THEN
3945!--       Ratio of nucleation vs. condensation rates in the smallest bin   
3946          zn_vs_c = 0.0_wp 
3947          IF ( zj3n3(2) > 1.0_wp )  THEN
3948             zn_vs_c = ( zj3n3(2) ) / ( zj3n3(2) + pcocnv * zcolrate(in1a) )
3949          ENDIF
3950!       
3951!--       Collision rate in the smallest bin, including nucleation and
3952!--       condensation(see Jacobson, Fundamentals of Atmospheric Modeling, 2nd
3953!--       Edition (2005), equation (16.73) )
3954          zcolrate_ocnv = zcolrate
3955          zcolrate_ocnv(in1a) = zcolrate_ocnv(in1a) + zj3n3(2) / pcocnv
3956!       
3957!--       Total sink for organic vapor
3958          zcs_ocnv = zcs_tot + zj3n3(2) / pcocnv
3959!       
3960!--       New gas phase concentration (#/m3)
3961          zcvap_new2 = pcocnv / ( 1.0_wp + ptstep * zcs_ocnv )
3962!       
3963!--       Change in gas concentration (#/m3)
3964          zdvap2 = pcocnv - zcvap_new2
3965!
3966!--       Updated vapour concentration (#/m3)               
3967          pcocnv = zcvap_new2
3968!       
3969!--       Volume change of particles (m3(OC)/m3(air))
3970          zdvoloc = zcolrate_ocnv(in1a:fn2b) / zcs_ocnv * amvoc * zdvap2
3971!       
3972!--       Change of volume due to condensation in 1a-2b
3973          paero(in1a:fn2b)%volc(2) = paero(in1a:fn2b)%volc(2) + zdvoloc 
3974!       
3975!--       Change of number concentration in the smallest bin caused by
3976!--       nucleation (Jacobson (2005), equation (16.75)). If zxocnv = 0, then 
3977!--       the chosen nucleation mechanism doesn't take into account the non-
3978!--       volatile organic vapors and thus the paero doesn't have to be updated.
3979          IF ( zxocnv > 0.0_wp )  THEN
3980             paero(in1a)%numc = paero(in1a)%numc + zn_vs_c * zdvoloc(in1a) /   &
3981                                amvoc / ( n3 * zxocnv )
3982          ENDIF
3983       ENDIF
3984!   
3985!--    5.1.2) Semivolatile organic compound: all bins except subrange 1
3986       zcs_ocsv = SUM( zcolrate(in2a:fn2b) ) !< sink for semi-volatile organics
3987       IF ( pcocsv > 1.0E+10_wp  .AND.  zcs_ocsv > 1.0E-30  .AND.              &
3988            is_used( prtcl,'OC') )                                             &
3989       THEN
3990!
3991!--       New gas phase concentration (#/m3)
3992          zcvap_new3 = pcocsv / ( 1.0_wp + ptstep * zcs_ocsv )
3993!       
3994!--       Change in gas concentration (#/m3)
3995          zdvap3 = pcocsv - zcvap_new3
3996!       
3997!--       Updated gas concentration (#/m3)               
3998          pcocsv = zcvap_new3
3999!       
4000!--       Volume change of particles (m3(OC)/m3(air))
4001          zdvoloc(in2a:fn2b) = zdvoloc(in2a:fn2b) + zcolrate(in2a:fn2b) /      &
4002                               zcs_ocsv * amvoc * zdvap3
4003!                           
4004!--       Change of volume due to condensation in 1a-2b
4005          paero(in1a:fn2b)%volc(2) = paero(in1a:fn2b)%volc(2) + zdvoloc
4006       ENDIF
4007!
4008!-- 5.2) Sulphate: condensed on all bins
4009       IF ( pcsa > 1.0E+10_wp  .AND.  zcs_tot > 1.0E-30_wp  .AND.              &
4010            is_used( prtcl,'SO4' ) )                                           &
4011       THEN
4012!   
4013!--    Ratio of mass transfer between nucleation and condensation
4014          zn_vs_c = 0.0_wp
4015          IF ( zj3n3(1) > 1.0_wp )  THEN
4016             zn_vs_c = ( zj3n3(1) ) / ( zj3n3(1) + pcsa * zcolrate(in1a) )
4017          ENDIF
4018!       
4019!--       Collision rate in the smallest bin, including nucleation and
4020!--       condensation (see Jacobson, Fundamentals of Atmospheric Modeling, 2nd
4021!--       Edition (2005), equation (16.73))
4022          zcolrate(in1a) = zcolrate(in1a) + zj3n3(1) / pcsa     
4023!       
4024!--       Total sink for sulfate (1/s)
4025          zcs_su = zcs_tot + zj3n3(1) / pcsa
4026!       
4027!--       Sulphuric acid:
4028!--       New gas phase concentration (#/m3)
4029          zcvap_new1 = pcsa / ( 1.0_wp + ptstep * zcs_su )
4030!       
4031!--       Change in gas concentration (#/m3)
4032          zdvap1 = pcsa - zcvap_new1
4033!       
4034!--       Updating vapour concentration (#/m3)
4035          pcsa = zcvap_new1
4036!       
4037!--       Volume change of particles (m3(SO4)/m3(air)) by condensation
4038          zdvolsa = zcolrate(in1a:fn2b) / zcs_su * amvh2so4 * zdvap1
4039!--       For validation: zdvolsa = 5.5 mum3/cm3 per 12 h       
4040       !   zdvolsa = zdvolsa / SUM( zdvolsa ) * 5.5E-12_wp * dt_salsa / 43200.0_wp 
4041          !0.3E-12_wp, 0.6E-12_wp, 11.0E-12_wp, 4.6E-12_wp, 9.2E-12_wp   
4042!       
4043!--       Change of volume concentration of sulphate in aerosol [fxm]
4044          paero(in1a:fn2b)%volc(1) = paero(in1a:fn2b)%volc(1) + zdvolsa
4045!       
4046!--       Change of number concentration in the smallest bin caused by nucleation
4047!--       (Jacobson (2005), equation (16.75))
4048          IF ( zxsa > 0.0_wp )  THEN
4049             paero(in1a)%numc = paero(in1a)%numc + zn_vs_c * zdvolsa(in1a) /   &
4050                                amvh2so4 / ( n3 * zxsa )
4051          ENDIF
4052       ENDIF
4053    ENDIF
4054!
4055!
4056!-- Condensation of water vapour
4057    IF ( lscndh2oae )  THEN
4058       CALL gpparth2o( paero, ptemp, ppres, pcs, pcw, ptstep )
4059    ENDIF
4060!   
4061!
4062!-- Partitioning of H2O, HNO3, and NH3: Dissolutional growth
4063    IF ( lscndgas  .AND.  ino > 0  .AND.  inh > 0  .AND.                       &
4064         ( pchno3 > 1.0E+10_wp  .OR.  pcnh3 > 1.0E+10_wp ) )                   &
4065    THEN
4066       CALL gpparthno3( ppres, ptemp, paero, pchno3, pcnh3, pcw, pcs, zbeta,   &
4067                        ptstep )
4068    ENDIF
4069   
4070 END SUBROUTINE condensation
4071 
4072!------------------------------------------------------------------------------!
4073! Description:
4074! ------------
4075!> Calculates the particle number and volume increase, and gas-phase
4076!> concentration decrease due to nucleation subsequent growth to detectable size
4077!> of 3 nm.
4078!
4079!> Method:
4080!> When the formed clusters grow by condensation (possibly also by self-
4081!> coagulation), their number is reduced due to scavenging to pre-existing
4082!> particles. Thus, the apparent nucleation rate at 3 nm is significantly lower
4083!> than the real nucleation rate (at ~1 nm).
4084!
4085!> Calculation of the formation rate of detectable particles at 3 nm (i.e. J3):
4086!> nj3 = 1: Kerminen, V.-M. and Kulmala, M. (2002), J. Aerosol Sci.,33, 609-622.
4087!> nj3 = 2: Lehtinen et al. (2007), J. Aerosol Sci., 38(9), 988-994.
4088!> nj3 = 3: Anttila et al. (2010), J. Aerosol Sci., 41(7), 621-636.
4089!
4090!> Called from subroutine condensation (in module salsa_dynamics_mod.f90)
4091!
4092!> Calls one of the following subroutines:
4093!>  - binnucl
4094!>  - ternucl
4095!>  - kinnucl
4096!>  - actnucl
4097!
4098!> fxm: currently only sulphuric acid grows particles from 1 to 3 nm
4099!>  (if asked from Markku, this is terribly wrong!!!)
4100!
4101!> Coded by:
4102!> Hannele Korhonen (FMI) 2005
4103!> Harri Kokkola (FMI) 2006
4104!> Matti Niskanen(FMI) 2012
4105!> Anton Laakso  (FMI) 2013
4106!------------------------------------------------------------------------------!
4107
4108 SUBROUTINE nucleation( paero, ptemp, prh, ppres, pcsa, pcocnv, pcnh3, ptstep, &
4109                        pj3n3, pxsa, pxocnv )
4110    IMPLICIT NONE
4111!       
4112!-- Input and output variables
4113    REAL(wp), INTENT(in) ::  pcnh3    !< ammonia concentration (#/m3)
4114    REAL(wp), INTENT(in) ::  pcocnv   !< conc. of non-volatile OC (#/m3)     
4115    REAL(wp), INTENT(in) ::  pcsa     !< sulphuric acid conc. (#/m3)
4116    REAL(wp), INTENT(in) ::  ppres    !< ambient air pressure (Pa)
4117    REAL(wp), INTENT(in) ::  prh      !< ambient rel. humidity [0-1]       
4118    REAL(wp), INTENT(in) ::  ptemp    !< ambient temperature (K)
4119    REAL(wp), INTENT(in) ::  ptstep   !< time step (s) of SALSA
4120    TYPE(t_section), INTENT(inout) ::  paero(fn2b) !< aerosol properties                                                 
4121    REAL(wp), INTENT(inout) ::  pj3n3(2) !< formation mass rate of molecules
4122                                         !< (molec/m3s) for 1: H2SO4 and
4123                                         !< 2: organic vapour
4124    REAL(wp), INTENT(out) ::  pxocnv !< ratio of non-volatile organic vapours in
4125                                     !< 3nm aerosol particles
4126    REAL(wp), INTENT(out) ::  pxsa   !< ratio of H2SO4 in 3nm aerosol particles
4127!-- Local variables
4128    INTEGER(iwp) ::  iteration
4129    REAL(wp) ::  zbeta(fn2b)  !< transitional correction factor                                         
4130    REAL(wp) ::  zc_h2so4     !< H2SO4 conc. (#/cm3) !UNITS!
4131    REAL(wp) ::  zc_org       !< organic vapour conc. (#/cm3)
4132    REAL(wp) ::  zCoagStot    !< total losses due to coagulation, including
4133                              !< condensation and self-coagulation       
4134    REAL(wp) ::  zcocnv_local !< organic vapour conc. (#/m3)
4135    REAL(wp) ::  zcsink       !< condensational sink (#/m2)       
4136    REAL(wp) ::  zcsa_local   !< H2SO4 conc. (#/m3)       
4137    REAL(wp) ::  zdcrit       !< diameter of critical cluster (m)
4138    REAL(wp) ::  zdelta_vap   !< change of H2SO4 and organic vapour
4139                              !< concentration (#/m3)       
4140    REAL(wp) ::  zdfvap       !< air diffusion coefficient (m2/s)
4141    REAL(wp) ::  zdmean       !< mean diameter of existing particles (m)
4142    REAL(wp) ::  zeta         !< constant: proportional to ratio of CS/GR (m)
4143                              !< (condensation sink / growth rate)                                   
4144    REAL(wp) ::  zgamma       !< proportionality factor ((nm2*m2)/h)                                       
4145    REAL(wp) ::  zGRclust     !< growth rate of formed clusters (nm/h)
4146    REAL(wp) ::  zGRtot       !< total growth rate       
4147    REAL(wp) ::  zj3          !< number conc. of formed 3nm particles (#/m3)       
4148    REAL(wp) ::  zjnuc        !< nucleation rate at ~1nm (#/m3s)
4149    REAL(wp) ::  zKeff        !< effective cogulation coefficient between
4150                              !< freshly nucleated particles       
4151    REAL(wp) ::  zknud(fn2b)  !< particle Knudsen number       
4152    REAL(wp) ::  zkocnv       !< lever: zkocnv=1 --> organic compounds involved
4153                              !< in nucleation   
4154    REAL(wp) ::  zksa         !< lever: zksa=1 --> H2SO4 involved in nucleation
4155    REAL(wp) ::  zlambda      !< parameter for adjusting the growth rate due to
4156                              !< self-coagulation                                 
4157    REAL(wp) ::  zmfp         !< mean free path of condesing vapour(m)                                       
4158    REAL(wp) ::  zmixnh3      !< ammonia mixing ratio (ppt)
4159    REAL(wp) ::  zNnuc        !< number of clusters/particles at the size range
4160                              !< d1-dx (#/m3) 
4161    REAL(wp) ::  znoc         !< number of organic molecules in critical cluster
4162    REAL(wp) ::  znsa         !< number of H2SO4 molecules in critical cluster                                           
4163!
4164!-- Variable determined for the m-parameter
4165    REAL(wp) ::  zCc_2(fn2b) !<
4166    REAL(wp) ::  zCc_c !<
4167    REAL(wp) ::  zCc_x !<
4168    REAL(wp) ::  zCoagS_c !<
4169    REAL(wp) ::  zCoagS_x !<
4170    REAL(wp) ::  zcv_2(fn2b) !<
4171    REAL(wp) ::  zcv_c !<
4172    REAL(wp) ::  zcv_c2(fn2b) !<
4173    REAL(wp) ::  zcv_x !<
4174    REAL(wp) ::  zcv_x2(fn2b) !<
4175    REAL(wp) ::  zDc_2(fn2b) !<
4176    REAL(wp) ::  zDc_c(fn2b) !<
4177    REAL(wp) ::  zDc_c2(fn2b) !<
4178    REAL(wp) ::  zDc_x(fn2b) !<
4179    REAL(wp) ::  zDc_x2(fn2b) !<
4180    REAL(wp) ::  zgammaF_2(fn2b) !<
4181    REAL(wp) ::  zgammaF_c(fn2b) !<
4182    REAL(wp) ::  zgammaF_x(fn2b) !<
4183    REAL(wp) ::  zK_c2(fn2b) !<
4184    REAL(wp) ::  zK_x2(fn2b) !<
4185    REAL(wp) ::  zknud_2(fn2b) !<
4186    REAL(wp) ::  zknud_c !<
4187    REAL(wp) ::  zknud_x !<       
4188    REAL(wp) ::  zm_2(fn2b) !<
4189    REAL(wp) ::  zm_c !<
4190    REAL(wp) ::  zm_para !<
4191    REAL(wp) ::  zm_x !<
4192    REAL(wp) ::  zmyy !<
4193    REAL(wp) ::  zomega_2c(fn2b) !<
4194    REAL(wp) ::  zomega_2x(fn2b) !<
4195    REAL(wp) ::  zomega_c(fn2b) !<
4196    REAL(wp) ::  zomega_x(fn2b) !<
4197    REAL(wp) ::  zRc2(fn2b) !<
4198    REAL(wp) ::  zRx2(fn2b) !<
4199    REAL(wp) ::  zsigma_c2(fn2b) !<
4200    REAL(wp) ::  zsigma_x2(fn2b) !<
4201!
4202!-- 1) Nucleation rate (zjnuc) and diameter of critical cluster (zdcrit)
4203    zjnuc  = 0.0_wp
4204    znsa   = 0.0_wp
4205    znoc   = 0.0_wp
4206    zdcrit = 0.0_wp
4207    zksa   = 0.0_wp
4208    zkocnv = 0.0_wp
4209   
4210    SELECT CASE ( nsnucl )
4211   
4212    CASE(1)   ! Binary H2SO4-H2O nucleation
4213       
4214       zc_h2so4 = pcsa * 1.0E-6_wp   ! sulphuric acid conc. to #/cm3
4215       CALL binnucl( zc_h2so4, ptemp, prh, zjnuc, znsa, znoc, zdcrit,  zksa, &
4216                     zkocnv )     
4217   
4218    CASE(2)   ! Activation type nucleation
4219   
4220       zc_h2so4 = pcsa * 1.0E-6_wp   ! sulphuric acid conc. to #/cm3
4221       CALL binnucl( zc_h2so4, ptemp, prh, zjnuc, znsa,  znoc, zdcrit, zksa,  &
4222                     zkocnv )
4223       CALL actnucl( pcsa, zjnuc, zdcrit, znsa, znoc, zksa, zkocnv, act_coeff )
4224   
4225    CASE(3)   ! Kinetically limited nucleation of (NH4)HSO4 clusters
4226       
4227       zc_h2so4 = pcsa * 1.0E-6_wp   ! sulphuric acid conc. to #/cm3
4228       CALL binnucl( zc_h2so4, ptemp, prh, zjnuc, znsa, znoc, zdcrit, zksa,    &
4229                     zkocnv )
4230
4231       CALL kinnucl( zc_h2so4, zjnuc, zdcrit, znsa, znoc, zksa, zkocnv )
4232   
4233    CASE(4)   ! Ternary H2SO4-H2O-NH3 nucleation
4234   
4235       zmixnh3 = pcnh3 * ptemp * argas / ( ppres * avo )
4236       zc_h2so4 = pcsa * 1.0E-6_wp   ! sulphuric acid conc. to #/cm3
4237       CALL ternucl( zc_h2so4, zmixnh3, ptemp, prh, zjnuc, znsa, znoc, zdcrit, &
4238                     zksa, zkocnv ) 
4239   
4240    CASE(5)   ! Organic nucleation, J~[ORG] or J~[ORG]**2
4241   
4242       zc_org = pcocnv * 1.0E-6_wp   ! conc. of non-volatile OC to #/cm3
4243       zc_h2so4 = pcsa * 1.0E-6_wp   ! sulphuric acid conc. to #/cm3
4244       CALL binnucl( zc_h2so4, ptemp, prh, zjnuc, znsa, znoc, zdcrit, zksa,    &
4245                     zkocnv ) 
4246       CALL orgnucl( pcocnv, zjnuc, zdcrit, znsa, znoc, zksa, zkocnv )
4247   
4248    CASE(6)   ! Sum of H2SO4 and organic activation type nucleation,
4249              ! J~[H2SO4]+[ORG]
4250       
4251       zc_h2so4 = pcsa * 1.0E-6_wp   ! sulphuric acid conc. to #/cm3
4252       CALL binnucl( zc_h2so4, ptemp, prh, zjnuc, znsa, znoc, zdcrit, zksa,    &
4253                     zkocnv ) 
4254       CALL sumnucl( pcsa, pcocnv, zjnuc, zdcrit, znsa, znoc, zksa, zkocnv )
4255
4256           
4257    CASE(7)   ! Heteromolecular nucleation, J~[H2SO4]*[ORG]
4258       
4259       zc_h2so4 = pcsa * 1.0E-6_wp   ! sulphuric acid conc. to #/cm3
4260       zc_org = pcocnv * 1.0E-6_wp   ! conc. of non-volatile OC to #/cm3
4261       CALL binnucl( zc_h2so4, ptemp, prh, zjnuc, znsa, znoc, zdcrit, zksa,    &
4262                     zkocnv ) 
4263       CALL hetnucl( zc_h2so4, zc_org, zjnuc, zdcrit, znsa, znoc, zksa, zkocnv )
4264   
4265    CASE(8)   ! Homomolecular nucleation of H2SO4 and heteromolecular
4266              ! nucleation of H2SO4 and organic vapour,
4267              ! J~[H2SO4]**2 + [H2SO4]*[ORG] (EUCAARI project)
4268       zc_h2so4 = pcsa * 1.0E-6_wp   ! sulphuric acid conc. to #/cm3
4269       zc_org = pcocnv * 1.0E-6_wp   ! conc. of non-volatile OC to #/cm3
4270       CALL binnucl( zc_h2so4, ptemp, prh, zjnuc, znsa, znoc, zdcrit, zksa,    &
4271                     zkocnv ) 
4272       CALL SAnucl( zc_h2so4, zc_org, zjnuc, zdcrit, znsa, znoc, zksa, zkocnv )
4273   
4274    CASE(9)   ! Homomolecular nucleation of H2SO4 and organic vapour and
4275              ! heteromolecular nucleation of H2SO4 and organic vapour,
4276              ! J~[H2SO4]**2 + [H2SO4]*[ORG]+[ORG]**2 (EUCAARI project)
4277   
4278       zc_h2so4 = pcsa * 1.0E-6_wp   ! sulphuric acid conc. to #/cm3
4279       zc_org = pcocnv * 1.0E-6_wp   ! conc. of non-volatile OC to #/cm3
4280       CALL binnucl( zc_h2so4, ptemp, prh, zjnuc, znsa, znoc, zdcrit, zksa,    &
4281                     zkocnv ) 
4282
4283       CALL SAORGnucl( zc_h2so4, zc_org, zjnuc, zdcrit, znsa, znoc, zksa,      &
4284                       zkocnv )
4285    END SELECT
4286   
4287    zcsa_local = pcsa
4288    zcocnv_local = pcocnv
4289!
4290!-- 2) Change of particle and gas concentrations due to nucleation
4291!         
4292!-- 2.1) Check that there is enough H2SO4 and organic vapour to produce the
4293!--      nucleation 
4294    IF ( nsnucl <= 4 )  THEN 
4295!--    If the chosen nucleation scheme is 1-4, nucleation occurs only due to
4296!--    H2SO4. All of the total vapour concentration that is taking part to the
4297!--    nucleation is there for sulphuric acid (sa = H2SO4) and non-volatile
4298!--    organic vapour is zero.
4299       pxsa   = 1.0_wp   ! ratio of sulphuric acid in 3nm particles
4300       pxocnv = 0.0_wp   ! ratio of non-volatile origanic vapour
4301                                ! in 3nm particles
4302    ELSEIF ( nsnucl > 4 )  THEN
4303!--    If the chosen nucleation scheme is 5-9, nucleation occurs due to organic
4304!--    vapour or the combination of organic vapour and H2SO4. The number of
4305!--    needed molecules depends on the chosen nucleation type and it has an
4306!--    effect also on the minimum ratio of the molecules present.
4307       IF ( pcsa * znsa + pcocnv * znoc < 1.E-14_wp )  THEN
4308          pxsa   = 0.0_wp
4309          pxocnv = 0.0_wp             
4310       ELSE
4311          pxsa   = pcsa * znsa / ( pcsa * znsa + pcocnv * znoc ) 
4312          pxocnv = pcocnv * znoc / ( pcsa * znsa + pcocnv * znoc )
4313       ENDIF 
4314    ENDIF
4315!   
4316!-- The change in total vapour concentration is the sum of the concentrations
4317!-- of the vapours taking part to the nucleation (depends on the chosen
4318!-- nucleation scheme)
4319    zdelta_vap = MIN( zjnuc * ( znoc + znsa ), ( pcocnv * zkocnv + pcsa *      &
4320                      zksa ) / ptstep ) 
4321!                     
4322!-- Nucleation rate J at ~1nm (#/m3s)                           
4323    zjnuc = zdelta_vap / ( znoc + znsa )
4324!   
4325!-- H2SO4 concentration after nucleation in #/m3           
4326    zcsa_local = MAX( 1.0_wp, pcsa - zdelta_vap * pxsa ) 
4327!   
4328!-- Non-volative organic vapour concentration after nucleation (#/m3)
4329    zcocnv_local = MAX( 1.0_wp, pcocnv - zdelta_vap * pxocnv )
4330!
4331!-- 2.2) Formation rate of 3 nm particles (Kerminen & Kulmala, 2002)
4332!
4333!-- 2.2.1) Growth rate of clusters formed by H2SO4
4334!
4335!-- GR = 3.0e-15 / dens_clus * sum( molecspeed * molarmass * conc )
4336
4337!-- dens_clus  = density of the clusters (here 1830 kg/m3)
4338!-- molarmass  = molar mass of condensing species (here 98.08 g/mol)
4339!-- conc       = concentration of condensing species [#/m3]
4340!-- molecspeed = molecular speed of condensing species [m/s]
4341!--            = sqrt( 8.0 * R * ptemp / ( pi * molarmass ) )
4342!-- (Seinfeld & Pandis, 1998)
4343!
4344!-- Growth rate by H2SO4 and organic vapour in nm/h (Eq. 21)
4345    zGRclust = 2.3623E-15_wp * SQRT( ptemp ) * ( zcsa_local + zcocnv_local )
4346!   
4347!-- 2.2.2) Condensational sink of pre-existing particle population
4348!
4349!-- Diffusion coefficient (m2/s)
4350    zdfvap = 5.1111E-10_wp * ptemp ** 1.75_wp * ( p_0 + 1325.0_wp ) / ppres
4351!-- Mean free path of condensing vapour (m) (Jacobson (2005), Eq. 15.25 and
4352!-- 16.29)
4353    zmfp = 3.0_wp * zdfvap * SQRT( pi * amh2so4 / ( 8.0_wp * argas * ptemp ) )
4354!-- Knudsen number           
4355    zknud = 2.0_wp * zmfp / ( paero(:)%dwet + d_sa )                     
4356!-- Transitional regime correction factor (zbeta) according to Fuchs and
4357!-- Sutugin (1971), In: Hidy et al. (ed.), Topics in current  aerosol research,
4358!-- Pergamon. (Eq. 4 in Kerminen and Kulmala, 2002)
4359    zbeta = ( zknud + 1.0_wp) / ( 0.377_wp * zknud + 1.0_wp + 4.0_wp /         &
4360            ( 3.0_wp * massacc ) * ( zknud + zknud ** 2 ) ) 
4361!-- Condensational sink (#/m2) (Eq. 3)
4362    zcsink = SUM( paero(:)%dwet * zbeta * paero(:)%numc )
4363!
4364!-- Parameterised formation rate of detectable 3 nm particles (i.e. J3)
4365    IF ( nj3 == 1 )  THEN   ! Kerminen and Kulmala (2002)
4366!--    2.2.3) Parameterised formation rate of detectable 3 nm particles
4367!--    Constants needed for the parameterisation:
4368!--    dapp = 3 nm and dens_nuc = 1830 kg/m3
4369       IF ( zcsink < 1.0E-30_wp )  THEN
4370          zeta = 0._dp
4371       ELSE
4372!--       Mean diameter of backgroud population (nm)
4373          zdmean = 1.0_wp / SUM( paero(:)%numc ) * SUM( paero(:)%numc *        &
4374                   paero(:)%dwet ) * 1.0E+9_wp
4375!--       Proportionality factor (nm2*m2/h) (Eq. 22)
4376          zgamma = 0.23_wp * ( zdcrit * 1.0E+9_wp ) ** 0.2_wp * ( zdmean /     &
4377                 150.0_wp ) ** 0.048_wp * ( ptemp / 293.0_wp ) ** ( -0.75_wp ) &
4378                 * ( arhoh2so4 / 1000.0_wp ) ** ( -0.33_wp )
4379!--       Factor eta (nm) (Eq. 11)
4380          zeta = MIN( zgamma * zcsink / zGRclust, zdcrit * 1.0E11_wp ) 
4381       ENDIF
4382!       
4383!--    Number conc. of clusters surviving to 3 nm in a time step (#/m3) (Eq.14)
4384       zj3 = zjnuc * EXP( MIN( 0.0_wp, zeta / 3.0_wp - zeta /                  &
4385                               ( zdcrit * 1.0E9_wp ) ) )                   
4386
4387    ELSEIF ( nj3 > 1 )  THEN
4388!--    Defining the value for zm_para. The growth is investigated between
4389!--    [d1,reglim(1)] = [zdcrit,3nm]   
4390!--    m = LOG( CoagS_dx / CoagX_zdcrit ) / LOG( reglim / zdcrit )
4391!--    (Lehtinen et al. 2007, Eq. 5)
4392!--    The steps for the coagulation sink for reglim = 3nm and zdcrit ~= 1nm are
4393!--    explained in article of Kulmala et al. (2001). The particles of diameter
4394!--    zdcrit ~1.14 nm  and reglim = 3nm are both in turn the "number 1"
4395!--    variables (Kulmala et al. 2001).             
4396!--    c = critical (1nm), x = 3nm, 2 = wet or mean droplet
4397!--    Sum of the radii, R12 = R1 + zR2 (m) of two particles 1 and 2
4398       zRc2 = zdcrit / 2.0_wp + paero(:)%dwet / 2.0_wp
4399       zRx2 = reglim(1) / 2.0_wp + paero(:)%dwet / 2.0_wp
4400!       
4401!--    The mass of particle (kg) (comes only from H2SO4)
4402       zm_c = 4.0_wp / 3.0_wp * pi * ( zdcrit / 2.0_wp ) ** 3.0_wp * arhoh2so4                     
4403       zm_x = 4.0_wp / 3.0_wp * pi * ( reglim(1) / 2.0_wp ) ** 3.0_wp *        &
4404              arhoh2so4                 
4405       zm_2 = 4.0_wp / 3.0_wp * pi * ( paero(:)%dwet / 2.0_wp )** 3.0_wp *     &
4406              arhoh2so4
4407!             
4408!--    Mean relative thermal velocity between the particles (m/s)
4409       zcv_c = SQRT( 8.0_wp * abo * ptemp / ( pi * zm_c ) )
4410       zcv_x = SQRT( 8.0_wp * abo * ptemp / ( pi * zm_x ) )
4411       zcv_2 = SQRT( 8.0_wp * abo * ptemp / ( pi * zm_2 ) )
4412!       
4413!--    Average velocity after coagulation               
4414       zcv_c2 = SQRT( zcv_c ** 2.0_wp + zcv_2 ** 2.0_wp )
4415       zcv_x2 = SQRT( zcv_x ** 2.0_wp + zcv_2 ** 2.0_wp )
4416!       
4417!--    Knudsen number (zmfp = mean free path of condensing vapour)
4418       zknud_c = 2.0_wp * zmfp / zdcrit
4419       zknud_x = 2.0_wp * zmfp / reglim(1)
4420       zknud_2 = MAX( 0.0_wp, 2.0_wp * zmfp / paero(:)%dwet )
4421!
4422!--    Cunningham correction factor               
4423       zCc_c = 1.0_wp + zknud_c * ( 1.142_wp + 0.558_wp *                      &
4424               EXP( -0.999_wp / zknud_c ) ) 
4425       zCc_x = 1.0_wp + zknud_x * ( 1.142_wp + 0.558_wp *                      &
4426               EXP( -0.999_wp / zknud_x ) )
4427       zCc_2 = 1.0_wp + zknud_2 * ( 1.142_wp + 0.558_wp *                      &
4428               EXP( -0.999_wp / zknud_2 ) )
4429!                     
4430!--    Gas dynamic viscosity (N*s/m2).
4431!--    Viscocity(air @20C) = 1.81e-5_dp N/m2 *s (Hinds, p. 25)                     
4432       zmyy = 1.81E-5_wp * ( ptemp / 293.0_wp) ** ( 0.74_wp ) 
4433!       
4434!--    Particle diffusion coefficient (m2/s)               
4435       zDc_c = abo * ptemp * zCc_c / ( 3.0_wp * pi * zmyy * zdcrit ) 
4436       zDc_x = abo * ptemp * zCc_x / ( 3.0_wp * pi * zmyy * reglim(1) )
4437       zDc_2 = abo * ptemp * zCc_2 / ( 3.0_wp * pi * zmyy * paero(:)%dwet )
4438!       
4439!--    D12 = D1+D2 (Seinfield and Pandis, 2nd ed. Eq. 13.38)
4440       zDc_c2 = zDc_c + zDc_2   
4441       zDc_x2 = zDc_x + zDc_2
4442!       
4443!--    zgammaF = 8*D/pi/zcv (m) for calculating zomega
4444       zgammaF_c = 8.0_wp * zDc_c / pi / zcv_c
4445       zgammaF_x = 8.0_wp * zDc_x / pi / zcv_x
4446       zgammaF_2 = 8.0_wp * zDc_2 / pi / zcv_2
4447!       
4448!--    zomega (m) for calculating zsigma             
4449       zomega_c = ( ( zRc2 + zgammaF_c ) ** 3 - ( zRc2 ** 2 +                  &
4450                      zgammaF_c ) ** ( 3.0_wp / 2.0_wp ) ) / ( 3.0_wp *        &
4451                      zRc2 * zgammaF_c ) - zRc2 
4452       zomega_x = ( ( zRx2 + zgammaF_x ) ** 3.0_wp - ( zRx2 ** 2.0_wp +        &
4453                      zgammaF_x ) ** ( 3.0_wp / 2.0_wp ) ) / ( 3.0_wp *        &
4454                      zRx2 * zgammaF_x ) - zRx2
4455       zomega_2c = ( ( zRc2 + zgammaF_2 ) ** 3.0_wp - ( zRc2 ** 2.0_wp +       &
4456                       zgammaF_2 ) ** ( 3.0_wp / 2.0_wp ) ) / ( 3.0_wp *       &
4457                       zRc2 * zgammaF_2 ) - zRc2
4458       zomega_2x = ( ( zRx2 + zgammaF_2 ) ** 3.0_wp - ( zRx2 ** 2.0_wp +       &
4459                       zgammaF_2 ) ** ( 3.0_wp / 2.0_wp ) ) / ( 3.0_wp *       &
4460                       zRx2 * zgammaF_2 ) - zRx2
4461!                       
4462!--    The distance (m) at which the two fluxes are matched (condensation and
4463!--    coagulation sinks?)           
4464       zsigma_c2 = SQRT( zomega_c ** 2.0_wp + zomega_2c ** 2.0_wp ) 
4465       zsigma_x2 = SQRT( zomega_x ** 2.0_wp + zomega_2x ** 2.0_wp ) 
4466!       
4467!--    Coagulation coefficient in the continuum regime (m*m2/s)
4468       zK_c2 = 4.0_wp * pi * zRc2 * zDc_c2 / ( zRc2 / ( zRc2 + zsigma_c2 ) +   &
4469               4.0_wp * zDc_c2 / ( zcv_c2 * zRc2 ) ) 
4470       zK_x2 = 4.0_wp * pi * zRx2 * zDc_x2 / ( zRx2 / ( zRx2 + zsigma_x2 ) +   &
4471               4.0_wp * zDc_x2 / ( zcv_x2 * zRx2 ) )
4472!               
4473!--    Coagulation sink (1/s)
4474       zCoagS_c = MAX( 1.0E-20_wp, SUM( zK_c2 * paero(:)%numc ) )         
4475       zCoagS_x = MAX( 1.0E-20_wp, SUM( zK_x2 * paero(:)%numc ) ) 
4476!       
4477!--    Parameter m for calculating the coagulation sink onto background
4478!--    particles (Eq. 5&6 in Lehtinen et al. 2007)             
4479       zm_para = LOG( zCoagS_x / zCoagS_c ) / LOG( reglim(1) / zdcrit )
4480!       
4481!--    Parameter gamma for calculating the formation rate J of particles having
4482!--    a diameter zdcrit < d < reglim(1) (Anttila et al. 2010, eq. 5)
4483       zgamma = ( ( ( reglim(1) / zdcrit ) ** ( zm_para + 1.0_wp ) ) - 1.0_wp )&
4484                / ( zm_para + 1.0_wp )     
4485               
4486       IF ( nj3 == 2 )  THEN   ! Coagulation sink
4487!       
4488!--       Formation rate J before iteration (#/m3s)               
4489          zj3 = zjnuc * EXP( MIN( 0.0_wp, -zgamma * zdcrit * zCoagS_c /        &
4490                ( zGRclust * 1.0E-9_wp / ( 60.0_wp ** 2.0_wp ) ) ) )
4491               
4492       ELSEIF ( nj3 == 3 )  THEN  ! Coagulation sink and self-coag.
4493!--       IF polluted air... then the self-coagulation becomes important.
4494!--       Self-coagulation of small particles < 3 nm.
4495!
4496!--       "Effective" coagulation coefficient between freshly-nucleated
4497!--       particles:
4498          zKeff = 5.0E-16_wp   ! cm3/s
4499!         
4500!--       zlambda parameter for "adjusting" the growth rate due to the
4501!--       self-coagulation
4502          zlambda = 6.0_wp 
4503          IF ( reglim(1) >= 10.0E-9_wp )  THEN   ! for particles >10 nm:
4504             zKeff   = 5.0E-17_wp
4505             zlambda = 3.0_wp
4506          ENDIF
4507!         
4508!--       Initial values for coagulation sink and growth rate  (m/s)
4509          zCoagStot = zCoagS_c
4510          zGRtot = zGRclust * 1.0E-9_wp / 60.0_wp ** 2.0_wp 
4511!         
4512!--       Number of clusters/particles at the size range [d1,dx] (#/m3):
4513          zNnuc = zjnuc / zCoagStot !< Initial guess
4514!         
4515!--       Coagulation sink and growth rate due to self-coagulation:
4516          DO  iteration = 1, 5
4517             zCoagStot = zCoagS_c + zKeff * zNnuc * 1.0E-6_wp   ! (1/s) 
4518             zGRtot = zGRclust * 1.0E-9_wp / ( 3600.0_wp ) +  1.5708E-6_wp *   &
4519                      zlambda * zdcrit ** 3.0_wp * ( zNnuc * 1.0E-6_wp ) *     &
4520                      zcv_c * avo * 1.0E-9_wp / 3600.0_wp 
4521             zeta = - zCoagStot / ( ( zm_para + 1.0_wp ) * zGRtot * ( zdcrit **&
4522                      zm_para ) )   ! Eq. 7b (Anttila)
4523             zNnuc =  zNnuc_tayl( zdcrit, reglim(1), zm_para, zjnuc, zeta,     &
4524                      zGRtot )
4525          ENDDO
4526!         
4527!--       Calculate the final values with new zNnuc:   
4528          zCoagStot = zCoagS_c + zKeff * zNnuc * 1.0E-6_wp   ! (1/s)
4529          zGRtot = zGRclust * 1.0E-9_wp / 3600.0_wp + 1.5708E-6_wp *  zlambda  &
4530                   * zdcrit ** 3.0_wp * ( zNnuc * 1.0E-6_wp ) * zcv_c * avo *  &
4531                   1.0E-9_wp / 3600.0_wp !< (m/s)
4532          zj3 = zjnuc * EXP( MIN( 0.0_wp, -zgamma * zdcrit * zCoagStot /       &
4533                zGRtot ) )   ! (Eq. 5a) (#/m3s)
4534               
4535       ENDIF
4536       
4537    ENDIF
4538!-- If J3 very small (< 1 #/cm3), neglect particle formation. In real atmosphere
4539!-- this would mean that clusters form but coagulate to pre-existing particles
4540!-- who gain sulphate. Since CoagS ~ CS (4piD*CS'), we do *not* update H2SO4
4541!-- concentration here but let condensation take care of it.
4542!-- Formation mass rate of molecules (molec/m3s) for 1: H2SO4 and 2: organic
4543!-- vapour
4544    pj3n3(1) = zj3 * n3 * pxsa
4545    pj3n3(2) = zj3 * n3 * pxocnv
4546                                 
4547                         
4548 END SUBROUTINE nucleation
4549
4550!------------------------------------------------------------------------------!
4551! Description:
4552! ------------
4553!> Calculate the nucleation rate and the size of critical clusters assuming
4554!> binary nucleation.
4555!> Parametrisation according to Vehkamaki et al. (2002), J. Geophys. Res.,
4556!> 107(D22), 4622. Called from subroutine nucleation.
4557!------------------------------------------------------------------------------!
4558 SUBROUTINE binnucl( pc_sa, ptemp, prh, pnuc_rate, pn_crit_sa, pn_crit_ocnv,   &
4559                     pd_crit, pk_sa, pk_ocnv )
4560                   
4561    IMPLICIT NONE
4562!       
4563!-- Input and output variables       
4564    REAL(wp), INTENT(in) ::   pc_sa        !< H2SO4 conc. (#/cm3)
4565    REAL(wp), INTENT(in) ::   prh          !< relative humidity [0-1]       
4566    REAL(wp), INTENT(in) ::   ptemp        !< ambient temperature (K)
4567    REAL(wp), INTENT(out) ::  pnuc_rate    !< nucleation rate (#/(m3 s))
4568    REAL(wp), INTENT(out) ::  pn_crit_sa   !< number of H2SO4 molecules in
4569                                           !< cluster (#)
4570    REAL(wp), INTENT(out) ::  pn_crit_ocnv !< number of organic molecules in
4571                                           !< cluster (#)
4572    REAL(wp), INTENT(out) ::  pd_crit      !< diameter of critical cluster (m)
4573    REAL(wp), INTENT(out) ::  pk_sa        !< Lever: if pk_sa = 1, H2SO4 is
4574                                           !< involved in nucleation.
4575    REAL(wp), INTENT(out) ::  pk_ocnv      !< Lever: if pk_ocnv = 1, organic
4576                                           !< compounds are involved in
4577                                           !< nucleation.
4578!-- Local variables
4579    REAL(wp) ::  zx    !< mole fraction of sulphate in critical cluster
4580    REAL(wp) ::  zntot !< number of molecules in critical cluster
4581    REAL(wp) ::  zt    !< temperature
4582    REAL(wp) ::  zpcsa !< sulfuric acid concentration
4583    REAL(wp) ::  zrh   !< relative humidity
4584    REAL(wp) ::  zma   !<
4585    REAL(wp) ::  zmw   !<
4586    REAL(wp) ::  zxmass!<
4587    REAL(wp) ::  za    !<
4588    REAL(wp) ::  zb    !<
4589    REAL(wp) ::  zc    !<
4590    REAL(wp) ::  zroo  !<
4591    REAL(wp) ::  zm1   !<
4592    REAL(wp) ::  zm2   !<
4593    REAL(wp) ::  zv1   !<
4594    REAL(wp) ::  zv2   !<
4595    REAL(wp) ::  zcoll !<
4596   
4597    pnuc_rate = 0.0_wp
4598    pd_crit   = 1.0E-9_wp
4599
4600!             
4601!-- 1) Checking that we are in the validity range of the parameterization 
4602    zt    = MAX( ptemp, 190.15_wp )
4603    zt    = MIN( zt,    300.15_wp )
4604    zpcsa = MAX( pc_sa, 1.0E4_wp  )
4605    zpcsa = MIN( zpcsa, 1.0E11_wp ) 
4606    zrh   = MAX( prh,   0.0001_wp )
4607    zrh   = MIN( zrh,   1.0_wp    )
4608!               
4609!-- 2) Mole fraction of sulphate in a critical cluster (Eq. 11)
4610    zx = 0.7409967177282139_wp                                           &
4611         - 0.002663785665140117_wp * zt                                  &
4612         + 0.002010478847383187_wp * LOG( zrh )                          &
4613         - 0.0001832894131464668_wp* zt * LOG( zrh )                     &
4614         + 0.001574072538464286_wp * LOG( zrh ) ** 2                     &
4615         - 0.00001790589121766952_wp * zt * LOG( zrh ) ** 2              &
4616         + 0.0001844027436573778_wp * LOG( zrh ) ** 3                    &
4617         - 1.503452308794887E-6_wp * zt * LOG( zrh ) ** 3                &
4618         - 0.003499978417957668_wp * LOG( zpcsa )                        &
4619         + 0.0000504021689382576_wp * zt * LOG( zpcsa )
4620!                   
4621!-- 3) Nucleation rate (Eq. 12)
4622    pnuc_rate = 0.1430901615568665_wp                                    &
4623        + 2.219563673425199_wp * zt                                      &
4624        - 0.02739106114964264_wp * zt ** 2                               &
4625        + 0.00007228107239317088_wp * zt ** 3                            &
4626        + 5.91822263375044_wp / zx                                       &
4627        + 0.1174886643003278_wp * LOG( zrh )                             &
4628        + 0.4625315047693772_wp * zt * LOG( zrh )                        &
4629        - 0.01180591129059253_wp * zt ** 2 * LOG( zrh )                  &
4630        + 0.0000404196487152575_wp * zt ** 3 * LOG( zrh )                &
4631        + ( 15.79628615047088_wp * LOG( zrh ) ) / zx                     &
4632        - 0.215553951893509_wp * LOG( zrh ) ** 2                         &
4633        - 0.0810269192332194_wp * zt * LOG( zrh ) ** 2                   &
4634        + 0.001435808434184642_wp * zt ** 2 * LOG( zrh ) ** 2            &
4635        - 4.775796947178588E-6_wp * zt ** 3 * LOG( zrh ) ** 2            &
4636        - (2.912974063702185_wp * LOG( zrh ) ** 2 ) / zx                 &
4637        - 3.588557942822751_wp * LOG( zrh ) ** 3                         &
4638        + 0.04950795302831703_wp * zt * LOG( zrh ) ** 3                  &
4639        - 0.0002138195118737068_wp * zt ** 2 * LOG( zrh ) ** 3           &
4640        + 3.108005107949533E-7_wp * zt ** 3 * LOG( zrh ) ** 3            &
4641        - ( 0.02933332747098296_wp * LOG( zrh ) ** 3 ) / zx              &
4642        + 1.145983818561277_wp * LOG( zpcsa )                            &
4643        - 0.6007956227856778_wp * zt * LOG( zpcsa )                      &
4644        + 0.00864244733283759_wp * zt ** 2 * LOG( zpcsa )                &
4645        - 0.00002289467254710888_wp * zt ** 3 * LOG( zpcsa )             &
4646        - ( 8.44984513869014_wp * LOG( zpcsa ) ) / zx                    &
4647        + 2.158548369286559_wp * LOG( zrh ) * LOG( zpcsa )               &
4648        + 0.0808121412840917_wp * zt * LOG( zrh ) * LOG( zpcsa )         &
4649        - 0.0004073815255395214_wp * zt ** 2 * LOG( zrh ) * LOG( zpcsa ) &
4650        - 4.019572560156515E-7_wp * zt ** 3 * LOG( zrh ) * LOG( zpcsa )  & 
4651        + ( 0.7213255852557236_wp * LOG( zrh ) * LOG( zpcsa ) ) / zx     &
4652        + 1.62409850488771_wp * LOG( zrh ) ** 2 * LOG( zpcsa )           &
4653        - 0.01601062035325362_wp * zt * LOG( zrh ) ** 2 * LOG( zpcsa )   &
4654        + 0.00003771238979714162_wp*zt**2* LOG( zrh )**2 * LOG( zpcsa )  &
4655        + 3.217942606371182E-8_wp * zt**3 * LOG( zrh )**2 * LOG( zpcsa ) &
4656        - (0.01132550810022116_wp * LOG( zrh )**2 * LOG( zpcsa ) ) / zx  &
4657        + 9.71681713056504_wp * LOG( zpcsa ) ** 2                        &
4658        - 0.1150478558347306_wp * zt * LOG( zpcsa ) ** 2                 &
4659        + 0.0001570982486038294_wp * zt ** 2 * LOG( zpcsa ) ** 2         &
4660        + 4.009144680125015E-7_wp * zt ** 3 * LOG( zpcsa ) ** 2          &
4661        + ( 0.7118597859976135_wp * LOG( zpcsa ) ** 2 ) / zx             &
4662        - 1.056105824379897_wp * LOG( zrh ) * LOG( zpcsa ) ** 2          &
4663        + 0.00903377584628419_wp * zt * LOG( zrh ) * LOG( zpcsa )**2     &
4664        - 0.00001984167387090606_wp*zt**2*LOG( zrh )*LOG( zpcsa )**2     &
4665        + 2.460478196482179E-8_wp * zt**3 * LOG( zrh ) * LOG( zpcsa )**2 &
4666        - ( 0.05790872906645181_wp * LOG( zrh ) * LOG( zpcsa )**2 ) / zx &
4667        - 0.1487119673397459_wp * LOG( zpcsa ) ** 3                      &
4668        + 0.002835082097822667_wp * zt * LOG( zpcsa ) ** 3               &
4669        - 9.24618825471694E-6_wp * zt ** 2 * LOG( zpcsa ) ** 3           &
4670        + 5.004267665960894E-9_wp * zt ** 3 * LOG( zpcsa ) ** 3          &
4671        - ( 0.01270805101481648_wp * LOG( zpcsa ) ** 3 ) / zx
4672!           
4673!-- Nucleation rate in #/(cm3 s)
4674    pnuc_rate = EXP( pnuc_rate ) 
4675!       
4676!-- Check the validity of parameterization
4677    IF ( pnuc_rate < 1.0E-7_wp )  THEN
4678       pnuc_rate = 0.0_wp
4679       pd_crit   = 1.0E-9_wp
4680    ENDIF
4681!               
4682!-- 4) Total number of molecules in the critical cluster (Eq. 13)
4683    zntot = - 0.002954125078716302_wp                                    &
4684      - 0.0976834264241286_wp * zt                                       &
4685      + 0.001024847927067835_wp * zt ** 2                                &
4686      - 2.186459697726116E-6_wp * zt ** 3                                &
4687      - 0.1017165718716887_wp / zx                                       &
4688      - 0.002050640345231486_wp * LOG( zrh )                             &
4689      - 0.007585041382707174_wp * zt * LOG( zrh )                        &
4690      + 0.0001926539658089536_wp * zt ** 2 * LOG( zrh )                  &
4691      - 6.70429719683894E-7_wp * zt ** 3 * LOG( zrh )                    &
4692      - ( 0.2557744774673163_wp * LOG( zrh ) ) / zx                      &
4693      + 0.003223076552477191_wp * LOG( zrh ) ** 2                        &
4694      + 0.000852636632240633_wp * zt * LOG( zrh ) ** 2                   &
4695      - 0.00001547571354871789_wp * zt ** 2 * LOG( zrh ) ** 2            &
4696      + 5.666608424980593E-8_wp * zt ** 3 * LOG( zrh ) ** 2              &
4697      + ( 0.03384437400744206_wp * LOG( zrh ) ** 2 ) / zx                &
4698      + 0.04743226764572505_wp * LOG( zrh ) ** 3                         &
4699      - 0.0006251042204583412_wp * zt * LOG( zrh ) ** 3                  &
4700      + 2.650663328519478E-6_wp * zt ** 2 * LOG( zrh ) ** 3              &
4701      - 3.674710848763778E-9_wp * zt ** 3 * LOG( zrh ) ** 3              &
4702      - ( 0.0002672510825259393_wp * LOG( zrh ) ** 3 ) / zx              &
4703      - 0.01252108546759328_wp * LOG( zpcsa )                            &
4704      + 0.005806550506277202_wp * zt * LOG( zpcsa )                      &
4705      - 0.0001016735312443444_wp * zt ** 2 * LOG( zpcsa )                &
4706      + 2.881946187214505E-7_wp * zt ** 3 * LOG( zpcsa )                 &
4707      + ( 0.0942243379396279_wp * LOG( zpcsa ) ) / zx                    &
4708      - 0.0385459592773097_wp * LOG( zrh ) * LOG( zpcsa )                &
4709      - 0.0006723156277391984_wp * zt * LOG( zrh ) * LOG( zpcsa )        &
4710      + 2.602884877659698E-6_wp * zt ** 2 * LOG( zrh ) * LOG( zpcsa )    &
4711      + 1.194163699688297E-8_wp * zt ** 3 * LOG( zrh ) * LOG( zpcsa )    &
4712      - ( 0.00851515345806281_wp * LOG( zrh ) * LOG( zpcsa ) ) / zx      &
4713      - 0.01837488495738111_wp * LOG( zrh ) ** 2 * LOG( zpcsa )          &
4714      + 0.0001720723574407498_wp * zt * LOG( zrh ) ** 2 * LOG( zpcsa )   &
4715      - 3.717657974086814E-7_wp * zt**2 * LOG( zrh )**2 * LOG( zpcsa )   &
4716      - 5.148746022615196E-10_wp * zt**3 * LOG( zrh )**2 * LOG( zpcsa )  &
4717      + ( 0.0002686602132926594_wp * LOG(zrh)**2 * LOG(zpcsa) ) / zx     &
4718      - 0.06199739728812199_wp * LOG( zpcsa ) ** 2                       &
4719      + 0.000906958053583576_wp * zt * LOG( zpcsa ) ** 2                 &
4720      - 9.11727926129757E-7_wp * zt ** 2 * LOG( zpcsa ) ** 2             &
4721      - 5.367963396508457E-9_wp * zt ** 3 * LOG( zpcsa ) ** 2            &
4722      - ( 0.007742343393937707_wp * LOG( zpcsa ) ** 2 ) / zx             &
4723      + 0.0121827103101659_wp * LOG( zrh ) * LOG( zpcsa ) ** 2           &
4724      - 0.0001066499571188091_wp * zt * LOG( zrh ) * LOG( zpcsa ) ** 2   &
4725      + 2.534598655067518E-7_wp * zt**2 * LOG( zrh ) * LOG( zpcsa )**2   &
4726      - 3.635186504599571E-10_wp * zt**3 * LOG( zrh ) * LOG( zpcsa )**2  &
4727      + ( 0.0006100650851863252_wp * LOG( zrh ) * LOG( zpcsa ) **2 )/ zx &
4728      + 0.0003201836700403512_wp * LOG( zpcsa ) ** 3                     &
4729      - 0.0000174761713262546_wp * zt * LOG( zpcsa ) ** 3                &
4730      + 6.065037668052182E-8_wp * zt ** 2 * LOG( zpcsa ) ** 3            &
4731      - 1.421771723004557E-11_wp * zt ** 3 * LOG( zpcsa ) ** 3           &
4732      + ( 0.0001357509859501723_wp * LOG( zpcsa ) ** 3 ) / zx
4733    zntot = EXP( zntot )  ! in #
4734!
4735!-- 5) Size of the critical cluster pd_crit (m) (diameter) (Eq. 14)
4736    pn_crit_sa = zx * zntot
4737    pd_crit    = 2.0E-9_wp * EXP( -1.6524245_wp + 0.42316402_wp  * zx +        &
4738                 0.33466487_wp * LOG( zntot ) )
4739!
4740!-- 6) Organic compounds not involved when binary nucleation is assumed
4741    pn_crit_ocnv = 0.0_wp   ! number of organic molecules
4742    pk_sa        = 1.0_wp   ! if = 1, H2SO4 involved in nucleation
4743    pk_ocnv      = 0.0_wp   ! if = 1, organic compounds involved
4744!               
4745!-- Set nucleation rate to collision rate               
4746    IF ( pn_crit_sa < 4.0_wp ) THEN
4747!       
4748!--    Volumes of the colliding objects
4749       zma    = 96.0_wp   ! molar mass of SO4 in g/mol
4750       zmw    = 18.0_wp   ! molar mass of water in g/mol
4751       zxmass = 1.0_wp    ! mass fraction of H2SO4
4752       za = 0.7681724_wp + zxmass * ( 2.1847140_wp + zxmass * (     &
4753            7.1630022_wp + zxmass * ( -44.31447_wp + zxmass * (     &
4754            88.75606 + zxmass * ( -75.73729_wp + zxmass *           &
4755            23.43228_wp ) ) ) ) )
4756       zb = 1.808225E-3_wp + zxmass * ( -