source: palm/trunk/SOURCE/salsa_mod.f90 @ 3524

Last change on this file since 3524 was 3524, checked in by raasch, 3 years ago

unused variables removed, missing working precision added, missing preprocessor directives added, bugfix concerning allocation of t_surf_wall_v in nopointer case, declaration statements rearranged to avoid compile time errors, mpi_abort arguments replaced to avoid compile errors

  • Property svn:keywords set to Id
File size: 510.1 KB
Line 
1!> @file salsa_mod.f90
2!--------------------------------------------------------------------------------!
3! This file is part of PALM-4U.
4!
5! PALM-4U is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM-4U is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2018 Leibniz Universitaet Hannover
18!--------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: salsa_mod.f90 3524 2018-11-14 13:36:44Z raasch $
27! missing comma separator inserted
28!
29! 3483 2018-11-02 14:19:26Z raasch
30! bugfix: directives added to allow compilation without netCDF
31!
32! 3481 2018-11-02 09:14:13Z raasch
33! temporary variable cc introduced to circumvent a possible Intel18 compiler bug
34! related to contiguous/non-contguous pointer/target attributes
35!
36! 3473 2018-10-30 20:50:15Z suehring
37! NetCDF input routine renamed
38!
39! 3467 2018-10-30 19:05:21Z suehring
40! Initial revision
41!
42! 3412 2018-10-24 07:25:57Z monakurppa
43!
44! Authors:
45! --------
46! @author monakurppa
47!
48!
49! Description:
50! ------------
51!> Sectional aerosol module for large scale applications SALSA
52!> (Kokkola et al., 2008, ACP 8, 2469-2483). Solves the aerosol number and mass
53!> concentration as well as chemical composition. Includes aerosol dynamic
54!> processes: nucleation, condensation/evaporation of vapours, coagulation and
55!> deposition on tree leaves, ground and roofs.
56!> Implementation is based on formulations implemented in UCLALES-SALSA except
57!> for deposition which is based on parametrisations by Zhang et al. (2001,
58!> Atmos. Environ. 35, 549-560) or Petroff&Zhang (2010, Geosci. Model Dev. 3,
59!> 753-769)
60!>
61!> @todo Implement turbulent inflow of aerosols in inflow_turbulence.
62!> @todo Deposition on walls and horizontal surfaces calculated from the aerosol
63!>       dry radius, not wet
64!> @todo Deposition on subgrid scale vegetation
65!> @todo Deposition on vegetation calculated by default for deciduous broadleaf
66!>       trees
67!> @todo Revise masked data output. There is a potential bug in case of
68!>       terrain-following masked output, according to data_output_mask.
69!> @todo There are now improved interfaces for NetCDF data input which can be
70!>       used instead of get variable etc.
71!------------------------------------------------------------------------------!
72 MODULE salsa_mod
73
74    USE basic_constants_and_equations_mod,                                     &
75        ONLY:  c_p, g, p_0, pi, r_d
76 
77    USE chemistry_model_mod,                                                   &
78        ONLY:  chem_species, nspec, nvar, spc_names
79
80    USE chem_modules,                                                          &
81        ONLY:  call_chem_at_all_substeps, chem_gasphase_on
82
83    USE control_parameters
84       
85    USE indices,                                                               &
86        ONLY:  nbgp, nx, nxl, nxlg, nxr, nxrg, ny, nyn, nyng, nys, nysg, nzb,  &
87               nzb_s_inner, nz, nzt, wall_flags_0
88     
89    USE kinds
90   
91    USE pegrid
92   
93    USE salsa_util_mod
94
95    IMPLICIT NONE
96!
97!-- SALSA constants:
98!
99!-- Local constants:
100    INTEGER(iwp), PARAMETER ::  ngast   = 5 !< total number of gaseous tracers:
101                                            !< 1 = H2SO4, 2 = HNO3, 3 = NH3,
102                                            !< 4 = OCNV (non-volatile OC),
103                                            !< 5 = OCSV (semi-volatile) 
104    INTEGER(iwp), PARAMETER ::  nmod    = 7 !< number of modes for initialising
105                                            !< the aerosol size distribution                                             
106    INTEGER(iwp), PARAMETER ::  nreg    = 2 !< Number of main size subranges
107    INTEGER(iwp), PARAMETER ::  maxspec = 7 !< Max. number of aerosol species
108!   
109!-- Universal constants
110    REAL(wp), PARAMETER ::  abo    = 1.380662E-23_wp  !< Boltzmann constant (J/K)
111    REAL(wp), PARAMETER ::  alv    = 2.260E+6_wp      !< latent heat for H2O
112                                                      !< vaporisation (J/kg)
113    REAL(wp), PARAMETER ::  alv_d_rv  = 4896.96865_wp !< alv / rv
114    REAL(wp), PARAMETER ::  am_airmol = 4.8096E-26_wp !< Average mass of one air
115                                                      !< molecule (Jacobson,
116                                                      !< 2005, Eq. 2.3)                                                   
117    REAL(wp), PARAMETER ::  api6   = 0.5235988_wp     !< pi / 6   
118    REAL(wp), PARAMETER ::  argas  = 8.314409_wp      !< Gas constant (J/(mol K))
119    REAL(wp), PARAMETER ::  argas_d_cpd = 8.281283865E-3_wp !< argas per cpd
120    REAL(wp), PARAMETER ::  avo    = 6.02214E+23_wp   !< Avogadro constant (1/mol)
121    REAL(wp), PARAMETER ::  d_sa   = 5.539376964394570E-10_wp !< diameter of
122                                                      !< condensing sulphuric
123                                                      !< acid molecule (m) 
124    REAL(wp), PARAMETER ::  for_ppm_to_nconc =  7.243016311E+16_wp !<
125                                                 !< ppm * avo / R (K/(Pa*m3))
126    REAL(wp), PARAMETER ::  epsoc  = 0.15_wp          !< water uptake of organic
127                                                      !< material     
128    REAL(wp), PARAMETER ::  mclim  = 1.0E-23_wp    !< mass concentration min
129                                                   !< limit for aerosols (kg/m3)                                                   
130    REAL(wp), PARAMETER ::  n3     = 158.79_wp !< Number of H2SO4 molecules in
131                                               !< 3 nm cluster if d_sa=5.54e-10m
132    REAL(wp), PARAMETER ::  nclim  = 1.0_wp    !< number concentration min limit
133                                               !< for aerosols and gases (#/m3)
134    REAL(wp), PARAMETER ::  surfw0 = 0.073_wp  !< surface tension of pure water
135                                               !< at ~ 293 K (J/m2)   
136    REAL(wp), PARAMETER ::  vclim  = 1.0E-24_wp    !< volume concentration min
137                                                   !< limit for aerosols (m3/m3)                                           
138!-- Molar masses in kg/mol
139    REAL(wp), PARAMETER ::  ambc   = 12.0E-3_wp     !< black carbon (BC)
140    REAL(wp), PARAMETER ::  amdair = 28.970E-3_wp   !< dry air
141    REAL(wp), PARAMETER ::  amdu   = 100.E-3_wp     !< mineral dust
142    REAL(wp), PARAMETER ::  amh2o  = 18.0154E-3_wp  !< H2O
143    REAL(wp), PARAMETER ::  amh2so4  = 98.06E-3_wp  !< H2SO4
144    REAL(wp), PARAMETER ::  amhno3 = 63.01E-3_wp    !< HNO3
145    REAL(wp), PARAMETER ::  amn2o  = 44.013E-3_wp   !< N2O
146    REAL(wp), PARAMETER ::  amnh3  = 17.031E-3_wp   !< NH3
147    REAL(wp), PARAMETER ::  amo2   = 31.9988E-3_wp  !< O2
148    REAL(wp), PARAMETER ::  amo3   = 47.998E-3_wp   !< O3
149    REAL(wp), PARAMETER ::  amoc   = 150.E-3_wp     !< organic carbon (OC)
150    REAL(wp), PARAMETER ::  amss   = 58.44E-3_wp    !< sea salt (NaCl)
151!-- Densities in kg/m3
152    REAL(wp), PARAMETER ::  arhobc     = 2000.0_wp !< black carbon
153    REAL(wp), PARAMETER ::  arhodu     = 2650.0_wp !< mineral dust
154    REAL(wp), PARAMETER ::  arhoh2o    = 1000.0_wp !< H2O
155    REAL(wp), PARAMETER ::  arhoh2so4  = 1830.0_wp !< SO4
156    REAL(wp), PARAMETER ::  arhohno3   = 1479.0_wp !< HNO3
157    REAL(wp), PARAMETER ::  arhonh3    = 1530.0_wp !< NH3
158    REAL(wp), PARAMETER ::  arhooc     = 2000.0_wp !< organic carbon
159    REAL(wp), PARAMETER ::  arhoss     = 2165.0_wp !< sea salt (NaCl)
160!-- Volume of molecule in m3/#
161    REAL(wp), PARAMETER ::  amvh2o   = amh2o /avo / arhoh2o      !< H2O
162    REAL(wp), PARAMETER ::  amvh2so4 = amh2so4 / avo / arhoh2so4 !< SO4
163    REAL(wp), PARAMETER ::  amvhno3  = amhno3 / avo / arhohno3   !< HNO3
164    REAL(wp), PARAMETER ::  amvnh3   = amnh3 / avo / arhonh3     !< NH3 
165    REAL(wp), PARAMETER ::  amvoc    = amoc / avo / arhooc       !< OC
166    REAL(wp), PARAMETER ::  amvss    = amss / avo / arhoss       !< sea salt
167   
168!
169!-- SALSA switches:
170    INTEGER(iwp) ::  nj3 = 1 !< J3 parametrization (nucleation)
171                             !< 1 = condensational sink (Kerminen&Kulmala, 2002)
172                             !< 2 = coagulational sink (Lehtinen et al. 2007)
173                             !< 3 = coagS+self-coagulation (Anttila et al. 2010)                                       
174    INTEGER(iwp) ::  nsnucl = 0 !< Choice of the nucleation scheme:
175                                !< 0 = off   
176                                !< 1 = binary nucleation
177                                !< 2 = activation type nucleation
178                                !< 3 = kinetic nucleation
179                                !< 4 = ternary nucleation
180                                !< 5 = nucleation with ORGANICs
181                                !< 6 = activation type of nucleation with
182                                !<     H2SO4+ORG
183                                !< 7 = heteromolecular nucleation with H2SO4*ORG
184                                !< 8 = homomolecular nucleation of  H2SO4 +
185                                !<     heteromolecular nucleation with H2SO4*ORG
186                                !< 9 = homomolecular nucleation of  H2SO4 and ORG
187                                !<     +heteromolecular nucleation with H2SO4*ORG
188    LOGICAL ::  advect_particle_water = .TRUE.  !< advect water concentration of
189                                                !< particles                               
190    LOGICAL ::  decycle_lr            = .FALSE. !< Undo cyclic boundary
191                                                !< conditions: left and right
192    LOGICAL ::  decycle_ns            = .FALSE. !< north and south boundaries
193    LOGICAL ::  feedback_to_palm      = .FALSE. !< allow feedback due to
194                                                !< hydration and/or condensation
195                                                !< of H20
196    LOGICAL ::  no_insoluble          = .FALSE. !< Switch to exclude insoluble 
197                                                !< chemical components
198    LOGICAL ::  read_restart_data_salsa = .FALSE. !< read restart data for salsa
199    LOGICAL ::  salsa                 = .FALSE.   !< SALSA master switch
200    LOGICAL ::  salsa_gases_from_chem = .FALSE.   !< Transfer the gaseous
201                                                  !< components to SALSA from 
202                                                  !< from chemistry model
203    LOGICAL ::  van_der_waals_coagc   = .FALSE.   !< Enhancement of coagulation
204                                                  !< kernel by van der Waals and
205                                                  !< viscous forces
206    LOGICAL ::  write_binary_salsa    = .FALSE.   !< read binary for salsa
207!-- Process switches: nl* is read from the NAMELIST and is NOT changed.
208!--                   ls* is the switch used and will get the value of nl*
209!--                       except for special circumstances (spinup period etc.)
210    LOGICAL ::  nlcoag       = .FALSE. !< Coagulation master switch
211    LOGICAL ::  lscoag       = .FALSE. !<
212    LOGICAL ::  nlcnd        = .FALSE. !< Condensation master switch
213    LOGICAL ::  lscnd        = .FALSE. !<
214    LOGICAL ::  nlcndgas     = .FALSE. !< Condensation of precursor gases
215    LOGICAL ::  lscndgas     = .FALSE. !<
216    LOGICAL ::  nlcndh2oae   = .FALSE. !< Condensation of H2O on aerosol
217    LOGICAL ::  lscndh2oae   = .FALSE. !< particles (FALSE -> equilibrium calc.)
218    LOGICAL ::  nldepo       = .FALSE. !< Deposition master switch
219    LOGICAL ::  lsdepo       = .FALSE. !<
220    LOGICAL ::  nldepo_topo  = .FALSE. !< Deposition on vegetation master switch
221    LOGICAL ::  lsdepo_topo  = .FALSE. !<
222    LOGICAL ::  nldepo_vege  = .FALSE. !< Deposition on walls master switch
223    LOGICAL ::  lsdepo_vege  = .FALSE. !<
224    LOGICAL ::  nldistupdate = .TRUE.  !< Size distribution update master switch                                     
225    LOGICAL ::  lsdistupdate = .FALSE. !<                                     
226!
227!-- SALSA variables:
228    CHARACTER (LEN=20) ::  bc_salsa_b = 'neumann'   !< bottom boundary condition                                     
229    CHARACTER (LEN=20) ::  bc_salsa_t = 'neumann'   !< top boundary condition
230    CHARACTER (LEN=20) ::  depo_vege_type = 'zhang2001' !< or 'petroff2010'
231    CHARACTER (LEN=20) ::  depo_topo_type = 'zhang2001' !< or 'petroff2010'
232    CHARACTER (LEN=20), DIMENSION(4) ::  decycle_method = & 
233                             (/'dirichlet','dirichlet','dirichlet','dirichlet'/)
234                                 !< Decycling method at horizontal boundaries,
235                                 !< 1=left, 2=right, 3=south, 4=north
236                                 !< dirichlet = initial size distribution and
237                                 !< chemical composition set for the ghost and
238                                 !< first three layers
239                                 !< neumann = zero gradient
240    CHARACTER (LEN=3), DIMENSION(maxspec) ::  listspec = &  !< Active aerosols
241                                   (/'SO4','   ','   ','   ','   ','   ','   '/)
242    CHARACTER (LEN=20) ::  salsa_source_mode = 'no_source' 
243                                                    !< 'read_from_file',
244                                                    !< 'constant' or 'no_source'                                   
245    INTEGER(iwp) ::  dots_salsa = 0  !< starting index for salsa-timeseries
246    INTEGER(iwp) ::  fn1a = 1    !< last index for bin subranges:  subrange 1a
247    INTEGER(iwp) ::  fn2a = 1    !<                              subrange 2a
248    INTEGER(iwp) ::  fn2b = 1    !<                              subrange 2b
249    INTEGER(iwp), DIMENSION(ngast) ::  gas_index_chem = (/ 1, 1, 1, 1, 1/) !<
250                                 !< Index of gaseous compounds in the chemistry
251                                 !< model. In SALSA, 1 = H2SO4, 2 = HNO3,
252                                 !< 3 = NH3, 4 = OCNV, 5 = OCSV
253    INTEGER(iwp) ::  ibc_salsa_b !<
254    INTEGER(iwp) ::  ibc_salsa_t !<
255    INTEGER(iwp) ::  igctyp = 0  !< Initial gas concentration type
256                                 !< 0 = uniform (use H2SO4_init, HNO3_init,
257                                 !<     NH3_init, OCNV_init and OCSV_init)
258                                 !< 1 = read vertical profile from an input file 
259    INTEGER(iwp) ::  in1a = 1    !< start index for bin subranges: subrange 1a
260    INTEGER(iwp) ::  in2a = 1    !<                              subrange 2a
261    INTEGER(iwp) ::  in2b = 1    !<                              subrange 2b
262    INTEGER(iwp) ::  isdtyp = 0  !< Initial size distribution type
263                                 !< 0 = uniform
264                                 !< 1 = read vertical profile of the mode number
265                                 !<     concentration from an input file 
266    INTEGER(iwp) ::  ibc  = -1 !< Indice for: black carbon (BC)
267    INTEGER(iwp) ::  idu  = -1 !< dust
268    INTEGER(iwp) ::  inh  = -1 !< NH3
269    INTEGER(iwp) ::  ino  = -1 !< HNO3   
270    INTEGER(iwp) ::  ioc  = -1 !< organic carbon (OC)
271    INTEGER(iwp) ::  iso4 = -1 !< SO4 or H2SO4   
272    INTEGER(iwp) ::  iss  = -1 !< sea salt
273    INTEGER(iwp) ::  lod_aero = 0   !< level of detail for aerosol emissions
274    INTEGER(iwp) ::  lod_gases = 0  !< level of detail for gaseous emissions   
275    INTEGER(iwp), DIMENSION(nreg) ::  nbin = (/ 3, 7/)    !< Number of size bins
276                                               !< for each aerosol size subrange
277    INTEGER(iwp) ::  nbins = 1  !< total number of size bins
278    INTEGER(iwp) ::  ncc   = 1  !< number of chemical components used     
279    INTEGER(iwp) ::  ncc_tot = 1!< total number of chemical compounds (ncc+1
280                                !< if particle water is advected)
281    REAL(wp) ::  act_coeff = 1.0E-7_wp     !< Activation coefficient
282    REAL(wp) ::  aerosol_source = 0.0_wp   !< Constant aerosol flux (#/(m3*s))
283    REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::  emission_mass_fracs  !< array for
284                                    !< aerosol composition per emission category
285                                    !< 1:SO4 2:OC 3:BC 4:DU 5:SS 6:NO 7:NH 
286    REAL(wp) ::  dt_salsa  = 0.00001_wp    !< Time step of SALSA
287    REAL(wp) ::  H2SO4_init = nclim        !< Init value for sulphuric acid gas
288    REAL(wp) ::  HNO3_init  = nclim        !< Init value for nitric acid gas
289    REAL(wp) ::  last_salsa_time = 0.0_wp  !< time of the previous salsa
290                                           !< timestep
291    REAL(wp) ::  nf2a = 1.0_wp             !< Number fraction allocated to a-
292                                           !< bins in subrange 2
293                                           !< (b-bins will get 1-nf2a)   
294    REAL(wp) ::  NH3_init  = nclim         !< Init value for ammonia gas
295    REAL(wp) ::  OCNV_init = nclim         !< Init value for non-volatile
296                                           !< organic gases
297    REAL(wp) ::  OCSV_init = nclim         !< Init value for semi-volatile
298                                           !< organic gases
299    REAL(wp), DIMENSION(nreg+1) ::  reglim = & !< Min&max diameters of size subranges
300                                 (/ 3.0E-9_wp, 5.0E-8_wp, 1.0E-5_wp/)
301    REAL(wp) ::  rhlim = 1.20_wp    !< RH limit in %/100. Prevents
302                                    !< unrealistically high RH in condensation                           
303    REAL(wp) ::  skip_time_do_salsa = 0.0_wp !< Starting time of SALSA (s)
304!-- Initial log-normal size distribution: mode diameter (dpg, micrometres),
305!-- standard deviation (sigmag) and concentration (n_lognorm, #/cm3)
306    REAL(wp), DIMENSION(nmod) ::  dpg   = (/0.013_wp, 0.054_wp, 0.86_wp,       &
307                                            0.2_wp, 0.2_wp, 0.2_wp, 0.2_wp/) 
308    REAL(wp), DIMENSION(nmod) ::  sigmag  = (/1.8_wp, 2.16_wp, 2.21_wp,        &
309                                              2.0_wp, 2.0_wp, 2.0_wp, 2.0_wp/) 
310    REAL(wp), DIMENSION(nmod) ::  n_lognorm = (/1.04e+5_wp, 3.23E+4_wp, 5.4_wp,&
311                                                0.0_wp, 0.0_wp, 0.0_wp, 0.0_wp/)
312!-- Initial mass fractions / chemical composition of the size distribution   
313    REAL(wp), DIMENSION(maxspec) ::  mass_fracs_a = & !< mass fractions between
314             (/1.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0/) !< aerosol species for A bins
315    REAL(wp), DIMENSION(maxspec) ::  mass_fracs_b = & !< mass fractions between
316             (/0.0, 0.0, 0.0, 0.0, 0.0, 0.0, 0.0/) !< aerosol species for B bins
317             
318    REAL(wp), ALLOCATABLE, DIMENSION(:) ::  bin_low_limits  !< to deliver
319                                                            !< information about
320                                                            !< the lower
321                                                            !< diameters per bin                                       
322    REAL(wp), ALLOCATABLE, DIMENSION(:) ::  nsect     !< Background number
323                                                      !< concentration per bin
324    REAL(wp), ALLOCATABLE, DIMENSION(:) ::  massacc   !< Mass accomodation
325                                                      !< coefficients per bin                                             
326!
327!-- SALSA derived datatypes:
328!
329!-- Prognostic variable: Aerosol size bin information (number (#/m3) and
330!-- mass (kg/m3) concentration) and the concentration of gaseous tracers (#/m3).
331!-- Gas tracers are contained sequentially in dimension 4 as:
332!-- 1. H2SO4, 2. HNO3, 3. NH3, 4. OCNV (non-volatile organics),
333!-- 5. OCSV (semi-volatile)
334    TYPE salsa_variable
335       REAL(wp), POINTER, DIMENSION(:,:,:), CONTIGUOUS     ::  conc
336       REAL(wp), POINTER, DIMENSION(:,:,:), CONTIGUOUS     ::  conc_p
337       REAL(wp), POINTER, DIMENSION(:,:,:), CONTIGUOUS     ::  tconc_m
338       REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  flux_s, diss_s
339       REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  flux_l, diss_l
340       REAL(wp), ALLOCATABLE, DIMENSION(:)     ::  init
341       REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  source
342       REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::  sums_ws_l
343    END TYPE salsa_variable
344   
345!-- Map bin indices between parallel size distributions   
346    TYPE t_parallelbin
347       INTEGER(iwp) ::  cur  ! Index for current distribution
348       INTEGER(iwp) ::  par  ! Index for corresponding parallel distribution
349    END TYPE t_parallelbin
350   
351!-- Datatype used to store information about the binned size distributions of
352!-- aerosols
353    TYPE t_section
354       REAL(wp) ::  vhilim   !< bin volume at the high limit
355       REAL(wp) ::  vlolim   !< bin volume at the low limit
356       REAL(wp) ::  vratiohi !< volume ratio between the center and high limit
357       REAL(wp) ::  vratiolo !< volume ratio between the center and low limit
358       REAL(wp) ::  dmid     !< bin middle diameter (m)
359       !******************************************************
360       ! ^ Do NOT change the stuff above after initialization !
361       !******************************************************
362       REAL(wp) ::  dwet    !< Wet diameter or mean droplet diameter (m)
363       REAL(wp), DIMENSION(maxspec+1) ::  volc !< Volume concentrations
364                            !< (m^3/m^3) of aerosols + water. Since most of
365                            !< the stuff in SALSA is hard coded, these *have to
366                            !< be* in the order
367                            !< 1:SO4, 2:OC, 3:BC, 4:DU, 5:SS, 6:NO, 7:NH, 8:H2O
368       REAL(wp) ::  veqh2o  !< Equilibrium H2O concentration for each particle
369       REAL(wp) ::  numc    !< Number concentration of particles/droplets (#/m3)
370       REAL(wp) ::  core    !< Volume of dry particle
371    END TYPE t_section 
372!
373!-- Local aerosol properties in SALSA
374    TYPE(t_section), ALLOCATABLE ::  aero(:)
375!
376!-- SALSA tracers:
377!-- Tracers as x = x(k,j,i,bin). The 4th dimension contains all the size bins
378!-- sequentially for each aerosol species  + water.
379!
380!-- Prognostic tracers:
381!
382!-- Number concentration (#/m3)
383    TYPE(salsa_variable), ALLOCATABLE, DIMENSION(:), TARGET ::  aerosol_number
384    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  nconc_1
385    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  nconc_2
386    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  nconc_3
387!
388!-- Mass concentration (kg/m3)
389    TYPE(salsa_variable), ALLOCATABLE, DIMENSION(:), TARGET ::  aerosol_mass
390    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  mconc_1
391    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  mconc_2
392    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  mconc_3
393!
394!-- Gaseous tracers (#/m3)
395    TYPE(salsa_variable), ALLOCATABLE, DIMENSION(:), TARGET ::  salsa_gas
396    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  gconc_1
397    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  gconc_2
398    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:), TARGET ::  gconc_3
399!
400!-- Diagnostic tracers
401    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::  sedim_vd !< sedimentation
402                                                           !< velocity per size
403                                                           !< bin (m/s)
404    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::  Ra_dry !< dry radius (m)
405   
406!-- Particle component index tables
407    TYPE(component_index) :: prtcl !< Contains "getIndex" which gives the index
408                                   !< for a given aerosol component name, i.e.
409                                   !< 1:SO4, 2:OC, 3:BC, 4:DU,
410                                   !< 5:SS, 6:NO, 7:NH, 8:H2O 
411!                                   
412!-- Data output arrays:
413!-- Gases:
414    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  g_H2SO4_av  !< H2SO4
415    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  g_HNO3_av   !< HNO3
416    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  g_NH3_av    !< NH3
417    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  g_OCNV_av   !< non-vola-
418                                                                    !< tile OC
419    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  g_OCSV_av   !< semi-vol.
420                                                                    !< OC
421!-- Integrated:                                                                   
422    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  LDSA_av  !< lung deposited
423                                                         !< surface area                                                   
424    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  Ntot_av  !< total number conc.
425    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  PM25_av  !< PM2.5
426    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  PM10_av  !< PM10
427!-- In the particle phase:   
428    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  s_BC_av  !< black carbon
429    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  s_DU_av  !< dust
430    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  s_H2O_av !< liquid water
431    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  s_NH_av  !< ammonia
432    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  s_NO_av  !< nitrates
433    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  s_OC_av  !< org. carbon
434    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  s_SO4_av !< sulphates
435    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:), TARGET ::  s_SS_av  !< sea salt
436!-- Bins:   
437    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::  mbins_av  !< bin mass
438                                                            !< concentration
439    REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::  Nbins_av  !< bin number
440                                                            !< concentration 
441       
442!
443!-- PALM interfaces:
444!
445!-- Boundary conditions:
446    INTERFACE salsa_boundary_conds
447       MODULE PROCEDURE salsa_boundary_conds
448       MODULE PROCEDURE salsa_boundary_conds_decycle
449    END INTERFACE salsa_boundary_conds
450!   
451!-- Data output checks for 2D/3D data to be done in check_parameters
452    INTERFACE salsa_check_data_output
453       MODULE PROCEDURE salsa_check_data_output
454    END INTERFACE salsa_check_data_output
455   
456!
457!-- Input parameter checks to be done in check_parameters
458    INTERFACE salsa_check_parameters
459       MODULE PROCEDURE salsa_check_parameters
460    END INTERFACE salsa_check_parameters
461
462!
463!-- Averaging of 3D data for output
464    INTERFACE salsa_3d_data_averaging
465       MODULE PROCEDURE salsa_3d_data_averaging
466    END INTERFACE salsa_3d_data_averaging
467
468!
469!-- Data output of 2D quantities
470    INTERFACE salsa_data_output_2d
471       MODULE PROCEDURE salsa_data_output_2d
472    END INTERFACE salsa_data_output_2d
473
474!
475!-- Data output of 3D data
476    INTERFACE salsa_data_output_3d
477       MODULE PROCEDURE salsa_data_output_3d
478    END INTERFACE salsa_data_output_3d
479   
480!
481!-- Data output of 3D data
482    INTERFACE salsa_data_output_mask
483       MODULE PROCEDURE salsa_data_output_mask
484    END INTERFACE salsa_data_output_mask
485
486!
487!-- Definition of data output quantities
488    INTERFACE salsa_define_netcdf_grid
489       MODULE PROCEDURE salsa_define_netcdf_grid
490    END INTERFACE salsa_define_netcdf_grid
491   
492!
493!-- Output of information to the header file
494    INTERFACE salsa_header
495       MODULE PROCEDURE salsa_header
496    END INTERFACE salsa_header
497 
498!
499!-- Initialization actions 
500    INTERFACE salsa_init
501       MODULE PROCEDURE salsa_init
502    END INTERFACE salsa_init
503 
504!
505!-- Initialization of arrays
506    INTERFACE salsa_init_arrays
507       MODULE PROCEDURE salsa_init_arrays
508    END INTERFACE salsa_init_arrays
509
510!
511!-- Writing of binary output for restart runs  !!! renaming?!
512    INTERFACE salsa_wrd_local
513       MODULE PROCEDURE salsa_wrd_local
514    END INTERFACE salsa_wrd_local
515   
516!
517!-- Reading of NAMELIST parameters
518    INTERFACE salsa_parin
519       MODULE PROCEDURE salsa_parin
520    END INTERFACE salsa_parin
521
522!
523!-- Reading of parameters for restart runs
524    INTERFACE salsa_rrd_local
525       MODULE PROCEDURE salsa_rrd_local
526    END INTERFACE salsa_rrd_local
527   
528!
529!-- Swapping of time levels (required for prognostic variables)
530    INTERFACE salsa_swap_timelevel
531       MODULE PROCEDURE salsa_swap_timelevel
532    END INTERFACE salsa_swap_timelevel
533
534    INTERFACE salsa_driver
535       MODULE PROCEDURE salsa_driver
536    END INTERFACE salsa_driver
537
538    INTERFACE salsa_tendency
539       MODULE PROCEDURE salsa_tendency
540       MODULE PROCEDURE salsa_tendency_ij
541    END INTERFACE salsa_tendency
542   
543   
544   
545    SAVE
546
547    PRIVATE
548!
549!-- Public functions:
550    PUBLIC salsa_boundary_conds, salsa_check_data_output,                      &
551           salsa_check_parameters, salsa_3d_data_averaging,                    &
552           salsa_data_output_2d, salsa_data_output_3d, salsa_data_output_mask, &
553           salsa_define_netcdf_grid, salsa_diagnostics, salsa_driver,          &
554           salsa_header, salsa_init, salsa_init_arrays, salsa_parin,           &
555           salsa_rrd_local, salsa_swap_timelevel, salsa_tendency,              &
556           salsa_wrd_local
557!
558!-- Public parameters, constants and initial values
559    PUBLIC dots_salsa, dt_salsa, last_salsa_time, lsdepo, salsa,               &
560           salsa_gases_from_chem, skip_time_do_salsa
561!
562!-- Public prognostic variables
563    PUBLIC aerosol_mass, aerosol_number, fn2a, fn2b, gconc_2, in1a, in2b,      &
564           mconc_2, nbins, ncc, ncc_tot, nclim, nconc_2, ngast, prtcl, Ra_dry, &
565           salsa_gas, sedim_vd
566
567 CONTAINS
568
569!------------------------------------------------------------------------------!
570! Description:
571! ------------
572!> Parin for &salsa_par for new modules
573!------------------------------------------------------------------------------!
574 SUBROUTINE salsa_parin
575
576    IMPLICIT NONE
577
578    CHARACTER (LEN=80) ::  line   !< dummy string that contains the current line
579                                  !< of the parameter file
580                                 
581    NAMELIST /salsa_parameters/             &
582                          advect_particle_water, & ! Switch for advecting
583                                                ! particle water. If .FALSE.,
584                                                ! equilibration is called at
585                                                ! each time step.       
586                          bc_salsa_b,       &   ! bottom boundary condition
587                          bc_salsa_t,       &   ! top boundary condition
588                          decycle_lr,       &   ! decycle SALSA components
589                          decycle_method,   &   ! decycle method applied:
590                                                ! 1=left 2=right 3=south 4=north
591                          decycle_ns,       &   ! decycle SALSA components
592                          depo_vege_type,   &   ! Parametrisation type
593                          depo_topo_type,   &   ! Parametrisation type
594                          dpg,              &   ! Mean diameter for the initial
595                                                ! log-normal modes
596                          dt_salsa,         &   ! SALSA timestep in seconds
597                          feedback_to_palm, &   ! allow feedback due to
598                                                ! hydration / condensation
599                          H2SO4_init,       &   ! Init value for sulphuric acid
600                          HNO3_init,        &   ! Init value for nitric acid
601                          igctyp,           &   ! Initial gas concentration type
602                          isdtyp,           &   ! Initial size distribution type                                               
603                          listspec,         &   ! List of actived aerosols
604                                                ! (string list)
605                          mass_fracs_a,     &   ! Initial relative contribution 
606                                                ! of each species to particle 
607                                                ! volume in a-bins, 0 for unused
608                          mass_fracs_b,     &   ! Initial relative contribution 
609                                                ! of each species to particle
610                                                ! volume in b-bins, 0 for unused
611                          n_lognorm,        &   ! Number concentration for the
612                                                ! log-normal modes                                               
613                          nbin,             &   ! Number of size bins for
614                                                ! aerosol size subranges 1 & 2
615                          nf2a,             &   ! Number fraction of particles
616                                                ! allocated to a-bins in
617                                                ! subrange 2 b-bins will get
618                                                ! 1-nf2a                         
619                          NH3_init,         &   ! Init value for ammonia
620                          nj3,              &   ! J3 parametrization
621                                                ! 1 = condensational sink
622                                                !     (Kerminen&Kulmala, 2002)
623                                                ! 2 = coagulational sink
624                                                !     (Lehtinen et al. 2007)
625                                                ! 3 = coagS+self-coagulation
626                                                !     (Anttila et al. 2010)                                                   
627                          nlcnd,            &   ! Condensation master switch
628                          nlcndgas,         &   ! Condensation of gases
629                          nlcndh2oae,       &   ! Condensation of H2O                           
630                          nlcoag,           &   ! Coagulation master switch
631                          nldepo,           &   ! Deposition master switch
632                          nldepo_vege,      &   ! Deposition on vegetation
633                                                ! master switch
634                          nldepo_topo,      &   ! Deposition on topo master
635                                                ! switch                         
636                          nldistupdate,     &   ! Size distribution update
637                                                ! master switch
638                          nsnucl,           &   ! Nucleation scheme:
639                                                ! 0 = off,
640                                                ! 1 = binary nucleation
641                                                ! 2 = activation type nucleation
642                                                ! 3 = kinetic nucleation
643                                                ! 4 = ternary nucleation
644                                                ! 5 = nucleation with organics
645                                                ! 6 = activation type of
646                                                !     nucleation with H2SO4+ORG
647                                                ! 7 = heteromolecular nucleation
648                                                !     with H2SO4*ORG
649                                                ! 8 = homomolecular nucleation 
650                                                !     of H2SO4 + heteromolecular
651                                                !     nucleation with H2SO4*ORG
652                                                ! 9 = homomolecular nucleation
653                                                !     of H2SO4 and ORG + hetero-
654                                                !     molecular nucleation with
655                                                !     H2SO4*ORG
656                          OCNV_init,        &   ! Init value for non-volatile
657                                                ! organic gases
658                          OCSV_init,        &   ! Init value for semi-volatile
659                                                ! organic gases
660                          read_restart_data_salsa, & ! read restart data for
661                                                     ! salsa
662                          reglim,           &   ! Min&max diameter limits of
663                                                ! size subranges
664                          salsa,            &   ! Master switch for SALSA
665                          salsa_source_mode,&   ! 'read_from_file' or 'constant'
666                                                ! or 'no_source'
667                          sigmag,           &   ! stdev for the initial log-
668                                                ! normal modes                                               
669                          skip_time_do_salsa, & ! Starting time of SALSA (s)
670                          van_der_waals_coagc,& ! include van der Waals forces
671                          write_binary_salsa    ! Write binary for salsa
672                           
673       
674    line = ' '
675       
676!
677!-- Try to find salsa package
678    REWIND ( 11 )
679    line = ' '
680    DO WHILE ( INDEX( line, '&salsa_parameters' ) == 0 )
681       READ ( 11, '(A)', END=10 )  line
682    ENDDO
683    BACKSPACE ( 11 )
684
685!
686!-- Read user-defined namelist
687    READ ( 11, salsa_parameters )
688
689!
690!-- Set flag that indicates that the new module is switched on
691!-- Note that this parameter needs to be declared in modules.f90
692    salsa = .TRUE.
693
694 10 CONTINUE
695       
696 END SUBROUTINE salsa_parin
697
698 
699!------------------------------------------------------------------------------!
700! Description:
701! ------------
702!> Check parameters routine for salsa.
703!------------------------------------------------------------------------------!
704 SUBROUTINE salsa_check_parameters
705
706    USE control_parameters,                                                    &
707        ONLY:  message_string
708       
709    IMPLICIT NONE
710   
711!
712!-- Checks go here (cf. check_parameters.f90).
713    IF ( salsa  .AND.  .NOT.  humidity )  THEN
714       WRITE( message_string, * ) 'salsa = ', salsa, ' is ',                   &
715              'not allowed with humidity = ', humidity
716       CALL message( 'check_parameters', 'SA0009', 1, 2, 0, 6, 0 )
717    ENDIF
718   
719    IF ( bc_salsa_b == 'dirichlet' )  THEN
720       ibc_salsa_b = 0
721    ELSEIF ( bc_salsa_b == 'neumann' )  THEN
722       ibc_salsa_b = 1
723    ELSE
724       message_string = 'unknown boundary condition: bc_salsa_b = "'           &
725                         // TRIM( bc_salsa_t ) // '"'
726       CALL message( 'check_parameters', 'SA0011', 1, 2, 0, 6, 0 )                 
727    ENDIF
728   
729    IF ( bc_salsa_t == 'dirichlet' )  THEN
730       ibc_salsa_t = 0
731    ELSEIF ( bc_salsa_t == 'neumann' )  THEN
732       ibc_salsa_t = 1
733    ELSE
734       message_string = 'unknown boundary condition: bc_salsa_t = "'           &
735                         // TRIM( bc_salsa_t ) // '"'
736       CALL message( 'check_parameters', 'SA0012', 1, 2, 0, 6, 0 )                 
737    ENDIF
738   
739    IF ( nj3 < 1  .OR.  nj3 > 3 )  THEN
740       message_string = 'unknown nj3 (must be 1-3)'
741       CALL message( 'check_parameters', 'SA0044', 1, 2, 0, 6, 0 )
742    ENDIF
743           
744 END SUBROUTINE salsa_check_parameters
745
746!------------------------------------------------------------------------------!
747!
748! Description:
749! ------------
750!> Subroutine defining appropriate grid for netcdf variables.
751!> It is called out from subroutine netcdf.
752!> Same grid as for other scalars (see netcdf_interface_mod.f90)
753!------------------------------------------------------------------------------!
754 SUBROUTINE salsa_define_netcdf_grid( var, found, grid_x, grid_y, grid_z )
755   
756    IMPLICIT NONE
757
758    CHARACTER (LEN=*), INTENT(OUT) ::  grid_x   !<
759    CHARACTER (LEN=*), INTENT(OUT) ::  grid_y   !<
760    CHARACTER (LEN=*), INTENT(OUT) ::  grid_z   !<
761    CHARACTER (LEN=*), INTENT(IN)  ::  var      !<
762   
763    LOGICAL, INTENT(OUT) ::  found   !<
764   
765    found  = .TRUE.
766!
767!-- Check for the grid
768
769    IF ( var(1:2) == 'g_' )  THEN
770       grid_x = 'x' 
771       grid_y = 'y' 
772       grid_z = 'zu'   
773    ELSEIF ( var(1:4) == 'LDSA' )  THEN
774       grid_x = 'x' 
775       grid_y = 'y' 
776       grid_z = 'zu'
777    ELSEIF ( var(1:5) == 'm_bin' )  THEN
778       grid_x = 'x' 
779       grid_y = 'y' 
780       grid_z = 'zu'
781    ELSEIF ( var(1:5) == 'N_bin' )  THEN
782       grid_x = 'x' 
783       grid_y = 'y' 
784       grid_z = 'zu'
785    ELSEIF ( var(1:4) == 'Ntot' ) THEN
786       grid_x = 'x' 
787       grid_y = 'y' 
788       grid_z = 'zu'
789    ELSEIF ( var(1:2) == 'PM' )  THEN
790       grid_x = 'x' 
791       grid_y = 'y' 
792       grid_z = 'zu'
793    ELSEIF ( var(1:2) == 's_' )  THEN
794       grid_x = 'x' 
795       grid_y = 'y' 
796       grid_z = 'zu'
797    ELSE
798       found  = .FALSE.
799       grid_x = 'none'
800       grid_y = 'none'
801       grid_z = 'none'
802    ENDIF
803
804 END SUBROUTINE salsa_define_netcdf_grid
805
806 
807!------------------------------------------------------------------------------!
808! Description:
809! ------------
810!> Header output for new module
811!------------------------------------------------------------------------------!
812 SUBROUTINE salsa_header( io )
813
814    IMPLICIT NONE
815 
816    INTEGER(iwp), INTENT(IN) ::  io   !< Unit of the output file
817!
818!-- Write SALSA header
819    WRITE( io, 1 )
820    WRITE( io, 2 ) skip_time_do_salsa
821    WRITE( io, 3 ) dt_salsa
822    WRITE( io, 12 )  SHAPE( aerosol_number(1)%conc ), nbins
823    IF ( advect_particle_water )  THEN
824       WRITE( io, 16 )  SHAPE( aerosol_mass(1)%conc ), ncc_tot*nbins,          &
825                        advect_particle_water
826    ELSE
827       WRITE( io, 16 )  SHAPE( aerosol_mass(1)%conc ), ncc*nbins,              &
828                        advect_particle_water
829    ENDIF
830    IF ( .NOT. salsa_gases_from_chem )  THEN
831       WRITE( io, 17 )  SHAPE( aerosol_mass(1)%conc ), ngast,                  &
832                        salsa_gases_from_chem
833    ENDIF
834    WRITE( io, 4 ) 
835    IF ( nsnucl > 0 )  THEN
836       WRITE( io, 5 ) nsnucl, nj3
837    ENDIF
838    IF ( nlcoag )  THEN
839       WRITE( io, 6 ) 
840    ENDIF
841    IF ( nlcnd )  THEN
842       WRITE( io, 7 ) nlcndgas, nlcndh2oae
843    ENDIF
844    IF ( nldepo )  THEN
845       WRITE( io, 14 ) nldepo_vege, nldepo_topo
846    ENDIF
847    WRITE( io, 8 )  reglim, nbin, bin_low_limits
848    WRITE( io, 15 ) nsect
849    WRITE( io, 13 ) ncc, listspec, mass_fracs_a, mass_fracs_b
850    IF ( .NOT. salsa_gases_from_chem )  THEN
851       WRITE( io, 18 ) ngast, H2SO4_init, HNO3_init, NH3_init, OCNV_init,      &
852                       OCSV_init
853    ENDIF
854    WRITE( io, 9 )  isdtyp, igctyp
855    IF ( isdtyp == 0 )  THEN
856       WRITE( io, 10 )  dpg, sigmag, n_lognorm
857    ELSE
858       WRITE( io, 11 )
859    ENDIF
860   
861
8621   FORMAT (//' SALSA information:'/                                           &
863              ' ------------------------------'/)
8642   FORMAT   ('    Starts at: skip_time_do_salsa = ', F10.2, '  s')
8653   FORMAT  (/'    Timestep: dt_salsa = ', F6.2, '  s')
86612  FORMAT  (/'    Array shape (z,y,x,bins):'/                                 &
867              '       aerosol_number:  ', 4(I3)) 
86816  FORMAT  (/'       aerosol_mass:    ', 4(I3),/                              &
869              '       (advect_particle_water = ', L1, ')')
87017  FORMAT   ('       salsa_gas: ', 4(I3),/                                    &
871              '       (salsa_gases_from_chem = ', L1, ')')
8724   FORMAT  (/'    Aerosol dynamic processes included: ')
8735   FORMAT  (/'       nucleation (scheme = ', I1, ' and J3 parametrization = ',&
874               I1, ')')
8756   FORMAT  (/'       coagulation')
8767   FORMAT  (/'       condensation (of precursor gases = ', L1,                &
877              '          and water vapour = ', L1, ')' )
87814  FORMAT  (/'       dry deposition (on vegetation = ', L1,                   &
879              '          and on topography = ', L1, ')')             
8808   FORMAT  (/'    Aerosol bin subrange limits (in metres): ',  3(ES10.2E3), / &
881              '    Number of size bins for each aerosol subrange: ', 2I3,/     &
882              '    Aerosol bin limits (in metres): ', *(ES10.2E3))
88315  FORMAT   ('    Initial number concentration in bins at the lowest level',  &
884              ' (#/m**3):', *(ES10.2E3))       
88513  FORMAT  (/'    Number of chemical components used: ', I1,/                 &
886              '       Species: ',7(A6),/                                       &
887              '    Initial relative contribution of each species to particle', & 
888              ' volume in:',/                                                  &
889              '       a-bins: ', 7(F6.3),/                                     &
890              '       b-bins: ', 7(F6.3))
89118  FORMAT  (/'    Number of gaseous tracers used: ', I1,/                     &
892              '    Initial gas concentrations:',/                              &
893              '       H2SO4: ',ES12.4E3, ' #/m**3',/                           &
894              '       HNO3:  ',ES12.4E3, ' #/m**3',/                           &
895              '       NH3:   ',ES12.4E3, ' #/m**3',/                           &
896              '       OCNV:  ',ES12.4E3, ' #/m**3',/                           &
897              '       OCSV:  ',ES12.4E3, ' #/m**3')
8989    FORMAT (/'   Initialising concentrations: ', /                            &
899              '      Aerosol size distribution: isdtyp = ', I1,/               &
900              '      Gas concentrations: igctyp = ', I1 )
90110   FORMAT ( '      Mode diametres: dpg(nmod) = ', 7(F7.3),/                  &
902              '      Standard deviation: sigmag(nmod) = ', 7(F7.2),/           &
903              '      Number concentration: n_lognorm(nmod) = ', 7(ES12.4E3) )
90411   FORMAT (/'      Size distribution read from a file.')
905
906 END SUBROUTINE salsa_header
907
908!------------------------------------------------------------------------------!
909! Description:
910! ------------
911!> Allocate SALSA arrays and define pointers if required
912!------------------------------------------------------------------------------!
913 SUBROUTINE salsa_init_arrays
914 
915    USE surface_mod,                                                           &
916        ONLY:  surf_def_h, surf_def_v, surf_lsm_h, surf_lsm_v, surf_usm_h,     &
917               surf_usm_v
918
919    IMPLICIT NONE
920   
921    INTEGER(iwp) ::  gases_available !< Number of available gas components in
922                                     !< the chemistry model
923    INTEGER(iwp) ::  i   !< loop index for allocating
924    INTEGER(iwp) ::  l   !< loop index for allocating: surfaces
925    INTEGER(iwp) ::  lsp !< loop index for chem species in the chemistry model
926   
927    gases_available = 0
928
929!
930!-- Allocate prognostic variables (see salsa_swap_timelevel)
931#if defined( __nopointer )
932    message_string = 'SALSA runs only with POINTER Version'
933    CALL message( 'salsa_mod: salsa_init_arrays', 'SA0023', 1, 2, 0, 6, 0 )
934#else         
935!
936!-- Set derived indices:
937!-- (This does the same as the subroutine salsa_initialize in SALSA/
938!-- UCLALES-SALSA)       
939    in1a = 1                ! 1st index of subrange 1a
940    in2a = in1a + nbin(1)   ! 1st index of subrange 2a
941    fn1a = in2a - 1         ! last index of subrange 1a
942    fn2a = fn1a + nbin(2)   ! last index of subrange 2a
943   
944!   
945!-- If the fraction of insoluble aerosols in subrange 2 is zero: do not allocate
946!-- arrays for them
947    IF ( nf2a > 0.999999_wp  .AND.  SUM( mass_fracs_b ) < 0.00001_wp )  THEN
948       no_insoluble = .TRUE.
949       in2b = fn2a+1    ! 1st index of subrange 2b
950       fn2b = fn2a      ! last index of subrange 2b
951    ELSE
952       in2b = in2a + nbin(2)   ! 1st index of subrange 2b
953       fn2b = fn2a + nbin(2)   ! last index of subrange 2b
954    ENDIF
955   
956   
957    nbins = fn2b   ! total number of aerosol size bins
958!   
959!-- Create index tables for different aerosol components
960    CALL component_index_constructor( prtcl, ncc, maxspec, listspec )
961   
962    ncc_tot = ncc
963    IF ( advect_particle_water )  ncc_tot = ncc + 1  ! Add water
964   
965!
966!-- Allocate:
967    ALLOCATE( aero(nbins), bin_low_limits(nbins), nsect(nbins), massacc(nbins) )
968    IF ( nldepo ) ALLOCATE( sedim_vd(nzb:nzt+1,nysg:nyng,nxlg:nxrg,nbins) )         
969    ALLOCATE( Ra_dry(nzb:nzt+1,nysg:nyng,nxlg:nxrg,nbins) )
970   
971!   
972!-- Aerosol number concentration
973    ALLOCATE( aerosol_number(nbins) )
974    ALLOCATE( nconc_1(nzb:nzt+1,nysg:nyng,nxlg:nxrg,nbins),                    &
975              nconc_2(nzb:nzt+1,nysg:nyng,nxlg:nxrg,nbins),                    &
976              nconc_3(nzb:nzt+1,nysg:nyng,nxlg:nxrg,nbins) )
977    nconc_1 = 0.0_wp
978    nconc_2 = 0.0_wp
979    nconc_3 = 0.0_wp
980   
981    DO i = 1, nbins
982       aerosol_number(i)%conc(nzb:nzt+1,nysg:nyng,nxlg:nxrg)    => nconc_1(:,:,:,i)
983       aerosol_number(i)%conc_p(nzb:nzt+1,nysg:nyng,nxlg:nxrg)  => nconc_2(:,:,:,i)
984       aerosol_number(i)%tconc_m(nzb:nzt+1,nysg:nyng,nxlg:nxrg) => nconc_3(:,:,:,i)
985       ALLOCATE( aerosol_number(i)%flux_s(nzb+1:nzt,0:threads_per_task-1),     &
986                 aerosol_number(i)%diss_s(nzb+1:nzt,0:threads_per_task-1),     &
987                 aerosol_number(i)%flux_l(nzb+1:nzt,nys:nyn,0:threads_per_task-1),&
988                 aerosol_number(i)%diss_l(nzb+1:nzt,nys:nyn,0:threads_per_task-1),&
989                 aerosol_number(i)%init(nzb:nzt+1),                            &
990                 aerosol_number(i)%sums_ws_l(nzb:nzt+1,0:threads_per_task-1) )
991    ENDDO     
992   
993!   
994!-- Aerosol mass concentration   
995    ALLOCATE( aerosol_mass(ncc_tot*nbins) ) 
996    ALLOCATE( mconc_1(nzb:nzt+1,nysg:nyng,nxlg:nxrg,ncc_tot*nbins),            &
997              mconc_2(nzb:nzt+1,nysg:nyng,nxlg:nxrg,ncc_tot*nbins),            &
998              mconc_3(nzb:nzt+1,nysg:nyng,nxlg:nxrg,ncc_tot*nbins) )
999    mconc_1 = 0.0_wp
1000    mconc_2 = 0.0_wp
1001    mconc_3 = 0.0_wp
1002   
1003    DO i = 1, ncc_tot*nbins
1004       aerosol_mass(i)%conc(nzb:nzt+1,nysg:nyng,nxlg:nxrg)    => mconc_1(:,:,:,i)
1005       aerosol_mass(i)%conc_p(nzb:nzt+1,nysg:nyng,nxlg:nxrg)  => mconc_2(:,:,:,i)
1006       aerosol_mass(i)%tconc_m(nzb:nzt+1,nysg:nyng,nxlg:nxrg) => mconc_3(:,:,:,i)       
1007       ALLOCATE( aerosol_mass(i)%flux_s(nzb+1:nzt,0:threads_per_task-1),       &
1008                 aerosol_mass(i)%diss_s(nzb+1:nzt,0:threads_per_task-1),       &
1009                 aerosol_mass(i)%flux_l(nzb+1:nzt,nys:nyn,0:threads_per_task-1),&
1010                 aerosol_mass(i)%diss_l(nzb+1:nzt,nys:nyn,0:threads_per_task-1),&
1011                 aerosol_mass(i)%init(nzb:nzt+1),                              &
1012                 aerosol_mass(i)%sums_ws_l(nzb:nzt+1,0:threads_per_task-1)  )
1013    ENDDO
1014   
1015!
1016!-- Surface fluxes: answs = aerosol number, amsws = aerosol mass
1017!
1018!-- Horizontal surfaces: default type
1019    DO  l = 0, 2   ! upward (l=0), downward (l=1) and model top (l=2)
1020       ALLOCATE( surf_def_h(l)%answs( 1:surf_def_h(l)%ns, nbins ) )
1021       ALLOCATE( surf_def_h(l)%amsws( 1:surf_def_h(l)%ns, nbins*ncc_tot ) )
1022       surf_def_h(l)%answs = 0.0_wp
1023       surf_def_h(l)%amsws = 0.0_wp
1024    ENDDO
1025!-- Horizontal surfaces: natural type   
1026    IF ( land_surface )  THEN
1027       ALLOCATE( surf_lsm_h%answs( 1:surf_lsm_h%ns, nbins ) )
1028       ALLOCATE( surf_lsm_h%amsws( 1:surf_lsm_h%ns, nbins*ncc_tot ) )
1029       surf_lsm_h%answs = 0.0_wp
1030       surf_lsm_h%amsws = 0.0_wp
1031    ENDIF
1032!-- Horizontal surfaces: urban type
1033    IF ( urban_surface )  THEN
1034       ALLOCATE( surf_usm_h%answs( 1:surf_usm_h%ns, nbins ) )
1035       ALLOCATE( surf_usm_h%amsws( 1:surf_usm_h%ns, nbins*ncc_tot ) )
1036       surf_usm_h%answs = 0.0_wp
1037       surf_usm_h%amsws = 0.0_wp
1038    ENDIF
1039!
1040!-- Vertical surfaces: northward (l=0), southward (l=1), eastward (l=2) and
1041!-- westward (l=3) facing
1042    DO  l = 0, 3   
1043       ALLOCATE( surf_def_v(l)%answs( 1:surf_def_v(l)%ns, nbins ) )
1044       surf_def_v(l)%answs = 0.0_wp
1045       ALLOCATE( surf_def_v(l)%amsws( 1:surf_def_v(l)%ns, nbins*ncc_tot ) )
1046       surf_def_v(l)%amsws = 0.0_wp
1047       
1048       IF ( land_surface)  THEN
1049          ALLOCATE( surf_lsm_v(l)%answs( 1:surf_lsm_v(l)%ns, nbins ) )
1050          surf_lsm_v(l)%answs = 0.0_wp
1051          ALLOCATE( surf_lsm_v(l)%amsws( 1:surf_lsm_v(l)%ns, nbins*ncc_tot ) )
1052          surf_lsm_v(l)%amsws = 0.0_wp
1053       ENDIF
1054       
1055       IF ( urban_surface )  THEN
1056          ALLOCATE( surf_usm_v(l)%answs( 1:surf_usm_v(l)%ns, nbins ) )
1057          surf_usm_v(l)%answs = 0.0_wp
1058          ALLOCATE( surf_usm_v(l)%amsws( 1:surf_usm_v(l)%ns, nbins*ncc_tot ) )
1059          surf_usm_v(l)%amsws = 0.0_wp
1060       ENDIF
1061    ENDDO   
1062   
1063!
1064!-- Concentration of gaseous tracers (1. SO4, 2. HNO3, 3. NH3, 4. OCNV, 5. OCSV)
1065!-- (number concentration (#/m3) )
1066!
1067!-- If chemistry is on, read gas phase concentrations from there. Otherwise,
1068!-- allocate salsa_gas array.
1069
1070    IF ( air_chemistry )  THEN   
1071       DO  lsp = 1, nvar
1072          IF ( TRIM( chem_species(lsp)%name ) == 'H2SO4' )  THEN
1073             gases_available = gases_available + 1
1074             gas_index_chem(1) = lsp
1075          ELSEIF ( TRIM( chem_species(lsp)%name ) == 'HNO3' )  THEN
1076             gases_available = gases_available + 1 
1077             gas_index_chem(2) = lsp
1078          ELSEIF ( TRIM( chem_species(lsp)%name ) == 'NH3' )  THEN
1079             gases_available = gases_available + 1
1080             gas_index_chem(3) = lsp
1081          ELSEIF ( TRIM( chem_species(lsp)%name ) == 'OCNV' )  THEN
1082             gases_available = gases_available + 1
1083             gas_index_chem(4) = lsp
1084          ELSEIF ( TRIM( chem_species(lsp)%name ) == 'OCSV' )  THEN
1085             gases_available = gases_available + 1
1086             gas_index_chem(5) = lsp
1087          ENDIF
1088       ENDDO
1089
1090       IF ( gases_available == ngast )  THEN
1091          salsa_gases_from_chem = .TRUE.
1092       ELSE
1093          WRITE( message_string, * ) 'SALSA is run together with chemistry '// &
1094                                     'but not all gaseous components are '//   &
1095                                     'provided by kpp (H2SO4, HNO3, NH3, '//   &
1096                                     'OCNV, OCSC)'
1097       CALL message( 'check_parameters', 'SA0024', 1, 2, 0, 6, 0 )
1098       ENDIF
1099
1100    ELSE
1101
1102       ALLOCATE( salsa_gas(ngast) ) 
1103       ALLOCATE( gconc_1(nzb:nzt+1,nysg:nyng,nxlg:nxrg,ngast),                 &
1104                 gconc_2(nzb:nzt+1,nysg:nyng,nxlg:nxrg,ngast),                 &
1105                 gconc_3(nzb:nzt+1,nysg:nyng,nxlg:nxrg,ngast) )
1106       gconc_1 = 0.0_wp
1107       gconc_2 = 0.0_wp
1108       gconc_3 = 0.0_wp
1109       
1110       DO i = 1, ngast
1111          salsa_gas(i)%conc(nzb:nzt+1,nysg:nyng,nxlg:nxrg)    => gconc_1(:,:,:,i)
1112          salsa_gas(i)%conc_p(nzb:nzt+1,nysg:nyng,nxlg:nxrg)  => gconc_2(:,:,:,i)
1113          salsa_gas(i)%tconc_m(nzb:nzt+1,nysg:nyng,nxlg:nxrg) => gconc_3(:,:,:,i)
1114          ALLOCATE( salsa_gas(i)%flux_s(nzb+1:nzt,0:threads_per_task-1),       &
1115                    salsa_gas(i)%diss_s(nzb+1:nzt,0:threads_per_task-1),       &
1116                    salsa_gas(i)%flux_l(nzb+1:nzt,nys:nyn,0:threads_per_task-1),&
1117                    salsa_gas(i)%diss_l(nzb+1:nzt,nys:nyn,0:threads_per_task-1),&
1118                    salsa_gas(i)%init(nzb:nzt+1),                              &
1119                    salsa_gas(i)%sums_ws_l(nzb:nzt+1,0:threads_per_task-1) )
1120       ENDDO       
1121!
1122!--    Surface fluxes: gtsws = gaseous tracer flux
1123!
1124!--    Horizontal surfaces: default type
1125       DO  l = 0, 2   ! upward (l=0), downward (l=1) and model top (l=2)
1126          ALLOCATE( surf_def_h(l)%gtsws( 1:surf_def_h(l)%ns, ngast ) )
1127          surf_def_h(l)%gtsws = 0.0_wp
1128       ENDDO
1129!--    Horizontal surfaces: natural type   
1130       IF ( land_surface )  THEN
1131          ALLOCATE( surf_lsm_h%gtsws( 1:surf_lsm_h%ns, ngast ) )
1132          surf_lsm_h%gtsws = 0.0_wp
1133       ENDIF
1134!--    Horizontal surfaces: urban type         
1135       IF ( urban_surface )  THEN
1136          ALLOCATE( surf_usm_h%gtsws( 1:surf_usm_h%ns, ngast ) )
1137          surf_usm_h%gtsws = 0.0_wp
1138       ENDIF
1139!
1140!--    Vertical surfaces: northward (l=0), southward (l=1), eastward (l=2) and
1141!--    westward (l=3) facing
1142       DO  l = 0, 3     
1143          ALLOCATE( surf_def_v(l)%gtsws( 1:surf_def_v(l)%ns, ngast ) )
1144          surf_def_v(l)%gtsws = 0.0_wp
1145          IF ( land_surface )  THEN
1146             ALLOCATE( surf_lsm_v(l)%gtsws( 1:surf_lsm_v(l)%ns, ngast ) )
1147             surf_lsm_v(l)%gtsws = 0.0_wp
1148          ENDIF
1149          IF ( urban_surface )  THEN
1150             ALLOCATE( surf_usm_v(l)%gtsws( 1:surf_usm_v(l)%ns, ngast ) )
1151             surf_usm_v(l)%gtsws = 0.0_wp
1152          ENDIF
1153       ENDDO
1154    ENDIF
1155   
1156#endif
1157
1158 END SUBROUTINE salsa_init_arrays
1159
1160!------------------------------------------------------------------------------!
1161! Description:
1162! ------------
1163!> Initialization of SALSA. Based on salsa_initialize in UCLALES-SALSA.
1164!> Subroutines salsa_initialize, SALSAinit and DiagInitAero in UCLALES-SALSA are
1165!> also merged here.
1166!------------------------------------------------------------------------------!
1167 SUBROUTINE salsa_init
1168
1169    IMPLICIT NONE
1170   
1171    INTEGER(iwp) :: b
1172    INTEGER(iwp) :: c
1173    INTEGER(iwp) :: g
1174    INTEGER(iwp) :: i
1175    INTEGER(iwp) :: j
1176   
1177    bin_low_limits = 0.0_wp
1178    nsect          = 0.0_wp
1179    massacc        = 1.0_wp 
1180   
1181!
1182!-- Indices for chemical components used (-1 = not used)
1183    i = 0
1184    IF ( is_used( prtcl, 'SO4' ) )  THEN
1185       iso4 = get_index( prtcl,'SO4' )
1186       i = i + 1
1187    ENDIF
1188    IF ( is_used( prtcl,'OC' ) )  THEN
1189       ioc = get_index(prtcl, 'OC')
1190       i = i + 1
1191    ENDIF
1192    IF ( is_used( prtcl, 'BC' ) )  THEN
1193       ibc = get_index( prtcl, 'BC' )
1194       i = i + 1
1195    ENDIF
1196    IF ( is_used( prtcl, 'DU' ) )  THEN
1197       idu = get_index( prtcl, 'DU' )
1198       i = i + 1
1199    ENDIF
1200    IF ( is_used( prtcl, 'SS' ) )  THEN
1201       iss = get_index( prtcl, 'SS' )
1202       i = i + 1
1203    ENDIF
1204    IF ( is_used( prtcl, 'NO' ) )  THEN
1205       ino = get_index( prtcl, 'NO' )
1206       i = i + 1
1207    ENDIF
1208    IF ( is_used( prtcl, 'NH' ) )  THEN
1209       inh = get_index( prtcl, 'NH' )
1210       i = i + 1
1211    ENDIF
1212!   
1213!-- All species must be known
1214    IF ( i /= ncc )  THEN
1215       message_string = 'Unknown aerosol species/component(s) given in the' // &
1216                        ' initialization'
1217       CALL message( 'salsa_mod: salsa_init', 'SA0020', 1, 2, 0, 6, 0 )
1218    ENDIF
1219   
1220!
1221!-- Initialise
1222!
1223!-- Aerosol size distribution (TYPE t_section)
1224    aero(:)%dwet     = 1.0E-10_wp
1225    aero(:)%veqh2o   = 1.0E-10_wp
1226    aero(:)%numc     = nclim
1227    aero(:)%core     = 1.0E-10_wp
1228    DO c = 1, maxspec+1    ! 1:SO4, 2:OC, 3:BC, 4:DU, 5:SS, 6:NO, 7:NH, 8:H2O
1229       aero(:)%volc(c) = 0.0_wp
1230    ENDDO
1231   
1232    IF ( nldepo )  sedim_vd = 0.0_wp
1233!   
1234!-- Initilisation actions that are NOT conducted for restart runs
1235    IF ( .NOT. read_restart_data_salsa )  THEN   
1236   
1237       DO  b = 1, nbins
1238          aerosol_number(b)%conc      = nclim
1239          aerosol_number(b)%conc_p    = 0.0_wp
1240          aerosol_number(b)%tconc_m   = 0.0_wp
1241          aerosol_number(b)%flux_s    = 0.0_wp
1242          aerosol_number(b)%diss_s    = 0.0_wp
1243          aerosol_number(b)%flux_l    = 0.0_wp
1244          aerosol_number(b)%diss_l    = 0.0_wp
1245          aerosol_number(b)%init      = nclim
1246          aerosol_number(b)%sums_ws_l = 0.0_wp
1247       ENDDO
1248       DO  c = 1, ncc_tot*nbins
1249          aerosol_mass(c)%conc      = mclim
1250          aerosol_mass(c)%conc_p    = 0.0_wp
1251          aerosol_mass(c)%tconc_m   = 0.0_wp
1252          aerosol_mass(c)%flux_s    = 0.0_wp
1253          aerosol_mass(c)%diss_s    = 0.0_wp
1254          aerosol_mass(c)%flux_l    = 0.0_wp
1255          aerosol_mass(c)%diss_l    = 0.0_wp
1256          aerosol_mass(c)%init      = mclim
1257          aerosol_mass(c)%sums_ws_l = 0.0_wp
1258       ENDDO
1259       
1260       IF ( .NOT. salsa_gases_from_chem )  THEN
1261          DO  g = 1, ngast
1262             salsa_gas(g)%conc_p    = 0.0_wp
1263             salsa_gas(g)%tconc_m   = 0.0_wp
1264             salsa_gas(g)%flux_s    = 0.0_wp
1265             salsa_gas(g)%diss_s    = 0.0_wp
1266             salsa_gas(g)%flux_l    = 0.0_wp
1267             salsa_gas(g)%diss_l    = 0.0_wp
1268             salsa_gas(g)%sums_ws_l = 0.0_wp
1269          ENDDO
1270       
1271!
1272!--       Set initial value for gas compound tracers and initial values
1273          salsa_gas(1)%conc = H2SO4_init
1274          salsa_gas(1)%init = H2SO4_init
1275          salsa_gas(2)%conc = HNO3_init
1276          salsa_gas(2)%init = HNO3_init
1277          salsa_gas(3)%conc = NH3_init
1278          salsa_gas(3)%init = NH3_init
1279          salsa_gas(4)%conc = OCNV_init
1280          salsa_gas(4)%init = OCNV_init
1281          salsa_gas(5)%conc = OCSV_init
1282          salsa_gas(5)%init = OCSV_init     
1283       ENDIF
1284!
1285!--    Aerosol radius in each bin: dry and wet (m)
1286       Ra_dry = 1.0E-10_wp
1287!   
1288!--    Initialise aerosol tracers   
1289       aero(:)%vhilim   = 0.0_wp
1290       aero(:)%vlolim   = 0.0_wp
1291       aero(:)%vratiohi = 0.0_wp
1292       aero(:)%vratiolo = 0.0_wp
1293       aero(:)%dmid     = 0.0_wp
1294!
1295!--    Initialise the sectional particle size distribution
1296       CALL set_sizebins()
1297!
1298!--    Initialise location-dependent aerosol size distributions and
1299!--    chemical compositions:
1300       CALL aerosol_init
1301!
1302!--    Initalisation run of SALSA
1303       DO  i = nxl, nxr
1304          DO  j = nys, nyn
1305             CALL salsa_driver( i, j, 1 )
1306             CALL salsa_diagnostics( i, j )
1307          ENDDO
1308       ENDDO
1309    ENDIF
1310!
1311!-- Set the aerosol and gas sources
1312    IF ( salsa_source_mode == 'read_from_file' )  THEN
1313       CALL salsa_set_source
1314    ENDIF
1315   
1316 END SUBROUTINE salsa_init
1317
1318!------------------------------------------------------------------------------!
1319! Description:
1320! ------------
1321!> Initializes particle size distribution grid by calculating size bin limits
1322!> and mid-size for *dry* particles in each bin. Called from salsa_initialize
1323!> (only at the beginning of simulation).
1324!> Size distribution described using:
1325!>   1) moving center method (subranges 1 and 2)
1326!>      (Jacobson, Atmos. Env., 31, 131-144, 1997)
1327!>   2) fixed sectional method (subrange 3)
1328!> Size bins in each subrange are spaced logarithmically
1329!> based on given subrange size limits and bin number.
1330!
1331!> Mona changed 06/2017: Use geometric mean diameter to describe the mean
1332!> particle diameter in a size bin, not the arithmeric mean which clearly
1333!> overestimates the total particle volume concentration.
1334!
1335!> Coded by:
1336!> Hannele Korhonen (FMI) 2005
1337!> Harri Kokkola (FMI) 2006
1338!
1339!> Bug fixes for box model + updated for the new aerosol datatype:
1340!> Juha Tonttila (FMI) 2014
1341!------------------------------------------------------------------------------!
1342 SUBROUTINE set_sizebins
1343               
1344    IMPLICIT NONE
1345!   
1346!-- Local variables
1347    INTEGER(iwp) ::  cc
1348    INTEGER(iwp) ::  dd
1349    REAL(wp) ::  ratio_d !< ratio of the upper and lower diameter of subranges
1350!
1351!-- vlolim&vhilim: min & max *dry* volumes [fxm]
1352!-- dmid: bin mid *dry* diameter (m)
1353!-- vratiolo&vratiohi: volume ratio between the center and low/high limit
1354!
1355!-- 1) Size subrange 1:
1356    ratio_d = reglim(2) / reglim(1)   ! section spacing (m)
1357    DO  cc = in1a,fn1a
1358       aero(cc)%vlolim = api6 * ( reglim(1) * ratio_d **                       &
1359                                ( REAL( cc-1 ) / nbin(1) ) ) ** 3.0_wp
1360       aero(cc)%vhilim = api6 * ( reglim(1) * ratio_d **                       &
1361                                ( REAL( cc ) / nbin(1) ) ) ** 3.0_wp
1362       aero(cc)%dmid = SQRT( ( aero(cc)%vhilim / api6 ) ** ( 1.0_wp / 3.0_wp ) &
1363                           * ( aero(cc)%vlolim / api6 ) ** ( 1.0_wp / 3.0_wp ) )
1364       aero(cc)%vratiohi = aero(cc)%vhilim / ( api6 * aero(cc)%dmid ** 3.0_wp )
1365       aero(cc)%vratiolo = aero(cc)%vlolim / ( api6 * aero(cc)%dmid ** 3.0_wp )
1366    ENDDO
1367!
1368!-- 2) Size subrange 2:
1369!-- 2.1) Sub-subrange 2a: high hygroscopicity
1370    ratio_d = reglim(3) / reglim(2)   ! section spacing
1371    DO  dd = in2a, fn2a
1372       cc = dd - in2a
1373       aero(dd)%vlolim = api6 * ( reglim(2) * ratio_d **                       &
1374                                  ( REAL( cc ) / nbin(2) ) ) ** 3.0_wp
1375       aero(dd)%vhilim = api6 * ( reglim(2) * ratio_d **                       &
1376                                  ( REAL( cc+1 ) / nbin(2) ) ) ** 3.0_wp
1377       aero(dd)%dmid = SQRT( ( aero(dd)%vhilim / api6 ) ** ( 1.0_wp / 3.0_wp ) &
1378                           * ( aero(dd)%vlolim / api6 ) ** ( 1.0_wp / 3.0_wp ) )
1379       aero(dd)%vratiohi = aero(dd)%vhilim / ( api6 * aero(dd)%dmid ** 3.0_wp )
1380       aero(dd)%vratiolo = aero(dd)%vlolim / ( api6 * aero(dd)%dmid ** 3.0_wp )
1381    ENDDO
1382!         
1383!-- 2.2) Sub-subrange 2b: low hygroscopicity
1384    IF ( .NOT. no_insoluble )  THEN
1385       aero(in2b:fn2b)%vlolim   = aero(in2a:fn2a)%vlolim
1386       aero(in2b:fn2b)%vhilim   = aero(in2a:fn2a)%vhilim
1387       aero(in2b:fn2b)%dmid     = aero(in2a:fn2a)%dmid
1388       aero(in2b:fn2b)%vratiohi = aero(in2a:fn2a)%vratiohi
1389       aero(in2b:fn2b)%vratiolo = aero(in2a:fn2a)%vratiolo
1390    ENDIF
1391!         
1392!-- Initialize the wet diameter with the bin dry diameter to avoid numerical
1393!-- problems later
1394    aero(:)%dwet = aero(:)%dmid
1395!
1396!-- Save bin limits (lower diameter) to be delivered to the host model if needed
1397    DO cc = 1, nbins
1398       bin_low_limits(cc) = ( aero(cc)%vlolim / api6 )**( 1.0_wp / 3.0_wp )
1399    ENDDO   
1400   
1401 END SUBROUTINE set_sizebins
1402 
1403!------------------------------------------------------------------------------!
1404! Description:
1405! ------------
1406!> Initilize altitude-dependent aerosol size distributions and compositions.
1407!>
1408!> Mona added 06/2017: Correct the number and mass concentrations by normalizing
1409!< by the given total number and mass concentration.
1410!>
1411!> Tomi Raatikainen, FMI, 29.2.2016
1412!------------------------------------------------------------------------------!
1413 SUBROUTINE aerosol_init
1414 
1415    USE arrays_3d,                                                             &
1416        ONLY:  zu
1417 
1418!    USE NETCDF
1419   
1420    USE netcdf_data_input_mod,                                                 &
1421        ONLY:  get_attribute, netcdf_data_input_get_dimension_length,          &
1422               get_variable, open_read_file
1423   
1424    IMPLICIT NONE
1425   
1426    INTEGER(iwp) ::  b          !< loop index: size bins
1427    INTEGER(iwp) ::  c          !< loop index: chemical components
1428    INTEGER(iwp) ::  ee         !< index: end
1429    INTEGER(iwp) ::  g          !< loop index: gases
1430    INTEGER(iwp) ::  i          !< loop index: x-direction
1431    INTEGER(iwp) ::  id_faero   !< NetCDF id of PIDS_SALSA
1432    INTEGER(iwp) ::  id_fchem   !< NetCDF id of PIDS_CHEM
1433    INTEGER(iwp) ::  j          !< loop index: y-direction
1434    INTEGER(iwp) ::  k          !< loop index: z-direction
1435    INTEGER(iwp) ::  kk         !< loop index: z-direction
1436    INTEGER(iwp) ::  nz_file    !< Number of grid-points in file (heights)                           
1437    INTEGER(iwp) ::  prunmode
1438    INTEGER(iwp) ::  ss !< index: start
1439    LOGICAL  ::  netcdf_extend = .FALSE. !< Flag indicating wether netcdf
1440                                         !< topography input file or not
1441    REAL(wp), DIMENSION(nbins) ::  core  !< size of the bin mid aerosol particle,
1442    REAL(wp) ::  flag           !< flag to mask topography grid points
1443    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  pr_gas !< gas profiles
1444    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  pr_mass_fracs_a !< mass fraction
1445                                                              !< profiles: a
1446    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  pr_mass_fracs_b !< and b
1447    REAL(wp), DIMENSION(:,:), ALLOCATABLE ::  pr_nsect !< sectional size
1448                                                       !< distribution profile
1449    REAL(wp), DIMENSION(nbins)            ::  nsect  !< size distribution (#/m3)
1450    REAL(wp), DIMENSION(0:nz+1,nbins)     ::  pndist !< size dist as a function
1451                                                     !< of height (#/m3)
1452    REAL(wp), DIMENSION(0:nz+1)           ::  pnf2a  !< number fraction: bins 2a
1453    REAL(wp), DIMENSION(0:nz+1,maxspec)   ::  pvf2a  !< mass distributions of 
1454                                                     !< aerosol species for a 
1455    REAL(wp), DIMENSION(0:nz+1,maxspec)   ::  pvf2b  !< and b-bins     
1456    REAL(wp), DIMENSION(0:nz+1)           ::  pvfOC1a !< mass fraction between
1457                                                     !< SO4 and OC in 1a
1458    REAL(wp), DIMENSION(:), ALLOCATABLE   ::  pr_z
1459
1460    prunmode = 1
1461!
1462!-- Bin mean aerosol particle volume (m3)
1463    core(:) = 0.0_wp
1464    core(1:nbins) = api6 * aero(1:nbins)%dmid ** 3.0_wp
1465!   
1466!-- Set concentrations to zero
1467    nsect(:)     = 0.0_wp
1468    pndist(:,:)  = 0.0_wp
1469    pnf2a(:)     = nf2a   
1470    pvf2a(:,:)   = 0.0_wp
1471    pvf2b(:,:)   = 0.0_wp
1472    pvfOC1a(:)   = 0.0_wp
1473
1474    IF ( isdtyp == 1 )  THEN
1475!
1476!--    Read input profiles from PIDS_SALSA   
1477#if defined( __netcdf )
1478!   
1479!--    Location-dependent size distributions and compositions.     
1480       INQUIRE( FILE='PIDS_SALSA'// TRIM( coupling_char ), EXIST=netcdf_extend )
1481       IF ( netcdf_extend )  THEN
1482!
1483!--       Open file in read-only mode 
1484          CALL open_read_file( 'PIDS_SALSA' // TRIM( coupling_char ), id_faero )
1485!
1486!--       Input heights   
1487          CALL netcdf_data_input_get_dimension_length( id_faero, nz_file, "profile_z" ) 
1488         
1489          ALLOCATE( pr_z(nz_file), pr_mass_fracs_a(maxspec,nz_file),           &
1490                    pr_mass_fracs_b(maxspec,nz_file), pr_nsect(nbins,nz_file) ) 
1491          CALL get_variable( id_faero, 'profile_z', pr_z ) 
1492!       
1493!--       Mass fracs profile: 1: H2SO4 (sulphuric acid), 2: OC (organic carbon),
1494!--                           3: BC (black carbon),      4: DU (dust), 
1495!--                           5: SS (sea salt),          6: HNO3 (nitric acid),
1496!--                           7: NH3 (ammonia)         
1497          CALL get_variable( id_faero, "profile_mass_fracs_a", pr_mass_fracs_a,&
1498                             0, nz_file-1, 0, maxspec-1 )
1499          CALL get_variable( id_faero, "profile_mass_fracs_b", pr_mass_fracs_b,&
1500                             0, nz_file-1, 0, maxspec-1 )
1501          CALL get_variable( id_faero, "profile_nsect", pr_nsect, 0, nz_file-1,&
1502                             0, nbins-1 )                   
1503         
1504          kk = 1
1505          DO  k = nzb, nz+1
1506             IF ( kk < nz_file )  THEN
1507                DO  WHILE ( pr_z(kk+1) <= zu(k) )
1508                   kk = kk + 1
1509                   IF ( kk == nz_file )  EXIT
1510                ENDDO
1511             ENDIF
1512             IF ( kk < nz_file )  THEN
1513!             
1514!--             Set initial value for gas compound tracers and initial values
1515                pvf2a(k,:) = pr_mass_fracs_a(:,kk) + ( zu(k) - pr_z(kk) ) / (  &
1516                            pr_z(kk+1) - pr_z(kk) ) * ( pr_mass_fracs_a(:,kk+1)&
1517                            - pr_mass_fracs_a(:,kk) )   
1518                pvf2b(k,:) = pr_mass_fracs_b(:,kk) + ( zu(k) - pr_z(kk) ) / (  &
1519                            pr_z(kk+1) - pr_z(kk) ) * ( pr_mass_fracs_b(:,kk+1)&
1520                            - pr_mass_fracs_b(:,kk) )             
1521                pndist(k,:) = pr_nsect(:,kk) + ( zu(k) - pr_z(kk) ) / (        &
1522                              pr_z(kk+1) - pr_z(kk) ) * ( pr_nsect(:,kk+1) -   &
1523                              pr_nsect(:,kk) )
1524             ELSE
1525                pvf2a(k,:) = pr_mass_fracs_a(:,kk)       
1526                pvf2b(k,:) = pr_mass_fracs_b(:,kk)
1527                pndist(k,:) = pr_nsect(:,kk)
1528             ENDIF
1529             IF ( iso4 < 0 )  THEN
1530                pvf2a(k,1) = 0.0_wp
1531                pvf2b(k,1) = 0.0_wp
1532             ENDIF
1533             IF ( ioc < 0 )  THEN
1534                pvf2a(k,2) = 0.0_wp
1535                pvf2b(k,2) = 0.0_wp
1536             ENDIF
1537             IF ( ibc < 0 )  THEN
1538                pvf2a(k,3) = 0.0_wp
1539                pvf2b(k,3) = 0.0_wp
1540             ENDIF
1541             IF ( idu < 0 )  THEN
1542                pvf2a(k,4) = 0.0_wp
1543                pvf2b(k,4) = 0.0_wp
1544             ENDIF
1545             IF ( iss < 0 )  THEN
1546                pvf2a(k,5) = 0.0_wp
1547                pvf2b(k,5) = 0.0_wp
1548             ENDIF
1549             IF ( ino < 0 )  THEN
1550                pvf2a(k,6) = 0.0_wp
1551                pvf2b(k,6) = 0.0_wp
1552             ENDIF
1553             IF ( inh < 0 )  THEN
1554                pvf2a(k,7) = 0.0_wp
1555                pvf2b(k,7) = 0.0_wp
1556             ENDIF
1557!
1558!--          Then normalise the mass fraction so that SUM = 1
1559             pvf2a(k,:) = pvf2a(k,:) / SUM( pvf2a(k,:) )
1560             IF ( SUM( pvf2b(k,:) ) > 0.0_wp ) pvf2b(k,:) = pvf2b(k,:) /       &
1561                                                            SUM( pvf2b(k,:) )
1562          ENDDO         
1563          DEALLOCATE( pr_z, pr_mass_fracs_a, pr_mass_fracs_b, pr_nsect )
1564       ELSE
1565          message_string = 'Input file '// TRIM( 'PIDS_SALSA' ) //             &
1566                           TRIM( coupling_char ) // ' for SALSA missing!'
1567          CALL message( 'salsa_mod: aerosol_init', 'SA0032', 1, 2, 0, 6, 0 )               
1568       ENDIF   ! netcdf_extend   
1569#endif
1570 
1571    ELSEIF ( isdtyp == 0 )  THEN
1572!
1573!--    Mass fractions for species in a and b-bins
1574       IF ( iso4 > 0 )  THEN
1575          pvf2a(:,1) = mass_fracs_a(iso4) 
1576          pvf2b(:,1) = mass_fracs_b(iso4)
1577       ENDIF
1578       IF ( ioc > 0 )  THEN
1579          pvf2a(:,2) = mass_fracs_a(ioc)
1580          pvf2b(:,2) = mass_fracs_b(ioc) 
1581       ENDIF
1582       IF ( ibc > 0 )  THEN
1583          pvf2a(:,3) = mass_fracs_a(ibc) 
1584          pvf2b(:,3) = mass_fracs_b(ibc)
1585       ENDIF
1586       IF ( idu > 0 )  THEN
1587          pvf2a(:,4) = mass_fracs_a(idu)
1588          pvf2b(:,4) = mass_fracs_b(idu) 
1589       ENDIF
1590       IF ( iss > 0 )  THEN
1591          pvf2a(:,5) = mass_fracs_a(iss)
1592          pvf2b(:,5) = mass_fracs_b(iss) 
1593       ENDIF
1594       IF ( ino > 0 )  THEN
1595          pvf2a(:,6) = mass_fracs_a(ino)
1596          pvf2b(:,6) = mass_fracs_b(ino)
1597       ENDIF
1598       IF ( inh > 0 )  THEN
1599          pvf2a(:,7) = mass_fracs_a(inh)
1600          pvf2b(:,7) = mass_fracs_b(inh)
1601       ENDIF
1602       DO  k = nzb, nz+1
1603          pvf2a(k,:) = pvf2a(k,:) / SUM( pvf2a(k,:) )
1604          IF ( SUM( pvf2b(k,:) ) > 0.0_wp ) pvf2b(k,:) = pvf2b(k,:) /          &
1605                                                         SUM( pvf2b(k,:) )
1606       ENDDO
1607       
1608       CALL size_distribution( n_lognorm, dpg, sigmag, nsect )
1609!
1610!--    Normalize by the given total number concentration
1611       nsect = nsect * SUM( n_lognorm ) * 1.0E+6_wp / SUM( nsect )     
1612       DO  b = in1a, fn2b
1613          pndist(:,b) = nsect(b)
1614       ENDDO
1615    ENDIF
1616   
1617    IF ( igctyp == 1 )  THEN
1618!
1619!--    Read input profiles from PIDS_CHEM   
1620#if defined( __netcdf )
1621!   
1622!--    Location-dependent size distributions and compositions.     
1623       INQUIRE( FILE='PIDS_CHEM' // TRIM( coupling_char ), EXIST=netcdf_extend )
1624       IF ( netcdf_extend  .AND.  .NOT. salsa_gases_from_chem )  THEN
1625!
1626!--       Open file in read-only mode     
1627          CALL open_read_file( 'PIDS_CHEM' // TRIM( coupling_char ), id_fchem )
1628!
1629!--       Input heights   
1630          CALL netcdf_data_input_get_dimension_length( id_fchem, nz_file, "profile_z" ) 
1631          ALLOCATE( pr_z(nz_file), pr_gas(ngast,nz_file) ) 
1632          CALL get_variable( id_fchem, 'profile_z', pr_z ) 
1633!       
1634!--       Gases:
1635          CALL get_variable( id_fchem, "profile_H2SO4", pr_gas(1,:) )
1636          CALL get_variable( id_fchem, "profile_HNO3", pr_gas(2,:) )
1637          CALL get_variable( id_fchem, "profile_NH3", pr_gas(3,:) )
1638          CALL get_variable( id_fchem, "profile_OCNV", pr_gas(4,:) )
1639          CALL get_variable( id_fchem, "profile_OCSV", pr_gas(5,:) )
1640         
1641          kk = 1
1642          DO  k = nzb, nz+1
1643             IF ( kk < nz_file )  THEN
1644                DO  WHILE ( pr_z(kk+1) <= zu(k) )
1645                   kk = kk + 1
1646                   IF ( kk == nz_file )  EXIT
1647                ENDDO
1648             ENDIF
1649             IF ( kk < nz_file )  THEN
1650!             
1651!--             Set initial value for gas compound tracers and initial values
1652                DO  g = 1, ngast
1653                   salsa_gas(g)%init(k) =  pr_gas(g,kk) + ( zu(k) - pr_z(kk) ) &
1654                                           / ( pr_z(kk+1) - pr_z(kk) ) *       &
1655                                           ( pr_gas(g,kk+1) - pr_gas(g,kk) )
1656                   salsa_gas(g)%conc(k,:,:) = salsa_gas(g)%init(k)
1657                ENDDO
1658             ELSE
1659                DO  g = 1, ngast
1660                   salsa_gas(g)%init(k) =  pr_gas(g,kk) 
1661                   salsa_gas(g)%conc(k,:,:) = salsa_gas(g)%init(k)
1662                ENDDO
1663             ENDIF
1664          ENDDO
1665         
1666          DEALLOCATE( pr_z, pr_gas )
1667       ELSEIF ( .NOT. netcdf_extend  .AND.  .NOT.  salsa_gases_from_chem )  THEN
1668          message_string = 'Input file '// TRIM( 'PIDS_CHEM' ) //              &
1669                           TRIM( coupling_char ) // ' for SALSA missing!'
1670          CALL message( 'salsa_mod: aerosol_init', 'SA0033', 1, 2, 0, 6, 0 )               
1671       ENDIF   ! netcdf_extend     
1672#endif
1673
1674    ENDIF
1675
1676    IF ( ioc > 0  .AND.  iso4 > 0 )  THEN     
1677!--    Both are there, so use the given "massDistrA"
1678       pvfOC1a(:) = pvf2a(:,2) / ( pvf2a(:,2) + pvf2a(:,1) )  ! Normalize
1679    ELSEIF ( ioc > 0 )  THEN
1680!--    Pure organic carbon
1681       pvfOC1a(:) = 1.0_wp
1682    ELSEIF ( iso4 > 0 )  THEN
1683!--    Pure SO4
1684       pvfOC1a(:) = 0.0_wp   
1685    ELSE
1686       message_string = 'Either OC or SO4 must be active for aerosol region 1a!'
1687       CALL message( 'salsa_mod: aerosol_init', 'SA0021', 1, 2, 0, 6, 0 )
1688    ENDIF   
1689   
1690!
1691!-- Initialize concentrations
1692    DO  i = nxlg, nxrg
1693       DO  j = nysg, nyng
1694          DO  k = nzb, nzt+1
1695!
1696!--          Predetermine flag to mask topography         
1697             flag = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_0(k,j,i), 0 ) )
1698!         
1699!--          a) Number concentrations
1700!--           Region 1:
1701             DO  b = in1a, fn1a
1702                aerosol_number(b)%conc(k,j,i) = pndist(k,b) * flag
1703                IF ( prunmode == 1 )  THEN
1704                   aerosol_number(b)%init = pndist(:,b)
1705                ENDIF
1706             ENDDO
1707!             
1708!--           Region 2:
1709             IF ( nreg > 1 )  THEN
1710                DO  b = in2a, fn2a
1711                   aerosol_number(b)%conc(k,j,i) = MAX( 0.0_wp, pnf2a(k) ) *   &
1712                                                    pndist(k,b) * flag
1713                   IF ( prunmode == 1 )  THEN
1714                      aerosol_number(b)%init = MAX( 0.0_wp, nf2a ) * pndist(:,b)
1715                   ENDIF
1716                ENDDO
1717                IF ( .NOT. no_insoluble )  THEN
1718                   DO  b = in2b, fn2b
1719                      IF ( pnf2a(k) < 1.0_wp )  THEN             
1720                         aerosol_number(b)%conc(k,j,i) = MAX( 0.0_wp, 1.0_wp   &
1721                                               - pnf2a(k) ) * pndist(k,b) * flag
1722                         IF ( prunmode == 1 )  THEN
1723                            aerosol_number(b)%init = MAX( 0.0_wp, 1.0_wp -     &
1724                                                          nf2a ) * pndist(:,b)
1725                         ENDIF
1726                      ENDIF
1727                   ENDDO
1728                ENDIF
1729             ENDIF
1730!
1731!--          b) Aerosol mass concentrations
1732!--             bin subrange 1: done here separately due to the SO4/OC convention
1733!--          SO4:
1734             IF ( iso4 > 0 )  THEN
1735                ss = ( iso4 - 1 ) * nbins + in1a !< start
1736                ee = ( iso4 - 1 ) * nbins + fn1a !< end
1737                b = in1a
1738                DO  c = ss, ee
1739                   aerosol_mass(c)%conc(k,j,i) = MAX( 0.0_wp, 1.0_wp -         &
1740                                                  pvfOC1a(k) ) * pndist(k,b) * &
1741                                                  core(b) * arhoh2so4 * flag
1742                   IF ( prunmode == 1 )  THEN
1743                      aerosol_mass(c)%init = MAX( 0.0_wp, 1.0_wp - MAXVAL(     &
1744                                             pvfOC1a ) ) * pndist(:,b) *       &
1745                                             core(b) * arhoh2so4
1746                   ENDIF
1747                   b = b+1
1748                ENDDO
1749             ENDIF
1750!--          OC:
1751             IF ( ioc > 0 ) THEN
1752                ss = ( ioc - 1 ) * nbins + in1a !< start
1753                ee = ( ioc - 1 ) * nbins + fn1a !< end
1754                b = in1a
1755                DO  c = ss, ee
1756                   aerosol_mass(c)%conc(k,j,i) = MAX( 0.0_wp, pvfOC1a(k) ) *   &
1757                                           pndist(k,b) * core(b) * arhooc * flag
1758                   IF ( prunmode == 1 )  THEN
1759                      aerosol_mass(c)%init = MAX( 0.0_wp, MAXVAL( pvfOC1a ) )  &
1760                                             * pndist(:,b) *  core(b) * arhooc
1761                   ENDIF
1762                   b = b+1
1763                ENDDO
1764             ENDIF
1765             
1766             prunmode = 3  ! Init only once
1767 
1768          ENDDO !< k
1769       ENDDO !< j
1770    ENDDO !< i
1771   
1772!
1773!-- c) Aerosol mass concentrations
1774!--    bin subrange 2:
1775    IF ( nreg > 1 ) THEN
1776   
1777       IF ( iso4 > 0 ) THEN
1778          CALL set_aero_mass( iso4, pvf2a(:,1), pvf2b(:,1), pnf2a, pndist,     &
1779                              core, arhoh2so4 )
1780       ENDIF
1781       IF ( ioc > 0 ) THEN
1782          CALL set_aero_mass( ioc, pvf2a(:,2), pvf2b(:,2), pnf2a, pndist, core,&
1783                              arhooc )
1784       ENDIF
1785       IF ( ibc > 0 ) THEN
1786          CALL set_aero_mass( ibc, pvf2a(:,3), pvf2b(:,3), pnf2a, pndist, core,&
1787                              arhobc )
1788       ENDIF
1789       IF ( idu > 0 ) THEN
1790          CALL set_aero_mass( idu, pvf2a(:,4), pvf2b(:,4), pnf2a, pndist, core,&
1791                              arhodu )
1792       ENDIF
1793       IF ( iss > 0 ) THEN
1794          CALL set_aero_mass( iss, pvf2a(:,5), pvf2b(:,5), pnf2a, pndist, core,&
1795                              arhoss )
1796       ENDIF
1797       IF ( ino > 0 ) THEN
1798          CALL set_aero_mass( ino, pvf2a(:,6), pvf2b(:,6), pnf2a, pndist, core,&
1799                              arhohno3 )
1800       ENDIF
1801       IF ( inh > 0 ) THEN
1802          CALL set_aero_mass( inh, pvf2a(:,7), pvf2b(:,7), pnf2a, pndist, core,&
1803                              arhonh3 )
1804       ENDIF
1805
1806    ENDIF
1807   
1808 END SUBROUTINE aerosol_init
1809 
1810!------------------------------------------------------------------------------!
1811! Description:
1812! ------------
1813!> Create a lognormal size distribution and discretise to a sectional
1814!> representation.
1815!------------------------------------------------------------------------------!
1816 SUBROUTINE size_distribution( in_ntot, in_dpg, in_sigma, psd_sect )
1817   
1818    IMPLICIT NONE
1819   
1820!-- Log-normal size distribution: modes   
1821    REAL(wp), DIMENSION(:), INTENT(in) ::  in_dpg    !< geometric mean diameter
1822                                                     !< (micrometres)
1823    REAL(wp), DIMENSION(:), INTENT(in) ::  in_ntot   !< number conc. (#/cm3)
1824    REAL(wp), DIMENSION(:), INTENT(in) ::  in_sigma  !< standard deviation
1825    REAL(wp), DIMENSION(:), INTENT(inout) ::  psd_sect !< sectional size
1826                                                       !< distribution
1827    INTEGER(iwp) ::  b          !< running index: bin
1828    INTEGER(iwp) ::  ib         !< running index: iteration
1829    REAL(wp) ::  d1             !< particle diameter (m, dummy)
1830    REAL(wp) ::  d2             !< particle diameter (m, dummy)
1831    REAL(wp) ::  delta_d        !< (d2-d1)/10                                                     
1832    REAL(wp) ::  deltadp        !< bin width
1833    REAL(wp) ::  dmidi          !< ( d1 + d2 ) / 2
1834   
1835    DO  b = in1a, fn2b !< aerosol size bins
1836       psd_sect(b) = 0.0_wp
1837!--    Particle diameter at the low limit (largest in the bin) (m)
1838       d1 = ( aero(b)%vlolim / api6 ) ** ( 1.0_wp / 3.0_wp )
1839!--    Particle diameter at the high limit (smallest in the bin) (m)
1840       d2 = ( aero(b)%vhilim / api6 ) ** ( 1.0_wp / 3.0_wp )
1841!--    Span of particle diameter in a bin (m)
1842       delta_d = ( d2 - d1 ) / 10.0_wp
1843!--    Iterate:             
1844       DO  ib = 1, 10
1845          d1 = ( aero(b)%vlolim / api6 ) ** ( 1.0_wp / 3.0_wp ) + ( ib - 1)    &
1846               * delta_d
1847          d2 = d1 + delta_d
1848          dmidi = ( d1 + d2 ) / 2.0_wp
1849          deltadp = LOG10( d2 / d1 )
1850         
1851!--       Size distribution
1852!--       in_ntot = total number, total area, or total volume concentration
1853!--       in_dpg = geometric-mean number, area, or volume diameter
1854!--       n(k) = number, area, or volume concentration in a bin
1855!--       n_lognorm and dpg converted to units of #/m3 and m
1856          psd_sect(b) = psd_sect(b) + SUM( in_ntot * 1.0E+6_wp * deltadp /     &
1857                     ( SQRT( 2.0_wp * pi ) * LOG10( in_sigma ) ) *             &
1858                     EXP( -LOG10( dmidi / ( 1.0E-6_wp * in_dpg ) )**2.0_wp /   &
1859                     ( 2.0_wp * LOG10( in_sigma ) ** 2.0_wp ) ) )
1860 
1861       ENDDO
1862    ENDDO
1863   
1864 END SUBROUTINE size_distribution
1865
1866!------------------------------------------------------------------------------!
1867! Description:
1868! ------------
1869!> Sets the mass concentrations to aerosol arrays in 2a and 2b.
1870!>
1871!> Tomi Raatikainen, FMI, 29.2.2016
1872!------------------------------------------------------------------------------!
1873 SUBROUTINE set_aero_mass( ispec, ppvf2a, ppvf2b, ppnf2a, ppndist, pcore, prho )
1874   
1875    IMPLICIT NONE
1876
1877    INTEGER(iwp), INTENT(in) :: ispec  !< Aerosol species index
1878    REAL(wp), INTENT(in) ::  pcore(nbins) !< Aerosol bin mid core volume   
1879    REAL(wp), INTENT(in) ::  ppndist(0:nz+1,nbins) !< Aerosol size distribution
1880    REAL(wp), INTENT(in) ::  ppnf2a(0:nz+1) !< Number fraction for 2a   
1881    REAL(wp), INTENT(in) ::  ppvf2a(0:nz+1) !< Mass distributions for a
1882    REAL(wp), INTENT(in) ::  ppvf2b(0:nz+1) !< and b bins   
1883    REAL(wp), INTENT(in) ::  prho !< Aerosol density
1884    INTEGER(iwp) ::  b  !< loop index
1885    INTEGER(iwp) ::  c  !< loop index       
1886    INTEGER(iwp) ::  ee !< index: end
1887    INTEGER(iwp) ::  i  !< loop index
1888    INTEGER(iwp) ::  j  !< loop index
1889    INTEGER(iwp) ::  k  !< loop index
1890    INTEGER(iwp) ::  prunmode  !< 1 = initialise
1891    INTEGER(iwp) ::  ss !< index: start
1892    REAL(wp) ::  flag   !< flag to mask topography grid points
1893   
1894    prunmode = 1
1895   
1896    DO i = nxlg, nxrg
1897       DO j = nysg, nyng
1898          DO k = nzb, nzt+1 
1899!
1900!--          Predetermine flag to mask topography
1901             flag = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_0(k,j,i), 0 ) ) 
1902!             
1903!--          Regime 2a:
1904             ss = ( ispec - 1 ) * nbins + in2a
1905             ee = ( ispec - 1 ) * nbins + fn2a
1906             b = in2a
1907             DO c = ss, ee
1908                aerosol_mass(c)%conc(k,j,i) = MAX( 0.0_wp, ppvf2a(k) ) *       &
1909                               ppnf2a(k) * ppndist(k,b) * pcore(b) * prho * flag
1910                IF ( prunmode == 1 )  THEN
1911                   aerosol_mass(c)%init = MAX( 0.0_wp, MAXVAL( ppvf2a(:) ) ) * &
1912                                          MAXVAL( ppnf2a ) * pcore(b) * prho * &
1913                                          MAXVAL( ppndist(:,b) ) 
1914                ENDIF
1915                b = b+1
1916             ENDDO
1917!--          Regime 2b:
1918             IF ( .NOT. no_insoluble )  THEN
1919                ss = ( ispec - 1 ) * nbins + in2b
1920                ee = ( ispec - 1 ) * nbins + fn2b
1921                b = in2a
1922                DO c = ss, ee
1923                   aerosol_mass(c)%conc(k,j,i) = MAX( 0.0_wp, ppvf2b(k) ) * (  &
1924                                         1.0_wp - ppnf2a(k) ) * ppndist(k,b) * &
1925                                         pcore(b) * prho * flag
1926                   IF ( prunmode == 1 )  THEN
1927                      aerosol_mass(c)%init = MAX( 0.0_wp, MAXVAL( ppvf2b(:) ) )&
1928                                        * ( 1.0_wp - MAXVAL( ppnf2a ) ) *      &
1929                                        MAXVAL( ppndist(:,b) ) * pcore(b) * prho
1930                   ENDIF
1931                   b = b+1
1932                ENDDO
1933             ENDIF
1934             prunmode = 3  ! Init only once
1935          ENDDO
1936       ENDDO
1937    ENDDO
1938 END SUBROUTINE set_aero_mass
1939
1940!------------------------------------------------------------------------------!
1941! Description:
1942! ------------
1943!> Swapping of timelevels
1944!------------------------------------------------------------------------------!
1945 SUBROUTINE salsa_swap_timelevel( mod_count )
1946
1947    IMPLICIT NONE
1948
1949    INTEGER(iwp), INTENT(IN) ::  mod_count  !<
1950    INTEGER(iwp) ::  b  !<   
1951    INTEGER(iwp) ::  c  !<   
1952    INTEGER(iwp) ::  cc !<
1953    INTEGER(iwp) ::  g  !<
1954
1955!
1956!-- Example for prognostic variable "prog_var"
1957#if defined( __nopointer )
1958    IF ( myid == 0 )  THEN
1959       message_string =  ' SALSA runs only with POINTER Version'
1960       CALL message( 'salsa_swap_timelevel', 'SA0022', 1, 2, 0, 6, 0 )
1961    ENDIF
1962#else
1963   
1964    SELECT CASE ( mod_count )
1965
1966       CASE ( 0 )
1967
1968          DO  b = 1, nbins
1969             aerosol_number(b)%conc(nzb:nzt+1,nysg:nyng,nxlg:nxrg)   =>        &
1970                nconc_1(:,:,:,b)
1971             aerosol_number(b)%conc_p(nzb:nzt+1,nysg:nyng,nxlg:nxrg) =>        &
1972                nconc_2(:,:,:,b)
1973             DO  c = 1, ncc_tot
1974                cc = ( c-1 ) * nbins + b  ! required due to possible Intel18 bug
1975                aerosol_mass(cc)%conc(nzb:nzt+1,nysg:nyng,nxlg:nxrg)   =>      &
1976                   mconc_1(:,:,:,cc)
1977                aerosol_mass(cc)%conc_p(nzb:nzt+1,nysg:nyng,nxlg:nxrg) =>      &
1978                   mconc_2(:,:,:,cc)
1979             ENDDO
1980          ENDDO
1981         
1982          IF ( .NOT. salsa_gases_from_chem )  THEN
1983             DO  g = 1, ngast
1984                salsa_gas(g)%conc(nzb:nzt+1,nysg:nyng,nxlg:nxrg)   =>          &
1985                   gconc_1(:,:,:,g)
1986                salsa_gas(g)%conc_p(nzb:nzt+1,nysg:nyng,nxlg:nxrg) =>          &
1987                   gconc_2(:,:,:,g)
1988             ENDDO
1989          ENDIF
1990
1991       CASE ( 1 )
1992
1993          DO  b = 1, nbins
1994             aerosol_number(b)%conc(nzb:nzt+1,nysg:nyng,nxlg:nxrg)   =>        &
1995                nconc_2(:,:,:,b)
1996             aerosol_number(b)%conc_p(nzb:nzt+1,nysg:nyng,nxlg:nxrg) =>        &
1997                nconc_1(:,:,:,b)
1998             DO  c = 1, ncc_tot
1999                cc = ( c-1 ) * nbins + b  ! required due to possible Intel18 bug
2000                aerosol_mass(cc)%conc(nzb:nzt+1,nysg:nyng,nxlg:nxrg)   =>      &
2001                   mconc_2(:,:,:,cc)
2002                aerosol_mass(cc)%conc_p(nzb:nzt+1,nysg:nyng,nxlg:nxrg) =>      &
2003                   mconc_1(:,:,:,cc)
2004             ENDDO
2005          ENDDO
2006         
2007          IF ( .NOT. salsa_gases_from_chem )  THEN
2008             DO  g = 1, ngast
2009                salsa_gas(g)%conc(nzb:nzt+1,nysg:nyng,nxlg:nxrg)   =>          &
2010                   gconc_2(:,:,:,g)
2011                salsa_gas(g)%conc_p(nzb:nzt+1,nysg:nyng,nxlg:nxrg) =>          &
2012                   gconc_1(:,:,:,g)
2013             ENDDO
2014          ENDIF
2015
2016    END SELECT
2017#endif
2018
2019 END SUBROUTINE salsa_swap_timelevel
2020
2021
2022!------------------------------------------------------------------------------!
2023! Description:
2024! ------------
2025!> This routine reads the respective restart data.
2026!------------------------------------------------------------------------------!
2027 SUBROUTINE salsa_rrd_local 
2028
2029   
2030    IMPLICIT NONE
2031   
2032    CHARACTER (LEN=20) :: field_char   !<
2033    INTEGER(iwp) ::  b  !<   
2034    INTEGER(iwp) ::  c  !<
2035    INTEGER(iwp) ::  g  !<
2036    INTEGER(iwp) ::  i  !<
2037    INTEGER(iwp) ::  j  !<
2038    INTEGER(iwp) ::  k  !<   
2039   
2040    IF ( read_restart_data_salsa )  THEN
2041       READ ( 13 )  field_char
2042
2043       DO  WHILE ( TRIM( field_char ) /= '*** end salsa ***' )
2044       
2045          DO b = 1, nbins
2046             READ ( 13 )  aero(b)%vlolim
2047             READ ( 13 )  aero(b)%vhilim
2048             READ ( 13 )  aero(b)%dmid
2049             READ ( 13 )  aero(b)%vratiohi
2050             READ ( 13 )  aero(b)%vratiolo
2051          ENDDO
2052
2053          DO  i = nxl, nxr
2054             DO  j = nys, nyn
2055                DO k = nzb+1, nzt
2056                   DO  b = 1, nbins
2057                      READ ( 13 )  aerosol_number(b)%conc(k,j,i)
2058                      DO  c = 1, ncc_tot
2059                         READ ( 13 )  aerosol_mass((c-1)*nbins+b)%conc(k,j,i)
2060                      ENDDO
2061                   ENDDO
2062                   IF ( .NOT. salsa_gases_from_chem )  THEN
2063                      DO  g = 1, ngast
2064                         READ ( 13 )  salsa_gas(g)%conc(k,j,i)
2065                      ENDDO
2066                   ENDIF
2067                ENDDO
2068             ENDDO
2069          ENDDO
2070
2071          READ ( 13 )  field_char
2072
2073       ENDDO
2074       
2075    ENDIF
2076
2077 END SUBROUTINE salsa_rrd_local
2078   
2079
2080!------------------------------------------------------------------------------!
2081! Description:
2082! ------------
2083!> This routine writes the respective restart data.
2084!> Note that the following input variables in PARIN have to be equal between
2085!> restart runs:
2086!>    listspec, nbin, nbin2, nf2a, ncc, mass_fracs_a, mass_fracs_b
2087!------------------------------------------------------------------------------!
2088 SUBROUTINE salsa_wrd_local
2089
2090    IMPLICIT NONE
2091   
2092    INTEGER(iwp) ::  b  !<   
2093    INTEGER(iwp) ::  c  !<
2094    INTEGER(iwp) ::  g  !<
2095    INTEGER(iwp) ::  i  !<
2096    INTEGER(iwp) ::  j  !<
2097    INTEGER(iwp) ::  k  !<
2098   
2099    IF ( write_binary  .AND.  write_binary_salsa )  THEN
2100       
2101       DO b = 1, nbins
2102          WRITE ( 14 )  aero(b)%vlolim
2103          WRITE ( 14 )  aero(b)%vhilim
2104          WRITE ( 14 )  aero(b)%dmid
2105          WRITE ( 14 )  aero(b)%vratiohi
2106          WRITE ( 14 )  aero(b)%vratiolo
2107       ENDDO
2108       
2109       DO  i = nxl, nxr
2110          DO  j = nys, nyn
2111             DO  k = nzb+1, nzt
2112                DO  b = 1, nbins
2113                   WRITE ( 14 )  aerosol_number(b)%conc(k,j,i)
2114                   DO  c = 1, ncc_tot
2115                      WRITE ( 14 )  aerosol_mass((c-1)*nbins+b)%conc(k,j,i)
2116                   ENDDO
2117                ENDDO
2118                IF ( .NOT. salsa_gases_from_chem )  THEN
2119                   DO  g = 1, ngast
2120                      WRITE ( 14 )  salsa_gas(g)%conc(k,j,i)
2121                   ENDDO
2122                ENDIF
2123             ENDDO
2124          ENDDO
2125       ENDDO
2126       
2127       WRITE ( 14 )  '*** end salsa ***   '
2128         
2129    ENDIF
2130       
2131 END SUBROUTINE salsa_wrd_local   
2132
2133
2134!------------------------------------------------------------------------------!
2135! Description:
2136! ------------
2137!> Performs necessary unit and dimension conversion between the host model and
2138!> SALSA module, and calls the main SALSA routine.
2139!> Partially adobted form the original SALSA boxmodel version.
2140!> Now takes masses in as kg/kg from LES!! Converted to m3/m3 for SALSA
2141!> 05/2016 Juha: This routine is still pretty much in its original shape.
2142!>               It's dumb as a mule and twice as ugly, so implementation of
2143!>               an improved solution is necessary sooner or later.
2144!> Juha Tonttila, FMI, 2014
2145!> Jaakko Ahola, FMI, 2016
2146!> Only aerosol processes included, Mona Kurppa, UHel, 2017
2147!------------------------------------------------------------------------------!
2148 SUBROUTINE salsa_driver( i, j, prunmode )
2149
2150    USE arrays_3d,                                                             &
2151        ONLY: pt_p, q_p, rho_air_zw, u, v, w
2152       
2153    USE plant_canopy_model_mod,                                                &
2154        ONLY: lad_s
2155       
2156    USE surface_mod,                                                           &
2157        ONLY:  surf_def_h, surf_def_v, surf_lsm_h, surf_lsm_v, surf_usm_h,     &
2158               surf_usm_v
2159 
2160    IMPLICIT NONE
2161   
2162    INTEGER(iwp), INTENT(in) ::  i   !< loop index
2163    INTEGER(iwp), INTENT(in) ::  j   !< loop index
2164    INTEGER(iwp), INTENT(in) ::  prunmode !< 1: Initialization call
2165                                          !< 2: Spinup period call
2166                                          !< 3: Regular runtime call
2167!-- Local variables
2168    TYPE(t_section), DIMENSION(fn2b) ::  aero_old !< helper array
2169    INTEGER(iwp) ::  bb     !< loop index
2170    INTEGER(iwp) ::  cc     !< loop index
2171    INTEGER(iwp) ::  endi   !< end index
2172    INTEGER(iwp) ::  k_wall !< vertical index of topography top
2173    INTEGER(iwp) ::  k      !< loop index
2174    INTEGER(iwp) ::  l      !< loop index
2175    INTEGER(iwp) ::  nc_h2o !< index of H2O in the prtcl index table
2176    INTEGER(iwp) ::  ss     !< loop index
2177    INTEGER(iwp) ::  str    !< start index
2178    INTEGER(iwp) ::  vc     !< default index in prtcl
2179    REAL(wp) ::  cw_old     !< previous H2O mixing ratio
2180    REAL(wp) ::  flag       !< flag to mask topography grid points
2181    REAL(wp), DIMENSION(nzb:nzt+1) ::  in_adn !< air density (kg/m3)   
2182    REAL(wp), DIMENSION(nzb:nzt+1) ::  in_cs  !< H2O sat. vapour conc.
2183    REAL(wp), DIMENSION(nzb:nzt+1) ::  in_cw  !< H2O vapour concentration
2184    REAL(wp) ::  in_lad                       !< leaf area density (m2/m3)
2185    REAL(wp), DIMENSION(nzb:nzt+1) ::  in_p   !< pressure (Pa)     
2186    REAL(wp) ::  in_rh                        !< relative humidity                     
2187    REAL(wp), DIMENSION(nzb:nzt+1) ::  in_t   !< temperature (K)
2188    REAL(wp), DIMENSION(nzb:nzt+1) ::  in_u   !< wind magnitude (m/s)
2189    REAL(wp), DIMENSION(nzb:nzt+1) ::  kvis   !< kinematic viscosity of air(m2/s)                                           
2190    REAL(wp), DIMENSION(nzb:nzt+1,fn2b) ::  Sc      !< particle Schmidt number   
2191    REAL(wp), DIMENSION(nzb:nzt+1,fn2b) ::  vd      !< particle fall seed (m/s,
2192                                                    !< sedimentation velocity)
2193    REAL(wp), DIMENSION(nzb:nzt+1) ::  ppm_to_nconc !< Conversion factor
2194                                                    !< from ppm to #/m3                                                     
2195    REAL(wp) ::  zgso4  !< SO4
2196    REAL(wp) ::  zghno3 !< HNO3
2197    REAL(wp) ::  zgnh3  !< NH3
2198    REAL(wp) ::  zgocnv !< non-volatile OC
2199    REAL(wp) ::  zgocsv !< semi-volatile OC
2200   
2201    aero_old(:)%numc = 0.0_wp
2202    in_adn           = 0.0_wp   
2203    in_cs            = 0.0_wp
2204    in_cw            = 0.0_wp 
2205    in_lad           = 0.0_wp
2206    in_rh            = 0.0_wp
2207    in_p             = 0.0_wp 
2208    in_t             = 0.0_wp 
2209    in_u             = 0.0_wp
2210    kvis             = 0.0_wp
2211    Sc               = 0.0_wp
2212    vd               = 0.0_wp
2213    ppm_to_nconc     = 1.0_wp
2214    zgso4            = nclim
2215    zghno3           = nclim
2216    zgnh3            = nclim
2217    zgocnv           = nclim
2218    zgocsv           = nclim
2219   
2220!       
2221!-- Aerosol number is always set, but mass can be uninitialized
2222    DO cc = 1, nbins
2223       aero(cc)%volc     = 0.0_wp
2224       aero_old(cc)%volc = 0.0_wp
2225    ENDDO
2226!   
2227!-- Set the salsa runtime config (How to make this more efficient?)
2228    CALL set_salsa_runtime( prunmode )
2229!             
2230!-- Calculate thermodynamic quantities needed in SALSA
2231    CALL salsa_thrm_ij( i, j, p_ij=in_p, temp_ij=in_t, cw_ij=in_cw,            &
2232                        cs_ij=in_cs, adn_ij=in_adn )
2233!
2234!-- Magnitude of wind: needed for deposition
2235    IF ( lsdepo )  THEN
2236       in_u(nzb+1:nzt) = SQRT(                                                 &
2237                   ( 0.5_wp * ( u(nzb+1:nzt,j,i) + u(nzb+1:nzt,j,i+1) ) )**2 + & 
2238                   ( 0.5_wp * ( v(nzb+1:nzt,j,i) + v(nzb+1:nzt,j+1,i) ) )**2 + &
2239                   ( 0.5_wp * ( w(nzb:nzt-1,j,i) + w(nzb+1:nzt,j,  i) ) )**2 )
2240    ENDIF
2241!
2242!-- Calculate conversion factors for gas concentrations
2243    ppm_to_nconc = for_ppm_to_nconc * in_p / in_t
2244!
2245!-- Determine topography-top index on scalar grid
2246    k_wall = MAXLOC( MERGE( 1, 0, BTEST( wall_flags_0(:,j,i), 12 ) ),          &
2247                     DIM = 1 ) - 1     
2248               
2249    DO k = nzb+1, nzt
2250!
2251!--    Predetermine flag to mask topography
2252       flag = MERGE( 1.0_wp, 0.0_wp, BTEST( wall_flags_0(k,j,i), 0 ) )
2253!       
2254!--    Do not run inside buildings       
2255       IF ( flag == 0.0_wp )  CYCLE   
2256!
2257!--    Wind velocity for dry depositon on vegetation   
2258       IF ( lsdepo_vege  .AND.  plant_canopy  )  THEN
2259          in_lad = lad_s(k-k_wall,j,i)
2260       ENDIF       
2261!
2262!--    For initialization and spinup, limit the RH with the parameter rhlim
2263       IF ( prunmode < 3 ) THEN
2264          in_cw(k) = MIN( in_cw(k), in_cs(k) * rhlim )
2265       ELSE
2266          in_cw(k) = in_cw(k)
2267       ENDIF
2268       cw_old = in_cw(k) !* in_adn(k)
2269!               
2270!--    Set volume concentrations:
2271!--    Sulphate (SO4) or sulphuric acid H2SO4
2272       IF ( iso4 > 0 )  THEN
2273          vc = 1
2274          str = ( iso4-1 ) * nbins + 1    ! start index
2275          endi = iso4 * nbins             ! end index
2276          cc = 1
2277          DO ss = str, endi
2278             aero(cc)%volc(vc) = aerosol_mass(ss)%conc(k,j,i) / arhoh2so4
2279             cc = cc+1
2280          ENDDO
2281          aero_old(1:nbins)%volc(vc) = aero(1:nbins)%volc(vc)
2282       ENDIF
2283       
2284!--    Organic carbon (OC) compounds
2285       IF ( ioc > 0 )  THEN
2286          vc = 2
2287          str = ( ioc-1 ) * nbins + 1
2288          endi = ioc * nbins
2289          cc = 1
2290          DO ss = str, endi
2291             aero(cc)%volc(vc) = aerosol_mass(ss)%conc(k,j,i) / arhooc
2292             cc = cc+1
2293          ENDDO
2294          aero_old(1:nbins)%volc(vc) = aero(1:nbins)%volc(vc)
2295       ENDIF
2296       
2297!--    Black carbon (BC)
2298       IF ( ibc > 0 )  THEN
2299          vc = 3
2300          str = ( ibc-1 ) * nbins + 1 + fn1a
2301          endi = ibc * nbins
2302          cc = 1 + fn1a
2303          DO ss = str, endi
2304             aero(cc)%volc(vc) = aerosol_mass(ss)%conc(k,j,i) / arhobc
2305             cc = cc+1
2306          ENDDO                   
2307          aero_old(1:nbins)%volc(vc) = aero(1:nbins)%volc(vc)
2308       ENDIF
2309
2310!--    Dust (DU)
2311       IF ( idu > 0 )  THEN
2312          vc = 4
2313          str = ( idu-1 ) * nbins + 1 + fn1a
2314          endi = idu * nbins
2315          cc = 1 + fn1a
2316          DO ss = str, endi
2317             aero(cc)%volc(vc) = aerosol_mass(ss)%conc(k,j,i) / arhodu
2318             cc = cc+1
2319          ENDDO
2320          aero_old(1:nbins)%volc(vc) = aero(1:nbins)%volc(vc)
2321       ENDIF
2322
2323!--    Sea salt (SS)
2324       IF ( iss > 0 )  THEN
2325          vc = 5
2326          str = ( iss-1 ) * nbins + 1 + fn1a
2327          endi = iss * nbins
2328          cc = 1 + fn1a
2329          DO ss = str, endi
2330             aero(cc)%volc(vc) = aerosol_mass(ss)%conc(k,j,i) / arhoss 
2331             cc = cc+1
2332          ENDDO
2333          aero_old(1:nbins)%volc(vc) = aero(1:nbins)%volc(vc)
2334       ENDIF
2335
2336!--    Nitrate (NO(3-)) or nitric acid HNO3
2337       IF ( ino > 0 )  THEN
2338          vc = 6
2339          str = ( ino-1 ) * nbins + 1 
2340          endi = ino * nbins
2341          cc = 1
2342          DO ss = str, endi
2343             aero(cc)%volc(vc) = aerosol_mass(ss)%conc(k,j,i) / arhohno3
2344             cc = cc+1
2345          ENDDO
2346          aero_old(1:nbins)%volc(vc) = aero(1:nbins)%volc(vc)
2347       ENDIF
2348
2349!--    Ammonium (NH(4+)) or ammonia NH3
2350       IF ( inh > 0 )  THEN
2351          vc = 7
2352          str = ( inh-1 ) * nbins + 1
2353          endi = inh * nbins
2354          cc = 1
2355          DO ss = str, endi
2356             aero(cc)%volc(vc) = aerosol_mass(ss)%conc(k,j,i) / arhonh3 
2357             cc = cc+1
2358          ENDDO
2359          aero_old(1:nbins)%volc(vc) = aero(1:nbins)%volc(vc)
2360       ENDIF
2361
2362!--    Water (always used)
2363       nc_h2o = get_index( prtcl,'H2O' )
2364       vc = 8
2365       str = ( nc_h2o-1 ) * nbins + 1
2366       endi = nc_h2o * nbins
2367       cc = 1
2368       IF ( advect_particle_water )  THEN
2369          DO ss = str, endi
2370             aero(cc)%volc(vc) = aerosol_mass(ss)%conc(k,j,i) / arhoh2o
2371             cc = cc+1
2372          ENDDO
2373       ELSE
2374         aero(1:nbins)%volc(vc) = mclim
2375       ENDIF
2376       aero_old(1:nbins)%volc(vc) = aero(1:nbins)%volc(vc)
2377!
2378!--    Number concentrations (numc) and particle sizes
2379!--    (dwet = wet diameter, core = dry volume)
2380       DO  bb = 1, nbins
2381          aero(bb)%numc = aerosol_number(bb)%conc(k,j,i) 
2382          aero_old(bb)%numc = aero(bb)%numc
2383          IF ( aero(bb)%numc > nclim )  THEN
2384             aero(bb)%dwet = ( SUM( aero(bb)%volc(:) ) / aero(bb)%numc / api6 )&
2385                                **( 1.0_wp / 3.0_wp )
2386             aero(bb)%core = SUM( aero(bb)%volc(1:7) ) / aero(bb)%numc
2387          ELSE
2388             aero(bb)%dwet = aero(bb)%dmid
2389             aero(bb)%core = api6 * ( aero(bb)%dwet ) ** 3.0_wp
2390          ENDIF
2391       ENDDO
2392!       
2393!--    On EACH call of salsa_driver, calculate the ambient sizes of
2394!--    particles by equilibrating soluble fraction of particles with water
2395!--    using the ZSR method.
2396       in_rh = in_cw(k) / in_cs(k)
2397       IF ( prunmode==1  .OR.  .NOT. advect_particle_water )  THEN
2398          CALL equilibration( in_rh, in_t(k), aero, .TRUE. )
2399       ENDIF
2400!
2401!--    Gaseous tracer concentrations in #/m3
2402       IF ( salsa_gases_from_chem )  THEN       
2403!       
2404!--       Convert concentrations in ppm to #/m3
2405          zgso4  = chem_species(gas_index_chem(1))%conc(k,j,i) * ppm_to_nconc(k)
2406          zghno3 = chem_species(gas_index_chem(2))%conc(k,j,i) * ppm_to_nconc(k)
2407          zgnh3  = chem_species(gas_index_chem(3))%conc(k,j,i) * ppm_to_nconc(k)
2408          zgocnv = chem_species(gas_index_chem(4))%conc(k,j,i) * ppm_to_nconc(k)     
2409          zgocsv = chem_species(gas_index_chem(5))%conc(k,j,i) * ppm_to_nconc(k)                 
2410       ELSE
2411          zgso4  = salsa_gas(1)%conc(k,j,i) 
2412          zghno3 = salsa_gas(2)%conc(k,j,i) 
2413          zgnh3  = salsa_gas(3)%conc(k,j,i) 
2414          zgocnv = salsa_gas(4)%conc(k,j,i) 
2415          zgocsv = salsa_gas(5)%conc(k,j,i)
2416       ENDIF   
2417!
2418!--    ***************************************!
2419!--                   Run SALSA               !
2420!--    ***************************************!
2421       CALL run_salsa( in_p(k), in_cw(k), in_cs(k), in_t(k), in_u(k),          &
2422                       in_adn(k), in_lad, zgso4, zgocnv, zgocsv, zghno3, zgnh3,&
2423                       aero, prtcl, kvis(k), Sc(k,:), vd(k,:), dt_salsa )
2424!--    ***************************************!
2425       IF ( lsdepo ) sedim_vd(k,j,i,:) = vd(k,:)
2426!                           
2427!--    Calculate changes in concentrations
2428       DO bb = 1, nbins
2429          aerosol_number(bb)%conc(k,j,i) = aerosol_number(bb)%conc(k,j,i)      &
2430                                 +  ( aero(bb)%numc - aero_old(bb)%numc ) * flag
2431       ENDDO
2432       
2433       IF ( iso4 > 0 )  THEN
2434          vc = 1
2435          str = ( iso4-1 ) * nbins + 1
2436          endi = iso4 * nbins
2437          cc = 1
2438          DO ss = str, endi
2439             aerosol_mass(ss)%conc(k,j,i) = aerosol_mass(ss)%conc(k,j,i)       &
2440                               + ( aero(cc)%volc(vc) - aero_old(cc)%volc(vc) ) &
2441                               * arhoh2so4 * flag
2442             cc = cc+1
2443          ENDDO
2444       ENDIF
2445       
2446       IF ( ioc > 0 )  THEN
2447          vc = 2
2448          str = ( ioc-1 ) * nbins + 1
2449          endi = ioc * nbins
2450          cc = 1
2451          DO ss = str, endi
2452             aerosol_mass(ss)%conc(k,j,i) = aerosol_mass(ss)%conc(k,j,i)       &
2453                               + ( aero(cc)%volc(vc) - aero_old(cc)%volc(vc) ) &
2454                               * arhooc * flag
2455             cc = cc+1
2456          ENDDO
2457       ENDIF
2458       
2459       IF ( ibc > 0 )  THEN
2460          vc = 3
2461          str = ( ibc-1 ) * nbins + 1 + fn1a
2462          endi = ibc * nbins
2463          cc = 1 + fn1a
2464          DO ss = str, endi
2465             aerosol_mass(ss)%conc(k,j,i) = aerosol_mass(ss)%conc(k,j,i)       &
2466                               + ( aero(cc)%volc(vc) - aero_old(cc)%volc(vc) ) &
2467                               * arhobc * flag
2468             cc = cc+1
2469          ENDDO
2470       ENDIF
2471       
2472       IF ( idu > 0 )  THEN
2473          vc = 4
2474          str = ( idu-1 ) * nbins + 1 + fn1a
2475          endi = idu * nbins
2476          cc = 1 + fn1a
2477          DO ss = str, endi
2478             aerosol_mass(ss)%conc(k,j,i) = aerosol_mass(ss)%conc(k,j,i)       &
2479                               + ( aero(cc)%volc(vc) - aero_old(cc)%volc(vc) ) &
2480                               * arhodu * flag
2481             cc = cc+1
2482          ENDDO
2483       ENDIF
2484       
2485       IF ( iss > 0 )  THEN
2486          vc = 5
2487          str = ( iss-1 ) * nbins + 1 + fn1a
2488          endi = iss * nbins
2489          cc = 1 + fn1a
2490          DO ss = str, endi
2491             aerosol_mass(ss)%conc(k,j,i) = aerosol_mass(ss)%conc(k,j,i)       &
2492                               + ( aero(cc)%volc(vc) - aero_old(cc)%volc(vc) ) &
2493                               * arhoss * flag
2494             cc = cc+1
2495          ENDDO
2496       ENDIF
2497       
2498       IF ( ino > 0 )  THEN
2499          vc = 6
2500          str = ( ino-1 ) * nbins + 1
2501          endi = ino * nbins
2502          cc = 1
2503          DO ss = str, endi
2504             aerosol_mass(ss)%conc(k,j,i) = aerosol_mass(ss)%conc(k,j,i)       &
2505                               + ( aero(cc)%volc(vc) - aero_old(cc)%volc(vc) ) &
2506                               * arhohno3 * flag
2507             cc = cc+1
2508          ENDDO
2509       ENDIF
2510       
2511       IF ( inh > 0 )  THEN
2512          vc = 7
2513          str = ( ino-1 ) * nbins + 1
2514          endi = ino * nbins
2515          cc = 1
2516          DO ss = str, endi
2517             aerosol_mass(ss)%conc(k,j,i) = aerosol_mass(ss)%conc(k,j,i)       &
2518                               + ( aero(cc)%volc(vc) - aero_old(cc)%volc(vc) ) &
2519                               * arhonh3 * flag
2520             cc = cc+1
2521          ENDDO
2522       ENDIF
2523       
2524       IF ( advect_particle_water )  THEN
2525          nc_h2o = get_index( prtcl,'H2O' )
2526          vc = 8
2527          str = ( nc_h2o-1 ) * nbins + 1
2528          endi = nc_h2o * nbins
2529          cc = 1
2530          DO ss = str, endi
2531             aerosol_mass(ss)%conc(k,j,i) = aerosol_mass(ss)%conc(k,j,i)       &
2532                               + ( aero(cc)%volc(vc) - aero_old(cc)%volc(vc) ) &
2533                               * arhoh2o * flag
2534             IF ( prunmode == 1 )  THEN
2535                aerosol_mass(ss)%init(k) = MAX( aerosol_mass(ss)%init(k),      &
2536                                               aerosol_mass(ss)%conc(k,j,i) )
2537             ENDIF
2538             cc = cc+1                             
2539          ENDDO
2540       ENDIF
2541
2542!--    Condensation of precursor gases
2543       IF ( lscndgas )  THEN
2544          IF ( salsa_gases_from_chem )  THEN         
2545!         
2546!--          SO4 (or H2SO4)
2547             chem_species( gas_index_chem(1) )%conc(k,j,i) =                &
2548                            chem_species( gas_index_chem(1) )%conc(k,j,i) + &
2549                                                  ( zgso4 / ppm_to_nconc(k) - &
2550                       chem_species( gas_index_chem(1) )%conc(k,j,i) ) * flag
2551!                           
2552!--          HNO3
2553             chem_species( gas_index_chem(2) )%conc(k,j,i) =                &
2554                            chem_species( gas_index_chem(2) )%conc(k,j,i) + &
2555                                                 ( zghno3 / ppm_to_nconc(k) - &
2556                       chem_species( gas_index_chem(2) )%conc(k,j,i) ) * flag
2557!                           
2558!--          NH3
2559             chem_species( gas_index_chem(3) )%conc(k,j,i) =                &
2560                            chem_species( gas_index_chem(3) )%conc(k,j,i) + &
2561                                                  ( zgnh3 / ppm_to_nconc(k) - &
2562                       chem_species( gas_index_chem(3) )%conc(k,j,i) ) * flag
2563!                           
2564!--          non-volatile OC
2565             chem_species( gas_index_chem(4) )%conc(k,j,i) =                &
2566                            chem_species( gas_index_chem(4) )%conc(k,j,i) + &
2567                                                 ( zgocnv / ppm_to_nconc(k) - &
2568                       chem_species( gas_index_chem(4) )%conc(k,j,i) ) * flag
2569!                           
2570!--          semi-volatile OC
2571             chem_species( gas_index_chem(5) )%conc(k,j,i) =                &
2572                            chem_species( gas_index_chem(5) )%conc(k,j,i) + &
2573                                                 ( zgocsv / ppm_to_nconc(k) - &
2574                       chem_species( gas_index_chem(5) )%conc(k,j,i) ) * flag                 
2575         
2576          ELSE
2577!         
2578!--          SO4 (or H2SO4)
2579             salsa_gas(1)%conc(k,j,i) = salsa_gas(1)%conc(k,j,i) + ( zgso4 -   &
2580                                          salsa_gas(1)%conc(k,j,i) ) * flag
2581!                           
2582!--          HNO3
2583             salsa_gas(2)%conc(k,j,i) = salsa_gas(2)%conc(k,j,i) + ( zghno3 -  &
2584                                          salsa_gas(2)%conc(k,j,i) ) * flag
2585!                           
2586!--          NH3
2587             salsa_gas(3)%conc(k,j,i) = salsa_gas(3)%conc(k,j,i) + ( zgnh3 -   &
2588                                          salsa_gas(3)%conc(k,j,i) ) * flag
2589!                           
2590!--          non-volatile OC
2591             salsa_gas(4)%conc(k,j,i) = salsa_gas(4)%conc(k,j,i) + ( zgocnv -  &
2592                                          salsa_gas(4)%conc(k,j,i) ) * flag
2593!                           
2594!--          semi-volatile OC
2595             salsa_gas(5)%conc(k,j,i) = salsa_gas(5)%conc(k,j,i) + ( zgocsv -  &
2596                                          salsa_gas(5)%conc(k,j,i) ) * flag
2597          ENDIF
2598       ENDIF
2599!               
2600!--    Tendency of water vapour mixing ratio is obtained from the
2601!--    change in RH during SALSA run. This releases heat and changes pt.
2602!--    Assumes no temperature change during SALSA run.
2603!--    q = r / (1+r), Euler method for integration
2604!
2605       IF ( feedback_to_palm )  THEN
2606          q_p(k,j,i) = q_p(k,j,i) + 1.0_wp / ( in_cw(k) * in_adn(k) + 1.0_wp ) &
2607                       ** 2.0_wp * ( in_cw(k) - cw_old ) * in_adn(k) 
2608          pt_p(k,j,i) = pt_p(k,j,i) + alv / c_p * ( in_cw(k) - cw_old ) *      &
2609                        in_adn(k) / ( in_cw(k) / in_adn(k) + 1.0_wp ) ** 2.0_wp&
2610                        * pt_p(k,j,i) / in_t(k)
2611       ENDIF
2612                         
2613    ENDDO   ! k
2614!   
2615!-- Set surfaces and wall fluxes due to deposition 
2616    IF ( lsdepo_topo  .AND.  prunmode == 3 )  THEN
2617       IF ( .NOT. land_surface  .AND.  .NOT. urban_surface )  THEN
2618          CALL depo_topo( i, j, surf_def_h(0), vd, Sc, kvis, in_u, rho_air_zw )
2619          DO  l = 0, 3
2620             CALL depo_topo( i, j, surf_def_v(l), vd, Sc, kvis, in_u,          &
2621                             rho_air_zw**0.0_wp )
2622          ENDDO
2623       ELSE
2624          CALL depo_topo( i, j, surf_usm_h, vd, Sc, kvis, in_u, rho_air_zw )
2625          DO  l = 0, 3
2626             CALL depo_topo( i, j, surf_usm_v(l), vd, Sc, kvis, in_u,          &
2627                             rho_air_zw**0.0_wp )
2628          ENDDO
2629          CALL depo_topo( i, j, surf_lsm_h, vd, Sc, kvis, in_u, rho_air_zw )
2630          DO  l = 0, 3
2631             CALL depo_topo( i, j, surf_lsm_v(l), vd, Sc, kvis, in_u,          &
2632                             rho_air_zw**0.0_wp )
2633          ENDDO
2634       ENDIF
2635    ENDIF
2636   
2637 END SUBROUTINE salsa_driver
2638
2639!------------------------------------------------------------------------------!
2640! Description:
2641! ------------
2642!> The SALSA subroutine
2643!> Modified for the new aerosol datatype,
2644!> Juha Tonttila, FMI, 2014.
2645!> Only aerosol processes included, Mona Kurppa, UHel, 2017
2646!------------------------------------------------------------------------------!   
2647 SUBROUTINE run_salsa( ppres, pcw, pcs, ptemp, mag_u, adn, lad, pc_h2so4,      &
2648                       pc_ocnv, pc_ocsv, pc_hno3, pc_nh3, paero, prtcl, kvis,  &
2649                       Sc, vc, ptstep )
2650
2651    IMPLICIT NONE
2652!
2653!-- Input parameters and variables
2654    REAL(wp), INTENT(in) ::  adn    !< air density (kg/m3)
2655    REAL(wp), INTENT(in) ::  lad    !< leaf area density (m2/m3)
2656    REAL(wp), INTENT(in) ::  mag_u  !< magnitude of wind (m/s)
2657    REAL(wp), INTENT(in) ::  ppres  !< atmospheric pressure at each grid
2658                                    !< point (Pa)
2659    REAL(wp), INTENT(in) ::  ptemp  !< temperature at each grid point (K)
2660    REAL(wp), INTENT(in) ::  ptstep !< time step of salsa processes (s)
2661    TYPE(component_index), INTENT(in) :: prtcl  !< part. component index table
2662!       
2663!-- Input variables that are changed within:
2664    REAL(wp), INTENT(inout) ::  kvis     !< kinematic viscosity of air (m2/s)
2665    REAL(wp), INTENT(inout) ::  Sc(:)    !< particle Schmidt number
2666    REAL(wp), INTENT(inout) ::  vc(:)    !< particle fall speed (m/s,
2667                                         !< sedimentation velocity)
2668!-- Gas phase concentrations at each grid point (#/m3)
2669    REAL(wp), INTENT(inout) ::  pc_h2so4 !< sulphuric acid
2670    REAL(wp), INTENT(inout) ::  pc_hno3  !< nitric acid
2671    REAL(wp), INTENT(inout) ::  pc_nh3   !< ammonia
2672    REAL(wp), INTENT(inout) ::  pc_ocnv  !< nonvolatile OC
2673    REAL(wp), INTENT(inout) ::  pc_ocsv  !< semivolatile OC
2674    REAL(wp), INTENT(inout) ::  pcs      !< Saturation concentration of water
2675                                         !< vapour (kg/m3)
2676    REAL(wp), INTENT(inout) ::  pcw      !< Water vapour concentration (kg/m3)                                                   
2677    TYPE(t_section), INTENT(inout) ::  paero(fn2b) 
2678!
2679!-- Coagulation
2680    IF ( lscoag )   THEN
2681       CALL coagulation( paero, ptstep, ptemp, ppres )
2682    ENDIF
2683!
2684!-- Condensation
2685    IF ( lscnd )   THEN
2686       CALL condensation( paero, pc_h2so4, pc_ocnv, pc_ocsv,  pc_hno3, pc_nh3, &
2687                          pcw, pcs, ptemp, ppres, ptstep, prtcl )
2688    ENDIF   
2689!   
2690!-- Deposition
2691    IF ( lsdepo )  THEN
2692       CALL deposition( paero, ptemp, adn, mag_u, lad, kvis, Sc, vc ) 
2693    ENDIF       
2694!
2695!-- Size distribution bin update
2696!-- Mona: why done 3 times in SALSA-standalone?
2697    IF ( lsdistupdate )   THEN
2698       CALL distr_update( paero )
2699    ENDIF
2700   
2701  END SUBROUTINE run_salsa
2702 
2703!------------------------------------------------------------------------------!
2704! Description:
2705! ------------
2706!> Set logical switches according to the host model state and user-specified
2707!> NAMELIST options.
2708!> Juha Tonttila, FMI, 2014
2709!> Only aerosol processes included, Mona Kurppa, UHel, 2017
2710!------------------------------------------------------------------------------!
2711 SUBROUTINE set_salsa_runtime( prunmode )
2712 
2713    IMPLICIT NONE
2714   
2715    INTEGER(iwp), INTENT(in) ::  prunmode
2716   
2717    SELECT CASE(prunmode)
2718
2719       CASE(1) !< Initialization
2720          lscoag       = .FALSE.
2721          lscnd        = .FALSE.
2722          lscndgas     = .FALSE.
2723          lscndh2oae   = .FALSE.
2724          lsdepo       = .FALSE.
2725          lsdepo_vege  = .FALSE.
2726          lsdepo_topo  = .FALSE.
2727          lsdistupdate = .TRUE.
2728
2729       CASE(2)  !< Spinup period
2730          lscoag      = ( .FALSE. .AND. nlcoag   )
2731          lscnd       = ( .TRUE.  .AND. nlcnd    )
2732          lscndgas    = ( .TRUE.  .AND. nlcndgas )
2733          lscndh2oae  = ( .TRUE.  .AND. nlcndh2oae )
2734
2735       CASE(3)  !< Run
2736          lscoag       = nlcoag
2737          lscnd        = nlcnd
2738          lscndgas     = nlcndgas
2739          lscndh2oae   = nlcndh2oae
2740          lsdepo       = nldepo
2741          lsdepo_vege  = nldepo_vege
2742          lsdepo_topo  = nldepo_topo
2743          lsdistupdate = nldistupdate
2744
2745    END SELECT
2746
2747
2748 END SUBROUTINE set_salsa_runtime
2749 
2750!------------------------------------------------------------------------------!
2751! Description:
2752! ------------
2753!> Calculates the absolute temperature (using hydrostatic pressure), saturation
2754!> vapour pressure and mixing ratio over water, relative humidity and air
2755!> density needed in the SALSA model.
2756!> NOTE, no saturation adjustment takes place -> the resulting water vapour
2757!> mixing ratio can be supersaturated, allowing the microphysical calculations
2758!> in SALSA.
2759!
2760!> Juha Tonttila, FMI, 2014 (original SALSAthrm)
2761!> Mona Kurppa, UHel, 2017 (adjustment for PALM and only aerosol processes)
2762!------------------------------------------------------------------------------!
2763 SUBROUTINE salsa_thrm_ij( i, j, p_ij, temp_ij, cw_ij, cs_ij, adn_ij )
2764 
2765    USE arrays_3d,                                                             &
2766        ONLY: p, pt, q, zu
2767       
2768    USE basic_constants_and_equations_mod,                                     &
2769        ONLY:  barometric_formula, exner_function, ideal_gas_law_rho, magnus
2770       
2771    USE control_parameters,                                                    &
2772        ONLY: pt_surface, surface_pressure
2773       
2774    IMPLICIT NONE
2775   
2776    INTEGER(iwp), INTENT(in) ::  i
2777    INTEGER(iwp), INTENT(in) ::  j
2778    REAL(wp), DIMENSION(:), INTENT(inout) ::  adn_ij
2779    REAL(wp), DIMENSION(:), INTENT(inout) ::  p_ij       
2780    REAL(wp), DIMENSION(:), INTENT(inout) ::  temp_ij
2781    REAL(wp), DIMENSION(:), INTENT(inout), OPTIONAL ::  cw_ij
2782    REAL(wp), DIMENSION(:), INTENT(inout), OPTIONAL ::  cs_ij
2783    REAL(wp), DIMENSION(nzb:nzt+1) ::  e_s !< saturation vapour pressure
2784                                           !< over water (Pa)
2785    REAL(wp) ::  t_surface !< absolute surface temperature (K)
2786!
2787!-- Pressure p_ijk (Pa) = hydrostatic pressure + perturbation pressure (p)
2788    t_surface = pt_surface * exner_function( surface_pressure )
2789    p_ij(:) = 100.0_wp * barometric_formula( zu, t_surface, surface_pressure ) &
2790              + p(:,j,i)
2791!             
2792!-- Absolute ambient temperature (K)
2793    temp_ij(:) = pt(:,j,i) * exner_function( p_ij(:) )       
2794!
2795!-- Air density
2796    adn_ij(:) = ideal_gas_law_rho( p_ij(:), temp_ij(:) )
2797!
2798!-- Water vapour concentration r_v (kg/m3)
2799    IF ( PRESENT( cw_ij ) )  THEN
2800       cw_ij(:) = ( q(:,j,i) / ( 1.0_wp - q(:,j,i) ) ) * adn_ij(:) 
2801    ENDIF
2802!
2803!-- Saturation mixing ratio r_s (kg/kg) from vapour pressure at temp (Pa)
2804    IF ( PRESENT( cs_ij ) )  THEN
2805       e_s(:) = magnus( temp_ij(:) ) 
2806       cs_ij(:) = ( 0.622_wp * e_s / ( p_ij(:) - e_s(:) ) ) * adn_ij(:) 
2807    ENDIF
2808   
2809 END SUBROUTINE salsa_thrm_ij
2810
2811!------------------------------------------------------------------------------!
2812! Description:
2813! ------------
2814!> Calculates ambient sizes of particles by equilibrating soluble fraction of
2815!> particles with water using the ZSR method (Stokes and Robinson, 1966).
2816!> Method:
2817!> Following chemical components are assumed water-soluble
2818!> - (ammonium) sulphate (100%)
2819!> - sea salt (100 %)
2820!> - organic carbon (epsoc * 100%)
2821!> Exact thermodynamic considerations neglected.
2822!> - If particles contain no sea salt, calculation according to sulphate
2823!>   properties
2824!> - If contain sea salt but no sulphate, calculation according to sea salt
2825!>   properties
2826!> - If contain both sulphate and sea salt -> the molar fraction of these
2827!>   compounds determines which one of them is used as the basis of calculation.
2828!> If sulphate and sea salt coexist in a particle, it is assumed that the Cl is
2829!> replaced by sulphate; thus only either sulphate + organics or sea salt +
2830!> organics is included in the calculation of soluble fraction.
2831!> Molality parameterizations taken from Table 1 of Tang: Thermodynamic and
2832!> optical properties of mixed-salt aerosols of atmospheric importance,
2833!> J. Geophys. Res., 102 (D2), 1883-1893 (1997)
2834!
2835!> Coded by:
2836!> Hannele Korhonen (FMI) 2005
2837!> Harri Kokkola (FMI) 2006
2838!> Matti Niskanen(FMI) 2012
2839!> Anton Laakso  (FMI) 2013
2840!> Modified for the new aerosol datatype, Juha Tonttila (FMI) 2014
2841!
2842!> fxm: should sea salt form a solid particle when prh is very low (even though
2843!> it could be mixed with e.g. sulphate)?
2844!> fxm: crashes if no sulphate or sea salt
2845!> fxm: do we really need to consider Kelvin effect for subrange 2
2846!------------------------------------------------------------------------------!     
2847 SUBROUTINE equilibration( prh, ptemp, paero, init )
2848     
2849    IMPLICIT NONE
2850!
2851!-- Input variables
2852    LOGICAL, INTENT(in) ::  init   !< TRUE: Initialization call
2853                                   !< FALSE: Normal runtime: update water
2854                                   !<        content only for 1a
2855    REAL(wp), INTENT(in) ::  prh   !< relative humidity [0-1]
2856    REAL(wp), INTENT(in) ::  ptemp !< temperature (K)
2857!
2858!-- Output variables
2859    TYPE(t_section), INTENT(inout) ::  paero(fn2b)     
2860!
2861!-- Local
2862    INTEGER(iwp) :: b      !< loop index
2863    INTEGER(iwp) :: counti  !< loop index
2864    REAL(wp) ::  zaw        !< water activity [0-1]       
2865    REAL(wp) ::  zbinmol(7) !< binary molality of each components (mol/kg)
2866    REAL(wp) ::  zcore      !< Volume of dry particle   
2867    REAL(wp) ::  zdold      !< Old diameter
2868    REAL(wp) ::  zdwet      !< Wet diameter or mean droplet diameter
2869    REAL(wp) ::  zke        !< Kelvin term in the Köhler equation
2870    REAL(wp) ::  zlwc       !< liquid water content [kg/m3-air]
2871    REAL(wp) ::  zrh        !< Relative humidity
2872    REAL(wp) ::  zvpart(7)  !< volume of chem. compounds in one particle
2873   
2874    zaw       = 0.0_wp
2875    zbinmol   = 0.0_wp
2876    zcore     = 0.0_wp
2877    zdold     = 0.0_wp
2878    zdwet     = 0.0_wp
2879    zlwc      = 0.0_wp
2880    zrh       = 0.0_wp
2881   
2882!               
2883!-- Relative humidity:
2884    zrh = prh
2885    zrh = MAX( zrh, 0.05_wp )
2886    zrh = MIN( zrh, 0.98_wp)   
2887!
2888!-- 1) Regime 1: sulphate and partly water-soluble OC. Done for every CALL
2889    DO  b = in1a, fn1a   ! size bin
2890         
2891       zbinmol = 0.0_wp
2892       zdold   = 1.0_wp 
2893       zke     = 1.02_wp
2894       
2895       IF ( paero(b)%numc > nclim )  THEN
2896!
2897!--       Volume in one particle
2898          zvpart = 0.0_wp
2899          zvpart(1:2) = paero(b)%volc(1:2) / paero(b)%numc
2900          zvpart(6:7) = paero(b)%volc(6:7) / paero(b)%numc
2901!               
2902!--       Total volume and wet diameter of one dry particle
2903          zcore = SUM( zvpart(1:2) )
2904          zdwet = paero(b)%dwet
2905         
2906          counti = 0
2907          DO  WHILE ( ABS( zdwet / zdold - 1.0_wp ) > 1.0E-2_wp ) 
2908         
2909             zdold = MAX( zdwet, 1.0E-20_wp )
2910             zaw = MAX( 1.0E-3_wp, zrh / zke ) ! To avoid underflow
2911!                   
2912!--          Binary molalities (mol/kg):
2913!--          Sulphate
2914             zbinmol(1) = 1.1065495E+2_wp - 3.6759197E+2_wp * zaw              &
2915                                          + 5.0462934E+2_wp * zaw**2.0_wp      &
2916                                          - 3.1543839E+2_wp * zaw**3.0_wp      &
2917                                          + 6.770824E+1_wp  * zaw**4.0_wp 
2918!--          Organic carbon                     
2919             zbinmol(2) = 1.0_wp / ( zaw * amh2o ) - 1.0_wp / amh2o
2920!--          Nitric acid                             
2921             zbinmol(6) = 2.306844303E+1_wp - 3.563608869E+1_wp * zaw          &
2922                                            - 6.210577919E+1_wp * zaw**2.0_wp  &
2923                                            + 5.510176187E+2_wp * zaw**3.0_wp  &
2924                                            - 1.460055286E+3_wp * zaw**4.0_wp  &
2925                                            + 1.894467542E+3_wp * zaw**5.0_wp  &
2926                                            - 1.220611402E+3_wp * zaw**6.0_wp  &
2927                                            + 3.098597737E+2_wp * zaw**7.0_wp 
2928!
2929!--          Calculate the liquid water content (kg/m3-air) using ZSR (see e.g.
2930!--          Eq. 10.98 in Seinfeld and Pandis (2006))
2931             zlwc = ( paero(b)%volc(1) * ( arhoh2so4 / amh2so4 ) ) /           &
2932                    zbinmol(1) + epsoc * paero(b)%volc(2) * ( arhooc / amoc )  &
2933                    / zbinmol(2) + ( paero(b)%volc(6) * ( arhohno3/amhno3 ) )  &
2934                    / zbinmol(6)
2935!                           
2936!--          Particle wet diameter (m)
2937             zdwet = ( zlwc / paero(b)%numc / arhoh2o / api6 +                 &
2938                     ( SUM( zvpart(6:7) ) / api6 ) +      &
2939                       zcore / api6 )**( 1.0_wp / 3.0_wp )
2940!                             
2941!--          Kelvin effect (Eq. 10.85 in in Seinfeld and Pandis (2006)). Avoid
2942!--          overflow.
2943             zke = EXP( MIN( 50.0_wp,                                          &
2944                       4.0_wp * surfw0 * amvh2so4 / ( abo * ptemp *  zdwet ) ) )
2945             
2946             counti = counti + 1
2947             IF ( counti > 1000 )  THEN
2948                message_string = 'Subrange 1: no convergence!'
2949                CALL message( 'salsa_mod: equilibration', 'SA0042',            &
2950                              1, 2, 0, 6, 0 )
2951             ENDIF
2952          ENDDO
2953!               
2954!--       Instead of lwc, use the volume concentration of water from now on
2955!--       (easy to convert...)
2956          paero(b)%volc(8) = zlwc / arhoh2o
2957!               
2958!--       If this is initialization, update the core and wet diameter
2959          IF ( init )  THEN
2960             paero(b)%dwet = zdwet
2961             paero(b)%core = zcore
2962          ENDIF
2963         
2964       ELSE
2965!--       If initialization
2966!--       1.2) empty bins given bin average values 
2967          IF ( init )  THEN
2968             paero(b)%dwet = paero(b)%dmid
2969             paero(b)%core = api6 * paero(b)%dmid ** 3.0_wp
2970          ENDIF
2971         
2972       ENDIF
2973             
2974    ENDDO !< b
2975!
2976!-- 2) Regime 2a: sulphate, OC, BC and sea salt
2977!--    This is done only for initialization call, otherwise the water contents
2978!--    are computed via condensation
2979    IF ( init )  THEN
2980       DO  b = in2a, fn2b
2981             
2982!--       Initialize
2983          zke     = 1.02_wp
2984          zbinmol = 0.0_wp
2985          zdold   = 1.0_wp
2986!               
2987!--       1) Particle properties calculated for non-empty bins
2988          IF ( paero(b)%numc > nclim )  THEN
2989!               
2990!--          Volume in one particle [fxm]
2991             zvpart = 0.0_wp
2992             zvpart(1:7) = paero(b)%volc(1:7) / paero(b)%numc
2993!
2994!--          Total volume and wet diameter of one dry particle [fxm]
2995             zcore = SUM( zvpart(1:5) )
2996             zdwet = paero(b)%dwet
2997
2998             counti = 0
2999             DO  WHILE ( ABS( zdwet / zdold - 1.0_wp ) > 1.0E-12_wp )
3000             
3001                zdold = MAX( zdwet, 1.0E-20_wp )
3002                zaw = zrh / zke
3003!                     
3004!--             Binary molalities (mol/kg):
3005!--             Sulphate
3006                zbinmol(1) = 1.1065495E+2_wp - 3.6759197E+2_wp * zaw           & 
3007                        + 5.0462934E+2_wp * zaw**2 - 3.1543839E+2_wp * zaw**3  &
3008                        + 6.770824E+1_wp  * zaw**4 
3009!--             Organic carbon                       
3010                zbinmol(2) = 1.0_wp / ( zaw * amh2o ) - 1.0_wp / amh2o
3011!--             Nitric acid
3012                zbinmol(6) = 2.306844303E+1_wp - 3.563608869E+1_wp * zaw       &
3013                     - 6.210577919E+1_wp * zaw**2 + 5.510176187E+2_wp * zaw**3 &
3014                     - 1.460055286E+3_wp * zaw**4 + 1.894467542E+3_wp * zaw**5 &
3015                     - 1.220611402E+3_wp * zaw**6 + 3.098597737E+2_wp * zaw**7 
3016!--             Sea salt (natrium chloride)                                 
3017                zbinmol(5) = 5.875248E+1_wp - 1.8781997E+2_wp * zaw            &
3018                         + 2.7211377E+2_wp * zaw**2 - 1.8458287E+2_wp * zaw**3 &
3019                         + 4.153689E+1_wp  * zaw**4 
3020!                                 
3021!--             Calculate the liquid water content (kg/m3-air)
3022                zlwc = ( paero(b)%volc(1) * ( arhoh2so4 / amh2so4 ) ) /        &
3023                       zbinmol(1) + epsoc * ( paero(b)%volc(2) * ( arhooc /    &
3024                       amoc ) ) / zbinmol(2) + ( paero(b)%volc(6) * ( arhohno3 &
3025                       / amhno3 ) ) / zbinmol(6) + ( paero(b)%volc(5) *        &
3026                       ( arhoss / amss ) ) / zbinmol(5)
3027                       
3028!--             Particle wet radius (m)
3029                zdwet = ( zlwc / paero(b)%numc / arhoh2o / api6 +              &
3030                          ( SUM( zvpart(6:7) ) / api6 )  + &
3031                           zcore / api6 ) ** ( 1.0_wp / 3.0_wp )
3032!                               
3033!--             Kelvin effect (Eq. 10.85 in Seinfeld and Pandis (2006))
3034                zke = EXP( MIN( 50.0_wp,                                       &
3035                        4.0_wp * surfw0 * amvh2so4 / ( abo * zdwet * ptemp ) ) )
3036                         
3037                counti = counti + 1
3038                IF ( counti > 1000 )  THEN
3039                   message_string = 'Subrange 2: no convergence!'
3040                CALL message( 'salsa_mod: equilibration', 'SA0043',            &
3041                              1, 2, 0, 6, 0 )
3042                ENDIF
3043             ENDDO
3044!                   
3045!--          Liquid water content; instead of LWC use the volume concentration
3046             paero(b)%volc(8) = zlwc / arhoh2o
3047             paero(b)%dwet    = zdwet
3048             paero(b)%core    = zcore
3049             
3050          ELSE
3051!--          2.2) empty bins given bin average values
3052             paero(b)%dwet = paero(b)%dmid
3053             paero(b)%core = api6 * paero(b)%dmid ** 3.0_wp
3054          ENDIF
3055               
3056       ENDDO   ! b
3057    ENDIF
3058
3059 END SUBROUTINE equilibration
3060 
3061!------------------------------------------------------------------------------!
3062!> Description:
3063!> ------------
3064!> Calculation of the settling velocity vc (m/s) per aerosol size bin and
3065!> deposition on plant canopy (lsdepo_vege).
3066!
3067!> Deposition is based on either the scheme presented in:
3068!> Zhang et al. (2001), Atmos. Environ. 35, 549-560 (includes collection due to
3069!> Brownian diffusion, impaction, interception and sedimentation)
3070!> OR
3071!> Petroff & Zhang (2010), Geosci. Model Dev. 3, 753-769 (includes also
3072!> collection due to turbulent impaction)
3073!
3074!> Equation numbers refer to equation in Jacobson (2005): Fundamentals of
3075!> Atmospheric Modeling, 2nd Edition.
3076!
3077!> Subroutine follows closely sedim_SALSA in UCLALES-SALSA written by Juha
3078!> Tonttila (KIT/FMI) and Zubair Maalick (UEF).
3079!> Rewritten to PALM by Mona Kurppa (UH), 2017.
3080!
3081!> Call for grid point i,j,k
3082!------------------------------------------------------------------------------!
3083
3084 SUBROUTINE deposition( paero, tk, adn, mag_u, lad, kvis, Sc, vc )
3085 
3086    USE plant_canopy_model_mod,                                                &
3087        ONLY: cdc
3088 
3089    IMPLICIT NONE
3090   
3091    REAL(wp), INTENT(in)    ::  adn    !< air density (kg/m3) 
3092    REAL(wp), INTENT(out)   ::  kvis   !< kinematic viscosity of air (m2/s)
3093    REAL(wp), INTENT(in) ::     lad    !< leaf area density (m2/m3)
3094    REAL(wp), INTENT(in)    ::  mag_u  !< wind velocity (m/s)
3095    REAL(wp), INTENT(out)   ::  Sc(:)  !< particle Schmidt number 
3096    REAL(wp), INTENT(in)    ::  tk     !< abs.temperature (K)   
3097    REAL(wp), INTENT(out)   ::  vc(:)  !< critical fall speed i.e. settling
3098                                       !< velocity of an aerosol particle (m/s)
3099    TYPE(t_section), INTENT(inout) ::  paero(fn2b)       
3100   
3101    INTEGER(iwp) ::  b      !< loop index
3102    INTEGER(iwp) ::  c      !< loop index
3103    REAL(wp) ::  avis       !< molecular viscocity of air (kg/(m*s))
3104    REAL(wp), PARAMETER ::  c_A = 1.249_wp !< Constants A, B and C for
3105    REAL(wp), PARAMETER ::  c_B = 0.42_wp  !< calculating  the Cunningham 
3106    REAL(wp), PARAMETER ::  c_C = 0.87_wp  !< slip-flow correction (Cc) 
3107                                           !< according to Jacobson (2005),
3108                                           !< Eq. 15.30
3109    REAL(wp) ::  Cc         !< Cunningham slip-flow correction factor     
3110    REAL(wp) ::  Kn         !< Knudsen number   
3111    REAL(wp) ::  lambda     !< molecular mean free path (m)
3112    REAL(wp) ::  mdiff      !< particle diffusivity coefficient   
3113    REAL(wp) ::  pdn        !< particle density (kg/m3)     
3114    REAL(wp) ::  ustar      !< friction velocity (m/s)   
3115    REAL(wp) ::  va         !< thermal speed of an air molecule (m/s)
3116    REAL(wp) ::  zdwet      !< wet diameter (m)                             
3117!
3118!-- Initialise
3119    Cc            = 0.0_wp
3120    Kn            = 0.0_wp
3121    mdiff         = 0.0_wp
3122    pdn           = 1500.0_wp    ! default value
3123    ustar         = 0.0_wp 
3124!
3125!-- Molecular viscosity of air (Eq. 4.54)
3126    avis = 1.8325E-5_wp * ( 416.16_wp / ( tk + 120.0_wp ) ) * ( tk /           &
3127           296.16_wp )**1.5_wp
3128!             
3129!-- Kinematic viscosity (Eq. 4.55)
3130    kvis =  avis / adn
3131!       
3132!-- Thermal velocity of an air molecule (Eq. 15.32)
3133    va = SQRT( 8.0_wp * abo * tk / ( pi * am_airmol ) ) 
3134!
3135!-- Mean free path (m) (Eq. 15.24)
3136    lambda = 2.0_wp * avis / ( adn * va )
3137   
3138    DO  b = 1, nbins
3139   
3140       IF ( paero(b)%numc < nclim )  CYCLE
3141       zdwet = paero(b)%dwet
3142!
3143!--    Knudsen number (Eq. 15.23)
3144       Kn = MAX( 1.0E-2_wp, lambda / ( zdwet * 0.5_wp ) ) ! To avoid underflow
3145!
3146!--    Cunningham slip-flow correction (Eq. 15.30)
3147       Cc = 1.0_wp + Kn * ( c_A + c_B * EXP( -c_C / Kn ) )
3148
3149!--    Particle diffusivity coefficient (Eq. 15.29)
3150       mdiff = ( abo * tk * Cc ) / ( 3.0_wp * pi * avis * zdwet )
3151!       
3152!--    Particle Schmidt number (Eq. 15.36)
3153       Sc(b) = kvis / mdiff       
3154!       
3155!--    Critical fall speed i.e. settling velocity  (Eq. 20.4)                 
3156       vc(b) = MIN( 1.0_wp, terminal_vel( 0.5_wp * zdwet, pdn, adn, avis, Cc) )
3157       
3158       IF ( lsdepo_vege  .AND.  plant_canopy  .AND.  lad > 0.0_wp )  THEN
3159!       
3160!--       Friction velocity calculated following Prandtl (1925):
3161          ustar = SQRT( cdc ) * mag_u
3162          CALL depo_vege( paero, b, vc(b), mag_u, ustar, kvis, Sc(b), lad )
3163       ENDIF
3164    ENDDO
3165 
3166 END SUBROUTINE deposition
3167 
3168!------------------------------------------------------------------------------!
3169! Description:
3170! ------------
3171!> Calculate change in number and volume concentrations due to deposition on
3172!> plant canopy.
3173!------------------------------------------------------------------------------!
3174 SUBROUTINE depo_vege( paero, b, vc, mag_u, ustar, kvis_a, Sc, lad )
3175 
3176    IMPLICIT NONE
3177   
3178    INTEGER(iwp), INTENT(in) ::  b  !< loop index
3179    REAL(wp), INTENT(in) ::  kvis_a !< kinematic viscosity of air (m2/s)
3180    REAL(wp), INTENT(in) ::  lad    !< leaf area density (m2/m3)
3181    REAL(wp), INTENT(in) ::  mag_u  !< wind velocity (m/s)   
3182    REAL(wp), INTENT(in) ::  Sc     !< particle Schmidt number
3183    REAL(wp), INTENT(in) ::  ustar  !< friction velocity (m/s)                                   
3184    REAL(wp), INTENT(in) ::  vc     !< terminal velocity (m/s) 
3185    TYPE(t_section), INTENT(inout) ::  paero(fn2b) 
3186   
3187    INTEGER(iwp) ::  c      !< loop index
3188    REAL(wp), PARAMETER ::  c_A = 1.249_wp !< Constants A, B and C for
3189    REAL(wp), PARAMETER ::  c_B = 0.42_wp  !< calculating  the Cunningham 
3190    REAL(wp), PARAMETER ::  c_C = 0.87_wp  !< slip-flow correction (Cc) 
3191                                           !< according to Jacobson (2005),
3192                                           !< Eq. 15.30
3193    REAL(wp) ::  alpha       !< parameter, Table 3 in Zhang et al. (2001) 
3194    REAL(wp) ::  depo        !< deposition efficiency
3195    REAL(wp) ::  C_Br        !< coefficient for Brownian diffusion
3196    REAL(wp) ::  C_IM        !< coefficient for inertial impaction
3197    REAL(wp) ::  C_IN        !< coefficient for interception
3198    REAL(wp) ::  C_IT        !< coefficient for turbulent impaction   
3199    REAL(wp) ::  gamma       !< parameter, Table 3 in Zhang et al. (2001)   
3200    REAL(wp) ::  par_A       !< parameter A for the characteristic radius of
3201                             !< collectors, Table 3 in Zhang et al. (2001)   
3202    REAL(wp) ::  rt          !< the overall quasi-laminar resistance for
3203                             !< particles
3204    REAL(wp) ::  St          !< Stokes number for smooth surfaces or bluff
3205                             !< surface elements                                 
3206    REAL(wp) ::  tau_plus    !< dimensionless particle relaxation time   
3207    REAL(wp) ::  v_bd        !< deposition velocity due to Brownian diffusion
3208    REAL(wp) ::  v_im        !< deposition velocity due to impaction
3209    REAL(wp) ::  v_in        !< deposition velocity due to interception
3210    REAL(wp) ::  v_it        !< deposition velocity due to turbulent impaction                               
3211!
3212!-- Initialise
3213    depo     = 0.0_wp 
3214    rt       = 0.0_wp
3215    St       = 0.0_wp
3216    tau_plus = 0.0_wp
3217    v_bd     = 0.0_wp     
3218    v_im     = 0.0_wp       
3219    v_in     = 0.0_wp       
3220    v_it     = 0.0_wp         
3221       
3222    IF ( depo_vege_type == 'zhang2001' )  THEN
3223!       
3224!--    Parameters for the land use category 'deciduous broadleaf trees'(Table 3)     
3225       par_A = 5.0E-3_wp
3226       alpha = 0.8_wp
3227       gamma = 0.56_wp 
3228!       
3229!--    Stokes number for vegetated surfaces (Seinfeld & Pandis (2006): Eq.19.24) 
3230       St = vc * ustar / ( g * par_A )         
3231!         
3232!--    The overall quasi-laminar resistance for particles (Zhang et al., Eq. 5)       
3233       rt = MAX( EPSILON( 1.0_wp ), ( 3.0_wp * ustar * EXP( -St**0.5_wp ) *    &
3234                         ( Sc**( -gamma ) + ( St / ( alpha + St ) )**2.0_wp +  &
3235                           0.5_wp * ( paero(b)%dwet / par_A )**2.0_wp ) ) )
3236       depo = ( rt + vc ) * lad
3237       paero(b)%numc = paero(b)%numc - depo * paero(b)%numc * dt_salsa
3238       DO  c = 1, maxspec+1
3239          paero(b)%volc(c) = paero(b)%volc(c) - depo * paero(b)%volc(c) *      &
3240                             dt_salsa
3241       ENDDO
3242       
3243    ELSEIF ( depo_vege_type == 'petroff2010' )  THEN
3244!
3245!--    vd = v_BD + v_IN + v_IM + v_IT + vc
3246!--    Deposition efficiencies from Table 1. Constants from Table 2.
3247       C_Br  = 1.262_wp
3248       C_IM  = 0.130_wp
3249       C_IN  = 0.216_wp
3250       C_IT  = 0.056_wp
3251       par_A = 0.03_wp   ! Here: leaf width (m)     
3252!       
3253!--    Stokes number for vegetated surfaces (Seinfeld & Pandis (2006): Eq.19.24) 
3254       St = vc * ustar / ( g * par_A )         
3255!
3256!--    Non-dimensional relexation time of the particle on top of canopy
3257       tau_plus = vc * ustar**2.0_wp / ( kvis_a * g ) 
3258!
3259!--    Brownian diffusion
3260       v_bd = mag_u * C_Br * Sc**( -2.0_wp / 3.0_wp ) *                        &
3261              ( mag_u * par_A / kvis_a )**( -0.5_wp )
3262!
3263!--    Interception
3264       v_in = mag_u * C_IN * paero(b)%dwet / par_A * ( 2.0_wp + LOG( 2.0_wp *  &
3265              par_A / paero(b)%dwet ) )                     
3266!
3267!--    Impaction: Petroff (2009) Eq. 18
3268       v_im = mag_u * C_IM * ( St / ( St + 0.47_wp ) )**2.0_wp
3269       
3270       IF ( tau_plus < 20.0_wp )  THEN
3271          v_it = 2.5E-3_wp * C_IT * tau_plus**2.0_wp
3272       ELSE
3273          v_it = C_IT
3274       ENDIF
3275       depo = ( v_bd + v_in + v_im + v_it + vc ) * lad     
3276       paero(b)%numc = paero(b)%numc - depo * paero(b)%numc * dt_salsa     
3277       DO  c = 1, maxspec+1
3278          paero(b)%volc(c) = paero(b)%volc(c) - depo * paero(b)%volc(c) *      &
3279                             dt_salsa
3280       ENDDO
3281    ENDIF 
3282 
3283 END SUBROUTINE depo_vege
3284 
3285!------------------------------------------------------------------------------!
3286! Description:
3287! ------------ 
3288!> Calculate deposition on horizontal and vertical surfaces. Implement as
3289!> surface flux.
3290!------------------------------------------------------------------------------!
3291
3292 SUBROUTINE depo_topo( i, j, surf, vc, Sc, kvis, mag_u, norm )
3293 
3294    USE surface_mod,                                                           &
3295        ONLY:  surf_type
3296 
3297    IMPLICIT NONE
3298   
3299    INTEGER(iwp), INTENT(in) ::  i     !< loop index
3300    INTEGER(iwp), INTENT(in) ::  j     !< loop index
3301    REAL(wp), INTENT(in) ::  kvis(:)   !< kinematic viscosity of air (m2/s)
3302    REAL(wp), INTENT(in) ::  mag_u(:)  !< wind velocity (m/s)                                                 
3303    REAL(wp), INTENT(in) ::  norm(:)   !< normalisation (usually air density)
3304    REAL(wp), INTENT(in) ::  Sc(:,:)  !< particle Schmidt number
3305    REAL(wp), INTENT(in) ::  vc(:,:)  !< terminal velocity (m/s)   
3306    TYPE(surf_type), INTENT(inout) :: surf  !< respective surface type
3307    INTEGER(iwp) ::  b      !< loop index
3308    INTEGER(iwp) ::  c      !< loop index
3309    INTEGER(iwp) ::  k      !< loop index
3310    INTEGER(iwp) ::  m      !< loop index
3311    INTEGER(iwp) ::  surf_e !< End index of surface elements at (j,i)-gridpoint
3312    INTEGER(iwp) ::  surf_s !< Start index of surface elements at (j,i)-gridpoint
3313    REAL(wp) ::  alpha      !< parameter, Table 3 in Zhang et al. (2001)
3314    REAL(wp) ::  C_Br       !< coefficient for Brownian diffusion
3315    REAL(wp) ::  C_IM       !< coefficient for inertial impaction
3316    REAL(wp) ::  C_IN       !< coefficient for interception
3317    REAL(wp) ::  C_IT       !< coefficient for turbulent impaction
3318    REAL(wp) ::  depo       !< deposition efficiency
3319    REAL(wp) ::  gamma      !< parameter, Table 3 in Zhang et al. (2001)
3320    REAL(wp) ::  par_A      !< parameter A for the characteristic radius of
3321                            !< collectors, Table 3 in Zhang et al. (2001)
3322    REAL(wp) ::  rt         !< the overall quasi-laminar resistance for
3323                            !< particles
3324    REAL(wp) ::  St         !< Stokes number for bluff surface elements 
3325    REAL(wp) ::  tau_plus   !< dimensionless particle relaxation time   
3326    REAL(wp) ::  v_bd       !< deposition velocity due to Brownian diffusion
3327    REAL(wp) ::  v_im       !< deposition velocity due to impaction
3328    REAL(wp) ::  v_in       !< deposition velocity due to interception
3329    REAL(wp) ::  v_it       !< deposition velocity due to turbulent impaction 
3330!
3331!-- Initialise
3332    rt       = 0.0_wp
3333    St       = 0.0_wp
3334    tau_plus = 0.0_wp
3335    v_bd     = 0.0_wp     
3336    v_im     = 0.0_wp       
3337    v_in     = 0.0_wp       
3338    v_it     = 0.0_wp                                 
3339    surf_s   = surf%start_index(j,i)
3340    surf_e   = surf%end_index(j,i) 
3341   
3342    DO  m = surf_s, surf_e
3343       k = surf%k(m)       
3344       DO  b = 1, nbins
3345          IF ( aerosol_number(b)%conc(k,j,i) <= nclim  .OR.                    &
3346               Sc(k+1,b) < 1.0_wp )  CYCLE   
3347                   
3348          IF ( depo_topo_type == 'zhang2001' )  THEN
3349!       
3350!--          Parameters for the land use category 'urban' in Table 3
3351             alpha = 1.5_wp
3352             gamma = 0.56_wp 
3353             par_A = 10.0E-3_wp
3354!       
3355!--          Stokes number for smooth surfaces or surfaces with bluff roughness
3356!--          elements (Seinfeld and Pandis, 2nd edition (2006): Eq. 19.23)       
3357             St = MAX( 0.01_wp, vc(k+1,b) * surf%us(m) ** 2.0_wp /             &
3358                       ( g * kvis(k+1)  ) ) 
3359!         
3360!--          The overall quasi-laminar resistance for particles (Eq. 5)       
3361             rt = MAX( EPSILON( 1.0_wp ), ( 3.0_wp * surf%us(m) * (            &
3362                       Sc(k+1,b)**( -gamma ) + ( St / ( alpha + St ) )**2.0_wp &
3363                        + 0.5_wp * ( Ra_dry(k,j,i,b) / par_A )**2.0_wp ) *     &
3364                       EXP( -St**0.5_wp ) ) ) 
3365             depo = vc(k+1,b) + rt
3366             
3367          ELSEIF ( depo_topo_type == 'petroff2010' )  THEN 
3368!
3369!--          vd = v_BD + v_IN + v_IM + v_IT + vc
3370!--          Deposition efficiencies from Table 1. Constants from Table 2.
3371             C_Br  = 1.262_wp
3372             C_IM  = 0.130_wp
3373             C_IN  = 0.216_wp
3374             C_IT  = 0.056_wp
3375             par_A = 0.03_wp   ! Here: leaf width (m) 
3376!       
3377!--          Stokes number for smooth surfaces or surfaces with bluff roughness
3378!--          elements (Seinfeld and Pandis, 2nd edition (2006): Eq. 19.23)       
3379             St = MAX( 0.01_wp, vc(k+1,b) * surf%us(m) ** 2.0_wp /             &
3380                       ( g *  kvis(k+1) ) )             
3381!
3382!--          Non-dimensional relexation time of the particle on top of canopy
3383             tau_plus = vc(k+1,b) * surf%us(m)**2.0_wp / ( kvis(k+1) * g ) 
3384!
3385!--          Brownian diffusion
3386             v_bd = mag_u(k+1) * C_Br * Sc(k+1,b)**( -2.0_wp / 3.0_wp ) *      &
3387                    ( mag_u(k+1) * par_A / kvis(k+1) )**( -0.5_wp )
3388!
3389!--          Interception
3390             v_in = mag_u(k+1) * C_IN * Ra_dry(k,j,i,b)/ par_A * ( 2.0_wp +    &
3391                    LOG( 2.0_wp * par_A / Ra_dry(k,j,i,b) ) )                     
3392!
3393!--          Impaction: Petroff (2009) Eq. 18
3394             v_im = mag_u(k+1) * C_IM * ( St / ( St + 0.47_wp ) )**2.0_wp
3395             
3396             IF ( tau_plus < 20.0_wp )  THEN
3397                v_it = 2.5E-3_wp * C_IT * tau_plus**2.0_wp
3398             ELSE
3399                v_it = C_IT
3400             ENDIF
3401             depo =  v_bd + v_in + v_im + v_it + vc(k+1,b)       
3402         
3403          ENDIF
3404          IF ( lod_aero == 3  .OR.  salsa_source_mode ==  'no_source' )  THEN
3405             surf%answs(m,b) = -depo * norm(k) * aerosol_number(b)%conc(k,j,i) 
3406             DO  c = 1, ncc_tot   
3407                surf%amsws(m,(c-1)*nbins+b) = -depo *  norm(k) *               &
3408                                         aerosol_mass((c-1)*nbins+b)%conc(k,j,i)
3409             ENDDO    ! c
3410          ELSE
3411             surf%answs(m,b) = SUM( aerosol_number(b)%source(:,j,i) ) -        &
3412                               MAX( 0.0_wp, depo * norm(k) *                   &
3413                               aerosol_number(b)%conc(k,j,i) )
3414             DO  c = 1, ncc_tot   
3415                surf%amsws(m,(c-1)*nbins+b) = SUM(                             &
3416                               aerosol_mass((c-1)*nbins+b)%source(:,j,i) ) -   &
3417                               MAX(  0.0_wp, depo *  norm(k) *                 &
3418                               aerosol_mass((c-1)*nbins+b)%conc(k,j,i) )
3419             ENDDO
3420          ENDIF
3421       ENDDO    ! b
3422    ENDDO    ! m     
3423     
3424 END SUBROUTINE depo_topo
3425 
3426!------------------------------------------------------------------------------!
3427! Description:
3428! ------------
3429! Function for calculating terminal velocities for different particles sizes.
3430!------------------------------------------------------------------------------!
3431 REAL(wp) FUNCTION terminal_vel( radius, rhop, rhoa, visc, beta )
3432 
3433    IMPLICIT NONE
3434   
3435    REAL(wp), INTENT(in) ::  beta    !< Cunningham correction factor
3436    REAL(wp), INTENT(in) ::  radius  !< particle radius (m)
3437    REAL(wp), INTENT(in) ::  rhop    !< particle density (kg/m3)
3438    REAL(wp), INTENT(in) ::  rhoa    !< air density (kg/m3)
3439    REAL(wp), INTENT(in) ::  visc    !< molecular viscosity of air (kg/(m*s))
3440   
3441    REAL(wp), PARAMETER ::  rhoa_ref = 1.225_wp ! reference air density (kg/m3)
3442!
3443!-- Stokes law with Cunningham slip correction factor
3444    terminal_vel = ( 4.0_wp * radius**2.0_wp ) * ( rhop - rhoa ) * g * beta /  &
3445                   ( 18.0_wp * visc ) ! (m/s)
3446       
3447 END FUNCTION terminal_vel
3448 
3449!------------------------------------------------------------------------------!
3450! Description:
3451! ------------
3452!> Calculates particle loss and change in size distribution due to (Brownian)
3453!> coagulation. Only for particles with dwet < 30 micrometres.
3454!
3455!> Method:
3456!> Semi-implicit, non-iterative method: (Jacobson, 1994)
3457!> Volume concentrations of the smaller colliding particles added to the bin of
3458!> the larger colliding particles. Start from first bin and use the updated
3459!> number and volume for calculation of following bins. NB! Our bin numbering
3460!> does not follow particle size in subrange 2.
3461!
3462!> Schematic for bin numbers in different subranges:
3463!>             1                            2
3464!>    +-------------------------------------------+
3465!>  a | 1 | 2 | 3 || 4 | 5 | 6 | 7 |  8 |  9 | 10||
3466!>  b |           ||11 |12 |13 |14 | 15 | 16 | 17||
3467!>    +-------------------------------------------+
3468!
3469!> Exact coagulation coefficients for each pressure level are scaled according
3470!> to current particle wet size (linear scaling).
3471!> Bins are organized in terms of the dry size of the condensation nucleus,
3472!> while coagulation kernell is calculated with the actual hydrometeor
3473!> size.
3474!
3475!> Called from salsa_driver
3476!> fxm: Process selection should be made smarter - now just lots of IFs inside
3477!>      loops
3478!
3479!> Coded by:
3480!> Hannele Korhonen (FMI) 2005
3481!> Harri Kokkola (FMI) 2006
3482!> Tommi Bergman (FMI) 2012
3483!> Matti Niskanen(FMI) 2012
3484!> Anton Laakso  (FMI) 2013
3485!> Juha Tonttila (FMI) 2014
3486!------------------------------------------------------------------------------!
3487 SUBROUTINE coagulation( paero, ptstep, ptemp, ppres )
3488               
3489    IMPLICIT NONE
3490   
3491!-- Input and output variables
3492    TYPE(t_section), INTENT(inout) ::  paero(fn2b) !< Aerosol properties
3493    REAL(wp), INTENT(in) ::  ppres  !< ambient pressure (Pa)
3494    REAL(wp), INTENT(in) ::  ptemp  !< ambient temperature (K)
3495    REAL(wp), INTENT(in) ::  ptstep !< time step (s)
3496!-- Local variables
3497    INTEGER(iwp) ::  index_2a !< corresponding bin in subrange 2a
3498    INTEGER(iwp) ::  index_2b !< corresponding bin in subrange 2b
3499    INTEGER(iwp) ::  b !< loop index
3500    INTEGER(iwp) ::  ll !< loop index
3501    INTEGER(iwp) ::  mm !< loop index
3502    INTEGER(iwp) ::  nn !< loop index
3503    REAL(wp) ::  pressi !< pressure
3504    REAL(wp) ::  temppi !< temperature
3505    REAL(wp) ::  zcc(fn2b,fn2b)   !< updated coagulation coefficients (m3/s) 
3506    REAL(wp) ::  zdpart_mm        !< diameter of particle (m)
3507    REAL(wp) ::  zdpart_nn        !< diameter of particle (m)   
3508    REAL(wp) ::  zminusterm       !< coagulation loss in a bin (1/s)
3509    REAL(wp) ::  zplusterm(8)     !< coagulation gain in a bin (fxm/s)
3510                                  !< (for each chemical compound)
3511    REAL(wp) ::  zmpart(fn2b)     !< approximate mass of particles (kg)
3512   
3513    zcc       = 0.0_wp
3514    zmpart    = 0.0_wp
3515    zdpart_mm = 0.0_wp
3516    zdpart_nn = 0.0_wp
3517!
3518!-- 1) Coagulation to coarse mode calculated in a simplified way:
3519!--    CoagSink ~ Dp in continuum subrange, thus we calculate 'effective'
3520!--    number concentration of coarse particles
3521
3522!-- 2) Updating coagulation coefficients
3523!   
3524!-- Aerosol mass (kg). Density of 1500 kg/m3 assumed
3525    zmpart(1:fn2b) = api6 * ( MIN( paero(1:fn2b)%dwet, 30.0E-6_wp )**3.0_wp  ) &
3526                     * 1500.0_wp 
3527    temppi = ptemp
3528    pressi = ppres
3529    zcc    = 0.0_wp
3530!
3531!-- Aero-aero coagulation
3532    DO  mm = 1, fn2b   ! smaller colliding particle
3533       IF ( paero(mm)%numc < nclim )  CYCLE
3534       DO  nn = mm, fn2b   ! larger colliding particle
3535          IF ( paero(nn)%numc < nclim )  CYCLE
3536         
3537          zdpart_mm = MIN( paero(mm)%dwet, 30.0E-6_wp )     ! Limit to 30 um
3538          zdpart_nn = MIN( paero(nn)%dwet, 30.0E-6_wp )     ! Limit to 30 um
3539!             
3540!--       Coagulation coefficient of particles (m3/s)
3541          zcc(mm,nn) = coagc( zdpart_mm, zdpart_nn, zmpart(mm), zmpart(nn),    &
3542                              temppi, pressi )
3543          zcc(nn,mm) = zcc(mm,nn)
3544       ENDDO
3545    ENDDO
3546       
3547!   
3548!-- 3) New particle and volume concentrations after coagulation:
3549!--    Calculated according to Jacobson (2005) eq. 15.9
3550!
3551!-- Aerosols in subrange 1a:
3552    DO  b = in1a, fn1a
3553       IF ( paero(b)%numc < nclim )  CYCLE
3554       zminusterm   = 0.0_wp
3555       zplusterm(:) = 0.0_wp
3556!       
3557!--    Particles lost by coagulation with larger aerosols
3558       DO  ll = b+1, fn2b
3559          zminusterm = zminusterm + zcc(b,ll) * paero(ll)%numc
3560       ENDDO
3561!       
3562!--    Coagulation gain in a bin: change in volume conc. (cm3/cm3):
3563       DO ll = in1a, b-1
3564          zplusterm(1:2) = zplusterm(1:2) + zcc(ll,b) * paero(ll)%volc(1:2)
3565          zplusterm(6:7) = zplusterm(6:7) + zcc(ll,b) * paero(ll)%volc(6:7)
3566          zplusterm(8)   = zplusterm(8)   + zcc(ll,b) * paero(ll)%volc(8)
3567       ENDDO
3568!       
3569!--    Volume and number concentrations after coagulation update [fxm]
3570       paero(b)%volc(1:2) = ( paero(b)%volc(1:2) + ptstep * zplusterm(1:2) * &
3571                             paero(b)%numc ) / ( 1.0_wp + ptstep * zminusterm )
3572       paero(b)%volc(6:7) = ( paero(b)%volc(6:7) + ptstep * zplusterm(6:7) * &
3573                             paero(b)%numc ) / ( 1.0_wp + ptstep * zminusterm )
3574       paero(b)%volc(8)   = ( paero(b)%volc(8)   + ptstep * zplusterm(8) *   &
3575                             paero(b)%numc ) / ( 1.0_wp + ptstep * zminusterm )
3576       paero(b)%numc = paero(b)%numc / ( 1.0_wp + ptstep * zminusterm  +     &
3577                        0.5_wp * ptstep * zcc(b,b) * paero(b)%numc )               
3578    ENDDO
3579!             
3580!-- Aerosols in subrange 2a:
3581    DO  b = in2a, fn2a
3582       IF ( paero(b)%numc < nclim )  CYCLE
3583       zminusterm   = 0.0_wp
3584       zplusterm(:) = 0.0_wp
3585!       
3586!--    Find corresponding size bin in subrange 2b
3587       index_2b = b - in2a + in2b
3588!       
3589!--    Particles lost by larger particles in 2a
3590       DO  ll = b+1, fn2a
3591          zminusterm = zminusterm + zcc(b,ll) * paero(ll)%numc
3592       ENDDO
3593!       
3594!--    Particles lost by larger particles in 2b
3595       IF ( .NOT. no_insoluble )  THEN
3596          DO  ll = index_2b+1, fn2b
3597             zminusterm = zminusterm + zcc(b,ll) * paero(ll)%numc
3598          ENDDO
3599       ENDIF
3600!       
3601!--    Particle volume gained from smaller particles in subranges 1, 2a and 2b
3602       DO  ll = in1a, b-1
3603          zplusterm(1:2) = zplusterm(1:2) + zcc(ll,b) * paero(ll)%volc(1:2)
3604          zplusterm(6:7) = zplusterm(6:7) + zcc(ll,b) * paero(ll)%volc(6:7)
3605          zplusterm(8)   = zplusterm(8)   + zcc(ll,b) * paero(ll)%volc(8)
3606       ENDDO 
3607!       
3608!--    Particle volume gained from smaller particles in 2a
3609!--    (Note, for components not included in the previous loop!)
3610       DO  ll = in2a, b-1
3611          zplusterm(3:5) = zplusterm(3:5) + zcc(ll,b)*paero(ll)%volc(3:5)             
3612       ENDDO
3613       
3614!       
3615!--    Particle volume gained from smaller (and equal) particles in 2b
3616       IF ( .NOT. no_insoluble )  THEN
3617          DO  ll = in2b, index_2b
3618             zplusterm(1:8) = zplusterm(1:8) + zcc(ll,b) * paero(ll)%volc(1:8)
3619          ENDDO
3620       ENDIF
3621!       
3622!--    Volume and number concentrations after coagulation update [fxm]
3623       paero(b)%volc(1:8) = ( paero(b)%volc(1:8) + ptstep * zplusterm(1:8) * &
3624                             paero(b)%numc ) / ( 1.0_wp + ptstep * zminusterm )
3625       paero(b)%numc = paero(b)%numc / ( 1.0_wp + ptstep * zminusterm +      &
3626                        0.5_wp * ptstep * zcc(b,b) * paero(b)%numc )
3627    ENDDO
3628!             
3629!-- Aerosols in subrange 2b:
3630    IF ( .NOT. no_insoluble )  THEN
3631       DO  b = in2b, fn2b
3632          IF ( paero(b)%numc < nclim )  CYCLE
3633          zminusterm   = 0.0_wp
3634          zplusterm(:) = 0.0_wp
3635!       
3636!--       Find corresponding size bin in subsubrange 2a
3637          index_2a = b - in2b + in2a
3638!       
3639!--       Particles lost to larger particles in subranges 2b
3640          DO  ll = b+1, fn2b
3641             zminusterm = zminusterm + zcc(b,ll) * paero(ll)%numc
3642          ENDDO
3643!       
3644!--       Particles lost to larger and equal particles in 2a
3645          DO  ll = index_2a, fn2a
3646             zminusterm = zminusterm + zcc(b,ll) * paero(ll)%numc
3647          ENDDO
3648!       
3649!--       Particle volume gained from smaller particles in subranges 1 & 2a
3650          DO  ll = in1a, index_2a-1
3651             zplusterm(1:8) = zplusterm(1:8) + zcc(ll,b) * paero(ll)%volc(1:8)
3652          ENDDO
3653!       
3654!--       Particle volume gained from smaller particles in 2b
3655          DO  ll = in2b, b-1
3656             zplusterm(1:8) = zplusterm(1:8) + zcc(ll,b) * paero(ll)%volc(1:8)
3657          ENDDO
3658!       
3659!--       Volume and number concentrations after coagulation update [fxm]
3660          paero(b)%volc(1:8) = ( paero(b)%volc(1:8) + ptstep * zplusterm(1:8)&
3661                           * paero(b)%numc ) / ( 1.0_wp + ptstep * zminusterm )
3662          paero(b)%numc = paero(b)%numc / ( 1.0_wp + ptstep * zminusterm  +  &
3663                           0.5_wp * ptstep * zcc(b,b) * paero(b)%numc )
3664       ENDDO
3665    ENDIF
3666
3667 END SUBROUTINE coagulation
3668
3669!------------------------------------------------------------------------------!
3670! Description:
3671! ------------
3672!> Calculation of coagulation coefficients. Extended version of the function
3673!> originally found in mo_salsa_init.
3674!
3675!> J. Tonttila, FMI, 05/2014
3676!------------------------------------------------------------------------------!
3677 REAL(wp) FUNCTION coagc( diam1, diam2, mass1, mass2, temp, pres )
3678 
3679    IMPLICIT NONE
3680!       
3681!-- Input and output variables
3682    REAL(wp), INTENT(in) ::  diam1 !< diameter of colliding particle 1 (m)
3683    REAL(wp), INTENT(in) ::  diam2 !< diameter of colliding particle 2 (m)
3684    REAL(wp), INTENT(in) ::  mass1 !< mass of colliding particle 1 (kg)
3685    REAL(wp), INTENT(in) ::  mass2 !< mass of colliding particle 2 (kg)
3686    REAL(wp), INTENT(in) ::  pres  !< ambient pressure (Pa?) [fxm]
3687    REAL(wp), INTENT(in) ::  temp  !< ambient temperature (K)       
3688!
3689!-- Local variables
3690    REAL(wp) ::  fmdist !< distance of flux matching (m)   
3691    REAL(wp) ::  knud_p !< particle Knudsen number
3692    REAL(wp) ::  mdiam  !< mean diameter of colliding particles (m) 
3693    REAL(wp) ::  mfp    !< mean free path of air molecules (m)   
3694    REAL(wp) ::  visc   !< viscosity of air (kg/(m s))                   
3695    REAL(wp), DIMENSION (2) ::  beta   !< Cunningham correction factor
3696    REAL(wp), DIMENSION (2) ::  dfpart !< particle diffusion coefficient
3697                                       !< (m2/s)       
3698    REAL(wp), DIMENSION (2) ::  diam   !< diameters of particles (m)
3699    REAL(wp), DIMENSION (2) ::  flux   !< flux in continuum and free molec.
3700                                       !< regime (m/s)       
3701    REAL(wp), DIMENSION (2) ::  knud   !< particle Knudsen number       
3702    REAL(wp), DIMENSION (2) ::  mpart  !< masses of particles (kg)
3703    REAL(wp), DIMENSION (2) ::  mtvel  !< particle mean thermal velocity (m/s)
3704    REAL(wp), DIMENSION (2) ::  omega  !< particle mean free path             
3705    REAL(wp), DIMENSION (2) ::  tva    !< temporary variable (m)       
3706!
3707!-- Initialisation
3708    coagc   = 0.0_wp
3709!
3710!-- 1) Initializing particle and ambient air variables
3711    diam  = (/ diam1, diam2 /) !< particle diameters (m)
3712    mpart = (/ mass1, mass2 /) !< particle masses (kg)
3713!-- Viscosity of air (kg/(m s))       
3714    visc = ( 7.44523E-3_wp * temp ** 1.5_wp ) /                                &
3715           ( 5093.0_wp * ( temp + 110.4_wp ) ) 
3716!-- Mean free path of air (m)           
3717    mfp = ( 1.656E-10_wp * temp + 1.828E-8_wp ) * ( p_0 + 1325.0_wp ) / pres
3718!
3719!-- 2) Slip correction factor for small particles
3720    knud = 2.0_wp * EXP( LOG(mfp) - LOG(diam) )! Knudsen number for air (15.23)
3721!-- Cunningham correction factor (Allen and Raabe, Aerosol Sci. Tech. 4, 269)       
3722    beta = 1.0_wp + knud * ( 1.142_wp + 0.558_wp * EXP( -0.999_wp / knud ) )
3723!
3724!-- 3) Particle properties
3725!-- Diffusion coefficient (m2/s) (Jacobson (2005) eq. 15.29)
3726    dfpart = beta * abo * temp / ( 3.0_wp * pi * visc * diam ) 
3727!-- Mean thermal velocity (m/s) (Jacobson (2005) eq. 15.32)
3728    mtvel = SQRT( ( 8.0_wp * abo * temp ) / ( pi * mpart ) )
3729!-- Particle mean free path (m) (Jacobson (2005) eq. 15.34 )
3730    omega = 8.0_wp * dfpart / ( pi * mtvel ) 
3731!-- Mean diameter (m)
3732    mdiam = 0.5_wp * ( diam(1) + diam(2) )
3733!
3734!-- 4) Calculation of fluxes (Brownian collision kernels) and flux matching
3735!-- following Jacobson (2005):
3736!-- Flux in continuum regime (m3/s) (eq. 15.28)
3737    flux(1) = 4.0_wp * pi * mdiam * ( dfpart(1) + dfpart(2) )
3738!-- Flux in free molec. regime (m3/s) (eq. 15.31)
3739    flux(2) = pi * SQRT( ( mtvel(1)**2.0_wp ) + ( mtvel(2)**2.0_wp ) ) *      &
3740              ( mdiam**2.0_wp )
3741!-- temporary variables (m) to calculate flux matching distance (m)
3742    tva(1) = ( ( mdiam + omega(1) )**3.0_wp - ( mdiam**2.0_wp +                &
3743               omega(1)**2.0_wp ) * SQRT( ( mdiam**2.0_wp + omega(1)**2.0_wp ) &
3744               ) ) / ( 3.0_wp * mdiam * omega(1) ) - mdiam
3745    tva(2) = ( ( mdiam + omega(2) )**3.0_wp - ( mdiam**2.0_wp +                &
3746               omega(2)**2.0_wp ) * SQRT( ( mdiam**2 + omega(2)**2 ) ) ) /     &
3747             ( 3.0_wp * mdiam * omega(2) ) - mdiam
3748!-- Flux matching distance (m) i.e. the mean distance from the centre of a
3749!-- sphere reached by particles leaving sphere's surface and travelling a
3750!-- distance of particle mean free path mfp (eq. 15 34)                 
3751    fmdist = SQRT( tva(1)**2 + tva(2)**2.0_wp) 
3752!
3753!-- 5) Coagulation coefficient (m3/s) (eq. 15.33). Here assumed
3754!-- coalescence efficiency 1!!
3755    coagc = flux(1) / ( mdiam / ( mdiam + fmdist) + flux(1) / flux(2) ) 
3756!-- coagulation coefficient = coalescence efficiency * collision kernel
3757!
3758!-- Corrected collision kernel following Karl et al., 2016 (ACP):
3759!-- Inclusion of van der Waals and viscous forces
3760    IF ( van_der_waals_coagc )  THEN
3761       knud_p = SQRT( omega(1)**2 + omega(2)**2 ) / mdiam   
3762       IF ( knud_p >= 0.1_wp  .AND.  knud_p <= 10.0_wp )  THEN
3763          coagc = coagc * ( 2.0_wp + 0.4_wp * LOG( knud_p ) )
3764       ELSE
3765          coagc = coagc * 3.0_wp
3766       ENDIF
3767    ENDIF
3768   
3769 END FUNCTION coagc
3770 
3771!------------------------------------------------------------------------------!   
3772! Description:
3773! ------------
3774!> Calculates the change in particle volume and gas phase
3775!> concentrations due to nucleation, condensation and dissolutional growth.
3776!
3777!> Sulphuric acid and organic vapour: only condensation and no evaporation.
3778!
3779!> New gas and aerosol phase concentrations calculated according to Jacobson
3780!> (1997): Numerical techniques to solve condensational and dissolutional growth
3781!> equations when growth is coupled to reversible reactions, Aerosol Sci. Tech.,
3782!> 27, pp 491-498.
3783!
3784!> Following parameterization has been used:
3785!> Molecular diffusion coefficient of condensing vapour (m2/s)
3786!> (Reid et al. (1987): Properties of gases and liquids, McGraw-Hill, New York.)
3787!> D = {1.d-7*sqrt(1/M_air + 1/M_gas)*T^1.75} / &
3788!      {p_atm/p_stand * (d_air^(1/3) + d_gas^(1/3))^2 }
3789! M_air = 28.965 : molar mass of air (g/mol)
3790! d_air = 19.70  : diffusion volume of air
3791! M_h2so4 = 98.08 : molar mass of h2so4 (g/mol)
3792! d_h2so4 = 51.96  : diffusion volume of h2so4
3793!
3794!> Called from main aerosol model
3795!
3796!> fxm: calculated for empty bins too
3797!> fxm: same diffusion coefficients and mean free paths used for sulphuric acid
3798!>      and organic vapours (average values? 'real' values for each?)
3799!> fxm: one should really couple with vapour production and loss terms as well
3800!>      should nucleation be coupled here as well????
3801!
3802! Coded by:
3803! Hannele Korhonen (FMI) 2005
3804! Harri Kokkola (FMI) 2006
3805! Juha Tonttila (FMI) 2014
3806! Rewritten to PALM by Mona Kurppa (UHel) 2017
3807!------------------------------------------------------------------------------!
3808 SUBROUTINE condensation( paero, pcsa, pcocnv, pcocsv, pchno3, pcnh3, pcw, pcs,&
3809                          ptemp, ppres, ptstep, prtcl )
3810       
3811    IMPLICIT NONE
3812   
3813!-- Input and output variables
3814    REAL(wp), INTENT(IN) ::  ppres !< ambient pressure (Pa)
3815    REAL(wp), INTENT(IN) ::  pcs   !< Water vapour saturation concentration
3816                                   !< (kg/m3)     
3817    REAL(wp), INTENT(IN) ::  ptemp !< ambient temperature (K)
3818    REAL(wp), INTENT(IN) ::  ptstep            !< timestep (s) 
3819    TYPE(component_index), INTENT(in) :: prtcl !< Keeps track which substances
3820                                               !< are used                                               
3821    REAL(wp), INTENT(INOUT) ::  pchno3 !< Gas concentrations (#/m3):
3822                                       !< nitric acid HNO3
3823    REAL(wp), INTENT(INOUT) ::  pcnh3  !< ammonia NH3
3824    REAL(wp), INTENT(INOUT) ::  pcocnv !< non-volatile organics
3825    REAL(wp), INTENT(INOUT) ::  pcocsv !< semi-volatile organics
3826    REAL(wp), INTENT(INOUT) ::  pcsa   !< sulphuric acid H2SO4
3827    REAL(wp), INTENT(INOUT) ::  pcw    !< Water vapor concentration (kg/m3)
3828    TYPE(t_section), INTENT(inout) ::  paero(fn2b) !< Aerosol properties                                     
3829!-- Local variables
3830    REAL(wp) ::  zbeta(fn2b) !< transitional correction factor for aerosols
3831    REAL(wp) ::  zcolrate(fn2b) !< collision rate of molecules to particles
3832                                !< (1/s)
3833    REAL(wp) ::  zcolrate_ocnv(fn2b) !< collision rate of organic molecules
3834                                     !< to particles (1/s)
3835    REAL(wp) ::  zcs_ocnv !< condensation sink of nonvolatile organics (1/s)       
3836    REAL(wp) ::  zcs_ocsv !< condensation sink of semivolatile organics (1/s)
3837    REAL(wp) ::  zcs_su !< condensation sink of sulfate (1/s)
3838    REAL(wp) ::  zcs_tot!< total condensation sink (1/s) (gases)
3839!-- vapour concentration after time step (#/m3)
3840    REAL(wp) ::  zcvap_new1 !< sulphuric acid
3841    REAL(wp) ::  zcvap_new2 !< nonvolatile organics
3842    REAL(wp) ::  zcvap_new3 !< semivolatile organics
3843    REAL(wp) ::  zdfpart(in1a+1) !< particle diffusion coefficient (m2/s)     
3844    REAL(wp) ::  zdfvap !< air diffusion coefficient (m2/s)
3845!-- change in vapour concentration (#/m3)
3846    REAL(wp) ::  zdvap1 !< sulphuric acid
3847    REAL(wp) ::  zdvap2 !< nonvolatile organics
3848    REAL(wp) ::  zdvap3 !< semivolatile organics
3849    REAL(wp) ::  zdvoloc(fn2b) !< change of organics volume in each bin [fxm]   
3850    REAL(wp) ::  zdvolsa(fn2b) !< change of sulphate volume in each bin [fxm]
3851    REAL(wp) ::  zj3n3(2)      !< Formation massrate of molecules in
3852                               !< nucleation, (molec/m3s). 1: H2SO4
3853                               !< and 2: organic vapor       
3854    REAL(wp) ::  zknud(fn2b) !< particle Knudsen number       
3855    REAL(wp) ::  zmfp    !< mean free path of condensing vapour (m)
3856    REAL(wp) ::  zrh     !< Relative humidity [0-1]         
3857    REAL(wp) ::  zvisc   !< viscosity of air (kg/(m s))     
3858    REAL(wp) ::  zn_vs_c !< ratio of nucleation of all mass transfer in the
3859                         !< smallest bin
3860    REAL(wp) ::  zxocnv  !< ratio of organic vapour in 3nm particles
3861    REAL(wp) ::  zxsa    !< Ratio in 3nm particles: sulphuric acid
3862   
3863    zj3n3  = 0.0_wp
3864    zrh    = pcw / pcs   
3865    zxocnv = 0.0_wp
3866    zxsa   = 0.0_wp
3867!
3868!-- Nucleation
3869    IF ( nsnucl > 0 )  THEN
3870       CALL nucleation( paero, ptemp, zrh, ppres, pcsa, pcocnv, pcnh3, ptstep, &
3871                        zj3n3, zxsa, zxocnv )
3872    ENDIF
3873!
3874!-- Condensation on pre-existing particles
3875    IF ( lscndgas )  THEN
3876!
3877!--    Initialise:
3878       zdvolsa = 0.0_wp 
3879       zdvoloc = 0.0_wp
3880       zcolrate = 0.0_wp
3881!             
3882!--    1) Properties of air and condensing gases:
3883!--    Viscosity of air (kg/(m s)) (Eq. 4.54 in Jabonson (2005))
3884       zvisc = ( 7.44523E-3_wp * ptemp ** 1.5_wp ) / ( 5093.0_wp *             &
3885                 ( ptemp + 110.4_wp ) )
3886!--    Diffusion coefficient of air (m2/s)
3887       zdfvap = 5.1111E-10_wp * ptemp ** 1.75_wp * ( p_0 + 1325.0_wp ) / ppres
3888!--    Mean free path (m): same for H2SO4 and organic compounds
3889       zmfp = 3.0_wp * zdfvap * SQRT( pi * amh2so4 / ( 8.0_wp * argas * ptemp ) )
3890!                   
3891!--    2) Transition regime correction factor zbeta for particles:
3892!--       Fuchs and Sutugin (1971), In: Hidy et al. (ed.) Topics in current
3893!--       aerosol research, Pergamon. Size of condensing molecule considered 
3894!--       only for nucleation mode (3 - 20 nm)
3895!
3896!--    Particle Knudsen number: condensation of gases on aerosols
3897       zknud(in1a:in1a+1) = 2.0_wp * zmfp / ( paero(in1a:in1a+1)%dwet + d_sa )
3898       zknud(in1a+2:fn2b) = 2.0_wp * zmfp / paero(in1a+2:fn2b)%dwet
3899!   
3900!--    Transitional correction factor: aerosol + gas (the semi-empirical Fuchs-
3901!--    Sutugin interpolation function (Fuchs and Sutugin, 1971))
3902       zbeta = ( zknud + 1.0_wp ) / ( 0.377_wp * zknud + 1.0_wp + 4.0_wp /     &
3903               ( 3.0_wp * massacc ) * ( zknud + zknud ** 2.0_wp ) )
3904!                   
3905!--    3) Collision rate of molecules to particles
3906!--       Particle diffusion coefficient considered only for nucleation mode
3907!--       (3 - 20 nm)
3908!
3909!--    Particle diffusion coefficient (m2/s) (e.g. Eq. 15.29 in Jacobson (2005))
3910       zdfpart = abo * ptemp * zbeta(in1a:in1a+1) / ( 3.0_wp * pi * zvisc *    &
3911                 paero(in1a:in1a+1)%dwet )
3912!             
3913!--    Collision rate (mass-transfer coefficient): gases on aerosols (1/s)
3914!--    (Eq. 16.64 in Jacobson (2005))
3915       zcolrate(in1a:in1a+1) = MERGE( 2.0_wp * pi *                            &
3916                                      ( paero(in1a:in1a+1)%dwet + d_sa ) *     &
3917                                      ( zdfvap + zdfpart ) * zbeta(in1a:in1a+1)& 
3918                                        * paero(in1a:in1a+1)%numc, 0.0_wp,     &
3919                                      paero(in1a:in1a+1)%numc > nclim )
3920       zcolrate(in1a+2:fn2b) = MERGE( 2.0_wp * pi * paero(in1a+2:fn2b)%dwet *  &
3921                                      zdfvap * zbeta(in1a+2:fn2b) *            &
3922                                      paero(in1a+2:fn2b)%numc, 0.0_wp,         &
3923                                      paero(in1a+2:fn2b)%numc > nclim )
3924!                 
3925!-- 4) Condensation sink (1/s)
3926       zcs_tot = SUM( zcolrate )   ! total sink
3927!
3928!--    5) Changes in gas-phase concentrations and particle volume
3929!
3930!--    5.1) Organic vapours
3931!
3932!--    5.1.1) Non-volatile organic compound: condenses onto all bins
3933       IF ( pcocnv > 1.0E+10_wp  .AND.  zcs_tot > 1.0E-30_wp  .AND.            &
3934            is_used( prtcl,'OC' ) )                                            &
3935       THEN
3936!--       Ratio of nucleation vs. condensation rates in the smallest bin   
3937          zn_vs_c = 0.0_wp 
3938          IF ( zj3n3(2) > 1.0_wp )  THEN
3939             zn_vs_c = ( zj3n3(2) ) / ( zj3n3(2) + pcocnv * zcolrate(in1a) )
3940          ENDIF
3941!       
3942!--       Collision rate in the smallest bin, including nucleation and
3943!--       condensation(see Jacobson, Fundamentals of Atmospheric Modeling, 2nd
3944!--       Edition (2005), equation (16.73) )
3945          zcolrate_ocnv = zcolrate
3946          zcolrate_ocnv(in1a) = zcolrate_ocnv(in1a) + zj3n3(2) / pcocnv
3947!       
3948!--       Total sink for organic vapor
3949          zcs_ocnv = zcs_tot + zj3n3(2) / pcocnv
3950!       
3951!--       New gas phase concentration (#/m3)
3952          zcvap_new2 = pcocnv / ( 1.0_wp + ptstep * zcs_ocnv )
3953!       
3954!--       Change in gas concentration (#/m3)
3955          zdvap2 = pcocnv - zcvap_new2
3956!
3957!--       Updated vapour concentration (#/m3)               
3958          pcocnv = zcvap_new2
3959!       
3960!--       Volume change of particles (m3(OC)/m3(air))
3961          zdvoloc = zcolrate_ocnv(in1a:fn2b) / zcs_ocnv * amvoc * zdvap2
3962!       
3963!--       Change of volume due to condensation in 1a-2b
3964          paero(in1a:fn2b)%volc(2) = paero(in1a:fn2b)%volc(2) + zdvoloc 
3965!       
3966!--       Change of number concentration in the smallest bin caused by
3967!--       nucleation (Jacobson (2005), equation (16.75)). If zxocnv = 0, then 
3968!--       the chosen nucleation mechanism doesn't take into account the non-
3969!--       volatile organic vapors and thus the paero doesn't have to be updated.
3970          IF ( zxocnv > 0.0_wp )  THEN
3971             paero(in1a)%numc = paero(in1a)%numc + zn_vs_c * zdvoloc(in1a) /   &
3972                                amvoc / ( n3 * zxocnv )
3973          ENDIF
3974       ENDIF
3975!   
3976!--    5.1.2) Semivolatile organic compound: all bins except subrange 1
3977       zcs_ocsv = SUM( zcolrate(in2a:fn2b) ) !< sink for semi-volatile organics
3978       IF ( pcocsv > 1.0E+10_wp  .AND.  zcs_ocsv > 1.0E-30  .AND.              &
3979            is_used( prtcl,'OC') )                                             &
3980       THEN
3981!
3982!--       New gas phase concentration (#/m3)
3983          zcvap_new3 = pcocsv / ( 1.0_wp + ptstep * zcs_ocsv )
3984!       
3985!--       Change in gas concentration (#/m3)
3986          zdvap3 = pcocsv - zcvap_new3
3987!       
3988!--       Updated gas concentration (#/m3)               
3989          pcocsv = zcvap_new3
3990!       
3991!--       Volume change of particles (m3(OC)/m3(air))
3992          zdvoloc(in2a:fn2b) = zdvoloc(in2a:fn2b) + zcolrate(in2a:fn2b) /      &
3993                               zcs_ocsv * amvoc * zdvap3
3994!                           
3995!--       Change of volume due to condensation in 1a-2b
3996          paero(in1a:fn2b)%volc(2) = paero(in1a:fn2b)%volc(2) + zdvoloc
3997       ENDIF
3998!
3999!-- 5.2) Sulphate: condensed on all bins
4000       IF ( pcsa > 1.0E+10_wp  .AND.  zcs_tot > 1.0E-30_wp  .AND.              &
4001            is_used( prtcl,'SO4' ) )                                           &
4002       THEN
4003!   
4004!--    Ratio of mass transfer between nucleation and condensation
4005          zn_vs_c = 0.0_wp
4006          IF ( zj3n3(1) > 1.0_wp )  THEN
4007             zn_vs_c = ( zj3n3(1) ) / ( zj3n3(1) + pcsa * zcolrate(in1a) )
4008          ENDIF
4009!       
4010!--       Collision rate in the smallest bin, including nucleation and
4011!--       condensation (see Jacobson, Fundamentals of Atmospheric Modeling, 2nd
4012!--       Edition (2005), equation (16.73))
4013          zcolrate(in1a) = zcolrate(in1a) + zj3n3(1) / pcsa     
4014!       
4015!--       Total sink for sulfate (1/s)
4016          zcs_su = zcs_tot + zj3n3(1) / pcsa
4017!       
4018!--       Sulphuric acid:
4019!--       New gas phase concentration (#/m3)
4020          zcvap_new1 = pcsa / ( 1.0_wp + ptstep * zcs_su )
4021!       
4022!--       Change in gas concentration (#/m3)
4023          zdvap1 = pcsa - zcvap_new1
4024!       
4025!--       Updating vapour concentration (#/m3)
4026          pcsa = zcvap_new1
4027!       
4028!--       Volume change of particles (m3(SO4)/m3(air)) by condensation
4029          zdvolsa = zcolrate(in1a:fn2b) / zcs_su * amvh2so4 * zdvap1
4030!--       For validation: zdvolsa = 5.5 mum3/cm3 per 12 h       
4031       !   zdvolsa = zdvolsa / SUM( zdvolsa ) * 5.5E-12_wp * dt_salsa / 43200.0_wp 
4032          !0.3E-12_wp, 0.6E-12_wp, 11.0E-12_wp, 4.6E-12_wp, 9.2E-12_wp   
4033!       
4034!--       Change of volume concentration of sulphate in aerosol [fxm]
4035          paero(in1a:fn2b)%volc(1) = paero(in1a:fn2b)%volc(1) + zdvolsa
4036!       
4037!--       Change of number concentration in the smallest bin caused by nucleation
4038!--       (Jacobson (2005), equation (16.75))
4039          IF ( zxsa > 0.0_wp )  THEN
4040             paero(in1a)%numc = paero(in1a)%numc + zn_vs_c * zdvolsa(in1a) /   &
4041                                amvh2so4 / ( n3 * zxsa )
4042          ENDIF
4043       ENDIF
4044    ENDIF
4045!
4046!
4047!-- Condensation of water vapour
4048    IF ( lscndh2oae )  THEN
4049       CALL gpparth2o( paero, ptemp, ppres, pcs, pcw, ptstep )
4050    ENDIF
4051!   
4052!
4053!-- Partitioning of H2O, HNO3, and NH3: Dissolutional growth
4054    IF ( lscndgas  .AND.  ino > 0  .AND.  inh > 0  .AND.                       &
4055         ( pchno3 > 1.0E+10_wp  .OR.  pcnh3 > 1.0E+10_wp ) )                   &
4056    THEN
4057       CALL gpparthno3( ppres, ptemp, paero, pchno3, pcnh3, pcw, pcs, zbeta,   &
4058                        ptstep )
4059    ENDIF
4060   
4061 END SUBROUTINE condensation
4062 
4063!------------------------------------------------------------------------------!
4064! Description:
4065! ------------
4066!> Calculates the particle number and volume increase, and gas-phase
4067!> concentration decrease due to nucleation subsequent growth to detectable size
4068!> of 3 nm.
4069!
4070!> Method:
4071!> When the formed clusters grow by condensation (possibly also by self-
4072!> coagulation), their number is reduced due to scavenging to pre-existing
4073!> particles. Thus, the apparent nucleation rate at 3 nm is significantly lower
4074!> than the real nucleation rate (at ~1 nm).
4075!
4076!> Calculation of the formation rate of detectable particles at 3 nm (i.e. J3):
4077!> nj3 = 1: Kerminen, V.-M. and Kulmala, M. (2002), J. Aerosol Sci.,33, 609-622.
4078!> nj3 = 2: Lehtinen et al. (2007), J. Aerosol Sci., 38(9), 988-994.
4079!> nj3 = 3: Anttila et al. (2010), J. Aerosol Sci., 41(7), 621-636.
4080!
4081!> Called from subroutine condensation (in module salsa_dynamics_mod.f90)
4082!
4083!> Calls one of the following subroutines:
4084!>  - binnucl
4085!>  - ternucl
4086!>  - kinnucl
4087!>  - actnucl
4088!
4089!> fxm: currently only sulphuric acid grows particles from 1 to 3 nm
4090!>  (if asked from Markku, this is terribly wrong!!!)
4091!
4092!> Coded by:
4093!> Hannele Korhonen (FMI) 2005
4094!> Harri Kokkola (FMI) 2006
4095!> Matti Niskanen(FMI) 2012
4096!> Anton Laakso  (FMI) 2013
4097!------------------------------------------------------------------------------!
4098
4099 SUBROUTINE nucleation( paero, ptemp, prh, ppres, pcsa, pcocnv, pcnh3, ptstep, &
4100                        pj3n3, pxsa, pxocnv )
4101    IMPLICIT NONE
4102!       
4103!-- Input and output variables
4104    REAL(wp), INTENT(in) ::  pcnh3    !< ammonia concentration (#/m3)
4105    REAL(wp), INTENT(in) ::  pcocnv   !< conc. of non-volatile OC (#/m3)     
4106    REAL(wp), INTENT(in) ::  pcsa     !< sulphuric acid conc. (#/m3)
4107    REAL(wp), INTENT(in) ::  ppres    !< ambient air pressure (Pa)
4108    REAL(wp), INTENT(in) ::  prh      !< ambient rel. humidity [0-1]       
4109    REAL(wp), INTENT(in) ::  ptemp    !< ambient temperature (K)
4110    REAL(wp), INTENT(in) ::  ptstep   !< time step (s) of SALSA
4111    TYPE(t_section), INTENT(inout) ::  paero(fn2b) !< aerosol properties                                                 
4112    REAL(wp), INTENT(inout) ::  pj3n3(2) !< formation mass rate of molecules
4113                                         !< (molec/m3s) for 1: H2SO4 and
4114                                         !< 2: organic vapour
4115    REAL(wp), INTENT(out) ::  pxocnv !< ratio of non-volatile organic vapours in
4116                                     !< 3nm aerosol particles
4117    REAL(wp), INTENT(out) ::  pxsa   !< ratio of H2SO4 in 3nm aerosol particles
4118!-- Local variables
4119    INTEGER(iwp) ::  iteration
4120    REAL(wp) ::  zbeta(fn2b)  !< transitional correction factor                                         
4121    REAL(wp) ::  zc_h2so4     !< H2SO4 conc. (#/cm3) !UNITS!
4122    REAL(wp) ::  zc_org       !< organic vapour conc. (#/cm3)
4123    REAL(wp) ::  zCoagStot    !< total losses due to coagulation, including
4124                              !< condensation and self-coagulation       
4125    REAL(wp) ::  zcocnv_local !< organic vapour conc. (#/m3)
4126    REAL(wp) ::  zcsink       !< condensational sink (#/m2)       
4127    REAL(wp) ::  zcsa_local   !< H2SO4 conc. (#/m3)       
4128    REAL(wp) ::  zdcrit       !< diameter of critical cluster (m)
4129    REAL(wp) ::  zdelta_vap   !< change of H2SO4 and organic vapour
4130                              !< concentration (#/m3)       
4131    REAL(wp) ::  zdfvap       !< air diffusion coefficient (m2/s)
4132    REAL(wp) ::  zdmean       !< mean diameter of existing particles (m)
4133    REAL(wp) ::  zeta         !< constant: proportional to ratio of CS/GR (m)
4134                              !< (condensation sink / growth rate)                                   
4135    REAL(wp) ::  zgamma       !< proportionality factor ((nm2*m2)/h)                                       
4136    REAL(wp) ::  zGRclust     !< growth rate of formed clusters (nm/h)
4137    REAL(wp) ::  zGRtot       !< total growth rate       
4138    REAL(wp) ::  zj3          !< number conc. of formed 3nm particles (#/m3)       
4139    REAL(wp) ::  zjnuc        !< nucleation rate at ~1nm (#/m3s)
4140    REAL(wp) ::  zKeff        !< effective cogulation coefficient between
4141                              !< freshly nucleated particles       
4142    REAL(wp) ::  zknud(fn2b)  !< particle Knudsen number       
4143    REAL(wp) ::  zkocnv       !< lever: zkocnv=1 --> organic compounds involved
4144                              !< in nucleation   
4145    REAL(wp) ::  zksa         !< lever: zksa=1 --> H2SO4 involved in nucleation
4146    REAL(wp) ::  zlambda      !< parameter for adjusting the growth rate due to
4147                              !< self-coagulation                                 
4148    REAL(wp) ::  zmfp         !< mean free path of condesing vapour(m)                                       
4149    REAL(wp) ::  zmixnh3      !< ammonia mixing ratio (ppt)
4150    REAL(wp) ::  zNnuc        !< number of clusters/particles at the size range
4151                              !< d1-dx (#/m3) 
4152    REAL(wp) ::  znoc         !< number of organic molecules in critical cluster
4153    REAL(wp) ::  znsa         !< number of H2SO4 molecules in critical cluster                                           
4154!
4155!-- Variable determined for the m-parameter
4156    REAL(wp) ::  zCc_2(fn2b) !<
4157    REAL(wp) ::  zCc_c !<
4158    REAL(wp) ::  zCc_x !<
4159    REAL(wp) ::  zCoagS_c !<
4160    REAL(wp) ::  zCoagS_x !<
4161    REAL(wp) ::  zcv_2(fn2b) !<
4162    REAL(wp) ::  zcv_c !<
4163    REAL(wp) ::  zcv_c2(fn2b) !<
4164    REAL(wp) ::  zcv_x !<
4165    REAL(wp) ::  zcv_x2(fn2b) !<
4166    REAL(wp) ::  zDc_2(fn2b) !<
4167    REAL(wp) ::  zDc_c(fn2b) !<
4168    REAL(wp) ::  zDc_c2(fn2b) !<
4169    REAL(wp) ::  zDc_x(fn2b) !<
4170    REAL(wp) ::  zDc_x2(fn2b) !<
4171    REAL(wp) ::  zgammaF_2(fn2b) !<
4172    REAL(wp) ::  zgammaF_c(fn2b) !<
4173    REAL(wp) ::  zgammaF_x(fn2b) !<
4174    REAL(wp) ::  zK_c2(fn2b) !<
4175    REAL(wp) ::  zK_x2(fn2b) !<
4176    REAL(wp) ::  zknud_2(fn2b) !<
4177    REAL(wp) ::  zknud_c !<
4178    REAL(wp) ::  zknud_x !<       
4179    REAL(wp) ::  zm_2(fn2b) !<
4180    REAL(wp) ::  zm_c !<
4181    REAL(wp) ::  zm_para !<
4182    REAL(wp) ::  zm_x !<
4183    REAL(wp) ::  zmyy !<
4184    REAL(wp) ::  zomega_2c(fn2b) !<
4185    REAL(wp) ::  zomega_2x(fn2b) !<
4186    REAL(wp) ::  zomega_c(fn2b) !<
4187    REAL(wp) ::  zomega_x(fn2b) !<
4188    REAL(wp) ::  zRc2(fn2b) !<
4189    REAL(wp) ::  zRx2(fn2b) !<
4190    REAL(wp) ::  zsigma_c2(fn2b) !<
4191    REAL(wp) ::  zsigma_x2(fn2b) !<
4192!
4193!-- 1) Nucleation rate (zjnuc) and diameter of critical cluster (zdcrit)
4194    zjnuc  = 0.0_wp
4195    znsa   = 0.0_wp
4196    znoc   = 0.0_wp
4197    zdcrit = 0.0_wp
4198    zksa   = 0.0_wp
4199    zkocnv = 0.0_wp
4200   
4201    SELECT CASE ( nsnucl )
4202   
4203    CASE(1)   ! Binary H2SO4-H2O nucleation
4204       
4205       zc_h2so4 = pcsa * 1.0E-6_wp   ! sulphuric acid conc. to #/cm3
4206       CALL binnucl( zc_h2so4, ptemp, prh, zjnuc, znsa, znoc, zdcrit,  zksa, &
4207                     zkocnv )     
4208   
4209    CASE(2)   ! Activation type nucleation
4210   
4211       zc_h2so4 = pcsa * 1.0E-6_wp   ! sulphuric acid conc. to #/cm3
4212       CALL binnucl( zc_h2so4, ptemp, prh, zjnuc, znsa,  znoc, zdcrit, zksa,  &
4213                     zkocnv )
4214       CALL actnucl( pcsa, zjnuc, zdcrit, znsa, znoc, zksa, zkocnv, act_coeff )
4215   
4216    CASE(3)   ! Kinetically limited nucleation of (NH4)HSO4 clusters
4217       
4218       zc_h2so4 = pcsa * 1.0E-6_wp   ! sulphuric acid conc. to #/cm3
4219       CALL binnucl( zc_h2so4, ptemp, prh, zjnuc, znsa, znoc, zdcrit, zksa,    &
4220                     zkocnv )
4221
4222       CALL kinnucl( zc_h2so4, zjnuc, zdcrit, znsa, znoc, zksa, zkocnv )
4223   
4224    CASE(4)   ! Ternary H2SO4-H2O-NH3 nucleation
4225   
4226       zmixnh3 = pcnh3 * ptemp * argas / ( ppres * avo )
4227       zc_h2so4 = pcsa * 1.0E-6_wp   ! sulphuric acid conc. to #/cm3
4228       CALL ternucl( zc_h2so4, zmixnh3, ptemp, prh, zjnuc, znsa, znoc, zdcrit, &
4229                     zksa, zkocnv ) 
4230   
4231    CASE(5)   ! Organic nucleation, J~[ORG] or J~[ORG]**2
4232   
4233       zc_org = pcocnv * 1.0E-6_wp   ! conc. of non-volatile OC to #/cm3
4234       zc_h2so4 = pcsa * 1.0E-6_wp   ! sulphuric acid conc. to #/cm3
4235       CALL binnucl( zc_h2so4, ptemp, prh, zjnuc, znsa, znoc, zdcrit, zksa,    &
4236                     zkocnv ) 
4237       CALL orgnucl( pcocnv, zjnuc, zdcrit, znsa, znoc, zksa, zkocnv )
4238   
4239    CASE(6)   ! Sum of H2SO4 and organic activation type nucleation,
4240              ! J~[H2SO4]+[ORG]
4241       
4242       zc_h2so4 = pcsa * 1.0E-6_wp   ! sulphuric acid conc. to #/cm3
4243       CALL binnucl( zc_h2so4, ptemp, prh, zjnuc, znsa, znoc, zdcrit, zksa,    &
4244                     zkocnv ) 
4245       CALL sumnucl( pcsa, pcocnv, zjnuc, zdcrit, znsa, znoc, zksa, zkocnv )
4246
4247           
4248    CASE(7)   ! Heteromolecular nucleation, J~[H2SO4]*[ORG]
4249       
4250       zc_h2so4 = pcsa * 1.0E-6_wp   ! sulphuric acid conc. to #/cm3
4251       zc_org = pcocnv * 1.0E-6_wp   ! conc. of non-volatile OC to #/cm3
4252       CALL binnucl( zc_h2so4, ptemp, prh, zjnuc, znsa, znoc, zdcrit, zksa,    &
4253                     zkocnv ) 
4254       CALL hetnucl( zc_h2so4, zc_org, zjnuc, zdcrit, znsa, znoc, zksa, zkocnv )
4255   
4256    CASE(8)   ! Homomolecular nucleation of H2SO4 and heteromolecular
4257              ! nucleation of H2SO4 and organic vapour,
4258              ! J~[H2SO4]**2 + [H2SO4]*[ORG] (EUCAARI project)
4259       zc_h2so4 = pcsa * 1.0E-6_wp   ! sulphuric acid conc. to #/cm3
4260       zc_org = pcocnv * 1.0E-6_wp   ! conc. of non-volatile OC to #/cm3
4261       CALL binnucl( zc_h2so4, ptemp, prh, zjnuc, znsa, znoc, zdcrit, zksa,    &
4262                     zkocnv ) 
4263       CALL SAnucl( zc_h2so4, zc_org, zjnuc, zdcrit, znsa, znoc, zksa, zkocnv )
4264   
4265    CASE(9)   ! Homomolecular nucleation of H2SO4 and organic vapour and
4266              ! heteromolecular nucleation of H2SO4 and organic vapour,
4267              ! J~[H2SO4]**2 + [H2SO4]*[ORG]+[ORG]**2 (EUCAARI project)
4268   
4269       zc_h2so4 = pcsa * 1.0E-6_wp   ! sulphuric acid conc. to #/cm3
4270       zc_org = pcocnv * 1.0E-6_wp   ! conc. of non-volatile OC to #/cm3
4271       CALL binnucl( zc_h2so4, ptemp, prh, zjnuc, znsa, znoc, zdcrit, zksa,    &
4272                     zkocnv ) 
4273
4274       CALL SAORGnucl( zc_h2so4, zc_org, zjnuc, zdcrit, znsa, znoc, zksa,      &
4275                       zkocnv )
4276    END SELECT
4277   
4278    zcsa_local = pcsa
4279    zcocnv_local = pcocnv
4280!
4281!-- 2) Change of particle and gas concentrations due to nucleation
4282!         
4283!-- 2.1) Check that there is enough H2SO4 and organic vapour to produce the
4284!--      nucleation 
4285    IF ( nsnucl <= 4 )  THEN 
4286!--    If the chosen nucleation scheme is 1-4, nucleation occurs only due to
4287!--    H2SO4. All of the total vapour concentration that is taking part to the
4288!--    nucleation is there for sulphuric acid (sa = H2SO4) and non-volatile
4289!--    organic vapour is zero.
4290       pxsa   = 1.0_wp   ! ratio of sulphuric acid in 3nm particles
4291       pxocnv = 0.0_wp   ! ratio of non-volatile origanic vapour
4292                                ! in 3nm particles
4293    ELSEIF ( nsnucl > 4 )  THEN
4294!--    If the chosen nucleation scheme is 5-9, nucleation occurs due to organic
4295!--    vapour or the combination of organic vapour and H2SO4. The number of
4296!--    needed molecules depends on the chosen nucleation type and it has an
4297!--    effect also on the minimum ratio of the molecules present.
4298       IF ( pcsa * znsa + pcocnv * znoc < 1.E-14_wp )  THEN
4299          pxsa   = 0.0_wp
4300          pxocnv = 0.0_wp             
4301       ELSE
4302          pxsa   = pcsa * znsa / ( pcsa * znsa + pcocnv * znoc ) 
4303          pxocnv = pcocnv * znoc / ( pcsa * znsa + pcocnv * znoc )
4304       ENDIF 
4305    ENDIF
4306!   
4307!-- The change in total vapour concentration is the sum of the concentrations
4308!-- of the vapours taking part to the nucleation (depends on the chosen
4309!-- nucleation scheme)
4310    zdelta_vap = MIN( zjnuc * ( znoc + znsa ), ( pcocnv * zkocnv + pcsa *      &
4311                      zksa ) / ptstep ) 
4312!                     
4313!-- Nucleation rate J at ~1nm (#/m3s)                           
4314    zjnuc = zdelta_vap / ( znoc + znsa )
4315!   
4316!-- H2SO4 concentration after nucleation in #/m3           
4317    zcsa_local = MAX( 1.0_wp, pcsa - zdelta_vap * pxsa ) 
4318!   
4319!-- Non-volative organic vapour concentration after nucleation (#/m3)
4320    zcocnv_local = MAX( 1.0_wp, pcocnv - zdelta_vap * pxocnv )
4321!
4322!-- 2.2) Formation rate of 3 nm particles (Kerminen & Kulmala, 2002)
4323!
4324!-- 2.2.1) Growth rate of clusters formed by H2SO4
4325!
4326!-- GR = 3.0e-15 / dens_clus * sum( molecspeed * molarmass * conc )
4327
4328!-- dens_clus  = density of the clusters (here 1830 kg/m3)
4329!-- molarmass  = molar mass of condensing species (here 98.08 g/mol)
4330!-- conc       = concentration of condensing species [#/m3]
4331!-- molecspeed = molecular speed of condensing species [m/s]
4332!--            = sqrt( 8.0 * R * ptemp / ( pi * molarmass ) )
4333!-- (Seinfeld & Pandis, 1998)
4334!
4335!-- Growth rate by H2SO4 and organic vapour in nm/h (Eq. 21)
4336    zGRclust = 2.3623E-15_wp * SQRT( ptemp ) * ( zcsa_local + zcocnv_local )
4337!   
4338!-- 2.2.2) Condensational sink of pre-existing particle population
4339!
4340!-- Diffusion coefficient (m2/s)
4341    zdfvap = 5.1111E-10_wp * ptemp ** 1.75_wp * ( p_0 + 1325.0_wp ) / ppres
4342!-- Mean free path of condensing vapour (m) (Jacobson (2005), Eq. 15.25 and
4343!-- 16.29)
4344    zmfp = 3.0_wp * zdfvap * SQRT( pi * amh2so4 / ( 8.0_wp * argas * ptemp ) )
4345!-- Knudsen number           
4346    zknud = 2.0_wp * zmfp / ( paero(:)%dwet + d_sa )                     
4347!-- Transitional regime correction factor (zbeta) according to Fuchs and
4348!-- Sutugin (1971), In: Hidy et al. (ed.), Topics in current  aerosol research,
4349!-- Pergamon. (Eq. 4 in Kerminen and Kulmala, 2002)
4350    zbeta = ( zknud + 1.0_wp) / ( 0.377_wp * zknud + 1.0_wp + 4.0_wp /         &
4351            ( 3.0_wp * massacc ) * ( zknud + zknud ** 2 ) ) 
4352!-- Condensational sink (#/m2) (Eq. 3)
4353    zcsink = SUM( paero(:)%dwet * zbeta * paero(:)%numc )
4354!
4355!-- Parameterised formation rate of detectable 3 nm particles (i.e. J3)
4356    IF ( nj3 == 1 )  THEN   ! Kerminen and Kulmala (2002)
4357!--    2.2.3) Parameterised formation rate of detectable 3 nm particles
4358!--    Constants needed for the parameterisation:
4359!--    dapp = 3 nm and dens_nuc = 1830 kg/m3
4360       IF ( zcsink < 1.0E-30_wp )  THEN
4361          zeta = 0._dp
4362       ELSE
4363!--       Mean diameter of backgroud population (nm)
4364          zdmean = 1.0_wp / SUM( paero(:)%numc ) * SUM( paero(:)%numc *        &
4365                   paero(:)%dwet ) * 1.0E+9_wp
4366!--       Proportionality factor (nm2*m2/h) (Eq. 22)
4367          zgamma = 0.23_wp * ( zdcrit * 1.0E+9_wp ) ** 0.2_wp * ( zdmean /     &
4368                 150.0_wp ) ** 0.048_wp * ( ptemp / 293.0_wp ) ** ( -0.75_wp ) &
4369                 * ( arhoh2so4 / 1000.0_wp ) ** ( -0.33_wp )
4370!--       Factor eta (nm) (Eq. 11)
4371          zeta = MIN( zgamma * zcsink / zGRclust, zdcrit * 1.0E11_wp ) 
4372       ENDIF
4373!       
4374!--    Number conc. of clusters surviving to 3 nm in a time step (#/m3) (Eq.14)
4375       zj3 = zjnuc * EXP( MIN( 0.0_wp, zeta / 3.0_wp - zeta /                  &
4376                               ( zdcrit * 1.0E9_wp ) ) )                   
4377
4378    ELSEIF ( nj3 > 1 )  THEN
4379!--    Defining the value for zm_para. The growth is investigated between
4380!--    [d1,reglim(1)] = [zdcrit,3nm]   
4381!--    m = LOG( CoagS_dx / CoagX_zdcrit ) / LOG( reglim / zdcrit )
4382!--    (Lehtinen et al. 2007, Eq. 5)
4383!--    The steps for the coagulation sink for reglim = 3nm and zdcrit ~= 1nm are
4384!--    explained in article of Kulmala et al. (2001). The particles of diameter
4385!--    zdcrit ~1.14 nm  and reglim = 3nm are both in turn the "number 1"
4386!--    variables (Kulmala et al. 2001).             
4387!--    c = critical (1nm), x = 3nm, 2 = wet or mean droplet
4388!--    Sum of the radii, R12 = R1 + zR2 (m) of two particles 1 and 2
4389       zRc2 = zdcrit / 2.0_wp + paero(:)%dwet / 2.0_wp
4390       zRx2 = reglim(1) / 2.0_wp + paero(:)%dwet / 2.0_wp
4391!       
4392!--    The mass of particle (kg) (comes only from H2SO4)
4393       zm_c = 4.0_wp / 3.0_wp * pi * ( zdcrit / 2.0_wp ) ** 3.0_wp * arhoh2so4                     
4394       zm_x = 4.0_wp / 3.0_wp * pi * ( reglim(1) / 2.0_wp ) ** 3.0_wp *        &
4395              arhoh2so4                 
4396       zm_2 = 4.0_wp / 3.0_wp * pi * ( paero(:)%dwet / 2.0_wp )** 3.0_wp *     &
4397              arhoh2so4
4398!             
4399!--    Mean relative thermal velocity between the particles (m/s)
4400       zcv_c = SQRT( 8.0_wp * abo * ptemp / ( pi * zm_c ) )
4401       zcv_x = SQRT( 8.0_wp * abo * ptemp / ( pi * zm_x ) )
4402       zcv_2 = SQRT( 8.0_wp * abo * ptemp / ( pi * zm_2 ) )
4403!       
4404!--    Average velocity after coagulation               
4405       zcv_c2 = SQRT( zcv_c ** 2.0_wp + zcv_2 ** 2.0_wp )
4406       zcv_x2 = SQRT( zcv_x ** 2.0_wp + zcv_2 ** 2.0_wp )
4407!       
4408!--    Knudsen number (zmfp = mean free path of condensing vapour)
4409       zknud_c = 2.0_wp * zmfp / zdcrit
4410       zknud_x = 2.0_wp * zmfp / reglim(1)
4411       zknud_2 = MAX( 0.0_wp, 2.0_wp * zmfp / paero(:)%dwet )
4412!
4413!--    Cunningham correction factor               
4414       zCc_c = 1.0_wp + zknud_c * ( 1.142_wp + 0.558_wp *                      &
4415               EXP( -0.999_wp / zknud_c ) ) 
4416       zCc_x = 1.0_wp + zknud_x * ( 1.142_wp + 0.558_wp *                      &
4417               EXP( -0.999_wp / zknud_x ) )
4418       zCc_2 = 1.0_wp + zknud_2 * ( 1.142_wp + 0.558_wp *                      &
4419               EXP( -0.999_wp / zknud_2 ) )
4420!                     
4421!--    Gas dynamic viscosity (N*s/m2).
4422!--    Viscocity(air @20C) = 1.81e-5_dp N/m2 *s (Hinds, p. 25)                     
4423       zmyy = 1.81E-5_wp * ( ptemp / 293.0_wp) ** ( 0.74_wp ) 
4424!       
4425!--    Particle diffusion coefficient (m2/s)               
4426       zDc_c = abo * ptemp * zCc_c / ( 3.0_wp * pi * zmyy * zdcrit ) 
4427       zDc_x = abo * ptemp * zCc_x / ( 3.0_wp * pi * zmyy * reglim(1) )
4428       zDc_2 = abo * ptemp * zCc_2 / ( 3.0_wp * pi * zmyy * paero(:)%dwet )
4429!       
4430!--    D12 = D1+D2 (Seinfield and Pandis, 2nd ed. Eq. 13.38)
4431       zDc_c2 = zDc_c + zDc_2   
4432       zDc_x2 = zDc_x + zDc_2
4433!       
4434!--    zgammaF = 8*D/pi/zcv (m) for calculating zomega
4435       zgammaF_c = 8.0_wp * zDc_c / pi / zcv_c
4436       zgammaF_x = 8.0_wp * zDc_x / pi / zcv_x
4437       zgammaF_2 = 8.0_wp * zDc_2 / pi / zcv_2
4438!       
4439!--    zomega (m) for calculating zsigma             
4440       zomega_c = ( ( zRc2 + zgammaF_c ) ** 3 - ( zRc2 ** 2 +                  &
4441                      zgammaF_c ) ** ( 3.0_wp / 2.0_wp ) ) / ( 3.0_wp *        &
4442                      zRc2 * zgammaF_c ) - zRc2 
4443       zomega_x = ( ( zRx2 + zgammaF_x ) ** 3.0_wp - ( zRx2 ** 2.0_wp +        &
4444                      zgammaF_x ) ** ( 3.0_wp / 2.0_wp ) ) / ( 3.0_wp *        &
4445                      zRx2 * zgammaF_x ) - zRx2
4446       zomega_2c = ( ( zRc2 + zgammaF_2 ) ** 3.0_wp - ( zRc2 ** 2.0_wp +       &
4447                       zgammaF_2 ) ** ( 3.0_wp / 2.0_wp ) ) / ( 3.0_wp *       &
4448                       zRc2 * zgammaF_2 ) - zRc2
4449       zomega_2x = ( ( zRx2 + zgammaF_2 ) ** 3.0_wp - ( zRx2 ** 2.0_wp +       &
4450                       zgammaF_2 ) ** ( 3.0_wp / 2.0_wp ) ) / ( 3.0_wp *       &
4451                       zRx2 * zgammaF_2 ) - zRx2
4452!                       
4453!--    The distance (m) at which the two fluxes are matched (condensation and
4454!--    coagulation sinks?)           
4455       zsigma_c2 = SQRT( zomega_c ** 2.0_wp + zomega_2c ** 2.0_wp ) 
4456       zsigma_x2 = SQRT( zomega_x ** 2.0_wp + zomega_2x ** 2.0_wp ) 
4457!       
4458!--    Coagulation coefficient in the continuum regime (m*m2/s)
4459       zK_c2 = 4.0_wp * pi * zRc2 * zDc_c2 / ( zRc2 / ( zRc2 + zsigma_c2 ) +   &
4460               4.0_wp * zDc_c2 / ( zcv_c2 * zRc2 ) ) 
4461       zK_x2 = 4.0_wp * pi * zRx2 * zDc_x2 / ( zRx2 / ( zRx2 + zsigma_x2 ) +   &
4462               4.0_wp * zDc_x2 / ( zcv_x2 * zRx2 ) )
4463!               
4464!--    Coagulation sink (1/s)
4465       zCoagS_c = MAX( 1.0E-20_wp, SUM( zK_c2 * paero(:)%numc ) )         
4466       zCoagS_x = MAX( 1.0E-20_wp, SUM( zK_x2 * paero(:)%numc ) ) 
4467!       
4468!--    Parameter m for calculating the coagulation sink onto background
4469!--    particles (Eq. 5&6 in Lehtinen et al. 2007)             
4470       zm_para = LOG( zCoagS_x / zCoagS_c ) / LOG( reglim(1) / zdcrit )
4471!       
4472!--    Parameter gamma for calculating the formation rate J of particles having
4473!--    a diameter zdcrit < d < reglim(1) (Anttila et al. 2010, eq. 5)
4474       zgamma = ( ( ( reglim(1) / zdcrit ) ** ( zm_para + 1.0_wp ) ) - 1.0_wp )&
4475                / ( zm_para + 1.0_wp )     
4476               
4477       IF ( nj3 == 2 )  THEN   ! Coagulation sink
4478!       
4479!--       Formation rate J before iteration (#/m3s)               
4480          zj3 = zjnuc * EXP( MIN( 0.0_wp, -zgamma * zdcrit * zCoagS_c /        &
4481                ( zGRclust * 1.0E-9_wp / ( 60.0_wp ** 2.0_wp ) ) ) )
4482               
4483       ELSEIF ( nj3 == 3 )  THEN  ! Coagulation sink and self-coag.
4484!--       IF polluted air... then the self-coagulation becomes important.
4485!--       Self-coagulation of small particles < 3 nm.
4486!
4487!--       "Effective" coagulation coefficient between freshly-nucleated
4488!--       particles:
4489          zKeff = 5.0E-16_wp   ! cm3/s
4490!         
4491!--       zlambda parameter for "adjusting" the growth rate due to the
4492!--       self-coagulation
4493          zlambda = 6.0_wp 
4494          IF ( reglim(1) >= 10.0E-9_wp )  THEN   ! for particles >10 nm:
4495             zKeff   = 5.0E-17_wp
4496             zlambda = 3.0_wp
4497          ENDIF
4498!         
4499!--       Initial values for coagulation sink and growth rate  (m/s)
4500          zCoagStot = zCoagS_c
4501          zGRtot = zGRclust * 1.0E-9_wp / 60.0_wp ** 2.0_wp 
4502!         
4503!--       Number of clusters/particles at the size range [d1,dx] (#/m3):
4504          zNnuc = zjnuc / zCoagStot !< Initial guess
4505!         
4506!--       Coagulation sink and growth rate due to self-coagulation:
4507          DO  iteration = 1, 5
4508             zCoagStot = zCoagS_c + zKeff * zNnuc * 1.0E-6_wp   ! (1/s) 
4509             zGRtot = zGRclust * 1.0E-9_wp / ( 3600.0_wp ) +  1.5708E-6_wp *   &
4510                      zlambda * zdcrit ** 3.0_wp * ( zNnuc * 1.0E-6_wp ) *     &
4511                      zcv_c * avo * 1.0E-9_wp / 3600.0_wp 
4512             zeta = - zCoagStot / ( ( zm_para + 1.0_wp ) * zGRtot * ( zdcrit **&
4513                      zm_para ) )   ! Eq. 7b (Anttila)
4514             zNnuc =  zNnuc_tayl( zdcrit, reglim(1), zm_para, zjnuc, zeta,     &
4515                      zGRtot )
4516          ENDDO
4517!         
4518!--       Calculate the final values with new zNnuc:   
4519          zCoagStot = zCoagS_c + zKeff * zNnuc * 1.0E-6_wp   ! (1/s)
4520          zGRtot = zGRclust * 1.0E-9_wp / 3600.0_wp + 1.5708E-6_wp *  zlambda  &
4521                   * zdcrit ** 3.0_wp * ( zNnuc * 1.0E-6_wp ) * zcv_c * avo *  &
4522                   1.0E-9_wp / 3600.0_wp !< (m/s)
4523          zj3 = zjnuc * EXP( MIN( 0.0_wp, -zgamma * zdcrit * zCoagStot /       &
4524                zGRtot ) )   ! (Eq. 5a) (#/m3s)
4525               
4526       ENDIF
4527       
4528    ENDIF
4529!-- If J3 very small (< 1 #/cm3), neglect particle formation. In real atmosphere
4530!-- this would mean that clusters form but coagulate to pre-existing particles
4531!-- who gain sulphate. Since CoagS ~ CS (4piD*CS'), we do *not* update H2SO4
4532!-- concentration here but let condensation take care of it.
4533!-- Formation mass rate of molecules (molec/m3s) for 1: H2SO4 and 2: organic
4534!-- vapour
4535    pj3n3(1) = zj3 * n3 * pxsa
4536    pj3n3(2) = zj3 * n3 * pxocnv
4537                                 
4538                         
4539 END SUBROUTINE nucleation
4540
4541!------------------------------------------------------------------------------!
4542! Description:
4543! ------------
4544!> Calculate the nucleation rate and the size of critical clusters assuming
4545!> binary nucleation.
4546!> Parametrisation according to Vehkamaki et al. (2002), J. Geophys. Res.,
4547!> 107(D22), 4622. Called from subroutine nucleation.
4548!------------------------------------------------------------------------------!
4549 SUBROUTINE binnucl( pc_sa, ptemp, prh, pnuc_rate, pn_crit_sa, pn_crit_ocnv,   &
4550                     pd_crit, pk_sa, pk_ocnv )
4551                   
4552    IMPLICIT NONE
4553!       
4554!-- Input and output variables       
4555    REAL(wp), INTENT(in) ::   pc_sa        !< H2SO4 conc. (#/cm3)
4556    REAL(wp), INTENT(in) ::   prh          !< relative humidity [0-1]       
4557    REAL(wp), INTENT(in) ::   ptemp        !< ambient temperature (K)
4558    REAL(wp), INTENT(out) ::  pnuc_rate    !< nucleation rate (#/(m3 s))
4559    REAL(wp), INTENT(out) ::  pn_crit_sa   !< number of H2SO4 molecules in
4560                                           !< cluster (#)
4561    REAL(wp), INTENT(out) ::  pn_crit_ocnv !< number of organic molecules in
4562                                           !< cluster (#)
4563    REAL(wp), INTENT(out) ::  pd_crit      !< diameter of critical cluster (m)
4564    REAL(wp), INTENT(out) ::  pk_sa        !< Lever: if pk_sa = 1, H2SO4 is
4565                                           !< involved in nucleation.
4566    REAL(wp), INTENT(out) ::  pk_ocnv      !< Lever: if pk_ocnv = 1, organic
4567                                           !< compounds are involved in
4568                                           !< nucleation.
4569!-- Local variables
4570    REAL(wp) ::  zx    !< mole fraction of sulphate in critical cluster
4571    REAL(wp) ::  zntot !< number of molecules in critical cluster
4572    REAL(wp) ::  zt    !< temperature
4573    REAL(wp) ::  zpcsa !< sulfuric acid concentration
4574    REAL(wp) ::  zrh   !< relative humidity
4575    REAL(wp) ::  zma   !<
4576    REAL(wp) ::  zmw   !<
4577    REAL(wp) ::  zxmass!<
4578    REAL(wp) ::  za    !<
4579    REAL(wp) ::  zb    !<
4580    REAL(wp) ::  zc    !<
4581    REAL(wp) ::  zroo  !<
4582    REAL(wp) ::  zm1   !<
4583    REAL(wp) ::  zm2   !<
4584    REAL(wp) ::  zv1   !<
4585    REAL(wp) ::  zv2   !<
4586    REAL(wp) ::  zcoll !<
4587   
4588    pnuc_rate = 0.0_wp
4589    pd_crit   = 1.0E-9_wp
4590
4591!             
4592!-- 1) Checking that we are in the validity range of the parameterization 
4593    zt    = MAX( ptemp, 190.15_wp )
4594    zt    = MIN( zt,    300.15_wp )
4595    zpcsa = MAX( pc_sa, 1.0E4_wp  )
4596    zpcsa = MIN( zpcsa, 1.0E11_wp ) 
4597    zrh   = MAX( prh,   0.0001_wp )
4598    zrh   = MIN( zrh,   1.0_wp    )
4599!               
4600!-- 2) Mole fraction of sulphate in a critical cluster (Eq. 11)
4601    zx = 0.7409967177282139_wp                                           &
4602         - 0.002663785665140117_wp * zt                                  &
4603         + 0.002010478847383187_wp * LOG( zrh )                          &
4604         - 0.0001832894131464668_wp* zt * LOG( zrh )                     &
4605         + 0.001574072538464286_wp * LOG( zrh ) ** 2                     &
4606         - 0.00001790589121766952_wp * zt * LOG( zrh ) ** 2              &
4607         + 0.0001844027436573778_wp * LOG( zrh ) ** 3                    &
4608         - 1.503452308794887E-6_wp * zt * LOG( zrh ) ** 3                &
4609         - 0.003499978417957668_wp * LOG( zpcsa )                        &
4610         + 0.0000504021689382576_wp * zt * LOG( zpcsa )
4611!                   
4612!-- 3) Nucleation rate (Eq. 12)
4613    pnuc_rate = 0.1430901615568665_wp                                    &
4614        + 2.219563673425199_wp * zt                                      &
4615        - 0.02739106114964264_wp * zt ** 2                               &
4616        + 0.00007228107239317088_wp * zt ** 3                            &
4617        + 5.91822263375044_wp / zx                                       &
4618        + 0.1174886643003278_wp * LOG( zrh )                             &
4619        + 0.4625315047693772_wp * zt * LOG( zrh )                        &
4620        - 0.01180591129059253_wp * zt ** 2 * LOG( zrh )                  &
4621        + 0.0000404196487152575_wp * zt ** 3 * LOG( zrh )                &
4622        + ( 15.79628615047088_wp * LOG( zrh ) ) / zx                     &
4623        - 0.215553951893509_wp * LOG( zrh ) ** 2                         &
4624        - 0.0810269192332194_wp * zt * LOG( zrh ) ** 2                   &
4625        + 0.001435808434184642_wp * zt ** 2 * LOG( zrh ) ** 2            &
4626        - 4.775796947178588E-6_wp * zt ** 3 * LOG( zrh ) ** 2            &
4627        - (2.912974063702185_wp * LOG( zrh ) ** 2 ) / zx                 &
4628        - 3.588557942822751_wp * LOG( zrh ) ** 3                         &
4629        + 0.04950795302831703_wp * zt * LOG( zrh ) ** 3                  &
4630        - 0.0002138195118737068_wp * zt ** 2 * LOG( zrh ) ** 3           &
4631        + 3.108005107949533E-7_wp * zt ** 3 * LOG( zrh ) ** 3            &
4632        - ( 0.02933332747098296_wp * LOG( zrh ) ** 3 ) / zx              &
4633        + 1.145983818561277_wp * LOG( zpcsa )                            &
4634        - 0.6007956227856778_wp * zt * LOG( zpcsa )                      &
4635        + 0.00864244733283759_wp * zt ** 2 * LOG( zpcsa )                &
4636        - 0.00002289467254710888_wp * zt ** 3 * LOG( zpcsa )             &
4637        - ( 8.44984513869014_wp * LOG( zpcsa ) ) / zx                    &
4638        + 2.158548369286559_wp * LOG( zrh ) * LOG( zpcsa )               &
4639        + 0.0808121412840917_wp * zt * LOG( zrh ) * LOG( zpcsa )         &
4640        - 0.0004073815255395214_wp * zt ** 2 * LOG( zrh ) * LOG( zpcsa ) &
4641        - 4.019572560156515E-7_wp * zt ** 3 * LOG( zrh ) * LOG( zpcsa )  & 
4642        + ( 0.7213255852557236_wp * LOG( zrh ) * LOG( zpcsa ) ) / zx     &
4643        + 1.62409850488771_wp * LOG( zrh ) ** 2 * LOG( zpcsa )           &
4644        - 0.01601062035325362_wp * zt * LOG( zrh ) ** 2 * LOG( zpcsa )   &
4645        + 0.00003771238979714162_wp*zt**2* LOG( zrh )**2 * LOG( zpcsa )  &
4646        + 3.217942606371182E-8_wp * zt**3 * LOG( zrh )**2 * LOG( zpcsa ) &
4647        - (0.01132550810022116_wp * LOG( zrh )**2 * LOG( zpcsa ) ) / zx  &
4648        + 9.71681713056504_wp * LOG( zpcsa ) ** 2                        &
4649        - 0.1150478558347306_wp * zt * LOG( zpcsa ) ** 2                 &
4650        + 0.0001570982486038294_wp * zt ** 2 * LOG( zpcsa ) ** 2         &
4651        + 4.009144680125015E-7_wp * zt ** 3 * LOG( zpcsa ) ** 2          &
4652        + ( 0.7118597859976135_wp * LOG( zpcsa ) ** 2 ) / zx             &
4653        - 1.056105824379897_wp * LOG( zrh ) * LOG( zpcsa ) ** 2          &
4654        + 0.00903377584628419_wp * zt * LOG( zrh ) * LOG( zpcsa )**2     &
4655        - 0.00001984167387090606_wp*zt**2*LOG( zrh )*LOG( zpcsa )**2     &
4656        + 2.460478196482179E-8_wp * zt**3 * LOG( zrh ) * LOG( zpcsa )**2 &
4657        - ( 0.05790872906645181_wp * LOG( zrh ) * LOG( zpcsa )**2 ) / zx &
4658        - 0.1487119673397459_wp * LOG( zpcsa ) ** 3                      &
4659        + 0.002835082097822667_wp * zt * LOG( zpcsa ) ** 3               &
4660        - 9.24618825471694E-6_wp * zt ** 2 * LOG( zpcsa ) ** 3           &
4661        + 5.004267665960894E-9_wp * zt ** 3 * LOG( zpcsa ) ** 3          &
4662        - ( 0.01270805101481648_wp * LOG( zpcsa ) ** 3 ) / zx
4663!           
4664!-- Nucleation rate in #/(cm3 s)
4665    pnuc_rate = EXP( pnuc_rate ) 
4666!       
4667!-- Check the validity of parameterization
4668    IF ( pnuc_rate < 1.0E-7_wp )  THEN
4669       pnuc_rate = 0.0_wp
4670       pd_crit   = 1.0E-9_wp
4671    ENDIF
4672!               
4673!-- 4) Total number of molecules in the critical cluster (Eq. 13)
4674    zntot = - 0.002954125078716302_wp                                    &
4675      - 0.0976834264241286_wp * zt                                       &
4676      + 0.001024847927067835_wp * zt ** 2                                &
4677      - 2.186459697726116E-6_wp * zt ** 3                                &
4678      - 0.1017165718716887_wp / zx                                       &
4679      - 0.002050640345231486_wp * LOG( zrh )                             &
4680      - 0.007585041382707174_wp * zt * LOG( zrh )                        &
4681      + 0.0001926539658089536_wp * zt ** 2 * LOG( zrh )                  &
4682      - 6.70429719683894E-7_wp * zt ** 3 * LOG( zrh )                    &
4683      - ( 0.2557744774673163_wp * LOG( zrh ) ) / zx                      &
4684      + 0.003223076552477191_wp * LOG( zrh ) ** 2                        &
4685      + 0.000852636632240633_wp * zt * LOG( zrh ) ** 2                   &
4686      - 0.00001547571354871789_wp * zt ** 2 * LOG( zrh ) ** 2            &
4687      + 5.666608424980593E-8_wp * zt ** 3 * LOG( zrh ) ** 2              &
4688      + ( 0.03384437400744206_wp * LOG( zrh ) ** 2 ) / zx                &
4689      + 0.04743226764572505_wp * LOG( zrh ) ** 3                         &
4690      - 0.0006251042204583412_wp * zt * LOG( zrh ) ** 3                  &
4691      + 2.650663328519478E-6_wp * zt ** 2 * LOG( zrh ) ** 3              &
4692      - 3.674710848763778E-9_wp * zt ** 3 * LOG( zrh ) ** 3              &
4693      - ( 0.0002672510825259393_wp * LOG( zrh ) ** 3 ) / zx              &
4694      - 0.01252108546759328_wp * LOG( zpcsa )                            &
4695      + 0.005806550506277202_wp * zt * LOG( zpcsa )                      &
4696      - 0.0001016735312443444_wp * zt ** 2 * LOG( zpcsa )                &
4697      + 2.881946187214505E-7_wp * zt ** 3 * LOG( zpcsa )                 &
4698      + ( 0.0942243379396279_wp * LOG( zpcsa ) ) / zx                    &
4699      - 0.0385459592773097_wp * LOG( zrh ) * LOG( zpcsa )                &
4700      - 0.0006723156277391984_wp * zt * LOG( zrh ) * LOG( zpcsa )        &
4701      + 2.602884877659698E-6_wp * zt ** 2 * LOG( zrh ) * LOG( zpcsa )    &
4702      + 1.194163699688297E-8_wp * zt ** 3 * LOG( zrh ) * LOG( zpcsa )    &
4703      - ( 0.00851515345806281_wp * LOG( zrh ) * LOG( zpcsa ) ) / zx      &
4704      - 0.01837488495738111_wp * LOG( zrh ) ** 2 * LOG( zpcsa )          &
4705      + 0.0001720723574407498_wp * zt * LOG( zrh ) ** 2 * LOG( zpcsa )   &
4706      - 3.717657974086814E-7_wp * zt**2 * LOG( zrh )**2 * LOG( zpcsa )   &
4707      - 5.148746022615196E-10_wp * zt**3 * LOG( zrh )**2 * LOG( zpcsa )  &
4708      + ( 0.0002686602132926594_wp * LOG(zrh)**2 * LOG(zpcsa) ) / zx     &
4709      - 0.06199739728812199_wp * LOG( zpcsa ) ** 2                       &
4710      + 0.000906958053583576_wp * zt * LOG( zpcsa ) ** 2                 &
4711      - 9.11727926129757E-7_wp * zt ** 2 * LOG( zpcsa ) ** 2             &
4712      - 5.367963396508457E-9_wp * zt ** 3 * LOG( zpcsa ) ** 2            &
4713      - ( 0.007742343393937707_wp * LOG( zpcsa ) ** 2 ) / zx             &
4714      + 0.0121827103101659_wp * LOG( zrh ) * LOG( zpcsa ) ** 2           &
4715      - 0.0001066499571188091_wp * zt * LOG( zrh ) * LOG( zpcsa ) ** 2   &
4716      + 2.534598655067518E-7_wp * zt**2 * LOG( zrh ) * LOG( zpcsa )**2   &
4717      - 3.635186504599571E-10_wp * zt**3 * LOG( zrh ) * LOG( zpcsa )**2  &
4718      + ( 0.0006100650851863252_wp * LOG( zrh ) * LOG( zpcsa ) **2 )/ zx &
4719      + 0.0003201836700403512_wp * LOG( zpcsa ) ** 3                     &
4720      - 0.0000174761713262546_wp * zt * LOG( zpcsa ) ** 3                &
4721      + 6.065037668052182E-8_wp * zt ** 2 * LOG( zpcsa ) ** 3            &
4722      - 1.421771723004557E-11_wp * zt ** 3 * LOG( zpcsa ) ** 3           &
4723      + ( 0.0001357509859501723_wp * LOG( zpcsa ) ** 3 ) / zx
4724    zntot = EXP( zntot )  ! in #
4725!
4726!-- 5) Size of the critical cluster pd_crit (m) (diameter) (Eq. 14)
4727    pn_crit_sa = zx * zntot
4728    pd_crit    = 2.0E-9_wp * EXP( -1.6524245_wp + 0.42316402_wp  * zx +        &
4729                 0.33466487_wp * LOG( zntot ) )
4730!
4731!-- 6) Organic compounds not involved when binary nucleation is assumed
4732    pn_crit_ocnv = 0.0_wp   ! number of organic molecules
4733    pk_sa        = 1.0_wp   ! if = 1, H2SO4 involved in nucleation
4734    pk_ocnv      = 0.0_wp   ! if = 1, organic compounds involved
4735!               
4736!-- Set nucleation rate to collision rate               
4737    IF ( pn_crit_sa < 4.0_wp ) THEN
4738!       
4739!--    Volumes of the colliding objects
4740       zma    = 96.0_wp   ! molar mass of SO4 in g/mol
4741       zmw    = 18.0_wp   ! molar mass of water in g/mol
4742       zxmass = 1.0_wp    ! mass fraction of H2SO4
4743       za = 0.7681724_wp + zxmass * ( 2.1847140_wp + zxmass * (     &
4744            7.1630022_wp + zxmass * ( -44.31447_wp + zxmass * (     &
4745            88.75606 + zxmass * ( -75.73729_wp + zxmass *           &
4746            23.43228_wp ) ) ) ) )
4747       zb = 1.808225E-3_wp + zxmass * ( -9.294656E-3_wp + zxmass *  &
4748            ( -0.03742148_wp + zxmass * ( 0.2565321_wp + zxmass *   &
4749            ( -0.5362872_wp + zxmass * ( 0.4857736 - zxmass *       &
4750            0.1629592_wp ) ) ) ) )
4751       zc = - 3.478524E-6_wp + zxmass * ( 1.335867E-5_wp + zxmass * &
4752           ( 5.195706E-5_wp + zxmass * ( -3.717636E-4_wp + zxmass * &
4753           ( 7.990811E-4_wp + zxmass * ( -7.458060E-4_wp + zxmass * &
4754             2.58139E-4_wp )