source: palm/trunk/SOURCE/palm.f90 @ 2001

Last change on this file since 2001 was 2001, checked in by knoop, 5 years ago

last commit documented

  • Property svn:keywords set to Id
File size: 17.2 KB
Line 
1!> @file palm.f90
2!------------------------------------------------------------------------------!
3! This file is part of PALM.
4!
5! PALM is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 1997-2016 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! -----------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: palm.f90 2001 2016-08-20 18:41:22Z knoop $
27!
28! 2000 2016-08-20 18:09:15Z knoop
29! Forced header and separation lines into 80 columns
30!
31! 1976 2016-07-27 13:28:04Z maronga
32! Added call to radiation_last_actions for binary output of land surface model
33! data
34!
35! 1972 2016-07-26 07:52:02Z maronga
36! Added call to lsm_last_actions for binary output of land surface model data
37!
38! 1960 2016-07-12 16:34:24Z suehring
39! Separate humidity and passive scalar
40!
41! 1834 2016-04-07 14:34:20Z raasch
42! Initial version of purely vertical nesting introduced.
43!
44! 1833 2016-04-07 14:23:03Z raasch
45! required user interface version changed
46!
47! 1808 2016-04-05 19:44:00Z raasch
48! routine local_flush replaced by FORTRAN statement
49!
50! 1783 2016-03-06 18:36:17Z raasch
51! required user interface version changed
52!
53! 1781 2016-03-03 15:12:23Z raasch
54! pmc initialization moved from time_integration to here
55!
56! 1779 2016-03-03 08:01:28Z raasch
57! setting of nest_domain and coupling_char moved to the pmci
58!
59! 1764 2016-02-28 12:45:19Z raasch
60! cpp-statements for nesting removed, communicator settings cleaned up
61!
62! 1762 2016-02-25 12:31:13Z hellstea
63! Introduction of nested domain feature
64!
65! 1747 2016-02-08 12:25:53Z raasch
66! OpenACC-adjustment for new surface layer parameterization
67!
68! 1682 2015-10-07 23:56:08Z knoop
69! Code annotations made doxygen readable
70!
71! 1668 2015-09-23 13:45:36Z raasch
72! warning replaced by abort in case of failed user interface check
73!
74! 1666 2015-09-23 07:31:10Z raasch
75! check for user's interface version added
76!
77! 1482 2014-10-18 12:34:45Z raasch
78! adjustments for using CUDA-aware OpenMPI
79!
80! 1468 2014-09-24 14:06:57Z maronga
81! Adapted for use on up to 6-digit processor cores
82!
83! 1402 2014-05-09 14:25:13Z raasch
84! location messages added
85!
86! 1374 2014-04-25 12:55:07Z raasch
87! bugfix: various modules added
88!
89! 1320 2014-03-20 08:40:49Z raasch
90! ONLY-attribute added to USE-statements,
91! kind-parameters added to all INTEGER and REAL declaration statements,
92! kinds are defined in new module kinds,
93! old module precision_kind is removed,
94! revision history before 2012 removed,
95! comment fields (!:) to be used for variable explanations added to
96! all variable declaration statements
97!
98! 1318 2014-03-17 13:35:16Z raasch
99! module interfaces removed
100!
101! 1241 2013-10-30 11:36:58Z heinze
102! initialization of nuding and large scale forcing from external file
103!
104! 1221 2013-09-10 08:59:13Z raasch
105! +wall_flags_00, rflags_invers, rflags_s_inner in copyin statement
106!
107! 1212 2013-08-15 08:46:27Z raasch
108! +tri in copyin statement
109!
110! 1179 2013-06-14 05:57:58Z raasch
111! ref_state added to copyin-list
112!
113! 1113 2013-03-10 02:48:14Z raasch
114! openACC statements modified
115!
116! 1111 2013-03-08 23:54:10Z raasch
117! openACC statements updated
118!
119! 1092 2013-02-02 11:24:22Z raasch
120! unused variables removed
121!
122! 1036 2012-10-22 13:43:42Z raasch
123! code put under GPL (PALM 3.9)
124!
125! 1015 2012-09-27 09:23:24Z raasch
126! Version number changed from 3.8 to 3.8a.
127! OpenACC statements added + code changes required for GPU optimization
128!
129! 849 2012-03-15 10:35:09Z raasch
130! write_particles renamed lpm_write_restart_file
131!
132! Revision 1.1  1997/07/24 11:23:35  raasch
133! Initial revision
134!
135!
136! Description:
137! ------------
138!> Large-Eddy Simulation (LES) model for the convective boundary layer,
139!> optimized for use on parallel machines (implementation realized using the
140!> Message Passing Interface (MPI)). The model can also be run on vector machines
141!> (less well optimized) and workstations. Versions for the different types of
142!> machines are controlled via cpp-directives.
143!> Model runs are only feasible using the ksh-script mrun.
144!>
145!> @todo create routine last_actions instead of calling lsm_last_actions etc.
146!------------------------------------------------------------------------------!
147 PROGRAM palm
148 
149
150    USE arrays_3d
151
152    USE control_parameters,                                                    &
153        ONLY:  constant_diffusion, coupling_char, coupling_mode,               &
154               do2d_at_begin, do3d_at_begin, humidity, io_blocks, io_group,    &
155               large_scale_forcing, message_string, nest_domain, neutral,      &
156               nudging, passive_scalar, simulated_time, simulated_time_chr,    &
157               user_interface_current_revision,                                &
158               user_interface_required_revision, version, wall_heatflux,       &
159               write_binary
160
161    USE cpulog,                                                                &
162        ONLY:  cpu_log, log_point, cpu_statistics
163
164    USE grid_variables,                                                        &
165        ONLY:  fxm, fxp, fym, fyp, fwxm, fwxp, fwym, fwyp, wall_e_x, wall_e_y, &
166               wall_u, wall_v, wall_w_x, wall_w_y
167
168    USE indices,                                                               &
169        ONLY:  nbgp, ngp_2dh, ngp_2dh_s_inner, nzb_diff_s_inner, nzb_diff_s_outer,   &
170               nzb_diff_u, nzb_diff_v, nzb_s_inner, nzb_s_outer, nzb_u_inner,  &
171               nzb_u_outer, nzb_v_inner, nzb_v_outer, nzb_w_inner,             &
172               nzb_w_outer, rflags_invers, rflags_s_inner, wall_flags_0,       &
173               wall_flags_00
174
175    USE kinds
176
177    USE land_surface_model_mod,                                                &
178        ONLY:  land_surface, lsm_last_actions
179
180    USE ls_forcing_mod,                                                        &
181        ONLY:  init_ls_forcing
182
183    USE nudge_mod,                                                             &
184        ONLY:  init_nudge
185
186    USE particle_attributes,                                                   &
187        ONLY:  particle_advection
188
189    USE pegrid
190
191    USE pmc_interface,                                                         &
192        ONLY:  cpl_id, nested_run, pmci_child_initialize, pmci_init,           &
193               pmci_modelconfiguration, pmci_parent_initialize
194
195    USE radiation_model_mod,                                                   &
196        ONLY:  radiation, radiation_last_actions
197
198    USE statistics,                                                            &
199        ONLY:  hom, rmask, weight_pres, weight_substep
200
201    USE surface_layer_fluxes_mod,                                              &
202        ONLY:  pt1, qv1, uv_total
203
204#if defined( __openacc )
205    USE OPENACC
206#endif
207
208    IMPLICIT NONE
209
210!
211!-- Local variables
212    CHARACTER(LEN=9)  ::  time_to_string  !<
213    CHARACTER(LEN=10) ::  env_string      !< to store string of environment var
214    INTEGER(iwp)      ::  env_stat        !< to hold status of GET_ENV
215    INTEGER(iwp)      ::  i               !<
216    INTEGER(iwp)      ::  myid_openmpi    !< OpenMPI local rank for CUDA aware MPI
217#if defined( __openacc )
218    REAL(wp), DIMENSION(100) ::  acc_dum     !<
219#endif
220
221    version = 'PALM 4.0'
222    user_interface_required_revision = 'r1819'
223
224#if defined( __parallel )
225!
226!-- MPI initialisation. comm2d is preliminary set, because
227!-- it will be defined in init_pegrid but is used before in cpu_log.
228    CALL MPI_INIT( ierr )
229
230!
231!-- Initialize the coupling for nested-domain runs
232!-- comm_palm is the communicator which includes all PEs (MPI processes)
233!-- available for this (nested) model. If it is not a nested run, comm_palm
234!-- is returned as MPI_COMM_WORLD
235    CALL pmci_init( comm_palm )
236    comm2d = comm_palm
237!
238!-- Get the (preliminary) number of MPI processes and the local PE-id (in case
239!-- of a further communicator splitting in init_coupling, these numbers will
240!-- be changed in init_pegrid).
241    IF ( nested_run )  THEN
242
243       CALL MPI_COMM_SIZE( comm_palm, numprocs, ierr )
244       CALL MPI_COMM_RANK( comm_palm, myid, ierr )
245
246    ELSE
247
248       CALL MPI_COMM_SIZE( MPI_COMM_WORLD, numprocs, ierr )
249       CALL MPI_COMM_RANK( MPI_COMM_WORLD, myid, ierr )
250!
251!--    Initialize PE topology in case of coupled atmosphere-ocean runs (comm_palm
252!--    will be splitted in init_coupling)
253       CALL init_coupling
254    ENDIF
255#endif
256
257#if defined( __openacc )
258!
259!-- Get the local MPI rank in case of CUDA aware OpenMPI. Important, if there
260!-- is more than one accelerator board on the node
261    CALL GET_ENVIRONMENT_VARIABLE('OMPI_COMM_WORLD_LOCAL_RANK',                &
262         VALUE=env_string, STATUS=env_stat )
263    READ( env_string, '(I1)' )  myid_openmpi
264    PRINT*, '### local_rank = ', myid_openmpi, '  status=',env_stat
265!
266!-- Get the number of accelerator boards per node and assign the MPI processes
267!-- to these boards
268    PRINT*, '*** ACC_DEVICE_NVIDIA = ', ACC_DEVICE_NVIDIA
269    num_acc_per_node  = ACC_GET_NUM_DEVICES( ACC_DEVICE_NVIDIA )
270    IF ( numprocs == 1  .AND.  num_acc_per_node > 0 )  num_acc_per_node = 1
271    PRINT*, '*** myid = ', myid_openmpi, ' num_acc_per_node = ', num_acc_per_node
272    acc_rank = MOD( myid_openmpi, num_acc_per_node )
273    CALL ACC_SET_DEVICE_NUM ( acc_rank, ACC_DEVICE_NVIDIA )
274!
275!-- Test output (to be removed later)
276    WRITE (*,'(A,I6,A,I3,A,I3,A,I3)') '*** Connect MPI-Task ', myid_openmpi,   &
277                                      ' to CPU ', acc_rank, ' Devices: ',      &
278                                      num_acc_per_node, ' connected to:',      &
279                                      ACC_GET_DEVICE_NUM( ACC_DEVICE_NVIDIA )
280#endif
281
282!
283!-- Ensure that OpenACC first attaches the GPU devices by copying a dummy data
284!-- region
285    !$acc data copyin( acc_dum )
286
287!
288!-- Initialize measuring of the CPU-time remaining to the run
289    CALL local_tremain_ini
290
291!
292!-- Start of total CPU time measuring.
293    CALL cpu_log( log_point(1), 'total', 'start' )
294    CALL cpu_log( log_point(2), 'initialisation', 'start' )
295
296!
297!-- Open a file for debug output
298    WRITE (myid_char,'(''_'',I6.6)')  myid
299    OPEN( 9, FILE='DEBUG'//TRIM( coupling_char )//myid_char, FORM='FORMATTED' )
300
301!
302!-- Initialize dvrp logging. Also, one PE maybe split from the global
303!-- communicator for doing the dvrp output. In that case, the number of
304!-- PEs available for PALM is reduced by one and communicator comm_palm
305!-- is changed respectively.
306#if defined( __parallel )
307    CALL MPI_COMM_RANK( comm_palm, myid, ierr )
308!
309!-- TEST OUTPUT (TO BE REMOVED)
310    WRITE(9,*) '*** coupling_mode = "', TRIM( coupling_mode ), '"'
311    FLUSH( 9 )
312    IF ( TRIM( coupling_mode ) /= 'uncoupled' )  THEN
313       PRINT*, '*** PE', myid, ' Global target PE:', target_id, &
314               TRIM( coupling_mode )
315    ENDIF
316#endif
317
318    CALL init_dvrp_logging
319
320!
321!-- Read control parameters from NAMELIST files and read environment-variables
322    CALL parin
323
324!
325!-- Check for the user's interface version
326    IF ( user_interface_current_revision /= user_interface_required_revision )  &
327    THEN
328       message_string = 'current user-interface revision "' //                  &
329                        TRIM( user_interface_current_revision ) // '" does ' // &
330                        'not match the required revision ' //                   &
331                        TRIM( user_interface_required_revision )
332        CALL message( 'palm', 'PA0169', 1, 2, 0, 6, 0 )
333    ENDIF
334
335!
336!-- Determine processor topology and local array indices
337    CALL init_pegrid
338
339!
340!-- Generate grid parameters
341    CALL init_grid
342
343!
344!-- Initialize nudging if required
345    IF ( nudging )  THEN
346       CALL init_nudge
347    ENDIF
348
349!
350!-- Initialize reading of large scale forcing from external file - if required
351    IF ( large_scale_forcing )  THEN
352       CALL init_ls_forcing
353    ENDIF
354
355!
356!-- Check control parameters and deduce further quantities
357    CALL check_parameters
358
359!
360!-- Initialize all necessary variables
361    CALL init_3d_model
362
363!
364!-- Coupling protocol setup for nested-domain runs
365    IF ( nested_run )  THEN
366       CALL pmci_modelconfiguration
367!
368!--    Receive and interpolate initial data on children.
369!--    Child initialization must be made first if the model is both child and
370!--    parent
371       CALL pmci_child_initialize
372!
373!--    Send initial condition data from parent to children
374       CALL pmci_parent_initialize
375!
376!--    Exchange_horiz is needed after the nest initialization
377       IF ( nest_domain )  THEN
378          CALL exchange_horiz( u, nbgp )
379          CALL exchange_horiz( v, nbgp )
380          CALL exchange_horiz( w, nbgp )
381          IF ( .NOT. neutral )  THEN
382             CALL exchange_horiz( pt, nbgp )
383          ENDIF
384          IF ( .NOT. constant_diffusion )  CALL exchange_horiz( e, nbgp )
385          IF ( humidity       )  CALL exchange_horiz( q, nbgp )
386          IF ( passive_scalar )  CALL exchange_horiz( s, nbgp )
387       ENDIF
388
389    ENDIF
390
391!
392!-- Output of program header
393    IF ( myid == 0 )  CALL header
394
395    CALL cpu_log( log_point(2), 'initialisation', 'stop' )
396
397!
398!-- Set start time in format hh:mm:ss
399    simulated_time_chr = time_to_string( simulated_time )
400
401!
402!-- If required, output of initial arrays
403    IF ( do2d_at_begin )  THEN
404       CALL data_output_2d( 'xy', 0 )
405       CALL data_output_2d( 'xz', 0 )
406       CALL data_output_2d( 'yz', 0 )
407    ENDIF
408
409    IF ( do3d_at_begin )  THEN
410       CALL data_output_3d( 0 )
411    ENDIF
412
413!
414!-- Declare and initialize variables in the accelerator memory with their
415!-- host values
416    !$acc  data copyin( d, diss, e, e_p, kh, km, p, pt, pt_p, q, ql, tend, te_m, tpt_m, tu_m, tv_m, tw_m, u, u_p, v, vpt, v_p, w, w_p )          &
417    !$acc       copyin( tri, tric, dzu, ddzu, ddzw, dd2zu, l_grid, l_wall, ptdf_x, ptdf_y, pt_init, rdf, rdf_sc, ref_state, ug, u_init, vg, v_init, zu, zw )   &
418    !$acc       copyin( hom, ol, pt1, qs, qsws, qswst, qv1, rif_wall, shf, ts, tswst, us, usws, uswst, uv_total, vsws, vswst, z0, z0h )      &
419    !$acc       copyin( fxm, fxp, fym, fyp, fwxm, fwxp, fwym, fwyp, nzb_diff_s_inner, nzb_diff_s_outer, nzb_diff_u )       &
420    !$acc       copyin( nzb_diff_v, nzb_s_inner, nzb_s_outer, nzb_u_inner )    &
421    !$acc       copyin( nzb_u_outer, nzb_v_inner, nzb_v_outer, nzb_w_inner )   &
422    !$acc       copyin( nzb_w_outer, rflags_invers, rflags_s_inner, rmask, wall_heatflux, wall_e_x, wall_e_y, wall_u, wall_v, wall_w_x, wall_w_y, wall_flags_0, wall_flags_00 )  &
423    !$acc       copyin( ngp_2dh, ngp_2dh_s_inner )  &
424    !$acc       copyin( weight_pres, weight_substep )
425!
426!-- Integration of the model equations using timestep-scheme
427    CALL time_integration
428
429!
430!-- If required, write binary data for restart runs
431    IF ( write_binary(1:4) == 'true' )  THEN
432
433       CALL cpu_log( log_point(22), 'write_3d_binary', 'start' )
434
435       CALL location_message( 'writing restart data', .FALSE. )
436
437       CALL check_open( 14 )
438
439       DO  i = 0, io_blocks-1
440          IF ( i == io_group )  THEN
441!
442!--          Write flow field data
443             CALL write_3d_binary
444          ENDIF
445#if defined( __parallel )
446          CALL MPI_BARRIER( comm2d, ierr )
447#endif
448       ENDDO
449
450       CALL location_message( 'finished', .TRUE. )
451
452       CALL cpu_log( log_point(22), 'write_3d_binary', 'stop' )
453
454!
455!--    If required, write particle data
456       IF ( particle_advection )  CALL lpm_write_restart_file
457    ENDIF
458
459!
460!-- If required, repeat output of header including the required CPU-time
461    IF ( myid == 0 )  CALL header
462!
463!-- If required, final land surface and user-defined actions, and
464!-- last actions on the open files and close files. Unit 14 was opened
465!-- in write_3d_binary but it is closed here, to allow writing on this
466!-- unit in routine user_last_actions.
467    CALL cpu_log( log_point(4), 'last actions', 'start' )
468    DO  i = 0, io_blocks-1
469       IF ( i == io_group )  THEN
470          IF ( land_surface )  THEN
471             CALL lsm_last_actions
472          ENDIF
473          IF ( radiation )  THEN
474             CALL radiation_last_actions
475          ENDIF
476          CALL user_last_actions
477          IF ( write_binary(1:4) == 'true' )  CALL close_file( 14 )
478       ENDIF
479#if defined( __parallel )
480       CALL MPI_BARRIER( comm2d, ierr )
481#endif
482    ENDDO
483    CALL close_file( 0 )
484    CALL close_dvrp
485    CALL cpu_log( log_point(4), 'last actions', 'stop' )
486
487#if defined( __mpi2 )
488!
489!-- Test exchange via intercommunicator in case of a MPI-2 coupling
490    IF ( coupling_mode == 'atmosphere_to_ocean' )  THEN
491       i = 12345 + myid
492       CALL MPI_SEND( i, 1, MPI_INTEGER, myid, 11, comm_inter, ierr )
493    ELSEIF ( coupling_mode == 'ocean_to_atmosphere' )  THEN
494       CALL MPI_RECV( i, 1, MPI_INTEGER, myid, 11, comm_inter, status, ierr )
495       PRINT*, '### myid: ', myid, '   received from atmosphere:  i = ', i
496    ENDIF
497#endif
498
499!
500!-- Close the OpenACC dummy data region
501    !$acc end data
502    !$acc end data
503
504!
505!-- Take final CPU-time for CPU-time analysis
506    CALL cpu_log( log_point(1), 'total', 'stop' )
507    CALL cpu_statistics
508
509#if defined( __parallel )
510    CALL MPI_FINALIZE( ierr )
511#endif
512
513 END PROGRAM palm
Note: See TracBrowser for help on using the repository browser.