source: palm/trunk/SOURCE/multi_agent_system_mod.f90 @ 3587

Last change on this file since 3587 was 3587, checked in by sward, 4 years ago

Added MAS substep time to agent output

  • Property svn:keywords set to Id
File size: 197.1 KB
Line 
1!> @file multi_agent_system_mod.f90
2!--------------------------------------------------------------------------------!
3! This file is part of PALM-4U.
4!
5! PALM-4U is free software: you can redistribute it and/or modify it under the
6! terms of the GNU General Public License as published by the Free Software
7! Foundation, either version 3 of the License, or (at your option) any later
8! version.
9!
10! PALM-4U is distributed in the hope that it will be useful, but WITHOUT ANY
11! WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
12! A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
13!
14! You should have received a copy of the GNU General Public License along with
15! PALM. If not, see <http://www.gnu.org/licenses/>.
16!
17! Copyright 2016 Leibniz Universitaet Hannover
18!------------------------------------------------------------------------------!
19!
20! Current revisions:
21! ------------------
22!
23!
24! Former revisions:
25! -----------------
26! $Id: multi_agent_system_mod.f90 3587 2018-11-30 13:52:19Z sward $
27! Added output of agent substep time
28!
29! 3525 2018-11-14 16:06:14Z kanani
30! Changes related to clean-up of biometeorology (dom_dwd_user)
31!
32! 3448 2018-10-29 18:14:31Z kanani
33! Adjustment of biometeorology calls,
34! implement some agent biometeorology
35!
36! 3274 2018-09-24 15:42:55Z knoop
37! Modularization of all bulk cloud physics code components
38!
39! 3268 2018-09-21 13:45:37Z sward
40! Cleaned up agent pointer assignment in output routine
41!
42! 3248 2018-09-14 09:42:06Z sward
43! Minor formating changes
44!
45! 3246 2018-09-13 15:14:50Z sward
46! Added error handling for input namelist via parin_fail_message
47!
48! 3241 2018-09-12 15:02:00Z raasch
49! unused variables removed
50!
51! 3235 2018-09-07 14:06:15Z sward
52! Bugfix in output, added agent-number dimension and related messages and
53! input parameters, updated cpu logging, added mas_last_actions
54!
55! 3201 2018-08-20 11:45:01Z sward
56! Bugfix, missing pre-processor directive. Set default
57! read_agents_from_restartfile = .FALSE. restarts not yet implemented.
58!
59! 3198 2018-08-15 09:23:10Z sward
60! Now using time_since_reference_point; moved multi_agent_system_start and
61! multi_agent_system_end to control_parameters; renamed NAMELIST agents_par to
62! agent_parameters
63!
64! 3187 2018-07-31 10:32:34Z sward
65! Reworked agent pathfinding to avoid collisions with walls
66!
67! 3165 2018-07-24 13:12:42Z sward
68! Added agent ID output
69!
70! 3160 2018-07-20 11:52:56Z sward
71! Changed C_SIZEOF to STORAGE_SIZE
72!
73! 3159 2018-07-20 11:20:01Z sward
74! Initial revision
75!
76!
77!
78! Authors:
79! --------
80! @author sward
81!
82!
83! Description:
84! ------------
85!> Multi Agent System for the simulation of pedestrian movement in urban
86!> environments
87!------------------------------------------------------------------------------!
88 MODULE multi_agent_system_mod
89
90    USE, INTRINSIC ::  ISO_C_BINDING
91
92    USE basic_constants_and_equations_mod,                                     &
93        ONLY:  pi
94
95    USE control_parameters,                                                    &
96        ONLY:  biometeorology, dt_3d, dt_write_agent_data, message_string,     &
97               time_since_reference_point
98
99    USE cpulog,                                                                &
100        ONLY:  cpu_log, log_point, log_point_s
101
102    USE grid_variables,                                                        &
103        ONLY:  ddx, ddy, dx, dy
104
105    USE indices,                                                               &
106        ONLY:  nx, nxl, nxlg, nxr, nxrg, ny, nyn, nyng, nys, nysg, nzb,        &
107               wall_flags_0
108
109    USE random_function_mod,                                                   &
110        ONLY:  random_function
111
112    USE kinds
113
114    USE pegrid
115
116    CHARACTER(LEN=15) ::  bc_mas_lr = 'absorb'  !< left/right boundary condition
117    CHARACTER(LEN=15) ::  bc_mas_ns = 'absorb'  !< north/south boundary condition
118
119    INTEGER(iwp) ::  deleted_agents = 0                !< number of deleted agents per time step
120    INTEGER(iwp) ::  dim_size_agtnum_manual = 9999999  !< namelist parameter (see documentation)
121    INTEGER(iwp) ::  heap_count                        !< number of items in binary heap (for pathfinding)
122    INTEGER(iwp) ::  ibc_mas_lr                        !< agent left/right boundary condition dummy
123    INTEGER(iwp) ::  ibc_mas_ns                        !< agent north/south boundary condition dummy
124!    INTEGER(iwp) ::  ind_pm10 = -9                     !< chemical species index of PM10
125!    INTEGER(iwp) ::  ind_pm25 = -9                     !< chemical species index of PM2.5
126    INTEGER(iwp) ::  iran_agent = -1234567             !< number for random generator
127    INTEGER(iwp) ::  min_nr_agent = 2                  !< namelist parameter (see documentation)
128    INTEGER(iwp) ::  ghla_count_recv                   !< number of agents in left ghost layer
129    INTEGER(iwp) ::  ghna_count_recv                   !< number of agents in north ghost layer
130    INTEGER(iwp) ::  ghra_count_recv                   !< number of agents in right ghost layer
131    INTEGER(iwp) ::  ghsa_count_recv                   !< number of agents in south ghost layer
132    INTEGER(iwp) ::  maximum_number_of_agents = 0      !< maximum number of agents during run
133    INTEGER(iwp) ::  nr_move_north                     !< number of agts to move north during exchange_horiz
134    INTEGER(iwp) ::  nr_move_south                     !< number of agts to move south during exchange_horiz
135    INTEGER(iwp) ::  number_of_agents = 0              !< number of agents for each grid box (3d array is saved on agt_count)
136    INTEGER(iwp) ::  number_of_agent_groups = 1        !< namelist parameter (see documentation)
137    INTEGER(iwp) ::  sort_count_mas = 0                !< counter for sorting agents
138    INTEGER(iwp) ::  agt_path_size = 15                !< size of agent path array
139    INTEGER(iwp) ::  step_dealloc_mas = 100            !< namelist parameter (see documentation)
140    INTEGER(iwp) ::  total_number_of_agents            !< total number of agents in the whole model domain
141
142    INTEGER(iwp), PARAMETER ::  NR_2_direction_move = 10000 !< parameter for agent exchange
143    INTEGER(iwp), PARAMETER ::  PHASE_INIT    = 1           !< phase parameter
144    INTEGER(iwp), PARAMETER ::  PHASE_RELEASE = 2           !< phase parameter
145
146    INTEGER(iwp), PARAMETER ::  max_number_of_agent_groups = 100 !< maximum allowed number of agent groups
147
148    INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE ::  agt_count         !< 3d array of number of agents of every grid box
149    INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE ::  s_measure_height  !< k-index(s-grid) for measurement
150    INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE ::  top_top_s         !< k-index of first s-gridpoint above topography
151    INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE ::  top_top_w         !< k-index of first v-gridpoint above topography
152    INTEGER(iwp), DIMENSION(:,:), ALLOCATABLE ::  obstacle_flags    !< flags to identify corners and edges of topography that cannot be crossed by agents
153
154    LOGICAL ::  deallocate_memory_mas = .TRUE.          !< namelist parameter (see documentation)
155    LOGICAL ::  dt_3d_reached_mas                       !< flag: agent timestep has reached model timestep
156    LOGICAL ::  dt_3d_reached_l_mas                     !< flag: agent timestep has reached model timestep
157    LOGICAL ::  agents_active = .FALSE.                 !< flag for agent system
158    LOGICAL ::  random_start_position_agents = .TRUE.   !< namelist parameter (see documentation)
159    LOGICAL ::  read_agents_from_restartfile = .FALSE.  !< namelist parameter (see documentation)
160    LOGICAL ::  agent_own_timestep = .FALSE.            !< namelist parameter (see documentation)
161
162    LOGICAL, DIMENSION(max_number_of_agent_groups) ::  a_rand_target = .FALSE. !< namelist parameter (see documentation)
163
164    REAL(wp) ::  agent_maximum_age = 9999999.9_wp          !< namelist parameter (see documentation)
165    REAL(wp) ::  agent_substep_time = 0.0_wp               !< time measurement during one LES timestep
166    REAL(wp) ::  alloc_factor_mas = 20.0_wp                !< namelist parameter (see documentation)
167    REAL(wp) ::  coll_t_0 = 3.                             !< namelist parameter (see documentation)
168    REAL(wp) ::  corner_gate_start = 0.5_wp                !< namelist parameter (see documentation)
169    REAL(wp) ::  corner_gate_width = 1.0_wp                !< namelist parameter (see documentation)
170    REAL(wp) ::  dim_size_factor_agtnum = 1.0_wp           !< namelist parameter (see documentation)
171    REAL(wp) ::  d_sigma_rep_agent                         !< inverse of sigma_rep_agent
172    REAL(wp) ::  d_sigma_rep_wall                          !< inverse of sigma_rep_wall
173    REAL(wp) ::  d_tau_accel_agent                         !< inverse of tau_accel_agent
174    REAL(wp) ::  desired_speed = 1.2_wp                    !< namelist parameter (see documentation)
175    REAL(wp) ::  des_sp_sig = .2_wp                        !< namelist parameter (see documentation)
176    REAL(wp) ::  dist_target_reached = 2.0_wp              !< distance at which target counts as reached
177    REAL(wp) ::  dist_to_int_target = .25_wp               !< namelist parameter (see documentation)
178    REAL(wp) ::  dt_agent = 0.02_wp                        !< namelist parameter (see documentation)
179    REAL(wp) ::  dt_arel = 9999999.9_wp                    !< namelist parameter (see documentation)
180    REAL(wp) ::  end_time_arel = 9999999.9_wp              !< namelist parameter (see documentation)
181    REAL(wp) ::  force_x                                   !< dummy value for force on current agent in x-direction
182    REAL(wp) ::  force_y                                   !< dummy value for force on current agent in y-direction
183    REAL(wp) ::  max_dist_from_path = 0.25_wp              !< distance from current path at which a new path is calculated
184    REAL(wp) ::  radius_agent = .25_wp                     !< namelist parameter (see documentation)
185    REAL(wp) ::  repuls_agent = 1.5_wp                     !< namelist parameter (see documentation)
186    REAL(wp) ::  repuls_wall = 7.0_wp                      !< namelist parameter (see documentation)
187    REAL(wp) ::  scan_radius_agent = 3.0_wp                !< namelist parameter (see documentation)
188    REAL(wp) ::  scan_radius_wall = 2.0_wp                 !< namelist parameter (see documentation)
189    REAL(wp) ::  sigma_rep_agent = 0.3_wp                  !< namelist parameter (see documentation)
190    REAL(wp) ::  sigma_rep_wall = 0.1_wp                   !< namelist parameter (see documentation)
191    REAL(wp) ::  tau_accel_agent = 0.5_wp                  !< namelist parameter (see documentation)
192    REAL(wp) ::  time_arel = 0.0_wp                        !< time for agent release
193    REAL(wp) ::  time_write_agent_data = 0.0_wp            !< write agent data at current time on file
194    REAL(wp) ::  v_max_agent = 1.3_wp                      !< namelist parameter (see documentation)
195
196    REAL(wp), DIMENSION(:), ALLOCATABLE ::  dummy_path_x  !<  dummy path (x-coordinate)
197    REAL(wp), DIMENSION(:), ALLOCATABLE ::  dummy_path_y  !<  dummy path (y-coordinate)
198
199    REAL(wp), DIMENSION(max_number_of_agent_groups) ::  adx = 9999999.9_wp  !< namelist parameter (see documentation)
200    REAL(wp), DIMENSION(max_number_of_agent_groups) ::  ady = 9999999.9_wp  !< namelist parameter (see documentation)
201    REAL(wp), DIMENSION(max_number_of_agent_groups) ::  asl = 9999999.9_wp  !< namelist parameter (see documentation)
202    REAL(wp), DIMENSION(max_number_of_agent_groups) ::  asn = 9999999.9_wp  !< namelist parameter (see documentation)
203    REAL(wp), DIMENSION(max_number_of_agent_groups) ::  asr = 9999999.9_wp  !< namelist parameter (see documentation)
204    REAL(wp), DIMENSION(max_number_of_agent_groups) ::  ass = 9999999.9_wp  !< namelist parameter (see documentation)
205    REAL(wp), DIMENSION(max_number_of_agent_groups) ::  at_x = 9999999.9_wp !< namelist parameter (see documentation)
206    REAL(wp), DIMENSION(max_number_of_agent_groups) ::  at_y = 9999999.9_wp !< namelist parameter (see documentation)
207!
208!-- Type for the definition of an agent
209    TYPE agent_type
210        INTEGER(iwp) ::  block_nr             !< number for sorting
211        INTEGER(iwp) ::  group                !< number of agent group
212        INTEGER(idp) ::  id                   !< particle ID (64 bit integer)
213        INTEGER(iwp) ::  path_counter         !< current target along path (path_x/y)
214        LOGICAL      ::  agent_mask           !< if this parameter is set to false the agent will be deleted
215        REAL(wp)     ::  age                  !< age of agent
216        REAL(wp)     ::  age_m                !< age of agent
217        REAL(wp)     ::  dt_sum               !< sum of agents subtimesteps
218        REAL(wp)     ::  clo                  !< clothing index
219        REAL(wp)     ::  energy_storage       !< energy stored by agent
220        REAL(wp)     ::  clothing_temp        !< energy stored by agent
221        REAL(wp)     ::  actlev               !< metabolic + work energy of the person
222        REAL(wp)     ::  age_years            !< physical age of the person
223        REAL(wp)     ::  weight               !< total weight of the person (kg)
224        REAL(wp)     ::  height               !< height of the person (m)
225        REAL(wp)     ::  work                 !< workload of the agent (W)
226        INTEGER(iwp) ::  sex                  !< agents gender: 1 = male, 2 = female
227        REAL(wp)     ::  force_x              !< force term x-direction
228        REAL(wp)     ::  force_y              !< force term y-direction
229        REAL(wp)     ::  origin_x             !< origin x-position of agent
230        REAL(wp)     ::  origin_y             !< origin y-position of agent
231        REAL(wp)     ::  pm10                 !< PM10 concentration at agent position
232        REAL(wp)     ::  pm25                 !< PM25 concentration at agent position
233        REAL(wp)     ::  speed_abs            !< absolute value of agent speed
234        REAL(wp)     ::  speed_e_x            !< normalized speed of agent in x
235        REAL(wp)     ::  speed_e_y            !< normalized speed of agent in y
236        REAL(wp)     ::  speed_des            !< agent's desired speed
237        REAL(wp)     ::  speed_x              !< speed of agent in x
238        REAL(wp)     ::  speed_y              !< speed of agent in y
239        REAL(wp)     ::  ipt                  !< instationary thermal index iPT (°C)
240        REAL(wp)     ::  windspeed            !< absolute value of windspeed at agent position
241        REAL(wp)     ::  x                    !< x-position
242        REAL(wp)     ::  y                    !< y-position
243        REAL(wp)     ::  t                    !< temperature
244        REAL(wp)     ::  t_x                  !< x-position
245        REAL(wp)     ::  t_y                  !< y-position
246        REAL(wp), DIMENSION(0:15) ::  path_x  !< agent path to target (x)
247        REAL(wp), DIMENSION(0:15) ::  path_y  !< agent path to target (y)
248    END TYPE agent_type
249
250    TYPE(agent_type), DIMENSION(:), POINTER ::  agents               !< Agent array for this grid cell
251    TYPE(agent_type)                        ::  zero_agent           !< zero agent to avoid weird thing
252    TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  move_also_north  !< for agent exchange between PEs
253    TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  move_also_south  !< for agent exchange between PEs
254    TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  agt_gh_l         !< ghost layer left of pe domain
255    TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  agt_gh_n         !< ghost layer north of pe domain
256    TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  agt_gh_r         !< ghost layer right of pe domain
257    TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  agt_gh_s         !< ghost layer south of pe domain
258!
259!-- Type for 2D grid on which agents are stored
260    TYPE  grid_agent_def
261        INTEGER(iwp), DIMENSION(0:3)            ::  start_index        !< start agent index for current block
262        INTEGER(iwp), DIMENSION(0:3)            ::  end_index          !< end agent index for current block
263        INTEGER(iwp)                            ::  id_counter         !< agent id counter (removeable?)
264        LOGICAL                                 ::  time_loop_done     !< timestep loop for agent advection
265        TYPE(agent_type), POINTER, DIMENSION(:) ::  agents             !< Particle array for this grid cell
266    END TYPE grid_agent_def
267
268    TYPE(grid_agent_def), DIMENSION(:,:), ALLOCATABLE, TARGET ::  grid_agents !< 2D grid on which agents are stored
269!
270!-- Item in a priority queue (binary heap)
271    TYPE heap_item
272       INTEGER(iwp) ::  mesh_id       !< id of the submitted mesh point
273       REAL(wp)     ::  priority      !< priority of the mesh point (= distance so far + heuristic to goal)
274    END TYPE heap_item
275
276    TYPE(heap_item), DIMENSION(:), ALLOCATABLE ::  queue  !< priority queue realized as binary heap
277!
278!-- Type for mesh point in visibility graph
279    TYPE  mesh_point
280        INTEGER(iwp)                            ::  polygon_id          !< Polygon the point belongs to
281        INTEGER(iwp)                            ::  vertex_id           !< Vertex in the polygon
282        INTEGER(iwp)                            ::  noc                 !< number of connections
283        INTEGER(iwp)                            ::  origin_id           !< ID of previous mesh point on path (A*)
284        INTEGER(iwp), DIMENSION(:), ALLOCATABLE ::  connected_vertices  !< Index of connected vertices
285        REAL(wp)                                ::  cost_so_far         !< Cost to reach this mesh point (A*)
286        REAL(wp)                                ::  x                   !< x-coordinate
287        REAL(wp)                                ::  y                   !< y-coordinate
288        REAL(wp)                                ::  x_s                 !< corner shifted outward from building by 1m (x)
289        REAL(wp)                                ::  y_s                 !< corner shifted outward from building by 1m (y)
290        REAL(wp), DIMENSION(:), ALLOCATABLE     ::  distance_to_vertex  !< Distance to each vertex
291    END TYPE mesh_point
292
293    TYPE(mesh_point), DIMENSION(:), ALLOCATABLE ::  mesh     !< navigation mesh
294    TYPE(mesh_point), DIMENSION(:), ALLOCATABLE ::  tmp_mesh !< temporary navigation mesh
295!
296!-- Vertex of a polygon
297    TYPE  vertex_type
298        LOGICAL               ::  delete  !< Flag to mark vertex for deletion
299        REAL(wp)              ::  x       !< x-coordinate
300        REAL(wp)              ::  y       !< y-coordinate
301    END TYPE vertex_type
302!
303!-- Polygon containing a number of vertices
304    TYPE  polygon_type
305        INTEGER(iwp)                                 ::  nov       !< Number of vertices in this polygon
306        TYPE(vertex_type), DIMENSION(:), ALLOCATABLE ::  vertices  !< Array of vertices
307    END TYPE polygon_type
308
309    TYPE(polygon_type), DIMENSION(:), ALLOCATABLE ::  polygons  !< Building data in polygon form
310
311    SAVE
312
313    PRIVATE
314!
315!-- Public functions
316    PUBLIC mas_init, mas_last_actions, mas_parin, multi_agent_system
317
318!
319!-- Public parameters, constants and initial values
320    PUBLIC agents_active
321
322    INTERFACE mas_parin
323       MODULE PROCEDURE mas_parin
324    END INTERFACE mas_parin
325
326    INTERFACE mas_init
327       MODULE PROCEDURE mas_init
328    END INTERFACE mas_init
329
330    INTERFACE mas_last_actions
331       MODULE PROCEDURE mas_last_actions
332    END INTERFACE mas_last_actions
333
334    INTERFACE multi_agent_system
335       MODULE PROCEDURE multi_agent_system
336    END INTERFACE multi_agent_system
337
338    CONTAINS
339
340
341!------------------------------------------------------------------------------!
342! Description:
343! ------------
344!> Multi Agent System:
345!> executes a number of agents sub-timesteps until the model timestep is reached.
346!> The agent timestep is usually smaller than the model timestep
347!------------------------------------------------------------------------------!
348 SUBROUTINE multi_agent_system
349
350    USE biometeorology_mod,                                                   &
351        ONLY:  bio_calc_ipt, bio_calculate_mrt_grid, bio_get_thermal_index_input_ij
352
353
354    IMPLICIT NONE
355
356    INTEGER(iwp)       ::  i                  !< counter
357    INTEGER(iwp)       ::  ie                 !< counter
358    INTEGER(iwp)       ::  is                 !< counter
359    INTEGER(iwp)       ::  j                  !< counter
360    INTEGER(iwp)       ::  je                 !< counter
361    INTEGER(iwp)       ::  js                 !< counter
362    INTEGER(iwp), SAVE ::  mas_count = 0      !< counts the mas-calls
363    INTEGER(iwp)                :: a     !< agent iterator
364    !-- local meteorological conditions
365    REAL(wp)                    :: tmrt  !< mean radiant temperature        (°C)
366    REAL(wp)                    :: ta    !< air temperature                 (°C)
367    REAL(wp)                    :: vp    !< vapour pressure                 (hPa)
368    REAL(wp)                    :: v     !< wind speed    (local level)     (m/s)
369    REAL(wp)                    :: pair  !< air pressure                    (hPa)
370
371
372    LOGICAL       ::  first_loop_stride   !< flag for first loop stride of agent sub-timesteps
373    LOGICAL, SAVE ::  first_call = .TRUE. !< first call of mas flag for output
374
375    CALL cpu_log( log_point(9), 'mas', 'start' )
376!
377!-- Initialize variables for the next (sub-) timestep, i.e., for marking
378!-- those agents to be deleted after the timestep
379    deleted_agents = 0
380    agent_substep_time = 0.0_wp
381!
382!-- If necessary, release new set of agents
383    IF ( time_arel >= dt_arel  .AND.  end_time_arel > time_since_reference_point )  THEN
384
385       CALL mas_create_agent(PHASE_RELEASE)
386!
387!--    The MOD function allows for changes in the output interval with
388!--    restart runs.
389       time_arel = MOD( time_arel, MAX( dt_arel, dt_3d ) )
390
391    ENDIF
392
393    first_loop_stride = .TRUE.
394    grid_agents(:,:)%time_loop_done = .TRUE.
395!
396!-- Set timestep variable
397    IF ( .NOT. agent_own_timestep ) dt_agent = dt_3d
398!
399!-- Timestep loop for agent transport.
400!-- This loop has to be repeated until the transport time of every agent
401!-- (within the total domain!) has reached the LES timestep (dt_3d).
402!-- Timestep scheme is Euler-forward
403    DO
404!
405!--    Write agent data at current time on file.
406       time_write_agent_data = time_write_agent_data + dt_agent
407       agent_substep_time    = agent_substep_time    + dt_agent
408       IF ( time_write_agent_data >= dt_write_agent_data )  THEN
409#if defined( __netcdf )
410          IF ( first_loop_stride ) CALL mas_get_prognostic_quantities
411          CALL mas_data_output_agents ( first_call )
412#else
413          WRITE( message_string, * ) 'NetCDF is needed for agent output. ',    &
414                                     'Set __netcdf in compiler options'
415          CALL message( 'multi_agent_system', 'PA0071', 1, 2, 0, 6, 0 )
416#endif
417          IF(first_call) first_call = .FALSE.
418          time_write_agent_data = time_write_agent_data - dt_write_agent_data
419       ENDIF
420!
421!--    Flag is true by default, will be set to false if an agent has not yet
422!--    reached the model timestep
423       grid_agents(:,:)%time_loop_done = .TRUE.
424
425!
426!--    First part of agent transport:
427!--    Evaluate social forces for all agents at current positions
428       CALL cpu_log( log_point_s(9), 'mas_social_forces', 'start' )
429       DO  i = nxl, nxr
430          DO  j = nys, nyn
431
432             number_of_agents = agt_count(j,i)
433!
434!--          If grid cell is empty, cycle
435             IF ( number_of_agents <= 0 ) CYCLE
436
437             agents => grid_agents(j,i)%agents(1:number_of_agents)
438!
439!--          Evaluation of social forces
440             CALL mas_timestep_forces_call(i,j)
441
442          ENDDO
443       ENDDO
444       CALL cpu_log( log_point_s(9), 'mas_social_forces', 'stop' )
445!
446!--    Second part of agent transport:
447!--    timestep
448       CALL cpu_log( log_point_s(16), 'mas_timestep', 'start' )
449       DO  i = nxl, nxr
450          DO  j = nys, nyn
451
452             number_of_agents = agt_count(j,i)
453!
454!--          If grid cell is empty, flag must be true
455             IF ( number_of_agents <= 0 )  THEN
456                grid_agents(j,i)%time_loop_done = .TRUE.
457                CYCLE
458             ENDIF
459
460             agents => grid_agents(j,i)%agents(1:number_of_agents)
461
462             agents(1:number_of_agents)%agent_mask = .TRUE.
463!
464!--          Initialize the variable storing the total time that an agent
465!--          has advanced within the timestep procedure
466             IF ( first_loop_stride )  THEN
467                agents(1:number_of_agents)%dt_sum = 0.0_wp
468             ENDIF
469!
470!--          Initialize the switch used for the loop exit condition checked
471!--          at the end of this loop. If at least one agent has failed to
472!--          reach the LES timestep, this switch will be set false in
473!--          mas_transport.
474             dt_3d_reached_l_mas = .TRUE.
475!
476!--          Timestep
477             CALL mas_timestep
478!
479!--          Delete agents that have been simulated longer than allowed
480             CALL mas_boundary_conds( 'max_sim_time' )
481!
482!--          Delete agents that have reached target area
483             CALL mas_boundary_conds( 'target_area' )
484!
485!---         If not all agents of the actual grid cell have reached the
486!--          LES timestep, this cell has to to another loop iteration. Due to
487!--          the fact that agents can move into neighboring grid cell,
488!--          these neighbor cells also have to perform another loop iteration
489             IF ( .NOT. dt_3d_reached_l_mas )  THEN
490                js = MAX(nys,j-1)
491                je = MIN(nyn,j+1)
492                is = MAX(nxl,i-1)
493                ie = MIN(nxr,i+1)
494                grid_agents(js:je,is:ie)%time_loop_done = .FALSE.
495             ENDIF
496
497          ENDDO
498       ENDDO
499       CALL cpu_log( log_point_s(16), 'mas_timestep', 'stop' )
500
501!
502!--    Find out, if all agents on every PE have completed the LES timestep
503!--    and set the switch corespondingly
504       dt_3d_reached_l_mas = ALL(grid_agents(:,:)%time_loop_done)
505#if defined( __parallel )
506       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
507       CALL MPI_ALLREDUCE( dt_3d_reached_l_mas, dt_3d_reached_mas, 1, MPI_LOGICAL, &
508                           MPI_LAND, comm2d, ierr )
509#else
510       dt_3d_reached_mas = dt_3d_reached_l_mas
511#endif
512
513!
514!--    Increment time since last release
515       IF ( dt_3d_reached_mas )  time_arel = time_arel + dt_3d
516
517!
518!--    Move Agents local to PE to a different grid cell
519       CALL cpu_log( log_point_s(18), 'mas_move_exch_sort', 'start' )
520       CALL mas_eh_move_agent
521!
522!--    Horizontal boundary conditions including exchange between subdmains
523       CALL mas_eh_exchange_horiz
524!
525!--    Pack agents (eliminate those marked for deletion),
526!--    determine new number of agents
527       CALL mas_ps_sort_in_subboxes
528       CALL cpu_log( log_point_s(18), 'mas_move_exch_sort', 'stop' )
529!
530!--    Initialize variables for the next (sub-) timestep, i.e., for marking
531!--    those agents to be deleted after the timestep
532       deleted_agents = 0
533
534       IF ( biometeorology )  THEN
535!
536!--       Fill out the MRT 2D grid from appropriate source (RTM, RRTMG,...)
537          CALL bio_calculate_mrt_grid ( .FALSE. )
538!
539!--       Call of human thermal comfort mod (and UV exposure)
540          DO  i = nxl, nxr
541             DO  j = nys, nyn
542
543                number_of_agents = agt_count(j,i)
544!
545!--             If grid cell gets empty, cycle
546                IF ( number_of_agents <= 0 )  CYCLE
547
548                agents => grid_agents(j,i)%agents(1:number_of_agents)
549!
550!--             Evaluation of social forces
551!                CALL bio_dynamic( i, j )
552!
553!--             Determine local meteorological conditions
554                CALL bio_get_thermal_index_input_ij ( .FALSE., i, j, ta, vp,  &
555                                                      v, pair, tmrt )
556
557                DO  a = 1, number_of_agents
558!
559!--                Calculate instationary thermal indices based on local tmrt
560
561                   CALL bio_calc_ipt ( ta, vp, v, pair, tmrt,                 &
562                                       agents(a)%dt_sum,                      &
563                                       agents(a)%energy_storage,              &
564                                       agents(a)%clothing_temp,               &
565                                       agents(a)%clo,                         &
566                                       agents(a)%actlev,                      &
567                                       agents(a)%age_years,                   &
568                                       agents(a)%weight,                      &
569                                       agents(a)%height,                      &
570                                       agents(a)%work,                        &
571                                       agents(a)%sex,                         &
572                                       agents(a)%ipt )
573                END DO
574
575             ENDDO
576          ENDDO
577       ENDIF
578
579       IF ( dt_3d_reached_mas )  EXIT
580
581       first_loop_stride = .FALSE.
582    ENDDO   ! timestep loop
583
584!
585!-- Deallocate unused memory
586    IF ( deallocate_memory_mas  .AND.  mas_count == step_dealloc_mas )  THEN
587       CALL mas_eh_dealloc_agents_array
588       mas_count = 0
589    ELSEIF ( deallocate_memory_mas )  THEN
590       mas_count = mas_count + 1
591    ENDIF
592
593    CALL cpu_log( log_point(9), 'mas', 'stop' )
594
595 END SUBROUTINE multi_agent_system
596
597!------------------------------------------------------------------------------!
598! Description:
599! ------------
600!> Calculation of the direction vector from each agent to its current
601!> intermittent target
602!------------------------------------------------------------------------------!
603    SUBROUTINE mas_agent_direction
604
605       IMPLICIT NONE
606
607       LOGICAL ::  path_flag !< true if new path must be calculated
608
609       INTEGER(iwp) ::  n  !< loop variable over all agents in a grid box
610       INTEGER(iwp) ::  pc !< agent path counter
611
612       REAL(wp) ::  abs_dir         !< length of direction vector (for normalization)
613!       REAL(wp) ::  d_curr_target   !< rounding influence expressed as x speed component
614!       REAL(wp) ::  d_prev_target   !< rounding influence expressed as x speed component
615       REAL(wp) ::  dir_x           !< direction of agent (x)
616       REAL(wp) ::  dir_y           !< direction of agent (y)
617!       REAL(wp) ::  dist_round = 3. !< distance at which agents start rounding a corner
618       REAL(wp) ::  dtit            !< distance to intermittent target
619!       REAL(wp) ::  round_fac  = 0.2 !< factor for rounding influence
620!       REAL(wp) ::  speed_round_x   !< rounding influence expressed as x speed component
621!       REAL(wp) ::  speed_round_y   !< rounding influence expressed as x speed component
622
623!
624!--    loop over all agents in the current grid box
625       DO n = 1, number_of_agents
626          path_flag = .FALSE.
627          pc = agents(n)%path_counter
628!
629!--       If no path was calculated for agent yet, do it
630          IF ( pc >= 999 ) THEN
631             CALL mas_nav_find_path(n)
632             pc = agents(n)%path_counter
633!
634!--       Check if new path must be calculated and if so, do it
635          ELSE
636!
637!--          Case one: Agent has come close enough to intermittent target.
638!--                    -> chose new int target and calculate rest of path if no
639!--                       new intermittent targets are left
640             dtit = SQRT((agents(n)%x - agents(n)%path_x(pc))**2               &
641                       + (agents(n)%y - agents(n)%path_y(pc))**2)
642             IF ( dtit < dist_to_int_target ) THEN
643                agents(n)%path_counter = agents(n)%path_counter + 1
644                pc = agents(n)%path_counter
645!
646!--             Path counter out of scope (each agent can store a maximum of 15
647!--             intermittent targets on the way to her final target); new path
648!--             must be calculated
649                IF ( pc >= SIZE(agents(n)%path_x) ) THEN
650                   path_flag = .TRUE.
651                ENDIF
652!
653!--          Case two: Agent too far from path
654!--                    -> set flag for new path to be calculated
655             ELSEIF ( dist_point_to_edge(agents(n)%path_x(pc-1),               &
656                                         agents(n)%path_y(pc-1),               &
657                                         agents(n)%path_x(pc),                 &
658                                         agents(n)%path_y(pc),                 &
659                                         agents(n)%x, agents(n)%y)             &
660                      > max_dist_from_path )                                   &
661             THEN
662                path_flag = .TRUE.
663             ENDIF
664!
665!--          If either of the above two cases was true, calculate new path and
666!--          reset 0th path point. This point (the last target the agent had)
667!--          is needed for the agents rounding of corners and the calculation
668!--          of her deviation from her current path
669             IF ( path_flag ) THEN
670                CALL mas_nav_find_path(n)
671                pc = agents(n)%path_counter
672             ENDIF
673          ENDIF
674!
675!--       Normalize direction vector
676          abs_dir             = 1.0d-12
677          dir_x               = agents(n)%path_x(pc) - agents(n)%x
678          dir_y               = agents(n)%path_y(pc) - agents(n)%y
679          abs_dir             = SQRT(dir_x**2 + dir_y**2)+1.0d-12
680!--         needed later for corner rounding
681!           dir_x               = dir_x/abs_dir
682!           dir_y               = dir_y/abs_dir
683!           dir_x               = dir_x + speed_round_x
684!           dir_y               = dir_y + speed_round_y
685!           abs_dir             = SQRT(dir_x**2 + dir_y**2)+1.0d-12
686          agents(n)%speed_e_x = dir_x/abs_dir
687          agents(n)%speed_e_y = dir_y/abs_dir
688       ENDDO
689
690!
691!-- corner rounding; to be added
692!
693!--       Calculate direction change due to rounding of corners
694
695!           speed_round_x = 0.
696!           speed_round_y = 0.
697!           
698!           d_curr_target = SQRT( (agents(n)%path_x(pc) - agents(n)%x)**2 +      &
699!                                 (agents(n)%path_y(pc) - agents(n)%y)**2 )
700!           d_prev_target = SQRT( (agents(n)%path_x(pc-1) - agents(n)%x)**2 +    &
701!                                 (agents(n)%path_y(pc-1) - agents(n)%y)**2 )
702! !
703! !--       Agent is close to next target and that target is not the final one
704!           IF ( d_curr_target < dist_round .AND. dist_round <                   &
705!                           SQRT( (agents(n)%path_x(pc) - agents(n)%t_x)**2 +    &
706!                                 (agents(n)%path_y(pc) - agents(n)%t_y)**2 ) )  &
707!           THEN
708!              speed_round_x = (agents(n)%path_x(pc+1) - agents(n)%path_x(pc)) / &
709!                              ABS( agents(n)%path_x(pc)                         &
710!                                 - agents(n)%path_x(pc+1)) * round_fac *        &
711!                              SIN( pi/dist_round*d_curr_target )
712!              speed_round_y = (agents(n)%path_y(pc+1) - agents(n)%path_y(pc)) / &
713!                              ABS( agents(n)%path_y(pc)                         &
714!                                 - agents(n)%path_y(pc+1)) * round_fac *        &
715!                              SIN( pi/dist_round*d_curr_target )
716!           ENDIF
717!
718!           IF ( d_prev_target < dist_round ) THEN
719!              IF ( agents(n)%path_x(pc) /= agents(n)%path_x(pc+1) ) THEN
720!                 speed_round_x = speed_round_x +                                   &
721!                                 (agents(n)%path_x(pc) - agents(n)%path_x(pc+1)) / &
722!                                 ABS( agents(n)%path_x(pc)                         &
723!                                    - agents(n)%path_x(pc+1)) * round_fac *        &
724!                                 SIN( pi/dist_round*d_prev_target )
725!              ENDIF
726!             
727!              IF ( agents(n)%path_y(pc) /= agents(n)%path_y(pc+1) ) THEN
728!                 speed_round_y = speed_round_y +                                   &
729!                              (agents(n)%path_y(pc) - agents(n)%path_y(pc+1)) / &
730!                              ABS( agents(n)%path_y(pc)                         &
731!                                 - agents(n)%path_y(pc+1)) * round_fac *        &
732!                              SIN( pi/dist_round*d_prev_target )
733!              ENDIF
734             
735!           ENDIF
736
737
738    END SUBROUTINE mas_agent_direction
739
740!------------------------------------------------------------------------------!
741! Description:
742! ------------
743!> Boundary conditions for maximum time, target reached and out of domain
744!------------------------------------------------------------------------------!
745    SUBROUTINE mas_boundary_conds( location )
746
747       IMPLICIT NONE
748
749       CHARACTER (LEN=*) ::  location !< Identifier
750
751       INTEGER(iwp) ::  n   !< agent number
752       INTEGER(iwp) ::  grp !< agent group
753
754       REAL(wp) ::  dist_to_target !< distance to target
755
756       IF ( location == 'max_sim_time' )  THEN
757
758!
759!--       Delete agents that have been simulated longer than allowed
760          DO  n = 1, number_of_agents
761
762             IF ( agents(n)%age > agent_maximum_age  .AND.                     &
763                  agents(n)%agent_mask )                                       &
764             THEN
765                agents(n)%agent_mask  = .FALSE.
766                deleted_agents = deleted_agents + 1
767             ENDIF
768
769          ENDDO
770       ENDIF
771
772       IF ( location == 'target_area' )  THEN
773
774!
775!--       Delete agents that entered target region
776          DO  n = 1, number_of_agents
777             grp = agents(n)%group
778             dist_to_target = SQRT((agents(n)%x-at_x(grp))**2                  &
779                                 + (agents(n)%y-at_y(grp))**2)
780             IF ( dist_to_target < dist_target_reached ) THEN
781                agents(n)%agent_mask  = .FALSE.
782                deleted_agents = deleted_agents + 1
783             ENDIF
784
785          ENDDO
786       ENDIF
787
788    END SUBROUTINE mas_boundary_conds
789
790!------------------------------------------------------------------------------!
791! Description:
792! ------------
793!> Release new agents at their respective sources
794!------------------------------------------------------------------------------!
795    SUBROUTINE mas_create_agent (phase)
796
797       IMPLICIT  NONE
798
799       INTEGER(iwp) ::  alloc_size  !< relative increase of allocated memory for agents
800       INTEGER(iwp) ::  i           !< loop variable ( agent groups )
801       INTEGER(iwp) ::  ip          !< index variable along x
802       INTEGER(iwp) ::  jp          !< index variable along y
803       INTEGER(iwp) ::  loop_stride !< loop variable for initialization
804       INTEGER(iwp) ::  n           !< loop variable ( number of agents )
805       INTEGER(iwp) ::  new_size    !< new size of allocated memory for agents
806       INTEGER(iwp) ::  rn_side     !< index of agent path
807
808       INTEGER(iwp), INTENT(IN) ::  phase       !< mode of inititialization
809
810       INTEGER(iwp), DIMENSION(nysg:nyng,nxlg:nxrg) ::  local_count !< start address of new agent
811       INTEGER(iwp), DIMENSION(nysg:nyng,nxlg:nxrg) ::  local_start !< start address of new agent
812
813       LOGICAL ::  first_stride !< flag for initialization
814
815       REAL(wp) ::  pos_x       !< increment for agent position in x
816       REAL(wp) ::  pos_y       !< increment for agent position in y
817       REAL(wp) ::  rand_contr  !< dummy argument for random position
818       REAL(wp) ::  rn_side_dum !< index of agent path
819
820       TYPE(agent_type),TARGET ::  tmp_agent !< temporary agent used for initialization
821
822!
823!--    Calculate agent positions and store agent attributes, if
824!--    agent is situated on this PE
825       DO  loop_stride = 1, 2
826          first_stride = (loop_stride == 1)
827          IF ( first_stride )   THEN
828             local_count = 0           ! count number of agents
829          ELSE
830             local_count = agt_count   ! Start address of new agents
831          ENDIF
832
833          DO  i = 1, number_of_agent_groups
834
835             pos_y = ass(i)
836
837             DO WHILE ( pos_y <= asn(i) )
838
839                IF ( pos_y >= nys * dy  .AND.                                  &
840                           pos_y <  ( nyn + 1 ) * dy  )                        &
841                THEN
842
843                   pos_x = asl(i)
844
845            xloop: DO WHILE ( pos_x <= asr(i) )
846
847                      IF ( pos_x >= nxl * dx  .AND.                            &
848                                 pos_x <  ( nxr + 1) * dx )                    &
849                      THEN
850
851                         tmp_agent%agent_mask = .TRUE.
852                         tmp_agent%group         = i
853                         tmp_agent%id            = 0_idp
854                         tmp_agent%block_nr      = -1
855                         tmp_agent%path_counter  = 999 !SIZE(tmp_agent%path_x)
856                         tmp_agent%age           = 0.0_wp
857                         tmp_agent%age_m         = 0.0_wp
858                         tmp_agent%dt_sum        = 0.0_wp
859                         tmp_agent%clo           = -999.0_wp
860                         tmp_agent%energy_storage= 0.0_wp
861                         tmp_agent%ipt           = 99999.0_wp
862                         tmp_agent%clothing_temp = -999._wp      !< energy stored by agent (W)
863                         tmp_agent%actlev        = 134.6862_wp   !< metabolic + work energy of the person
864                         tmp_agent%age_years     = 35._wp        !< physical age of the person
865                         tmp_agent%weight        = 75._wp        !< total weight of the person (kg)
866                         tmp_agent%height        = 1.75_wp       !< height of the person (m)
867                         tmp_agent%work          = 134.6862_wp   !< workload of the agent (W)
868                         tmp_agent%sex           = 1             !< agents gender: 1 = male, 2 = female
869                         tmp_agent%force_x       = 0.0_wp
870                         tmp_agent%force_y       = 0.0_wp
871                         tmp_agent%origin_x      = pos_x
872                         tmp_agent%origin_y      = pos_y
873                         tmp_agent%speed_abs     = 0.0_wp
874                         tmp_agent%speed_e_x     = 0.0_wp
875                         tmp_agent%speed_e_y     = 0.0_wp
876                         tmp_agent%speed_des     = random_normal(desired_speed,&
877                                                                 des_sp_sig)
878                         tmp_agent%speed_x       = 0.0_wp
879                         tmp_agent%speed_y       = 0.0_wp
880                         tmp_agent%x             = pos_x
881                         tmp_agent%y             = pos_y
882                         tmp_agent%path_x        = -1.0_wp
883                         tmp_agent%path_y        = -1.0_wp
884                         tmp_agent%t_x           = - pi
885                         tmp_agent%t_y           = - pi
886!
887!--                      Determine the grid indices of the agent position
888                         ip = tmp_agent%x * ddx
889                         jp = tmp_agent%y * ddy
890!
891!--                      Give each agent its target
892                         IF ( a_rand_target(i) ) THEN
893!
894!--                         Agent shall receive random target just outside
895!--                         simulated area
896                            rn_side_dum = random_function(iran_agent)
897                            rn_side     = FLOOR(4.*rn_side_dum)
898                            IF ( rn_side < 2 ) THEN
899                               IF ( rn_side == 0 ) THEN
900                                  tmp_agent%t_y = -2*dy
901                               ELSE
902                                  tmp_agent%t_y = (ny+3)*dy
903                               ENDIF
904                               tmp_agent%t_x = random_function(iran_agent) *   &
905                                               (nx+1)*dx
906                            ELSE
907                               IF ( rn_side == 2 ) THEN
908                                  tmp_agent%t_x = -2*dx
909                               ELSE
910                                  tmp_agent%t_x = (nx+3)*dx
911                               ENDIF
912                               tmp_agent%t_y = random_function(iran_agent) *   &
913                                               (ny+1)*dy
914                            ENDIF
915!
916!--                      Agent gets target of her group
917                         ELSE
918                            tmp_agent%t_x = at_x(i)
919                            tmp_agent%t_y = at_y(i)
920                         ENDIF
921
922                         local_count(jp,ip) = local_count(jp,ip) + 1
923
924                         IF ( .NOT. first_stride )  THEN
925                            grid_agents(jp,ip)%agents(local_count(jp,ip))      &
926                                              = tmp_agent
927                         ENDIF
928
929                      ENDIF
930
931                      pos_x = pos_x + adx(i)
932
933                   ENDDO xloop
934
935                ENDIF
936
937                pos_y = pos_y + ady(i)
938
939             ENDDO
940
941          ENDDO
942
943!
944!--       Allocate or reallocate agents array to new size
945          IF ( first_stride )  THEN
946             DO  ip = nxlg, nxrg
947                DO  jp = nysg, nyng
948                   IF ( phase == PHASE_INIT )  THEN
949                      IF ( local_count(jp,ip) > 0 )  THEN
950                         alloc_size = MAX( INT( local_count(jp,ip) *           &
951                            ( 1.0_wp + alloc_factor_mas / 100.0_wp ) ),        &
952                            min_nr_agent )
953                      ELSE
954                         alloc_size = min_nr_agent
955                      ENDIF
956                      ALLOCATE(grid_agents(jp,ip)%agents(1:alloc_size))
957                      DO  n = 1, alloc_size
958                         grid_agents(jp,ip)%agents(n) = zero_agent
959                      ENDDO
960                   ELSEIF ( phase == PHASE_RELEASE )  THEN
961                      IF ( local_count(jp,ip) > 0 )  THEN
962                         new_size   = local_count(jp,ip) + agt_count(jp,ip)
963                         alloc_size = MAX( INT( new_size * ( 1.0_wp +          &
964                            alloc_factor_mas / 100.0_wp ) ), min_nr_agent )
965                         IF( alloc_size > SIZE( grid_agents(jp,ip)%agents) )   &
966                         THEN
967                            CALL mas_eh_realloc_agents_array(ip,jp,alloc_size)
968                         ENDIF
969                      ENDIF
970                   ENDIF
971                ENDDO
972             ENDDO
973          ENDIF
974
975       ENDDO
976
977       local_start = agt_count+1
978       agt_count   = local_count
979
980!
981!--    Calculate agent IDs
982       DO  ip = nxl, nxr
983          DO  jp = nys, nyn
984             number_of_agents = agt_count(jp,ip)
985             IF ( number_of_agents <= 0 )  CYCLE
986             agents => grid_agents(jp,ip)%agents(1:number_of_agents)
987
988             DO  n = local_start(jp,ip), number_of_agents  !only new agents
989
990                agents(n)%id = 10000_idp**2 * grid_agents(jp,ip)%id_counter +  &
991                               10000_idp * jp + ip
992!
993!--             Count the number of agents that have been released before
994                grid_agents(jp,ip)%id_counter = grid_agents(jp,ip)%id_counter  &
995                                                + 1
996
997             ENDDO
998
999          ENDDO
1000       ENDDO
1001
1002!
1003!--    Add random fluctuation to agent positions.
1004       IF ( random_start_position_agents )  THEN
1005          DO  ip = nxl, nxr
1006             DO  jp = nys, nyn
1007                number_of_agents = agt_count(jp,ip)
1008                IF ( number_of_agents <= 0 )  CYCLE
1009                agents => grid_agents(jp,ip)%agents(1:number_of_agents)
1010!
1011!--             Move only new agents. Moreover, limit random fluctuation
1012!--             in order to prevent that agents move more than one grid box,
1013!--             which would lead to problems concerning agent exchange
1014!--             between processors in case adx/ady are larger than dx/dy,
1015!--             respectively. 
1016                DO  n = local_start(jp,ip), number_of_agents
1017                   IF ( asl(agents(n)%group) /= asr(agents(n)%group) )  THEN
1018                      rand_contr = ( random_function( iran_agent ) - 0.5_wp ) *&
1019                                     adx(agents(n)%group)
1020                      agents(n)%x = agents(n)%x +                        &
1021                              MERGE( rand_contr, SIGN( dx, rand_contr ),       &
1022                                     ABS( rand_contr ) < dx                    &
1023                                   ) 
1024                   ENDIF
1025                   IF ( ass(agents(n)%group) /= asn(agents(n)%group) )  THEN
1026                      rand_contr = ( random_function( iran_agent ) - 0.5_wp ) *&
1027                                     ady(agents(n)%group)
1028                      agents(n)%y = agents(n)%y +                        &
1029                              MERGE( rand_contr, SIGN( dy, rand_contr ),       &
1030                                     ABS( rand_contr ) < dy )
1031                   ENDIF
1032                ENDDO
1033!
1034!--             Delete agents that have been simulated longer than allowed
1035                CALL mas_boundary_conds( 'max_sim_time' )
1036!
1037!--             Delete agents that have reached target area
1038                CALL mas_boundary_conds( 'target_area' )
1039
1040             ENDDO
1041          ENDDO
1042!
1043!--       Exchange agents between grid cells and processors
1044          CALL mas_eh_move_agent
1045          CALL mas_eh_exchange_horiz
1046
1047       ENDIF
1048!
1049!--    In case of random_start_position_agents, delete agents identified by
1050!--    mas_eh_exchange_horiz and mas_boundary_conds. Then sort agents into
1051!--    blocks, which is needed for a fast interpolation of the LES fields
1052!--    on the agent position.
1053       CALL mas_ps_sort_in_subboxes
1054
1055!
1056!--    Determine the current number of agents
1057       number_of_agents = 0
1058       DO  ip = nxl, nxr
1059          DO  jp = nys, nyn
1060             number_of_agents = number_of_agents + agt_count(jp,ip)
1061          ENDDO
1062       ENDDO
1063!
1064!--    Calculate the number of agents of the total domain
1065#if defined( __parallel )
1066       IF ( collective_wait )  CALL MPI_BARRIER( comm2d, ierr )
1067       CALL MPI_ALLREDUCE( number_of_agents, total_number_of_agents, 1, &
1068       MPI_INTEGER, MPI_SUM, comm2d, ierr )
1069#else
1070       total_number_of_agents = number_of_agents
1071#endif
1072
1073       RETURN
1074
1075    END SUBROUTINE mas_create_agent
1076
1077!------------------------------------------------------------------------------!
1078! Description:
1079! ------------
1080!> Creates flags that indicate if a gridbox contains edges or corners. These
1081!> flags are used for agents to check if obstacles are close to them.
1082!------------------------------------------------------------------------------!
1083    SUBROUTINE mas_create_obstacle_flags
1084
1085       USE arrays_3d,                                                          &
1086           ONLY:  zw
1087
1088       IMPLICIT NONE
1089
1090       INTEGER(iwp) ::  il
1091       INTEGER(iwp) ::  jl
1092
1093       ALLOCATE(obstacle_flags(nysg:nyng,nxlg:nxrg))
1094
1095       obstacle_flags = 0
1096
1097       DO il = nxlg, nxrg
1098          DO jl = nysg, nyng
1099!
1100!--          Exclude cyclic topography boundary
1101             IF ( il < 0 .OR. il > nx .OR. jl < 0 .OR. jl > ny ) CYCLE
1102!
1103!--          North edge
1104             IF ( jl < nyng ) THEN
1105                IF ( ( top_top_s(jl,il) - top_top_s(jl+1,il) ) > 1 .AND.       &
1106                     ( zw( top_top_w(jl,il) ) -                                &
1107                       zw( top_top_w(jl+1,il) ) ) > .51_wp )                   &
1108                THEN
1109                   obstacle_flags(jl,il) = IBSET( obstacle_flags(jl,il), 0 )
1110                ENDIF
1111             ENDIF
1112!
1113!--          North right corner
1114             IF ( jl < nyng .AND. il < nxrg ) THEN
1115                IF ( ( top_top_s(jl,il) - top_top_s(jl+1,il) )   > 1 .AND.     &
1116                     ( top_top_s(jl,il) - top_top_s(jl+1,il+1) ) > 1 .AND.     &
1117                     ( top_top_s(jl,il) - top_top_s(jl,il+1) )   > 1 .AND.     &
1118                     ( zw( top_top_w(jl,il) ) -                                &
1119                       zw( top_top_w(jl+1,il+1) ) ) > .51_wp )                 &
1120                THEN
1121                   obstacle_flags(jl,il) = IBSET( obstacle_flags(jl,il), 1 )
1122                ENDIF
1123             ENDIF
1124!
1125!--          Right edge
1126             IF ( il < nxrg ) THEN
1127                IF ( ( top_top_s(jl,il) - top_top_s(jl,il+1) ) > 1 .AND.       &
1128                     ( zw( top_top_w(jl,il) ) -                                &
1129                       zw( top_top_w(jl,il+1) ) ) > .51_wp )                   &
1130                THEN
1131                   obstacle_flags(jl,il) = IBSET( obstacle_flags(jl,il), 2 )
1132                ENDIF
1133             ENDIF
1134!
1135!--          South right corner
1136             IF ( jl > nysg .AND. il < nxrg ) THEN
1137                IF ( ( top_top_s(jl,il) - top_top_s(jl,il+1) )   > 1 .AND.     &
1138                     ( top_top_s(jl,il) - top_top_s(jl-1,il+1) ) > 1 .AND.     &
1139                     ( top_top_s(jl,il) - top_top_s(jl-1,il) )   > 1 .AND.     &
1140                     ( zw(top_top_w(jl,il)) -                                  &
1141                       zw( top_top_w(jl-1,il+1) ) ) > .51_wp )                 &
1142                THEN
1143                   obstacle_flags(jl,il) = IBSET( obstacle_flags(jl,il), 3 )
1144                ENDIF
1145             ENDIF
1146!
1147!--          South edge
1148             IF ( jl > nysg ) THEN
1149                IF ( ( top_top_s(jl,il) - top_top_s(jl-1,il) ) > 1 .AND.       &
1150                     ( zw( top_top_w(jl,il) ) -                                &
1151                       zw( top_top_w(jl-1,il) ) ) > .51_wp )                   &
1152                THEN
1153                   obstacle_flags(jl,il) = IBSET( obstacle_flags(jl,il), 4 )
1154                ENDIF
1155             ENDIF
1156!
1157!--          South left corner
1158             IF ( jl > nysg .AND. il > nxlg ) THEN
1159                IF ( ( top_top_s(jl,il) - top_top_s(jl-1,il) )   > 1 .AND.     &
1160                     ( top_top_s(jl,il) - top_top_s(jl-1,il-1) ) > 1 .AND.     &
1161                     ( top_top_s(jl,il) - top_top_s(jl,il-1) )   > 1 .AND.     &
1162                     ( zw( top_top_w(jl,il) ) -                                &
1163                       zw(top_top_w(jl-1,il-1) ) ) > .51_wp )                  &
1164                THEN
1165                   obstacle_flags(jl,il) = IBSET( obstacle_flags(jl,il), 5 )
1166                ENDIF
1167             ENDIF
1168!
1169!--          Left edge
1170             IF ( il > nxlg ) THEN
1171                IF ( ( top_top_s(jl,il) - top_top_s(jl,il-1) ) > 1 .AND.       &
1172                     ( zw(top_top_w(jl,il) ) -                                 &
1173                       zw(top_top_w(jl,il-1) ) ) > .51_wp )                 &
1174                THEN
1175                   obstacle_flags(jl,il) = IBSET( obstacle_flags(jl,il), 6 )
1176                ENDIF
1177             ENDIF
1178!
1179!--          North left corner
1180             IF ( jl < nyng .AND. il > nxlg ) THEN
1181                IF ( ( top_top_s(jl,il) - top_top_s(jl,il-1) )   > 1 .AND.     &
1182                     ( top_top_s(jl,il) - top_top_s(jl+1,il-1) ) > 1 .AND.     &
1183                     ( top_top_s(jl,il) - top_top_s(jl+1,il) )   > 1 .AND.     &
1184                     ( zw( top_top_w(jl,il) ) -                                &
1185                       zw( top_top_w(jl+1,il-1) ) ) > .51_wp )                 &
1186                THEN
1187                   obstacle_flags(jl,il) = IBSET( obstacle_flags(jl,il), 7 )
1188                ENDIF
1189             ENDIF
1190
1191          ENDDO
1192       ENDDO
1193
1194    END SUBROUTINE mas_create_obstacle_flags
1195
1196!------------------------------------------------------------------------------!
1197! Description:
1198! ------------
1199!> Write agent data in netCDF format
1200!------------------------------------------------------------------------------!
1201    SUBROUTINE mas_data_output_agents( ftest )
1202
1203       USE control_parameters,                                                 &
1204           ONLY:  agt_time_count, end_time, message_string,                    &
1205                  multi_agent_system_end, multi_agent_system_start
1206
1207       USE netcdf_interface,                                                   &
1208           ONLY:  nc_stat, id_set_agt, id_var_time_agt,        &
1209                  id_var_agt, netcdf_handle_error
1210
1211       USE pegrid
1212
1213#if defined( __netcdf )
1214       USE NETCDF
1215#endif
1216       USE mas_global_attributes,                                              &
1217           ONLY:  dim_size_agtnum
1218
1219       IMPLICIT NONE
1220
1221       INTEGER(iwp) ::  agt_size !< Agent size in bytes
1222       INTEGER(iwp) ::  dummy    !< dummy
1223       INTEGER(iwp) ::  ii       !< counter (x)
1224       INTEGER(iwp) ::  ip       !< counter (x)
1225       INTEGER(iwp) ::  jp       !< counter (y)
1226       INTEGER(iwp) ::  n        !< counter (number of PEs)
1227       INTEGER(iwp) ::  noa      !< number of agents
1228       INTEGER(iwp) ::  noa_rcv  !< received number of agents
1229       INTEGER(iwp) ::  out_noa  !< number of agents for output
1230
1231       INTEGER(iwp), DIMENSION(0:numprocs-1) ::  noa_arr !< number of agents on each PE
1232
1233       TYPE(agent_type), DIMENSION(:), ALLOCATABLE, TARGET ::  trf_agents !< all agents on current PE
1234       TYPE(agent_type), DIMENSION(:), ALLOCATABLE, TARGET ::  out_agents !< all agents in entire domain
1235
1236       LOGICAL, INTENT (INOUT) :: ftest
1237
1238       LOGICAL, SAVE :: agt_dimension_exceeded = .FALSE.
1239
1240       CALL cpu_log( log_point_s(17), 'mas_data_output', 'start' )
1241!
1242!--    Get total number of agents and put all agents on one PE in one array
1243       noa = 0
1244       DO  ip = nxl, nxr
1245          DO  jp = nys, nyn
1246             noa  = noa  + agt_count(jp,ip)
1247          ENDDO
1248       ENDDO
1249       IF(noa > 0) THEN
1250          ALLOCATE(trf_agents(1:noa))
1251          dummy = 1
1252          DO  ip = nxl, nxr
1253             DO  jp = nys, nyn
1254                IF ( agt_count(jp,ip) == 0 ) CYCLE
1255                agents => grid_agents(jp,ip)%agents(1:agt_count(jp,ip))
1256                trf_agents(dummy:(dummy-1+agt_count(jp,ip))) = agents
1257                dummy = dummy + agt_count(jp,ip)
1258             ENDDO
1259          ENDDO
1260       ENDIF
1261#if defined( __parallel )
1262!
1263!--    Gather all agents on PE0 for output
1264       IF ( myid == 0 )  THEN
1265          noa_arr(0) = noa
1266!
1267!--       Receive data from all other PEs.
1268          DO  n = 1, numprocs-1
1269              CALL MPI_RECV( noa_arr(n), 1, MPI_INTEGER,                       &
1270                              n, 0, comm2d, status, ierr )
1271          ENDDO
1272       ELSE
1273          CALL MPI_SEND( noa, 1, MPI_INTEGER, 0, 0, comm2d, ierr )
1274       ENDIF
1275       CALL MPI_BARRIER( comm2d, ierr )
1276       agt_size = STORAGE_SIZE(zero_agent)/8
1277       IF ( myid == 0 )  THEN
1278!
1279!--       Receive data from all other PEs.
1280          out_noa = SUM(noa_arr)
1281          IF ( out_noa > 0 ) THEN
1282             ALLOCATE( out_agents(1:out_noa) )
1283             IF ( noa > 0 ) THEN
1284                out_agents(1:noa) = trf_agents
1285             ENDIF
1286             noa_rcv = noa
1287             DO n = 1, numprocs-1
1288                IF ( noa_arr(n) > 0 ) THEN
1289                   CALL MPI_RECV( out_agents(noa_rcv+1), noa_arr(n)*agt_size,  &
1290                                  MPI_BYTE, n, 0, comm2d, status, ierr )
1291                   noa_rcv = noa_rcv + noa_arr(n)
1292                ENDIF
1293             ENDDO
1294          ELSE
1295             ALLOCATE( out_agents(1:2) )
1296             out_agents = zero_agent
1297             out_noa    = 2
1298          ENDIF
1299       ELSE
1300          IF ( noa > 0 ) THEN
1301             CALL MPI_SEND( trf_agents(1), noa*agt_size, MPI_BYTE, 0, 0,       &
1302                                        comm2d, ierr )
1303          ENDIF
1304       ENDIF
1305!
1306!--    A barrier has to be set, because otherwise some PEs may
1307!--    proceed too fast so that PE0 may receive wrong data on
1308!--    tag 0
1309       CALL MPI_BARRIER( comm2d, ierr )
1310#endif
1311       IF ( myid == 0 ) THEN
1312#if defined( __parallel )
1313          agents => out_agents
1314#else
1315          agents => trf_agents
1316#endif
1317
1318#if defined( __netcdf )
1319!
1320!--       Update maximum number of agents
1321          maximum_number_of_agents = MAX(maximum_number_of_agents, out_noa)
1322!
1323!--       Output in netCDF format
1324          IF ( ftest ) THEN
1325!
1326!--          First, define size of agent number dimension from amount of agents
1327!--          released, release interval, time of agent simulation and max
1328!--          age of agents
1329             dim_size_agtnum = MIN( MIN( multi_agent_system_end, end_time )    &
1330                                       - multi_agent_system_start,             &
1331                                    agent_maximum_age)
1332
1333             DO ii = 1, number_of_agent_groups
1334                dim_size_agtnum = dim_size_agtnum                              &
1335                                + (FLOOR( ( asr(ii)-asl(ii) ) / adx(ii) ) + 1) &
1336                                * (FLOOR( ( asn(ii)-ass(ii) ) / ady(ii) ) + 1) &
1337                                * (FLOOR( dim_size_agtnum / dt_arel )     + 1) &
1338                                * dim_size_factor_agtnum
1339                dim_size_agtnum = MIN( dim_size_agtnum, dim_size_agtnum_manual )
1340             ENDDO
1341             CALL check_open( 118 )
1342          ENDIF
1343
1344!
1345!--       Update the NetCDF time axis
1346          agt_time_count = agt_time_count + 1
1347
1348          IF ( .NOT. agt_dimension_exceeded ) THEN
1349!
1350!--          if number of agents to be output exceeds dimension, set flag and
1351!--          print warning
1352             IF ( out_noa > dim_size_agtnum ) THEN
1353
1354                agt_dimension_exceeded = .TRUE.
1355                WRITE(message_string,'(A,F11.1,2(A,I8))')                      &
1356                                'Number of agents exceeds agent dimension.' // &
1357                                '&Starting at time_since_reference_point = ',  &
1358                                time_since_reference_point,                    &
1359                                ' s, &data may be missing.'//                  &
1360                                '&Number of agents:     ', out_noa,            &
1361                                '&Agent dimension size: ', dim_size_agtnum
1362
1363                CALL message( 'mas_data_output_agents',                        &
1364                              'PA0420', 0, 1, 0, 6, 0 )
1365
1366             ENDIF
1367          ENDIF
1368
1369!
1370!--       reduce number of output agents to dimension size, if necessary
1371          IF ( agt_dimension_exceeded ) THEN
1372
1373             out_noa = MIN( out_noa, dim_size_agtnum )
1374
1375          ENDIF
1376
1377          nc_stat = NF90_PUT_VAR( id_set_agt, id_var_time_agt,                 &
1378                                  (/ time_since_reference_point + agent_substep_time /),            &
1379                                  start = (/ agt_time_count /),                &
1380                                  count = (/ 1 /) )
1381          CALL netcdf_handle_error( 'mas_data_output_agents', 1 )
1382
1383!
1384!--       Output agent attributes
1385
1386          nc_stat = NF90_PUT_VAR( id_set_agt, id_var_agt(1), agents%id,        &
1387                                  start = (/ 1, agt_time_count /),             &
1388                                  count = (/ out_noa /) )
1389          CALL netcdf_handle_error( 'mas_data_output_agents', 2 )
1390 
1391          nc_stat = NF90_PUT_VAR( id_set_agt, id_var_agt(2), agents%x,         &
1392                                  start = (/ 1, agt_time_count /),             &
1393                                  count = (/ out_noa /) )
1394          CALL netcdf_handle_error( 'mas_data_output_agents', 3 )
1395
1396          nc_stat = NF90_PUT_VAR( id_set_agt, id_var_agt(3), agents%y,         &
1397                                  start = (/ 1, agt_time_count /),             &
1398                                  count = (/ out_noa /) )
1399          CALL netcdf_handle_error( 'mas_data_output_agents', 4 )
1400
1401          nc_stat = NF90_PUT_VAR( id_set_agt, id_var_agt(4), agents%windspeed, &
1402                                  start = (/ 1, agt_time_count /),             &
1403                                  count = (/ out_noa /) )
1404          CALL netcdf_handle_error( 'mas_data_output_agents', 5 )
1405
1406          nc_stat = NF90_PUT_VAR( id_set_agt, id_var_agt(5), agents%t,         &
1407                                  start = (/ 1, agt_time_count /),             &
1408                                  count = (/ out_noa /) )
1409          CALL netcdf_handle_error( 'mas_data_output_agents', 6 )
1410
1411          nc_stat = NF90_PUT_VAR( id_set_agt, id_var_agt(6), agents%group,     &
1412                                  start = (/ 1, agt_time_count /),             &
1413                                  count = (/ out_noa /) )
1414          CALL netcdf_handle_error( 'mas_data_output_agents', 7 )
1415          CALL cpu_log( log_point_s(17), 'mas_data_output', 'stop' )
1416
1417
1418!           nc_stat = NF90_PUT_VAR( id_set_agt, id_var_agt(6), agents%pm10,      &
1419!                                   start = (/ 1, agt_time_count /),             &
1420!                                   count = (/ out_noa /) )
1421!           CALL netcdf_handle_error( 'mas_data_output_agents', 8 )
1422!
1423!           nc_stat = NF90_PUT_VAR( id_set_agt, id_var_agt(7), agents%pm25,      &
1424!                                   start = (/ 1, agt_time_count /),             &
1425!                                   count = (/ out_noa /) )
1426!           CALL netcdf_handle_error( 'mas_data_output_agents', 9 )
1427!
1428!           nc_stat = NF90_PUT_VAR( id_set_agt, id_var_agt(8), agents%therm_comf,&
1429!                                   start = (/ 1, agt_time_count /),             &
1430!                                   count = (/ out_noa /) )
1431!
1432!           nc_stat = NF90_PUT_VAR( id_set_agt, id_var_agt(9), agents%uv,        &
1433!                                   start = (/ 1, agt_time_count /),             &
1434!                                   count = (/ out_noa /) )
1435!           CALL netcdf_handle_error( 'mas_data_output_agents', 10 )
1436
1437#endif
1438          agents => NULL()
1439#if defined( __parallel )
1440          IF ( ALLOCATED( out_agents ) ) DEALLOCATE( out_agents )
1441#endif
1442       ELSE
1443          CALL cpu_log( log_point_s(17), 'mas_data_output', 'stop' )
1444       ENDIF
1445
1446       IF ( ALLOCATED( trf_agents ) ) DEALLOCATE( trf_agents )
1447
1448    END SUBROUTINE mas_data_output_agents
1449
1450!------------------------------------------------------------------------------!
1451! Description:
1452! ------------
1453!> If an agent moves from one processor to another, this subroutine moves
1454!> the corresponding elements from the agent arrays of the old grid cells
1455!> to the agent arrays of the new grid cells.
1456!------------------------------------------------------------------------------!
1457    SUBROUTINE mas_eh_add_agents_to_gridcell (agent_array)
1458
1459       IMPLICIT NONE
1460
1461       INTEGER(iwp) ::  aindex !< dummy argument for new number of agents per grid box
1462       INTEGER(iwp) ::  ip     !< grid index (x) of agent
1463       INTEGER(iwp) ::  jp     !< grid index (x) of agent
1464       INTEGER(iwp) ::  n      !< index variable of agent
1465
1466       LOGICAL ::  pack_done !< flag to indicate that packing is done
1467
1468       TYPE(agent_type), DIMENSION(:), INTENT(IN)  ::  agent_array !< new agents in a grid box
1469       TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  temp_ns     !< temporary agent array for reallocation
1470
1471       pack_done     = .FALSE.
1472
1473       DO n = 1, SIZE(agent_array)
1474
1475          IF ( .NOT. agent_array(n)%agent_mask )  CYCLE
1476
1477          ip = agent_array(n)%x * ddx
1478          jp = agent_array(n)%y * ddy
1479
1480          IF ( ip >= nxl  .AND.  ip <= nxr  .AND.                              &
1481               jp >= nys  .AND.  jp <= nyn )  &
1482          THEN ! agent stays on processor
1483             number_of_agents = agt_count(jp,ip)
1484             agents => grid_agents(jp,ip)%agents(1:number_of_agents)
1485
1486             aindex = agt_count(jp,ip)+1
1487             IF( aindex > SIZE(grid_agents(jp,ip)%agents) )  THEN
1488                IF ( pack_done )  THEN
1489                   CALL mas_eh_realloc_agents_array (ip,jp)
1490                ELSE
1491                   CALL mas_ps_pack
1492                   agt_count(jp,ip) = number_of_agents
1493                   aindex = agt_count(jp,ip)+1
1494                   IF ( aindex > SIZE(grid_agents(jp,ip)%agents) )  THEN
1495                      CALL mas_eh_realloc_agents_array (ip,jp)
1496                   ENDIF
1497                   pack_done = .TRUE.
1498                ENDIF
1499             ENDIF
1500             grid_agents(jp,ip)%agents(aindex) = agent_array(n)
1501             agt_count(jp,ip) = aindex
1502          ELSE
1503             IF ( jp <= nys - 1 )  THEN
1504                nr_move_south = nr_move_south+1
1505!
1506!--             Before agent information is swapped to exchange-array, check
1507!--             if enough memory is allocated. If required, reallocate exchange
1508!--             array.
1509                IF ( nr_move_south > SIZE(move_also_south) )  THEN
1510!
1511!--                At first, allocate further temporary array to swap agent
1512!--                information.
1513                   ALLOCATE( temp_ns(SIZE(move_also_south)+NR_2_direction_move))
1514                   temp_ns(1:nr_move_south-1) = move_also_south                &
1515                                                (1:nr_move_south-1)
1516                   DEALLOCATE( move_also_south )
1517                   ALLOCATE( move_also_south(SIZE(temp_ns)) )
1518                   move_also_south(1:nr_move_south-1) = temp_ns                &
1519                                                        (1:nr_move_south-1)
1520                   DEALLOCATE( temp_ns )
1521
1522                ENDIF
1523
1524                move_also_south(nr_move_south) = agent_array(n)
1525
1526                IF ( jp == -1 )  THEN
1527!
1528!--                Apply boundary condition along y
1529                   IF ( ibc_mas_ns == 0 )  THEN
1530                      move_also_south(nr_move_south)%y =                       &
1531                                         move_also_south(nr_move_south)%y      &
1532                                       + ( ny + 1 ) * dy
1533                      move_also_south(nr_move_south)%origin_y =                &
1534                                       move_also_south(nr_move_south)%origin_y &
1535                                       + ( ny + 1 ) * dy
1536                   ELSEIF ( ibc_mas_ns == 1 )  THEN
1537!
1538!--                   Agent absorption
1539                      move_also_south(nr_move_south)%agent_mask = .FALSE.
1540                      deleted_agents = deleted_agents + 1
1541
1542                   ENDIF
1543                ENDIF
1544             ELSEIF ( jp >= nyn+1 )  THEN
1545                nr_move_north = nr_move_north+1
1546!
1547!--             Before agent information is swapped to exchange-array, check
1548!--             if enough memory is allocated. If required, reallocate exchange
1549!--             array.
1550                IF ( nr_move_north > SIZE(move_also_north) )  THEN
1551!
1552!--                At first, allocate further temporary array to swap agent
1553!--                information.
1554                   ALLOCATE( temp_ns(SIZE(move_also_north)+NR_2_direction_move))
1555                   temp_ns(1:nr_move_north-1) =                                &
1556                                move_also_south(1:nr_move_north-1)
1557                   DEALLOCATE( move_also_north )
1558                   ALLOCATE( move_also_north(SIZE(temp_ns)) )
1559                   move_also_north(1:nr_move_north-1) =                        &
1560                               temp_ns(1:nr_move_north-1)
1561                   DEALLOCATE( temp_ns )
1562
1563                ENDIF
1564
1565                move_also_north(nr_move_north) = agent_array(n)
1566                IF ( jp == ny+1 )  THEN
1567!
1568!--                Apply boundary condition along y
1569                   IF ( ibc_mas_ns == 0 )  THEN
1570
1571                      move_also_north(nr_move_north)%y =                       &
1572                         move_also_north(nr_move_north)%y                      &
1573                       - ( ny + 1 ) * dy
1574                      move_also_north(nr_move_north)%origin_y =                &
1575                         move_also_north(nr_move_north)%origin_y               &
1576                       - ( ny + 1 ) * dy
1577                   ELSEIF ( ibc_mas_ns == 1 )  THEN
1578!
1579!--                   Agent absorption
1580                      move_also_north(nr_move_north)%agent_mask = .FALSE.
1581                      deleted_agents = deleted_agents + 1
1582
1583                   ENDIF
1584                ENDIF
1585             ENDIF
1586          ENDIF
1587       ENDDO
1588
1589       RETURN
1590
1591    END SUBROUTINE mas_eh_add_agents_to_gridcell
1592
1593!------------------------------------------------------------------------------!
1594! Description:
1595! ------------
1596!> After ghost layer agents have been received from neighboring PEs, this
1597!> subroutine sorts them into the corresponding grid cells
1598!------------------------------------------------------------------------------!
1599    SUBROUTINE mas_eh_add_ghost_agents_to_gridcell (agent_array)
1600
1601       IMPLICIT NONE
1602
1603       INTEGER(iwp) ::  ip     !< grid index (x) of agent
1604       INTEGER(iwp) ::  jp     !< grid index (x) of agent
1605       INTEGER(iwp) ::  n      !< index variable of agent
1606       INTEGER(iwp) ::  aindex !< dummy argument for new number of agents per grid box
1607
1608       LOGICAL ::  pack_done !< flag to indicate that packing is done
1609
1610       TYPE(agent_type), DIMENSION(:), INTENT(IN)  ::  agent_array !< new agents in a grid box
1611
1612       pack_done     = .FALSE.
1613
1614       DO n = 1, SIZE(agent_array)
1615
1616          IF ( .NOT. agent_array(n)%agent_mask )  CYCLE
1617
1618          ip = agent_array(n)%x * ddx
1619          jp = agent_array(n)%y * ddy
1620
1621          IF ( ip < nxl  .OR.  ip > nxr  .OR.  jp < nys  .OR.  jp > nyn ) THEN
1622             number_of_agents = agt_count(jp,ip)
1623             agents => grid_agents(jp,ip)%agents(1:number_of_agents)
1624
1625             aindex = agt_count(jp,ip)+1
1626             IF( aindex > SIZE(grid_agents(jp,ip)%agents) )  THEN
1627                IF ( pack_done )  THEN
1628                   CALL mas_eh_realloc_agents_array (ip,jp)
1629                ELSE
1630                   CALL mas_ps_pack
1631                   agt_count(jp,ip) = number_of_agents
1632                   aindex = agt_count(jp,ip)+1
1633                   IF ( aindex > SIZE(grid_agents(jp,ip)%agents) )  THEN
1634                      CALL mas_eh_realloc_agents_array (ip,jp)
1635                   ENDIF
1636                   pack_done = .TRUE.
1637                ENDIF
1638             ENDIF
1639             grid_agents(jp,ip)%agents(aindex) = agent_array(n)
1640             agt_count(jp,ip) = aindex
1641          ENDIF
1642       ENDDO
1643    END SUBROUTINE mas_eh_add_ghost_agents_to_gridcell
1644
1645!------------------------------------------------------------------------------!
1646! Description:
1647! ------------
1648!> Resizing of agent arrays
1649!------------------------------------------------------------------------------!
1650    SUBROUTINE mas_eh_dealloc_agents_array
1651
1652       IMPLICIT NONE
1653
1654       INTEGER(iwp) ::  i         !< grid index (x) of agent
1655       INTEGER(iwp) ::  j         !< grid index (y) of agent
1656       INTEGER(iwp) ::  old_size  !< old array size
1657       INTEGER(iwp) ::  new_size  !< new array size
1658       INTEGER(iwp) ::  noa       !< number of agents
1659
1660       LOGICAL ::  dealloc  !< flag that indicates if reallocation is necessary
1661
1662       TYPE(agent_type), DIMENSION(10) ::  tmp_agents_s !< temporary static agent array
1663
1664       TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  tmp_agents_d !< temporary dynamic agent array
1665
1666       DO  i = nxlg, nxrg
1667          DO  j = nysg, nyng
1668!
1669!--          Determine number of active agents
1670             noa = agt_count(j,i)
1671!
1672!--          Determine allocated memory size
1673             old_size = SIZE( grid_agents(j,i)%agents )
1674!
1675!--          Check for large unused memory
1676             dealloc = ( ( noa < min_nr_agent .AND. old_size  > min_nr_agent ) &
1677                    .OR. ( noa > min_nr_agent .AND. old_size - noa *           &
1678                         ( 1.0_wp + 0.01_wp * alloc_factor_mas ) > 0.0_wp ) )
1679!
1680!--          If large unused memory was found, resize the corresponding array
1681             IF ( dealloc )  THEN
1682                IF ( noa < min_nr_agent )  THEN
1683                   new_size = min_nr_agent
1684                ELSE
1685                   new_size = INT( noa * ( 1.0_wp +                            &
1686                                            0.01_wp * alloc_factor_mas ) )
1687                ENDIF
1688
1689                IF ( noa <= 10 )  THEN
1690
1691                   tmp_agents_s(1:noa) = grid_agents(j,i)%agents(1:noa)
1692
1693                   DEALLOCATE(grid_agents(j,i)%agents)
1694                   ALLOCATE(grid_agents(j,i)%agents(1:new_size))
1695
1696                   grid_agents(j,i)%agents(1:noa)          = tmp_agents_s(1:noa)
1697                   grid_agents(j,i)%agents(noa+1:new_size) = zero_agent
1698
1699                ELSE
1700
1701                   ALLOCATE(tmp_agents_d(noa))
1702                   tmp_agents_d(1:noa) = grid_agents(j,i)%agents(1:noa)
1703
1704                   DEALLOCATE(grid_agents(j,i)%agents)
1705                   ALLOCATE(grid_agents(j,i)%agents(new_size))
1706
1707                   grid_agents(j,i)%agents(1:noa)          = tmp_agents_d(1:noa)
1708                   grid_agents(j,i)%agents(noa+1:new_size) = zero_agent
1709
1710                   DEALLOCATE(tmp_agents_d)
1711
1712                ENDIF
1713
1714             ENDIF
1715          ENDDO
1716       ENDDO
1717
1718    END SUBROUTINE mas_eh_dealloc_agents_array
1719
1720!------------------------------------------------------------------------------!
1721! Description:
1722! ------------
1723!> Exchange between subdomains.
1724!> As soon as one agent has moved beyond the boundary of the domain, it
1725!> is included in the relevant transfer arrays and marked for subsequent
1726!> deletion on this PE.
1727!> First sweep for crossings in x direction. Find out first the number of
1728!> agents to be transferred and allocate temporary arrays needed to store
1729!> them.
1730!> For a one-dimensional decomposition along y, no transfer is necessary,
1731!> because the agent remains on the PE, but the agent coordinate has to
1732!> be adjusted.
1733!------------------------------------------------------------------------------!
1734    SUBROUTINE mas_eh_exchange_horiz
1735
1736       IMPLICIT NONE
1737
1738       INTEGER(iwp) ::  i                !< grid index (x) of agent positition
1739       INTEGER(iwp) ::  ip               !< index variable along x
1740       INTEGER(iwp) ::  j                !< grid index (y) of agent positition
1741       INTEGER(iwp) ::  jp               !< index variable along y
1742       INTEGER(iwp) ::  n                !< agent index variable
1743       INTEGER(iwp) ::  par_size         !< Agent size in bytes
1744       INTEGER(iwp) ::  trla_count       !< number of agents send to left PE
1745       INTEGER(iwp) ::  trla_count_recv  !< number of agents receive from right PE
1746       INTEGER(iwp) ::  trna_count       !< number of agents send to north PE
1747       INTEGER(iwp) ::  trna_count_recv  !< number of agents receive from south PE
1748       INTEGER(iwp) ::  trra_count       !< number of agents send to right PE
1749       INTEGER(iwp) ::  trra_count_recv  !< number of agents receive from left PE
1750       INTEGER(iwp) ::  trsa_count       !< number of agents send to south PE
1751       INTEGER(iwp) ::  trsa_count_recv  !< number of agents receive from north PE
1752
1753       TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  rvla  !< agents received from right PE
1754       TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  rvna  !< agents received from south PE
1755       TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  rvra  !< agents received from left PE
1756       TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  rvsa  !< agents received from north PE
1757       TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  trla  !< agents send to left PE
1758       TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  trna  !< agents send to north PE
1759       TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  trra  !< agents send to right PE
1760       TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  trsa  !< agents send to south PE
1761
1762#if defined( __parallel )
1763
1764!
1765!--    Exchange between subdomains.
1766!--    As soon as one agent has moved beyond the boundary of the domain, it
1767!--    is included in the relevant transfer arrays and marked for subsequent
1768!--    deletion on this PE.
1769!--    First sweep for crossings in x direction. Find out first the number of
1770!--    agents to be transferred and allocate temporary arrays needed to store
1771!--    them.
1772!--    For a one-dimensional decomposition along y, no transfer is necessary,
1773!--    because the agent remains on the PE, but the agent coordinate has to
1774!--    be adjusted.
1775       trla_count  = 0
1776       trra_count  = 0
1777
1778       trla_count_recv   = 0
1779       trra_count_recv   = 0
1780
1781       IF ( pdims(1) /= 1 )  THEN
1782!
1783!--       First calculate the storage necessary for sending and receiving the data.
1784!--       Compute only first (nxl) and last (nxr) loop iterration.
1785          DO  ip = nxl, nxr, nxr - nxl
1786             DO  jp = nys, nyn
1787
1788                number_of_agents = agt_count(jp,ip)
1789                IF ( number_of_agents <= 0 )  CYCLE
1790                agents => grid_agents(jp,ip)%agents(1:number_of_agents)
1791                DO  n = 1, number_of_agents
1792                   IF ( agents(n)%agent_mask )  THEN
1793                      i = agents(n)%x * ddx
1794!
1795!--                   Above calculation does not work for indices less than zero
1796                      IF ( agents(n)%x < 0.0_wp )  i = -1
1797
1798                      IF ( i < nxl )  THEN
1799                         trla_count = trla_count + 1
1800                      ELSEIF ( i > nxr )  THEN
1801                         trra_count = trra_count + 1
1802                      ENDIF
1803                   ENDIF
1804                ENDDO
1805
1806             ENDDO
1807          ENDDO
1808
1809          IF ( trla_count  == 0 )  trla_count  = 1
1810          IF ( trra_count  == 0 )  trra_count  = 1
1811
1812          ALLOCATE( trla(trla_count), trra(trra_count) )
1813
1814          trla = zero_agent
1815          trra = zero_agent
1816
1817          trla_count  = 0
1818          trra_count  = 0
1819
1820       ENDIF
1821!
1822!--    Compute only first (nxl) and last (nxr) loop iterration
1823       DO  ip = nxl, nxr, nxr-nxl
1824          DO  jp = nys, nyn
1825             number_of_agents = agt_count(jp,ip)
1826             IF ( number_of_agents <= 0 ) CYCLE
1827             agents => grid_agents(jp,ip)%agents(1:number_of_agents)
1828             DO  n = 1, number_of_agents
1829!
1830!--             Only those agents that have not been marked as 'deleted' may
1831!--             be moved.
1832                IF ( agents(n)%agent_mask )  THEN
1833
1834                   i = agents(n)%x * ddx
1835!
1836!--                Above calculation does not work for indices less than zero
1837                   IF ( agents(n)%x < 0.0_wp )  i = -1
1838
1839                   IF ( i <  nxl )  THEN
1840                      IF ( i < 0 )  THEN
1841!
1842!--                      Apply boundary condition along x
1843                         IF ( ibc_mas_lr == 0 )  THEN
1844!
1845!--                         Cyclic condition
1846                            IF ( pdims(1) == 1 )  THEN
1847                               agents(n)%x        = ( nx + 1 ) * dx +          &
1848                                                    agents(n)%x
1849                               agents(n)%origin_x = ( nx + 1 ) * dx +          &
1850                                                    agents(n)%origin_x
1851                            ELSE
1852                               trla_count         = trla_count + 1
1853                               trla(trla_count)   = agents(n)
1854                               trla(trla_count)%x = ( nx + 1 ) * dx +          &
1855                                                    trla(trla_count)%x
1856                               trla(trla_count)%origin_x =                     &
1857                                                trla(trla_count)%origin_x +    &
1858                                                ( nx + 1 ) * dx
1859                               agents(n)%agent_mask  = .FALSE.
1860                               deleted_agents = deleted_agents + 1
1861
1862                               IF ( trla(trla_count)%x >=                      &
1863                                        (nx + 1)* dx - 1.0E-12_wp )            &
1864                               THEN
1865                                  trla(trla_count)%x = trla(trla_count)%x -    &
1866                                                   1.0E-10_wp
1867                                  trla(trla_count)%origin_x =                  &
1868                                                   trla(trla_count)%origin_x - 1
1869                               ENDIF
1870
1871                            ENDIF
1872
1873                         ELSEIF ( ibc_mas_lr == 1 )  THEN
1874!
1875!--                         Agent absorption
1876                            agents(n)%agent_mask = .FALSE.
1877                            deleted_agents = deleted_agents + 1
1878
1879                         ENDIF
1880                      ELSE
1881!
1882!--                      Store agent data in the transfer array, which will be
1883!--                      send to the neighbouring PE
1884                         trla_count = trla_count + 1
1885                         trla(trla_count) = agents(n)
1886                         agents(n)%agent_mask = .FALSE.
1887                         deleted_agents = deleted_agents + 1
1888
1889                      ENDIF
1890
1891                   ELSEIF ( i > nxr )  THEN
1892                      IF ( i > nx )  THEN
1893!
1894!--                      Apply boundary condition along x
1895                         IF ( ibc_mas_lr == 0 )  THEN
1896!
1897!--                         Cyclic condition
1898                            IF ( pdims(1) == 1 )  THEN
1899                               agents(n)%x = agents(n)%x - ( nx + 1 ) * dx
1900                               agents(n)%origin_x = agents(n)%origin_x - &
1901                               ( nx + 1 ) * dx
1902                            ELSE
1903                               trra_count = trra_count + 1
1904                               trra(trra_count) = agents(n)
1905                               trra(trra_count)%x = trra(trra_count)%x -       &
1906                                                    ( nx + 1 ) * dx
1907                               trra(trra_count)%origin_x =                     &
1908                                                   trra(trra_count)%origin_x - &
1909                                                   ( nx + 1 ) * dx
1910                               agents(n)%agent_mask = .FALSE.
1911                               deleted_agents = deleted_agents + 1
1912
1913                            ENDIF
1914
1915                         ELSEIF ( ibc_mas_lr == 1 )  THEN
1916!
1917!--                         Agent absorption
1918                            agents(n)%agent_mask = .FALSE.
1919                            deleted_agents = deleted_agents + 1
1920
1921                         ENDIF
1922                      ELSE
1923!
1924!--                      Store agent data in the transfer array, which will be send
1925!--                      to the neighbouring PE
1926                         trra_count = trra_count + 1
1927                         trra(trra_count) = agents(n)
1928                         agents(n)%agent_mask = .FALSE.
1929                         deleted_agents = deleted_agents + 1
1930
1931                      ENDIF
1932
1933                   ENDIF
1934                ENDIF
1935
1936             ENDDO
1937          ENDDO
1938       ENDDO
1939
1940!
1941!--    Allocate arrays required for north-south exchange, as these
1942!--    are used directly after agents are exchange along x-direction.
1943       ALLOCATE( move_also_north(1:NR_2_direction_move) )
1944       ALLOCATE( move_also_south(1:NR_2_direction_move) )
1945
1946       nr_move_north = 0
1947       nr_move_south = 0
1948!
1949!--    Send left boundary, receive right boundary (but first exchange how many
1950!--    and chec if agent storage must be extended)
1951       IF ( pdims(1) /= 1 )  THEN
1952
1953          CALL MPI_SENDRECV( trla_count,      1, MPI_INTEGER, pleft,  0, &
1954                             trra_count_recv, 1, MPI_INTEGER, pright, 0, &
1955                             comm2d, status, ierr )
1956
1957          ALLOCATE(rvra(MAX(1,trra_count_recv)))
1958!
1959!--       This MPI_SENDRECV should work even with odd mixture on 32 and 64 Bit
1960!--       variables in structure agent_type (due to the calculation of par_size)
1961          par_size = STORAGE_SIZE(trla(1))/8
1962          CALL MPI_SENDRECV( trla, max(1,trla_count)*par_size, MPI_BYTE, pleft,&
1963                    1, rvra, max(1,trra_count_recv)*par_size, MPI_BYTE, pright,&
1964                             1, comm2d, status, ierr )
1965
1966          IF ( trra_count_recv > 0 ) THEN
1967             CALL mas_eh_add_agents_to_gridcell(rvra(1:trra_count_recv))
1968          ENDIF
1969
1970          DEALLOCATE(rvra)
1971
1972!
1973!--       Send right boundary, receive left boundary
1974          CALL MPI_SENDRECV( trra_count,      1, MPI_INTEGER, pright, 0,       &
1975                             trla_count_recv, 1, MPI_INTEGER, pleft,  0,       &
1976                             comm2d, status, ierr )
1977
1978          ALLOCATE(rvla(MAX(1,trla_count_recv)))
1979!
1980!--       This MPI_SENDRECV should work even with odd mixture on 32 and 64 Bit
1981!--       variables in structure agent_type (due to the calculation of par_size)
1982          par_size = STORAGE_SIZE(trra(1))/8
1983          CALL MPI_SENDRECV( trra, max(1,trra_count)*par_size, MPI_BYTE,       &
1984                             pright, 1, rvla,                                  &
1985                             max(1,trla_count_recv)*par_size, MPI_BYTE,        &
1986                             pleft, 1, comm2d, status, ierr )
1987
1988          IF ( trla_count_recv > 0 ) THEN
1989             CALL mas_eh_add_agents_to_gridcell(rvla(1:trla_count_recv))
1990          ENDIF
1991
1992          DEALLOCATE( rvla )
1993          DEALLOCATE( trla, trra )
1994
1995       ENDIF
1996
1997!
1998!--    Check whether agents have crossed the boundaries in y direction. Note
1999!--    that this case can also apply to agents that have just been received
2000!--    from the adjacent right or left PE.
2001!--    Find out first the number of agents to be transferred and allocate
2002!--    temporary arrays needed to store them.
2003!--    For a one-dimensional decomposition along y, no transfer is necessary,
2004!--    because the agent remains on the PE.
2005       trsa_count  = nr_move_south
2006       trna_count  = nr_move_north
2007
2008       trsa_count_recv   = 0
2009       trna_count_recv   = 0
2010
2011       IF ( pdims(2) /= 1 )  THEN
2012!
2013!--       First calculate the storage necessary for sending and receiving the
2014!--       data
2015          DO  ip = nxl, nxr
2016             DO  jp = nys, nyn, nyn-nys    !compute only first (nys) and last (nyn) loop iterration
2017                number_of_agents = agt_count(jp,ip)
2018                IF ( number_of_agents <= 0 )  CYCLE
2019                agents => grid_agents(jp,ip)%agents(1:number_of_agents)
2020                DO  n = 1, number_of_agents
2021                   IF ( agents(n)%agent_mask )  THEN
2022                      j = agents(n)%y * ddy
2023!
2024!--                   Above calculation does not work for indices less than zero
2025                      IF ( agents(n)%y < 0.0_wp )  j = -1
2026
2027                      IF ( j < nys )  THEN
2028                         trsa_count = trsa_count + 1
2029                      ELSEIF ( j > nyn )  THEN
2030                         trna_count = trna_count + 1
2031                      ENDIF
2032                   ENDIF
2033                ENDDO
2034             ENDDO
2035          ENDDO
2036
2037          IF ( trsa_count  == 0 )  trsa_count  = 1
2038          IF ( trna_count  == 0 )  trna_count  = 1
2039
2040          ALLOCATE( trsa(trsa_count), trna(trna_count) )
2041
2042          trsa = zero_agent
2043          trna = zero_agent
2044
2045          trsa_count  = nr_move_south
2046          trna_count  = nr_move_north
2047
2048          trsa(1:nr_move_south) = move_also_south(1:nr_move_south)
2049          trna(1:nr_move_north) = move_also_north(1:nr_move_north)
2050
2051       ENDIF
2052
2053       DO  ip = nxl, nxr
2054          DO  jp = nys, nyn, nyn-nys ! compute only first (nys) and last (nyn) loop iterration
2055             number_of_agents = agt_count(jp,ip)
2056             IF ( number_of_agents <= 0 )  CYCLE
2057             agents => grid_agents(jp,ip)%agents(1:number_of_agents)
2058             DO  n = 1, number_of_agents
2059!
2060!--             Only those agents that have not been marked as 'deleted' may
2061!--             be moved.
2062                IF ( agents(n)%agent_mask )  THEN
2063
2064                   j = agents(n)%y * ddy
2065!
2066!--                Above calculation does not work for indices less than zero
2067                   IF ( agents(n)%y < 0.0_wp * dy )  j = -1
2068
2069                   IF ( j < nys )  THEN
2070                      IF ( j < 0 )  THEN
2071!
2072!--                      Apply boundary condition along y
2073                         IF ( ibc_mas_ns == 0 )  THEN
2074!
2075!--                         Cyclic condition
2076                            IF ( pdims(2) == 1 )  THEN
2077                               agents(n)%y = ( ny + 1 ) * dy + agents(n)%y
2078                               agents(n)%origin_y = ( ny + 1 ) * dy +          &
2079                                                     agents(n)%origin_y
2080                            ELSE
2081                               trsa_count         = trsa_count + 1
2082                               trsa(trsa_count)   = agents(n)
2083                               trsa(trsa_count)%y = ( ny + 1 ) * dy +          &
2084                                                 trsa(trsa_count)%y
2085                               trsa(trsa_count)%origin_y =                     &
2086                                                  trsa(trsa_count)%origin_y    &
2087                                                + ( ny + 1 ) * dy
2088                               agents(n)%agent_mask = .FALSE.
2089                               deleted_agents = deleted_agents + 1
2090
2091                               IF ( trsa(trsa_count)%y >=                      &
2092                                                    (ny+1)* dy - 1.0E-12_wp )  &
2093                               THEN
2094                                  trsa(trsa_count)%y = trsa(trsa_count)%y -    &
2095                                                       1.0E-10_wp
2096                                  trsa(trsa_count)%origin_y =                  &
2097                                                  trsa(trsa_count)%origin_y - 1
2098                               ENDIF
2099
2100                            ENDIF
2101
2102                         ELSEIF ( ibc_mas_ns == 1 )  THEN
2103!
2104!--                         Agent absorption
2105                            agents(n)%agent_mask = .FALSE.
2106                            deleted_agents          = deleted_agents + 1
2107
2108                         ENDIF
2109                      ELSE
2110!
2111!--                      Store agent data in the transfer array, which will
2112!--                      be send to the neighbouring PE
2113                         trsa_count = trsa_count + 1
2114                         trsa(trsa_count) = agents(n)
2115                         agents(n)%agent_mask = .FALSE.
2116                         deleted_agents = deleted_agents + 1
2117
2118                      ENDIF
2119
2120                   ELSEIF ( j > nyn )  THEN
2121                      IF ( j > ny )  THEN
2122!
2123!--                      Apply boundary condition along y
2124                         IF ( ibc_mas_ns == 0 )  THEN
2125!
2126!--                         Cyclic condition
2127                            IF ( pdims(2) == 1 )  THEN
2128                               agents(n)%y        = agents(n)%y -              &
2129                                                    ( ny + 1 ) * dy
2130                               agents(n)%origin_y = agents(n)%origin_y -       &
2131                                                    ( ny + 1 ) * dy
2132                            ELSE
2133                               trna_count         = trna_count + 1
2134                               trna(trna_count)   = agents(n)
2135                               trna(trna_count)%y =                            &
2136                                          trna(trna_count)%y - ( ny + 1 ) * dy
2137                               trna(trna_count)%origin_y =                     &
2138                                         trna(trna_count)%origin_y -           &
2139                                         ( ny + 1 ) * dy
2140                               agents(n)%agent_mask = .FALSE.
2141                               deleted_agents          = deleted_agents + 1
2142                            ENDIF
2143
2144                         ELSEIF ( ibc_mas_ns == 1 )  THEN
2145!
2146!--                         Agent absorption
2147                            agents(n)%agent_mask = .FALSE.
2148                            deleted_agents = deleted_agents + 1
2149
2150                         ENDIF
2151                      ELSE
2152!
2153!--                      Store agent data in the transfer array, which will
2154!--                      be send to the neighbouring PE
2155                         trna_count = trna_count + 1
2156                         trna(trna_count) = agents(n)
2157                         agents(n)%agent_mask = .FALSE.
2158                         deleted_agents = deleted_agents + 1
2159
2160                      ENDIF
2161
2162                   ENDIF
2163                ENDIF
2164             ENDDO
2165          ENDDO
2166       ENDDO
2167
2168!
2169!--    Send front boundary, receive back boundary (but first exchange how many
2170!--    and chec if agent storage must be extended)
2171       IF ( pdims(2) /= 1 )  THEN
2172
2173          CALL MPI_SENDRECV( trsa_count,      1, MPI_INTEGER, psouth, 0,       &
2174                             trna_count_recv, 1, MPI_INTEGER, pnorth, 0,       &
2175                             comm2d, status, ierr )
2176
2177          ALLOCATE(rvna(MAX(1,trna_count_recv)))
2178!
2179!--       This MPI_SENDRECV should work even with odd mixture on 32 and 64 Bit
2180!--       variables in structure agent_type (due to the calculation of par_size)
2181          par_size = STORAGE_SIZE(trsa(1))/8
2182          CALL MPI_SENDRECV( trsa, trsa_count*par_size, MPI_BYTE,              &
2183                             psouth, 1, rvna,                                  &
2184                             trna_count_recv*par_size, MPI_BYTE, pnorth, 1,    &
2185                             comm2d, status, ierr )
2186
2187          IF ( trna_count_recv  > 0 ) THEN
2188             CALL mas_eh_add_agents_to_gridcell(rvna(1:trna_count_recv))
2189          ENDIF
2190
2191          DEALLOCATE(rvna)
2192
2193!
2194!--       Send back boundary, receive front boundary
2195          CALL MPI_SENDRECV( trna_count,      1, MPI_INTEGER, pnorth, 0,       &
2196                             trsa_count_recv, 1, MPI_INTEGER, psouth, 0,       &
2197                             comm2d, status, ierr )
2198
2199          ALLOCATE(rvsa(MAX(1,trsa_count_recv)))
2200!
2201!--       This MPI_SENDRECV should work even with odd mixture on 32 and 64 Bit
2202!--       variables in structure agent_type (due to the calculation of par_size)
2203          par_size = STORAGE_SIZE(trna(1))/8
2204          CALL MPI_SENDRECV( trna, trna_count*par_size, MPI_BYTE,              &
2205                             pnorth, 1, rvsa,                                  &
2206                             trsa_count_recv*par_size, MPI_BYTE, psouth, 1,    &
2207                             comm2d, status, ierr )
2208
2209          IF ( trsa_count_recv > 0 ) THEN
2210             CALL mas_eh_add_agents_to_gridcell(rvsa(1:trsa_count_recv))
2211          ENDIF
2212
2213          DEALLOCATE(rvsa)
2214
2215          number_of_agents = number_of_agents + trsa_count_recv
2216
2217          DEALLOCATE( trsa, trna )
2218
2219       ENDIF
2220
2221       DEALLOCATE( move_also_north )
2222       DEALLOCATE( move_also_south )
2223
2224#else
2225
2226       DO  ip = nxl, nxr, nxr-nxl
2227          DO  jp = nys, nyn
2228             number_of_agents = agt_count(jp,ip)
2229             IF ( number_of_agents <= 0 )  CYCLE
2230             agents => grid_agents(jp,ip)%agents(1:number_of_agents)
2231             DO  n = 1, number_of_agents
2232!
2233!--             Apply boundary conditions
2234                IF ( agents(n)%x < 0.0_wp )  THEN
2235
2236                   IF ( ibc_mas_lr == 0 )  THEN
2237!
2238!--                   Cyclic boundary. Relevant coordinate has to be changed.
2239                      agents(n)%x = ( nx + 1 ) * dx + agents(n)%x
2240                      agents(n)%origin_x = ( nx + 1 ) * dx + &
2241                                  agents(n)%origin_x
2242                   ELSEIF ( ibc_mas_lr == 1 )  THEN
2243!
2244!--                   Agent absorption
2245                      agents(n)%agent_mask = .FALSE.
2246                      deleted_agents = deleted_agents + 1
2247                   ENDIF
2248
2249                ELSEIF ( agents(n)%x >= ( nx + 1 ) * dx )  THEN
2250
2251                   IF ( ibc_mas_lr == 0 )  THEN
2252!
2253!--                   Cyclic boundary. Relevant coordinate has to be changed.
2254                      agents(n)%x = agents(n)%x - ( nx + 1 ) * dx
2255
2256                   ELSEIF ( ibc_mas_lr == 1 )  THEN
2257!
2258!--                   Agent absorption
2259                      agents(n)%agent_mask = .FALSE.
2260                      deleted_agents = deleted_agents + 1
2261                   ENDIF
2262
2263                ENDIF
2264             ENDDO
2265          ENDDO
2266       ENDDO
2267
2268       DO  ip = nxl, nxr
2269          DO  jp = nys, nyn, nyn-nys
2270             number_of_agents = agt_count(jp,ip)
2271             IF ( number_of_agents <= 0 )  CYCLE
2272             agents => grid_agents(jp,ip)%agents(1:number_of_agents)
2273             DO  n = 1, number_of_agents
2274
2275                IF ( agents(n)%y < 0.0_wp )  THEN
2276
2277                   IF ( ibc_mas_ns == 0 )  THEN
2278!
2279!--                   Cyclic boundary. Relevant coordinate has to be changed.
2280                      agents(n)%y = ( ny + 1 ) * dy + agents(n)%y
2281                      agents(n)%origin_y = ( ny + 1 ) * dy + &
2282                           agents(n)%origin_y
2283
2284                   ELSEIF ( ibc_mas_ns == 1 )  THEN
2285!
2286!--                   Agent absorption
2287                      agents(n)%agent_mask = .FALSE.
2288                      deleted_agents = deleted_agents + 1
2289                   ENDIF
2290
2291                ELSEIF ( agents(n)%y >= ( ny + 0.5_wp ) * dy )  THEN
2292
2293                   IF ( ibc_mas_ns == 0 )  THEN
2294!
2295!--                   Cyclic boundary. Relevant coordinate has to be changed.
2296                      agents(n)%y = agents(n)%y - ( ny + 1 ) * dy
2297
2298                   ELSEIF ( ibc_mas_ns == 1 )  THEN
2299!
2300!--                   Agent absorption
2301                      agents(n)%agent_mask = .FALSE.
2302                      deleted_agents = deleted_agents + 1
2303                   ENDIF
2304
2305                ENDIF
2306
2307             ENDDO
2308          ENDDO
2309       ENDDO
2310#endif
2311
2312!
2313!--    Accumulate the number of agents transferred between the subdomains)
2314       CALL mas_eh_ghost_exchange
2315
2316    END SUBROUTINE mas_eh_exchange_horiz
2317
2318!------------------------------------------------------------------------------!
2319! Description:
2320! ------------
2321!> Sends the agents from the three gridcells closest to the
2322!> north/south/left/right border of a PE to the corresponding neighbors ghost
2323!> layer (which is three grid boxes deep)
2324!------------------------------------------------------------------------------!
2325    SUBROUTINE mas_eh_ghost_exchange
2326
2327       IMPLICIT NONE
2328
2329#if defined( __parallel )
2330
2331       INTEGER(iwp) ::  ip          !< index variable along x
2332       INTEGER(iwp) ::  jp          !< index variable along y
2333       INTEGER(iwp) ::  agt_size    !< Bit size of agent datatype
2334       INTEGER(iwp) ::  ghla_count  !< ghost points left agent
2335       INTEGER(iwp) ::  ghna_count  !< ghost points north agent
2336       INTEGER(iwp) ::  ghra_count  !< ghost points right agent
2337       INTEGER(iwp) ::  ghsa_count  !< ghost points south agent
2338
2339       LOGICAL ::  ghla_empty      !< ghost points left agent
2340       LOGICAL ::  ghla_empty_rcv  !< ghost points left agent
2341       LOGICAL ::  ghna_empty      !< ghost points north agent
2342       LOGICAL ::  ghna_empty_rcv  !< ghost points north agent
2343       LOGICAL ::  ghra_empty      !< ghost points right agent
2344       LOGICAL ::  ghra_empty_rcv  !< ghost points right agent
2345       LOGICAL ::  ghsa_empty      !< ghost points south agent
2346       LOGICAL ::  ghsa_empty_rcv  !< ghost points south agent
2347
2348       TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  ghla  !< agents received from right PE
2349       TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  ghna  !< agents received from south PE
2350       TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  ghra  !< agents received from left PE
2351       TYPE(agent_type), DIMENSION(:), ALLOCATABLE ::  ghsa  !< agents received from north PE
2352
2353       ghla_empty = .TRUE.
2354       ghna_empty = .TRUE.
2355       ghra_empty = .TRUE.
2356       ghsa_empty = .TRUE.
2357!
2358!--    reset ghost layer
2359       DO ip = nxlg, nxl-1
2360          DO jp = nysg, nyng
2361             agt_count(jp,ip) = 0
2362          ENDDO
2363       ENDDO
2364       DO ip = nxr+1, nxrg
2365          DO jp = nysg, nyng
2366             agt_count(jp,ip) = 0
2367          ENDDO
2368       ENDDO
2369       DO ip = nxl, nxr
2370          DO jp = nysg, nys-1
2371             agt_count(jp,ip) = 0
2372          ENDDO
2373       ENDDO
2374       DO ip = nxl, nxr
2375          DO jp = nyn+1, nyng
2376             agt_count(jp,ip) = 0
2377          ENDDO
2378       ENDDO
2379!
2380!--    Transfer of agents from left to right and vice versa
2381       IF ( pdims(1) /= 1 )  THEN
2382!
2383!--       Reset left and right ghost layers
2384          ghla_count  = 0
2385          ghra_count  = 0
2386!
2387!--       First calculate the storage necessary for sending
2388!--       and receiving the data.
2389          ghla_count = SUM(agt_count(nys:nyn,nxl:nxl+2))
2390          ghra_count = SUM(agt_count(nys:nyn,nxr-2:nxr))
2391!
2392!--       No cyclic boundaries for agents
2393          IF ( nxl == 0 .OR. ghla_count == 0 ) THEN
2394             ghla_count = 1
2395          ELSE
2396             ghla_empty = .FALSE.
2397          ENDIF
2398          IF ( nxr == nx .OR. ghra_count == 0 ) THEN
2399             ghra_count = 1
2400          ELSE
2401             ghra_empty = .FALSE.
2402          ENDIF
2403          ALLOCATE( ghla(1:ghla_count), ghra(1:ghra_count) )
2404          ghla = zero_agent
2405          ghra = zero_agent
2406!
2407!--       Get all agents that will be sent left into one array
2408          ghla_count = 0
2409          IF ( nxl /= 0 ) THEN
2410             DO ip = nxl, nxl+2
2411                DO jp = nys, nyn
2412
2413                   number_of_agents = agt_count(jp,ip)
2414                   IF ( number_of_agents <= 0 )  CYCLE
2415                   ghla(ghla_count+1:ghla_count+number_of_agents)              &
2416                       = grid_agents(jp,ip)%agents(1:number_of_agents)
2417                   ghla_count = ghla_count + number_of_agents
2418
2419                ENDDO
2420             ENDDO
2421          ENDIF
2422          IF ( ghla_count == 0 )  ghla_count = 1
2423!
2424!--       Get all agents that will be sent right into one array
2425          ghra_count = 0
2426          IF ( nxr /= nx ) THEN
2427             DO ip = nxr-2, nxr
2428                DO jp = nys, nyn
2429
2430                   number_of_agents = agt_count(jp,ip)
2431                   IF ( number_of_agents <= 0 )  CYCLE
2432                   ghra(ghra_count+1:ghra_count+number_of_agents)              &
2433                       = grid_agents(jp,ip)%agents(1:number_of_agents)
2434                   ghra_count = ghra_count + number_of_agents
2435
2436                ENDDO
2437             ENDDO
2438          ENDIF
2439          IF ( ghra_count == 0 ) ghra_count = 1
2440!
2441!--       Send/receive number of agents that
2442!--       will be transferred to/from left/right neighbor
2443          CALL MPI_SENDRECV( ghla_count,      1, MPI_INTEGER, pleft,  0,       &
2444                             ghra_count_recv, 1, MPI_INTEGER, pright, 0,       &
2445                             comm2d, status, ierr )
2446          ALLOCATE ( agt_gh_r(1:ghra_count_recv) )
2447!
2448!--       Send/receive number of agents that
2449!--       will be transferred to/from right/left neighbor
2450          CALL MPI_SENDRECV( ghra_count,      1, MPI_INTEGER, pright,  0,      &
2451                             ghla_count_recv, 1, MPI_INTEGER, pleft,   0,      &
2452                             comm2d, status, ierr )
2453!
2454!--       Send/receive flag that indicates if there are actually any agents
2455!--       in ghost  layer
2456          CALL MPI_SENDRECV( ghla_empty,     1, MPI_LOGICAL, pleft, 1,         &
2457                             ghra_empty_rcv, 1, MPI_LOGICAL, pright,1,         &
2458                             comm2d, status, ierr )
2459          CALL MPI_SENDRECV( ghra_empty,     1, MPI_LOGICAL, pright,1,         &
2460                             ghla_empty_rcv, 1, MPI_LOGICAL, pleft, 1,         &
2461                             comm2d, status, ierr )
2462
2463
2464          ALLOCATE ( agt_gh_l(1:ghla_count_recv) )
2465!
2466!--       Get bit size of one agent
2467          agt_size = STORAGE_SIZE(zero_agent)/8
2468!
2469!--       Send/receive agents to/from left/right neighbor
2470          CALL MPI_SENDRECV( ghla,     ghla_count      * agt_size, MPI_BYTE,   &
2471                                pleft, 1,                                      &
2472                             agt_gh_r, ghra_count_recv * agt_size, MPI_BYTE,   &
2473                                pright,1,                                      &
2474                             comm2d, status, ierr )
2475!
2476!--       Send/receive agents to/from left/right neighbor
2477          CALL MPI_SENDRECV( ghra,     ghra_count      * agt_size, MPI_BYTE,   &
2478                                pright,1,                                      &
2479                             agt_gh_l, ghla_count_recv * agt_size, MPI_BYTE,   &
2480                                pleft, 1,                                      &
2481                             comm2d, status, ierr )
2482!
2483!--       If agents were received, add them to the respective ghost layer cells
2484          IF ( .NOT. ghra_empty_rcv ) THEN
2485             CALL mas_eh_add_ghost_agents_to_gridcell(agt_gh_r)
2486          ENDIF
2487
2488          IF ( .NOT. ghla_empty_rcv ) THEN
2489             CALL mas_eh_add_ghost_agents_to_gridcell(agt_gh_l)
2490          ENDIF
2491
2492          DEALLOCATE( ghla, ghra, agt_gh_l, agt_gh_r )
2493
2494       ENDIF
2495
2496!
2497!--    Transfer of agents from south to north and vice versa
2498       IF ( pdims(2) /= 1 )  THEN
2499!
2500!--       Reset south and north ghost layers
2501          ghsa_count  = 0
2502          ghna_count  = 0
2503!
2504!--       First calculate the storage necessary for sending
2505!--       and receiving the data.
2506          ghsa_count = SUM(agt_count(nys:nys+2,nxlg:nxrg))
2507          ghna_count = SUM(agt_count(nyn-2:nyn,nxlg:nxrg))
2508!
2509!--       No cyclic boundaries for agents
2510          IF ( nys == 0 .OR. ghsa_count == 0 ) THEN
2511             ghsa_count = 1
2512          ELSE
2513             ghsa_empty = .FALSE.
2514          ENDIF
2515          IF ( nyn == ny .OR. ghna_count == 0 ) THEN
2516             ghna_count = 1
2517          ELSE
2518             ghna_empty = .FALSE.
2519          ENDIF
2520          ALLOCATE( ghsa(1:ghsa_count), ghna(1:ghna_count) )
2521          ghsa = zero_agent
2522          ghna = zero_agent
2523!
2524!--       Get all agents that will be sent south into one array
2525          ghsa_count = 0
2526          IF ( nys /= 0 ) THEN
2527             DO ip = nxlg, nxrg
2528                DO jp = nys, nys+2
2529
2530                   number_of_agents = agt_count(jp,ip)
2531                   IF ( number_of_agents <= 0 )  CYCLE
2532                   ghsa(ghsa_count+1:ghsa_count+number_of_agents)              &
2533                       = grid_agents(jp,ip)%agents(1:number_of_agents)
2534                   ghsa_count = ghsa_count + number_of_agents
2535
2536                ENDDO
2537             ENDDO
2538          ENDIF
2539          IF ( ghsa_count == 0 )  ghsa_count = 1
2540!
2541!--       Get all agents that will be sent north into one array
2542          ghna_count = 0
2543          IF ( nyn /= ny ) THEN
2544             DO ip = nxlg, nxrg
2545                DO jp = nyn-2, nyn
2546
2547                   number_of_agents = agt_count(jp,ip)
2548                   IF ( number_of_agents <= 0 )  CYCLE
2549                   ghna(ghna_count+1:ghna_count+number_of_agents)              &
2550                       = grid_agents(jp,ip)%agents(1:number_of_agents)
2551                   ghna_count = ghna_count + number_of_agents
2552
2553                ENDDO
2554             ENDDO
2555          ENDIF
2556          IF ( ghna_count == 0 ) ghna_count = 1
2557!
2558!--       Send/receive number of agents that
2559!--       will be transferred to/from south/north neighbor
2560          CALL MPI_SENDRECV( ghsa_count, 1, MPI_INTEGER, psouth, 0,            &
2561                             ghna_count_recv,   1, MPI_INTEGER, pnorth, 0,     &
2562                             comm2d, status, ierr )
2563          ALLOCATE ( agt_gh_n(1:ghna_count_recv) )
2564!
2565!--       Send/receive number of agents that
2566!--       will be transferred to/from north/south neighbor
2567          CALL MPI_SENDRECV( ghna_count, 1, MPI_INTEGER, pnorth, 0,            &
2568                             ghsa_count_recv,   1, MPI_INTEGER, psouth, 0,     &
2569                             comm2d, status, ierr )
2570!
2571!--       Send/receive flag that indicates if there are actually any agents
2572!--       in ghost  layer
2573          CALL MPI_SENDRECV( ghsa_empty,     1, MPI_LOGICAL, psouth, 1,        &
2574                             ghna_empty_rcv, 1, MPI_LOGICAL, pnorth, 1,        &
2575                             comm2d, status, ierr )
2576          CALL MPI_SENDRECV( ghna_empty,     1, MPI_LOGICAL, pnorth, 1,        &
2577                             ghsa_empty_rcv, 1, MPI_LOGICAL, psouth, 1,        &
2578                             comm2d, status, ierr )
2579
2580
2581          ALLOCATE ( agt_gh_s(1:ghsa_count_recv) )
2582!
2583!--       Get bit size of one agent
2584          agt_size = STORAGE_SIZE(zero_agent)/8
2585!
2586!--       Send/receive agents to/from south/north neighbor
2587          CALL MPI_SENDRECV( ghsa,     ghsa_count      * agt_size, MPI_BYTE,   &
2588                                psouth,1,                                      &
2589                             agt_gh_n, ghna_count_recv * agt_size, MPI_BYTE,   &
2590                                pnorth,1,                                      &
2591                             comm2d, status, ierr )
2592!
2593!--       Send/receive agents to/from south/north neighbor
2594          CALL MPI_SENDRECV( ghna,     ghna_count      * agt_size, MPI_BYTE,   &
2595                                pnorth,1,                                      &
2596                             agt_gh_s, ghsa_count_recv * agt_size, MPI_BYTE,   &
2597                                psouth,1,                                      &
2598                             comm2d, status, ierr )
2599!
2600!--       If agents were received, add them to the respective ghost layer cells
2601          IF ( .NOT. ghna_empty_rcv ) THEN
2602             CALL mas_eh_add_ghost_agents_to_gridcell(agt_gh_n)
2603          ENDIF
2604
2605          IF ( .NOT. ghsa_empty_rcv ) THEN
2606             CALL mas_eh_add_ghost_agents_to_gridcell(agt_gh_s)
2607          ENDIF
2608
2609          DEALLOCATE( ghna, ghsa, agt_gh_n, agt_gh_s )
2610
2611       ENDIF
2612
2613#endif
2614
2615    END SUBROUTINE mas_eh_ghost_exchange
2616
2617!------------------------------------------------------------------------------!
2618! Description:
2619! ------------
2620!> If an agent moves from one grid cell to another (on the current
2621!> processor!), this subroutine moves the corresponding element from the
2622!> agent array of the old grid cell to the agent array of the new grid
2623!> cell.
2624!------------------------------------------------------------------------------!
2625    SUBROUTINE mas_eh_move_agent
2626
2627       IMPLICIT NONE
2628
2629       INTEGER(iwp) ::  i              !< grid index (x) of agent position
2630       INTEGER(iwp) ::  ip             !< index variable along x
2631       INTEGER(iwp) ::  j              !< grid index (y) of agent position
2632       INTEGER(iwp) ::  jp             !< index variable along y
2633       INTEGER(iwp) ::  n              !< index variable for agent array
2634       INTEGER(iwp) ::  na_before_move !< number of agents per grid box before moving
2635       INTEGER(iwp) ::  aindex         !< dummy argument for number of new agent per grid box
2636
2637       TYPE(agent_type), DIMENSION(:), POINTER ::  agents_before_move !< agents before moving
2638
2639       DO  ip = nxl, nxr
2640          DO  jp = nys, nyn
2641
2642                na_before_move = agt_count(jp,ip)
2643                IF ( na_before_move <= 0 )  CYCLE
2644                agents_before_move => grid_agents(jp,ip)%agents(1:na_before_move)
2645
2646                DO  n = 1, na_before_move
2647                   i = agents_before_move(n)%x * ddx
2648                   j = agents_before_move(n)%y * ddy
2649
2650!--                For mas_eh_exchange_horiz to work properly agents need to be
2651!--                moved to the outermost gridboxes of the respective processor.
2652!--                If the agent index is inside the processor the following
2653!--                lines will not change the index
2654                   i = MIN ( i , nxr )
2655                   i = MAX ( i , nxl )
2656                   j = MIN ( j , nyn )
2657                   j = MAX ( j , nys )
2658
2659!
2660!--                Check if agent has moved to another grid cell.
2661                   IF ( i /= ip  .OR.  j /= jp )  THEN
2662!
2663!--                   If the agent stays on the same processor, the agent
2664!--                   will be added to the agent array of the new processor.
2665                      number_of_agents = agt_count(j,i)
2666                      agents => grid_agents(j,i)%agents(1:number_of_agents)
2667
2668                      aindex = number_of_agents+1
2669                      IF (  aindex > SIZE(grid_agents(j,i)%agents)  )     &
2670                      THEN
2671                         CALL mas_eh_realloc_agents_array(i,j)
2672                      ENDIF
2673
2674                      grid_agents(j,i)%agents(aindex) = agents_before_move(n)
2675                      agt_count(j,i) = aindex
2676
2677                      agents_before_move(n)%agent_mask = .FALSE.
2678                   ENDIF
2679                ENDDO
2680
2681          ENDDO
2682       ENDDO
2683
2684       RETURN
2685
2686    END SUBROUTINE mas_eh_move_agent
2687
2688!------------------------------------------------------------------------------!
2689! Description:
2690! ------------
2691!> If the allocated memory for the agent array do not suffice to add arriving
2692!> agents from neighbour grid cells, this subrouting reallocates the
2693!> agent array to assure enough memory is available.
2694!------------------------------------------------------------------------------!
2695    SUBROUTINE mas_eh_realloc_agents_array (i,j,size_in)
2696
2697       IMPLICIT NONE
2698
2699       INTEGER(iwp) :: old_size  !< old array size
2700       INTEGER(iwp) :: new_size  !< new array size
2701
2702       INTEGER(iwp), INTENT(in) ::  i  !< grid index (y)
2703       INTEGER(iwp), INTENT(in) ::  j  !< grid index (y)
2704
2705       INTEGER(iwp), INTENT(in), OPTIONAL ::  size_in  !< size of input array
2706
2707       TYPE(agent_type), DIMENSION(10) :: tmp_agents_s !< temporary static agent array
2708
2709       TYPE(agent_type), DIMENSION(:), ALLOCATABLE :: tmp_agents_d !< temporary dynamic agent array
2710
2711       old_size = SIZE(grid_agents(j,i)%agents)
2712
2713       IF ( PRESENT(size_in) )   THEN
2714          new_size = size_in
2715       ELSE
2716          new_size = old_size * ( 1.0_wp + alloc_factor_mas / 100.0_wp )
2717       ENDIF
2718
2719       new_size = MAX( new_size, min_nr_agent, old_size + 1 )
2720
2721       IF ( old_size <= 10 )  THEN
2722
2723          tmp_agents_s(1:old_size) = grid_agents(j,i)%agents(1:old_size)
2724
2725          DEALLOCATE(grid_agents(j,i)%agents)
2726          ALLOCATE(grid_agents(j,i)%agents(new_size))
2727
2728          grid_agents(j,i)%agents(1:old_size)         = tmp_agents_s(1:old_size)
2729          grid_agents(j,i)%agents(old_size+1:new_size) = zero_agent
2730
2731       ELSE
2732
2733          ALLOCATE(tmp_agents_d(new_size))
2734          tmp_agents_d(1:old_size) = grid_agents(j,i)%agents
2735
2736          DEALLOCATE(grid_agents(j,i)%agents)
2737          ALLOCATE(grid_agents(j,i)%agents(new_size))
2738
2739          grid_agents(j,i)%agents(1:old_size)         = tmp_agents_d(1:old_size)
2740          grid_agents(j,i)%agents(old_size+1:new_size) = zero_agent
2741
2742          DEALLOCATE(tmp_agents_d)
2743
2744       ENDIF
2745       agents => grid_agents(j,i)%agents(1:number_of_agents)
2746
2747       RETURN
2748    END SUBROUTINE mas_eh_realloc_agents_array
2749
2750!------------------------------------------------------------------------------!
2751! Description:
2752! ------------
2753!> Inquires prognostic model quantities at the position of each agent and
2754!> stores them in that agent for later output
2755!------------------------------------------------------------------------------!
2756    SUBROUTINE mas_get_prognostic_quantities
2757
2758       USE arrays_3d,                                                          &
2759           ONLY:  u, v, pt, hyp, exner
2760
2761!       USE chemistry_model_mod,                                                &
2762!           ONLY:  chem_species
2763
2764!       USE control_parameters,                                                 &
2765!              ONLY:  air_chemistry
2766
2767       IMPLICIT NONE
2768
2769       INTEGER(iwp) ::  i_offset  !<  index offset for windspeed measurement
2770       INTEGER(iwp) ::  il        !<  x-index
2771       INTEGER(iwp) ::  is        !<  subgrid box counter
2772       INTEGER(iwp) ::  j_offset  !<  index offset for windspeed measurement
2773       INTEGER(iwp) ::  jl        !<  y-index
2774       INTEGER(iwp) ::  kl        !<  z-index
2775       INTEGER(iwp) ::  nl        !<  agent counter
2776       INTEGER(iwp) ::  se        !<  subgrid box end index
2777       INTEGER(iwp) ::  si        !<  subgrid box start index
2778
2779       REAL(wp) ::  u_a  !< windspeed at agent position (x)
2780       REAL(wp) ::  v_a  !< windspeed at agent position (y)
2781
2782       DO  il = nxl, nxr
2783          DO  jl = nys, nyn
2784
2785             number_of_agents = agt_count(jl,il)
2786!
2787!--          If grid cell is empty, cycle
2788             IF ( number_of_agents <= 0 ) CYCLE
2789             kl = s_measure_height(jl,il)
2790
2791             agents => grid_agents(jl,il)%agents(1:number_of_agents)
2792!
2793!--          loop over the four subgrid boxes
2794             DO is = 0,3
2795!
2796!--             Set indices
2797                si = grid_agents(jl,il)%start_index(is)
2798                se = grid_agents(jl,il)%end_index(is)
2799                DO nl = si, se
2800!
2801!--                Calculate index offset in x-direction:
2802!--                Left value if wall right of grid box
2803!--                Right value if wall left of grid box
2804!--                Else the one that is closer to the agent
2805                   IF ( BTEST( obstacle_flags( jl, il+1 ), 6 ) ) THEN
2806                      i_offset = 0
2807                   ELSEIF ( BTEST( obstacle_flags( jl, il-1 ), 2 ) ) THEN
2808                      i_offset = 1
2809                   ELSE
2810                      i_offset = MERGE( 0, 1, BTEST(is,1) )
2811                   ENDIF
2812                   u_a = u( kl, jl, il + i_offset )
2813!
2814!--                Calculate index offset in y-direction:
2815!--                South value if wall north of grid box
2816!--                North value if wall south of grid box
2817!--                Else the one that is closer to the agent
2818                   IF ( BTEST( obstacle_flags( jl+1, il ), 4 ) ) THEN
2819                      j_offset = 0
2820                   ELSEIF ( BTEST( obstacle_flags( jl-1, il ), 0 ) ) THEN
2821                      j_offset = 1
2822                   ELSE
2823                      j_offset = MERGE( 0, 1, BTEST(is,0) )
2824                   ENDIF
2825                   v_a = v( kl, jl + j_offset, il )
2826!
2827!--                Calculate windspeed at agent postion
2828                   agents(nl)%windspeed = SQRT(u_a**2 + v_a**2)
2829!
2830!--                Calculate temperature at agent position
2831                   agents(nl)%t = pt(kl,jl,il) * exner(kl)
2832! !
2833! !--                Get PM10 concentration at agent position, if possible
2834!                    IF ( ind_pm10 == -9 ) THEN
2835!                       agents(nl)%pm10 = 0.0_wp
2836!                    ELSE
2837!                       agents(nl)%pm10 = chem_species(ind_pm10)%conc(kl,jl,il)
2838!                    ENDIF
2839! !
2840! !--                Get PM10 concentration at agent position, if possible
2841!                    IF ( ind_pm25 == -9 ) THEN
2842!                       agents(nl)%pm25 = 0.0_wp
2843!                    ELSE
2844!                       agents(nl)%pm25 = chem_species(ind_pm25)%conc(kl,jl,il)
2845!                    ENDIF
2846                ENDDO
2847
2848             ENDDO
2849
2850          ENDDO
2851       ENDDO
2852
2853    END SUBROUTINE mas_get_prognostic_quantities
2854
2855!------------------------------------------------------------------------------!
2856! Description:
2857! ------------
2858!> Adds an item to the priority queue (binary heap) at the correct position
2859!------------------------------------------------------------------------------!
2860    SUBROUTINE mas_heap_insert_item( id, priority )
2861
2862       IMPLICIT NONE
2863
2864       INTEGER(iwp) ::  cur_pos !< current position
2865       INTEGER(iwp) ::  id      !< mesh ID of item
2866
2867       REAL(wp) ::  priority !< item priority
2868
2869       TYPE(heap_item) ::  item !< heap item
2870
2871       item%mesh_id  = id
2872       item%priority = priority
2873!
2874!--    Extend heap, if necessary
2875       IF ( heap_count + 1 > SIZE(queue) ) THEN
2876          CALL mas_heap_extend
2877       ENDIF
2878!
2879!--    Insert item at first unoccupied postion (highest index) of heap
2880       cur_pos = heap_count
2881       queue(cur_pos) = item
2882!
2883!--    Sort while inserted item is not at top of heap
2884       DO WHILE ( cur_pos /= 0 )
2885!
2886!--       If priority < its parent's priority, swap them.
2887!--       Else, sorting is done.
2888          IF ( queue(cur_pos)%priority                                         &
2889              < queue(FLOOR((cur_pos)/2.))%priority )                          &
2890          THEN
2891             item = queue(cur_pos)
2892             queue(cur_pos) = queue(FLOOR((cur_pos)/2.))
2893             queue(FLOOR((cur_pos)/2.)) = item
2894             cur_pos = FLOOR((cur_pos)/2.)
2895          ELSE
2896             EXIT
2897          ENDIF
2898       ENDDO
2899!
2900!--    Item was added to heap, so the heap count increases
2901       heap_count = heap_count + 1
2902
2903    END SUBROUTINE mas_heap_insert_item
2904
2905!------------------------------------------------------------------------------!
2906! Description:
2907! ------------
2908!> Extends the size of the priority queue (binary heap)
2909!------------------------------------------------------------------------------!
2910    SUBROUTINE mas_heap_extend
2911
2912       IMPLICIT NONE
2913
2914       INTEGER(iwp) ::  soh !< size of heap
2915
2916       TYPE(heap_item), DIMENSION(:), ALLOCATABLE ::  dummy_heap !< dummy heap
2917
2918       soh = SIZE(queue)-1
2919       ALLOCATE(dummy_heap(0:soh))
2920       dummy_heap = queue
2921       DEALLOCATE(queue)
2922       ALLOCATE(queue(0:2*soh+1))
2923       queue(0:soh) = dummy_heap(0:soh)
2924
2925    END SUBROUTINE mas_heap_extend
2926
2927!------------------------------------------------------------------------------!
2928! Description:
2929! ------------
2930!> Removes first (smallest) element from the priority queue, reorders the rest
2931!> and returns the ID of the removed mesh point
2932!------------------------------------------------------------------------------!
2933    SUBROUTINE mas_heap_extract_item ( id )
2934
2935       IMPLICIT NONE
2936
2937       INTEGER(iwp) ::  id      !< ID of item extracted item
2938       INTEGER(iwp) ::  child   !< child of item in heap
2939       INTEGER(iwp) ::  cur_pos !< current position of item in heap
2940
2941       TYPE(heap_item) ::  dummy
2942!
2943!--    Get ID of mesh point with lowest priority (extracted item: top of heap)
2944       id = queue(0)%mesh_id
2945!
2946!--    Put last item in heap at first position
2947       queue(0) = queue(heap_count-1)
2948       cur_pos = 0
2949       DO
2950!
2951!--       If current item has no children, sorting is done
2952          IF( 2*cur_pos+1 > heap_count - 1 ) THEN
2953             EXIT
2954!
2955!--       If current item has only one child, check if item and its child are
2956!--       ordered correctly. Else, swap them.
2957          ELSEIF ( 2*cur_pos+2 > heap_count - 1 ) THEN
2958             IF ( queue(cur_pos)%priority > queue(2*cur_pos+1)%priority ) THEN
2959                dummy = queue(cur_pos)
2960                queue(cur_pos) = queue(2*cur_pos+1)
2961                queue(2*cur_pos+1) = dummy
2962                cur_pos = 2*cur_pos+1
2963             ELSE
2964                EXIT
2965             ENDIF
2966          ELSE
2967!
2968!--          determine the smaller child
2969             IF ( queue(2*cur_pos+1)%priority                                  &
2970                 >= queue(2*cur_pos+2)%priority )                              &
2971             THEN
2972                child = 2
2973             ELSE
2974                child = 1
2975             ENDIF
2976!
2977!--          Check if item and its smaller child are ordered falsely. If so,
2978!--          swap them. Else, sorting is done.
2979             IF ( queue(cur_pos)%priority > queue(2*cur_pos+child )%priority ) &
2980             THEN
2981                dummy = queue(cur_pos)
2982                queue(cur_pos) = queue(2*cur_pos+child)
2983                queue(2*cur_pos+child) = dummy
2984                cur_pos = 2*cur_pos+child
2985             ELSE
2986                EXIT
2987             ENDIF
2988          ENDIF
2989       ENDDO
2990!
2991!--    Top item was removed from heap, thus, heap_cout decreases by one
2992       heap_count = heap_count-1
2993
2994    END SUBROUTINE mas_heap_extract_item
2995
2996!------------------------------------------------------------------------------!
2997! Description:
2998! ------------
2999!> Initialization of Multi Agent System
3000!------------------------------------------------------------------------------!
3001    SUBROUTINE mas_init
3002
3003!       USE chem_gasphase_mod,                                                  &
3004!           ONLY:  nspec
3005
3006!       USE chemistry_model_mod,                                                &
3007!           ONLY:  chem_species
3008
3009       USE control_parameters,                                                 &
3010           ONLY:  coupling_char, initializing_actions, io_blocks, io_group
3011
3012       USE surface_mod,                                                        &
3013           ONLY:  get_topography_top_index, get_topography_top_index_ji
3014
3015       USE arrays_3d,                                                          &
3016           ONLY:  zu, zw
3017
3018       USE indices,                                                            &
3019           ONLY:  nzt 
3020
3021       IMPLICIT NONE
3022
3023       INTEGER(iwp) ::  i             !< grid cell (x)
3024       INTEGER(iwp) ::  ii            !< io-block counter
3025       INTEGER(iwp) ::  il            !< io-block counter
3026       INTEGER(iwp) ::  jl            !< io-block counter
3027       INTEGER(iwp) ::  kl            !< io-block counter
3028       INTEGER(iwp) ::  kdum            !< io-block counter
3029       INTEGER(iwp) ::  locdum            !< io-block counter
3030       INTEGER(iwp) ::  j             !< grid cell (y)
3031       INTEGER(iwp) ::  size_of_mesh  !< temporary value for read
3032       INTEGER(iwp) ::  size_of_pols  !< temporary value for read
3033       INTEGER(iwp) ::  ioerr         !< IOSTAT flag for IO-commands ( 0 = no error )
3034
3035       REAL(wp) ::  zdum  !< dummy for measurement height
3036       REAL(wp) ::  avg_agt_height = 1.8_wp
3037
3038
3039!
3040!--    Check the number of agent groups.
3041       IF ( number_of_agent_groups > max_number_of_agent_groups )  THEN
3042          WRITE( message_string, * ) 'max_number_of_agent_groups =',      &
3043                                     max_number_of_agent_groups ,         &
3044                                     '&number_of_agent_groups reset to ', &
3045                                     max_number_of_agent_groups
3046          CALL message( 'mas_init', 'PA0072', 0, 1, 0, 6, 0 )
3047          number_of_agent_groups = max_number_of_agent_groups
3048       ENDIF
3049
3050!
3051!--    Set some parameters
3052       d_sigma_rep_agent = 1.0_wp/sigma_rep_agent
3053       d_sigma_rep_wall  = 1.0_wp/sigma_rep_wall
3054       d_tau_accel_agent = 1.0_wp/tau_accel_agent
3055       IF ( dt_agent /= 999.0_wp ) THEN
3056          agent_own_timestep = .TRUE.
3057       ENDIF
3058
3059!
3060!--    Get index of first grid box above topography
3061       ALLOCATE( top_top_s(nysg:nyng,nxlg:nxrg),                               &
3062                 top_top_w(nysg:nyng,nxlg:nxrg),                               &
3063                 s_measure_height(nys:nyn,nxl:nxr) )
3064!
3065!--    Get first index above topography for scalar grid and last index in
3066!--    topography for z-component of wind
3067       DO il = nxlg, nxrg
3068          DO jl = nysg, nyng
3069             top_top_s(jl,il) = get_topography_top_index_ji(jl,il,'s') + 1
3070             top_top_w(jl,il) = get_topography_top_index_ji(jl,il,'w')
3071          ENDDO
3072       ENDDO
3073!
3074!--    Create 2D array containing the index at which measurements are done by
3075!--    agents. The height of this measurement is given by avg_agt_height.
3076       DO il = nxl, nxr
3077          DO jl = nys, nyn
3078
3079             kdum = top_top_w(jl,il)
3080             zdum = zw(kdum)
3081             zdum = zdum + avg_agt_height
3082             locdum = 0
3083!
3084!--          Locate minimum distance from u-grid to measurement height (zdum)
3085             DO kl = 1, nzt
3086                IF ( ABS(zu(kl)-zdum) < ABS(zu(locdum)-zdum) ) locdum = kl
3087             ENDDO
3088             s_measure_height(jl,il) = locdum
3089
3090          ENDDO
3091       ENDDO
3092! !
3093! !--    Get indices of PM10 and PM2.5 species, if active
3094!        IF ( air_chemistry ) THEN
3095!           DO il = 1, nspec
3096! print*,chem_species(il)%name
3097! !              IF ( spec_name(1:4) == 'PM10' ) THEN 
3098! !                 ind_pm10 = il
3099! !              ELSEIF ( spec_name(1:4) == 'PM25' ) THEN
3100! !                 ind_pm25 = il
3101! !              ENDIF
3102!
3103!           ENDDO
3104!        ENDIF
3105! stop
3106       CALL mas_create_obstacle_flags
3107
3108!
3109!--    Set default start positions, if necessary
3110       IF ( asl(1) == 9999999.9_wp )  asl(1) = 0.0_wp
3111       IF ( asr(1) == 9999999.9_wp )  asr(1) = ( nx + 1 ) * dx
3112       IF ( ass(1) == 9999999.9_wp )  ass(1) = 0.0_wp
3113       IF ( asn(1) == 9999999.9_wp )  asn(1) = ( ny + 1 ) * dy
3114       IF ( adx(1) == 9999999.9_wp .OR. adx(1) == 0.0_wp ) adx(1) = dx
3115       IF ( ady(1) == 9999999.9_wp .OR. ady(1) == 0.0_wp ) ady(1) = dy
3116
3117       DO  j = 2, number_of_agent_groups
3118          IF ( asl(j) == 9999999.9_wp )  asl(j) = asl(j-1)
3119          IF ( asr(j) == 9999999.9_wp )  asr(j) = asr(j-1)
3120          IF ( ass(j) == 9999999.9_wp )  ass(j) = ass(j-1)
3121          IF ( asn(j) == 9999999.9_wp )  asn(j) = asn(j-1)
3122          IF ( adx(j) == 9999999.9_wp .OR. adx(j) == 0.0_wp ) adx(j) = adx(j-1)
3123          IF ( ady(j) == 9999999.9_wp .OR. ady(j) == 0.0_wp ) ady(j) = ady(j-1)
3124       ENDDO
3125
3126!
3127!--    Check boundary condition and set internal variables
3128       SELECT CASE ( bc_mas_lr )
3129
3130          CASE ( 'cyclic' )
3131             ibc_mas_lr = 0
3132
3133          CASE ( 'absorb' )
3134             ibc_mas_lr = 1
3135
3136          CASE DEFAULT
3137             WRITE( message_string, * ) 'unknown boundary condition ',         &
3138                                        'bc_mas_lr = "', TRIM( bc_mas_lr ), '"'
3139             CALL message( 'mas_init', 'PA0073', 1, 2, 0, 6, 0 )
3140
3141       END SELECT
3142       SELECT CASE ( bc_mas_ns )
3143
3144          CASE ( 'cyclic' )
3145             ibc_mas_ns = 0
3146
3147          CASE ( 'absorb' )
3148             ibc_mas_ns = 1
3149
3150          CASE DEFAULT
3151             WRITE( message_string, * ) 'unknown boundary condition ',         &
3152                                        'bc_mas_ns = "', TRIM( bc_mas_ns ), '"'
3153             CALL message( 'mas_init', 'PA0074', 1, 2, 0, 6, 0 )
3154
3155       END SELECT
3156
3157!
3158!--    For the first model run of a possible job chain initialize the
3159!--    agents, otherwise read the agent data from restart file.
3160       IF ( TRIM( initializing_actions ) == 'read_restart_data'                &
3161            .AND.  read_agents_from_restartfile )  THEN
3162
3163!           CALL mas_read_restart_file
3164
3165       ELSE
3166!
3167!--       Read preprocessed data of navigation mesh and building polygons
3168!--       for agent pathfinding
3169          DO ii = 0, io_blocks-1
3170             IF ( ii == io_group )  THEN
3171                OPEN ( 119, FILE='NAVIGATION_DATA'//TRIM( coupling_char ),     &
3172                            FORM='UNFORMATTED', IOSTAT=ioerr )
3173!
3174!--             Read mesh data
3175                READ(119) size_of_mesh
3176                ALLOCATE( mesh(1:size_of_mesh))
3177                DO i = 1, size_of_mesh
3178                   READ(119) mesh(i)%polygon_id, mesh(i)%vertex_id,            &
3179                             mesh(i)%noc, mesh(i)%origin_id,                   &
3180                             mesh(i)%cost_so_far, mesh(i)%x,                   &
3181                             mesh(i)%y, mesh(i)%x_s, mesh(i)%y_s
3182                   ALLOCATE( mesh(i)%connected_vertices(1:mesh(i)%noc),        &
3183                             mesh(i)%distance_to_vertex(1:mesh(i)%noc) )
3184                   DO j = 1, mesh(i)%noc
3185                      READ(119) mesh(i)%connected_vertices(j),                 &
3186                                mesh(i)%distance_to_vertex(j)
3187                   ENDDO
3188                ENDDO
3189!
3190!--             Read polygon data
3191                READ(119) size_of_pols
3192                ALLOCATE( polygons(1:size_of_pols) )
3193                DO i = 1, size_of_pols
3194                   READ(119) polygons(i)%nov
3195                   ALLOCATE( polygons(i)%vertices(0:polygons(i)%nov+1) )
3196                   DO j = 0, polygons(i)%nov+1
3197                      READ(119) polygons(i)%vertices(j)%delete,                &
3198                                polygons(i)%vertices(j)%x,                     &
3199                                polygons(i)%vertices(j)%y
3200                   ENDDO
3201                ENDDO
3202                CLOSE(119)
3203
3204             ENDIF
3205#if defined( __parallel ) && ! defined ( __check )
3206             CALL MPI_BARRIER( comm2d, ierr )
3207#endif
3208          ENDDO
3209
3210!
3211!--       Allocate agent arrays and set attributes of the initial set of
3212!--       agents, which can be also periodically released at later times.
3213          ALLOCATE( agt_count  (nysg:nyng,nxlg:nxrg),                          &
3214                    grid_agents(nysg:nyng,nxlg:nxrg) )
3215!
3216!--       Allocate dummy arrays for pathfinding
3217          ALLOCATE( dummy_path_x(0:agt_path_size),                 &
3218                    dummy_path_y(0:agt_path_size) )
3219
3220          number_of_agents = 0
3221          sort_count_mas   = 0
3222          agt_count        = 0
3223
3224!
3225!--       initialize counter for agent IDs
3226          grid_agents%id_counter = 1
3227
3228!
3229!--       Initialize all agents with dummy values (otherwise errors may
3230!--       occur within restart runs). The reason for this is still not clear
3231!--       and may be presumably caused by errors in the respective user-interface.
3232          zero_agent%agent_mask = .FALSE.
3233          zero_agent%block_nr      = -1
3234          zero_agent%group         = 0
3235          zero_agent%id            = 0_idp
3236          zero_agent%path_counter  = agt_path_size
3237          zero_agent%age           = 0.0_wp
3238          zero_agent%age_m         = 0.0_wp
3239          zero_agent%dt_sum        = 0.0_wp
3240          zero_agent%clo           = 0.0_wp
3241          zero_agent%energy_storage= 0.0_wp
3242          zero_agent%force_x       = 0.0_wp
3243          zero_agent%force_y       = 0.0_wp
3244          zero_agent%origin_x      = 0.0_wp
3245          zero_agent%origin_y      = 0.0_wp
3246          zero_agent%speed_abs     = 0.0_wp
3247          zero_agent%speed_e_x     = 0.0_wp
3248          zero_agent%speed_e_y     = 0.0_wp
3249          zero_agent%speed_des     = random_normal(desired_speed, des_sp_sig)
3250          zero_agent%speed_x       = 0.0_wp
3251          zero_agent%speed_y       = 0.0_wp
3252          zero_agent%ipt           = 0.0_wp
3253          zero_agent%x             = 0.0_wp
3254          zero_agent%y             = 0.0_wp
3255          zero_agent%path_x        = 0.0_wp
3256          zero_agent%path_y        = 0.0_wp
3257          zero_agent%t_x           = 0.0_wp
3258          zero_agent%t_y           = 0.0_wp
3259
3260!
3261!--    Set a seed value for the random number generator to be exclusively
3262!--    used for the agent code. The generated random numbers should be
3263!--    different on the different PEs.
3264          iran_agent = iran_agent + myid
3265
3266          CALL mas_create_agent (PHASE_INIT)
3267
3268       ENDIF
3269
3270!
3271!--    To avoid programm abort, assign agents array to the local version of
3272!--    first grid cell
3273       number_of_agents = agt_count(nys,nxl)
3274       agents => grid_agents(nys,nxl)%agents(1:number_of_agents)
3275
3276    END SUBROUTINE mas_init
3277
3278!------------------------------------------------------------------------------!
3279! Description:
3280! ------------
3281!> Output of informative message about maximum agent number
3282!------------------------------------------------------------------------------!
3283    SUBROUTINE mas_last_actions
3284
3285       USE control_parameters,                                                 &
3286           ONLY:  message_string
3287
3288       IMPLICIT NONE
3289
3290       WRITE(message_string,'(A,I8,A)')                                        &
3291                         'The maximumn number of agents during this run was',  &
3292                         maximum_number_of_agents,                             &
3293                         '&Consider adjusting the INPUT parameter'//           &
3294                         '&dim_size_agtnum_manual accordingly for the next run.'
3295
3296       CALL message( 'mas_data_output_agents', 'PA0457', 0, 0, 0, 6, 0 )
3297
3298    END SUBROUTINE mas_last_actions
3299
3300!------------------------------------------------------------------------------!
3301! Description:
3302! ------------
3303!> Finds the shortest path from a start position to a target position using the
3304!> A*-algorithm
3305!------------------------------------------------------------------------------!
3306    SUBROUTINE mas_nav_a_star( start_x, start_y, target_x, target_y, nsteps )
3307
3308       IMPLICIT NONE
3309
3310       LOGICAL ::  target_reached !< flag
3311
3312       INTEGER(iwp) ::  cur_node     !< current node of binary heap
3313       INTEGER(iwp) ::  il           !< counter (x)
3314       INTEGER(iwp) ::  neigh_node   !< neighbor node
3315       INTEGER(iwp) ::  node_counter !< binary heap node counter
3316       INTEGER(iwp) ::  path_ag      !< index of agent path
3317       INTEGER(iwp) ::  som          !< size of mesh
3318       INTEGER(iwp) ::  steps        !< steps along the path
3319       INTEGER(iwp) ::  nsteps        !< number of steps
3320
3321       REAL(wp) ::  start_x      !< x-coordinate agent
3322       REAL(wp) ::  start_y      !< y-coordinate agent
3323       REAL(wp) ::  new_cost     !< updated cost to reach node
3324       REAL(wp) ::  new_priority !< priority of node to be added to queue
3325       REAL(wp) ::  rn_gate      !< random number for corner gate
3326       REAL(wp) ::  target_x     !< x-coordinate target
3327       REAL(wp) ::  target_y     !< y-coordinate target
3328!
3329!--    Coordinate Type
3330       TYPE coord
3331          REAL(wp) ::  x   !< x-coordinate
3332          REAL(wp) ::  x_s !< x-coordinate (shifted)
3333          REAL(wp) ::  y   !< y-coordinate
3334          REAL(wp) ::  y_s !< y-coordinate (shifted)
3335       END TYPE coord
3336
3337       TYPE(coord), DIMENSION(:), ALLOCATABLE, TARGET ::  path     !< path array
3338       TYPE(coord), DIMENSION(:), ALLOCATABLE, TARGET ::  tmp_path !< temporary path for resizing
3339
3340       node_counter = 0
3341!
3342!--    Create temporary navigation mesh including agent and target positions
3343       CALL mas_nav_create_tmp_mesh( start_x, start_y, target_x, target_y, som )
3344       tmp_mesh(som)%cost_so_far = 0.0_wp
3345!
3346!--    Initialize priority queue
3347       heap_count = 0_iwp
3348       ALLOCATE(queue(0:100))
3349       target_reached = .FALSE.
3350!
3351!--    Add starting point (agent position) to frontier (the frontier consists
3352!--    of all the nodes that are to be visited. The node with the smallest
3353!--    priority will be visited first. The priority consists of the distance
3354!--    from the start node to this node plus a minimal guess (direct distance)
3355!--    from this node to the goal). For the starting node, the priority is set
3356!--    to 0, as it's the only node thus far
3357       CALL mas_heap_insert_item(som,0.0_wp)
3358       cur_node = som
3359       DO WHILE ( heap_count > 0 )
3360!
3361!--       Step one: Pick lowest priority item from queue
3362          node_counter = node_counter + 1
3363          CALL mas_heap_extract_item(cur_node)
3364!
3365!--       Node 0 is the goal node
3366          IF ( cur_node == 0 ) THEN
3367             EXIT
3368          ENDIF
3369!
3370!--       Loop over all of cur_node's neighbors
3371          DO il = 1, tmp_mesh(cur_node)%noc
3372             neigh_node = tmp_mesh(cur_node)%connected_vertices(il)
3373!
3374!--          Check, if the way from the start node to this neigh_node via
3375!--          cur_node is shorter than the previously found shortest path to it.
3376!--          If so, replace said cost and add neigh_node to the frontier.
3377!--          cost_so_far is initialized as 1.d12 so that all found distances
3378!--          should be smaller.
3379             new_cost   = tmp_mesh(cur_node)%cost_so_far                       &
3380                         + tmp_mesh(cur_node)%distance_to_vertex(il)
3381             IF ( new_cost < tmp_mesh(neigh_node)%cost_so_far ) THEN
3382                tmp_mesh(neigh_node)%cost_so_far = new_cost
3383                tmp_mesh(neigh_node)%origin_id   = cur_node
3384!
3385!--             Priority in the queue is cost_so_far + heuristic to goal
3386                new_priority = new_cost                                        &
3387                              + heuristic(tmp_mesh(neigh_node)%x,              &
3388                                tmp_mesh(neigh_node)%y, tmp_mesh(0)%x,         &
3389                                tmp_mesh(0)%y)
3390                CALL mas_heap_insert_item(neigh_node,new_priority)
3391             ENDIF
3392          ENDDO
3393       ENDDO
3394!
3395!--    Add nodes to a path array. To do this, we must backtrack from the target
3396!--    node to its origin to its origin and so on until an node is reached that
3397!--    has no origin (%origin_id == -1). This is the starting node.
3398       DEALLOCATE(queue)
3399       cur_node = 0
3400       steps = 0
3401       ALLOCATE(path(1:100))
3402       DO WHILE ( cur_node /= -1 )
3403          steps = steps + 1
3404!
3405!--       Resize path array if necessary
3406          IF ( steps > SIZE(path) ) THEN
3407             ALLOCATE(tmp_path(1:steps-1))
3408             tmp_path(1:steps-1) = path(1:steps-1)
3409             DEALLOCATE(path)
3410             ALLOCATE(path(1:2*(steps-1)))
3411             path(1:steps-1) = tmp_path(1:steps-1)
3412             DEALLOCATE(tmp_path)
3413          ENDIF
3414          path(steps)%x = tmp_mesh(cur_node)%x
3415          path(steps)%y = tmp_mesh(cur_node)%y
3416          path(steps)%x_s = tmp_mesh(cur_node)%x_s
3417          path(steps)%y_s = tmp_mesh(cur_node)%y_s
3418          cur_node = tmp_mesh(cur_node)%origin_id
3419       ENDDO
3420!
3421!--    Add calculated intermittent targets to the path until either the
3422!--    target or the maximum number of intermittent targets is reached.
3423!--    Ignore starting point (reduce index by one), it is agent position.
3424       dummy_path_x = -1
3425       dummy_path_y = -1
3426       path_ag = 1
3427       steps = steps - 1
3428       nsteps = 0
3429       DO WHILE( steps > 0 .AND. path_ag <= agt_path_size )
3430!
3431!--       Each target point is randomly chosen along a line target along the
3432!--       bisector of the building corner that starts at corner_gate_start
3433!--       and has a width of corner_gate_width. This is to avoid clustering
3434!--       when opposing agent groups try to reach the same corner target.
3435          rn_gate = random_function(iran_agent) * corner_gate_width            &
3436                                                + corner_gate_start
3437          dummy_path_x(path_ag) = path(steps)%x + rn_gate                      &
3438                         * (path(steps)%x_s - path(steps)%x)
3439          dummy_path_y(path_ag) = path(steps)%y + rn_gate                      &
3440                         * (path(steps)%y_s - path(steps)%y)
3441          steps = steps - 1
3442          path_ag = path_ag + 1
3443          nsteps = nsteps + 1
3444       ENDDO
3445!
3446!--    Set current intermittent target of this agent
3447       DEALLOCATE(tmp_mesh, path)
3448
3449    END SUBROUTINE mas_nav_a_star
3450
3451!------------------------------------------------------------------------------!
3452! Description:
3453! ------------
3454!> Adds a connection between two points of the navigation mesh
3455!> (one-way: in_mp1 to in_mp2)
3456!------------------------------------------------------------------------------!
3457    SUBROUTINE mas_nav_add_connection ( in_mp1, id2, in_mp2 )
3458
3459       IMPLICIT NONE
3460
3461       LOGICAL ::  connection_established  !< Flag to indicate if connection has already been established
3462
3463       INTEGER(iwp) ::  id2  !< ID of in_mp2
3464       INTEGER(iwp) ::  il   !< local counter
3465       INTEGER(iwp) ::  noc1 !< number of connections in in_mp1
3466
3467       INTEGER, DIMENSION(:), ALLOCATABLE ::  dum_cv !< dummy array for connected_vertices
3468
3469       REAL(wp) ::  dist  !< Distance between the two points
3470
3471       REAL(wp), DIMENSION(:), ALLOCATABLE ::  dum_dtv
3472
3473       TYPE(mesh_point) ::  in_mp1  !< mesh point that gets a new connection
3474       TYPE(mesh_point) ::  in_mp2  !< mesh point in_mp1 will be connected to
3475
3476       connection_established = .FALSE.
3477!
3478!--    Check if connection has already been established
3479       noc1 = SIZE(in_mp1%connected_vertices)
3480       DO il = 1, in_mp1%noc
3481          IF ( in_mp1%connected_vertices(il) == id2 ) THEN
3482             connection_established = .TRUE.
3483             EXIT
3484          ENDIF
3485       ENDDO
3486
3487       IF ( .NOT. connection_established ) THEN
3488!
3489!--       Resize arrays, if necessary
3490          IF ( in_mp1%noc >= noc1 ) THEN
3491             ALLOCATE( dum_cv(1:noc1),dum_dtv(1:noc1) )
3492             dum_cv  = in_mp1%connected_vertices
3493             dum_dtv = in_mp1%distance_to_vertex
3494             DEALLOCATE( in_mp1%connected_vertices, in_mp1%distance_to_vertex )
3495             ALLOCATE( in_mp1%connected_vertices(1:2*noc1),                    &
3496                       in_mp1%distance_to_vertex(1:2*noc1) )
3497             in_mp1%connected_vertices         = -999
3498             in_mp1%distance_to_vertex         = -999.
3499             in_mp1%connected_vertices(1:noc1) = dum_cv
3500             in_mp1%distance_to_vertex(1:noc1) = dum_dtv
3501          ENDIF
3502
3503!
3504!--       Add connection
3505          in_mp1%noc = in_mp1%noc+1
3506          dist = SQRT( (in_mp1%x - in_mp2%x)**2 + (in_mp1%y - in_mp2%y)**2 )
3507          in_mp1%connected_vertices(in_mp1%noc) = id2
3508          in_mp1%distance_to_vertex(in_mp1%noc) = dist
3509       ENDIF
3510
3511    END SUBROUTINE mas_nav_add_connection
3512
3513!------------------------------------------------------------------------------!
3514! Description:
3515! ------------
3516!> Adds a vertex (curren position of agent or target) to the existing tmp_mesh
3517!------------------------------------------------------------------------------!
3518    SUBROUTINE mas_nav_add_vertex_to_mesh ( in_mp, in_id )
3519
3520       IMPLICIT NONE
3521
3522       LOGICAL ::  intersection_found !< flag
3523
3524       INTEGER(iwp) ::  jl    !< mesh point counter
3525       INTEGER(iwp) ::  pl    !< polygon counter
3526       INTEGER(iwp) ::  vl    !< vertex counter
3527       INTEGER(iwp) ::  pid_t !< polygon id of tested mesh point
3528       INTEGER(iwp) ::  vid_t !< vertex id of tested mesh point
3529       INTEGER(iwp) ::  in_id !< vertex id of tested mesh point
3530
3531       REAL(wp) ::  v1x !< x-coordinate of test vertex 1 for intersection test
3532       REAL(wp) ::  v1y !< y-coordinate of test vertex 1 for intersection test
3533       REAL(wp) ::  v2x !< x-coordinate of test vertex 2 for intersection test
3534       REAL(wp) ::  v2y !< y-coordinate of test vertex 2 for intersection test
3535       REAL(wp) ::  x   !< x-coordinate of current mesh point
3536       REAL(wp) ::  x_t !< x-coordinate of tested mesh point
3537       REAL(wp) ::  y   !< y-coordinate of current mesh point
3538       REAL(wp) ::  y_t !< y-coordinate of tested mesh point
3539
3540       TYPE(mesh_point) ::  in_mp !< Input mesh point
3541!
3542!--
3543       x = in_mp%x
3544       y = in_mp%y
3545       DO jl = 0, SIZE(tmp_mesh)-2
3546          IF ( in_id == jl ) CYCLE
3547!
3548!--       Ignore mesh points with 0 connections
3549          IF ( tmp_mesh(jl)%polygon_id /= -1 ) THEN
3550             IF ( tmp_mesh(jl)%noc == 0 ) CYCLE
3551          ENDIF
3552          x_t = tmp_mesh(jl)%x
3553          y_t = tmp_mesh(jl)%y
3554          pid_t = tmp_mesh(jl)%polygon_id
3555          vid_t = tmp_mesh(jl)%vertex_id
3556!
3557!--       If the connecting line between the target and a mesh point points
3558!--       into the mesh point's polygon, no connection will be
3559!--       established between the two points. This is the case if the
3560!--       previous (next) vertex of the polygon is right of the connecting
3561!--       line and the next (previous) vertex of the polygon is left of the
3562!--       connecting line.
3563          IF ( pid_t > 0 .AND. pid_t <= SIZE(polygons) ) THEN
3564             IF ( (((is_left(x,y,x_t,y_t,polygons(pid_t)%vertices(vid_t-1)%x,  &
3565                                       polygons(pid_t)%vertices(vid_t-1)%y)    &
3566                  .AND. is_right(x,y,x_t,y_t,                                  &
3567                                       polygons(pid_t)%vertices(vid_t+1)%x,    &
3568                                       polygons(pid_t)%vertices(vid_t+1)%y) )  &
3569                  .OR. (is_right(x,y,x_t,y_t,                                  &
3570                                       polygons(pid_t)%vertices(vid_t-1)%x,    &
3571                                       polygons(pid_t)%vertices(vid_t-1)%y)    &
3572                  .AND. is_left(x,y,x_t,y_t,                                   &
3573                                       polygons(pid_t)%vertices(vid_t+1)%x,    &
3574                                       polygons(pid_t)%vertices(vid_t+1)%y)))))&
3575             THEN
3576                CYCLE
3577             ENDIF
3578          ENDIF
3579!
3580!--       For each edge of each polygon, check if it intersects with the
3581!--       potential connection. If at least one intersection is found,
3582!--       no connection can be made
3583          intersection_found = .FALSE.
3584          DO pl = 1, SIZE(polygons)
3585             DO vl = 1, polygons(pl)%nov
3586                v1x = polygons(pl)%vertices(vl)%x
3587                v1y = polygons(pl)%vertices(vl)%y
3588                v2x = polygons(pl)%vertices(vl+1)%x
3589                v2y = polygons(pl)%vertices(vl+1)%y
3590                intersection_found = intersect(x,y,x_t,y_t,v1x,v1y,v2x,v2y)
3591                IF ( intersection_found ) THEN
3592                   EXIT
3593                ENDIF
3594             ENDDO
3595             IF ( intersection_found ) EXIT
3596          ENDDO
3597          IF ( intersection_found ) CYCLE
3598!
3599!--       If neither of the above two test was true, a connection will be
3600!--       established between the two mesh points.
3601          CALL mas_nav_add_connection(in_mp,jl, tmp_mesh(jl))
3602          CALL mas_nav_add_connection(tmp_mesh(jl),in_id, in_mp)
3603       ENDDO
3604       CALL mas_nav_reduce_connections(in_mp)
3605
3606    END SUBROUTINE mas_nav_add_vertex_to_mesh
3607
3608!------------------------------------------------------------------------------!
3609! Description:
3610! ------------
3611!> Creates a temporary copy of the navigation mesh to be used for pathfinding
3612!------------------------------------------------------------------------------!
3613    SUBROUTINE mas_nav_create_tmp_mesh( a_x, a_y, t_x, t_y, som )
3614
3615       IMPLICIT NONE
3616
3617       INTEGER(iwp) ::  som !< size of mesh
3618       INTEGER(iwp) ::  noc !< number of connetions
3619       INTEGER(iwp) ::  im  !< local mesh point counter
3620
3621       REAL(wp) ::  a_x !< x-coordinate agent
3622       REAL(wp) ::  a_y !< y-coordinate agent
3623       REAL(wp) ::  t_x !< x-coordinate target
3624       REAL(wp) ::  t_y !< y-coordinate target
3625!
3626!--    give tmp_mesh the size of mesh
3627       som = SIZE(mesh)+1
3628       ALLOCATE(tmp_mesh(0:som))
3629!
3630!--    give the allocatable variables in tmp_mesh their respctive sizes
3631       DO im = 1, som-1
3632          noc = mesh(im)%noc
3633          ALLOCATE(tmp_mesh(im)%connected_vertices(1:noc))
3634          ALLOCATE(tmp_mesh(im)%distance_to_vertex(1:noc))
3635       ENDDO
3636!
3637!--    copy mesh to tmp_mesh
3638       tmp_mesh(1:som-1) = mesh(1:som-1)
3639!
3640!--    Add target point ...
3641       CALL mas_nav_init_mesh_point(tmp_mesh(0),-1_iwp,-1_iwp,t_x, t_y)
3642       CALL mas_nav_add_vertex_to_mesh(tmp_mesh(0),0_iwp)
3643!
3644!--    ... and start point to temp mesh
3645       CALL mas_nav_init_mesh_point(tmp_mesh(som),-1_iwp,-1_iwp,a_x, a_y)
3646       CALL mas_nav_add_vertex_to_mesh(tmp_mesh(som),som)
3647
3648    END SUBROUTINE mas_nav_create_tmp_mesh
3649   
3650
3651!------------------------------------------------------------------------------!
3652! Description:
3653! ------------
3654!> Finds the shortest path from an agents' position to her target. As the
3655!> actual pathfinding algorithm uses the obstacle corners and then shifts them
3656!> outward after pathfinding, cases can uccur in which the connection between
3657!> these intermittent targets then intersect with obstacles. To remedy this
3658!> the pathfinding algorithm is then run on every two subsequent intermittent
3659!> targets iteratively and new intermittent targets may be added to the path
3660!> this way.
3661!------------------------------------------------------------------------------!
3662    SUBROUTINE mas_nav_find_path( nl )
3663
3664       IMPLICIT NONE
3665
3666       INTEGER(iwp) ::  nl            !< local agent counter
3667       INTEGER(iwp) ::  il            !< local counter
3668       INTEGER(iwp) ::  jl            !< local counter
3669       INTEGER(iwp) ::  kl            !< local counter
3670       INTEGER(iwp) ::  nsteps_total  !< number of steps on path
3671       INTEGER(iwp) ::  nsteps_dummy  !< number of steps on path
3672       
3673       REAL(wp), DIMENSION(0:30) ::  ld_path_x !< local dummy agent path to target (x)
3674       REAL(wp), DIMENSION(0:30) ::  ld_path_y !< local dummy agent path to target (y)
3675!
3676!--    Initialize agent path arrays
3677       agents(nl)%path_x    = -1
3678       agents(nl)%path_y    = -1
3679       agents(nl)%path_x(0) = agents(nl)%x
3680       agents(nl)%path_y(0) = agents(nl)%y
3681!
3682!--    Calculate initial path
3683       CALL mas_nav_a_star( agents(nl)%x,   agents(nl)%y,                      &
3684                            agents(nl)%t_x, agents(nl)%t_y, nsteps_total )
3685!
3686!--    Set the rest of the agent path that was just calculated
3687       agents(nl)%path_x(1:nsteps_total) = dummy_path_x(1:nsteps_total)
3688       agents(nl)%path_y(1:nsteps_total) = dummy_path_y(1:nsteps_total)
3689!
3690!--    Iterate through found path and check more intermittent targets need
3691!--    to be added. For this, run pathfinding between every two consecutive
3692!--    intermittent targets.
3693       DO il = 0, MIN(agt_path_size-1, nsteps_total-1)
3694!
3695!--       pathfinding between two consecutive intermittent targets
3696          CALL mas_nav_a_star( agents(nl)%path_x(il),   agents(nl)%path_y(il), &
3697                              agents(nl)%path_x(il+1), agents(nl)%path_y(il+1),&
3698                              nsteps_dummy )
3699          nsteps_dummy = nsteps_dummy - 1
3700!
3701!--       If additional intermittent targets are found, add them to the path
3702          IF ( nsteps_dummy > 0 ) THEN
3703             ld_path_x = -1
3704             ld_path_y = -1
3705             ld_path_x(il+1:il+nsteps_dummy) = dummy_path_x(1:nsteps_dummy)
3706             ld_path_y(il+1:il+nsteps_dummy) = dummy_path_y(1:nsteps_dummy)
3707             kl = 1
3708             DO jl = il+1,nsteps_total
3709               ld_path_x( il+nsteps_dummy+kl ) = agents(nl)%path_x(jl)
3710               ld_path_y( il+nsteps_dummy+kl ) = agents(nl)%path_y(jl)
3711               kl = kl + 1
3712               IF ( kl > agt_path_size ) EXIT
3713             ENDDO
3714             nsteps_total = MIN(nsteps_total + nsteps_dummy, agt_path_size)
3715             agents(nl)%path_x(il+1:nsteps_total) = ld_path_x(il+1:nsteps_total)
3716             agents(nl)%path_y(il+1:nsteps_total) = ld_path_y(il+1:nsteps_total)
3717          ENDIF
3718
3719       ENDDO
3720!
3721!--    reset path counter to first intermittent target
3722       agents(nl)%path_counter = 1
3723
3724    END SUBROUTINE mas_nav_find_path
3725
3726!------------------------------------------------------------------------------!
3727! Description:
3728! ------------
3729!> Reduces the size of connection array to the amount of actual connections
3730!> after all connetions were added to a mesh point
3731!------------------------------------------------------------------------------!
3732    SUBROUTINE mas_nav_reduce_connections ( in_mp )
3733
3734       IMPLICIT NONE
3735
3736       INTEGER(iwp) ::  noc  !< number of connections
3737
3738       INTEGER, DIMENSION(:), ALLOCATABLE ::  dum_cv   !< dummy connected_vertices
3739
3740       REAL(wp), DIMENSION(:), ALLOCATABLE ::  dum_dtv !< dummy distance_to_vertex
3741
3742       TYPE(mesh_point) ::  in_mp
3743
3744       noc = in_mp%noc
3745       ALLOCATE( dum_cv(1:noc),dum_dtv(1:noc) )
3746       dum_cv  = in_mp%connected_vertices(1:noc)
3747       dum_dtv = in_mp%distance_to_vertex(1:noc)
3748       DEALLOCATE( in_mp%connected_vertices, in_mp%distance_to_vertex )
3749       ALLOCATE( in_mp%connected_vertices(1:noc),                    &
3750                 in_mp%distance_to_vertex(1:noc) )
3751       in_mp%connected_vertices(1:noc) = dum_cv(1:noc)
3752       in_mp%distance_to_vertex(1:noc) = dum_dtv(1:noc)
3753
3754    END SUBROUTINE mas_nav_reduce_connections
3755
3756!------------------------------------------------------------------------------!
3757! Description:
3758! ------------
3759!> Initializes a point of the navigation mesh
3760!------------------------------------------------------------------------------!
3761    SUBROUTINE mas_nav_init_mesh_point ( in_mp, pid, vid, x, y )
3762
3763       IMPLICIT NONE
3764
3765       INTEGER(iwp) ::  pid !< polygon ID
3766       INTEGER(iwp) ::  vid !< vertex ID
3767
3768       REAL(wp) ::  x !< x-coordinate
3769       REAL(wp) ::  y !< y-coordinate
3770
3771       TYPE(mesh_point) ::  in_mp !< mesh point to be initialized
3772
3773       in_mp%origin_id          = -1
3774       in_mp%polygon_id         = pid
3775       in_mp%vertex_id          = vid
3776       in_mp%cost_so_far        = 1.d12
3777       in_mp%x                  = x
3778       in_mp%y                  = y
3779       in_mp%x_s                = x
3780       in_mp%y_s                = y
3781       ALLOCATE(in_mp%connected_vertices(1:100),                               &
3782                in_mp%distance_to_vertex(1:100))
3783       in_mp%connected_vertices = -999
3784       in_mp%distance_to_vertex = -999.
3785       in_mp%noc                = 0
3786
3787    END SUBROUTINE mas_nav_init_mesh_point
3788
3789!------------------------------------------------------------------------------!
3790! Description:
3791! ------------
3792!> Reading of namlist from parin file
3793!------------------------------------------------------------------------------!
3794    SUBROUTINE mas_parin
3795
3796       USE control_parameters,                                                 &
3797           ONLY: agent_time_unlimited, multi_agent_system_end,                 &
3798                 multi_agent_system_start
3799
3800       IMPLICIT NONE
3801
3802       CHARACTER (LEN=80) ::  line  !<
3803
3804       NAMELIST /agent_parameters/  a_rand_target,                             &
3805                                    adx,                                       &
3806                                    ady,                                       &
3807                                    agent_maximum_age,                         &
3808                                    agent_time_unlimited,                      &
3809                                    alloc_factor_mas,                          &
3810                                    asl,                                       &
3811                                    asn,                                       &
3812                                    asr,                                       &
3813                                    ass,                                       &
3814                                    at_x,                                      &
3815                                    at_y,                                      &
3816                                    bc_mas_lr,                                 &
3817                                    bc_mas_ns,                                 &
3818                                    coll_t_0,                                  &
3819                                    corner_gate_start,                         &
3820                                    corner_gate_width,                         &
3821                                    dim_size_agtnum_manual,                    &
3822                                    dim_size_factor_agtnum,                    &
3823                                    deallocate_memory_mas,                     &
3824                                    dist_to_int_target,                        &
3825                                    dt_agent,                                  &
3826                                    dt_arel,                                   &
3827                                    dt_write_agent_data,                       &
3828                                    end_time_arel,                             &
3829                                    max_dist_from_path,                        &
3830                                    min_nr_agent,                              &
3831                                    multi_agent_system_end,                    &
3832                                    multi_agent_system_start,                  &
3833                                    number_of_agent_groups,                    &
3834                                    radius_agent,                              &
3835                                    random_start_position_agents,              &
3836                                    read_agents_from_restartfile,              &
3837                                    repuls_agent,                              &
3838                                    repuls_wall,                               &
3839                                    scan_radius_agent,                         &
3840                                    sigma_rep_agent,                           &
3841                                    sigma_rep_wall,                            &
3842                                    step_dealloc_mas,                          &
3843                                    tau_accel_agent
3844
3845!
3846!--    Try to find agent package
3847       REWIND ( 11 )
3848       line = ' '
3849       DO WHILE ( INDEX( line, '&agent_parameters' ) == 0 )
3850          READ ( 11, '(A)', END=20 )  line
3851       ENDDO
3852       BACKSPACE ( 11 )
3853
3854!
3855!--    Read user-defined namelist
3856       READ ( 11, agent_parameters, ERR = 10, END = 20 )
3857
3858!
3859!--    Set flag that indicates that agents are switched on
3860       agents_active = .TRUE.
3861       GOTO 20
3862
3863 10    BACKSPACE( 11 )
3864       READ( 11 , '(A)') line
3865       CALL parin_fail_message( 'agent_parameters', line )
3866
3867 20    CONTINUE
3868
3869    END SUBROUTINE mas_parin
3870
3871!------------------------------------------------------------------------------!
3872! Description:
3873! ------------
3874!> Routine for the whole processor
3875!> Sort all agents into the 4 respective subgrid boxes
3876!------------------------------------------------------------------------------!
3877    SUBROUTINE mas_ps_sort_in_subboxes
3878
3879       IMPLICIT NONE
3880
3881       INTEGER(iwp) ::  i           !< grid box (x)
3882       INTEGER(iwp) ::  ip          !< counter (x)
3883       INTEGER(iwp) ::  is          !< box counter
3884       INTEGER(iwp) ::  j           !< grid box (y)
3885       INTEGER(iwp) ::  jp          !< counter (y)
3886       INTEGER(iwp) ::  m           !< sorting index
3887       INTEGER(iwp) ::  n           !< agent index
3888       INTEGER(iwp) ::  nn          !< agent counter
3889       INTEGER(iwp) ::  sort_index  !< sorting index
3890
3891       INTEGER(iwp), DIMENSION(0:3) ::  sort_count  !< number of agents in one subbox
3892
3893       TYPE(agent_type), DIMENSION(:,:), ALLOCATABLE ::  sort_agents  !< sorted agent array
3894
3895       DO  ip = nxl, nxr
3896          DO  jp = nys, nyn
3897             number_of_agents = agt_count(jp,ip)
3898             IF ( number_of_agents <= 0 )  CYCLE
3899             agents => grid_agents(jp,ip)%agents(1:number_of_agents)
3900
3901             nn = 0
3902             sort_count = 0
3903             ALLOCATE( sort_agents(number_of_agents, 0:3) )
3904
3905             DO  n = 1, number_of_agents
3906                sort_index = 0
3907
3908                IF ( agents(n)%agent_mask )  THEN
3909                   nn = nn + 1
3910!
3911!--                Sorting agents with a binary scheme
3912!--                sort_index=11_2=3_10 -> agent at the left,south subgridbox
3913!--                sort_index=10_2=2_10 -> agent at the left,north subgridbox
3914!--                sort_index=01_2=1_10 -> agent at the right,south subgridbox
3915!--                sort_index=00_2=0_10 -> agent at the right,north subgridbox
3916!--                For this the center of the gridbox is calculated
3917                   i = (agents(n)%x + 0.5_wp * dx) * ddx
3918                   j = (agents(n)%y + 0.5_wp * dy) * ddy
3919
3920                   IF ( i == ip )  sort_index = sort_index + 2
3921                   IF ( j == jp )  sort_index = sort_index + 1
3922
3923                   sort_count(sort_index) = sort_count(sort_index) + 1
3924                   m = sort_count(sort_index)
3925                   sort_agents(m,sort_index) = agents(n)
3926                   sort_agents(m,sort_index)%block_nr = sort_index
3927                ENDIF
3928             ENDDO
3929
3930             nn = 0
3931             DO is = 0,3
3932                grid_agents(jp,ip)%start_index(is) = nn + 1
3933                DO n = 1,sort_count(is)
3934                   nn = nn + 1
3935                   agents(nn) = sort_agents(n,is)
3936                ENDDO
3937                grid_agents(jp,ip)%end_index(is) = nn
3938             ENDDO
3939
3940             number_of_agents = nn
3941             agt_count(jp,ip) = number_of_agents
3942             DEALLOCATE(sort_agents)
3943          ENDDO
3944       ENDDO
3945
3946    END SUBROUTINE mas_ps_sort_in_subboxes
3947
3948!------------------------------------------------------------------------------!
3949! Description:
3950! ------------
3951!> Move all agents not marked for deletion to lowest indices (packing)
3952!------------------------------------------------------------------------------!
3953    SUBROUTINE mas_ps_pack
3954
3955       IMPLICIT NONE
3956
3957       INTEGER(iwp) ::  n  !< agent counter
3958       INTEGER(iwp) ::  nn !< number of agents
3959!
3960!--    Find out elements marked for deletion and move data from highest index
3961!--    values to these free indices
3962       nn = number_of_agents
3963
3964       DO WHILE ( .NOT. agents(nn)%agent_mask )
3965          nn = nn-1
3966          IF ( nn == 0 )  EXIT
3967       ENDDO
3968
3969       IF ( nn > 0 )  THEN
3970          DO  n = 1, number_of_agents
3971             IF ( .NOT. agents(n)%agent_mask )  THEN
3972                agents(n) = agents(nn)
3973                nn = nn - 1
3974                DO WHILE ( .NOT. agents(nn)%agent_mask )
3975                   nn = nn-1
3976                   IF ( n == nn )  EXIT
3977                ENDDO
3978             ENDIF
3979             IF ( n == nn )  EXIT
3980          ENDDO
3981       ENDIF
3982
3983!
3984!--    The number of deleted agents has been determined in routines
3985!--    mas_boundary_conds, mas_droplet_collision, and mas_eh_exchange_horiz
3986       number_of_agents = nn
3987
3988    END SUBROUTINE mas_ps_pack 
3989
3990!------------------------------------------------------------------------------!
3991! Description:
3992! ------------
3993!> Sort agents in each sub-grid box into two groups: agents that already
3994!> completed the LES timestep, and agents that need further timestepping to
3995!> complete the LES timestep.
3996!------------------------------------------------------------------------------!
3997!    SUBROUTINE mas_ps_sort_timeloop_done
3998!
3999!       IMPLICIT NONE
4000!
4001!       INTEGER(iwp) :: end_index     !< agent end index for each sub-box
4002!       INTEGER(iwp) :: i             !< index of agent grid box in x-direction
4003!       INTEGER(iwp) :: j             !< index of agent grid box in y-direction
4004!       INTEGER(iwp) :: n             !< running index for number of agents
4005!       INTEGER(iwp) :: nb            !< index of subgrid boux
4006!       INTEGER(iwp) :: nf            !< indices for agents in each sub-box that already finalized their substeps
4007!       INTEGER(iwp) :: nnf           !< indices for agents in each sub-box that need further treatment
4008!       INTEGER(iwp) :: num_finalized !< number of agents in each sub-box that already finalized their substeps
4009!       INTEGER(iwp) :: start_index   !< agent start index for each sub-box
4010!
4011!       TYPE(agent_type), DIMENSION(:), ALLOCATABLE :: sort_agents  !< temporary agent array
4012!
4013!       DO  i = nxl, nxr
4014!          DO  j = nys, nyn
4015!
4016!             number_of_agents = agt_count(j,i)
4017!             IF ( number_of_agents <= 0 )  CYCLE
4018!
4019!             agents => grid_agents(j,i)%agents(1:number_of_agents)
4020!
4021!             DO  nb = 0, 3
4022!
4023!--             Obtain start and end index for each subgrid box
4024!                start_index = grid_agents(j,i)%start_index(nb)
4025!                end_index   = grid_agents(j,i)%end_index(nb)
4026!
4027!--             Allocate temporary array used for sorting
4028!                ALLOCATE( sort_agents(start_index:end_index) )
4029!
4030!--             Determine number of agents already completed the LES
4031!--             timestep, and write them into a temporary array
4032!                nf = start_index
4033!                num_finalized = 0
4034!                DO  n = start_index, end_index
4035!                   IF ( dt_3d - agents(n)%dt_sum < 1E-8_wp )  THEN
4036!                      sort_agents(nf) = agents(n)
4037!                      nf              = nf + 1
4038!                      num_finalized   = num_finalized + 1
4039!                   ENDIF
4040!                ENDDO
4041!
4042!--             Determine number of agents that not completed the LES
4043!--             timestep, and write them into a temporary array
4044!                nnf = nf
4045!                DO  n = start_index, end_index
4046!                   IF ( dt_3d - agents(n)%dt_sum > 1E-8_wp )  THEN
4047!                      sort_agents(nnf) = agents(n)
4048!                      nnf              = nnf + 1
4049!                   ENDIF
4050!                ENDDO
4051!
4052!--             Write back sorted agents
4053!                agents(start_index:end_index) =                          &
4054!                                        sort_agents(start_index:end_index)
4055!
4056!--             Determine updated start_index, used to masked already
4057!--             completed agents.
4058!                grid_agents(j,i)%start_index(nb) =                     &
4059!                                   grid_agents(j,i)%start_index(nb)    &
4060!                                 + num_finalized
4061!
4062!--             Deallocate dummy array
4063!                DEALLOCATE ( sort_agents )
4064!
4065!--             Finally, if number of non-completed agents is non zero
4066!--             in any of the sub-boxes, set control flag appropriately.
4067!                IF ( nnf > nf )                                             &
4068!                   grid_agents(j,i)%time_loop_done = .FALSE.
4069!
4070!             ENDDO
4071!          ENDDO
4072!       ENDDO
4073!
4074!    END SUBROUTINE mas_ps_sort_timeloop_done
4075
4076!------------------------------------------------------------------------------!
4077! Description:
4078! ------------
4079!> Calls social forces calculations
4080!------------------------------------------------------------------------------!
4081    SUBROUTINE mas_timestep_forces_call ( ip, jp )
4082
4083       IMPLICIT NONE
4084
4085       INTEGER(iwp) ::  ip  !< counter, x-direction
4086       INTEGER(iwp) ::  jp  !< counter, y-direction
4087       INTEGER(iwp) ::  n   !< loop variable over all agents in a grid box
4088
4089!
4090!--    Get direction for all agents in current grid cell
4091       CALL mas_agent_direction
4092
4093       DO n = 1, number_of_agents
4094
4095          force_x = 0.0_wp
4096          force_y = 0.0_wp
4097
4098          CALL mas_timestep_social_forces ( 'acceleration', n, ip, jp )
4099
4100          CALL mas_timestep_social_forces ( 'other_agents', n, ip, jp )
4101
4102          CALL mas_timestep_social_forces ( 'walls',        n, ip, jp )
4103!
4104!--       Update forces
4105          agents(n)%force_x = force_x
4106          agents(n)%force_y = force_y
4107       ENDDO
4108
4109    END SUBROUTINE mas_timestep_forces_call
4110
4111!------------------------------------------------------------------------------!
4112! Description:
4113! ------------
4114!> Euler timestep of agent transport
4115!------------------------------------------------------------------------------!
4116    SUBROUTINE mas_timestep
4117
4118       IMPLICIT NONE
4119
4120       INTEGER(iwp) ::  n !< loop variable over all agents in a grid box
4121
4122       REAL(wp) ::  abs_v !< absolute value of velocity
4123       REAL(wp) ::  abs_f !< absolute value of force
4124
4125       DO n = 1, number_of_agents
4126!
4127!--       Limit absolute force to a maximum to prevent unrealistic acceleration
4128          abs_f = SQRT((agents(n)%force_x)**2 + (agents(n)%force_y)**2)
4129          IF ( abs_f > 20. ) THEN
4130             agents(n)%force_x = agents(n)%force_x * 20. / abs_f
4131             agents(n)%force_y = agents(n)%force_y * 20. / abs_f
4132          ENDIF
4133!
4134!--       Update agent speed
4135          agents(n)%speed_x = agents(n)%speed_x + agents(n)%force_x * dt_agent
4136          agents(n)%speed_y = agents(n)%speed_y + agents(n)%force_y * dt_agent
4137!
4138!--       Reduction of agent speed to maximum agent speed
4139          abs_v = SQRT((agents(n)%speed_x)**2 + (agents(n)%speed_y)**2)
4140          IF ( abs_v > v_max_agent ) THEN
4141             agents(n)%speed_x = agents(n)%speed_x * v_max_agent / abs_v
4142             agents(n)%speed_y = agents(n)%speed_y * v_max_agent / abs_v
4143          ENDIF
4144!
4145!--       Update agent position
4146          agents(n)%x = agents(n)%x + agents(n)%speed_x * dt_agent
4147          agents(n)%y = agents(n)%y + agents(n)%speed_y * dt_agent
4148!
4149!--       Update absolute value of agent speed
4150          agents(n)%speed_abs = abs_v
4151!
4152!--       Increment the agent age and the total time that the agent
4153!--       has advanced within the agent timestep procedure
4154          agents(n)%age_m  = agents(n)%age
4155          agents(n)%age    = agents(n)%age    + dt_agent
4156          agents(n)%dt_sum = agents(n)%dt_sum + dt_agent
4157!
4158!--       Check whether there is still an agent that has not yet completed
4159!--       the total LES timestep
4160          IF ( ( dt_3d - agents(n)%dt_sum ) > 1E-8_wp )  THEN
4161             dt_3d_reached_l_mas = .FALSE.
4162          ENDIF
4163
4164       ENDDO
4165
4166    END SUBROUTINE mas_timestep
4167
4168!------------------------------------------------------------------------------!
4169! Description:
4170! ------------
4171!> Calculates the Social Forces (Helbing and Molnar, 1995) that the agent
4172!> experiences due to acceleration towards target and repulsion by obstacles
4173!------------------------------------------------------------------------------!
4174    SUBROUTINE mas_timestep_social_forces ( mode, nl, ip, jp )
4175
4176       IMPLICIT NONE
4177
4178       CHARACTER (LEN=*) ::  mode  !< identifier for the mode of calculation
4179
4180       INTEGER(iwp) ::  ij_dum      !< index of nearest wall
4181       INTEGER(iwp) ::  il          !< index variable along x
4182       INTEGER(iwp) ::  ip          !< index variable along x
4183       INTEGER(iwp) ::  jl          !< index variable along y
4184       INTEGER(iwp) ::  jp          !< index variable along y
4185       INTEGER(iwp) ::  nl          !< loop variable over all agents in a grid box
4186       INTEGER(iwp) ::  no          !< loop variable over all agents in a grid box
4187       INTEGER(iwp) ::  noa         !< amount of agents in a grid box
4188       INTEGER(iwp) ::  sc_x_end    !< index for scan for topography/other agents
4189       INTEGER(iwp) ::  sc_x_start  !< index for scan for topography/other agents
4190       INTEGER(iwp) ::  sc_y_end    !< index for scan for topography/other agents
4191       INTEGER(iwp) ::  sc_y_start  !< index for scan for topography/other agents
4192
4193       LOGICAL ::  corner_found  !< flag that indicates a corner has been found near agent
4194
4195       REAL(wp) ::  a_pl             !< factor for collision avoidance
4196       REAL(wp) ::  ax_semimaj       !< semiminor axis of repulsive ellipse
4197       REAL(wp) ::  b_pl             !< factor for collision avoidance
4198       REAL(wp) ::  c_pl             !< factor for collision avoidance
4199       REAL(wp) ::  coll_t           !< time at which the next collision would happen
4200       REAL(wp) ::  d_coll_t_0       !< inverse of collision cutoff time
4201       REAL(wp) ::  d_pl             !< factor for collision avoidance
4202       REAL(wp) ::  ddum_f           !< dummy devisor collision avoidance
4203       REAL(wp) ::  dist             !< distance to obstacle
4204       REAL(wp) ::  dist_sq          !< distance to obstacle squared
4205       REAL(wp) ::  pos_rel_x        !< relative position of two agents (x)
4206       REAL(wp) ::  pos_rel_y        !< relative position of two agents (y)
4207       REAL(wp) ::  r_sq             !< y-position
4208       REAL(wp) ::  sra              !< scan radius (agents)
4209       REAL(wp) ::  srw              !< local variable for scan radius (walls)
4210       REAL(wp) ::  v_rel_x          !< relative velocity (x); collision avoidance
4211       REAL(wp) ::  v_rel_y          !< relative velocity (y); collision avoidance
4212       REAL(wp) ::  x_a              !< x-position
4213       REAL(wp) ::  x_wall           !< x-position of wall
4214       REAL(wp) ::  y_a              !< y-position
4215       REAL(wp) ::  y_wall           !< y-position of wall
4216
4217       REAL(wp), PARAMETER ::  k_pl = 1.5  !< factor for collision avoidance
4218
4219       TYPE(agent_type), DIMENSION(:), POINTER ::  l_agts !< agents that repulse current agent
4220
4221!
4222!--    Initialization
4223       x_a = agents(nl)%x
4224       y_a = agents(nl)%y
4225
4226       SELECT CASE ( TRIM( mode ) )
4227!
4228!--       Calculation of force due to agent trying to approach desired velocity
4229          CASE ( 'acceleration' )
4230
4231             force_x = force_x + d_tau_accel_agent                             &
4232                          * ( agents(nl)%speed_des*agents(nl)%speed_e_x        &
4233                             -agents(nl)%speed_x )
4234
4235             force_y = force_y + d_tau_accel_agent                             &
4236                          * ( agents(nl)%speed_des*agents(nl)%speed_e_y        &
4237                             -agents(nl)%speed_y )
4238
4239!
4240!--       Calculation of repulsive forces by other agents in a radius around the
4241!--       current one
4242          CASE ( 'other_agents' )
4243
4244             sra = scan_radius_agent
4245             d_coll_t_0 = 1./coll_t_0
4246!
4247!--          Find relevant gridboxes (those that could contain agents within
4248!--          scan radius)
4249             sc_x_start = FLOOR( (x_a - sra) * ddx )
4250             sc_x_end   = FLOOR( (x_a + sra) * ddx )
4251             sc_y_start = FLOOR( (y_a - sra) * ddx )
4252             sc_y_end   = FLOOR( (y_a + sra) * ddx )
4253             IF ( sc_x_start < nxlg ) sc_x_start = nxlg
4254             IF ( sc_x_end   > nxrg ) sc_x_end   = nxrg
4255             IF ( sc_y_start < nysg ) sc_y_start = nysg
4256             IF ( sc_y_end   > nyng ) sc_y_end   = nyng
4257
4258             sra = sra**2
4259!
4260!--          Loop over all previously found relevant gridboxes
4261             DO il = sc_x_start, sc_x_end
4262                DO jl = sc_y_start, sc_y_end
4263                   noa = agt_count(jl,il)
4264                   IF ( noa <= 0 )  CYCLE
4265                   l_agts => grid_agents(jl,il)%agents(1:noa)
4266                   DO no = 1, noa
4267!
4268!--                   Skip self
4269                      IF ( jl == jp .AND. il == ip .AND. no == nl ) CYCLE
4270                      pos_rel_x = l_agts(no)%x - x_a
4271                      pos_rel_y = l_agts(no)%y - y_a
4272                      dist_sq = pos_rel_x**2 + pos_rel_y**2
4273                      IF ( dist_sq > sra ) CYCLE
4274                      r_sq    = (2*radius_agent)**2
4275                      v_rel_x   = agents(nl)%speed_x - l_agts(no)%speed_x
4276                      v_rel_y   = agents(nl)%speed_y - l_agts(no)%speed_y
4277!
4278!--                   Collision is already occuring, default to standard
4279!--                   social forces
4280                      IF ( dist_sq <= r_sq ) THEN
4281                         dist = SQRT(dist_sq) + 1.0d-12
4282                         ax_semimaj = .5_wp*SQRT( dist )
4283
4284                         force_x = force_x - 0.125_wp * repuls_agent           &
4285                                        * d_sigma_rep_agent / ax_semimaj       &
4286                                        * EXP( -ax_semimaj*d_sigma_rep_agent ) &
4287                                        * (pos_rel_x/dist)
4288
4289                         force_y = force_y - 0.125_wp * repuls_agent           &
4290                                        * d_sigma_rep_agent / ax_semimaj       &
4291                                        * EXP( -ax_semimaj*d_sigma_rep_agent ) &
4292                                        * (pos_rel_y/dist)
4293!
4294!--                   Currently no collision, calculate collision avoidance
4295!--                   force according to Karamouzas et al (2014, PRL 113,238701)
4296                      ELSE
4297!
4298!--                     factors
4299                         a_pl = v_rel_x**2 +  v_rel_y**2
4300                         b_pl = pos_rel_x*v_rel_x + pos_rel_y*v_rel_y
4301                         c_pl = dist_sq - r_sq
4302                         d_pl = b_pl**2 - a_pl*c_pl
4303!
4304!--                      If the two agents are moving non-parallel, calculate
4305!--                      collision avoidance social force
4306                         IF ( d_pl > 0.0_wp .AND.                              &
4307                            ( a_pl < -0.00001 .OR. a_pl > 0.00001 ) )          &
4308                         THEN
4309
4310                            d_pl   = SQRT(d_pl)
4311                            coll_t = (b_pl - d_pl)/a_pl
4312                            IF ( coll_t > 0.0_wp ) THEN
4313!
4314!--                            Dummy factor
4315                               ddum_f = 1. / ( a_pl * coll_t**2 )              &
4316                                           * ( 2. / coll_t + 1.0 * d_coll_t_0 )
4317!
4318!--                            x-component of social force
4319                               force_x = force_x - k_pl *                      &
4320                                         EXP( -coll_t * d_coll_t_0 ) *         &
4321                                         ( v_rel_x -                           &
4322                                           ( b_pl * v_rel_x -                  &
4323                                             a_pl * pos_rel_x ) / d_pl ) *     &
4324                                         ddum_f
4325!
4326!--                            y-component of social force
4327                               force_y = force_y - k_pl *                      &
4328                                         EXP( -coll_t * d_coll_t_0 ) *         &
4329                                         ( v_rel_y -                           &
4330                                           ( b_pl * v_rel_y -                  &
4331                                             a_pl * pos_rel_y ) / d_pl ) *     &
4332                                         ddum_f
4333
4334                            ENDIF
4335                         ENDIF
4336                      ENDIF
4337                   ENDDO
4338                ENDDO
4339             ENDDO
4340
4341          CASE ( 'walls' )
4342
4343             srw = scan_radius_wall
4344             corner_found = .FALSE.
4345!
4346!--          find relevant grid boxes (those that could contain topography
4347!--          within radius)
4348             sc_x_start = (x_a - srw) * ddx
4349             sc_x_end   = (x_a + srw) * ddx
4350             sc_y_start = (y_a - srw) * ddx
4351             sc_y_end   = (y_a + srw) * ddx
4352             IF ( sc_x_start < nxlg ) sc_x_start = nxlg
4353             IF ( sc_x_end   > nxrg ) sc_x_end   = nxrg
4354             IF ( sc_y_start < nysg ) sc_y_start = nysg
4355             IF ( sc_y_end   > nyng ) sc_y_end   = nyng
4356!
4357!--          Find "walls" ( i.e. topography steps (up or down) higher than one
4358!--          grid box ) that are perpendicular to the agent within the defined
4359!--          search radius. Such obstacles cannot be passed and a social force
4360!--          to that effect is applied.
4361!--          Walls only apply a force perpendicular to the wall to the agent.
4362!--          There is therefore a search for walls directly right, left, south
4363!--          and north of the agent. All other walls are ignored.
4364!--
4365!--          Check for wall left of current agent
4366             ij_dum = 0
4367             IF ( sc_x_start < ip ) THEN
4368                DO il = ip - 1, sc_x_start, -1
4369!
4370!--                Going left from the agent, check for a right wall
4371                   IF ( BTEST( obstacle_flags(jp,il), 2 ) ) THEN
4372!
4373!--                   obstacle found in grid box il, wall at right side
4374                      x_wall = (il+1)*dx
4375!
4376!--                   Calculate force of found wall on agent
4377                      CALL mas_timestep_wall_corner_force( x_a, x_wall, y_a,   &
4378                                                           y_a )
4379!
4380!--                   calculate new x starting index for later scan for corners
4381                      ij_dum = il + 1
4382                      EXIT
4383                   ENDIF
4384                ENDDO
4385             ENDIF
4386             IF ( ij_dum /= 0 ) sc_x_start = ij_dum 
4387
4388!
4389!--          Check for wall right of current agent
4390             ij_dum = 0
4391             IF ( sc_x_end > ip ) THEN
4392                DO il = ip + 1, sc_x_end
4393!
4394!--                Going right from the agent, check for a left wall
4395                   IF ( BTEST( obstacle_flags(jp,il), 6 ) ) THEN
4396!
4397!--                   obstacle found in grid box il, wall at left side
4398                      x_wall = il*dx
4399!
4400!--                   Calculate force of found wall on agent
4401                      CALL mas_timestep_wall_corner_force( x_a, x_wall, y_a,   &
4402                                                           y_a )
4403!
4404!--                   calculate new x end index for later scan for corners
4405                      ij_dum = il - 1
4406                      EXIT
4407                   ENDIF
4408                ENDDO
4409             ENDIF
4410             IF ( ij_dum /= 0 ) sc_x_end = ij_dum 
4411
4412!
4413!--          Check for wall south of current agent
4414             ij_dum = 0
4415             IF ( sc_y_start < jp ) THEN
4416                DO jl = jp - 1, sc_y_start, -1
4417!
4418!--                Going south from the agent, check for a north wall
4419                   IF ( BTEST( obstacle_flags(jl,ip), 0 ) ) THEN
4420!
4421!--                   obstacle found in grid box jl, wall at left side
4422                      y_wall = (jl+1)*dy
4423
4424                      CALL mas_timestep_wall_corner_force( x_a, x_a, y_a,      &
4425                                                           y_wall )
4426!
4427!--                   calculate new y starting index for later scan for corners
4428                      ij_dum = jl + 1
4429                      EXIT
4430                   ENDIF
4431                ENDDO
4432             ENDIF
4433             IF ( ij_dum /= 0 ) sc_y_start = ij_dum 
4434
4435!
4436!--          Check for wall north of current agent
4437             ij_dum = 0
4438             IF ( sc_y_end > jp ) THEN
4439                DO jl = jp + 1, sc_y_end 
4440!
4441!--                Going north from the agent, check for a south wall
4442                   IF ( BTEST( obstacle_flags(jl,ip), 4 ) ) THEN
4443!
4444!--                   obstacle found in grid box jl, wall at left side
4445                      y_wall = jl*dy
4446
4447                      CALL mas_timestep_wall_corner_force( x_a, x_a, y_a,      &
4448                                                           y_wall )
4449!
4450!--                   calculate new y end index for later scan for corners
4451                      ij_dum = jl - 1
4452                   ENDIF
4453                ENDDO
4454             ENDIF
4455             IF ( ij_dum /= 0 ) sc_y_end = ij_dum 
4456
4457!
4458!--          Scan for corners surrounding current agent.
4459!--          Only gridcells that are closer than the closest wall in each
4460!--          direction (n,s,r,l) are considered in the search since those
4461!--          further away would have a significantly smaller resulting force
4462!--          than the closer wall.
4463             DO il = sc_x_start, sc_x_end
4464                DO jl = sc_y_start, sc_y_end
4465                   IF ( il == ip .OR. jl == jp ) CYCLE
4466!
4467!--                corners left of agent
4468                   IF ( il < ip ) THEN
4469!
4470!--                   south left quadrant: look for north right corner
4471                      IF ( jl < jp ) THEN
4472                         IF ( BTEST( obstacle_flags(jl,il), 1 ) ) THEN
4473!
4474!--                         calculate coordinates of the found corner
4475                            x_wall = (il+1)*dx
4476                            y_wall = (jl+1)*dy
4477
4478                            CALL mas_timestep_wall_corner_force( x_a, x_wall,  &
4479                                                                 y_a, y_wall )
4480
4481                         ENDIF
4482!
4483!--                   north left quadrant: look for south right corner
4484                      ELSEIF ( jl > jp ) THEN
4485                         IF ( BTEST( obstacle_flags(jl,il), 3 ) ) THEN
4486!
4487!--                         calculate coordinates of the corner of said gridcell
4488!--                         that is closest to the current agent
4489                            x_wall = (il+1)*dx
4490                            y_wall = jl*dy
4491
4492                            CALL mas_timestep_wall_corner_force( x_a, x_wall,  &
4493                                                                 y_a, y_wall )
4494
4495                         ENDIF
4496                      ENDIF
4497                   ELSEIF ( il > ip ) THEN
4498!
4499!--                   south right quadrant: look for north left corner
4500                      IF ( jl < jp ) THEN
4501                         IF ( BTEST( obstacle_flags(jl,il), 7 ) ) THEN
4502!
4503!--                         calculate coordinates of the corner of said gridcell
4504!--                         that is closest to the current agent
4505                            x_wall = il*dx
4506                            y_wall = (jl+1)*dy
4507
4508                            CALL mas_timestep_wall_corner_force( x_a, x_wall,  &
4509                                                                 y_a, y_wall )
4510
4511                         ENDIF
4512!
4513!--                   north right quadrant: look for south left corner
4514                      ELSEIF ( jl > jp ) THEN
4515                         IF ( BTEST( obstacle_flags(jl,il), 5 ) ) THEN
4516!
4517!--                         calculate coordinates of the corner of said gridcell
4518!--                         that is closest to the current agent
4519                            x_wall = il*dx
4520                            y_wall = jl*dy
4521
4522                            CALL mas_timestep_wall_corner_force( x_a, x_wall,  &
4523                                                                 y_a, y_wall )
4524
4525                         ENDIF
4526                      ENDIF
4527                   ENDIF
4528                ENDDO
4529             ENDDO
4530
4531          CASE DEFAULT
4532
4533       END SELECT
4534
4535    END SUBROUTINE mas_timestep_social_forces
4536
4537!------------------------------------------------------------------------------!
4538! Description:
4539! ------------
4540!> Given a distance to the current agent, calculates the force a found corner
4541!> or wall exerts on that agent
4542!------------------------------------------------------------------------------!
4543    SUBROUTINE mas_timestep_wall_corner_force( xa, xw, ya, yw )
4544
4545       IMPLICIT NONE
4546
4547       REAL(wp) ::  dist_l     !< distance to obstacle
4548       REAL(wp) ::  force_d_x  !< increment of social force, x-direction
4549       REAL(wp) ::  force_d_y  !< increment of social force, x-direction
4550       REAL(wp) ::  xa         !< x-position of agent
4551       REAL(wp) ::  xw         !< x-position of wall
4552       REAL(wp) ::  ya         !< x-position of agent
4553       REAL(wp) ::  yw         !< y-position of wall
4554
4555       force_d_x = 0.0_wp
4556       force_d_y = 0.0_wp
4557!
4558!--    calculate coordinates of corner relative to agent
4559!--    postion and distance between corner and agent
4560       xw = xa - xw
4561       yw = ya - yw
4562       dist_l = SQRT( (xw)**2 + (yw)**2 )
4563!
4564!--    calculate x and y component of repulsive force
4565!--    induced by previously found corner
4566       IF ( dist_l > 0 ) THEN
4567          force_d_x = repuls_wall * d_sigma_rep_wall         &
4568                      * EXP( -dist_l * d_sigma_rep_wall )      &
4569                      * xw / (dist_l)
4570          force_d_y = repuls_wall * d_sigma_rep_wall         &
4571                      * EXP( -dist_l * d_sigma_rep_wall )      &
4572                      * yw / (dist_l)
4573       ENDIF
4574
4575! !--    forces that are located outside of a sight radius of
4576! !--    200° (-> COS(100./180.*pi) = COS(.555*pi)) of
4577! !--    current agent are considered to have an effect of 50%
4578!        IF ( force_d_x * agents(nl)%speed_e_x +               &
4579!             force_d_y * agents(nl)%speed_e_y <               &
4580!             SQRT(force_d_x**2 + force_d_y**2) *              &
4581!             COS( .55555555 * 3.1415 ) )                      &
4582!        THEN
4583!           force_d_x = force_d_x * .5_wp
4584!           force_d_y = force_d_y * .5_wp
4585!        ENDIF
4586
4587!
4588!--    add force increment to total force of current agent
4589       force_x = force_x + force_d_x
4590       force_y = force_y + force_d_y
4591
4592    END SUBROUTINE mas_timestep_wall_corner_force
4593
4594!
4595!-- Calculates distance of point P to edge (A,B). If A = B, calculates
4596!-- point-to-point distance from A/B to P
4597    FUNCTION dist_point_to_edge ( a_x, a_y, b_x, b_y, p_x, p_y )
4598
4599       IMPLICIT NONE
4600
4601       REAL(wp)  :: ab_x                !< x-coordinate of vector from A to B
4602       REAL(wp)  :: ab_y                !< y-coordinate of vector from A to B
4603       REAL(wp)  :: ab_d                !< inverse length of vector from A to B
4604       REAL(wp)  :: ab_u_x              !< x-coordinate of vector with direction of ab and length 1
4605       REAL(wp)  :: ab_u_y              !< y-coordinate of vector with direction of ab and length 1
4606       REAL(wp)  :: ba_x                !< x-coordinate of vector from B to A
4607       REAL(wp)  :: ba_y                !< y-coordinate of vector from B to A
4608       REAL(wp)  :: ap_x                !< x-coordinate of vector from A to P
4609       REAL(wp)  :: ap_y                !< y-coordinate of vector from A to P
4610       REAL(wp)  :: bp_x                !< x-coordinate of vector from B to P
4611       REAL(wp)  :: bp_y                !< y-coordinate of vector from B to P
4612       REAL(wp)  :: a_x                 !< x-coordinate of point A of edge
4613       REAL(wp)  :: a_y                 !< y-coordinate of point A of edge
4614       REAL(wp)  :: b_x                 !< x-coordinate of point B of edge
4615       REAL(wp)  :: b_y                 !< y-coordinate of point B of edge
4616       REAL(wp)  :: p_x                 !< x-coordinate of point P
4617       REAL(wp)  :: p_y                 !< y-coordinate of point P
4618       REAL(wp)  :: dist_x              !< x-coordinate of point P
4619       REAL(wp)  :: dist_y              !< y-coordinate of point P
4620       REAL(wp)  :: dist_point_to_edge  !< y-coordinate of point P
4621
4622       ab_x = - a_x + b_x
4623       ab_y = - a_y + b_y
4624       ba_x = - b_x + a_x 
4625       ba_y = - b_y + a_y 
4626       ap_x = - a_x + p_x
4627       ap_y = - a_y + p_y
4628       bp_x = - b_x + p_x
4629       bp_y = - b_y + p_y
4630
4631       IF ( ab_x * ap_x + ab_y * ap_y <= 0. ) THEN
4632          dist_point_to_edge = SQRT((a_x - p_x)**2 + (a_y - p_y)**2)
4633       ELSEIF ( ba_x * bp_x + ba_y * bp_y <= 0. ) THEN
4634          dist_point_to_edge = SQRT((b_x - p_x)**2 + (b_y - p_y)**2)
4635       ELSE
4636          ab_d = 1./SQRT((ab_x)**2+(ab_y)**2)
4637