Home

Context Navigation

source: palm/trunk/SOURCE/pmc_handle_communicator_mod.f90 @ 3885

Last change on this file since 3885 was 3885, checked in by kanani, 5 years ago
restructure/add location/debug messages
Property svn:keywords set to `Id`
File size: 20.3 KB

Line
1	!> @file pmc_handle_communicator_mod.f90
2	!------------------------------------------------------------------------------!
3	! This file is part of the PALM model system.
4	!
5	! PALM is free software: you can redistribute it and/or modify it under the
6	! terms of the GNU General Public License as published by the Free Software
7	! Foundation, either version 3 of the License, or (at your option) any later
8	! version.
9	!
10	! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11	! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12	! A PARTICULAR PURPOSE. See the GNU General Public License for more details.
13	!
14	! You should have received a copy of the GNU General Public License along with
15	! PALM. If not, see <http://www.gnu.org/licenses/>.
16	!
17	! Copyright 1997-2019 Leibniz Universitaet Hannover
18	!------------------------------------------------------------------------------!
19	!
20	! Current revisions:
21	! ------------------
22	!
23	!
24	! Former revisions:
25	! -----------------
26	! $Id: pmc_handle_communicator_mod.f90 3885 2019-04-11 11:29:34Z kanani $
27	! Changes related to global restructuring of location messages and introduction
28	! of additional debug messages
29	!
30	! 3819 2019-03-27 11:01:36Z hellstea
31	! Adjustable anterpolation buffer introduced on all nest boundaries, it is controlled
32	! by the new nesting_parameters parameter anterpolation_buffer_width.
33	!
34	! 3655 2019-01-07 16:51:22Z knoop
35	! nestpar renamed to nesting_parameters
36	!
37	! 2841 2018-02-27 15:02:57Z knoop
38	! Bugfix: wrong placement of include 'mpif.h' corrected
39	!
40	! 2801 2018-02-14 16:01:55Z thiele
41	! Introduce particle transfer in nested models.
42	!
43	! 2718 2018-01-02 08:49:38Z maronga
44	! Corrected "Former revisions" section
45	!
46	! 2696 2017-12-14 17:12:51Z kanani
47	! Change in file header (GPL part)
48	! Bugfix, give Intent(inout) attributes in routine reading nestpar-namelist (MS)
49	!
50	! 2599 2017-11-01 13:18:45Z hellstea
51	! Separate peer communicator peer_comm introduced for MPI_INTERCOMM_CREATE.
52	! Some cleanup and commenting improvements.
53	!
54	! 2516 2017-10-04 11:03:04Z suehring
55	! Remove tabs
56	!
57	! 2514 2017-10-04 09:52:37Z suehring
58	! Bugfix, set filepointer to the beginning of the file after namelist read,
59	! in order to assure that further namelists are also found.
60	!
61	! 2279 2017-06-12 15:23:44Z suehring
62	! Error message text changed
63	!
64	! 2101 2017-01-05 16:42:31Z suehring
65	!
66	! 2013 2016-09-21 13:07:56Z suehring
67	! Bugfix in format descriptor
68	!
69	! 2000 2016-08-20 18:09:15Z knoop
70	! Forced header and separation lines into 80 columns
71	!
72	! 1938 2016-06-13 15:26:05Z hellstea
73	! Minor clean-up.
74	!
75	! 1901 2016-05-04 15:39:38Z raasch
76	! Initial version of purely vertical nesting introduced.
77	! Code clean up. The words server/client changed to parent/child.
78	!
79	! 1900 2016-05-04 15:27:53Z raasch
80	! re-formatting to match PALM style
81	!
82	! 1882 2016-04-20 15:24:46Z hellstea
83	! MPI_BCAST-calls to broadcast nesting_mode and nesting_datatransfer_mode
84	! are moved out from the DO i = 1, m_ncpl loop.
85	!
86	! 1850 2016-04-08 13:29:27Z maronga
87	! Module renamed
88	!
89	! 1808 2016-04-05 19:44:00Z raasch
90	! MPI module used by default on all machines
91	!
92	! 1797 2016-03-21 16:50:28Z raasch
93	! introduction of different datatransfer modes,
94	! export of comm_world_nesting
95	!
96	! 1791 2016-03-11 10:41:25Z raasch
97	! m_nrofcpl renamed m_ncpl,
98	! pmc_get_local_model_info renamed pmc_get_model_info, some keywords also
99	! renamed and some added,
100	! debug write-statements commented out
101	!
102	! 1786 2016-03-08 05:49:27Z raasch
103	! Bugfix: nesting_mode is broadcast now
104	!
105	! 1779 2016-03-03 08:01:28Z raasch
106	! only the total number of PEs is given in the nestpar-NAMELIST,
107	! additional comments included
108	!
109	! 1764 2016-02-28 12:45:19Z raasch
110	! pmc_layout type: comm_cpl and comm_parent removed, character "name" moved at
111	! the beginning of the variable list,
112	! domain layout is read with new NAMELIST nestpar from standard file PARIN,
113	! MPI-datatype REAL8 replaced by REAL, kind=8 replaced by wp,
114	! variable domain_layouts instead of m_couplers introduced for this NAMELIST,
115	! general format changed to PALM style
116	!
117	! 1762 2016-02-25 12:31:13Z hellstea
118	! Initial revision by K. Ketelsen
119	!
120	! Description:
121	! ------------
122	! Handle MPI communicator in PALM model coupler
123	!-------------------------------------------------------------------------------!
124	MODULE PMC_handle_communicator
125	#if defined( __parallel )
126	USE kinds
127
128	#if !defined( __mpifh )
129	USE MPI
130	#endif
131
132	USE pmc_general, &
133	ONLY: pmc_status_ok, pmc_status_error, pmc_max_models
134	USE control_parameters, &
135	ONLY: message_string
136
137	IMPLICIT NONE
138
139	#if defined( __mpifh )
140	INCLUDE "mpif.h"
141	#endif
142
143	TYPE pmc_layout
144
145	CHARACTER(LEN=32) :: name
146
147	INTEGER :: id !<
148	INTEGER :: parent_id !<
149	INTEGER :: npe_total !<
150
151	REAL(wp) :: lower_left_x !<
152	REAL(wp) :: lower_left_y !<
153
154	END TYPE pmc_layout
155
156	PUBLIC pmc_status_ok, pmc_status_error
157
158	INTEGER, PARAMETER, PUBLIC :: pmc_error_npes = 1 !< illegal number of processes
159	INTEGER, PARAMETER, PUBLIC :: pmc_namelist_error = 2 !< error(s) in nesting_parameters namelist
160	INTEGER, PARAMETER, PUBLIC :: pmc_no_namelist_found = 3 !< no couple layout namelist found
161
162	INTEGER :: m_world_comm !< global nesting communicator
163	INTEGER :: m_my_cpl_id !< coupler id of this model
164	INTEGER :: m_parent_id !< coupler id of parent of this model
165	INTEGER :: m_ncpl !< number of couplers given in nesting_parameters namelist
166
167	TYPE(pmc_layout), PUBLIC, DIMENSION(pmc_max_models) :: m_couplers !< information of all couplers
168
169	INTEGER, PUBLIC :: m_model_comm !< communicator of this model
170	INTEGER, PUBLIC :: m_to_parent_comm !< communicator to the parent
171	INTEGER, PUBLIC :: m_world_rank !<
172	INTEGER :: m_world_npes !<
173	INTEGER, PUBLIC :: m_model_rank !<
174	INTEGER, PUBLIC :: m_model_npes !<
175	INTEGER :: m_parent_remote_size !< number of processes in the parent model
176	INTEGER :: peer_comm !< peer_communicator for inter communicators
177
178	INTEGER, DIMENSION(pmc_max_models), PUBLIC :: m_to_child_comm !< communicator to the child(ren)
179	INTEGER, DIMENSION(:), POINTER, PUBLIC :: pmc_parent_for_child !<
180
181
182	INTERFACE pmc_is_rootmodel
183	MODULE PROCEDURE pmc_is_rootmodel
184	END INTERFACE pmc_is_rootmodel
185
186	INTERFACE pmc_get_model_info
187	MODULE PROCEDURE pmc_get_model_info
188	END INTERFACE pmc_get_model_info
189
190	PUBLIC pmc_get_model_info, pmc_init_model, pmc_is_rootmodel
191
192	CONTAINS
193
194	SUBROUTINE pmc_init_model( comm, nesting_datatransfer_mode, nesting_mode, &
195	anterpolation_buffer_width, pmc_status )
196
197	USE control_parameters, &
198	ONLY: message_string
199
200	USE pegrid, &
201	ONLY: myid
202
203	IMPLICIT NONE
204
205	CHARACTER(LEN=8), INTENT(INOUT) :: nesting_mode !<
206	CHARACTER(LEN=7), INTENT(INOUT) :: nesting_datatransfer_mode !<
207
208	INTEGER, INTENT(INOUT) :: anterpolation_buffer_width !< Boundary buffer width for anterpolation
209	INTEGER, INTENT(INOUT) :: comm !<
210	INTEGER, INTENT(INOUT) :: pmc_status !<
211
212	INTEGER :: childcount !<
213	INTEGER :: i !<
214	INTEGER :: ierr !<
215	INTEGER :: istat !<
216	INTEGER :: m_my_cpl_rank !<
217	INTEGER :: tag !<
218
219	INTEGER, DIMENSION(pmc_max_models) :: activeparent ! I am active parent for this child ID
220	INTEGER, DIMENSION(pmc_max_models+1) :: start_pe
221
222	pmc_status = pmc_status_ok
223	comm = -1
224	m_world_comm = MPI_COMM_WORLD
225	m_my_cpl_id = -1
226	childcount = 0
227	activeparent = -1
228	start_pe(:) = 0
229
230	CALL MPI_COMM_RANK( MPI_COMM_WORLD, m_world_rank, istat )
231	CALL MPI_COMM_SIZE( MPI_COMM_WORLD, m_world_npes, istat )
232	!
233	!-- Only process 0 of root model reads
234	IF ( m_world_rank == 0 ) THEN
235
236	CALL read_coupling_layout( nesting_datatransfer_mode, nesting_mode, &
237	anterpolation_buffer_width, pmc_status )
238
239	IF ( pmc_status /= pmc_no_namelist_found .AND. &
240	pmc_status /= pmc_namelist_error ) &
241	THEN
242	!
243	!-- Calculate start PE of every model
244	start_pe(1) = 0
245	DO i = 2, m_ncpl+1
246	start_pe(i) = start_pe(i-1) + m_couplers(i-1)%npe_total
247	ENDDO
248
249	!
250	!-- The sum of numbers of processes requested by all the domains
251	!-- must be equal to the total number of processes of the run
252	IF ( start_pe(m_ncpl+1) /= m_world_npes ) THEN
253	WRITE ( message_string, '(2A,I6,2A,I6,A)' ) &
254	'nesting-setup requires different number of ', &
255	'MPI procs (', start_pe(m_ncpl+1), ') than ', &
256	'provided (', m_world_npes,')'
257	CALL message( 'pmc_init_model', 'PA0229', 3, 2, 0, 6, 0 )
258	ENDIF
259
260	ENDIF
261
262	ENDIF
263	!
264	!-- Broadcast the read status. This synchronises all other processes with
265	!-- process 0 of the root model. Without synchronisation, they would not
266	!-- behave in the correct way (e.g. they would not return in case of a
267	!-- missing NAMELIST).
268	CALL MPI_BCAST( pmc_status, 1, MPI_INTEGER, 0, MPI_COMM_WORLD, istat )
269
270	IF ( pmc_status == pmc_no_namelist_found ) THEN
271	!
272	!-- Not a nested run; return the MPI_WORLD communicator
273	comm = MPI_COMM_WORLD
274	RETURN
275
276	ELSEIF ( pmc_status == pmc_namelist_error ) THEN
277	!
278	!-- Only the root model gives the error message. Others are aborted by the
279	!-- message-routine with MPI_ABORT. Must be done this way since myid and
280	!-- comm2d have not yet been assigned at this point.
281	IF ( m_world_rank == 0 ) THEN
282	message_string = 'errors in \$nesting_parameters'
283	CALL message( 'pmc_init_model', 'PA0223', 3, 2, 0, 6, 0 )
284	ENDIF
285
286	ENDIF
287
288	CALL MPI_BCAST( m_ncpl, 1, MPI_INTEGER, 0, MPI_COMM_WORLD, istat )
289	CALL MPI_BCAST( start_pe, m_ncpl+1, MPI_INTEGER, 0, MPI_COMM_WORLD, istat )
290	!
291	!-- Broadcast coupling layout
292	DO i = 1, m_ncpl
293	CALL MPI_BCAST( m_couplers(i)%name, LEN( m_couplers(i)%name ), &
294	MPI_CHARACTER, 0, MPI_COMM_WORLD, istat )
295	CALL MPI_BCAST( m_couplers(i)%id, 1, MPI_INTEGER, 0, &
296	MPI_COMM_WORLD, istat )
297	CALL MPI_BCAST( m_couplers(i)%Parent_id, 1, MPI_INTEGER, 0, &
298	MPI_COMM_WORLD, istat )
299	CALL MPI_BCAST( m_couplers(i)%npe_total, 1, MPI_INTEGER, 0, &
300	MPI_COMM_WORLD, istat )
301	CALL MPI_BCAST( m_couplers(i)%lower_left_x, 1, MPI_REAL, 0, &
302	MPI_COMM_WORLD, istat )
303	CALL MPI_BCAST( m_couplers(i)%lower_left_y, 1, MPI_REAL, 0, &
304	MPI_COMM_WORLD, istat )
305	ENDDO
306	CALL MPI_BCAST( nesting_mode, LEN( nesting_mode ), MPI_CHARACTER, 0, &
307	MPI_COMM_WORLD, istat )
308	CALL MPI_BCAST( nesting_datatransfer_mode, LEN(nesting_datatransfer_mode), &
309	MPI_CHARACTER, 0, MPI_COMM_WORLD, istat )
310	!
311	!-- Assign global MPI processes to individual models by setting the couple id
312	DO i = 1, m_ncpl
313	IF ( m_world_rank >= start_pe(i) .AND. m_world_rank < start_pe(i+1) ) &
314	THEN
315	m_my_cpl_id = i
316	EXIT
317	ENDIF
318	ENDDO
319	m_my_cpl_rank = m_world_rank - start_pe(i)
320	!
321	!-- MPI_COMM_WORLD is the communicator for ALL models (MPI-1 approach).
322	!-- The communictors for the individual models as created by MPI_COMM_SPLIT.
323	!-- The color of the model is represented by the coupler id
324	CALL MPI_COMM_SPLIT( MPI_COMM_WORLD, m_my_cpl_id, m_my_cpl_rank, comm, &
325	istat )
326	!
327	!-- Get size and rank of the model running on this process
328	CALL MPI_COMM_RANK( comm, m_model_rank, istat )
329	CALL MPI_COMM_SIZE( comm, m_model_npes, istat )
330	!
331	!-- Broadcast (from process 0) the parent id and id of every model
332	DO i = 1, m_ncpl
333	CALL MPI_BCAST( m_couplers(i)%parent_id, 1, MPI_INTEGER, 0, &
334	MPI_COMM_WORLD, istat )
335	CALL MPI_BCAST( m_couplers(i)%id, 1, MPI_INTEGER, 0, &
336	MPI_COMM_WORLD, istat )
337	ENDDO
338	!
339	!-- Save the current model communicator for pmc internal use
340	m_model_comm = comm
341
342	!
343	!-- Create intercommunicator between the parent and children.
344	!-- MPI_INTERCOMM_CREATE creates an intercommunicator between 2 groups of
345	!-- different colors.
346	!-- The grouping was done above with MPI_COMM_SPLIT.
347	!-- A duplicate of MPI_COMM_WORLD is created and used as peer communicator
348	!-- (peer_comm) for MPI_INTERCOMM_CREATE.
349	CALL MPI_COMM_DUP( MPI_COMM_WORLD, peer_comm, ierr )
350	DO i = 2, m_ncpl
351	IF ( m_couplers(i)%parent_id == m_my_cpl_id ) THEN
352	!
353	!-- Identify all children models of the current model and create
354	!-- inter-communicators to connect between the current model and its
355	!-- children models.
356	tag = 500 + i
357	CALL MPI_INTERCOMM_CREATE( comm, 0, peer_comm, start_pe(i), &
358	tag, m_to_child_comm(i), istat)
359	childcount = childcount + 1
360	activeparent(i) = 1
361	ELSEIF ( i == m_my_cpl_id) THEN
362	!
363	!-- Create an inter-communicator to connect between the current
364	!-- model and its parent model.
365	tag = 500 + i
366	CALL MPI_INTERCOMM_CREATE( comm, 0, peer_comm, &
367	start_pe(m_couplers(i)%parent_id), &
368	tag, m_to_parent_comm, istat )
369	ENDIF
370	ENDDO
371	!
372	!-- If I am a parent, count the number of children I have.
373	!-- Although this loop is symmetric on all processes, the "activeparent" flag
374	!-- is true (==1) on the respective individual process only.
375	ALLOCATE( pmc_parent_for_child(childcount+1) )
376
377	childcount = 0
378	DO i = 2, m_ncpl
379	IF ( activeparent(i) == 1 ) THEN
380	childcount = childcount + 1
381	pmc_parent_for_child(childcount) = i
382	ENDIF
383	ENDDO
384	!
385	!-- Get the size of the parent model
386	IF ( m_my_cpl_id > 1 ) THEN
387	CALL MPI_COMM_REMOTE_SIZE( m_to_parent_comm, m_parent_remote_size, &
388	istat )
389	ELSE
390	!
391	!-- The root model does not have a parent
392	m_parent_remote_size = -1
393	ENDIF
394	!
395	!-- Set myid to non-zero value except for the root domain. This is a setting
396	!-- for the message routine which is called at the end of pmci_init. That
397	!-- routine outputs messages for myid = 0, only. However, myid has not been
398	!-- assigened so far, so that all processes of the root model would output a
399	!-- message. To avoid this, set myid to some other value except for process 0
400	!-- of the root domain.
401	IF ( m_world_rank /= 0 ) myid = 1
402
403	END SUBROUTINE PMC_init_model
404
405
406
407	SUBROUTINE pmc_get_model_info( comm_world_nesting, cpl_id, cpl_name, &
408	cpl_parent_id, lower_left_x, lower_left_y, &
409	ncpl, npe_total, request_for_cpl_id )
410	!
411	!-- Provide module private variables of the pmc for PALM
412
413	USE kinds
414
415	IMPLICIT NONE
416
417	CHARACTER(LEN=*), INTENT(OUT), OPTIONAL :: cpl_name !<
418
419	INTEGER, INTENT(IN), OPTIONAL :: request_for_cpl_id !<
420
421	INTEGER, INTENT(OUT), OPTIONAL :: comm_world_nesting !<
422	INTEGER, INTENT(OUT), OPTIONAL :: cpl_id !<
423	INTEGER, INTENT(OUT), OPTIONAL :: cpl_parent_id !<
424	INTEGER, INTENT(OUT), OPTIONAL :: ncpl !<
425	INTEGER, INTENT(OUT), OPTIONAL :: npe_total !<
426
427	INTEGER :: requested_cpl_id !<
428
429	REAL(wp), INTENT(OUT), OPTIONAL :: lower_left_x !<
430	REAL(wp), INTENT(OUT), OPTIONAL :: lower_left_y !<
431
432	!
433	!-- Set the requested coupler id
434	IF ( PRESENT( request_for_cpl_id ) ) THEN
435	requested_cpl_id = request_for_cpl_id
436	!
437	!-- Check for allowed range of values
438	IF ( requested_cpl_id < 1 .OR. requested_cpl_id > m_ncpl ) RETURN
439	ELSE
440	requested_cpl_id = m_my_cpl_id
441	ENDIF
442	!
443	!-- Return the requested information
444	IF ( PRESENT( comm_world_nesting ) ) THEN
445	comm_world_nesting = m_world_comm
446	ENDIF
447	IF ( PRESENT( cpl_id ) ) THEN
448	cpl_id = requested_cpl_id
449	ENDIF
450	IF ( PRESENT( cpl_parent_id ) ) THEN
451	cpl_parent_id = m_couplers(requested_cpl_id)%parent_id
452	ENDIF
453	IF ( PRESENT( cpl_name ) ) THEN
454	cpl_name = m_couplers(requested_cpl_id)%name
455	ENDIF
456	IF ( PRESENT( ncpl ) ) THEN
457	ncpl = m_ncpl
458	ENDIF
459	IF ( PRESENT( npe_total ) ) THEN
460	npe_total = m_couplers(requested_cpl_id)%npe_total
461	ENDIF
462	IF ( PRESENT( lower_left_x ) ) THEN
463	lower_left_x = m_couplers(requested_cpl_id)%lower_left_x
464	ENDIF
465	IF ( PRESENT( lower_left_y ) ) THEN
466	lower_left_y = m_couplers(requested_cpl_id)%lower_left_y
467	ENDIF
468
469	END SUBROUTINE pmc_get_model_info
470
471
472
473	LOGICAL function pmc_is_rootmodel( )
474
475	IMPLICIT NONE
476
477	pmc_is_rootmodel = ( m_my_cpl_id == 1 )
478
479	END FUNCTION pmc_is_rootmodel
480
481
482
483	SUBROUTINE read_coupling_layout( nesting_datatransfer_mode, nesting_mode, &
484	anterpolation_buffer_width, pmc_status )
485
486	IMPLICIT NONE
487
488	CHARACTER(LEN=8), INTENT(INOUT) :: nesting_mode
489	CHARACTER(LEN=7), INTENT(INOUT) :: nesting_datatransfer_mode
490
491	INTEGER, INTENT(INOUT) :: anterpolation_buffer_width !< Boundary buffer width for anterpolation
492	INTEGER(iwp), INTENT(INOUT) :: pmc_status
493	INTEGER(iwp) :: bad_llcorner
494	INTEGER(iwp) :: i
495	INTEGER(iwp) :: istat
496
497	TYPE(pmc_layout), DIMENSION(pmc_max_models) :: domain_layouts
498
499	NAMELIST /nesting_parameters/ domain_layouts, nesting_datatransfer_mode, &
500	nesting_mode, anterpolation_buffer_width
501
502	!
503	!-- Initialize some coupling variables
504	domain_layouts(1:pmc_max_models)%id = -1
505	m_ncpl = 0
506
507	pmc_status = pmc_status_ok
508	!
509	!-- Open the NAMELIST-file and read the nesting layout
510	CALL check_open( 11 )
511	READ ( 11, nesting_parameters, IOSTAT=istat )
512	!
513	!-- Set filepointer to the beginning of the file. Otherwise process 0 will later
514	!-- be unable to read the inipar-NAMELIST
515	REWIND ( 11 )
516
517	IF ( istat < 0 ) THEN
518	!
519	!-- No nesting_parameters-NAMELIST found
520	pmc_status = pmc_no_namelist_found
521	RETURN
522	ELSEIF ( istat > 0 ) THEN
523	!
524	!-- Errors in reading nesting_parameters-NAMELIST
525	pmc_status = pmc_namelist_error
526	RETURN
527	ENDIF
528	!
529	!-- Output location message
530	CALL location_message( 'initialize communicators for nesting', 'start' )
531	!
532	!-- Assign the layout to the corresponding internally used variable m_couplers
533	m_couplers = domain_layouts
534	!
535	!-- Get the number of nested models given in the nesting_parameters-NAMELIST
536	DO i = 1, pmc_max_models
537	!
538	!-- When id=-1 is found for the first time, the list of domains is finished
539	IF ( m_couplers(i)%id == -1 .OR. i == pmc_max_models ) THEN
540	IF ( m_couplers(i)%id == -1 ) THEN
541	m_ncpl = i - 1
542	EXIT
543	ELSE
544	m_ncpl = pmc_max_models
545	ENDIF
546	ENDIF
547	ENDDO
548	!
549	!-- Make sure that all domains have equal lower left corner in case of vertical
550	!-- nesting
551	IF ( nesting_mode == 'vertical' ) THEN
552	bad_llcorner = 0
553	DO i = 1, m_ncpl
554	IF ( domain_layouts(i)%lower_left_x /= 0.0_wp .OR. &
555	domain_layouts(i)%lower_left_y /= 0.0_wp ) THEN
556	bad_llcorner = bad_llcorner + 1
557	domain_layouts(i)%lower_left_x = 0.0_wp
558	domain_layouts(i)%lower_left_y = 0.0_wp
559	ENDIF
560	ENDDO
561	IF ( bad_llcorner /= 0) THEN
562	WRITE ( message_string, *) 'at least one dimension of lower ', &
563	'left corner of one domain is not 0. ', &
564	'All lower left corners were set to (0, 0)'
565	CALL message( 'read_coupling_layout', 'PA0427', 0, 0, 0, 6, 0 )
566	ENDIF
567	ENDIF
568
569	CALL location_message( 'initialize communicators for nesting', 'finished' )
570
571	END SUBROUTINE read_coupling_layout
572
573	#endif
574	END MODULE pmc_handle_communicator

Note: See TracBrowser for help on using the repository browser.

Download in other formats:

| Impressum | ©Leibniz Universität Hannover |