source: palm/trunk/SOURCE/package_parin.f90 @ 280

 SUBROUTINE package_parin

!------------------------------------------------------------------------------!
! Actual revisions:
! -----------------
! +clip_dvrp_*, cluster_size, color_interval, dvrpsize_interval, particle_color,
! particle_dvrpsize in dvrp_graphics_par,
! parameter dvrp_psize moved from particles_par to dvrp_graphics_par
! Variables for dvrp-mode pathlines added
!
! Former revisions:
! -----------------
! $Id: package_parin.f90 266 2009-03-25 07:43:59Z letzel $
!
! 210 2008-11-06 08:54:02Z raasch
! Variables for dvrp-mode pathlines added
!
! 116 2007-10-11 02:30:27Z raasch
! +dt_sort_particles in package_parin
!
! 60 2007-03-11 11:50:04Z raasch
! Particles-package is now part of the default code
!
! RCS Log replace by Id keyword, revision history cleaned up
!
! Revision 1.18  2006/08/04 14:52:23  raasch
! +dt_dopts, dt_min_part, end_time_prel, particles_per_point,
! use_sgs_for_particles in particles_par
!
! Revision 1.1  2000/12/28 13:21:57  raasch
! Initial revision
!
!
! Description:
! ------------
! This subroutine reads from the NAMELIST file variables controling model
! software packages which are used optionally in the run.
!------------------------------------------------------------------------------!

    USE control_parameters
    USE dvrp_variables
    USE particle_attributes
    USE spectrum

    IMPLICIT NONE

    CHARACTER (LEN=80) ::  zeile

    NAMELIST /dvrp_graphics_par/  clip_dvrp_l, clip_dvrp_n, clip_dvrp_r,       &
                                  clip_dvrp_s, cluster_size, color_interval,   &
                                  dt_dvrp, dvrpsize_interval, dvrp_directory,  &
                                  dvrp_file, dvrp_host, dvrp_output,           &
                                  dvrp_password, dvrp_username, mode_dvrp,     &
                                  particle_color, particle_dvrpsize,           &
                                  pathlines_fadeintime, pathlines_fadeouttime, &
                                  pathlines_linecount, pathlines_maxhistory,   &
                                  pathlines_wavecount, pathlines_wavetime,     &
                                  slicer_range_limits_dvrp, superelevation,    &
                                  superelevation_x, superelevation_y,          &
                                  threshold, vc_alpha, vc_gradient_normals,    &
                                  vc_mode, vc_size_x, vc_size_y, vc_size_z

    NAMELIST /particles_par/      bc_par_b, bc_par_lr, bc_par_ns, bc_par_t,    &
                                  density_ratio, radius, dt_dopts,             &
                                  dt_min_part, dt_prel, dt_sort_particles,     &
                                  dt_write_particle_data, dvrp_psize,          &
                                  end_time_prel, initial_weighting_factor,     &
                                  maximum_number_of_particles,                 &
                                  maximum_number_of_tailpoints,                &
                                  maximum_tailpoint_age,                       &
                                  minimum_tailpoint_distance,                  &
                                  number_of_particle_groups,                   &
                                  particles_per_point,                         &
                                  particle_advection_start,                    &
                                  particle_maximum_age, pdx, pdy, pdz, psb,    &
                                  psl, psn, psr, pss, pst,                     &
                                  random_start_position,                       &
                                  read_particles_from_restartfile,             &
                                  skip_particles_for_tail, use_particle_tails, &
                                  use_sgs_for_particles,                       &
                                  vertical_particle_advection,                 &
                                  write_particle_statistics
    NAMELIST /spectra_par/        averaging_interval_sp, comp_spectra_level,   &
                                  data_output_sp, dt_dosp, plot_spectra_level, &
                                  skip_time_dosp, spectra_direction

!
!-- Position the namelist-file at the beginning (it was already opened in
!-- parin), search for the namelist-group of the package and position the
!-- file at this line. Do the same for each optionally used package.
    zeile = ' '

#if defined( __dvrp_graphics )
    REWIND ( 11 )
    zeile = ' '
    DO   WHILE ( INDEX( zeile, '&dvrp_graphics_par' ) == 0 )
       READ ( 11, '(A)', END=10 )  zeile
    ENDDO
    BACKSPACE ( 11 )

!
!-- Read user-defined namelist
    READ ( 11, dvrp_graphics_par )

 10 CONTINUE
#endif

!
!-- Try to find particles package
    REWIND ( 11 )
    zeile = ' '
    DO   WHILE ( INDEX( zeile, '&particles_par' ) == 0 )
       READ ( 11, '(A)', END=20 )  zeile
    ENDDO
    BACKSPACE ( 11 )

!
!-- Read user-defined namelist
    READ ( 11, particles_par )

!
!-- Set flag that indicates that particles are switched on
    particle_advection = .TRUE.

 20 CONTINUE


#if defined( __spectra )
    REWIND ( 11 )
    zeile = ' '
    DO   WHILE ( INDEX( zeile, '&spectra_par' ) == 0 )
       READ ( 11, '(A)', END=30 )  zeile
    ENDDO
    BACKSPACE ( 11 )

!
!-- Read user-defined namelist
    READ ( 11, spectra_par )

!
!-- Default setting of dt_dosp here (instead of check_parameters), because its
!-- current value is needed in init_pegrid
    IF ( dt_dosp == 9999999.9 )  dt_dosp = dt_data_output

 30 CONTINUE
#endif

 END SUBROUTINE package_parin