source: palm/trunk/SOURCE/palm.f90 @ 3717

Last change on this file since 3717 was 3703, checked in by knoop, 5 years ago

Updated user_interface_required_revision to r3703

  • Property svn:keywords set to Id
File size: 20.8 KB
Line 
1!> @file palm.f90
2!------------------------------------------------------------------------------!
3! This file is part of the PALM model system.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2019 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: palm.f90 3703 2019-01-29 16:43:53Z suehring $
27! Some interface calls moved to module_interface + cleanup
28!
29! 3648 2019-01-02 16:35:46Z suehring
30! Rename subroutines for surface-data output
31!
32! 3524 2018-11-14 13:36:44Z raasch
33! unused variable removed
34!
35! 3494 2018-11-06 14:51:27Z suehring
36! Last actions for surface output added
37!
38! 3487 2018-11-05 07:18:02Z maronga
39! Updates version to 6.0
40!
41! 3484 2018-11-02 14:41:25Z hellstea
42! pmci_ensure_nest_mass_conservation removed permanently
43!
44! 3458 2018-10-30 14:51:23Z kanani
45! from chemistry branch r3443, forkel:
46! removed double do_emis check around CALL chem_init
47! replaced call to calc_date_and_time to init_date_and_time
48!
49! 3337 2018-10-12 15:17:09Z kanani
50! (from branch resler)
51! Fix chemistry call
52!
53! 3298 2018-10-02 12:21:11Z kanani
54! - Minor formatting (kanani)
55! - Added Call of date_and_time_init (Russo)
56! - Added Call of calc_date_and_time before call of init_3d where emissions
57!   are initialized:
58!   we have to know the time indices to initialize emission values (Russo)
59! - Added Call of netcdf_data_input_chemistry_data (Russo)
60!
61! 3274 2018-09-24 15:42:55Z knoop
62! Modularization of all bulk cloud physics code components
63!
64! 3258 2018-09-18 07:23:31Z Giersch
65! current revision for user interface has been changed to 3240
66!
67! 3241 2018-09-12 15:02:00Z raasch
68! unused variables removed
69!
70! 3235 2018-09-07 14:06:15Z sward
71! Added mas_last_actions call and multi_agent_system_mod dependency
72!
73! 3232 2018-09-07 12:21:44Z raasch
74! references to mrun replaced by palmrun, and updated
75!
76! 3182 2018-07-27 13:36:03Z suehring
77! Deduct spinup_time from RUN_CONTROL output of main 3d run
78! (use time_since_reference_point instead of simulated_time)
79!
80! 2951 2018-04-06 09:05:08Z kanani
81! Add log_point_s for pmci_init
82!
83! 2903 2018-03-16 08:17:06Z hellstea
84! Nesting-related calls to pmci_ensure_nest_mass_conservation and pres after
85! the nest initialization are removed as they may create unwanted initial
86! perturbation in some cases.
87!
88! 2894 2018-03-15 09:17:58Z Giersch
89! Modified todo list, _write_restart_data/_last_actions has been renamed to
90! _wrd_local, unit 14 will be opened now for each io_group
91! write_3d_binary is called wrd_local now, wrd_global moved from wrd_local to
92! palm.f90, unit 14 is closed directly after the wrd_local call, Module related
93! routines for writing restart data have been moved to wrd_local
94!
95! 2801 2018-02-14 16:01:55Z suehring
96! Changed lpm from subroutine to module.
97! Introduce particle transfer in nested models.
98!
99! 2766 2018-01-22 17:17:47Z kanani
100! Removed preprocessor directive __chem
101!
102! 2720 2018-01-02 16:27:15Z kanani
103! Version update to 5.0
104!
105! 2718 2018-01-02 08:49:38Z maronga
106! Corrected "Former revisions" section
107!
108! 2696 2017-12-14 17:12:51Z kanani
109! Change in file header (GPL part)
110! Implementation of chemistry module (FK)
111! Introduce input-data standard
112! Rename lsm_last_actions into lsm_write_restart_data
113! Move usm_write_restart_data into io_blocks loop (MS)
114!
115! 2512 2017-10-04 08:26:59Z raasch
116! user interface required revision updated
117!
118! 2320 2017-07-21 12:47:43Z suehring
119! Modularize large-scale forcing and nudging
120!
121! 2298 2017-06-29 09:28:18Z raasch
122! type of write_binary changed from CHARACTER to LOGICAL,
123! user interface required revision updated, MPI2 related part removed
124!
125! 2296 2017-06-28 07:53:56Z maronga
126! Added call to new spinup routine
127!
128! 2292 2017-06-20 09:51:42Z schwenkel
129! Implementation of new microphysic scheme: cloud_scheme = 'morrison'
130! includes two more prognostic equations for cloud drop concentration (nc) 
131! and cloud water content (qc).
132!
133! 2261 2017-06-08 14:25:57Z raasch
134! output of run number for mrun to create unified cycle numbers
135!
136! 2233 2017-05-30 18:08:54Z suehring
137!
138! 2232 2017-05-30 17:47:52Z suehring
139! Renamed wall_flags_0 and wall_flags_00 into advc_flags_1 and advc_flags_2,
140! respectively, within copyin statement. Moreover, introduced further flag
141! array wall_flags_0.
142! Remove unused variables from ONLY list.
143!
144! 2178 2017-03-17 11:07:39Z hellstea
145! Calls for pmci_ensure_nest_mass_conservation and pres are added after
146! the nest initialization
147!
148! 2118 2017-01-17 16:38:49Z raasch
149! OpenACC directives and related code removed
150!
151! 2011 2016-09-19 17:29:57Z kanani
152! Flag urban_surface is now defined in module control_parameters.
153!
154! 2007 2016-08-24 15:47:17Z kanani
155! Temporarily added CALL for writing of restart data for urban surface model
156!
157! 2000 2016-08-20 18:09:15Z knoop
158! Forced header and separation lines into 80 columns
159!
160! 1976 2016-07-27 13:28:04Z maronga
161! Added call to radiation_last_actions for binary output of land surface model
162! data
163!
164! 1972 2016-07-26 07:52:02Z maronga
165! Added call to lsm_last_actions for binary output of land surface model data
166!
167! 1960 2016-07-12 16:34:24Z suehring
168! Separate humidity and passive scalar
169!
170! 1834 2016-04-07 14:34:20Z raasch
171! Initial version of purely vertical nesting introduced.
172!
173! 1833 2016-04-07 14:23:03Z raasch
174! required user interface version changed
175!
176! 1808 2016-04-05 19:44:00Z raasch
177! routine local_flush replaced by FORTRAN statement
178!
179! 1783 2016-03-06 18:36:17Z raasch
180! required user interface version changed
181!
182! 1781 2016-03-03 15:12:23Z raasch
183! pmc initialization moved from time_integration to here
184!
185! 1779 2016-03-03 08:01:28Z raasch
186! setting of nest_domain and coupling_char moved to the pmci
187!
188! 1764 2016-02-28 12:45:19Z raasch
189! cpp-statements for nesting removed, communicator settings cleaned up
190!
191! 1762 2016-02-25 12:31:13Z hellstea
192! Introduction of nested domain feature
193!
194! 1747 2016-02-08 12:25:53Z raasch
195! OpenACC-adjustment for new surface layer parameterization
196!
197! 1682 2015-10-07 23:56:08Z knoop
198! Code annotations made doxygen readable
199!
200! 1668 2015-09-23 13:45:36Z raasch
201! warning replaced by abort in case of failed user interface check
202!
203! 1666 2015-09-23 07:31:10Z raasch
204! check for user's interface version added
205!
206! 1482 2014-10-18 12:34:45Z raasch
207! adjustments for using CUDA-aware OpenMPI
208!
209! 1468 2014-09-24 14:06:57Z maronga
210! Adapted for use on up to 6-digit processor cores
211!
212! 1402 2014-05-09 14:25:13Z raasch
213! location messages added
214!
215! 1374 2014-04-25 12:55:07Z raasch
216! bugfix: various modules added
217!
218! 1320 2014-03-20 08:40:49Z raasch
219! ONLY-attribute added to USE-statements,
220! kind-parameters added to all INTEGER and REAL declaration statements,
221! kinds are defined in new module kinds,
222! old module precision_kind is removed,
223! revision history before 2012 removed,
224! comment fields (!:) to be used for variable explanations added to
225! all variable declaration statements
226!
227! 1318 2014-03-17 13:35:16Z raasch
228! module interfaces removed
229!
230! 1241 2013-10-30 11:36:58Z heinze
231! initialization of nuding and large scale forcing from external file
232!
233! 1221 2013-09-10 08:59:13Z raasch
234! +wall_flags_00, rflags_invers, rflags_s_inner in copyin statement
235!
236! 1212 2013-08-15 08:46:27Z raasch
237! +tri in copyin statement
238!
239! 1179 2013-06-14 05:57:58Z raasch
240! ref_state added to copyin-list
241!
242! 1113 2013-03-10 02:48:14Z raasch
243! openACC statements modified
244!
245! 1111 2013-03-08 23:54:10Z raasch
246! openACC statements updated
247!
248! 1092 2013-02-02 11:24:22Z raasch
249! unused variables removed
250!
251! 1036 2012-10-22 13:43:42Z raasch
252! code put under GPL (PALM 3.9)
253!
254! 1015 2012-09-27 09:23:24Z raasch
255! Version number changed from 3.8 to 3.8a.
256! OpenACC statements added + code changes required for GPU optimization
257!
258! 849 2012-03-15 10:35:09Z raasch
259! write_particles renamed lpm_write_restart_file
260!
261! Revision 1.1  1997/07/24 11:23:35  raasch
262! Initial revision
263!
264!
265! Description:
266! ------------
267!> Large-Eddy Simulation (LES) model for atmospheric and oceanic boundary-layer
268!> flows
269!> see the PALM homepage https://palm-model.org for further information
270!------------------------------------------------------------------------------!
271 PROGRAM palm
272 
273
274    USE arrays_3d
275
276    USE bulk_cloud_model_mod,                                                  &
277        ONLY: bulk_cloud_model, microphysics_morrison, microphysics_seifert
278
279    USE control_parameters,                                                    &
280        ONLY:  air_chemistry, constant_diffusion, child_domain,                &
281               coupling_char, do2d_at_begin, do3d_at_begin, humidity,          &
282               initializing_actions, io_blocks, io_group, message_string,      &
283               neutral, passive_scalar, runnr, simulated_time_chr, spinup,     &
284               time_since_reference_point, user_interface_current_revision,    &
285               user_interface_required_revision, version, write_binary
286
287    USE cpulog,                                                                &
288        ONLY:  cpu_log, log_point, log_point_s, cpu_statistics
289
290    USE date_and_time_mod,                                                     &
291        ONLY:  calc_date_and_time, init_date_and_time
292
293    USE indices,                                                               &
294        ONLY:  nbgp
295
296    USE kinds
297
298    USE module_interface,                                                      &
299        ONLY:  module_interface_last_actions
300
301    USE multi_agent_system_mod,                                                &
302        ONLY:  agents_active, mas_last_actions
303
304    USE netcdf_data_input_mod,                                                 &
305        ONLY:  netcdf_data_input_inquire_file, netcdf_data_input_init,         &
306               netcdf_data_input_surface_data, netcdf_data_input_topo
307
308    USE particle_attributes,                                                   &
309        ONLY:  particle_advection
310
311    USE pegrid
312
313    USE pmc_particle_interface,                                                &
314        ONLY: pmcp_g_alloc_win
315
316    USE pmc_interface,                                                         &
317        ONLY:  nested_run, pmci_child_initialize, pmci_init,                   &
318               pmci_modelconfiguration, pmci_parent_initialize
319               
320    USE surface_data_output_mod,                                               &
321        ONLY:  surface_data_output_last_action
322
323    USE write_restart_data_mod,                                                &
324        ONLY:  wrd_global, wrd_local
325
326#if defined( __parallel) && defined( _OPENACC )
327    USE openacc
328#endif
329
330
331    IMPLICIT NONE
332
333!
334!-- Local variables
335    CHARACTER(LEN=9) ::  time_to_string  !<
336    INTEGER(iwp)     ::  i               !< loop counter for blocked I/O
337#if defined( __parallel) && defined( _OPENACC )
338    INTEGER(iwp)     :: local_comm       !< local communicator (shared memory)
339    INTEGER(iwp)     :: local_num_procs  !< local number of processes
340    INTEGER(iwp)     :: local_id         !< local id
341    INTEGER(acc_device_kind) :: device_type !< device type for OpenACC
342    INTEGER(iwp)     ::  num_devices     !< number of devices visible to OpenACC
343    INTEGER(iwp)     ::  my_device       !< device used by this process
344#endif
345
346    version = 'PALM 6.0'
347    user_interface_required_revision = 'r3703'
348
349#if defined( __parallel )
350!
351!-- MPI initialisation. comm2d is preliminary set, because
352!-- it will be defined in init_pegrid but is used before in cpu_log.
353    CALL MPI_INIT( ierr )
354
355!
356!-- Initialize the coupling for nested-domain runs
357!-- comm_palm is the communicator which includes all PEs (MPI processes)
358!-- available for this (nested) model. If it is not a nested run, comm_palm
359!-- is returned as MPI_COMM_WORLD
360    CALL cpu_log( log_point_s(70), 'pmci_init', 'start' )
361    CALL pmci_init( comm_palm )
362    CALL cpu_log( log_point_s(70), 'pmci_init', 'stop' )
363    comm2d = comm_palm
364!
365!-- Get the (preliminary) number of MPI processes and the local PE-id (in case
366!-- of a further communicator splitting in init_coupling, these numbers will
367!-- be changed in init_pegrid).
368    IF ( nested_run )  THEN
369
370       CALL MPI_COMM_SIZE( comm_palm, numprocs, ierr )
371       CALL MPI_COMM_RANK( comm_palm, myid, ierr )
372
373    ELSE
374
375       CALL MPI_COMM_SIZE( MPI_COMM_WORLD, numprocs, ierr )
376       CALL MPI_COMM_RANK( MPI_COMM_WORLD, myid, ierr )
377!
378!--    Initialize PE topology in case of coupled atmosphere-ocean runs (comm_palm
379!--    will be splitted in init_coupling)
380       CALL init_coupling
381    ENDIF
382
383#ifdef _OPENACC
384!
385!-- Select OpenACC device to use in this process. For this find out how many
386!-- neighbors there are running on the same node and which id this process is.
387    IF ( nested_run )  THEN
388       CALL MPI_COMM_SPLIT_TYPE( comm_palm, MPI_COMM_TYPE_SHARED, 0,           &
389                                 MPI_INFO_NULL, local_comm, ierr )
390    ELSE
391       CALL MPI_COMM_SPLIT_TYPE( MPI_COMM_WORLD, MPI_COMM_TYPE_SHARED, 0,      &
392                                 MPI_INFO_NULL, local_comm, ierr )
393    ENDIF
394    CALL MPI_COMM_SIZE( local_comm, local_num_procs, ierr )
395    CALL MPI_COMM_RANK( local_comm, local_id, ierr )
396
397!
398!-- This loop including the barrier is a workaround for PGI compiler versions
399!-- up to and including 18.4. Later releases are able to select their GPUs in
400!-- parallel, without running into spurious errors.
401    DO i = 0, local_num_procs-1
402       CALL MPI_BARRIER( local_comm, ierr )
403
404       IF ( i == local_id )  THEN
405          device_type = acc_get_device_type()
406          num_devices = acc_get_num_devices( device_type )
407          my_device = MOD( local_id, num_devices )
408          CALL acc_set_device_num( my_device, device_type )
409       ENDIF
410    ENDDO
411
412    CALL MPI_COMM_FREE( local_comm, ierr )
413#endif
414#endif
415
416!
417!-- Initialize measuring of the CPU-time remaining to the run
418    CALL local_tremain_ini
419
420!
421!-- Start of total CPU time measuring.
422    CALL cpu_log( log_point(1), 'total', 'start' )
423    CALL cpu_log( log_point(2), 'initialisation', 'start' )
424
425!
426!-- Open a file for debug output
427    WRITE (myid_char,'(''_'',I6.6)')  myid
428    OPEN( 9, FILE='DEBUG'//TRIM( coupling_char )//myid_char, FORM='FORMATTED' )
429
430!
431!-- Initialize dvrp logging. Also, one PE maybe split from the global
432!-- communicator for doing the dvrp output. In that case, the number of
433!-- PEs available for PALM is reduced by one and communicator comm_palm
434!-- is changed respectively.
435#if defined( __parallel )
436    CALL MPI_COMM_RANK( comm_palm, myid, ierr )
437#endif
438
439    CALL init_dvrp_logging
440
441!
442!-- Read control parameters from NAMELIST files and read environment-variables
443    CALL parin
444
445!
446!-- Check for the user's interface version
447    IF ( user_interface_current_revision /= user_interface_required_revision )  &
448    THEN
449       message_string = 'current user-interface revision "' //                  &
450                        TRIM( user_interface_current_revision ) // '" does ' // &
451                        'not match the required revision ' //                   &
452                        TRIM( user_interface_required_revision )
453        CALL message( 'palm', 'PA0169', 1, 2, 0, 6, 0 )
454    ENDIF
455
456!
457!-- Determine processor topology and local array indices
458    CALL init_pegrid
459!
460!-- Check if input file according to input-data standard exists
461    CALL netcdf_data_input_inquire_file
462!
463!-- Read topography input data if required. This is required before the
464!-- numerical grid is finally created in init_grid
465    CALL netcdf_data_input_topo 
466!
467!-- Generate grid parameters, initialize generic topography and further process
468!-- topography information if required
469    CALL init_grid
470!
471!-- Read global attributes if available. 
472    CALL netcdf_data_input_init 
473!
474!-- Read surface classification data, e.g. vegetation and soil types, water
475!-- surfaces, etc., if available. Some of these data is required before
476!-- check parameters is invoked.     
477    CALL netcdf_data_input_surface_data
478!
479!-- Check control parameters and deduce further quantities
480    CALL check_parameters
481!
482!-- Initial time for chem_emissions_mod
483    CALL init_date_and_time
484
485    CALL init_3d_model
486
487!
488!-- Coupling protocol setup for nested-domain runs
489    IF ( nested_run )  THEN
490       CALL pmci_modelconfiguration
491!
492!--    Receive and interpolate initial data on children.
493!--    Child initialization must be made first if the model is both child and
494!--    parent if necessary
495       IF ( TRIM( initializing_actions ) /= 'read_restart_data' )  THEN
496          CALL pmci_child_initialize
497!
498!--       Send initial condition data from parent to children
499          CALL pmci_parent_initialize
500!
501!--       Exchange_horiz is needed after the nest initialization
502          IF ( child_domain )  THEN
503             CALL exchange_horiz( u, nbgp )
504             CALL exchange_horiz( v, nbgp )
505             CALL exchange_horiz( w, nbgp )
506             IF ( .NOT. neutral )  THEN
507                CALL exchange_horiz( pt, nbgp )
508             ENDIF
509             IF ( .NOT. constant_diffusion )  CALL exchange_horiz( e, nbgp )
510             IF ( humidity )  THEN
511                CALL exchange_horiz( q, nbgp )
512                IF ( bulk_cloud_model  .AND.  microphysics_morrison )  THEN
513                  CALL exchange_horiz( qc, nbgp )
514                  CALL exchange_horiz( nc, nbgp )
515                ENDIF
516                IF ( bulk_cloud_model  .AND.  microphysics_seifert )  THEN
517                   CALL exchange_horiz( qr, nbgp ) 
518                   CALL exchange_horiz( nr, nbgp )
519                ENDIF
520             ENDIF
521             IF ( passive_scalar )  CALL exchange_horiz( s, nbgp )
522          ENDIF
523       ENDIF
524
525       CALL pmcp_g_alloc_win                    ! Must be called after pmci_child_initialize and pmci_parent_initialize
526    ENDIF
527
528!
529!-- Output of program header
530    IF ( myid == 0 )  CALL header
531
532    CALL cpu_log( log_point(2), 'initialisation', 'stop' )
533
534!
535!-- Integration of the non-atmospheric equations (land surface model, urban
536!-- surface model)
537    IF ( spinup )  THEN
538       CALL time_integration_spinup
539    ENDIF
540
541!
542!-- Set start time in format hh:mm:ss
543    simulated_time_chr = time_to_string( time_since_reference_point )
544
545!
546!-- If required, output of initial arrays
547    IF ( do2d_at_begin )  THEN
548       CALL data_output_2d( 'xy', 0 )
549       CALL data_output_2d( 'xz', 0 )
550       CALL data_output_2d( 'yz', 0 )
551    ENDIF
552
553    IF ( do3d_at_begin )  THEN
554       CALL data_output_3d( 0 )
555    ENDIF
556
557!
558!-- Integration of the model equations using timestep-scheme
559    CALL time_integration
560
561!
562!-- If required, write binary data for restart runs
563    IF ( write_binary )  THEN
564
565       CALL cpu_log( log_point(22), 'wrd_local', 'start' )
566
567       CALL location_message( 'writing restart data', .FALSE. )
568
569       DO  i = 0, io_blocks-1
570          IF ( i == io_group )  THEN
571
572!
573!--          Open binary file
574             CALL check_open( 14 )
575!
576!--          Write control parameters and other global variables for restart.
577             IF ( myid == 0 )  CALL wrd_global
578!
579!--          Write processor specific flow field data for restart runs
580             CALL wrd_local
581!
582!--          Close binary file
583             CALL close_file( 14 )
584
585          ENDIF
586#if defined( __parallel )
587          CALL MPI_BARRIER( comm2d, ierr )
588#endif
589       ENDDO
590
591       CALL location_message( 'finished', .TRUE. )
592
593       CALL cpu_log( log_point(22), 'wrd_local', 'stop' )
594
595!
596!--    If required, write particle data in own restart files
597       IF ( particle_advection )  CALL lpm_write_restart_file
598       
599    ENDIF
600!
601!-- Last actions for surface output, for instantaneous and time-averaged data
602    CALL surface_data_output_last_action( 0 )
603    CALL surface_data_output_last_action( 1 )
604
605!
606!-- If required, repeat output of header including the required CPU-time
607    IF ( myid == 0 )  CALL header
608!
609!-- Perform module specific last actions
610    CALL cpu_log( log_point(4), 'last actions', 'start' )
611
612    IF ( myid == 0 .AND. agents_active ) CALL mas_last_actions ! ToDo: move to module_interface
613
614    CALL module_interface_last_actions
615
616    CALL cpu_log( log_point(4), 'last actions', 'stop' )
617
618!
619!-- Close files
620    CALL close_file( 0 )
621    CALL close_dvrp
622
623!
624!-- Write run number to file (used by palmrun to create unified cycle numbers
625!-- for output files
626    IF ( myid == 0  .AND.  runnr > 0 )  THEN
627       OPEN( 90, FILE='RUN_NUMBER', FORM='FORMATTED' )
628       WRITE( 90, '(I4)' )  runnr
629       CLOSE( 90 )
630    ENDIF
631
632!
633!-- Take final CPU-time for CPU-time analysis
634    CALL cpu_log( log_point(1), 'total', 'stop' )
635    CALL cpu_statistics
636
637#if defined( __parallel )
638    CALL MPI_FINALIZE( ierr )
639#endif
640
641 END PROGRAM palm
Note: See TracBrowser for help on using the repository browser.